1: \ libffi.fs shared library support package 14aug05py
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000,2003,2005 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ common stuff, same as fflib.fs
22:
23: Variable libs 0 libs !
24: \ links between libraries
25: Variable thisproc
26: Variable thislib
27:
28: Variable revdec revdec off
29: \ turn revdec on to compile bigFORTH libraries
30: Variable revarg revarg off
31: \ turn revarg on to compile declarations with reverse arguments
32: Variable legacy legacy off
33: \ turn legacy on to compile bigFORTH legacy libraries
34:
35: Vocabulary c-decl
36: Vocabulary cb-decl
37:
38: : @lib ( lib -- )
39: \G obtains library handle
40: cell+ dup 2 cells + count open-lib
41: dup 0= abort" Library not found" swap ! ;
42:
43: : @proc ( lib addr -- )
44: \G obtains symbol address
45: cell+ tuck cell+ @ count rot cell+ @
46: lib-sym dup 0= abort" Proc not found!" swap ! ;
47:
48: : proc, ( lib -- )
49: \G allocates and initializes proc stub
50: \G stub format:
51: \G linked list in library
52: \G address of proc
53: \G ptr to OS name of symbol as counted string
54: \G threaded code for invocation
55: here dup thisproc !
56: swap 2 cells + dup @ A, !
57: 0 , 0 A, ;
58:
59: Defer legacy-proc ' noop IS legacy-proc
60:
61: : proc: ( lib "name" -- )
62: \G Creates a named proc stub
63: Create proc, 0 also c-decl
64: legacy @ IF legacy-proc THEN
65: DOES> ( x1 .. xn -- r )
66: 3 cells + >r ;
67:
68: : library ( "name" "file" -- )
69: \G loads library "file" and creates a proc defining word "name"
70: \G library format:
71: \G linked list of libraries
72: \G library handle
73: \G linked list of library's procs
74: \G OS name of library as counted string
75: Create here libs @ A, dup libs !
76: 0 , 0 A, parse-name string, @lib
77: DOES> ( -- ) dup thislib ! proc: ;
78:
79: : init-shared-libs ( -- )
80: defers 'cold libs
81: 0 libs BEGIN @ dup WHILE dup REPEAT drop
82: BEGIN dup WHILE >r
83: r@ @lib
84: r@ 2 cells + BEGIN @ dup WHILE r@ over @proc REPEAT
85: drop rdrop
86: REPEAT drop ;
87:
88: ' init-shared-libs IS 'cold
89:
90: : symbol, ( "c-symbol" -- )
91: here thisproc @ 2 cells + ! parse-name s,
92: thislib @ thisproc @ @proc ;
93:
94: \ stuff for libffi
95:
96: \ libffi uses a parameter array for the input
97:
98: $20 Value maxargs
99:
100: Create retbuf 2 cells allot
101: Create argbuf maxargs 2* cells allot
102: Create argptr maxargs 0 [DO] argbuf [I] 2* cells + A, [LOOP]
103:
104: \ "forward" when revarg is on
105:
106: \ : >c+ ( char buf -- buf' ) tuck c! cell+ cell+ ;
107: : >i+ ( n buf -- buf' ) tuck l! cell+ cell+ ;
108: : >p+ ( addr buf -- buf' ) tuck ! cell+ cell+ ;
109: : >d+ ( d buf -- buf' ) dup >r ffi-2! r> cell+ cell+ ;
110: : >sf+ ( r buf -- buf' ) dup sf! cell+ cell+ ;
111: : >df+ ( r buf -- buf' ) dup df! cell+ cell+ ;
112:
113: \ "backward" when revarg is off
114:
115: : >i- ( n buf -- buf' ) 2 cells - tuck l! ;
116: : >p- ( addr buf -- buf' ) 2 cells - tuck ! ;
117: : >d- ( d buf -- buf' ) 2 cells - dup >r ffi-2! r> ;
118: : >sf- ( r buf -- buf' ) 2 cells - dup sf! ;
119: : >df- ( r buf -- buf' ) 2 cells - dup df! ;
120:
121: \ return value
122:
123: : i>x ( -- n ) retbuf l@ ;
124: : is>x ( -- n ) retbuf sl@ ;
125: : p>x ( -- addr ) retbuf @ ;
126: : d>x ( -- d ) retbuf ffi-2@ ;
127: : sf>x ( -- r ) retbuf sf@ ;
128: : df>x ( -- r ) retbuf df@ ;
129:
130: wordlist constant cifs
131:
132: Variable cifbuf $40 allot \ maximum: 64 parameters
133: : cifreset cifbuf cell+ cifbuf ! ;
134: cifreset
135: Variable args args off
136:
137: : argtype ( bkxt fwxt type "name" -- )
138: Create , , , DOES> 1 args +! ;
139:
140: : arg@ ( arg -- type pushxt )
141: dup @ swap cell+
142: revarg @ IF cell+ THEN @ ;
143:
144: : arg, ( xt -- )
145: dup ['] noop = IF drop EXIT THEN compile, ;
146:
147: : start, ( n -- ) cifbuf cell+ cifbuf !
148: revarg @ IF drop 0 ELSE 2* cells THEN argbuf +
149: postpone Literal ;
150:
151: Variable ind-call ind-call off
152: : fptr ind-call on Create here thisproc !
153: 0 , 0 , 0 , 0 also c-decl DOES> cell+ dup cell+ cell+ >r ! ;
154:
155: : ffi-call, ( -- lit-cif )
156: postpone drop postpone argptr postpone retbuf
157: thisproc @ cell+ postpone literal postpone @
158: 0 postpone literal here cell -
159: postpone ffi-call ;
160:
161: : cif, ( n -- )
162: cifbuf @ c! 1 cifbuf +! ;
163:
164: : cif@ ( -- addr u )
165: cifbuf cell+ cifbuf @ over - ;
166:
167: : create-cif ( rtype -- addr ) cif,
168: cif@ cifs search-wordlist
169: IF execute EXIT THEN
170: get-current >r cifs set-current
171: cif@ nextname Create here >r
172: cif@ 1- bounds ?DO I c@ ffi-type , LOOP r>
173: r> set-current ;
174:
175: : make-cif ( rtype -- addr ) create-cif
176: cif@ 1- tuck + c@ ffi-type here 0 ffi-size allot
177: dup >r ffi-prep-cif throw r> ;
178:
179: : decl, ( 0 arg1 .. argn call rtype start -- )
180: start, { retxt rtype } cifreset
181: revdec @ IF 0 >r
182: BEGIN dup WHILE >r REPEAT
183: BEGIN r> dup WHILE arg@ arg, REPEAT
184: ffi-call, retxt compile, postpone EXIT
185: BEGIN dup WHILE cif, REPEAT drop
186: ELSE 0 >r
187: BEGIN dup WHILE arg@ arg, >r REPEAT drop
188: ffi-call, retxt compile, postpone EXIT
189: BEGIN r> dup WHILE cif, REPEAT drop
190: THEN rtype make-cif swap ! here thisproc @ 2 cells + ! ;
191:
192: : rettype ( endxt n "name" -- )
193: Create 2,
194: DOES> 2@ args @ decl, ind-call @ 0= IF symbol, THEN
195: previous revarg off args off ind-call off ;
196:
197: also c-decl definitions
198:
199: : <rev> revarg on ;
200:
201: ' >i+ ' >i- 6 argtype int
202: ' >p+ ' >p- &12 argtype ptr
203: ' >d+ ' >d- 8 argtype llong
204: ' >sf+ ' >sf- 9 argtype sf
205: ' >df+ ' >df- &10 argtype df
206:
207: ' noop 0 rettype (void)
208: ' is>x 6 rettype (int)
209: ' i>x 6 rettype (uint)
210: ' p>x &12 rettype (ptr)
211: ' d>x 8 rettype (llong)
212: ' sf>x 9 rettype (sf)
213: ' df>x &10 rettype (fp)
214:
215: : (addr) thisproc @ cell+ postpone Literal postpone @ postpone EXIT
216: drop symbol, previous revarg off args off ;
217:
218: previous definitions
219:
220: \ legacy support for old library interfaces
221: \ interface to old vararg stuff not implemented yet
222:
223: also c-decl
224:
225: :noname ( n 0 -- 0 int1 .. intn )
226: legacy @ 0< revarg !
227: swap 0 ?DO int LOOP (int)
228: ; IS legacy-proc
229:
230: : (int) ( n -- )
231: >r ' execute r> 0 ?DO int LOOP (int) ;
232: : (void) ( n -- )
233: >r ' execute r> 0 ?DO int LOOP (void) ;
234: : (float) ( n -- )
235: >r ' execute r> 0 ?DO df LOOP (fp) ;
236:
237: previous
238:
239: \ callback stuff
240:
241: Variable callbacks
242: \G link between callbacks
243:
244: Variable rtype
245:
246: : alloc-callback ( ip -- addr )
247: rtype @ make-cif here 1 ffi-size allot
248: dup >r ffi-prep-closure throw r> ;
249:
250: : callback ( -- )
251: Create 0 ] postpone >r also cb-decl cifreset
252: DOES>
253: 0 Value -1 cells allot
254: here >r 0 , callbacks @ A, r@ callbacks !
255: swap postpone Literal postpone call , postpone EXIT
256: r@ cell+ cell+ alloc-callback r> ! ;
257:
258: : callback; ( 0 arg1 .. argn -- )
259: BEGIN over WHILE compile, REPEAT
260: postpone r> postpone execute compile, drop
261: postpone EXIT postpone [ previous ; immediate
262:
263: : rettype' ( xt n -- )
264: Create , A, immediate
265: DOES> 2@ rtype ! ;
266: : argtype' ( xt n -- )
267: Create , A, immediate
268: DOES> 2@ cif, ;
269:
270: : init-callbacks ( -- )
271: defers 'cold callbacks cell -
272: BEGIN cell+ @ dup WHILE dup cell+ cell+ alloc-callback over !
273: REPEAT drop ;
274:
275: ' init-callbacks IS 'cold
276:
277: also cb-decl definitions
278:
279: \ arguments
280:
281: ' ffi-arg-int 6 argtype' int
282: ' ffi-arg-float 9 argtype' sf
283: ' ffi-arg-double &10 argtype' df
284: ' ffi-arg-longlong 8 argtype' llong
285: ' ffi-arg-ptr &12 argtype' ptr
286:
287: ' ffi-ret-void 0 rettype' (void)
288: ' ffi-ret-int 6 rettype' (int)
289: ' ffi-ret-float 9 rettype' (sf)
290: ' ffi-ret-double &10 rettype' (fp)
291: ' ffi-ret-longlong 8 rettype' (llong)
292: ' ffi-ret-ptr &12 rettype' (ptr)
293:
294: previous definitions
295:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to libffi.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth