1: \ miscelleneous words
2:
3: \ Copyright (C) 1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: require glocals.fs
22:
23: ' require alias needs ( ... "name" -- ... ) \ gforth
24: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
25: \ needs is an F-PC name. we will probably switch to 'needs' in the future
26:
27: \ a little more compiler security
28:
29: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
30: AUser CSP
31:
32: : !CSP ( -- )
33: sp@ csp ! ;
34:
35: : ?CSP ( -- )
36: sp@ csp @ <> -22 and throw ;
37:
38: \ DMIN and DMAX
39:
40: : dmin ( d1 d2 -- d ) \ double d-min
41: 2over 2over d> IF 2swap THEN 2drop ;
42:
43:
44: : dmax ( d1 d2 -- d ) \ double d-max
45: 2over 2over d< IF 2swap THEN 2drop ;
46:
47: \ shell commands
48:
49: 0 Value $? ( -- n ) \ gforth dollar-question
50: \G @code{Value} -- the exit status returned by the most recently executed
51: \G @code{system} command.
52:
53: : system ( c-addr u -- ) \ gforth
54: \G Pass the string specified by @var{c-addr u} to the host operating system
55: \G for execution in a sub-shell.
56: (system) throw TO $? ;
57:
58: : sh ( "..." -- ) \ gforth
59: \G Parse a string and use @code{system} to pass it to the host
60: \G operating system for execution in a sub-shell.
61: '# parse cr system ;
62:
63: \ stuff
64:
65: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
66: \G equivalent to @code{] literal}
67: ] postpone literal ;
68:
69: [ifundef] in-dictionary?
70: : in-dictionary? ( x -- f )
71: forthstart dictionary-end within ;
72: [endif]
73:
74: : in-return-stack? ( addr -- f )
75: rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
76:
77: \ const-does>
78:
79: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
80: \ compile u literals, starting with the bottommost one
81: ?dup-if
82: swap >r 1- compile-literals
83: r> POSTPONE literal
84: endif ;
85:
86: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
87: \ compile u fliterals, starting with the bottommost one
88: ?dup-if
89: { F: r } 1- compile-fliterals
90: r POSTPONE fliteral
91: endif ;
92:
93: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
94: \ define a colon definition "name" containing w*uw r*ur as
95: \ literals and a call to target.
96: { uw ur target }
97: header docol: cfa, \ start colon def without stack junk
98: ur compile-fliterals uw compile-literals
99: target compile, POSTPONE exit reveal ;
100:
101: : const-does> ( run-time: w*uw r*ur uw ur "name" -- ) \ gforth
102: \G Defines @var{name} and returns.
103: \G
104: \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
105: \G code following the @code{const-does>}.
106: here >r 0 POSTPONE literal
107: POSTPONE (const-does>)
108: POSTPONE ;
109: noname : POSTPONE rdrop
110: latestxt r> cell+ ! \ patch the literal
111: ; immediate
112:
113: \ !! rewrite slurp-file using slurp-fid
114: : slurp-file ( c-addr1 u1 -- c-addr2 u2 ) \ gforth
115: \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
116: r/o bin open-file throw >r
117: r@ file-size throw abort" file too large"
118: dup allocate throw swap
119: 2dup r@ read-file throw over <> abort" could not read whole file"
120: r> close-file throw ;
121:
122: : slurp-fid { fid -- addr u } \ gforth
123: \G @var{addr u} is the content of the file @var{fid}
124: 0 0 begin ( awhole uwhole )
125: dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
126: rot r@ fid read-file throw ( awhole uwhole uread R: unew )
127: r> 2dup =
128: while ( awhole uwhole uread unew )
129: 2drop
130: repeat
131: - + dup >r resize throw r> ;
132:
133: \ ]] ... [[
134:
135: : compile-literal ( n -- )
136: postpone literal ;
137:
138: : [[ ( -- )
139: \G switch from postpone state to compile state
140: \ this is only a marker; it is never really interpreted
141: compile-only-error ; immediate
142:
143: : postponer ( c-addr u -- )
144: 2dup find-name dup if ( c-addr u nt )
145: nip nip name>comp
146: 2dup [comp'] [[ d= if
147: 2drop ['] compiler is parser
148: else
149: postpone,
150: endif
151: else
152: drop
153: 2dup snumber? dup if
154: 0> IF
155: swap postpone literal postpone compile-literal
156: THEN
157: postpone Literal postpone compile-literal
158: 2drop
159: ELSE
160: drop no.extensions
161: THEN
162: then ;
163:
164: : ]] ( -- )
165: \ switch into postpone state
166: ['] postponer is parser state on ; immediate restrict
167:
168: \ f.rdp
169:
170: : push-right ( c-addr u1 u2 cfill -- )
171: \ move string at c-addr u1 right by u2 chars (without exceeding
172: \ the original bound); fill the gap with cfill
173: >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
174: dup 2swap /string cmove>
175: r> r> r> fill ;
176:
177: : f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
178: \ um1 is the mantissa length to try, um2 is the actual mantissa length
179: c-addr ur um1 /string '0 fill
180: rf c-addr um1 represent if { nexp fsign }
181: nd nexp + up >=
182: ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
183: \ fixed-point notation
184: c-addr ur beforep nexp - dup { befored } '0 push-right
185: c-addr beforep 1- befored min dup { beforez } 0 max bl fill
186: fsign if
187: '- c-addr beforez 1- 0 max + c!
188: endif
189: c-addr ur beforep /string 1 '. push-right
190: nexp nd +
191: else \ exponential notation
192: c-addr ur 1 /string 1 '. push-right
193: fsign if
194: c-addr ur 1 '- push-right
195: endif
196: nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
197: ur explen - 1- fsign + { mantlen }
198: mantlen 0< if \ exponent too large
199: drop c-addr ur '* fill
200: else
201: c-addr ur + 0 explen negate /string move
202: endif
203: #>> mantlen
204: endif
205: else \ inf or nan
206: if \ negative
207: c-addr ur 1 '- push-right
208: endif
209: drop ur
210: \ !! align in some way?
211: endif
212: 1 max ur min ;
213:
214: : f>buf-rdp ( rf c-addr +nr +nd +np -- ) \ gforth
215: \G Convert @i{rf} into a string at @i{c-addr nr}. The conversion
216: \G rules and the meanings of @i{nr nd np} are the same as for
217: \G @code{f.rdp}.
218: \ first, get the mantissa length, then convert for real. The
219: \ mantissa length is wrong in a few cases because of different
220: \ rounding; In most cases this does not matter, because the
221: \ mantissa is shorter than expected and the final digits are 0;
222: \ but in a few cases the mantissa gets longer. Then it is
223: \ conceivable that you will see a result that is rounded too much.
224: \ However, I have not been able to construct an example where this
225: \ leads to an unexpected result.
226: swap 0 max swap 0 max
227: fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
228:
229: : f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
230: \G Convert @i{rf} into a string at @i{c-addr nr}. The conversion
231: \G rules and the meanings of @i{nr +nd np} are the same as for
232: \G @code{f.rdp}. The result in in the pictured numeric output buffer
233: \G and will be destroyed by anything destroying that buffer.
234: rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
235: over holdbuf u< -&17 and throw
236: 2tuck 2>r f>buf-rdp 2r> ;
237:
238: : f.rdp ( rf +nr +nd +np -- ) \ gforth
239: \G Print float @i{rf} formatted. The total width of the output is
240: \G @i{nr}. For fixed-point notation, the number of digits after the
241: \G decimal point is @i{+nd} and the minimum number of significant
242: \G digits is @i{np}. @code{Set-precision} has no effect on
243: \G @code{f.rdp}. Fixed-point notation is used if the number of
244: \G siginicant digits would be at least @i{np} and if the number of
245: \G digits before the decimal point would fit. If fixed-point notation
246: \G is not used, exponential notation is used, and if that does not
247: \G fit, asterisks are printed. We recommend using @i{nr}>=7 to avoid
248: \G the risk of numbers not fitting at all. We recommend
249: \G @i{nr}>=@i{np}+5 to avoid cases where @code{f.rdp} switches to
250: \G exponential notation because fixed-point notation would have too
251: \G few significant digits, yet exponential notation offers fewer
252: \G significant digits. We recommend @i{nr}>=@i{nd}+2, if you want to
253: \G have fixed-point notation for some numbers. We recommend
254: \G @i{np}>@i{nr}, if you want to have exponential notation for all
255: \G numbers.
256: f>str-rdp type ;
257:
258: 0 [if]
259: : testx ( rf ur nd up -- )
260: '| emit f.rdp ;
261:
262: : test ( -- )
263: -0.123456789123456789e-20
264: 40 0 ?do
265: cr
266: fdup 7 3 1 testx
267: fdup 7 3 4 testx
268: fdup 7 3 0 testx
269: fdup 7 7 1 testx
270: fdup 7 5 1 testx
271: fdup 7 0 2 testx
272: fdup 5 2 1 testx
273: fdup 4 2 1 testx
274: fdup 18 8 5 testx
275: '| emit
276: 10e f*
277: loop ;
278: [then]
279:
280: : f.s ( -- ) \ gforth f-dot-s
281: \G Display the number of items on the floating-point stack,
282: \G followed by a list of the items; TOS is the right-most item.
283: ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0
284: ?DO dup i - 1- floats fp@ + f@ 16 5 11 f.rdp space LOOP drop ;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>