1: \ converts primitives to, e.g., C code
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: \ This is not very nice (hard limits, no checking, assumes 1 chars = 1).
23: \ And it grew even worse when it aged.
24:
25: \ Optimizations:
26: \ superfluous stores are removed. GCC removes the superfluous loads by itself
27: \ TOS and FTOS can be kept in register( variable)s.
28: \
29: \ Problems:
30: \ The TOS optimization is somewhat hairy. The problems by example:
31: \ 1) dup ( w -- w w ): w=TOS; sp-=1; sp[1]=w; TOS=w;
32: \ The store is not superfluous although the earlier opt. would think so
33: \ Alternatively: sp[0]=TOS; w=TOS; sp-=1; TOS=w;
34: \ 2) ( -- .. ): sp[0] = TOS; ... /* This additional store is necessary */
35: \ 3) ( .. -- ): ... TOS = sp[0]; /* as well as this load */
36: \ 4) ( -- ): /* but here they are unnecessary */
37: \ 5) Words that call NEXT themselves have to be done very carefully.
38: \
39: \ To do:
40: \ add the store optimization for doubles
41: \ regarding problem 1 above: It would be better (for over) to implement
42: \ the alternative
43: \ store optimization for combined instructions.
44: \ eliminate stack-cast (no longer used)
45:
46: \ Design Uglyness:
47:
48: \ - global state (values, variables) in connection with combined instructions.
49:
50: \ - index computation is different for instruction-stream and the
51: \ stacks; there are two mechanisms for dealing with that
52: \ (stack-in-index-xt and a test for stack==instruction-stream); there
53: \ should be only one.
54:
55: warnings off
56:
57: [IFUNDEF] vocabulary \ we are executed just with kernel image
58: \ load the rest that is needed
59: \ (require fails because this file is needed from a
60: \ different directory with the wordlibraries)
61: include ./search.fs
62: include ./extend.fs
63: [THEN]
64: include ./stuff.fs
65:
66: [IFUNDEF] environment?
67: include ./environ.fs
68: [THEN]
69:
70: : struct% struct ; \ struct is redefined in gray
71:
72: include ./gray.fs
73:
74: 32 constant max-effect \ number of things on one side of a stack effect
75: 4 constant max-stacks \ the max. number of stacks (including inst-stream).
76: 255 constant maxchar
77: maxchar 1+ constant eof-char
78: #tab constant tab-char
79: #lf constant nl-char
80:
81: variable rawinput \ pointer to next character to be scanned
82: variable endrawinput \ pointer to the end of the input (the char after the last)
83: variable cookedinput \ pointer to the next char to be parsed
84: variable line \ line number of char pointed to by input
85: variable line-start \ pointer to start of current line (for error messages)
86: 0 line !
87: 2variable filename \ filename of original input file
88: 0 0 filename 2!
89: 2variable f-comment
90: 0 0 f-comment 2!
91: variable skipsynclines \ are sync lines ("#line ...") invisible to the parser?
92: skipsynclines on
93:
94: : th ( addr1 n -- addr2 )
95: cells + ;
96:
97: : holds ( addr u -- )
98: \ like HOLD, but for a string
99: tuck + swap 0 +do
100: 1- dup c@ hold
101: loop
102: drop ;
103:
104: : insert-wordlist { c-addr u wordlist xt -- }
105: \ adds name "addr u" to wordlist using defining word xt
106: \ xt may cause additional stack effects
107: get-current >r wordlist set-current
108: c-addr u nextname xt execute
109: r> set-current ;
110:
111: : start ( -- addr )
112: cookedinput @ ;
113:
114: : end ( addr -- addr u )
115: cookedinput @ over - ;
116:
117: : print-error-line ( -- )
118: \ print the current line and position
119: line-start @ endrawinput @ over - 2dup nl-char scan drop nip ( start end )
120: over - type cr
121: line-start @ rawinput @ over - typewhite ." ^" cr ;
122:
123: : ?print-error { f addr u -- }
124: f ?not? if
125: outfile-id >r try
126: stderr to outfile-id
127: filename 2@ type ." :" line @ 0 .r ." : " addr u type cr
128: print-error-line
129: 0
130: recover endtry
131: r> to outfile-id throw
132: abort
133: endif ;
134:
135: : quote ( -- )
136: [char] " emit ;
137:
138: variable output \ xt ( -- ) of output word for simple primitives
139: variable output-combined \ xt ( -- ) of output word for combined primitives
140:
141: struct%
142: cell% field stack-number \ the number of this stack
143: cell% 2* field stack-pointer \ stackpointer name
144: cell% field stack-type \ name for default type of stack items
145: cell% 2* field stack-cast \ cast string for assignments to stack elements
146: cell% field stack-in-index-xt \ ( in-size item -- in-index )
147: end-struct stack%
148:
149: struct%
150: cell% 2* field item-name \ name, excluding stack prefixes
151: cell% field item-stack \ descriptor for the stack used, 0 is default
152: cell% field item-type \ descriptor for the item type
153: cell% field item-offset \ offset in stack items, 0 for the deepest element
154: cell% field item-first \ true if this is the first occurence of the item
155: end-struct item%
156:
157: struct%
158: cell% 2* field type-c-name
159: cell% field type-stack \ default stack
160: cell% field type-size \ size of type in stack items
161: cell% field type-fetch \ xt of fetch code generator ( item -- )
162: cell% field type-store \ xt of store code generator ( item -- )
163: end-struct type%
164:
165: variable next-stack-number 0 next-stack-number !
166: create stacks max-stacks cells allot \ array of stacks
167:
168: : stack-in-index ( in-size item -- in-index )
169: item-offset @ - 1- ;
170:
171: : inst-in-index ( in-size item -- in-index )
172: nip dup item-offset @ swap item-type @ type-size @ + 1- ;
173:
174: : make-stack ( addr-ptr u1 type addr-cast u2 "stack-name" -- )
175: create stack% %allot >r
176: r@ stacks next-stack-number @ th !
177: next-stack-number @ r@ stack-number ! 1 next-stack-number +!
178: save-mem r@ stack-cast 2!
179: r@ stack-type !
180: save-mem r@ stack-pointer 2!
181: ['] stack-in-index r> stack-in-index-xt ! ;
182:
183: \ stack items
184:
185: : init-item ( addr u addr1 -- )
186: \ initialize item at addr1 with name addr u
187: \ !! remove stack prefix
188: dup item% %size erase
189: item-name 2! ;
190:
191: : map-items { addr end xt -- }
192: \ perform xt for all items in array addr...end
193: end addr ?do
194: i xt execute
195: item% %size +loop ;
196:
197: \ types
198:
199: : print-type-prefix ( type -- )
200: body> >head name>string type ;
201:
202: \ various variables for storing stuff of one primitive
203:
204: struct%
205: cell% 2* field prim-name
206: cell% 2* field prim-wordset
207: cell% 2* field prim-c-name
208: cell% 2* field prim-doc
209: cell% 2* field prim-c-code
210: cell% 2* field prim-forth-code
211: cell% 2* field prim-stack-string
212: cell% field prim-num \ ordinal number
213: cell% field prim-items-wordlist \ unique items
214: item% max-effect * field prim-effect-in
215: item% max-effect * field prim-effect-out
216: cell% field prim-effect-in-end
217: cell% field prim-effect-out-end
218: cell% max-stacks * field prim-stacks-in \ number of in items per stack
219: cell% max-stacks * field prim-stacks-out \ number of out items per stack
220: end-struct prim%
221:
222: : make-prim ( -- prim )
223: prim% %alloc { p }
224: s" " p prim-doc 2! s" " p prim-forth-code 2! s" " p prim-wordset 2!
225: p ;
226:
227: 0 value prim \ in combined prims either combined or a part
228: 0 value combined \ in combined prims the combined prim
229: variable in-part \ true if processing a part
230: in-part off
231:
232: 1000 constant max-combined
233: create combined-prims max-combined cells allot
234: variable num-combined
235:
236: table constant combinations
237: \ the keys are the sequences of pointers to primitives
238:
239: create current-depth max-stacks cells allot
240: create max-depth max-stacks cells allot
241: create min-depth max-stacks cells allot
242:
243: wordlist constant primitives
244:
245: : create-prim ( prim -- )
246: dup prim-name 2@ primitives ['] constant insert-wordlist ;
247:
248: : stack-in ( stack -- addr )
249: \ address of number of stack items in effect in
250: stack-number @ cells prim prim-stacks-in + ;
251:
252: : stack-out ( stack -- addr )
253: \ address of number of stack items in effect out
254: stack-number @ cells prim prim-stacks-out + ;
255:
256: \ global vars
257: variable c-line
258: 2variable c-filename
259: variable name-line
260: 2variable name-filename
261: 2variable last-name-filename
262: Variable function-number 0 function-number !
263:
264: \ a few more set ops
265:
266: : bit-equivalent ( w1 w2 -- w3 )
267: xor invert ;
268:
269: : complement ( set1 -- set2 )
270: empty ['] bit-equivalent binary-set-operation ;
271:
272: \ stack access stuff
273:
274: : normal-stack-access ( n stack -- )
275: stack-pointer 2@ type
276: dup
277: if
278: ." [" 0 .r ." ]"
279: else
280: drop ." TOS"
281: endif ;
282:
283: \ forward declaration for inst-stream (breaks cycle in definitions)
284: defer inst-stream-f ( -- stack )
285:
286: : part-stack-access { n stack -- }
287: \ print _<stack><x>, x=inst-stream? n : maxdepth-currentdepth-n-1
288: ." _" stack stack-pointer 2@ type
289: stack stack-number @ { stack# }
290: current-depth stack# th @ n + { access-depth }
291: stack inst-stream-f = if
292: access-depth
293: else
294: combined prim-stacks-in stack# th @
295: assert( dup max-depth stack# th @ = )
296: access-depth - 1-
297: endif
298: 0 .r ;
299:
300: : stack-access ( n stack -- )
301: \ print a stack access at index n of stack
302: in-part @ if
303: part-stack-access
304: else
305: normal-stack-access
306: endif ;
307:
308: : item-in-index { item -- n }
309: \ n is the index of item (in the in-effect)
310: item item-stack @ dup >r stack-in @ ( in-size r:stack )
311: item r> stack-in-index-xt @ execute ;
312:
313: : item-stack-type-name ( item -- addr u )
314: item-stack @ stack-type @ type-c-name 2@ ;
315:
316: : fetch-single ( item -- )
317: \ fetch a single stack item from its stack
318: >r
319: r@ item-name 2@ type
320: ." = vm_" r@ item-stack-type-name type
321: ." 2" r@ item-type @ print-type-prefix ." ("
322: r@ item-in-index r@ item-stack @ stack-access
323: ." );" cr
324: rdrop ;
325:
326: : fetch-double ( item -- )
327: \ fetch a double stack item from its stack
328: >r
329: ." vm_two"
330: r@ item-stack-type-name type ." 2"
331: r@ item-type @ print-type-prefix ." ("
332: r@ item-name 2@ type ." , "
333: r@ item-in-index r@ item-stack @ 2dup ." (Cell)" stack-access
334: ." , " -1 under+ ." (Cell)" stack-access
335: ." );" cr
336: rdrop ;
337:
338: : same-as-in? ( item -- f )
339: \ f is true iff the offset and stack of item is the same as on input
340: >r
341: r@ item-first @ if
342: rdrop false exit
343: endif
344: r@ item-name 2@ prim prim-items-wordlist @ search-wordlist 0= abort" bug"
345: execute @
346: dup r@ =
347: if \ item first appeared in output
348: drop false
349: else
350: dup item-stack @ r@ item-stack @ =
351: swap item-offset @ r@ item-offset @ = and
352: endif
353: rdrop ;
354:
355: : item-out-index ( item -- n )
356: \ n is the index of item (in the in-effect)
357: >r r@ item-stack @ stack-out @ r> item-offset @ - 1- ;
358:
359: : really-store-single ( item -- )
360: >r
361: r@ item-out-index r@ item-stack @ stack-access ." = vm_"
362: r@ item-type @ print-type-prefix ." 2"
363: r@ item-stack-type-name type ." ("
364: r@ item-name 2@ type ." );"
365: rdrop ;
366:
367: : store-single ( item -- )
368: >r
369: r@ same-as-in?
370: if
371: r@ item-in-index 0= r@ item-out-index 0= xor
372: if
373: ." IF_" r@ item-stack @ stack-pointer 2@ type
374: ." TOS(" r@ really-store-single ." );" cr
375: endif
376: else
377: r@ really-store-single cr
378: endif
379: rdrop ;
380:
381: : store-double ( item -- )
382: \ !! store optimization is not performed, because it is not yet needed
383: >r
384: ." vm_"
385: r@ item-type @ print-type-prefix ." 2two"
386: r@ item-stack-type-name type ." ("
387: r@ item-name 2@ type ." , "
388: r@ item-out-index r@ item-stack @ 2dup stack-access
389: ." , " -1 under+ stack-access
390: ." );" cr
391: rdrop ;
392:
393: : single ( -- xt1 xt2 n )
394: ['] fetch-single ['] store-single 1 ;
395:
396: : double ( -- xt1 xt2 n )
397: ['] fetch-double ['] store-double 2 ;
398:
399: : s, ( addr u -- )
400: \ allocate a string
401: here swap dup allot move ;
402:
403: wordlist constant prefixes
404:
405: : declare ( addr "name" -- )
406: \ remember that there is a stack item at addr called name
407: create , ;
408:
409: : !default ( w addr -- )
410: dup @ if
411: 2drop \ leave nonzero alone
412: else
413: !
414: endif ;
415:
416: : create-type { addr u xt1 xt2 n stack -- } ( "prefix" -- )
417: \ describes a type
418: \ addr u specifies the C type name
419: \ stack effect entries of the type start with prefix
420: create type% %allot >r
421: addr u save-mem r@ type-c-name 2!
422: xt1 r@ type-fetch !
423: xt2 r@ type-store !
424: n r@ type-size !
425: stack r@ type-stack !
426: rdrop ;
427:
428: : type-prefix ( xt1 xt2 n stack "prefix" -- )
429: create-type
430: does> ( item -- )
431: \ initialize item
432: { item typ }
433: typ item item-type !
434: typ type-stack @ item item-stack !default
435: item item-name 2@ prim prim-items-wordlist @ search-wordlist 0= if
436: item item-name 2@ nextname item declare
437: item item-first on
438: \ typ type-c-name 2@ type space type ." ;" cr
439: else
440: drop
441: item item-first off
442: endif ;
443:
444: : execute-prefix ( item addr1 u1 -- )
445: \ execute the word ( item -- ) associated with the longest prefix
446: \ of addr1 u1
447: 0 swap ?do
448: dup i prefixes search-wordlist
449: if \ ok, we have the type ( item addr1 xt )
450: nip execute
451: UNLOOP EXIT
452: endif
453: -1 s+loop
454: \ we did not find a type, abort
455: false s" unknown prefix" ?print-error ;
456:
457: : declaration ( item -- )
458: dup item-name 2@ execute-prefix ;
459:
460: : declaration-list ( addr1 addr2 -- )
461: ['] declaration map-items ;
462:
463: : declarations ( -- )
464: wordlist dup prim prim-items-wordlist ! set-current
465: prim prim-effect-in prim prim-effect-in-end @ declaration-list
466: prim prim-effect-out prim prim-effect-out-end @ declaration-list ;
467:
468: : print-declaration { item -- }
469: item item-first @ if
470: item item-type @ type-c-name 2@ type space
471: item item-name 2@ type ." ;" cr
472: endif ;
473:
474: : print-declarations ( -- )
475: prim prim-effect-in prim prim-effect-in-end @ ['] print-declaration map-items
476: prim prim-effect-out prim prim-effect-out-end @ ['] print-declaration map-items ;
477:
478: : stack-prefix ( stack "prefix" -- )
479: name tuck nextname create ( stack length ) 2,
480: does> ( item -- )
481: 2@ { item stack prefix-length }
482: item item-name 2@ prefix-length /string item item-name 2!
483: stack item item-stack !
484: item declaration ;
485:
486: \ types pointed to by stacks for use in combined prims
487: \ !! output-c-combined shouldn't use these names!
488: s" Cell" single 0 create-type w
489: s" Float" single 0 create-type r
490:
491: s" sp" save-mem w s" (Cell)" make-stack data-stack
492: s" fp" save-mem r s" " make-stack fp-stack
493: s" rp" save-mem w s" (Cell)" make-stack return-stack
494: s" IP" save-mem w s" error don't use # on results" make-stack inst-stream
495: ' inst-in-index inst-stream stack-in-index-xt !
496: ' inst-stream <is> inst-stream-f
497: \ !! initialize stack-in and stack-out
498:
499: \ offset computation
500: \ the leftmost (i.e. deepest) item has offset 0
501: \ the rightmost item has the highest offset
502:
503: : compute-offset { item xt -- }
504: \ xt specifies in/out; update stack-in/out and set item-offset
505: item item-type @ type-size @
506: item item-stack @ xt execute dup @ >r +!
507: r> item item-offset ! ;
508:
509: : compute-offset-in ( addr1 addr2 -- )
510: ['] stack-in compute-offset ;
511:
512: : compute-offset-out ( addr1 addr2 -- )
513: ['] stack-out compute-offset ;
514:
515: : clear-stack { -- }
516: dup stack-in off stack-out off ;
517:
518: : compute-offsets ( -- )
519: data-stack clear-stack fp-stack clear-stack return-stack clear-stack
520: inst-stream clear-stack
521: prim prim-effect-in prim prim-effect-in-end @ ['] compute-offset-in map-items
522: prim prim-effect-out prim prim-effect-out-end @ ['] compute-offset-out map-items
523: inst-stream stack-out @ 0= s" # can only be on the input side" ?print-error ;
524:
525: : process-simple ( -- )
526: prim prim { W^ key } key cell
527: combinations ['] constant insert-wordlist
528: declarations compute-offsets
529: output @ execute ;
530:
531: : flush-a-tos { stack -- }
532: stack stack-out @ 0<> stack stack-in @ 0= and
533: if
534: ." IF_" stack stack-pointer 2@ 2dup type ." TOS("
535: 2dup type ." [0] = " type ." TOS);" cr
536: endif ;
537:
538: : flush-tos ( -- )
539: data-stack flush-a-tos
540: fp-stack flush-a-tos
541: return-stack flush-a-tos ;
542:
543: : fill-a-tos { stack -- }
544: stack stack-out @ 0= stack stack-in @ 0<> and
545: if
546: ." IF_" stack stack-pointer 2@ 2dup type ." TOS("
547: 2dup type ." TOS = " type ." [0]);" cr
548: endif ;
549:
550: : fill-tos ( -- )
551: \ !! inst-stream for prefetching?
552: fp-stack fill-a-tos
553: data-stack fill-a-tos
554: return-stack fill-a-tos ;
555:
556: : fetch ( addr -- )
557: dup item-type @ type-fetch @ execute ;
558:
559: : fetches ( -- )
560: prim prim-effect-in prim prim-effect-in-end @ ['] fetch map-items ;
561:
562: : stack-pointer-update { stack -- }
563: \ stack grow downwards
564: stack stack-in @ stack stack-out @ -
565: ?dup-if \ this check is not necessary, gcc would do this for us
566: stack stack-pointer 2@ type ." += " 0 .r ." ;" cr
567: endif ;
568:
569: : inst-pointer-update ( -- )
570: inst-stream stack-in @ ?dup-if
571: ." INC_IP(" 0 .r ." );" cr
572: endif ;
573:
574: : stack-pointer-updates ( -- )
575: inst-pointer-update
576: data-stack stack-pointer-update
577: fp-stack stack-pointer-update
578: return-stack stack-pointer-update ;
579:
580: : store ( item -- )
581: \ f is true if the item should be stored
582: \ f is false if the store is probably not necessary
583: dup item-type @ type-store @ execute ;
584:
585: : stores ( -- )
586: prim prim-effect-out prim prim-effect-out-end @ ['] store map-items ;
587:
588: : output-c-tail ( -- )
589: \ the final part of the generated C code
590: ." NEXT_P1;" cr
591: stores
592: fill-tos
593: ." NEXT_P2;" ;
594:
595: : type-c-code ( c-addr u xt -- )
596: \ like TYPE, but replaces "TAIL;" with tail code produced by xt
597: { xt }
598: begin ( c-addr1 u1 )
599: 2dup s" TAIL;" search
600: while ( c-addr1 u1 c-addr3 u3 )
601: 2dup 2>r drop nip over - type
602: xt execute
603: 2r> 5 /string
604: \ !! resync #line missing
605: repeat
606: 2drop type ;
607:
608: : print-debug-arg { item -- }
609: ." fputs(" quote space item item-name 2@ type ." =" quote ." , vm_out); "
610: ." printarg_" item item-type @ print-type-prefix
611: ." (" item item-name 2@ type ." );" cr ;
612:
613: : print-debug-args ( -- )
614: ." #ifdef VM_DEBUG" cr
615: ." if (vm_debug) {" cr
616: prim prim-effect-in prim prim-effect-in-end @ ['] print-debug-arg map-items
617: ." fputc('\n', vm_out);" cr
618: ." }" cr
619: ." #endif" cr ;
620:
621: : print-entry ( -- )
622: ." I_" prim prim-c-name 2@ type ." :" ;
623:
624: : output-c ( -- )
625: print-entry ." /* " prim prim-name 2@ type ." ( " prim prim-stack-string 2@ type ." ) */" cr
626: ." /* " prim prim-doc 2@ type ." */" cr
627: ." NAME(" quote prim prim-name 2@ type quote ." )" cr \ debugging
628: ." {" cr
629: ." DEF_CA" cr
630: print-declarations
631: ." NEXT_P0;" cr
632: flush-tos
633: fetches
634: print-debug-args
635: stack-pointer-updates
636: ." {" cr
637: ." #line " c-line @ . quote c-filename 2@ type quote cr
638: prim prim-c-code 2@ ['] output-c-tail type-c-code
639: ." }" cr
640: output-c-tail
641: ." }" cr
642: cr
643: ;
644:
645: : disasm-arg { item -- }
646: item item-stack @ inst-stream = if
647: ." fputc(' ', vm_out); "
648: ." printarg_" item item-type @ print-type-prefix
649: ." ((" item item-type @ type-c-name 2@ type ." )"
650: ." ip[" item item-offset @ 1+ 0 .r ." ]);" cr
651: endif ;
652:
653: : disasm-args ( -- )
654: prim prim-effect-in prim prim-effect-in-end @ ['] disasm-arg map-items ;
655:
656: : output-disasm ( -- )
657: \ generate code for disassembling VM instructions
658: ." if (ip[0] == prim[" function-number @ 0 .r ." ]) {" cr
659: ." fputs(" quote prim prim-name 2@ type quote ." , vm_out);" cr
660: disasm-args
661: ." ip += " inst-stream stack-in @ 1+ 0 .r ." ;" cr
662: ." } else " ;
663:
664: : gen-arg-parm { item -- }
665: item item-stack @ inst-stream = if
666: ." , " item item-type @ type-c-name 2@ type space
667: item item-name 2@ type
668: endif ;
669:
670: : gen-args-parm ( -- )
671: prim prim-effect-in prim prim-effect-in-end @ ['] gen-arg-parm map-items ;
672:
673: : gen-arg-gen { item -- }
674: item item-stack @ inst-stream = if
675: ." genarg_" item item-type @ print-type-prefix
676: ." (ctp, " item item-name 2@ type ." );" cr
677: endif ;
678:
679: : gen-args-gen ( -- )
680: prim prim-effect-in prim prim-effect-in-end @ ['] gen-arg-gen map-items ;
681:
682: : output-gen ( -- )
683: \ generate C code for generating VM instructions
684: ." void gen_" prim prim-c-name 2@ type ." (Inst **ctp" gen-args-parm ." )" cr
685: ." {" cr
686: ." gen_inst(ctp, vm_prim[" function-number @ 0 .r ." ]);" cr
687: gen-args-gen
688: ." }" cr ;
689:
690: : stack-used? { stack -- f }
691: stack stack-in @ stack stack-out @ or 0<> ;
692:
693: : output-funclabel ( -- )
694: ." &I_" prim prim-c-name 2@ type ." ," cr ;
695:
696: : output-forthname ( -- )
697: '" emit prim prim-name 2@ type '" emit ." ," cr ;
698:
699: : output-c-func ( -- )
700: \ used for word libraries
701: ." Cell * I_" prim prim-c-name 2@ type ." (Cell *SP, Cell **FP) /* " prim prim-name 2@ type
702: ." ( " prim prim-stack-string 2@ type ." ) */" cr
703: ." /* " prim prim-doc 2@ type ." */" cr
704: ." NAME(" quote prim prim-name 2@ type quote ." )" cr
705: \ debugging
706: ." {" cr
707: print-declarations
708: inst-stream stack-used? IF ." Cell *ip=IP;" cr THEN
709: data-stack stack-used? IF ." Cell *sp=SP;" cr THEN
710: fp-stack stack-used? IF ." Cell *fp=*FP;" cr THEN
711: return-stack stack-used? IF ." Cell *rp=*RP;" cr THEN
712: flush-tos
713: fetches
714: stack-pointer-updates
715: fp-stack stack-used? IF ." *FP=fp;" cr THEN
716: ." {" cr
717: ." #line " c-line @ . quote c-filename 2@ type quote cr
718: prim prim-c-code 2@ type
719: ." }" cr
720: stores
721: fill-tos
722: ." return (sp);" cr
723: ." }" cr
724: cr ;
725:
726: : output-label ( -- )
727: ." (Label)&&I_" prim prim-c-name 2@ type ." ," cr ;
728:
729: : output-alias ( -- )
730: ( primitive-number @ . ." alias " ) ." Primitive " prim prim-name 2@ type cr ;
731:
732: : output-forth ( -- )
733: prim prim-forth-code @ 0=
734: IF \ output-alias
735: \ this is bad for ec: an alias is compiled if tho word does not exist!
736: \ JAW
737: ELSE ." : " prim prim-name 2@ type ." ( "
738: prim prim-stack-string 2@ type ." )" cr
739: prim prim-forth-code 2@ type cr
740: THEN ;
741:
742: : output-tag-file ( -- )
743: name-filename 2@ last-name-filename 2@ compare if
744: name-filename 2@ last-name-filename 2!
745: #ff emit cr
746: name-filename 2@ type
747: ." ,0" cr
748: endif ;
749:
750: : output-tag ( -- )
751: output-tag-file
752: prim prim-name 2@ 1+ type
753: 127 emit
754: space prim prim-name 2@ type space
755: 1 emit
756: name-line @ 0 .r
757: ." ,0" cr ;
758:
759: [IFDEF] documentation
760: : register-doc ( -- )
761: prim prim-name 2@ documentation ['] create insert-wordlist
762: prim prim-name 2@ 2,
763: prim prim-stack-string 2@ condition-stack-effect 2,
764: prim prim-wordset 2@ 2,
765: prim prim-c-name 2@ condition-pronounciation 2,
766: prim prim-doc 2@ 2, ;
767: [THEN]
768:
769:
770: \ combining instructions
771:
772: \ The input should look like this:
773:
774: \ lit_+ = lit +
775:
776: \ The output should look like this:
777:
778: \ I_lit_+:
779: \ {
780: \ DEF_CA
781: \ Cell _x_ip0;
782: \ Cell _x_sp0;
783: \ Cell _x_sp1;
784: \ NEXT_P0;
785: \ _x_ip0 = (Cell) IPTOS;
786: \ _x_sp0 = (Cell) spTOS;
787: \ INC_IP(1);
788: \ /* sp += 0; */
789: \ /* lit ( #w -- w ) */
790: \ /* */
791: \ NAME("lit")
792: \ {
793: \ Cell w;
794: \ w = (Cell) _x_ip0;
795: \ #ifdef VM_DEBUG
796: \ if (vm_debug) {
797: \ fputs(" w=", vm_out); printarg_w (w);
798: \ fputc('\n', vm_out);
799: \ }
800: \ #endif
801: \ {
802: \ #line 136 "./prim"
803: \ }
804: \ _x_sp1 = (Cell)w;
805: \ }
806: \ I_plus: /* + ( n1 n2 -- n ) */
807: \ /* */
808: \ NAME("+")
809: \ {
810: \ DEF_CA
811: \ Cell n1;
812: \ Cell n2;
813: \ Cell n;
814: \ NEXT_P0;
815: \ n1 = (Cell) _x_sp0;
816: \ n2 = (Cell) _x_sp1;
817: \ #ifdef VM_DEBUG
818: \ if (vm_debug) {
819: \ fputs(" n1=", vm_out); printarg_n (n1);
820: \ fputs(" n2=", vm_out); printarg_n (n2);
821: \ fputc('\n', vm_out);
822: \ }
823: \ #endif
824: \ {
825: \ #line 516 "./prim"
826: \ n = n1+n2;
827: \ }
828: \ NEXT_P1;
829: \ _x_sp0 = (Cell)n;
830: \ NEXT_P2;
831: \ }
832: \ NEXT_P1;
833: \ spTOS = (Cell)_x_sp0;
834: \ NEXT_P2;
835:
836: : init-combined ( -- )
837: prim to combined
838: 0 num-combined !
839: current-depth max-stacks cells erase
840: max-depth max-stacks cells erase
841: min-depth max-stacks cells erase
842: prim prim-effect-in prim prim-effect-in-end !
843: prim prim-effect-out prim prim-effect-out-end ! ;
844:
845: : max! ( n addr -- )
846: tuck @ max swap ! ;
847:
848: : min! ( n addr -- )
849: tuck @ min swap ! ;
850:
851: : add-depths { p -- }
852: \ combine stack effect of p with *-depths
853: max-stacks 0 ?do
854: current-depth i th @
855: p prim-stacks-in i th @ +
856: dup max-depth i th max!
857: p prim-stacks-out i th @ -
858: dup min-depth i th min!
859: current-depth i th !
860: loop ;
861:
862: : add-prim ( addr u -- )
863: \ add primitive given by "addr u" to combined-prims
864: primitives search-wordlist s" unknown primitive" ?print-error
865: execute { p }
866: p combined-prims num-combined @ th !
867: 1 num-combined +!
868: p add-depths ;
869:
870: : compute-effects { q -- }
871: \ compute the stack effects of q from the depths
872: max-stacks 0 ?do
873: max-depth i th @ dup
874: q prim-stacks-in i th !
875: current-depth i th @ -
876: q prim-stacks-out i th !
877: loop ;
878:
879: : make-effect-items { stack# items effect-endp -- }
880: \ effect-endp points to a pointer to the end of the current item-array
881: \ and has to be updated
882: stacks stack# th @ { stack }
883: items 0 +do
884: effect-endp @ { item }
885: i 0 <# #s stack stack-pointer 2@ holds [char] _ hold #> save-mem
886: item item-name 2!
887: stack item item-stack !
888: stack stack-type @ item item-type !
889: i item item-offset !
890: item item-first on
891: item% %size effect-endp +!
892: loop ;
893:
894: : init-effects { q -- }
895: \ initialize effects field for FETCHES and STORES
896: max-stacks 0 ?do
897: i q prim-stacks-in i th @ q prim-effect-in-end make-effect-items
898: i q prim-stacks-out i th @ q prim-effect-out-end make-effect-items
899: loop ;
900:
901: : process-combined ( -- )
902: combined combined-prims num-combined @ cells
903: combinations ['] constant insert-wordlist
904: prim compute-effects
905: prim init-effects
906: output-combined perform ;
907:
908: \ C output
909:
910: : print-item { n stack -- }
911: \ print nth stack item name
912: stack stack-type @ type-c-name 2@ type space
913: ." _" stack stack-pointer 2@ type n 0 .r ;
914:
915: : print-declarations-combined ( -- )
916: max-stacks 0 ?do
917: max-depth i th @ min-depth i th @ - 0 +do
918: i stacks j th @ print-item ." ;" cr
919: loop
920: loop ;
921:
922: : part-fetches ( -- )
923: fetches ;
924:
925: : part-output-c-tail ( -- )
926: stores ;
927:
928: : output-combined-tail ( -- )
929: part-output-c-tail
930: prim >r combined to prim
931: in-part @ >r in-part off
932: output-c-tail
933: r> in-part ! r> to prim ;
934:
935: : output-part ( p -- )
936: to prim
937: ." /* " prim prim-name 2@ type ." ( " prim prim-stack-string 2@ type ." ) */" cr
938: ." NAME(" quote prim prim-name 2@ type quote ." )" cr \ debugging
939: ." {" cr
940: print-declarations
941: part-fetches
942: print-debug-args
943: prim add-depths \ !! right place?
944: ." {" cr
945: ." #line " c-line @ . quote c-filename 2@ type quote cr
946: prim prim-c-code 2@ ['] output-combined-tail type-c-code
947: ." }" cr
948: part-output-c-tail
949: ." }" cr ;
950:
951: : output-parts ( -- )
952: prim >r in-part on
953: current-depth max-stacks cells erase
954: num-combined @ 0 +do
955: combined-prims i th @ output-part
956: loop
957: in-part off
958: r> to prim ;
959:
960: : output-c-combined ( -- )
961: print-entry cr
962: \ debugging messages just in parts
963: ." {" cr
964: ." DEF_CA" cr
965: print-declarations-combined
966: ." NEXT_P0;" cr
967: flush-tos
968: fetches
969: \ print-debug-args
970: stack-pointer-updates
971: output-parts
972: output-c-tail
973: ." }" cr
974: cr ;
975:
976: : output-forth-combined ( -- )
977: ;
978:
979:
980: \ peephole optimization rules
981:
982: \ in order for this to work as intended, shorter combinations for each
983: \ length must be present, and the longer combinations must follow
984: \ shorter ones (this restriction may go away in the future).
985:
986: : output-peephole ( -- )
987: combined-prims num-combined @ 1- cells combinations search-wordlist
988: s" the prefix for this combination must be defined earlier" ?print-error
989: ." {"
990: execute prim-num @ 5 .r ." ,"
991: combined-prims num-combined @ 1- th @ prim-num @ 5 .r ." ,"
992: combined prim-num @ 5 .r ." }, /* "
993: combined prim-c-name 2@ type ." */"
994: cr ;
995:
996:
997: \ the parser
998:
999: eof-char max-member \ the whole character set + EOF
1000:
1001: : getinput ( -- n )
1002: rawinput @ endrawinput @ =
1003: if
1004: eof-char
1005: else
1006: cookedinput @ c@
1007: endif ;
1008:
1009: :noname ( n -- )
1010: dup bl > if
1011: emit space
1012: else
1013: .
1014: endif ;
1015: print-token !
1016:
1017: : testchar? ( set -- f )
1018: getinput member? ;
1019: ' testchar? test-vector !
1020:
1021: : checksyncline ( -- )
1022: \ when input points to a newline, check if the next line is a
1023: \ sync line. If it is, perform the appropriate actions.
1024: rawinput @ >r
1025: s" #line " r@ over compare 0<> if
1026: rdrop 1 line +! EXIT
1027: endif
1028: 0. r> 6 chars + 20 >number drop >r drop line ! r> ( c-addr )
1029: dup c@ bl = if
1030: char+ dup c@ [char] " <> 0= s" sync line syntax" ?print-error
1031: char+ dup 100 [char] " scan drop swap 2dup - save-mem filename 2!
1032: char+
1033: endif
1034: dup c@ nl-char <> 0= s" sync line syntax" ?print-error
1035: skipsynclines @ if
1036: dup char+ rawinput !
1037: rawinput @ c@ cookedinput @ c!
1038: endif
1039: drop ;
1040:
1041: : ?nextchar ( f -- )
1042: s" syntax error, wrong char" ?print-error
1043: rawinput @ endrawinput @ <> if
1044: rawinput @ c@
1045: 1 chars rawinput +!
1046: 1 chars cookedinput +!
1047: nl-char = if
1048: checksyncline
1049: rawinput @ line-start !
1050: endif
1051: rawinput @ c@ cookedinput @ c!
1052: endif ;
1053:
1054: : charclass ( set "name" -- )
1055: ['] ?nextchar terminal ;
1056:
1057: : .. ( c1 c2 -- set )
1058: ( creates a set that includes the characters c, c1<=c<=c2 )
1059: empty copy-set
1060: swap 1+ rot do
1061: i over add-member
1062: loop ;
1063:
1064: : ` ( -- terminal ) ( use: ` c )
1065: ( creates anonymous terminal for the character c )
1066: char singleton ['] ?nextchar make-terminal ;
1067:
1068: char a char z .. char A char Z .. union char _ singleton union charclass letter
1069: char 0 char 9 .. charclass digit
1070: bl singleton tab-char over add-member charclass white
1071: nl-char singleton eof-char over add-member complement charclass nonl
1072: nl-char singleton eof-char over add-member
1073: char : over add-member complement charclass nocolonnl
1074: bl 1+ maxchar .. char \ singleton complement intersection
1075: charclass nowhitebq
1076: bl 1+ maxchar .. charclass nowhite
1077: char " singleton eof-char over add-member complement charclass noquote
1078: nl-char singleton charclass nl
1079: eof-char singleton charclass eof
1080: nl-char singleton eof-char over add-member charclass nleof
1081:
1082: (( letter (( letter || digit )) **
1083: )) <- c-ident ( -- )
1084:
1085: (( ` # ?? (( letter || digit || ` : )) **
1086: )) <- stack-ident ( -- )
1087:
1088: (( nowhitebq nowhite ** ))
1089: <- forth-ident ( -- )
1090:
1091: Variable forth-flag
1092: Variable c-flag
1093:
1094: (( (( ` e || ` E )) {{ start }} nonl **
1095: {{ end evaluate }}
1096: )) <- eval-comment ( ... -- ... )
1097:
1098: (( (( ` f || ` F )) {{ start }} nonl **
1099: {{ end forth-flag @ IF type cr ELSE 2drop THEN }}
1100: )) <- forth-comment ( -- )
1101:
1102: (( (( ` c || ` C )) {{ start }} nonl **
1103: {{ end c-flag @ IF type cr ELSE 2drop THEN }}
1104: )) <- c-comment ( -- )
1105:
1106: (( ` - nonl ** {{
1107: forth-flag @ IF ." [ELSE]" cr THEN
1108: c-flag @ IF ." #else" cr THEN }}
1109: )) <- else-comment
1110:
1111: (( ` + {{ start }} nonl ** {{ end
1112: dup
1113: IF c-flag @
1114: IF ." #ifdef HAS_" bounds ?DO I c@ toupper emit LOOP cr
1115: THEN
1116: forth-flag @
1117: IF ." has? " type ." [IF]" cr THEN
1118: ELSE 2drop
1119: c-flag @ IF ." #endif" cr THEN
1120: forth-flag @ IF ." [THEN]" cr THEN
1121: THEN }}
1122: )) <- if-comment
1123:
1124: (( (( eval-comment || forth-comment || c-comment || else-comment || if-comment )) ?? nonl ** )) <- comment-body
1125:
1126: (( ` \ comment-body nleof )) <- comment ( -- )
1127:
1128: (( {{ start }} stack-ident {{ end 2 pick init-item item% %size + }} white ** )) **
1129: <- stack-items
1130:
1131: (( {{ prim prim-effect-in }} stack-items {{ prim prim-effect-in-end ! }}
1132: ` - ` - white **
1133: {{ prim prim-effect-out }} stack-items {{ prim prim-effect-out-end ! }}
1134: )) <- stack-effect ( -- )
1135:
1136: (( {{ prim create-prim }}
1137: ` ( white ** {{ start }} stack-effect {{ end prim prim-stack-string 2! }} ` ) white **
1138: (( {{ start }} forth-ident {{ end prim prim-wordset 2! }} white **
1139: (( {{ start }} c-ident {{ end prim prim-c-name 2! }} )) ??
1140: )) ?? nleof
1141: (( ` " ` " {{ start }} (( noquote ++ ` " )) ++ {{ end 1- prim prim-doc 2! }} ` " white ** nleof )) ??
1142: {{ skipsynclines off line @ c-line ! filename 2@ c-filename 2! start }} (( nocolonnl nonl ** nleof white ** )) ** {{ end prim prim-c-code 2! skipsynclines on }}
1143: (( ` : white ** nleof
1144: {{ start }} (( nonl ++ nleof white ** )) ++ {{ end prim prim-forth-code 2! }}
1145: )) ?? {{ process-simple }}
1146: nleof
1147: )) <- simple-primitive ( -- )
1148:
1149: (( {{ init-combined }}
1150: ` = (( white ++ {{ start }} forth-ident {{ end add-prim }} )) ++
1151: nleof {{ process-combined }}
1152: )) <- combined-primitive
1153:
1154: (( {{ make-prim to prim 0 to combined
1155: line @ name-line ! filename 2@ name-filename 2!
1156: function-number @ prim prim-num !
1157: start }} forth-ident {{ end 2dup prim prim-name 2! prim prim-c-name 2! }} white ++
1158: (( simple-primitive || combined-primitive )) {{ 1 function-number +! }}
1159: )) <- primitive ( -- )
1160:
1161: (( (( comment || primitive || nl white ** )) ** eof ))
1162: parser primitives2something
1163: warnings @ [IF]
1164: .( parser generated ok ) cr
1165: [THEN]
1166:
1167: : primfilter ( addr u -- )
1168: \ process the string at addr u
1169: over dup rawinput ! dup line-start ! cookedinput !
1170: + endrawinput !
1171: checksyncline
1172: primitives2something ;
1173:
1174: : process-file ( addr u xt-simple x-combined -- )
1175: output-combined ! output !
1176: save-mem 2dup filename 2!
1177: slurp-file
1178: warnings @ if
1179: ." ------------ CUT HERE -------------" cr endif
1180: primfilter ;
1181:
1182: \ : process ( xt -- )
1183: \ bl word count rot
1184: \ process-file ;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>