1: \ wiki forth
2:
3: \ Copyright (C) 2003,2004 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: require string.fs
22:
23: \ basic stuff
24:
25: : -scan ( addr u char -- addr' u' )
26: >r BEGIN dup WHILE 1- 2dup + c@ r@ = UNTIL THEN
27: rdrop ;
28: : -$split ( addr u char -- addr1 u1 addr2 u2 )
29: >r 2dup r@ -scan 2dup + c@ r> = negate over + >r
30: 2swap r> /string ;
31: : parse" ( -- addr u ) '" parse 2drop '" parse ;
32: : .' '' parse postpone SLiteral postpone type ; immediate
33: : s' '' parse postpone SLiteral ; immediate
34:
35: \ character recoding
36:
37: [IFDEF] 8-bit-io 8-bit-io [THEN]
38: \ UTF-8 IO fails with .type:
39:
40: : .type ( addr u -- )
41: bounds ?DO I c@
42: case
43: '& of ." &" endof
44: '< of ." <" endof
45: dup emit
46: endcase
47: LOOP ;
48:
49: \ tag handling
50:
51: Variable indentlevel
52: Variable tag-option
53: Variable tag-class
54: s" " tag-option $!
55: s" " tag-class $!
56:
57: : tag ( addr u -- ) '< emit type
58: tag-class $@len IF .\" class=\"" tag-class $@ type '" emit THEN
59: tag-option $@ type
60: '> emit
61: s" " tag-option $! s" " tag-class $! ;
62: : tag/ ( addr u -- ) s" /" tag-option $+! tag ;
63: : /tag ( addr u -- ) '< emit '/ emit type '> emit ;
64: : tagged ( addr1 u1 addr2 u2 -- ) 2dup 2>r tag .type 2r> /tag ;
65:
66: : opt ( addr u opt u -- ) s" " tag-option $+!
67: tag-option $+! s' ="' tag-option $+! tag-option $+!
68: s' "' tag-option $+! ;
69: : n>string ( n -- addr u ) 0 <# #S #> ;
70: : xy>string ( x y -- ) swap 0 <# #S 'x hold 2drop 0 #S 's hold #> ;
71: : opt# ( n opt u -- ) rot n>string 2swap opt ;
72: : href= ( addr u -- ) s" href" opt ;
73: : id= ( addr u -- ) s" id" opt ;
74: : src= ( addr u -- ) s" src" opt ;
75: : alt= ( addr u -- ) s" alt" opt ;
76: : width= ( n -- ) s" width" opt# ;
77: : height= ( n -- ) s" height" opt# ;
78: : align= ( addr u -- ) s" align" opt ;
79: : class= ( addr u -- )
80: tag-class $@len IF s" " tag-class $+! THEN
81: tag-class $+! ;
82: : indent= ( -- )
83: indentlevel @ 0 <# #S 'p hold #> class= ;
84: : mailto: ( addr u -- ) s' href="mailto:' tag-option $+!
85: tag-option $+! s' "' tag-option $+! ;
86:
87: \ environment handling
88:
89: Variable end-sec
90: Variable oldenv
91: Variable envs 30 0 [DO] 0 , [LOOP]
92:
93: : env$ ( -- addr ) envs dup @ 1+ cells + ;
94: : env ( addr u -- ) env$ $! ;
95: : env? ( -- ) envs @ oldenv @
96: 2dup > IF env$ $@ tag THEN
97: 2dup < IF env$ cell+ $@ /tag env$ cell+ $off THEN
98: drop oldenv ! ;
99: : +env 1 envs +! ;
100: : -env end-sec @ envs @ 2 > or IF -1 envs +! env? THEN ;
101: : -envs envs @ 0 ?DO -env cr LOOP ;
102: : >env ( addr u -- ) +env env env? ;
103:
104: \ alignment
105:
106: Variable table-format
107: Variable table#
108: Create table-starts &10 0 [DO] 0 c, 0 c, [LOOP]
109: Variable taligned
110:
111: : >align ( c -- )
112: CASE
113: 'l OF s" left" class= ENDOF
114: 'r OF s" right" class= ENDOF
115: 'c OF s" center" class= ENDOF
116: '< OF s" left" class= ENDOF
117: '> OF s" right" class= ENDOF
118: '= OF s" center" class= ENDOF
119: '~ OF s" middle" class= ENDOF
120: ENDCASE ;
121:
122: : >talign ( c -- )
123: CASE
124: 'l OF s" left" align= ENDOF
125: 'r OF s" right" align= ENDOF
126: 'c OF s" center" align= ENDOF
127: '< OF s" left" align= ENDOF
128: '> OF s" right" align= ENDOF
129: '= OF s" center" align= ENDOF
130: ENDCASE taligned on ;
131:
132: : >border ( c -- )
133: case
134: '- of s" border0" class= endof
135: '+ of s" border1" class= endof
136: endcase ;
137:
138: \ image handling
139:
140: wordlist Constant img-sizes
141:
142: Create imgbuf $20 allot
143:
144: Create pngsig $89 c, $50 c, $4E c, $47 c, $0D c, $0A c, $1A c, $0A c,
145: Create jfif $FF c, $D8 c, $FF c, $E0 c, $00 c, $10 c, $4A c, $46 c,
146: $49 c, $46 c,
147:
148: : b@ ( addr -- x ) 0 swap 4 bounds ?DO 8 lshift I c@ + LOOP ;
149: : bw@ ( addr -- x ) 0 swap 2 bounds ?DO 8 lshift I c@ + LOOP ;
150:
151: : gif? ( -- flag )
152: s" GIF89a" imgbuf over str=
153: s" GIF87a" imgbuf over str= or ;
154: : gif-size ( -- w h )
155: imgbuf 8 + c@ imgbuf 9 + c@ 8 lshift +
156: imgbuf 6 + c@ imgbuf 7 + c@ 8 lshift + ;
157:
158: : png? ( -- flag )
159: pngsig 8 imgbuf over str= ;
160: : png-size ( -- w h )
161: imgbuf $14 + b@ imgbuf $10 + b@ ;
162:
163: : jpg? ( -- flag )
164: jfif 10 imgbuf over str= ;
165: : jpg-size ( fd -- w h ) >r
166: 2. BEGIN
167: 2dup r@ reposition-file throw
168: imgbuf $10 r@ read-file throw 0<>
169: imgbuf bw@ $FFC0 $FFD0 within 0= and WHILE
170: imgbuf 2 + bw@ 2 + 0 d+ REPEAT
171: 2drop imgbuf 5 + bw@ imgbuf 7 + bw@ rdrop ;
172:
173: : img-size ( fd -- w h ) >r
174: gif? IF gif-size rdrop EXIT THEN
175: jpg? IF r> jpg-size EXIT THEN
176: png? IF png-size rdrop EXIT THEN
177: 0 0 rdrop ;
178:
179: 3 set-precision
180:
181: : f.size ( r -- )
182: f$ dup >r 0<=
183: IF '0 emit
184: ELSE scratch r@ min type r@ precision - zeros THEN
185: '. emit r@ negate zeros
186: scratch r> 0 max /string 0 max -zeros type ;
187:
188: : size-does> ( -- ) DOES> ( -- )
189: ." img." dup body> >name .name
190: 2@ ." { width: "
191: s>d d>f 13.8e f/ f.size ." em; height: "
192: s>d d>f 13.8e f/ f.size ." em; }" cr ;
193:
194: : size-css ( file< > -- )
195: outfile-id >r
196: bl sword r/w create-file throw to outfile-id
197: img-sizes wordlist-id
198: BEGIN @ dup WHILE
199: dup name>int execute
200: REPEAT drop
201: outfile-id close-file throw
202: r> to outfile-id
203: dup 0< IF throw ELSE drop THEN ;
204:
205: : size-class ( x y addr u -- x y )
206: 2dup class=
207: 2dup img-sizes search-wordlist IF drop 2drop
208: ELSE
209: get-current >r img-sizes set-current
210: nextname Create 2dup , , size-does>
211: r> set-current
212: THEN ;
213:
214: : .img-size ( addr u -- )
215: r/o open-file IF drop EXIT THEN >r
216: imgbuf $20 r@ read-file throw drop
217: r@ img-size
218: r> close-file throw
219: 2dup or IF 2dup xy>string size-class THEN
220: ?dup IF width= THEN
221: ?dup IF height= THEN
222: ;
223:
224: \ link creation
225:
226: Variable link
227: Variable link-sig
228: Variable link-suffix
229: Variable iconpath
230: Variable icon-prefix
231: Variable icon-tmp
232:
233: Variable do-size
234: Variable do-icon
235:
236: Defer parse-line
237:
238: : .img ( addr u -- )
239: dup >r '@ -$split dup r> = IF 2swap 2drop
240: ELSE 2swap icon-tmp $! icon-prefix $@ icon-tmp $+! icon-tmp $+!
241: icon-tmp $@ THEN
242: dup >r '| -$split dup r> = IF 2swap THEN
243: dup IF 2swap alt= ELSE 2drop THEN
244: tag-class $@len >r over c@ >align tag-class $@len r> = 1+ /string
245: tag-class $@len >r over c@ >border tag-class $@len r> = 1+ /string
246: 2dup .img-size src= s" img" tag/ ;
247: : >img ( -- ) '{ parse type '} parse .img ;
248:
249: : alt-suffix ( -- )
250: link-suffix $@len 2 - link-suffix $!len
251: s" [" link-suffix 0 $ins
252: s" ]" link-suffix $+!
253: link-suffix $@ alt= ;
254:
255: : get-icon ( addr u -- ) iconpath @ IF 2drop EXIT THEN
256: link-suffix $! s" .*" link-suffix $+!
257: icon-prefix $@ open-dir throw >r
258: BEGIN
259: pad $100 r@ read-dir throw WHILE
260: pad swap 2dup link-suffix $@ filename-match
261: IF icon-prefix $@ iconpath $! s" /" iconpath $+! iconpath $+!
262: iconpath $@ 2dup .img-size src= '- >border
263: alt-suffix s" img" tag/ true
264: ELSE 2drop false THEN
265: UNTIL ELSE drop THEN
266: r> close-dir throw ;
267:
268: : link-icon? ( -- ) do-icon @ 0= ?EXIT
269: iconpath @ IF iconpath $off THEN
270: link $@ + 1- c@ '/ = IF s" index.html" ELSE link $@ THEN
271: '# $split 2drop
272: BEGIN '. $split 2swap 2drop dup WHILE
273: 2dup get-icon REPEAT 2drop ;
274:
275: : link-size? ( -- ) do-size @ 0= ?EXIT
276: link $@ r/o open-file IF drop EXIT THEN >r
277: r@ file-size throw $400 um/mod nip
278: dup $800 < IF ." (" 0 u.r ." k)"
279: ELSE $400 / ." (" 0 u.r ." M)" THEN
280: r> close-file throw ;
281:
282: : link-sig? ( -- )
283: link $@ link-sig $! s" .sig" link-sig $+!
284: link-sig $@ r/o open-file IF drop EXIT THEN
285: close-file throw
286: ." (" link-sig $@ href= s" a" tag
287: s" |-@/sig.gif" .img ." sig" s" /a" tag ." )" ;
288:
289: : link-warn? ( -- ) \ local links only
290: link $@ ': scan nip ?EXIT
291: link $@ '# $split 2drop r/o open-file nip IF
292: s" Dead Link '" stderr write-file throw
293: link $@ stderr write-file throw
294: s\" ' !!!\n" stderr write-file throw
295: THEN ;
296:
297: : link-options ( addr u -- addr' u' )
298: do-size off do-icon on
299: over c@ '% = over 0> and IF do-size on 1 /string THEN
300: over c@ '\ = over 0> and IF do-icon off 1 /string THEN ;
301:
302: s" Gforth" environment? [IF] s" 0.5.0" str= [IF]
303: : parse-string ( c-addr u -- ) \ core,block
304: s" *evaluated string*" loadfilename>r
305: push-file #tib ! >tib !
306: >in off blk off loadfile off -1 loadline !
307: ['] parse-line catch
308: pop-file r>loadfilename throw ;
309: [ELSE]
310: : parse-string ( addr u -- )
311: evaluate-input cell new-tib #tib ! tib !
312: ['] parse-line catch pop-file throw ;
313: [THEN] [THEN]
314:
315: : .link ( addr u -- ) dup >r '| -$split dup r> = IF 2swap THEN
316: link-options link $!
317: link $@len 0= IF 2dup link $! ( s" .html" link $+! ) THEN
318: link $@ href= s" a" tag link-icon?
319: parse-string s" a" /tag link-size? link-sig? link-warn? ;
320: : >link ( -- ) '[ parse type '] parse .link ;
321:
322: \ line handling
323:
324: : char? ( -- c ) >in @ char swap >in ! ;
325:
326: : parse-tag ( addr u char -- )
327: >r r@ parse .type
328: r> parse 2swap tagged ;
329:
330: : .text ( -- ) >in @ >r char drop
331: source r@ /string >in @ r> - nip .type ;
332:
333: Create do-words $100 0 [DO] ' .text , [LOOP]
334:
335: :noname '( emit 1 >in +! ; '( cells do-words + !
336:
337: : bind-char ( xt -- ) char cells do-words + ! ;
338:
339: : char>tag ( -- ) char >r
340: :noname bl sword postpone SLiteral r@ postpone Literal
341: postpone parse-tag postpone ; r> cells do-words + ! ;
342:
343: : >tag '\ parse type '\ parse tag ;
344:
345: char>tag * b
346: char>tag _ em
347: char>tag # code
348: :noname '~ parse .type '~ parse .type ; '~ cells do-words + !
349:
350: ' >link bind-char [
351: ' >img bind-char {
352: ' >tag bind-char \
353:
354: : do-word ( char -- ) cells do-words + perform ;
355:
356: : word? ( -- addr u ) >in @ >r bl sword r> >in ! ;
357:
358: wordlist Constant autoreplacements
359:
360: :noname ( -- )
361: BEGIN char? do-word source nip >in @ = UNTIL ; is parse-line
362:
363: : parse-line+ ( -- )
364: BEGIN
365: word? autoreplacements search-wordlist
366: IF execute bl sword 2drop
367: source >in @ 1- /string drop c@ bl = >in +!
368: ELSE char? do-word THEN
369: source nip >in @ = UNTIL ;
370:
371: : parse-to ( char -- ) >r
372: BEGIN
373: word? autoreplacements search-wordlist
374: IF execute bl sword 2drop
375: source >in @ 1- /string drop c@ bl = >in +! bl true
376: ELSE char? dup r@ <> THEN WHILE
377: do-word source nip >in @ = UNTIL ELSE drop THEN
378: r> parse type ;
379:
380: \ autoreplace
381:
382: : autoreplace ( <[string|url]> -- )
383: get-current autoreplacements set-current
384: Create set-current
385: here 0 , '[ parse 2drop '] parse rot $!
386: DOES> $@ .link ;
387:
388: \ paragraph handling
389:
390: : parse-par ( -- )
391: BEGIN parse-line+ cr refill WHILE
392: source nip 0= UNTIL THEN ;
393:
394: : par ( addr u -- ) env?
395: 2dup tag parse-par /tag cr cr ;
396:
397: \ scan strings
398:
399: : get-rest ( addr -- ) 0 parse -trailing rot $! ;
400: Create $lf 1 c, #lf c,
401: : get-par ( addr -- ) >r s" " r@ $+!
402: BEGIN 0 parse 2dup s" ." str= 0= WHILE
403: r@ $@len IF $lf count r@ $+! THEN r@ $+!
404: refill 0= UNTIL ELSE 2drop THEN
405: rdrop ;
406:
407: \ toc handling
408:
409: Variable toc-link
410:
411: : >last ( addr link -- link' )
412: BEGIN dup @ WHILE @ REPEAT ! 0 ;
413:
414: Variable create-navs
415: Variable nav$
416: Variable nav-name
417: Variable nav-file
418: Create nav-buf 0 c,
419: : nav+ ( char -- ) nav-buf c! nav-buf 1 nav-file $+! ;
420:
421: : filenamize ( addr u -- )
422: bounds ?DO
423: I c@ dup 'A 'Z 1+ within IF bl + nav+
424: ELSE dup 'a 'z 1+ within IF nav+
425: ELSE dup '0 '9 1+ within IF nav+
426: ELSE dup bl = swap '- = or IF '- nav+
427: THEN THEN THEN THEN
428: LOOP ;
429: : >nav ( addr u -- addr' u' )
430: nav-name $! create-navs @ 0=
431: IF s" navigate/nav.scm" r/w create-file throw create-navs ! THEN
432: s' (script-fu-nav-file "' nav$ $! nav-name $@ nav$ $+!
433: s' " "./navigate/' nav$ $+! s" " nav-file $!
434: nav-name $@ filenamize
435: nav-file $@ nav$ $+! s' .jpg")' nav$ $+!
436: nav$ $@ create-navs @ write-line throw
437: s" [" nav$ $! nav-name $@ nav$ $+!
438: s" |-navigate/" nav$ $+! nav-file $@ nav$ $+! s" .jpg" nav$ $+!
439: nav$ $@ ;
440:
441: : toc, ( n -- ) , '| parse >nav here 0 , $! 0 parse here 0 , $! ;
442: : up-toc align here toc-link >last , 0 toc, ;
443: : top-toc align here toc-link >last , 1 toc, ;
444: : this-toc align here toc-link >last , 2 toc, ;
445: : sub-toc align here toc-link >last , 3 toc, ;
446: : new-toc toc-link off ;
447:
448: Variable toc-name
449: Variable toc-index
450: 6 Value /toc-line
451:
452: : .toc-entry ( toc flag -- )
453: swap cell+ dup @ swap cell+ dup cell+ $@ 2dup href= s" a" tag
454: '# scan 1 /string toc-name $@ compare >r
455: $@ .img swap
456: IF
457: case
458: 2 of s" ^]|-@/arrow_up.jpg" .img endof
459: 3 of
460: r@ 0= IF s" *]|-@/circle.jpg"
461: ELSE s" v]|-@/arrow_down.jpg" THEN .img endof
462: endcase
463: ELSE
464: case
465: 0 of s" ^]|-@/arrow_up.jpg" .img endof
466: 1 of s" >]|-@/arrow_right.jpg" .img endof
467: 2 of s" *]|-@/circle.jpg" .img endof
468: 3 of s" v]|-@/arrow_down.jpg" .img endof
469: endcase
470: THEN
471: s" a" /tag rdrop ." <!--" cr ." -->"
472: 1 toc-index +! toc-index @ /toc-line mod 0=
473: IF s" br" tag/ THEN ;
474:
475: : print-toc ( -- ) toc-index off cr s" menu" id= s" div" >env cr
476: 0 parse
477: dup 0= IF toc-name $! 0 ELSE
478: toc-name $! toc-name $@ id= s" " s" a" tagged 2
479: THEN >r
480: toc-link BEGIN @ dup WHILE
481: dup cell+ @ 3 = r@ 0= and IF rdrop 1 >r ( s" br" tag/ cr ) THEN
482: dup cell+ @ r@ >= IF dup r@ 2 = .toc-entry THEN
483: dup cell+ @ 2 = r@ 2 = and IF s" br" tag/ toc-index off THEN
484: REPEAT drop rdrop -env cr ;
485:
486: \ handle global tags
487:
488: : indent ( n -- )
489: indentlevel @ over
490: indentlevel !
491: 2dup < IF swap DO -env LOOP EXIT THEN
492: 2dup > IF DO s" div" >env LOOP EXIT THEN
493: 2dup = IF drop IF -env s" div" >env THEN THEN
494: ;
495: : +indent ( -- )
496: indentlevel @ IF -env indent= s" div" >env THEN
497: ;
498:
499: wordlist constant longtags
500:
501: Variable divs
502:
503: longtags set-current
504:
505: : --- 0 indent cr s" hr" tag/ cr ;
506: : * 1 indent s" h1" par +indent ;
507: : ** 1 indent s" h2" par +indent ;
508: : *** 2 indent s" h3" par +indent ;
509: : -- 0 indent cr print-toc ;
510: : && 0 parse id= ;
511: : - s" ul" env s" li" par ;
512: : + s" ol" env s" li" par ;
513: : ? s" dl" env s" dt" par ;
514: : : s" dl" env s" dd" par ;
515: : -<< s" ul" env env? s" li" >env ;
516: : +<< s" ol" env env? s" li" >env ;
517: : ?<< s" dl" env env? s" dt" >env ;
518: : :<< s" dl" env env? s" dd" >env ;
519: : p<< s" p" >env ;
520: : << +env ;
521: : <* s" center" class= ;
522: : <red s" #ff0000" s" color" opt s" font" >env ;
523: : red> -env ;
524: : >> -env ;
525: : *> ;
526: : :: interpret ;
527: : . end-sec on 0 indent ;
528: : :code s" pre" >env
529: BEGIN source >in @ /string type cr refill WHILE
530: source s" :endcode" str= UNTIL THEN
531: -env ;
532: : :code-file s" pre" >env
533: parse" slurp-file type -env ;
534: : \ postpone \ ;
535:
536: definitions
537:
538: : LT get-order longtags swap 1+ set-order
539: bl sword parser previous ; immediate
540:
541: \ Table
542:
543: : next-char ( -- char ) source drop >in @ + c@ ;
544: : next-table ( -- )
545: BEGIN
546: table-starts table# @ 2* + dup c@ dup
547: IF 1- over c! 1+ c@ 1+ ELSE swap 1+ c! 0 THEN
548: dup WHILE table# +! REPEAT drop
549: table-format $@ table# @ /string drop c@ taligned ! ;
550: : next>align ( -- )
551: next-char dup bl <> over '\ <> and
552: IF taligned ! 1 >in +! ELSE drop THEN ;
553:
554: : |tag ( addr u -- )
555: next-table
556: next-char '/ = IF 1 >in +!
557: next-char digit? IF
558: dup 1- table-starts table# @ 2* + c!
559: s" rowspan" opt# 1 >in +! THEN
560: next>align
561: THEN
562: next-char '\ = IF 1 >in +!
563: next-char digit? IF
564: dup 1- table-starts table# @ 2* + 1+ c!
565: dup 1- table# +!
566: s" colspan" opt# 1 >in +! THEN
567: next>align
568: THEN
569: taligned @ >talign >env
570: 1 table# +! ;
571: : |d table# @ 0> IF -env THEN s" td" |tag ;
572: : |h table# @ 0> IF -env THEN s" th" |tag ;
573: : |line s" tr" >env table# off ;
574: : line| 1 >in +! -env -env cr ;
575:
576: longtags set-current
577:
578: : <| ( -- ) table-starts &20 erase
579: s" table" class= s" div" >env
580: bl sword table-format $! bl sword
581: dup IF s" border" opt ELSE 2drop THEN
582: s" table" >env ;
583: : |> -env -env cr cr ;
584: : +| ( -- )
585: |line BEGIN |h '| parse-to next-char '+ = UNTIL line| ;
586: : -| ( -- )
587: |line BEGIN |d '| parse-to next-char '- = UNTIL line| ;
588: : =| ( -- )
589: |line |h '| parse-to
590: BEGIN |d '| parse-to next-char '= = UNTIL line| ;
591:
592: definitions
593:
594: \ parse a section
595:
596: : section-par ( -- ) >in off
597: bl sword longtags search-wordlist
598: IF execute
599: ELSE source nip IF >in off s" p" par THEN THEN ;
600: : parse-section ( -- ) end-sec off
601: BEGIN refill WHILE
602: section-par end-sec @ UNTIL THEN ;
603:
604: \ HTML head
605:
606: Variable css-file
607:
608: : .title ( addr u -- )
609: .' <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//en" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">' cr
610: s" html" >env s" head" >env cr
611: s" Content-Type" s" http-equiv" opt
612: s" text/xhtml; charset=iso-8859-1" s" content" opt
613: s" meta" tag/
614: css-file @ IF css-file $@len IF
615: s" StyleSheet" s" rel" opt
616: css-file $@ href=
617: s" text/css" s" type" opt s" link" tag/
618: THEN THEN
619: s" title" tagged cr
620: -env ;
621:
622: \ HTML trailer
623:
624: Variable public-key
625: Variable mail
626: Variable mail-name
627: Variable orig-date
628:
629: : .lastmod
630: ." Last modified: " time&date rot 0 u.r swap 1-
631: s" janfebmaraprmayjunjulaugsepoctnovdec" rot 3 * /string 3 min type
632: 0 u.r ;
633:
634: : .trailer
635: s" center" class= s" address" >env
636: orig-date @ IF ." Created " orig-date $@ type ." . " THEN
637: .lastmod
638: ." by "
639: s" Mail|@/mail.gif" .img mail $@ mailto: mail-name $@ s" a" tagged
640: public-key @ IF
641: public-key $@ href= s" a" tag
642: s" PGP key|@/gpg.asc.gif" .img s" a" /tag
643: THEN
644: -envs ;
645:
646: \ top word
647:
648: : maintainer ( -- )
649: '< sword -trailing mail-name $! '> sword mail $! ;
650: : pgp-key ( -- )
651: bl sword -trailing public-key $! ;
652: : created ( -- )
653: bl sword orig-date $! ;
654: : icons
655: bl sword icon-prefix $! ;
656: icons icons
657:
658: Variable style$
659: : style> style$ @ 0= IF s" " style$ $! THEN style$ $@ tag-option $! ;
660: : >style tag-option $@ style$ $! s" " tag-option $! ;
661:
662: : style style> opt >style ;
663: : background ( -- ) parse" s" background" style ;
664: : text ( -- ) parse" s" text" style ;
665: warnings @ warnings off
666: : link ( -- ) parse" s" link" style ;
667: warnings !
668: : vlink ( -- ) parse" s" vlink" style ;
669: : marginheight ( -- ) parse" s" marginheight" style ;
670: : css ( -- ) parse" css-file $! ;
671:
672: : wf ( -- )
673: outfile-id >r
674: bl sword r/w create-file throw to outfile-id
675: parse" .title
676: +env style> s" body" env env?
677: ['] parse-section catch .trailer
678: outfile-id close-file throw
679: r> to outfile-id
680: dup 0< IF throw ELSE drop THEN ;
681:
682: : eval-par ( addr u -- )
683: s" wf-temp.wf" r/w create-file throw >r
684: r@ write-file r> close-file throw
685: push-file s" wf-temp.wf" r/o open-file throw loadfile !
686: parse-par parse-section
687: loadfile @ close-file swap 2dup or
688: pop-file drop throw throw
689: s" wf-temp.wf" delete-file throw ;
690:
691: \ simple text data base
692:
693: Variable last-entry
694: Variable field#
695:
696: : table: ( xt n -- ) Create 0 , ['] type , , , 1 field# !
697: DOES> 2 cells + 2@ >in @ >r longtags set-current
698: Create definitions swap , r> >in !
699: here last-entry !
700: dup 0 DO 0 , LOOP
701: 1 DO s" " last-entry @ I cells + $! LOOP
702: last-entry @ get-rest
703: DOES> dup cell+ swap perform ;
704:
705: : field: Create field# @ , ['] type , 1 field# +!
706: DOES> @ cells last-entry @ + get-rest ;
707: : par: Create field# @ , ['] eval-par , 1 field# +!
708: DOES> @ cells last-entry @ + get-par ;
709:
710: : >field-rest >body @ cells postpone Literal postpone + ;
711: : >field ' >field-rest ; immediate
712:
713: : db-line ( -- )
714: BEGIN
715: source >in @ /string nip WHILE
716: '% parse postpone SLiteral postpone type
717: '% parse dup IF
718: '| $split 2swap
719: sfind 0= abort" Field not found"
720: dup postpone r@ >field-rest postpone $@
721: over IF drop evaluate ELSE
722: nip nip >body cell+ @ compile,
723: THEN
724: ELSE 2drop postpone cr THEN
725: REPEAT ;
726:
727: : db-par ( -- ) LT postpone p<< postpone >r
728: BEGIN db-line refill WHILE next-char '. = UNTIL 1 >in +! THEN
729: postpone rdrop LT postpone >> ; immediate
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>