File:  [gforth] / gforth / prims2x.fs
Revision 1.144: download - view: text, annotated - select for diffs
Thu Oct 9 14:15:19 2003 UTC (16 years, 1 month ago) by anton
Branches: MAIN
CVS tags: HEAD
put stack caching stuff in prims2x.fs (cvs log prims2y.fs for
	fine-grained changes)
set up prim etc. to work with the changes prims2x.fs (disabled USE_TOS for now)

    1: \ converts primitives to, e.g., C code 
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: \ This is not very nice (hard limits, no checking, assumes 1 chars = 1).
   23: \ And it grew even worse when it aged.
   24: 
   25: \ Optimizations:
   26: \ superfluous stores are removed. GCC removes the superfluous loads by itself
   27: \ TOS and FTOS can be kept in register( variable)s.
   28: \ 
   29: \ Problems:
   30: \ The TOS optimization is somewhat hairy. The problems by example:
   31: \ 1) dup ( w -- w w ): w=TOS; sp-=1; sp[1]=w; TOS=w;
   32: \    The store is not superfluous although the earlier opt. would think so
   33: \    Alternatively:    sp[0]=TOS; w=TOS; sp-=1; TOS=w;
   34: \ 2) ( -- .. ): sp[0] = TOS; ... /* This additional store is necessary */
   35: \ 3) ( .. -- ): ... TOS = sp[0]; /* as well as this load */
   36: \ 4) ( -- ): /* but here they are unnecessary */
   37: \ 5) Words that call NEXT themselves have to be done very carefully.
   38: \
   39: \ To do:
   40: \ add the store optimization for doubles
   41: \ regarding problem 1 above: It would be better (for over) to implement
   42: \ 	the alternative
   43: \ store optimization for combined instructions.
   44: 
   45: \ Design Uglyness:
   46: 
   47: \ - global state (values, variables) in connection with combined instructions.
   48: 
   49: \ - index computation is different for instruction-stream and the
   50: \ stacks; there are two mechanisms for dealing with that
   51: \ (stack-in-index-xt and a test for stack==instruction-stream); there
   52: \ should be only one.
   53: 
   54: \ for backwards compatibility, jaw
   55: require compat/strcomp.fs
   56: 
   57: warnings off
   58: 
   59: \ redefinitions of kernel words not present in gforth-0.6.1
   60: : latestxt lastcfa @ ;
   61: : latest last @ ;
   62: 
   63: [IFUNDEF] try
   64: include startup.fs
   65: [THEN]
   66: 
   67: : struct% struct ; \ struct is redefined in gray
   68: 
   69: warnings off
   70: \ warnings on
   71: 
   72: include ./gray.fs
   73: 128 constant max-effect \ number of things on one side of a stack effect
   74: 4 constant max-stacks  \ the max. number of stacks (including inst-stream).
   75: 255 constant maxchar
   76: maxchar 1+ constant eof-char
   77: #tab constant tab-char
   78: #lf constant nl-char
   79: 
   80: variable rawinput \ pointer to next character to be scanned
   81: variable endrawinput \ pointer to the end of the input (the char after the last)
   82: variable cookedinput \ pointer to the next char to be parsed
   83: variable line \ line number of char pointed to by input
   84: variable line-start \ pointer to start of current line (for error messages)
   85: 0 line !
   86: 2variable filename \ filename of original input file
   87: 0 0 filename 2!
   88: 2variable out-filename \ filename of the output file (for sync lines)
   89: 0 0 out-filename 2!
   90: 2variable f-comment
   91: 0 0 f-comment 2!
   92: variable skipsynclines \ are sync lines ("#line ...") invisible to the parser?
   93: skipsynclines on
   94: variable out-nls \ newlines in output (for output sync lines)
   95: 0 out-nls !
   96: variable store-optimization \ use store optimization?
   97: store-optimization off
   98: 
   99: variable include-skipped-insts
  100: \ does the threaded code for a combined instruction include the cells
  101: \ for the component instructions (true) or only the cells for the
  102: \ inline arguments (false)
  103: include-skipped-insts off
  104: 
  105: variable immarg \ values for immediate arguments (to be used in IMM_ARG macros)
  106: $12340000 immarg !
  107: 
  108: : th ( addr1 n -- addr2 )
  109:     cells + ;
  110: 
  111: : holds ( addr u -- )
  112:     \ like HOLD, but for a string
  113:     tuck + swap 0 +do
  114: 	1- dup c@ hold
  115:     loop
  116:     drop ;
  117: 
  118: : insert-wordlist { c-addr u wordlist xt -- }
  119:     \ adds name "addr u" to wordlist using defining word xt
  120:     \ xt may cause additional stack effects
  121:     get-current >r wordlist set-current
  122:     c-addr u nextname xt execute
  123:     r> set-current ;
  124: 
  125: : start ( -- addr )
  126:  cookedinput @ ;
  127: 
  128: : end ( addr -- addr u )
  129:  cookedinput @ over - ;
  130: 
  131: : print-error-line ( -- )
  132:     \ print the current line and position
  133:     line-start @ endrawinput @ over - 2dup nl-char scan drop nip ( start end )
  134:     over - type cr
  135:     line-start @ rawinput @ over - typewhite ." ^" cr ;
  136: 
  137: : ?print-error { f addr u -- }
  138:     f ?not? if
  139: 	outfile-id >r try
  140: 	    stderr to outfile-id
  141: 	    filename 2@ type ." :" line @ 0 .r ." : " addr u type cr
  142: 	    print-error-line
  143: 	    0
  144: 	recover endtry
  145: 	r> to outfile-id throw
  146: 	1 (bye) \ abort
  147:     endif ;
  148: 
  149: : quote ( -- )
  150:     [char] " emit ;
  151: 
  152: \ count output lines to generate sync lines for output
  153: 
  154: : count-nls ( addr u -- )
  155:     bounds u+do
  156: 	i c@ nl-char = negate out-nls +!
  157:     loop ;
  158: 
  159: :noname ( addr u -- )
  160:     2dup count-nls
  161:     defers type ;
  162: is type
  163: 
  164: variable output          \ xt ( -- ) of output word for simple primitives
  165: variable output-combined \ xt ( -- ) of output word for combined primitives
  166: 
  167: struct%
  168:     cell%    field stack-number \ the number of this stack
  169:     cell% 2* field stack-pointer \ stackpointer name
  170:     cell%    field stack-type \ name for default type of stack items
  171:     cell%    field stack-in-index-xt \ ( in-size item -- in-index )
  172:     cell%    field stack-access-transform \ ( nitem -- index )
  173: end-struct stack%
  174: 
  175: struct%
  176:  cell% 2* field item-name   \ name, excluding stack prefixes
  177:  cell%    field item-stack  \ descriptor for the stack used, 0 is default
  178:  cell%    field item-type   \ descriptor for the item type
  179:  cell%    field item-offset \ offset in stack items, 0 for the deepest element
  180:  cell%	  field item-first  \ true if this is the first occurence of the item
  181: end-struct item%
  182: 
  183: struct%
  184:     cell% 2* field type-c-name
  185:     cell%    field type-stack \ default stack
  186:     cell%    field type-size  \ size of type in stack items
  187:     cell%    field type-fetch \ xt of fetch code generator ( item -- )
  188:     cell%    field type-store \ xt of store code generator ( item -- )
  189: end-struct type%
  190: 
  191: struct%
  192:     cell%    field register-number
  193:     cell%    field register-type \ pointer to type
  194:     cell% 2* field register-name \ c name
  195: end-struct register%
  196: 
  197: struct%
  198:     cell% 2* field ss-registers  \ addr u; ss-registers[0] is TOS
  199:                                  \ 0 means: use memory
  200:     cell%    field ss-offset     \ stack pointer offset: sp[-offset] is TOS
  201: end-struct ss% \ stack-state
  202: 
  203: struct%
  204:     cell%              field state-number
  205:     cell% max-stacks * field state-sss
  206: end-struct state%
  207: 
  208: variable next-stack-number 0 next-stack-number !
  209: create stacks max-stacks cells allot \ array of stacks
  210: 256 constant max-registers
  211: create registers max-registers cells allot \ array of registers
  212: variable nregisters 0 nregisters ! \ number of registers
  213: variable next-state-number 0 next-state-number ! \ next state number
  214: 
  215: : stack-in-index ( in-size item -- in-index )
  216:     item-offset @ - 1- ;
  217: 
  218: : inst-in-index ( in-size item -- in-index )
  219:     nip dup item-offset @ swap item-type @ type-size @ + 1- ;
  220: 
  221: : make-stack ( addr-ptr u1 type "stack-name" -- )
  222:     next-stack-number @ max-stacks < s" too many stacks" ?print-error
  223:     create stack% %allot >r
  224:     r@ stacks next-stack-number @ th !
  225:     next-stack-number @ r@ stack-number !
  226:     1 next-stack-number +!
  227:     r@ stack-type !
  228:     save-mem r@ stack-pointer 2! 
  229:     ['] stack-in-index r@ stack-in-index-xt !
  230:     ['] noop r@ stack-access-transform !
  231:     rdrop ;
  232: 
  233: : map-stacks { xt -- }
  234:     \ perform xt for all stacks
  235:     next-stack-number @ 0 +do
  236: 	stacks i th @ xt execute
  237:     loop ;
  238: 
  239: : map-stacks1 { xt -- }
  240:     \ perform xt for all stacks except inst-stream
  241:     next-stack-number @ 1 +do
  242: 	stacks i th @ xt execute
  243:     loop ;
  244: 
  245: \ stack items
  246: 
  247: : init-item ( addr u addr1 -- )
  248:     \ initialize item at addr1 with name addr u
  249:     \ !! remove stack prefix
  250:     dup item% %size erase
  251:     item-name 2! ;
  252: 
  253: : map-items { addr end xt -- }
  254:     \ perform xt for all items in array addr...end
  255:     end addr ?do
  256: 	i xt execute
  257:     item% %size +loop ;
  258: 
  259: \ types
  260: 
  261: : print-type-prefix ( type -- )
  262:     body> >head name>string type ;
  263: 
  264: \ various variables for storing stuff of one primitive
  265: 
  266: struct%
  267:     cell% 2* field prim-name
  268:     cell% 2* field prim-wordset
  269:     cell% 2* field prim-c-name
  270:     cell% 2* field prim-doc
  271:     cell% 2* field prim-c-code
  272:     cell% 2* field prim-forth-code
  273:     cell% 2* field prim-stack-string
  274:     cell%    field prim-num            \ ordinal number
  275:     cell%    field prim-items-wordlist \ unique items
  276:     item% max-effect * field prim-effect-in
  277:     item% max-effect * field prim-effect-out
  278:     cell%    field prim-effect-in-end
  279:     cell%    field prim-effect-out-end
  280:     cell% max-stacks * field prim-stacks-in  \ number of in items per stack
  281:     cell% max-stacks * field prim-stacks-out \ number of out items per stack
  282: end-struct prim%
  283: 
  284: : make-prim ( -- prim )
  285:     prim% %alloc { p }
  286:     s" " p prim-doc 2! s" " p prim-forth-code 2! s" " p prim-wordset 2!
  287:     p ;
  288: 
  289: 0 value prim     \ in combined prims either combined or a part
  290: 0 value combined \ in combined prims the combined prim
  291: variable in-part \ true if processing a part
  292:  in-part off
  293: 0 value state-in  \ state on entering prim
  294: 0 value state-out \ state on exiting prim
  295: 0 value state-default  \ canonical state at bb boundaries
  296: 
  297: : prim-context ( ... p xt -- ... )
  298:     \ execute xt with prim set to p
  299:     prim >r
  300:     swap to prim
  301:     catch
  302:     r> to prim
  303:     throw ;
  304: 
  305: 1000 constant max-combined
  306: create combined-prims max-combined cells allot
  307: variable num-combined
  308: variable part-num \ current part number during process-combined
  309: 
  310: : map-combined { xt -- }
  311:     \ perform xt for all components of the current combined instruction
  312:     num-combined @ 0 +do
  313: 	combined-prims i th @ xt execute
  314:     loop ;
  315: 
  316: table constant combinations
  317:   \ the keys are the sequences of pointers to primitives
  318: 
  319: create current-depth max-stacks cells allot
  320: create max-depth     max-stacks cells allot
  321: create min-depth     max-stacks cells allot
  322: 
  323: create sp-update-in max-stacks cells allot
  324: \ where max-depth occured the first time
  325: create max-depths max-stacks max-combined 1+ * cells allot
  326: \ maximum depth at start of each part: array[parts] of array[stack]
  327: create max-back-depths max-stacks max-combined 1+ * cells allot
  328: \ maximun depth from end of the combination to the start of the each part
  329: 
  330: : s-c-max-depth ( nstack ncomponent -- addr )
  331:     max-stacks * + cells max-depths + ;
  332: 
  333: : s-c-max-back-depth ( nstack ncomponent -- addr )
  334:     max-stacks * + cells max-back-depths + ;
  335: 
  336: wordlist constant primitives
  337: 
  338: : create-prim ( prim -- )
  339:     dup prim-name 2@ primitives ['] constant insert-wordlist ;
  340: 
  341: : stack-in ( stack -- addr )
  342:     \ address of number of stack items in effect in
  343:     stack-number @ cells prim prim-stacks-in + ;
  344: 
  345: : stack-out ( stack -- addr )
  346:     \ address of number of stack items in effect out
  347:     stack-number @ cells prim prim-stacks-out + ;
  348: 
  349: \ global vars
  350: variable c-line
  351: 2variable c-filename
  352: variable name-line
  353: 2variable name-filename
  354: 2variable last-name-filename
  355: Variable function-number 0 function-number !
  356: Variable function-old 0 function-old !
  357: : function-diff ( n -- )
  358:     ." GROUPADD(" function-number @ function-old @ - 0 .r ." )" cr
  359:     function-number @ function-old ! ;
  360: : forth-fdiff ( -- )
  361:     function-number @ function-old @ - 0 .r ."  groupadd" cr
  362:     function-number @ function-old ! ;
  363: 
  364: \ a few more set ops
  365: 
  366: : bit-equivalent ( w1 w2 -- w3 )
  367:  xor invert ;
  368: 
  369: : complement ( set1 -- set2 )
  370:  empty ['] bit-equivalent binary-set-operation ;
  371: 
  372: \ forward declaration for inst-stream (breaks cycle in definitions)
  373: defer inst-stream-f ( -- stack )
  374: 
  375: \ stack access stuff
  376: 
  377: : normal-stack-access0 { n stack -- }
  378:     \ n has the ss-offset already applied (see ...-access1)
  379:     n stack stack-access-transform @ execute ." [" 0 .r ." ]" ;
  380: 
  381: : state-ss { stack state -- ss }
  382:     state state-sss stack stack-number @ th @ ;
  383: 
  384: : stack-reg { n stack state -- reg }
  385:     \ n is the index (TOS=0); reg is 0 if the access is to memory
  386:     stack state state-ss ss-registers 2@ n u> if ( addr ) \ in ss-registers?
  387: 	n th @
  388:     else
  389: 	drop 0
  390:     endif ;
  391: 
  392: : .reg ( reg -- )
  393:     register-name 2@ type ;
  394: 
  395: : stack-offset ( stack state -- n )
  396:     \ offset for stack in state
  397:     state-ss ss-offset @ ;
  398: 
  399: : normal-stack-access1 { n stack state -- }
  400:     n stack state stack-reg ?dup-if
  401: 	.reg exit
  402:     endif
  403:     stack stack-pointer 2@ type
  404:     n stack state stack-offset - stack normal-stack-access0 ;
  405: 
  406: : normal-stack-access ( n stack state -- )
  407:     over inst-stream-f = if
  408: 	." IMM_ARG(" normal-stack-access1 ." ," immarg ? ." )"
  409: 	1 immarg +!
  410:     else
  411: 	normal-stack-access1
  412:     endif ;
  413: 
  414: : stack-depth { stack -- n }
  415:     current-depth stack stack-number @ th @ ;
  416: 
  417: : part-stack-access { n stack -- }
  418:     \ print _<stack><x>, x=inst-stream? n : maxdepth-currentdepth-n-1
  419:     ." _" stack stack-pointer 2@ type
  420:     stack stack-number @ { stack# }
  421:     stack stack-depth n + { access-depth }
  422:     stack inst-stream-f = if
  423: 	access-depth
  424:     else
  425: 	combined prim-stacks-in stack# th @
  426: 	assert( dup max-depth stack# th @ = )
  427: 	access-depth - 1-
  428:     endif
  429:     0 .r ;
  430: 
  431: : part-stack-read { n stack -- }
  432:     stack stack-depth n + ( ndepth )
  433:     stack stack-number @ part-num @ s-c-max-depth @
  434: \    max-depth stack stack-number @ th @ ( ndepth nmaxdepth )
  435:     over <= if ( ndepth ) \ load from memory
  436: 	stack state-in normal-stack-access
  437:     else
  438: 	drop n stack part-stack-access
  439:     endif ;
  440: 
  441: : stack-diff ( stack -- n )
  442:     \ in-out
  443:     dup stack-in @ swap stack-out @ - ;
  444: 
  445: : part-stack-write { n stack -- }
  446:     stack stack-depth n +
  447:     stack stack-number @ part-num @ s-c-max-back-depth @
  448:     over <= if ( ndepth )
  449: 	stack combined ['] stack-diff prim-context -
  450: 	stack state-out normal-stack-access
  451:     else
  452: 	drop n stack part-stack-access
  453:     endif ;
  454: 
  455: : stack-read ( n stack -- )
  456:     \ print a stack access at index n of stack
  457:     in-part @ if
  458: 	part-stack-read
  459:     else
  460: 	state-in normal-stack-access
  461:     endif ;
  462: 
  463: : stack-write ( n stack -- )
  464:     \ print a stack access at index n of stack
  465:     in-part @ if
  466: 	part-stack-write
  467:     else
  468: 	state-out normal-stack-access
  469:     endif ;
  470: 
  471: : item-in-index { item -- n }
  472:     \ n is the index of item (in the in-effect)
  473:     item item-stack @ dup >r stack-in @ ( in-size r:stack )
  474:     item r> stack-in-index-xt @ execute ;
  475: 
  476: : item-stack-type-name ( item -- addr u )
  477:     item-stack @ stack-type @ type-c-name 2@ ;
  478: 
  479: : fetch-single ( item -- )
  480:     \ fetch a single stack item from its stack
  481:     >r
  482:     ." vm_" r@ item-stack-type-name type
  483:     ." 2" r@ item-type @ print-type-prefix ." ("
  484:     r@ item-in-index r@ item-stack @ stack-read ." ,"
  485:     r@ item-name 2@ type
  486:     ." );" cr
  487:     rdrop ; 
  488: 
  489: : fetch-double ( item -- )
  490:     \ fetch a double stack item from its stack
  491:     >r
  492:     ." vm_two"
  493:     r@ item-stack-type-name type ." 2"
  494:     r@ item-type @ print-type-prefix ." ("
  495:     r@ item-in-index r@ item-stack @ 2dup ." (Cell)" stack-read
  496:     ." , "                      -1 under+ ." (Cell)" stack-read
  497:     ." , " r@ item-name 2@ type
  498:     ." )" cr
  499:     rdrop ;
  500: 
  501: : same-as-in? ( item -- f )
  502:  \ f is true iff the offset and stack of item is the same as on input
  503:  >r
  504:  r@ item-first @ if
  505:      rdrop false exit
  506:  endif
  507:  r@ item-name 2@ prim prim-items-wordlist @ search-wordlist 0= abort" bug"
  508:  execute @
  509:  dup r@ =
  510:  if \ item first appeared in output
  511:    drop false
  512:  else
  513:    dup  item-stack  @ r@ item-stack  @ = 
  514:    swap item-offset @ r@ item-offset @ = and
  515:  endif
  516:  rdrop ;
  517: 
  518: : item-out-index ( item -- n )
  519:     \ n is the index of item (in the out-effect)
  520:     >r r@ item-stack @ stack-out @ r> item-offset @ - 1- ;
  521: 
  522: : really-store-single ( item -- )
  523:     >r
  524:     ." vm_"
  525:     r@ item-type @ print-type-prefix ." 2"
  526:     r@ item-stack-type-name type ." ("
  527:     r@ item-name 2@ type ." ,"
  528:     r@ item-out-index r@ item-stack @ stack-write ." );"
  529:     rdrop ;
  530: 
  531: : store-single { item -- }
  532:     item item-stack @ { stack }
  533:     store-optimization @ in-part @ 0= and item same-as-in? and
  534:     item item-in-index  stack state-in  stack-reg 0= and \  in in memory?
  535:     item item-out-index stack state-out stack-reg 0= and \ out in memory?
  536:     0= if
  537: 	item really-store-single cr
  538:     endif ;
  539: 
  540: : store-double ( item -- )
  541: \ !! store optimization is not performed, because it is not yet needed
  542:  >r
  543:  ." vm_"
  544:  r@ item-type @ print-type-prefix ." 2two"
  545:  r@ item-stack-type-name type ." ("
  546:  r@ item-name 2@ type ." , "
  547:  r@ item-out-index r@ item-stack @ 2dup stack-write
  548:  ." , "                       -1 under+ stack-write
  549:  ." )" cr
  550:  rdrop ;
  551: 
  552: : single ( -- xt1 xt2 n )
  553:     ['] fetch-single ['] store-single 1 ;
  554: 
  555: : double ( -- xt1 xt2 n )
  556:     ['] fetch-double ['] store-double 2 ;
  557: 
  558: : s, ( addr u -- )
  559: \ allocate a string
  560:  here swap dup allot move ;
  561: 
  562: wordlist constant prefixes
  563: 
  564: : declare ( addr "name" -- )
  565: \ remember that there is a stack item at addr called name
  566:  create , ;
  567: 
  568: : !default ( w addr -- )
  569:     dup @ if
  570: 	2drop \ leave nonzero alone
  571:     else
  572: 	!
  573:     endif ;
  574: 
  575: : create-type { addr u xt1 xt2 n stack -- } ( "prefix" -- )
  576:     \ describes a type
  577:     \ addr u specifies the C type name
  578:     \ stack effect entries of the type start with prefix
  579:     create type% %allot >r
  580:     addr u save-mem r@ type-c-name 2!
  581:     xt1   r@ type-fetch !
  582:     xt2   r@ type-store !
  583:     n     r@ type-size !
  584:     stack r@ type-stack !
  585:     rdrop ;
  586: 
  587: : type-prefix ( addr u xt1 xt2 n stack "prefix" -- )
  588:     get-current >r prefixes set-current
  589:     create-type r> set-current
  590: does> ( item -- )
  591:     \ initialize item
  592:     { item typ }
  593:     typ item item-type !
  594:     typ type-stack @ item item-stack !default
  595:     item item-name 2@ prim prim-items-wordlist @ search-wordlist 0= if
  596: 	item item-name 2@ nextname item declare
  597: 	item item-first on
  598: 	\ typ type-c-name 2@ type space type  ." ;" cr
  599:     else
  600: 	drop
  601: 	item item-first off
  602:     endif ;
  603: 
  604: : execute-prefix ( item addr1 u1 -- )
  605:     \ execute the word ( item -- ) associated with the longest prefix
  606:     \ of addr1 u1
  607:     0 swap ?do
  608: 	dup i prefixes search-wordlist
  609: 	if \ ok, we have the type ( item addr1 xt )
  610: 	    nip execute
  611: 	    UNLOOP EXIT
  612: 	endif
  613: 	-1 s+loop
  614:     \ we did not find a type, abort
  615:     false s" unknown prefix" ?print-error ;
  616: 
  617: : declaration ( item -- )
  618:     dup item-name 2@ execute-prefix ;
  619: 
  620: : declaration-list ( addr1 addr2 -- )
  621:     ['] declaration map-items ;
  622: 
  623: : declarations ( -- )
  624:  wordlist dup prim prim-items-wordlist ! set-current
  625:  prim prim-effect-in prim prim-effect-in-end @ declaration-list
  626:  prim prim-effect-out prim prim-effect-out-end @ declaration-list ;
  627: 
  628: : print-declaration { item -- }
  629:     item item-first @ if
  630: 	item item-type @ type-c-name 2@ type space
  631: 	item item-name 2@ type ." ;" cr
  632:     endif ;
  633: 
  634: : print-declarations ( -- )
  635:     prim prim-effect-in  prim prim-effect-in-end  @ ['] print-declaration map-items
  636:     prim prim-effect-out prim prim-effect-out-end @ ['] print-declaration map-items ;
  637:     
  638: : stack-prefix ( stack "prefix" -- )
  639:     get-current >r prefixes set-current
  640:     name tuck nextname create ( stack length ) 2,
  641:     r> set-current
  642: does> ( item -- )
  643:     2@ { item stack prefix-length }
  644:     item item-name 2@ prefix-length /string item item-name 2!
  645:     stack item item-stack !
  646:     item declaration ;
  647: 
  648: \ types pointed to by stacks for use in combined prims
  649: \ !! output-c-combined shouldn't use these names!
  650: : stack-type-name ( addr u "name" -- )
  651:     single 0 create-type ;
  652: 
  653: wordlist constant type-names \ this is here just to meet the requirement
  654:                     \ that a type be a word; it is never used for lookup
  655: 
  656: : define-type ( addr u -- xt )
  657:     \ define single type with name addr u, without stack
  658:     get-current type-names set-current >r
  659:     2dup nextname stack-type-name
  660:     r> set-current
  661:     latestxt ;
  662: 
  663: : stack ( "name" "stack-pointer" "type" -- )
  664:     \ define stack
  665:     name { d: stack-name }
  666:     name { d: stack-pointer }
  667:     name { d: stack-type }
  668:     stack-type define-type
  669:     stack-pointer rot >body stack-name nextname make-stack ;
  670: 
  671: stack inst-stream IP Cell
  672: ' inst-in-index inst-stream stack-in-index-xt !
  673: ' inst-stream <is> inst-stream-f
  674: \ !! initialize stack-in and stack-out
  675: 
  676: \ registers
  677: 
  678: : make-register ( type addr u -- )
  679:     \ define register with type TYPE and name ADDR U.
  680:     nregisters @ max-registers < s" too many registers" ?print-error
  681:     2dup nextname create register% %allot >r
  682:     r@ register-name 2!
  683:     r@ register-type !
  684:     nregisters @ r@ register-number !
  685:     1 nregisters +!
  686:     rdrop ;
  687: 
  688: : register ( "name" "type" -- )
  689:     \ define register
  690:     name { d: reg-name }
  691:     name { d: reg-type }
  692:     reg-type define-type >body
  693:     reg-name make-register ;
  694: 
  695: \ stack-states
  696: 
  697: : stack-state ( a-addr u uoffset "name" -- )
  698:     create ss% %allot >r
  699:     r@ ss-offset !
  700:     r@ ss-registers 2!
  701:     rdrop ;
  702: 
  703: 0 0 0 stack-state default-ss
  704: 
  705: \ state
  706: 
  707: : state ( "name" -- )
  708:     \ create a state initialized with default-sss
  709:     create state% %allot { s }
  710:     next-state-number @ s state-number ! 1 next-state-number +!
  711:     max-stacks 0 ?do
  712: 	default-ss s state-sss i th !
  713:     loop ;
  714: 
  715: : set-ss ( ss stack state -- )
  716:     state-sss swap stack-number @ th ! ;
  717: 
  718: \ offset computation
  719: \ the leftmost (i.e. deepest) item has offset 0
  720: \ the rightmost item has the highest offset
  721: 
  722: : compute-offset { item xt -- }
  723:     \ xt specifies in/out; update stack-in/out and set item-offset
  724:     item item-type @ type-size @
  725:     item item-stack @ xt execute dup @ >r +!
  726:     r> item item-offset ! ;
  727: 
  728: : compute-offset-in ( addr1 addr2 -- )
  729:     ['] stack-in compute-offset ;
  730: 
  731: : compute-offset-out ( addr1 addr2 -- )
  732:     ['] stack-out compute-offset ;
  733: 
  734: : compute-offsets ( -- )
  735:     prim prim-stacks-in  max-stacks cells erase
  736:     prim prim-stacks-out max-stacks cells erase
  737:     prim prim-effect-in  prim prim-effect-in-end  @ ['] compute-offset-in  map-items
  738:     prim prim-effect-out prim prim-effect-out-end @ ['] compute-offset-out map-items
  739:     inst-stream stack-out @ 0= s" # can only be on the input side" ?print-error ;
  740: 
  741: : process-simple ( -- )
  742:     prim prim { W^ key } key cell
  743:     combinations ['] constant insert-wordlist
  744:     declarations compute-offsets
  745:     output @ execute ;
  746: 
  747: : stack-state-items ( stack state -- n )
  748:     state-ss ss-registers 2@ nip ;
  749: 
  750: : unused-stack-items { stack -- n-in n-out }
  751:     \ n-in  are the stack items in state-in  not used    by prim
  752:     \ n-out are the stack items in state-out not written by prim
  753:     stack state-in  stack-state-items stack stack-in  @ - 0 max
  754:     stack state-out stack-state-items stack stack-out @ - 0 max ;
  755: 
  756: : spill-stack { stack -- }
  757:     \ spill regs of state-in that are not used by prim and are not in state-out
  758:     stack state-in stack-offset { offset }
  759:     stack state-in stack-state-items ( items )
  760:     dup stack unused-stack-items - - +do
  761: 	\ loop through the bottom items
  762: 	stack stack-pointer 2@ type
  763: 	i offset - stack normal-stack-access0 ."  = "
  764: 	i stack state-in normal-stack-access1 ." ;" cr
  765:     loop ;
  766: 
  767: : spill-state ( -- )
  768:     ['] spill-stack map-stacks1 ;
  769: 
  770: : fill-stack { stack -- }
  771:     stack state-out stack-offset { offset }
  772:     stack state-out stack-state-items ( items )
  773:     dup stack unused-stack-items - + +do
  774: 	\ loop through the bottom items
  775: 	i stack state-out normal-stack-access1 ."  = "
  776: 	stack stack-pointer 2@ type
  777: 	i offset - stack normal-stack-access0 ." ;" cr
  778:     loop ;
  779: 
  780: : fill-state ( -- )
  781:     \ !! inst-stream for prefetching?
  782:     ['] fill-stack map-stacks1 ;
  783: 
  784: : fetch ( addr -- )
  785:     dup item-type @ type-fetch @ execute ;
  786: 
  787: : fetches ( -- )
  788:     prim prim-effect-in prim prim-effect-in-end @ ['] fetch map-items ;
  789: 
  790: : reg-reg-move ( reg-from reg-to -- )
  791:     2dup = if
  792: 	2drop
  793:     else
  794: 	.reg ."  = " .reg ." ;" cr
  795:     endif ;
  796: 
  797: : stack-bottom-reg { n stack state -- reg }
  798:     stack state stack-state-items n - 1- stack state stack-reg ;
  799: 
  800: : stack-moves { stack -- }
  801:     \ generate moves between registers in state-in/state-out that are
  802:     \ not spilled or consumed/produced by prim.
  803:     \ !! this works only for a simple stack cache, not e.g., for
  804:     \ rotating stack caches, or registers shared between stacks (the
  805:     \ latter would also require a change in interface)
  806:     \ !! maybe place this after NEXT_P1?
  807:     stack unused-stack-items 2dup < if ( n-in n-out )
  808: 	\ move registers from 0..n_in-1 to n_out-n_in..n_out-1
  809: 	over - { diff } ( n-in )
  810: 	-1 swap 1- -do
  811: 	    i stack state-in stack-bottom-reg ( reg-from )
  812: 	    i diff + stack state-out stack-bottom-reg reg-reg-move
  813: 	1 -loop
  814:     else
  815: 	\ move registers from n_in-n_out..n_in-1 to 0..n_out-1
  816: 	swap over - { diff } ( n-out )
  817: 	0 +do
  818: 	    i diff + stack state-in stack-bottom-reg ( reg-from )
  819: 	    i stack state-out stack-bottom-reg reg-reg-move
  820: 	loop
  821:     endif ;
  822: 
  823: : stack-update-transform ( n1 stack -- n2 )
  824:     \ n2 is the number by which the stack pointer should be
  825:     \ incremented to pop n1 items
  826:     stack-access-transform @ dup >r execute
  827:     0 r> execute - ;
  828: 
  829: : stack-pointer-update { stack -- }
  830:     \ and moves
  831:     \ stacks grow downwards
  832:     stack stack-diff ( in-out )
  833:     stack state-in  stack-offset -
  834:     stack state-out stack-offset + ( [in-in_offset]-[out-out_offset] )
  835:     ?dup-if \ this check is not necessary, gcc would do this for us
  836: 	stack inst-stream = if
  837: 	    ." INC_IP(" 0 .r ." );" cr
  838: 	else
  839: 	    stack stack-pointer 2@ type ."  += "
  840: 	    stack stack-update-transform 0 .r ." ;" cr
  841: 	endif
  842:     endif
  843:     stack stack-moves ;
  844: 
  845: : stack-pointer-updates ( -- )
  846:     ['] stack-pointer-update map-stacks ;
  847: 
  848: : store ( item -- )
  849: \ f is true if the item should be stored
  850: \ f is false if the store is probably not necessary
  851:  dup item-type @ type-store @ execute ;
  852: 
  853: : stores ( -- )
  854:     prim prim-effect-out prim prim-effect-out-end @ ['] store map-items ;
  855: 
  856: : print-debug-arg { item -- }
  857:     ." fputs(" quote space item item-name 2@ type ." =" quote ." , vm_out); "
  858:     ." printarg_" item item-type @ print-type-prefix
  859:     ." (" item item-name 2@ type ." );" cr ;
  860:     
  861: : print-debug-args ( -- )
  862:     ." #ifdef VM_DEBUG" cr
  863:     ." if (vm_debug) {" cr
  864:     prim prim-effect-in prim prim-effect-in-end @ ['] print-debug-arg map-items
  865: \    ." fputc('\n', vm_out);" cr
  866:     ." }" cr
  867:     ." #endif" cr ;
  868: 
  869: : print-debug-result { item -- }
  870:     item item-first @ if
  871: 	item print-debug-arg
  872:     endif ;
  873: 
  874: : print-debug-results ( -- )
  875:     cr
  876:     ." #ifdef VM_DEBUG" cr
  877:     ." if (vm_debug) {" cr
  878:     ." fputs(" quote ."  -- " quote ." , vm_out); "
  879:     prim prim-effect-out prim prim-effect-out-end @ ['] print-debug-result map-items
  880:     ." fputc('\n', vm_out);" cr
  881:     ." }" cr
  882:     ." #endif" cr ;
  883: 
  884: : output-super-end ( -- )
  885:     prim prim-c-code 2@ s" SET_IP" search if
  886: 	." SUPER_END;" cr
  887:     endif
  888:     2drop ;
  889: 
  890: : output-nextp2 ( -- )
  891:     ." NEXT_P2;" cr ;
  892: 
  893: variable tail-nextp2 \ xt to execute for printing NEXT_P2 in INST_TAIL
  894: ' output-nextp2 tail-nextp2 !
  895: 
  896: : output-label2 ( -- )
  897:     ." LABEL2(" prim prim-c-name 2@ type ." )" cr
  898:     ." NEXT_P2;" cr ;
  899: 
  900: : output-c-tail1 { xt -- }
  901:     \ the final part of the generated C code, with xt printing LABEL2 or not.
  902:     output-super-end
  903:     print-debug-results
  904:     ." NEXT_P1;" cr
  905:     stores
  906:     fill-state 
  907:     xt execute ;
  908: 
  909: : output-c-tail1-no-stores { xt -- }
  910:     \ the final part of the generated C code for combinations
  911:     output-super-end
  912:     ." NEXT_P1;" cr
  913:     fill-state 
  914:     xt execute ;
  915: 
  916: : output-c-tail ( -- )
  917:     tail-nextp2 @ output-c-tail1 ;
  918: 
  919: : output-c-tail2 ( -- )
  920:     ['] output-label2 output-c-tail1 ;
  921: 
  922: : output-c-tail-no-stores ( -- )
  923:     tail-nextp2 @ output-c-tail1-no-stores ;
  924: 
  925: : output-c-tail2-no-stores ( -- )
  926:     ['] output-label2 output-c-tail1-no-stores ;
  927: 
  928: : type-c-code ( c-addr u xt -- )
  929:     \ like TYPE, but replaces "INST_TAIL;" with tail code produced by xt
  930:     { xt }
  931:     ." {" cr
  932:     ." #line " c-line @ . quote c-filename 2@ type quote cr
  933:     begin ( c-addr1 u1 )
  934: 	2dup s" INST_TAIL;" search
  935:     while ( c-addr1 u1 c-addr3 u3 )
  936: 	2dup 2>r drop nip over - type
  937: 	xt execute
  938: 	2r> 10 /string
  939: 	\ !! resync #line missing
  940:     repeat
  941:     2drop type
  942:     ." #line " out-nls @ 2 + . quote out-filename 2@ type quote cr
  943:     ." }" cr ;
  944: 
  945: : print-entry ( -- )
  946:     ." LABEL(" prim prim-c-name 2@ type ." )" ;
  947:     
  948: : output-c ( -- ) 
  949:     print-entry ."  /* " prim prim-name 2@ type ."  ( " prim prim-stack-string 2@ type ." ) */" cr
  950:     ." /* " prim prim-doc 2@ type ."  */" cr
  951:     ." NAME(" quote prim prim-name 2@ type quote ." )" cr \ debugging
  952:     ." {" cr
  953:     ." DEF_CA" cr
  954:     print-declarations
  955:     ." NEXT_P0;" cr
  956:     spill-state
  957:     fetches
  958:     print-debug-args
  959:     stack-pointer-updates
  960:     prim prim-c-code 2@ ['] output-c-tail type-c-code
  961:     output-c-tail2
  962:     ." }" cr
  963:     cr
  964: ;
  965: 
  966: : disasm-arg { item -- }
  967:     item item-stack @ inst-stream = if
  968: 	." {" cr
  969: 	item print-declaration
  970: 	item fetch
  971: 	item print-debug-arg
  972: 	." }" cr
  973:     endif ;
  974: 
  975: : disasm-args ( -- )
  976:     prim prim-effect-in prim prim-effect-in-end @ ['] disasm-arg map-items ;
  977: 
  978: : output-disasm ( -- )
  979:     \ generate code for disassembling VM instructions
  980:     ." if (VM_IS_INST(*ip, " function-number @ 0 .r ." )) {" cr
  981:     ."   fputs(" quote prim prim-name 2@ type quote ." , vm_out);" cr
  982:     disasm-args
  983:     ."   ip += " inst-stream stack-in @ 1+ 0 .r ." ;" cr
  984:     ."   goto _endif_;" cr
  985:     ." }" cr ;
  986: 
  987: : output-profile ( -- )
  988:     \ generate code for postprocessing the VM block profile stuff
  989:     ." if (VM_IS_INST(*ip, " function-number @ 0 .r ." )) {" cr
  990:     ."   add_inst(b, " quote prim prim-name 2@ type quote ." );" cr
  991:     ."   ip += " inst-stream stack-in @ 1+ 0 .r ." ;" cr
  992:     prim prim-c-code 2@  s" SET_IP"    search nip nip
  993:     prim prim-c-code 2@  s" SUPER_END" search nip nip or if
  994: 	."   return;" cr
  995:     else
  996: 	."   goto _endif_;" cr
  997:     endif
  998:     ." }" cr ;
  999: 
 1000: : output-profile-part ( p )
 1001:     ."   add_inst(b, " quote
 1002:     prim-name 2@ type
 1003:     quote ." );" cr ;
 1004:     
 1005: : output-profile-combined ( -- )
 1006:     \ generate code for postprocessing the VM block profile stuff
 1007:     ." if (VM_IS_INST(*ip, " function-number @ 0 .r ." )) {" cr
 1008:     ['] output-profile-part map-combined
 1009:     ."   ip += " inst-stream stack-in @ 1+ 0 .r ." ;" cr
 1010:     combined-prims num-combined @ 1- th @ prim-c-code 2@  s" SET_IP"    search nip nip
 1011:     combined-prims num-combined @ 1- th @ prim-c-code 2@  s" SUPER_END" search nip nip or if
 1012: 	."   return;" cr
 1013:     else
 1014: 	."   goto _endif_;" cr
 1015:     endif
 1016:     ." }" cr ;
 1017: 
 1018: : prim-branch? { prim -- f }
 1019:     \ true if prim is a branch or super-end
 1020:     prim prim-c-code 2@  s" SET_IP" search nip nip 0<> ;
 1021: 
 1022: : output-superend ( -- )
 1023:     \ output flag specifying whether the current word ends a dynamic superinst
 1024:     prim prim-branch?
 1025:     prim prim-c-code 2@  s" SUPER_END" search nip nip 0<> or
 1026:     prim prim-c-code 2@  s" SUPER_CONTINUE" search nip nip 0= and
 1027:     negate 0 .r ." , /* " prim prim-name 2@ type ."  */" cr ;
 1028: 
 1029: : gen-arg-parm { item -- }
 1030:     item item-stack @ inst-stream = if
 1031: 	." , " item item-type @ type-c-name 2@ type space
 1032: 	item item-name 2@ type
 1033:     endif ;
 1034: 
 1035: : gen-args-parm ( -- )
 1036:     prim prim-effect-in prim prim-effect-in-end @ ['] gen-arg-parm map-items ;
 1037: 
 1038: : gen-arg-gen { item -- }
 1039:     item item-stack @ inst-stream = if
 1040: 	."   genarg_" item item-type @ print-type-prefix
 1041:         ." (ctp, " item item-name 2@ type ." );" cr
 1042:     endif ;
 1043: 
 1044: : gen-args-gen ( -- )
 1045:     prim prim-effect-in prim prim-effect-in-end @ ['] gen-arg-gen map-items ;
 1046: 
 1047: : output-gen ( -- )
 1048:     \ generate C code for generating VM instructions
 1049:     ." void gen_" prim prim-c-name 2@ type ." (Inst **ctp" gen-args-parm ." )" cr
 1050:     ." {" cr
 1051:     ."   gen_inst(ctp, vm_prim[" function-number @ 0 .r ." ]);" cr
 1052:     gen-args-gen
 1053:     ." }" cr ;
 1054: 
 1055: : stack-used? { stack -- f }
 1056:     stack stack-in @ stack stack-out @ or 0<> ;
 1057: 
 1058: : output-funclabel ( -- )
 1059:   ." &I_" prim prim-c-name 2@ type ." ," cr ;
 1060: 
 1061: : output-forthname ( -- )
 1062:   '" emit prim prim-name 2@ type '" emit ." ," cr ;
 1063: 
 1064: \  : output-c-func ( -- )
 1065: \  \ used for word libraries
 1066: \      ." Cell * I_" prim prim-c-name 2@ type ." (Cell *SP, Cell **FP)      /* " prim prim-name 2@ type
 1067: \      ."  ( " prim prim-stack-string 2@ type ."  ) */" cr
 1068: \      ." /* " prim prim-doc 2@ type ."  */" cr
 1069: \      ." NAME(" quote prim prim-name 2@ type quote ." )" cr
 1070: \      \ debugging
 1071: \      ." {" cr
 1072: \      print-declarations
 1073: \      \ !! don't know what to do about that
 1074: \      inst-stream  stack-used? IF ." Cell *ip=IP;" cr THEN
 1075: \      data-stack   stack-used? IF ." Cell *sp=SP;" cr THEN
 1076: \      fp-stack     stack-used? IF ." Cell *fp=*FP;" cr THEN
 1077: \      return-stack stack-used? IF ." Cell *rp=*RP;" cr THEN
 1078: \      spill-state
 1079: \      fetches
 1080: \      stack-pointer-updates
 1081: \      fp-stack   stack-used? IF ." *FP=fp;" cr THEN
 1082: \      ." {" cr
 1083: \      ." #line " c-line @ . quote c-filename 2@ type quote cr
 1084: \      prim prim-c-code 2@ type
 1085: \      ." }" cr
 1086: \      stores
 1087: \      fill-state
 1088: \      ." return (sp);" cr
 1089: \      ." }" cr
 1090: \      cr ;
 1091: 
 1092: : output-label ( -- )  
 1093:     ." INST_ADDR(" prim prim-c-name 2@ type ." )," cr ;
 1094: 
 1095: : output-alias ( -- ) 
 1096:     ( primitive-number @ . ." alias " ) ." Primitive " prim prim-name 2@ type cr ;
 1097: 
 1098: : output-c-prim-num ( -- )
 1099:     ." N_" prim prim-c-name 2@ type ." ," cr ;
 1100: 
 1101: : output-forth ( -- )  
 1102:     prim prim-forth-code @ 0=
 1103:     IF    	\ output-alias
 1104: 	\ this is bad for ec: an alias is compiled if tho word does not exist!
 1105: 	\ JAW
 1106:     ELSE  ." : " prim prim-name 2@ type ."   ( "
 1107: 	prim prim-stack-string 2@ type ." )" cr
 1108: 	prim prim-forth-code 2@ type cr
 1109:     THEN ;
 1110: 
 1111: : output-tag-file ( -- )
 1112:     name-filename 2@ last-name-filename 2@ compare if
 1113: 	name-filename 2@ last-name-filename 2!
 1114: 	#ff emit cr
 1115: 	name-filename 2@ type
 1116: 	." ,0" cr
 1117:     endif ;
 1118: 
 1119: : output-tag ( -- )
 1120:     output-tag-file
 1121:     prim prim-name 2@ 1+ type
 1122:     127 emit
 1123:     space prim prim-name 2@ type space
 1124:     1 emit
 1125:     name-line @ 0 .r
 1126:     ." ,0" cr ;
 1127: 
 1128: : output-vi-tag ( -- )
 1129:     name-filename 2@ type #tab emit
 1130:     prim prim-name 2@ type #tab emit
 1131:     ." /^" prim prim-name 2@ type ."  *(/" cr ;
 1132: 
 1133: [IFDEF] documentation
 1134: : register-doc ( -- )
 1135:     prim prim-name 2@ documentation ['] create insert-wordlist
 1136:     prim prim-name 2@ 2,
 1137:     prim prim-stack-string 2@ condition-stack-effect 2,
 1138:     prim prim-wordset 2@ 2,
 1139:     prim prim-c-name 2@ condition-pronounciation 2,
 1140:     prim prim-doc 2@ 2, ;
 1141: [THEN]
 1142: 
 1143: 
 1144: \ combining instructions
 1145: 
 1146: \ The input should look like this:
 1147: 
 1148: \ lit_+ = lit +
 1149: 
 1150: \ The output should look like this:
 1151: 
 1152: \  I_lit_+:
 1153: \  {
 1154: \  DEF_CA
 1155: \  Cell _x_ip0;
 1156: \  Cell _x_sp0;
 1157: \  Cell _x_sp1;
 1158: \  NEXT_P0;
 1159: \  _x_ip0 = (Cell) IPTOS;
 1160: \  _x_sp0 = (Cell) spTOS;
 1161: \  INC_IP(1);
 1162: \  /* sp += 0; */
 1163: \  /* lit ( #w -- w ) */
 1164: \  /*  */
 1165: \  NAME("lit")
 1166: \  {
 1167: \  Cell w;
 1168: \  w = (Cell) _x_ip0;
 1169: \  #ifdef VM_DEBUG
 1170: \  if (vm_debug) {
 1171: \  fputs(" w=", vm_out); printarg_w (w);
 1172: \  fputc('\n', vm_out);
 1173: \  }
 1174: \  #endif
 1175: \  {
 1176: \  #line 136 "./prim"
 1177: \  }
 1178: \  _x_sp1 = (Cell)w;
 1179: \  }
 1180: \  I_plus:	/* + ( n1 n2 -- n ) */
 1181: \  /*  */
 1182: \  NAME("+")
 1183: \  {
 1184: \  DEF_CA
 1185: \  Cell n1;
 1186: \  Cell n2;
 1187: \  Cell n;
 1188: \  NEXT_P0;
 1189: \  n1 = (Cell) _x_sp0;
 1190: \  n2 = (Cell) _x_sp1;
 1191: \  #ifdef VM_DEBUG
 1192: \  if (vm_debug) {
 1193: \  fputs(" n1=", vm_out); printarg_n (n1);
 1194: \  fputs(" n2=", vm_out); printarg_n (n2);
 1195: \  fputc('\n', vm_out);
 1196: \  }
 1197: \  #endif
 1198: \  {
 1199: \  #line 516 "./prim"
 1200: \  n = n1+n2;
 1201: \  }
 1202: \  _x_sp0 = (Cell)n;
 1203: \  }
 1204: \  NEXT_P1;
 1205: \  spTOS = (Cell)_x_sp0;
 1206: \  NEXT_P2;
 1207: 
 1208: : init-combined ( -- )
 1209:     prim to combined
 1210:     0 num-combined !
 1211:     current-depth max-stacks cells erase
 1212:     include-skipped-insts @ current-depth 0 th !
 1213:     max-depth     max-stacks cells erase
 1214:     min-depth     max-stacks cells erase
 1215:     prim prim-effect-in  prim prim-effect-in-end  !
 1216:     prim prim-effect-out prim prim-effect-out-end ! ;
 1217: 
 1218: : max! ( n addr -- )
 1219:     tuck @ max swap ! ;
 1220: 
 1221: : min! ( n addr -- )
 1222:     tuck @ min swap ! ;
 1223: 
 1224: : inst-stream-adjustment ( nstack -- n )
 1225:     \ number of stack items to add for each part
 1226:     0= include-skipped-insts @ and negate ;
 1227: 
 1228: : add-depths { p -- }
 1229:     \ combine stack effect of p with *-depths
 1230:     max-stacks 0 ?do
 1231: 	current-depth i th @
 1232: 	p prim-stacks-in  i th @ + i inst-stream-adjustment +
 1233: 	dup max-depth i th max!
 1234: 	p prim-stacks-out i th @ -
 1235: 	dup min-depth i th min!
 1236: 	current-depth i th !
 1237:     loop ;
 1238: 
 1239: : copy-maxdepths ( n -- )
 1240:     max-depth max-depths rot max-stacks * th max-stacks cells move ;
 1241: 
 1242: : add-prim ( addr u -- )
 1243:     \ add primitive given by "addr u" to combined-prims
 1244:     primitives search-wordlist s" unknown primitive" ?print-error
 1245:     execute { p }
 1246:     p combined-prims num-combined @ th !
 1247:     num-combined @ copy-maxdepths
 1248:     1 num-combined +!
 1249:     p add-depths
 1250:     num-combined @ copy-maxdepths ;
 1251: 
 1252: : compute-effects { q -- }
 1253:     \ compute the stack effects of q from the depths
 1254:     max-stacks 0 ?do
 1255: 	max-depth i th @ dup
 1256: 	q prim-stacks-in i th !
 1257: 	current-depth i th @ -
 1258: 	q prim-stacks-out i th !
 1259:     loop ;
 1260: 
 1261: : make-effect-items { stack# items effect-endp -- }
 1262:     \ effect-endp points to a pointer to the end of the current item-array
 1263:     \ and has to be updated
 1264:     stacks stack# th @ { stack }
 1265:     items 0 +do
 1266: 	effect-endp @ { item }
 1267: 	i 0 <# #s stack stack-pointer 2@ holds [char] _ hold #> save-mem
 1268: 	item item-name 2!
 1269: 	stack item item-stack !
 1270: 	stack stack-type @ item item-type !
 1271: 	i item item-offset !
 1272: 	item item-first on
 1273: 	item% %size effect-endp +!
 1274:     loop ;
 1275: 
 1276: : init-effects { q -- }
 1277:     \ initialize effects field for FETCHES and STORES
 1278:     max-stacks 0 ?do
 1279: 	i q prim-stacks-in  i th @ q prim-effect-in-end  make-effect-items
 1280: 	i q prim-stacks-out i th @ q prim-effect-out-end make-effect-items
 1281:     loop ;
 1282: 
 1283: : compute-stack-max-back-depths ( stack -- )
 1284:     stack-number @ { stack# }
 1285:     current-depth stack# th @ dup
 1286:     dup stack# num-combined @ s-c-max-back-depth !
 1287:     -1 num-combined @ 1- -do ( max-depth current-depth )
 1288: 	combined-prims i th @ { p }
 1289: 	p prim-stacks-out stack# th @ +
 1290: 	dup >r max r>
 1291: 	over stack# i s-c-max-back-depth !
 1292: 	p prim-stacks-in stack# th @ -
 1293: 	stack# inst-stream-adjustment -
 1294:     1 -loop
 1295:     assert( dup stack# inst-stream-adjustment negate = )
 1296:     assert( over max-depth stack# th @ = )
 1297:     2drop ;
 1298: 
 1299: : compute-max-back-depths ( -- )
 1300:     \ compute max-back-depths.
 1301:     \ assumes that current-depths is correct for the end of the combination
 1302:     ['] compute-stack-max-back-depths map-stacks ;
 1303: 
 1304: : process-combined ( -- )
 1305:     combined combined-prims num-combined @ cells
 1306:     combinations ['] constant insert-wordlist
 1307:     combined-prims num-combined @ 1- th ( last-part )
 1308:     @ prim-c-code 2@ prim prim-c-code 2! \ used by output-super-end
 1309:     prim compute-effects
 1310:     prim init-effects
 1311:     compute-max-back-depths
 1312:     output-combined perform ;
 1313: 
 1314: \ reprocessing (typically to generate versions for another cache states)
 1315: \ !! use prim-context
 1316: 
 1317: variable reprocessed-num 0 reprocessed-num !
 1318: 
 1319: : new-name ( -- c-addr u )
 1320:     reprocessed-num @ 0
 1321:     1 reprocessed-num +!
 1322:     <# #s 'p hold '_ hold #> save-mem ;
 1323: 
 1324: : reprocess-simple ( prim -- )
 1325:     to prim
 1326:     new-name prim prim-c-name 2!
 1327:     output @ execute ;
 1328: 
 1329: : lookup-prim ( c-addr u -- prim )
 1330:     primitives search-wordlist 0= -13 and throw execute ;
 1331: 
 1332: : state-prim1 { in-state out-state prim -- }
 1333:     in-state out-state state-default dup d= ?EXIT
 1334:     in-state  to state-in
 1335:     out-state to state-out
 1336:     prim reprocess-simple ;
 1337: 
 1338: : state-prim ( in-state out-state "name" -- )
 1339:     parse-word lookup-prim state-prim1 ;
 1340: 
 1341: \ reprocessing with default states
 1342: 
 1343: \ This is a simple scheme and should be generalized
 1344: \ assumes we only cache one stack and use simple states for that
 1345: 
 1346: 0 value cache-stack  \ stack that we cache
 1347: 2variable cache-states \ states of the cache, starting with the empty state
 1348: 
 1349: : compute-default-state-out ( n-in -- n-out )
 1350:     \ for the current prim
 1351:     cache-stack stack-in @ - 0 max
 1352:     cache-stack stack-out @ + cache-states 2@ nip 1- min ;
 1353: 
 1354: : gen-prim-states ( prim -- )
 1355:     to prim
 1356:     cache-states 2@ swap { states } ( nstates )
 1357:     cache-stack stack-in @ +do
 1358: 	states i th @
 1359: 	states i compute-default-state-out th @
 1360: 	prim state-prim1
 1361:     loop ;
 1362: 
 1363: : prim-states ( "name" -- )
 1364:     parse-word lookup-prim gen-prim-states ;
 1365: 
 1366: : gen-branch-states ( prim -- )
 1367:     \ generate versions that produce state-default; useful for branches
 1368:     to prim
 1369:     cache-states 2@ swap { states } ( nstates )
 1370:     cache-stack stack-in @ +do
 1371: 	states i th @ state-default prim state-prim1
 1372:     loop ;
 1373: 
 1374: : branch-states ( out-state "name" -- )
 1375:     parse-word lookup-prim gen-branch-states ;
 1376: 
 1377: \ producing state transitions
 1378: 
 1379: : gen-transitions ( "name" -- )
 1380:     parse-word lookup-prim { prim }
 1381:     cache-states 2@ { states nstates }
 1382:     nstates 0 +do
 1383: 	nstates 0 +do
 1384: 	    i j <> if
 1385: 		states i th @ states j th @ prim state-prim1
 1386: 	    endif
 1387: 	loop
 1388:     loop ;
 1389: 
 1390: \ C output
 1391: 
 1392: : print-item { n stack -- }
 1393:     \ print nth stack item name
 1394:     stack stack-type @ type-c-name 2@ type space
 1395:     ." MAYBE_UNUSED _" stack stack-pointer 2@ type n 0 .r ;
 1396: 
 1397: : print-declarations-combined ( -- )
 1398:     max-stacks 0 ?do
 1399: 	max-depth i th @ min-depth i th @ - 0 +do
 1400: 	    i stacks j th @ print-item ." ;" cr
 1401: 	loop
 1402:     loop ;
 1403: 
 1404: : part-fetches ( -- )
 1405:     fetches ;
 1406: 
 1407: : part-output-c-tail ( -- )
 1408:     print-debug-results
 1409:     stores ;
 1410: 
 1411: : output-combined-tail ( -- )
 1412:     part-output-c-tail
 1413:     in-part @ >r in-part off
 1414:     combined ['] output-c-tail-no-stores prim-context
 1415:     r> in-part ! ;
 1416: 
 1417: : part-stack-pointer-updates ( -- )
 1418:     next-stack-number @ 0 +do
 1419: 	i part-num @ 1+ s-c-max-depth @ dup
 1420: 	i num-combined @ s-c-max-depth @ =    \ final depth
 1421: 	swap i part-num @ s-c-max-depth @ <> \ just reached now
 1422: 	part-num @ 0= \ first part
 1423: 	or and if
 1424: 	    stacks i th @ stack-pointer-update
 1425: 	endif
 1426:     loop ;
 1427: 
 1428: : output-part ( p -- )
 1429:     to prim
 1430:     ." /* " prim prim-name 2@ type ."  ( " prim prim-stack-string 2@ type ." ) */" cr
 1431:     ." NAME(" quote prim prim-name 2@ type quote ." )" cr \ debugging
 1432:     ." {" cr
 1433:     print-declarations
 1434:     part-fetches
 1435:     print-debug-args
 1436:     combined ['] part-stack-pointer-updates prim-context
 1437:     1 part-num +!
 1438:     prim add-depths \ !! right place?
 1439:     prim prim-c-code 2@ ['] output-combined-tail type-c-code
 1440:     part-output-c-tail
 1441:     ." }" cr ;
 1442: 
 1443: : output-parts ( -- )
 1444:     prim >r in-part on
 1445:     current-depth max-stacks cells erase
 1446:     0 part-num !
 1447:     ['] output-part map-combined
 1448:     in-part off
 1449:     r> to prim ;
 1450: 
 1451: : output-c-combined ( -- )
 1452:     print-entry cr
 1453:     \ debugging messages just in parts
 1454:     ." {" cr
 1455:     ." DEF_CA" cr
 1456:     print-declarations-combined
 1457:     ." NEXT_P0;" cr
 1458:     spill-state
 1459:     \ fetches \ now in parts
 1460:     \ print-debug-args
 1461:     \ stack-pointer-updates now in parts
 1462:     output-parts
 1463:     output-c-tail2-no-stores
 1464:     ." }" cr
 1465:     cr ;
 1466: 
 1467: : output-forth-combined ( -- )
 1468: ;
 1469: 
 1470: 
 1471: \ peephole optimization rules
 1472: 
 1473: \ data for a simple peephole optimizer that always tries to combine
 1474: \ the currently compiled instruction with the last one.
 1475: 
 1476: \ in order for this to work as intended, shorter combinations for each
 1477: \ length must be present, and the longer combinations must follow
 1478: \ shorter ones (this restriction may go away in the future).
 1479:   
 1480: : output-peephole ( -- )
 1481:     combined-prims num-combined @ 1- cells combinations search-wordlist
 1482:     s" the prefix for this superinstruction must be defined earlier" ?print-error
 1483:     ." {"
 1484:     execute prim-num @ 5 .r ." ,"
 1485:     combined-prims num-combined @ 1- th @ prim-num @ 5 .r ." ,"
 1486:     combined prim-num @ 5 .r ." }, /* "
 1487:     combined prim-c-name 2@ type ."  */"
 1488:     cr ;
 1489: 
 1490: 
 1491: \ cost and superinstruction data for a sophisticated combiner (e.g.,
 1492: \ shortest path)
 1493: 
 1494: \ This is intended as initializer for a structure like this
 1495: 
 1496: \  struct cost {
 1497: \    int loads;       /* number of stack loads */
 1498: \    int stores;      /* number of stack stores */
 1499: \    int updates;     /* number of stack pointer updates */
 1500: \    int offset;      /* offset into super2 table */
 1501: \    int length;      /* number of components */
 1502: \  };
 1503: 
 1504: \ How do you know which primitive or combined instruction this
 1505: \ structure refers to?  By the order of cost structures, as in most
 1506: \ other cases.
 1507: 
 1508: : super2-length ( -- n )
 1509:     combined if
 1510: 	num-combined @
 1511:     else
 1512: 	1
 1513:     endif ;
 1514: 
 1515: : compute-costs { p -- nloads nstores nupdates }
 1516:     \ compute the number of loads, stores, and stack pointer updates
 1517:     \ of a primitive or combined instruction; does not take TOS
 1518:     \ caching into account
 1519:     0 max-stacks 0 +do
 1520: 	p prim-stacks-in i th @ +
 1521:     loop
 1522:     super2-length 1- - \ don't count instruction fetches of subsumed insts
 1523:     0 max-stacks 0 +do
 1524: 	p prim-stacks-out i th @ +
 1525:     loop
 1526:     0 max-stacks 1 +do \ don't count ip updates, therefore "1 +do"
 1527: 	p prim-stacks-in i th @ p prim-stacks-out i th @ <> -
 1528:     loop ;
 1529: 
 1530: : output-num-part ( p -- )
 1531:     ." N_" prim-c-name 2@ type ." ," ;
 1532:     \ prim-num @ 4 .r ." ," ;
 1533: 
 1534: : output-name-comment ( -- )
 1535:     ."  /* " prim prim-name 2@ type ."  */" ;
 1536: 
 1537: variable offset-super2  0 offset-super2 ! \ offset into the super2 table
 1538: 
 1539: : output-costs-prefix ( -- )
 1540:     ." {" prim compute-costs
 1541:     rot 2 .r ." ," swap 2 .r ." ," 2 .r ." , "
 1542:     prim prim-branch? negate . ." ,"
 1543:     state-in  state-number @ 2 .r ." ,"
 1544:     state-out state-number @ 2 .r ." ," ;
 1545: 
 1546: : output-costs-gforth-simple ( -- )
 1547:     output-costs-prefix
 1548:     prim output-num-part
 1549:     1 2 .r ." },"
 1550:     output-name-comment
 1551:     cr ;
 1552: 
 1553: : output-costs-gforth-combined ( -- )
 1554:     output-costs-prefix
 1555:     ." N_START_SUPER+" offset-super2 @ 5 .r ." ,"
 1556:     super2-length dup 2 .r ." }," offset-super2 +!
 1557:     output-name-comment
 1558:     cr ;
 1559: 
 1560: : output-costs ( -- )
 1561:     \ description of superinstructions and simple instructions
 1562:     ." {" prim compute-costs
 1563:     rot 2 .r ." ," swap 2 .r ." ," 2 .r ." ,"
 1564:     offset-super2 @ 5 .r ." ,"
 1565:     super2-length dup 2 .r ." }," offset-super2 +!
 1566:     output-name-comment
 1567:     cr ;
 1568: 
 1569: : output-super2 ( -- )
 1570:     \ table of superinstructions without requirement for existing prefixes
 1571:     combined if
 1572: 	['] output-num-part map-combined 
 1573:     else
 1574: 	prim output-num-part
 1575:     endif
 1576:     output-name-comment
 1577:     cr ;   
 1578: 
 1579: \ the parser
 1580: 
 1581: eof-char max-member \ the whole character set + EOF
 1582: 
 1583: : getinput ( -- n )
 1584:  rawinput @ endrawinput @ =
 1585:  if
 1586:    eof-char
 1587:  else
 1588:    cookedinput @ c@
 1589:  endif ;
 1590: 
 1591: :noname ( n -- )
 1592:  dup bl > if
 1593:   emit space
 1594:  else
 1595:   .
 1596:  endif ;
 1597: print-token !
 1598: 
 1599: : testchar? ( set -- f )
 1600:  getinput member? ;
 1601: ' testchar? test-vector !
 1602: 
 1603: : checksynclines ( -- )
 1604:     \ when input points to a newline, check if the next line is a
 1605:     \ sync line.  If it is, perform the appropriate actions.
 1606:     rawinput @ begin >r
 1607: 	s" #line " r@ over compare if
 1608: 	    rdrop 1 line +! EXIT
 1609: 	endif
 1610: 	0. r> 6 chars + 20 >number drop >r drop line ! r> ( c-addr )
 1611: 	dup c@ bl = if
 1612: 	    char+ dup c@ [char] " <> 0= s" sync line syntax" ?print-error
 1613: 	    char+ dup 100 [char] " scan drop swap 2dup - save-mem filename 2!
 1614: 	    char+
 1615: 	endif
 1616: 	dup c@ nl-char <> 0= s" sync line syntax" ?print-error
 1617: 	skipsynclines @ if
 1618: 	    char+ dup rawinput !
 1619: 	    rawinput @ c@ cookedinput @ c!
 1620: 	endif
 1621:     again ;
 1622: 
 1623: : ?nextchar ( f -- )
 1624:     s" syntax error, wrong char" ?print-error
 1625:     rawinput @ endrawinput @ <> if
 1626: 	rawinput @ c@
 1627: 	1 chars rawinput +!
 1628: 	1 chars cookedinput +!
 1629: 	nl-char = if
 1630: 	    checksynclines
 1631: 	    rawinput @ line-start !
 1632: 	endif
 1633: 	rawinput @ c@
 1634: 	cookedinput @ c!
 1635:     endif ;
 1636: 
 1637: : charclass ( set "name" -- )
 1638:  ['] ?nextchar terminal ;
 1639: 
 1640: : .. ( c1 c2 -- set )
 1641:  ( creates a set that includes the characters c, c1<=c<=c2 )
 1642:  empty copy-set
 1643:  swap 1+ rot do
 1644:   i over add-member
 1645:  loop ;
 1646: 
 1647: : ` ( -- terminal ) ( use: ` c )
 1648:  ( creates anonymous terminal for the character c )
 1649:  char singleton ['] ?nextchar make-terminal ;
 1650: 
 1651: char a char z ..  char A char Z ..  union char _ singleton union  charclass letter
 1652: char 0 char 9 ..					charclass digit
 1653: bl singleton tab-char over add-member			charclass white
 1654: nl-char singleton eof-char over add-member complement	charclass nonl
 1655: nl-char singleton eof-char over add-member
 1656:     char : over add-member complement                   charclass nocolonnl
 1657: nl-char singleton eof-char over add-member
 1658:     char } over add-member complement                   charclass nobracenl
 1659: bl 1+ maxchar .. char \ singleton complement intersection
 1660:                                                         charclass nowhitebq
 1661: bl 1+ maxchar ..                                        charclass nowhite
 1662: char " singleton eof-char over add-member complement	charclass noquote
 1663: nl-char singleton					charclass nl
 1664: eof-char singleton					charclass eof
 1665: nl-char singleton eof-char over add-member		charclass nleof
 1666: 
 1667: (( letter (( letter || digit )) **
 1668: )) <- c-ident ( -- )
 1669: 
 1670: (( ` # ?? (( letter || digit || ` : )) ++
 1671: )) <- stack-ident ( -- )
 1672: 
 1673: (( nowhitebq nowhite ** ))
 1674: <- forth-ident ( -- )
 1675: 
 1676: Variable forth-flag
 1677: Variable c-flag
 1678: 
 1679: (( (( ` e || ` E )) {{ start }} nonl ** 
 1680:    {{ end evaluate }}
 1681: )) <- eval-comment ( ... -- ... )
 1682: 
 1683: (( (( ` f || ` F )) {{ start }} nonl ** 
 1684:    {{ end forth-flag @ IF type cr ELSE 2drop THEN }}
 1685: )) <- forth-comment ( -- )
 1686: 
 1687: (( (( ` c || ` C )) {{ start }} nonl ** 
 1688:    {{ end c-flag @ IF type cr ELSE 2drop THEN }}
 1689: )) <- c-comment ( -- )
 1690: 
 1691: (( ` - nonl ** {{ 
 1692: 	forth-flag @ IF forth-fdiff ." [ELSE]" cr THEN
 1693: 	c-flag @ IF
 1694: 	    function-diff
 1695: 	    ." #else /* " function-number @ 0 .r ."  */" cr THEN }}
 1696: )) <- else-comment
 1697: 
 1698: (( ` + {{ start }} nonl ** {{ end
 1699: 	dup
 1700: 	IF	c-flag @
 1701: 	    IF
 1702: 		function-diff
 1703: 		." #ifdef HAS_" bounds ?DO  I c@ toupper emit  LOOP cr
 1704: 		THEN
 1705: 		forth-flag @
 1706: 		IF  forth-fdiff  ." has? " type ."  [IF]"  cr THEN
 1707: 	ELSE	2drop
 1708: 	    c-flag @      IF
 1709: 		function-diff  ." #endif" cr THEN
 1710: 	    forth-flag @  IF  forth-fdiff  ." [THEN]"  cr THEN
 1711: 	THEN }}
 1712: )) <- if-comment
 1713: 
 1714: (( (( ` g || ` G )) {{ start }} nonl **
 1715:    {{ end
 1716:       forth-flag @ IF  forth-fdiff  ." group " type cr  THEN
 1717:       c-flag @     IF  function-diff
 1718: 	  ." GROUP(" type ." , " function-number @ 0 .r ." )" cr  THEN }}
 1719: )) <- group-comment
 1720: 
 1721: (( (( eval-comment || forth-comment || c-comment || else-comment || if-comment || group-comment )) ?? nonl ** )) <- comment-body
 1722: 
 1723: (( ` \ comment-body nleof )) <- comment ( -- )
 1724: 
 1725: (( {{ start }} stack-ident {{ end 2 pick init-item item% %size + }} white ** )) **
 1726: <- stack-items
 1727: 
 1728: (( {{ prim prim-effect-in }}  stack-items {{ prim prim-effect-in-end ! }}
 1729:    ` - ` - white **
 1730:    {{ prim prim-effect-out }} stack-items {{ prim prim-effect-out-end ! }}
 1731: )) <- stack-effect ( -- )
 1732: 
 1733: (( {{ prim create-prim }}
 1734:    ` ( white ** {{ start }} stack-effect {{ end prim prim-stack-string 2! }} ` ) white **
 1735:    (( {{ start }} forth-ident {{ end prim prim-wordset 2! }} white **
 1736:       (( {{ start }}  c-ident {{ end prim prim-c-name 2! }} )) ??
 1737:    )) ??  nleof
 1738:    (( ` " ` "  {{ start }} (( noquote ++ ` " )) ++ {{ end 1- prim prim-doc 2! }} ` " white ** nleof )) ??
 1739:    {{ skipsynclines off line @ c-line ! filename 2@ c-filename 2! start }}
 1740:    (( (( ` { nonl ** nleof (( (( nobracenl {{ line @ drop }} nonl ** )) ?? nleof )) ** ` } white ** nleof white ** ))
 1741:    || (( nocolonnl nonl **  nleof white ** )) ** ))
 1742:    {{ end prim prim-c-code 2! skipsynclines on }}
 1743:    (( ` :  white ** nleof
 1744:       {{ start }} (( nonl ++  nleof white ** )) ++ {{ end prim prim-forth-code 2! }}
 1745:    )) ?? {{ process-simple }}
 1746:    nleof
 1747: )) <- simple-primitive ( -- )
 1748: 
 1749: (( {{ init-combined }}
 1750:    ` = white ** (( {{ start }} forth-ident {{ end add-prim }} white ** )) ++
 1751:    nleof {{ process-combined }}
 1752: )) <- combined-primitive
 1753: 
 1754: (( {{ make-prim to prim 0 to combined
 1755:       line @ name-line ! filename 2@ name-filename 2!
 1756:       function-number @ prim prim-num !
 1757:       start }} [ifdef] vmgen c-ident [else] forth-ident [then] {{ end
 1758:       2dup prim prim-name 2! prim prim-c-name 2! }}  white **
 1759:    (( ` / white ** {{ start }} c-ident {{ end prim prim-c-name 2! }} white ** )) ??
 1760:    (( simple-primitive || combined-primitive ))
 1761:    {{ 1 function-number +! }}
 1762: )) <- primitive ( -- )
 1763: 
 1764: (( (( comment || primitive || nl white ** )) ** eof ))
 1765: parser primitives2something
 1766: warnings @ [IF]
 1767: .( parser generated ok ) cr
 1768: [THEN]
 1769: 
 1770: 
 1771: \ run with gforth-0.5.0 (slurp-file is missing)
 1772: [IFUNDEF] slurp-file
 1773: : slurp-file ( c-addr1 u1 -- c-addr2 u2 )
 1774:     \ c-addr1 u1 is the filename, c-addr2 u2 is the file's contents
 1775:     r/o bin open-file throw >r
 1776:     r@ file-size throw abort" file too large"
 1777:     dup allocate throw swap
 1778:     2dup r@ read-file throw over <> abort" could not read whole file"
 1779:     r> close-file throw ;
 1780: [THEN]
 1781: 
 1782: : primfilter ( addr u -- )
 1783:     \ process the string at addr u
 1784:     over dup rawinput ! dup line-start ! cookedinput !
 1785:     + endrawinput !
 1786:     checksynclines
 1787:     primitives2something ;    
 1788: 
 1789: : unixify ( c-addr u1 -- c-addr u2 )
 1790:     \ delete crs from the string
 1791:     bounds tuck tuck ?do ( c-addr1 )
 1792: 	i c@ dup #cr <> if
 1793: 	    over c! char+
 1794: 	else
 1795: 	    drop
 1796: 	endif
 1797:     loop
 1798:     over - ;
 1799: 
 1800: : process-file ( addr u xt-simple x-combined -- )
 1801:     output-combined ! output !
 1802:     save-mem 2dup filename 2!
 1803:     slurp-file unixify
 1804:     warnings @ if
 1805: 	." ------------ CUT HERE -------------" cr  endif
 1806:     primfilter ;
 1807: 
 1808: \  : process      ( xt -- )
 1809: \      bl word count rot
 1810: \      process-file ;

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>