File:  [gforth] / gforth / prims2x.fs
Revision 1.92: download - view: text, annotated - select for diffs
Sun Mar 18 11:35:35 2001 UTC (23 years ago) by anton
Branches: MAIN
CVS tags: HEAD
cleaned up prims2x.fs, prepare for pulling stack definition out

    1: \ converts primitives to, e.g., C code 
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: \ This is not very nice (hard limits, no checking, assumes 1 chars = 1).
   23: \ And it grew even worse when it aged.
   24: 
   25: \ Optimizations:
   26: \ superfluous stores are removed. GCC removes the superfluous loads by itself
   27: \ TOS and FTOS can be kept in register( variable)s.
   28: \ 
   29: \ Problems:
   30: \ The TOS optimization is somewhat hairy. The problems by example:
   31: \ 1) dup ( w -- w w ): w=TOS; sp-=1; sp[1]=w; TOS=w;
   32: \    The store is not superfluous although the earlier opt. would think so
   33: \    Alternatively:    sp[0]=TOS; w=TOS; sp-=1; TOS=w;
   34: \ 2) ( -- .. ): sp[0] = TOS; ... /* This additional store is necessary */
   35: \ 3) ( .. -- ): ... TOS = sp[0]; /* as well as this load */
   36: \ 4) ( -- ): /* but here they are unnecessary */
   37: \ 5) Words that call NEXT themselves have to be done very carefully.
   38: \
   39: \ To do:
   40: \ add the store optimization for doubles
   41: \ regarding problem 1 above: It would be better (for over) to implement
   42: \ 	the alternative
   43: \ store optimization for combined instructions.
   44: 
   45: \ Design Uglyness:
   46: 
   47: \ - global state (values, variables) in connection with combined instructions.
   48: 
   49: \ - index computation is different for instruction-stream and the
   50: \ stacks; there are two mechanisms for dealing with that
   51: \ (stack-in-index-xt and a test for stack==instruction-stream); there
   52: \ should be only one.
   53: 
   54: warnings off
   55: 
   56: [IFUNDEF] vocabulary	\ we are executed just with kernel image
   57: 			\ load the rest that is needed
   58: 			\ (require fails because this file is needed from a
   59: 			\ different directory with the wordlibraries)
   60: include ./search.fs			
   61: include ./extend.fs
   62: include ./stuff.fs
   63: [THEN]
   64: 
   65: [IFUNDEF] environment?
   66: include ./environ.fs
   67: [THEN]
   68: 
   69: : struct% struct ; \ struct is redefined in gray
   70: 
   71: include ./gray.fs
   72: 
   73: 32 constant max-effect \ number of things on one side of a stack effect
   74: 4 constant max-stacks  \ the max. number of stacks (including inst-stream).
   75: 255 constant maxchar
   76: maxchar 1+ constant eof-char
   77: #tab constant tab-char
   78: #lf constant nl-char
   79: 
   80: variable rawinput \ pointer to next character to be scanned
   81: variable endrawinput \ pointer to the end of the input (the char after the last)
   82: variable cookedinput \ pointer to the next char to be parsed
   83: variable line \ line number of char pointed to by input
   84: variable line-start \ pointer to start of current line (for error messages)
   85: 0 line !
   86: 2variable filename \ filename of original input file
   87: 0 0 filename 2!
   88: 2variable f-comment
   89: 0 0 f-comment 2!
   90: variable skipsynclines \ are sync lines ("#line ...") invisible to the parser?
   91: skipsynclines on 
   92: 
   93: : th ( addr1 n -- addr2 )
   94:     cells + ;
   95: 
   96: : holds ( addr u -- )
   97:     \ like HOLD, but for a string
   98:     tuck + swap 0 +do
   99: 	1- dup c@ hold
  100:     loop
  101:     drop ;
  102: 
  103: : insert-wordlist { c-addr u wordlist xt -- }
  104:     \ adds name "addr u" to wordlist using defining word xt
  105:     \ xt may cause additional stack effects
  106:     get-current >r wordlist set-current
  107:     c-addr u nextname xt execute
  108:     r> set-current ;
  109: 
  110: : start ( -- addr )
  111:  cookedinput @ ;
  112: 
  113: : end ( addr -- addr u )
  114:  cookedinput @ over - ;
  115: 
  116: : print-error-line ( -- )
  117:     \ print the current line and position
  118:     line-start @ endrawinput @ over - 2dup nl-char scan drop nip ( start end )
  119:     over - type cr
  120:     line-start @ rawinput @ over - typewhite ." ^" cr ;
  121: 
  122: : ?print-error { f addr u -- }
  123:     f ?not? if
  124: 	outfile-id >r try
  125: 	    stderr to outfile-id
  126: 	    filename 2@ type ." :" line @ 0 .r ." : " addr u type cr
  127: 	    print-error-line
  128: 	    0
  129: 	recover endtry
  130: 	r> to outfile-id throw
  131: 	abort
  132:     endif ;
  133: 
  134: : quote ( -- )
  135:     [char] " emit ;
  136: 
  137: variable output          \ xt ( -- ) of output word for simple primitives
  138: variable output-combined \ xt ( -- ) of output word for combined primitives
  139: 
  140: struct%
  141:     cell%    field stack-number \ the number of this stack
  142:     cell% 2* field stack-pointer \ stackpointer name
  143:     cell%    field stack-type \ name for default type of stack items
  144:     cell%    field stack-in-index-xt \ ( in-size item -- in-index )
  145: end-struct stack%
  146: 
  147: struct%
  148:  cell% 2* field item-name   \ name, excluding stack prefixes
  149:  cell%    field item-stack  \ descriptor for the stack used, 0 is default
  150:  cell%    field item-type   \ descriptor for the item type
  151:  cell%    field item-offset \ offset in stack items, 0 for the deepest element
  152:  cell%	  field item-first  \ true if this is the first occurence of the item
  153: end-struct item%
  154: 
  155: struct%
  156:     cell% 2* field type-c-name
  157:     cell%    field type-stack \ default stack
  158:     cell%    field type-size  \ size of type in stack items
  159:     cell%    field type-fetch \ xt of fetch code generator ( item -- )
  160:     cell%    field type-store \ xt of store code generator ( item -- )
  161: end-struct type%
  162: 
  163: variable next-stack-number 0 next-stack-number !
  164: create stacks max-stacks cells allot \ array of stacks
  165: 
  166: : stack-in-index ( in-size item -- in-index )
  167:     item-offset @ - 1- ;
  168: 
  169: : inst-in-index ( in-size item -- in-index )
  170:     nip dup item-offset @ swap item-type @ type-size @ + 1- ;
  171: 
  172: : make-stack ( addr-ptr u1 type "stack-name" -- )
  173:     next-stack-number @ max-stacks < s" too many stacks" ?print-error
  174:     create stack% %allot >r
  175:     r@ stacks next-stack-number @ th !
  176:     next-stack-number @ r@ stack-number !
  177:     1 next-stack-number +!
  178:     r@ stack-type !
  179:     save-mem r@ stack-pointer 2! 
  180:     ['] stack-in-index r> stack-in-index-xt ! ;
  181: 
  182: : map-stacks { xt -- }
  183:     \ perform xt for all stacks except inst-stream
  184:     next-stack-number @ 1 +do
  185: 	stacks i th @ xt execute
  186:     loop ;
  187: 
  188: \ stack items
  189: 
  190: : init-item ( addr u addr1 -- )
  191:     \ initialize item at addr1 with name addr u
  192:     \ !! remove stack prefix
  193:     dup item% %size erase
  194:     item-name 2! ;
  195: 
  196: : map-items { addr end xt -- }
  197:     \ perform xt for all items in array addr...end
  198:     end addr ?do
  199: 	i xt execute
  200:     item% %size +loop ;
  201: 
  202: \ types
  203: 
  204: : print-type-prefix ( type -- )
  205:     body> >head name>string type ;
  206: 
  207: \ various variables for storing stuff of one primitive
  208: 
  209: struct%
  210:     cell% 2* field prim-name
  211:     cell% 2* field prim-wordset
  212:     cell% 2* field prim-c-name
  213:     cell% 2* field prim-doc
  214:     cell% 2* field prim-c-code
  215:     cell% 2* field prim-forth-code
  216:     cell% 2* field prim-stack-string
  217:     cell%    field prim-num            \ ordinal number
  218:     cell%    field prim-items-wordlist \ unique items
  219:     item% max-effect * field prim-effect-in
  220:     item% max-effect * field prim-effect-out
  221:     cell%    field prim-effect-in-end
  222:     cell%    field prim-effect-out-end
  223:     cell% max-stacks * field prim-stacks-in  \ number of in items per stack
  224:     cell% max-stacks * field prim-stacks-out \ number of out items per stack
  225: end-struct prim%
  226: 
  227: : make-prim ( -- prim )
  228:     prim% %alloc { p }
  229:     s" " p prim-doc 2! s" " p prim-forth-code 2! s" " p prim-wordset 2!
  230:     p ;
  231: 
  232: 0 value prim     \ in combined prims either combined or a part
  233: 0 value combined \ in combined prims the combined prim
  234: variable in-part \ true if processing a part
  235:  in-part off
  236: 
  237: 1000 constant max-combined
  238: create combined-prims max-combined cells allot
  239: variable num-combined
  240: 
  241: table constant combinations
  242:   \ the keys are the sequences of pointers to primitives
  243: 
  244: create current-depth max-stacks cells allot
  245: create max-depth     max-stacks cells allot
  246: create min-depth     max-stacks cells allot
  247: 
  248: wordlist constant primitives
  249: 
  250: : create-prim ( prim -- )
  251:     dup prim-name 2@ primitives ['] constant insert-wordlist ;
  252: 
  253: : stack-in ( stack -- addr )
  254:     \ address of number of stack items in effect in
  255:     stack-number @ cells prim prim-stacks-in + ;
  256: 
  257: : stack-out ( stack -- addr )
  258:     \ address of number of stack items in effect out
  259:     stack-number @ cells prim prim-stacks-out + ;
  260: 
  261: \ global vars
  262: variable c-line
  263: 2variable c-filename
  264: variable name-line
  265: 2variable name-filename
  266: 2variable last-name-filename
  267: Variable function-number 0 function-number !
  268: 
  269: \ a few more set ops
  270: 
  271: : bit-equivalent ( w1 w2 -- w3 )
  272:  xor invert ;
  273: 
  274: : complement ( set1 -- set2 )
  275:  empty ['] bit-equivalent binary-set-operation ;
  276: 
  277: \ stack access stuff
  278: 
  279: : normal-stack-access ( n stack -- )
  280:     stack-pointer 2@ type
  281:     dup
  282:     if
  283: 	." [" 0 .r ." ]"
  284:     else
  285: 	drop ." TOS"
  286:     endif ;
  287: 
  288: \ forward declaration for inst-stream (breaks cycle in definitions)
  289: defer inst-stream-f ( -- stack )
  290: 
  291: : part-stack-access { n stack -- }
  292:     \ print _<stack><x>, x=inst-stream? n : maxdepth-currentdepth-n-1
  293:     ." _" stack stack-pointer 2@ type
  294:     stack stack-number @ { stack# }
  295:     current-depth stack# th @ n + { access-depth }
  296:     stack inst-stream-f = if
  297: 	access-depth
  298:     else
  299: 	combined prim-stacks-in stack# th @
  300: 	assert( dup max-depth stack# th @ = )
  301: 	access-depth - 1-
  302:     endif
  303:     0 .r ;
  304: 
  305: : stack-access ( n stack -- )
  306:     \ print a stack access at index n of stack
  307:     in-part @ if
  308: 	part-stack-access
  309:     else
  310: 	normal-stack-access
  311:     endif ;
  312: 
  313: : item-in-index { item -- n }
  314:     \ n is the index of item (in the in-effect)
  315:     item item-stack @ dup >r stack-in @ ( in-size r:stack )
  316:     item r> stack-in-index-xt @ execute ;
  317: 
  318: : item-stack-type-name ( item -- addr u )
  319:     item-stack @ stack-type @ type-c-name 2@ ;
  320: 
  321: : fetch-single ( item -- )
  322:  \ fetch a single stack item from its stack
  323:  >r
  324:  r@ item-name 2@ type
  325:  ."  = vm_" r@ item-stack-type-name type
  326:  ." 2" r@ item-type @ print-type-prefix ." ("
  327:  r@ item-in-index r@ item-stack @ stack-access
  328:  ." );" cr
  329:  rdrop ; 
  330: 
  331: : fetch-double ( item -- )
  332:  \ fetch a double stack item from its stack
  333:  >r
  334:  ." vm_two"
  335:  r@ item-stack-type-name type ." 2"
  336:  r@ item-type @ print-type-prefix ." ("
  337:  r@ item-name 2@ type ." , "
  338:  r@ item-in-index r@ item-stack @ 2dup ." (Cell)" stack-access
  339:  ." , "                      -1 under+ ." (Cell)" stack-access
  340:  ." );" cr
  341:  rdrop ;
  342: 
  343: : same-as-in? ( item -- f )
  344:  \ f is true iff the offset and stack of item is the same as on input
  345:  >r
  346:  r@ item-first @ if
  347:      rdrop false exit
  348:  endif
  349:  r@ item-name 2@ prim prim-items-wordlist @ search-wordlist 0= abort" bug"
  350:  execute @
  351:  dup r@ =
  352:  if \ item first appeared in output
  353:    drop false
  354:  else
  355:    dup  item-stack  @ r@ item-stack  @ = 
  356:    swap item-offset @ r@ item-offset @ = and
  357:  endif
  358:  rdrop ;
  359: 
  360: : item-out-index ( item -- n )
  361:     \ n is the index of item (in the in-effect)
  362:     >r r@ item-stack @ stack-out @ r> item-offset @ - 1- ;
  363: 
  364: : really-store-single ( item -- )
  365:  >r
  366:  r@ item-out-index r@ item-stack @ stack-access ."  = vm_"
  367:  r@ item-type @ print-type-prefix ." 2"
  368:  r@ item-stack-type-name type ." ("
  369:  r@ item-name 2@ type ." );"
  370:  rdrop ;
  371: 
  372: : store-single ( item -- )
  373:  >r
  374:  r@ same-as-in?
  375:  if
  376:    r@ item-in-index 0= r@ item-out-index 0= xor
  377:    if
  378:        ." IF_" r@ item-stack @ stack-pointer 2@ type
  379:        ." TOS(" r@ really-store-single ." );" cr
  380:    endif
  381:  else
  382:    r@ really-store-single cr
  383:  endif
  384:  rdrop ;
  385: 
  386: : store-double ( item -- )
  387: \ !! store optimization is not performed, because it is not yet needed
  388:  >r
  389:  ." vm_"
  390:  r@ item-type @ print-type-prefix ." 2two"
  391:  r@ item-stack-type-name type ." ("
  392:  r@ item-name 2@ type ." , "
  393:  r@ item-out-index r@ item-stack @ 2dup stack-access
  394:  ." , "                       -1 under+ stack-access
  395:  ." );" cr
  396:  rdrop ;
  397: 
  398: : single ( -- xt1 xt2 n )
  399:     ['] fetch-single ['] store-single 1 ;
  400: 
  401: : double ( -- xt1 xt2 n )
  402:     ['] fetch-double ['] store-double 2 ;
  403: 
  404: : s, ( addr u -- )
  405: \ allocate a string
  406:  here swap dup allot move ;
  407: 
  408: wordlist constant prefixes
  409: 
  410: : declare ( addr "name" -- )
  411: \ remember that there is a stack item at addr called name
  412:  create , ;
  413: 
  414: : !default ( w addr -- )
  415:     dup @ if
  416: 	2drop \ leave nonzero alone
  417:     else
  418: 	!
  419:     endif ;
  420: 
  421: : create-type { addr u xt1 xt2 n stack -- } ( "prefix" -- )
  422:     \ describes a type
  423:     \ addr u specifies the C type name
  424:     \ stack effect entries of the type start with prefix
  425:     create type% %allot >r
  426:     addr u save-mem r@ type-c-name 2!
  427:     xt1   r@ type-fetch !
  428:     xt2   r@ type-store !
  429:     n     r@ type-size !
  430:     stack r@ type-stack !
  431:     rdrop ;
  432: 
  433: : type-prefix ( xt1 xt2 n stack "prefix" -- )
  434:     create-type
  435: does> ( item -- )
  436:     \ initialize item
  437:     { item typ }
  438:     typ item item-type !
  439:     typ type-stack @ item item-stack !default
  440:     item item-name 2@ prim prim-items-wordlist @ search-wordlist 0= if
  441: 	item item-name 2@ nextname item declare
  442: 	item item-first on
  443: 	\ typ type-c-name 2@ type space type  ." ;" cr
  444:     else
  445: 	drop
  446: 	item item-first off
  447:     endif ;
  448: 
  449: : execute-prefix ( item addr1 u1 -- )
  450:     \ execute the word ( item -- ) associated with the longest prefix
  451:     \ of addr1 u1
  452:     0 swap ?do
  453: 	dup i prefixes search-wordlist
  454: 	if \ ok, we have the type ( item addr1 xt )
  455: 	    nip execute
  456: 	    UNLOOP EXIT
  457: 	endif
  458: 	-1 s+loop
  459:     \ we did not find a type, abort
  460:     false s" unknown prefix" ?print-error ;
  461: 
  462: : declaration ( item -- )
  463:     dup item-name 2@ execute-prefix ;
  464: 
  465: : declaration-list ( addr1 addr2 -- )
  466:     ['] declaration map-items ;
  467: 
  468: : declarations ( -- )
  469:  wordlist dup prim prim-items-wordlist ! set-current
  470:  prim prim-effect-in prim prim-effect-in-end @ declaration-list
  471:  prim prim-effect-out prim prim-effect-out-end @ declaration-list ;
  472: 
  473: : print-declaration { item -- }
  474:     item item-first @ if
  475: 	item item-type @ type-c-name 2@ type space
  476: 	item item-name 2@ type ." ;" cr
  477:     endif ;
  478: 
  479: : print-declarations ( -- )
  480:     prim prim-effect-in  prim prim-effect-in-end  @ ['] print-declaration map-items
  481:     prim prim-effect-out prim prim-effect-out-end @ ['] print-declaration map-items ;
  482:     
  483: : stack-prefix ( stack "prefix" -- )
  484:     name tuck nextname create ( stack length ) 2,
  485: does> ( item -- )
  486:     2@ { item stack prefix-length }
  487:     item item-name 2@ prefix-length /string item item-name 2!
  488:     stack item item-stack !
  489:     item declaration ;
  490: 
  491: \ types pointed to by stacks for use in combined prims
  492: \ !! output-c-combined shouldn't use these names!
  493: : stack-type-name ( addr u "name" -- )
  494:     single 0 create-type ;
  495: 
  496: s" Cell"  stack-type-name w
  497: s" Float" stack-type-name r
  498: 
  499: s" IP" save-mem w make-stack inst-stream
  500: ' inst-in-index inst-stream stack-in-index-xt !
  501: ' inst-stream <is> inst-stream-f
  502: 
  503: s" sp" save-mem w make-stack data-stack 
  504: s" fp" save-mem r make-stack fp-stack
  505: s" rp" save-mem w make-stack return-stack
  506: \ !! initialize stack-in and stack-out
  507: 
  508: \ offset computation
  509: \ the leftmost (i.e. deepest) item has offset 0
  510: \ the rightmost item has the highest offset
  511: 
  512: : compute-offset { item xt -- }
  513:     \ xt specifies in/out; update stack-in/out and set item-offset
  514:     item item-type @ type-size @
  515:     item item-stack @ xt execute dup @ >r +!
  516:     r> item item-offset ! ;
  517: 
  518: : compute-offset-in ( addr1 addr2 -- )
  519:     ['] stack-in compute-offset ;
  520: 
  521: : compute-offset-out ( addr1 addr2 -- )
  522:     ['] stack-out compute-offset ;
  523: 
  524: : clear-stack { -- }
  525:     dup stack-in off stack-out off ;
  526: 
  527: : compute-offsets ( -- )
  528:     ['] clear-stack map-stacks
  529:     inst-stream clear-stack
  530:     prim prim-effect-in  prim prim-effect-in-end  @ ['] compute-offset-in  map-items
  531:     prim prim-effect-out prim prim-effect-out-end @ ['] compute-offset-out map-items
  532:     inst-stream stack-out @ 0= s" # can only be on the input side" ?print-error ;
  533: 
  534: : process-simple ( -- )
  535:     prim prim { W^ key } key cell
  536:     combinations ['] constant insert-wordlist
  537:     declarations compute-offsets
  538:     output @ execute ;
  539: 
  540: : flush-a-tos { stack -- }
  541:     stack stack-out @ 0<> stack stack-in @ 0= and
  542:     if
  543: 	." IF_" stack stack-pointer 2@ 2dup type ." TOS("
  544: 	2dup type ." [0] = " type ." TOS);" cr
  545:     endif ;
  546: 
  547: : flush-tos ( -- )
  548:     ['] flush-a-tos map-stacks ;
  549: 
  550: : fill-a-tos { stack -- }
  551:     stack stack-out @ 0= stack stack-in @ 0<> and
  552:     if
  553: 	." IF_" stack stack-pointer 2@ 2dup type ." TOS("
  554: 	2dup type ." TOS = " type ." [0]);" cr
  555:     endif ;
  556: 
  557: : fill-tos ( -- )
  558:     \ !! inst-stream for prefetching?
  559:     ['] fill-a-tos map-stacks ;
  560: 
  561: : fetch ( addr -- )
  562:     dup item-type @ type-fetch @ execute ;
  563: 
  564: : fetches ( -- )
  565:     prim prim-effect-in prim prim-effect-in-end @ ['] fetch map-items ;
  566: 
  567: : stack-pointer-update { stack -- }
  568:     \ stack grow downwards
  569:     stack stack-in @ stack stack-out @ -
  570:     ?dup-if \ this check is not necessary, gcc would do this for us
  571: 	stack stack-pointer 2@ type ."  += " 0 .r ." ;" cr
  572:     endif ;
  573: 
  574: : inst-pointer-update ( -- )
  575:     inst-stream stack-in @ ?dup-if
  576: 	." INC_IP(" 0 .r ." );" cr
  577:     endif ;
  578: 
  579: : stack-pointer-updates ( -- )
  580:     inst-pointer-update
  581:     ['] stack-pointer-update map-stacks ;
  582: 
  583: : store ( item -- )
  584: \ f is true if the item should be stored
  585: \ f is false if the store is probably not necessary
  586:  dup item-type @ type-store @ execute ;
  587: 
  588: : stores ( -- )
  589:     prim prim-effect-out prim prim-effect-out-end @ ['] store map-items ;
  590: 
  591: : print-debug-arg { item -- }
  592:     ." fputs(" quote space item item-name 2@ type ." =" quote ." , vm_out); "
  593:     ." printarg_" item item-type @ print-type-prefix
  594:     ." (" item item-name 2@ type ." );" cr ;
  595:     
  596: : print-debug-args ( -- )
  597:     ." #ifdef VM_DEBUG" cr
  598:     ." if (vm_debug) {" cr
  599:     prim prim-effect-in prim prim-effect-in-end @ ['] print-debug-arg map-items
  600: \    ." fputc('\n', vm_out);" cr
  601:     ." }" cr
  602:     ." #endif" cr ;
  603: 
  604: : print-debug-result { item -- }
  605:     item item-first @ if
  606: 	item print-debug-arg
  607:     endif ;
  608: 
  609: : print-debug-results ( -- )
  610:     cr
  611:     ." #ifdef VM_DEBUG" cr
  612:     ." if (vm_debug) {" cr
  613:     ." fputs(" quote ."  -- " quote ." , vm_out); "
  614:     prim prim-effect-out prim prim-effect-out-end @ ['] print-debug-result map-items
  615:     ." fputc('\n', vm_out);" cr
  616:     ." }" cr
  617:     ." #endif" cr ;
  618: 
  619: : output-super-end ( -- )
  620:     prim prim-c-code 2@ s" SET_IP" search if
  621: 	." SUPER_END;" cr
  622:     endif
  623:     2drop ;
  624: 
  625: : output-c-tail ( -- )
  626:     \ the final part of the generated C code
  627:     output-super-end
  628:     print-debug-results
  629:     ." NEXT_P1;" cr
  630:     stores
  631:     fill-tos
  632:     ." NEXT_P2;" ;
  633: 
  634: : type-c-code ( c-addr u xt -- )
  635:     \ like TYPE, but replaces "TAIL;" with tail code produced by xt
  636:     { xt }
  637:     begin ( c-addr1 u1 )
  638: 	2dup s" TAIL;" search
  639:     while ( c-addr1 u1 c-addr3 u3 )
  640: 	2dup 2>r drop nip over - type
  641: 	xt execute
  642: 	2r> 5 /string
  643: 	\ !! resync #line missing
  644:     repeat
  645:     2drop type ;
  646: 
  647: : print-entry ( -- )
  648:     ." I_" prim prim-c-name 2@ type ." :" ;
  649:     
  650: : output-c ( -- ) 
  651:  print-entry ."  /* " prim prim-name 2@ type ."  ( " prim prim-stack-string 2@ type ." ) */" cr
  652:  ." /* " prim prim-doc 2@ type ."  */" cr
  653:  ." NAME(" quote prim prim-name 2@ type quote ." )" cr \ debugging
  654:  ." {" cr
  655:  ." DEF_CA" cr
  656:  print-declarations
  657:  ." NEXT_P0;" cr
  658:  flush-tos
  659:  fetches
  660:  print-debug-args
  661:  stack-pointer-updates
  662:  ." {" cr
  663:  ." #line " c-line @ . quote c-filename 2@ type quote cr
  664:  prim prim-c-code 2@ ['] output-c-tail type-c-code
  665:  ." }" cr
  666:  output-c-tail
  667:  ." }" cr
  668:  cr
  669: ;
  670: 
  671: : disasm-arg { item -- }
  672:     item item-stack @ inst-stream = if
  673: 	."   fputc(' ', vm_out); "
  674: 	." printarg_" item item-type @ print-type-prefix
  675: 	." ((" item item-type @ type-c-name 2@ type ." )"
  676: 	." ip[" item item-offset @ 1+ 0 .r ." ]);" cr
  677:     endif ;
  678: 
  679: : disasm-args ( -- )
  680:     prim prim-effect-in prim prim-effect-in-end @ ['] disasm-arg map-items ;
  681: 
  682: : output-disasm ( -- )
  683:     \ generate code for disassembling VM instructions
  684:     ." if (ip[0] == prim[" function-number @ 0 .r ." ]) {" cr
  685:     ."   fputs(" quote prim prim-name 2@ type quote ." , vm_out);" cr
  686:     disasm-args
  687:     ."   ip += " inst-stream stack-in @ 1+ 0 .r ." ;" cr
  688:     ."   goto _endif_;" cr
  689:     ." }" cr ;
  690: 
  691: : output-profile ( -- )
  692:     \ generate code for postprocessing the VM block profile stuff
  693:     ." if (VM_IS_INST(*ip, " function-number @ 0 .r ." )) {" cr
  694:     ."   add_inst(b, " quote  prim prim-name 2@ type quote ." );" cr
  695:     ."   ip += " inst-stream stack-in @ 1+ 0 .r ." ;" cr
  696:     prim prim-c-code 2@  s" SET_IP"    search nip nip
  697:     prim prim-c-code 2@  s" SUPER_END" search nip nip or if
  698: 	."   return;" cr
  699:     else
  700: 	."   goto _endif_;" cr
  701:     endif
  702:     ." }" cr ;
  703: 
  704: : gen-arg-parm { item -- }
  705:     item item-stack @ inst-stream = if
  706: 	." , " item item-type @ type-c-name 2@ type space
  707: 	item item-name 2@ type
  708:     endif ;
  709: 
  710: : gen-args-parm ( -- )
  711:     prim prim-effect-in prim prim-effect-in-end @ ['] gen-arg-parm map-items ;
  712: 
  713: : gen-arg-gen { item -- }
  714:     item item-stack @ inst-stream = if
  715: 	."   genarg_" item item-type @ print-type-prefix
  716:         ." (ctp, " item item-name 2@ type ." );" cr
  717:     endif ;
  718: 
  719: : gen-args-gen ( -- )
  720:     prim prim-effect-in prim prim-effect-in-end @ ['] gen-arg-gen map-items ;
  721: 
  722: : output-gen ( -- )
  723:     \ generate C code for generating VM instructions
  724:     ." void gen_" prim prim-c-name 2@ type ." (Inst **ctp" gen-args-parm ." )" cr
  725:     ." {" cr
  726:     ."   gen_inst(ctp, vm_prim[" function-number @ 0 .r ." ]);" cr
  727:     gen-args-gen
  728:     ." }" cr ;
  729: 
  730: : stack-used? { stack -- f }
  731:     stack stack-in @ stack stack-out @ or 0<> ;
  732: 
  733: : output-funclabel ( -- )
  734:   ." &I_" prim prim-c-name 2@ type ." ," cr ;
  735: 
  736: : output-forthname ( -- )
  737:   '" emit prim prim-name 2@ type '" emit ." ," cr ;
  738: 
  739: \  : output-c-func ( -- )
  740: \  \ used for word libraries
  741: \      ." Cell * I_" prim prim-c-name 2@ type ." (Cell *SP, Cell **FP)      /* " prim prim-name 2@ type
  742: \      ."  ( " prim prim-stack-string 2@ type ."  ) */" cr
  743: \      ." /* " prim prim-doc 2@ type ."  */" cr
  744: \      ." NAME(" quote prim prim-name 2@ type quote ." )" cr
  745: \      \ debugging
  746: \      ." {" cr
  747: \      print-declarations
  748: \      \ !! don't know what to do about that
  749: \      inst-stream  stack-used? IF ." Cell *ip=IP;" cr THEN
  750: \      data-stack   stack-used? IF ." Cell *sp=SP;" cr THEN
  751: \      fp-stack     stack-used? IF ." Cell *fp=*FP;" cr THEN
  752: \      return-stack stack-used? IF ." Cell *rp=*RP;" cr THEN
  753: \      flush-tos
  754: \      fetches
  755: \      stack-pointer-updates
  756: \      fp-stack   stack-used? IF ." *FP=fp;" cr THEN
  757: \      ." {" cr
  758: \      ." #line " c-line @ . quote c-filename 2@ type quote cr
  759: \      prim prim-c-code 2@ type
  760: \      ." }" cr
  761: \      stores
  762: \      fill-tos
  763: \      ." return (sp);" cr
  764: \      ." }" cr
  765: \      cr ;
  766: 
  767: : output-label ( -- )  
  768:     ." (Label)&&I_" prim prim-c-name 2@ type ." ," cr ;
  769: 
  770: : output-alias ( -- ) 
  771:     ( primitive-number @ . ." alias " ) ." Primitive " prim prim-name 2@ type cr ;
  772: 
  773: : output-forth ( -- )  
  774:     prim prim-forth-code @ 0=
  775:     IF    	\ output-alias
  776: 	\ this is bad for ec: an alias is compiled if tho word does not exist!
  777: 	\ JAW
  778:     ELSE  ." : " prim prim-name 2@ type ."   ( "
  779: 	prim prim-stack-string 2@ type ." )" cr
  780: 	prim prim-forth-code 2@ type cr
  781:     THEN ;
  782: 
  783: : output-tag-file ( -- )
  784:     name-filename 2@ last-name-filename 2@ compare if
  785: 	name-filename 2@ last-name-filename 2!
  786: 	#ff emit cr
  787: 	name-filename 2@ type
  788: 	." ,0" cr
  789:     endif ;
  790: 
  791: : output-tag ( -- )
  792:     output-tag-file
  793:     prim prim-name 2@ 1+ type
  794:     127 emit
  795:     space prim prim-name 2@ type space
  796:     1 emit
  797:     name-line @ 0 .r
  798:     ." ,0" cr ;
  799: 
  800: [IFDEF] documentation
  801: : register-doc ( -- )
  802:     prim prim-name 2@ documentation ['] create insert-wordlist
  803:     prim prim-name 2@ 2,
  804:     prim prim-stack-string 2@ condition-stack-effect 2,
  805:     prim prim-wordset 2@ 2,
  806:     prim prim-c-name 2@ condition-pronounciation 2,
  807:     prim prim-doc 2@ 2, ;
  808: [THEN]
  809: 
  810: 
  811: \ combining instructions
  812: 
  813: \ The input should look like this:
  814: 
  815: \ lit_+ = lit +
  816: 
  817: \ The output should look like this:
  818: 
  819: \  I_lit_+:
  820: \  {
  821: \  DEF_CA
  822: \  Cell _x_ip0;
  823: \  Cell _x_sp0;
  824: \  Cell _x_sp1;
  825: \  NEXT_P0;
  826: \  _x_ip0 = (Cell) IPTOS;
  827: \  _x_sp0 = (Cell) spTOS;
  828: \  INC_IP(1);
  829: \  /* sp += 0; */
  830: \  /* lit ( #w -- w ) */
  831: \  /*  */
  832: \  NAME("lit")
  833: \  {
  834: \  Cell w;
  835: \  w = (Cell) _x_ip0;
  836: \  #ifdef VM_DEBUG
  837: \  if (vm_debug) {
  838: \  fputs(" w=", vm_out); printarg_w (w);
  839: \  fputc('\n', vm_out);
  840: \  }
  841: \  #endif
  842: \  {
  843: \  #line 136 "./prim"
  844: \  }
  845: \  _x_sp1 = (Cell)w;
  846: \  }
  847: \  I_plus:	/* + ( n1 n2 -- n ) */
  848: \  /*  */
  849: \  NAME("+")
  850: \  {
  851: \  DEF_CA
  852: \  Cell n1;
  853: \  Cell n2;
  854: \  Cell n;
  855: \  NEXT_P0;
  856: \  n1 = (Cell) _x_sp0;
  857: \  n2 = (Cell) _x_sp1;
  858: \  #ifdef VM_DEBUG
  859: \  if (vm_debug) {
  860: \  fputs(" n1=", vm_out); printarg_n (n1);
  861: \  fputs(" n2=", vm_out); printarg_n (n2);
  862: \  fputc('\n', vm_out);
  863: \  }
  864: \  #endif
  865: \  {
  866: \  #line 516 "./prim"
  867: \  n = n1+n2;
  868: \  }
  869: \  NEXT_P1;
  870: \  _x_sp0 = (Cell)n;
  871: \  NEXT_P2;
  872: \  }
  873: \  NEXT_P1;
  874: \  spTOS = (Cell)_x_sp0;
  875: \  NEXT_P2;
  876: 
  877: : init-combined ( -- )
  878:     prim to combined
  879:     0 num-combined !
  880:     current-depth max-stacks cells erase
  881:     max-depth     max-stacks cells erase
  882:     min-depth     max-stacks cells erase
  883:     prim prim-effect-in  prim prim-effect-in-end  !
  884:     prim prim-effect-out prim prim-effect-out-end ! ;
  885: 
  886: : max! ( n addr -- )
  887:     tuck @ max swap ! ;
  888: 
  889: : min! ( n addr -- )
  890:     tuck @ min swap ! ;
  891: 
  892: : add-depths { p -- }
  893:     \ combine stack effect of p with *-depths
  894:     max-stacks 0 ?do
  895: 	current-depth i th @
  896: 	p prim-stacks-in  i th @ +
  897: 	dup max-depth i th max!
  898: 	p prim-stacks-out i th @ -
  899: 	dup min-depth i th min!
  900: 	current-depth i th !
  901:     loop ;
  902: 
  903: : add-prim ( addr u -- )
  904:     \ add primitive given by "addr u" to combined-prims
  905:     primitives search-wordlist s" unknown primitive" ?print-error
  906:     execute { p }
  907:     p combined-prims num-combined @ th !
  908:     1 num-combined +!
  909:     p add-depths ;
  910: 
  911: : compute-effects { q -- }
  912:     \ compute the stack effects of q from the depths
  913:     max-stacks 0 ?do
  914: 	max-depth i th @ dup
  915: 	q prim-stacks-in i th !
  916: 	current-depth i th @ -
  917: 	q prim-stacks-out i th !
  918:     loop ;
  919: 
  920: : make-effect-items { stack# items effect-endp -- }
  921:     \ effect-endp points to a pointer to the end of the current item-array
  922:     \ and has to be updated
  923:     stacks stack# th @ { stack }
  924:     items 0 +do
  925: 	effect-endp @ { item }
  926: 	i 0 <# #s stack stack-pointer 2@ holds [char] _ hold #> save-mem
  927: 	item item-name 2!
  928: 	stack item item-stack !
  929: 	stack stack-type @ item item-type !
  930: 	i item item-offset !
  931: 	item item-first on
  932: 	item% %size effect-endp +!
  933:     loop ;
  934: 
  935: : init-effects { q -- }
  936:     \ initialize effects field for FETCHES and STORES
  937:     max-stacks 0 ?do
  938: 	i q prim-stacks-in  i th @ q prim-effect-in-end  make-effect-items
  939: 	i q prim-stacks-out i th @ q prim-effect-out-end make-effect-items
  940:     loop ;
  941: 
  942: : process-combined ( -- )
  943:     combined combined-prims num-combined @ cells
  944:     combinations ['] constant insert-wordlist
  945:     combined-prims num-combined @ 1- th ( last-part )
  946:     @ prim-c-code 2@ prim prim-c-code 2! \ used by output-super-end
  947:     prim compute-effects
  948:     prim init-effects
  949:     output-combined perform ;
  950: 
  951: \ C output
  952: 
  953: : print-item { n stack -- }
  954:     \ print nth stack item name
  955:     stack stack-type @ type-c-name 2@ type space
  956:     ." _" stack stack-pointer 2@ type n 0 .r ;
  957: 
  958: : print-declarations-combined ( -- )
  959:     max-stacks 0 ?do
  960: 	max-depth i th @ min-depth i th @ - 0 +do
  961: 	    i stacks j th @ print-item ." ;" cr
  962: 	loop
  963:     loop ;
  964: 
  965: : part-fetches ( -- )
  966:     fetches ;
  967: 
  968: : part-output-c-tail ( -- )
  969:     print-debug-results
  970:     stores ;
  971: 
  972: : output-combined-tail ( -- )
  973:     part-output-c-tail
  974:     prim >r combined to prim
  975:     in-part @ >r in-part off
  976:     output-c-tail
  977:     r> in-part ! r> to prim ;
  978: 
  979: : output-part ( p -- )
  980:     to prim
  981:     ." /* " prim prim-name 2@ type ."  ( " prim prim-stack-string 2@ type ." ) */" cr
  982:     ." NAME(" quote prim prim-name 2@ type quote ." )" cr \ debugging
  983:     ." {" cr
  984:     print-declarations
  985:     part-fetches
  986:     print-debug-args
  987:     prim add-depths \ !! right place?
  988:     ." {" cr
  989:     ." #line " c-line @ . quote c-filename 2@ type quote cr
  990:     prim prim-c-code 2@ ['] output-combined-tail type-c-code
  991:     ." }" cr
  992:     part-output-c-tail
  993:     ." }" cr ;
  994: 
  995: : output-parts ( -- )
  996:     prim >r in-part on
  997:     current-depth max-stacks cells erase
  998:     num-combined @ 0 +do
  999: 	combined-prims i th @ output-part
 1000:     loop
 1001:     in-part off
 1002:     r> to prim ;
 1003: 
 1004: : output-c-combined ( -- )
 1005:     print-entry cr
 1006:     \ debugging messages just in parts
 1007:     ." {" cr
 1008:     ." DEF_CA" cr
 1009:     print-declarations-combined
 1010:     ." NEXT_P0;" cr
 1011:     flush-tos
 1012:     fetches
 1013:     \ print-debug-args
 1014:     stack-pointer-updates
 1015:     output-parts
 1016:     output-c-tail
 1017:     ." }" cr
 1018:     cr ;
 1019: 
 1020: : output-forth-combined ( -- )
 1021: ;
 1022: 
 1023: 
 1024: \ peephole optimization rules
 1025: 
 1026: \ in order for this to work as intended, shorter combinations for each
 1027: \ length must be present, and the longer combinations must follow
 1028: \ shorter ones (this restriction may go away in the future).
 1029:   
 1030: : output-peephole ( -- )
 1031:     combined-prims num-combined @ 1- cells combinations search-wordlist
 1032:     s" the prefix for this combination must be defined earlier" ?print-error
 1033:     ." {"
 1034:     execute prim-num @ 5 .r ." ,"
 1035:     combined-prims num-combined @ 1- th @ prim-num @ 5 .r ." ,"
 1036:     combined prim-num @ 5 .r ." }, /* "
 1037:     combined prim-c-name 2@ type ."  */"
 1038:     cr ;
 1039: 
 1040: : output-forth-peephole ( -- )
 1041:     combined-prims num-combined @ 1- cells combinations search-wordlist
 1042:     s" the prefix for this combination must be defined earlier" ?print-error
 1043:     execute prim-num @ 5 .r
 1044:     combined-prims num-combined @ 1- th @ prim-num @ 5 .r
 1045:     combined prim-num @ 5 .r ."  prim, \ "
 1046:     combined prim-c-name 2@ type
 1047:     cr ;
 1048: 
 1049: 
 1050: \ the parser
 1051: 
 1052: eof-char max-member \ the whole character set + EOF
 1053: 
 1054: : getinput ( -- n )
 1055:  rawinput @ endrawinput @ =
 1056:  if
 1057:    eof-char
 1058:  else
 1059:    cookedinput @ c@
 1060:  endif ;
 1061: 
 1062: :noname ( n -- )
 1063:  dup bl > if
 1064:   emit space
 1065:  else
 1066:   .
 1067:  endif ;
 1068: print-token !
 1069: 
 1070: : testchar? ( set -- f )
 1071:  getinput member? ;
 1072: ' testchar? test-vector !
 1073: 
 1074: : checksyncline ( -- )
 1075:     \ when input points to a newline, check if the next line is a
 1076:     \ sync line.  If it is, perform the appropriate actions.
 1077:     rawinput @ >r
 1078:     s" #line " r@ over compare 0<> if
 1079: 	rdrop 1 line +! EXIT
 1080:     endif
 1081:     0. r> 6 chars + 20 >number drop >r drop line ! r> ( c-addr )
 1082:     dup c@ bl = if
 1083: 	char+ dup c@ [char] " <> 0= s" sync line syntax" ?print-error
 1084: 	char+ dup 100 [char] " scan drop swap 2dup - save-mem filename 2!
 1085: 	char+
 1086:     endif
 1087:     dup c@ nl-char <> 0= s" sync line syntax" ?print-error
 1088:     skipsynclines @ if
 1089: 	dup char+ rawinput !
 1090: 	rawinput @ c@ cookedinput @ c!
 1091:     endif
 1092:     drop ;
 1093: 
 1094: : ?nextchar ( f -- )
 1095:     s" syntax error, wrong char" ?print-error
 1096:     rawinput @ endrawinput @ <> if
 1097: 	rawinput @ c@
 1098: 	1 chars rawinput +!
 1099: 	1 chars cookedinput +!
 1100: 	nl-char = if
 1101: 	    checksyncline
 1102: 	    rawinput @ line-start !
 1103: 	endif
 1104: 	rawinput @ c@ cookedinput @ c!
 1105:     endif ;
 1106: 
 1107: : charclass ( set "name" -- )
 1108:  ['] ?nextchar terminal ;
 1109: 
 1110: : .. ( c1 c2 -- set )
 1111:  ( creates a set that includes the characters c, c1<=c<=c2 )
 1112:  empty copy-set
 1113:  swap 1+ rot do
 1114:   i over add-member
 1115:  loop ;
 1116: 
 1117: : ` ( -- terminal ) ( use: ` c )
 1118:  ( creates anonymous terminal for the character c )
 1119:  char singleton ['] ?nextchar make-terminal ;
 1120: 
 1121: char a char z ..  char A char Z ..  union char _ singleton union  charclass letter
 1122: char 0 char 9 ..					charclass digit
 1123: bl singleton tab-char over add-member			charclass white
 1124: nl-char singleton eof-char over add-member complement	charclass nonl
 1125: nl-char singleton eof-char over add-member
 1126:     char : over add-member complement                   charclass nocolonnl
 1127: bl 1+ maxchar .. char \ singleton complement intersection
 1128:                                                         charclass nowhitebq
 1129: bl 1+ maxchar ..                                        charclass nowhite
 1130: char " singleton eof-char over add-member complement	charclass noquote
 1131: nl-char singleton					charclass nl
 1132: eof-char singleton					charclass eof
 1133: nl-char singleton eof-char over add-member		charclass nleof
 1134: 
 1135: (( letter (( letter || digit )) **
 1136: )) <- c-ident ( -- )
 1137: 
 1138: (( ` # ?? (( letter || digit || ` : )) **
 1139: )) <- stack-ident ( -- )
 1140: 
 1141: (( nowhitebq nowhite ** ))
 1142: <- forth-ident ( -- )
 1143: 
 1144: Variable forth-flag
 1145: Variable c-flag
 1146: 
 1147: (( (( ` e || ` E )) {{ start }} nonl ** 
 1148:    {{ end evaluate }}
 1149: )) <- eval-comment ( ... -- ... )
 1150: 
 1151: (( (( ` f || ` F )) {{ start }} nonl ** 
 1152:    {{ end forth-flag @ IF type cr ELSE 2drop THEN }}
 1153: )) <- forth-comment ( -- )
 1154: 
 1155: (( (( ` c || ` C )) {{ start }} nonl ** 
 1156:    {{ end c-flag @ IF type cr ELSE 2drop THEN }}
 1157: )) <- c-comment ( -- )
 1158: 
 1159: (( ` - nonl ** {{ 
 1160: 	forth-flag @ IF ." [ELSE]" cr THEN
 1161: 	c-flag @ IF ." #else" cr THEN }}
 1162: )) <- else-comment
 1163: 
 1164: (( ` + {{ start }} nonl ** {{ end
 1165: 	dup
 1166: 	IF	c-flag @
 1167: 		IF    ." #ifdef HAS_" bounds ?DO  I c@ toupper emit  LOOP cr
 1168: 		THEN
 1169: 		forth-flag @
 1170: 		IF  ." has? " type ."  [IF]"  cr THEN
 1171: 	ELSE	2drop
 1172: 	    c-flag @      IF  ." #endif"  cr THEN
 1173: 	    forth-flag @  IF  ." [THEN]"  cr THEN
 1174: 	THEN }}
 1175: )) <- if-comment
 1176: 
 1177: (( (( eval-comment || forth-comment || c-comment || else-comment || if-comment )) ?? nonl ** )) <- comment-body
 1178: 
 1179: (( ` \ comment-body nleof )) <- comment ( -- )
 1180: 
 1181: (( {{ start }} stack-ident {{ end 2 pick init-item item% %size + }} white ** )) **
 1182: <- stack-items
 1183: 
 1184: (( {{ prim prim-effect-in }}  stack-items {{ prim prim-effect-in-end ! }}
 1185:    ` - ` - white **
 1186:    {{ prim prim-effect-out }} stack-items {{ prim prim-effect-out-end ! }}
 1187: )) <- stack-effect ( -- )
 1188: 
 1189: (( {{ prim create-prim }}
 1190:    ` ( white ** {{ start }} stack-effect {{ end prim prim-stack-string 2! }} ` ) white **
 1191:    (( {{ start }} forth-ident {{ end prim prim-wordset 2! }} white **
 1192:       (( {{ start }}  c-ident {{ end prim prim-c-name 2! }} )) ??
 1193:    )) ??  nleof
 1194:    (( ` " ` "  {{ start }} (( noquote ++ ` " )) ++ {{ end 1- prim prim-doc 2! }} ` " white ** nleof )) ??
 1195:    {{ skipsynclines off line @ c-line ! filename 2@ c-filename 2! start }} (( nocolonnl nonl **  nleof white ** )) ** {{ end prim prim-c-code 2! skipsynclines on }}
 1196:    (( ` :  white ** nleof
 1197:       {{ start }} (( nonl ++  nleof white ** )) ++ {{ end prim prim-forth-code 2! }}
 1198:    )) ?? {{ process-simple }}
 1199:    nleof
 1200: )) <- simple-primitive ( -- )
 1201: 
 1202: (( {{ init-combined }}
 1203:    ` = white ** (( {{ start }} forth-ident {{ end add-prim }} white ** )) ++
 1204:    nleof {{ process-combined }}
 1205: )) <- combined-primitive
 1206: 
 1207: (( {{ make-prim to prim 0 to combined
 1208:       line @ name-line ! filename 2@ name-filename 2!
 1209:       function-number @ prim prim-num !
 1210:       start }} forth-ident {{ end 2dup prim prim-name 2! prim prim-c-name 2! }}  white ++
 1211:    (( simple-primitive || combined-primitive )) {{ 1 function-number +! }}
 1212: )) <- primitive ( -- )
 1213: 
 1214: (( (( comment || primitive || nl white ** )) ** eof ))
 1215: parser primitives2something
 1216: warnings @ [IF]
 1217: .( parser generated ok ) cr
 1218: [THEN]
 1219: 
 1220: : primfilter ( addr u -- )
 1221:     \ process the string at addr u
 1222:     over dup rawinput ! dup line-start ! cookedinput !
 1223:     + endrawinput !
 1224:     checksyncline
 1225:     primitives2something ;    
 1226: 
 1227: : process-file ( addr u xt-simple x-combined -- )
 1228:     output-combined ! output !
 1229:     save-mem 2dup filename 2!
 1230:     slurp-file
 1231:     warnings @ if
 1232: 	." ------------ CUT HERE -------------" cr  endif
 1233:     primfilter ;
 1234: 
 1235: \  : process      ( xt -- )
 1236: \      bl word count rot
 1237: \      process-file ;

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>