File:  [gforth] / gforth / libcc.fs
Revision 1.34: download - view: text, annotated - select for diffs
Tue Apr 29 20:03:40 2008 UTC (11 years, 3 months ago) by anton
Branches: MAIN
CVS tags: HEAD
lib.fs: only check those ffcall libraries we use
libcc.fs: removed some debugging output
unix/socket.fs: converted to libcc.fs style (partially thanks to Darren Bane
    <http://savannah.gnu.org/bugs/?23015>

    1: \ libcc.fs	foreign function interface implemented using a C compiler
    2: 
    3: \ Copyright (C) 2006,2007 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: \ What this implementation does is this: if it sees a declaration like
   22: 
   23: \ \ something that tells it that the current library is libc
   24: \ \c #include <unistd.h>
   25: \ c-function dlseek lseek n d n -- d
   26: 
   27: \ it genererates C code similar to the following:
   28: 
   29: \ #include <gforth.h>
   30: \ #include <unistd.h>
   31: \ 
   32: \ void gforth_c_lseek_ndn_d(void)
   33: \ {
   34: \   Cell *sp = gforth_SP;
   35: \   Float *fp = gforth_FP;
   36: \   long long result;  /* longest type in C */
   37: \   gforth_ll2d(lseek(sp[3],gforth_d2ll(sp[2],sp[1]),sp[0]),sp[3],sp[2]);
   38: \   gforth_SP = sp+2;
   39: \ }
   40: 
   41: \ Then it compiles this code and dynamically links it into the Gforth
   42: \ system (batching and caching are future work).  It also dynamically
   43: \ links lseek.  Performing DLSEEK then puts the function pointer of
   44: \ the function pointer of gforth_c_lseek_ndn_d on the stack and
   45: \ calls CALL-C.
   46: 
   47: \ ToDo:
   48: 
   49: \ Batching, caching and lazy evaluation:
   50: 
   51: \ Batching:
   52: 
   53: \ New words are deferred, and the corresponding C functions are
   54: \ collected in one file, until the first word is EXECUTEd; then the
   55: \ file is compiled and linked into the system, and the word is
   56: \ resolved.
   57: 
   58: \ Caching:
   59: 
   60: \ Instead of compiling all this stuff anew for every execution, we
   61: \ keep the files around and have an index file containing the function
   62: \ names and their corresponding .so files.  If the needed wrapper name
   63: \ is already present, it is just linked instead of generating the
   64: \ wrapper again.  This is all done by loading the index file(s?),
   65: \ which define words for the wrappers in a separate wordlist.
   66: 
   67: \ The files are built in .../lib/gforth/$VERSION/libcc/ or
   68: \ ~/.gforth/libcc/$HOST/.
   69: 
   70: \ other things to do:
   71: 
   72: \ c-variable forth-name c-name
   73: \ c-constant forth-name c-name
   74: 
   75: \ Todo: conversion between function pointers and xts (both directions)
   76: 
   77: \ taking an xt and turning it into a function pointer:
   78: 
   79: \ e.g., assume we have the xt of + and want to create a C function int
   80: \ gforth_callback_plus(int, int), and then pass the pointer to that
   81: \ function:
   82: 
   83: \ There should be Forth code like this:
   84: \   ] + 0 (bye)
   85: \ Assume that the start of this code is START
   86:         
   87: \ Now, there should be a C function:
   88: 
   89: \ int gforth_callback_plus(int p1, int p2)
   90: \ {
   91: \   Cell   *sp = gforth_SP;
   92: \   Float  *fp = gforth_FP;
   93: \   Float  *fp = gforth_FP;
   94: \   Address lp = gforth_LP;
   95: \   sp -= 2;
   96: \   sp[0] = p1;
   97: \   sp[1] = p2;
   98: \   gforth_engine(START, sp, rp, fp, lp);
   99: \   sp += 1;
  100: \   gforth_RP = rp;
  101: \   gforth_SP = sp;
  102: \   gforth_FP = fp;
  103: \   gforth_LP = lp;
  104: \   return sp[0];
  105: \ }
  106: 
  107: \ and the pointer to that function is the C function pointer for the XT of +.
  108: 
  109: \ Future problems:
  110: \   how to combine the Forth code generation with inlining
  111: \   START is not a constant across executions (when caching the C files)
  112: \      Solution: make START a variable, and store into it on startup with dlsym
  113: 
  114: \ Syntax:
  115: \  callback <rettype> <params> <paramtypes> -- <rettype>
  116: 
  117: 
  118: \ data structures
  119: 
  120: \ For every c-function, we have three words: two anonymous words
  121: \ created by c-function-ft (first time) and c-function-rt (run-time),
  122: \ and a named deferred word.  The deferred word first points to the
  123: \ first-time word, then to the run-time word; the run-time word calls
  124: \ the c function.
  125: 
  126: [ifundef] parse-name
  127:     ' parse-word alias parse-name
  128: [then]
  129: [ifundef] defer!
  130: : defer! ( xt xt-deferred -- ) \ gforth  defer-store
  131: \G Changes the @code{defer}red word @var{xt-deferred} to execute @var{xt}.
  132:     >body [ has? rom [IF] ] @ [ [THEN] ] ! ;
  133: [then]
  134: 
  135: \ : delete-file 2drop 0 ;
  136: 
  137: require struct.fs
  138: 
  139:     \ counted-string
  140:     
  141: \ c-function-ft word body:
  142: struct
  143:     cell% field cff-cfr \ xt of c-function-rt word
  144:     cell% field cff-deferred \ xt of c-function deferred word
  145:     cell% field cff-lha \ address of the lib-handle for the lib that
  146:                         \ contains the wrapper function of the word
  147:     char% field cff-rtype  \ return type
  148:     char% field cff-np     \ number of parameters
  149:     1 0   field cff-ptypes \ #npar parameter types
  150:     \  counted string: c-name
  151: end-struct cff%
  152: 
  153: variable c-source-file-id \ contains the source file id of the current batch
  154: 0 c-source-file-id !
  155: variable lib-handle-addr \ points to the library handle of the current batch.
  156:                          \ the library handle is 0 if the current
  157:                          \ batch is not yet compiled.
  158: 2variable lib-filename   \ filename without extension
  159: 2variable lib-modulename \ basename of the file without extension
  160: 
  161: : .nb ( n -- )
  162:     0 .r ;
  163: 
  164: : const+ ( n1 "name" -- n2 )
  165:     dup constant 1+ ;
  166: 
  167: : front-string { c-addr1 u1 c-addr2 u2 -- c-addr3 u3 }
  168:     \ insert string c-addr2 u2 in buffer c-addr1 u1; c-addr3 u3 is the
  169:     \ remainder of the buffer.
  170:     assert( u1 u2 u>= )
  171:     c-addr2 c-addr1 u2 move
  172:     c-addr1 u1 u2 /string ;
  173: 
  174: : front-char { c-addr1 u1 c -- c-addr3 u2 }
  175:     \ insert c in buffer c-addr1 u1; c-addr3 u3 is the remainder of
  176:     \ the buffer.
  177:     assert( u1 0 u> )
  178:     c c-addr1 c!
  179:     c-addr1 u1 1 /string ;
  180: 
  181: : s+ { addr1 u1 addr2 u2 -- addr u }
  182:     u1 u2 + allocate throw { addr }
  183:     addr1 addr u1 move
  184:     addr2 addr u1 + u2 move
  185:     addr u1 u2 +
  186: ;
  187: 
  188: : append { addr1 u1 addr2 u2 -- addr u }
  189:     addr1 u1 u2 + dup { u } resize throw { addr }
  190:     addr2 addr u1 + u2 move
  191:     addr u ;
  192: 
  193: \ linked list stuff (should go elsewhere)
  194: 
  195: struct
  196:     cell% field list-next
  197:     1 0   field list-payload
  198: end-struct list%
  199: 
  200: : list-insert { node list -- }
  201:     list list-next @ node list-next !
  202:     node list list-next ! ;
  203: 
  204: : list-append { node endlistp -- }
  205:     \ insert node at place pointed to by endlistp
  206:     node endlistp @ list-insert
  207:     node list-next endlistp ! ;
  208: 
  209: : list-map ( ... list xt -- ... )
  210:     \ xt ( ... node -- ... )
  211:     { xt } begin { node }
  212: 	node while
  213: 	    node xt execute
  214: 	    node list-next @
  215:     repeat ;
  216: 
  217: \ linked libraries
  218: 
  219: list%
  220:     cell% 2* field c-lib-string
  221: end-struct c-lib%
  222: 
  223: variable c-libs \ linked list of library names (without "lib")
  224: 
  225: : add-lib ( c-addr u -- )
  226: \G Add library lib@i{string} to the list of libraries, where
  227: \G @i{string} is represented by @i{c-addr u}.
  228:     c-lib% %size allocate throw dup >r
  229:     c-lib-string 2!
  230:     r> c-libs list-insert ;
  231: 
  232: : append-l ( c-addr1 u1 node -- c-addr2 u2 )
  233:     \ append " -l<nodelib>" to string1
  234:     >r s"  -l" append r> c-lib-string 2@ append ;
  235: 
  236: \ C prefix lines
  237: 
  238: \ linked list of longcstrings: [ link | count-cell | characters ]
  239: 
  240: list%
  241:     cell% field c-prefix-count
  242:     1 0   field c-prefix-chars
  243: end-struct c-prefix%
  244: 
  245: variable c-prefix-lines 0 c-prefix-lines !
  246: variable c-prefix-lines-end c-prefix-lines c-prefix-lines-end !
  247: 
  248: : print-c-prefix-line ( node -- )
  249:     dup c-prefix-chars swap c-prefix-count @ type cr ;
  250: 
  251: : print-c-prefix-lines ( -- )
  252:     c-prefix-lines @ ['] print-c-prefix-line list-map ;
  253: 
  254: : save-c-prefix-line ( c-addr u -- )
  255:     c-source-file-id @ ?dup-if
  256: 	>r 2dup r> write-line throw
  257:     then
  258:     align here 0 , c-prefix-lines-end list-append ( c-addr u )
  259:     longstring, ;
  260: 
  261: : \c ( "rest-of-line" -- ) \ gforth backslash-c
  262:     \G One line of C declarations for the C interface
  263:     -1 parse save-c-prefix-line ;
  264: 
  265: s" #include <gforth/" version-string s+ s" /libcc.h>" append ( c-addr u )
  266:   2dup save-c-prefix-line drop free throw
  267: 
  268: \ Types (for parsing)
  269: 
  270: wordlist constant libcc-types
  271: 
  272: get-current libcc-types set-current
  273: 
  274: \ index values
  275: -1
  276: const+ -- \ end of arguments
  277: const+ n \ integer cell
  278: const+ a \ address cell
  279: const+ d \ double
  280: const+ r \ float
  281: const+ func \ C function pointer
  282: const+ void
  283: drop
  284: 
  285: set-current
  286: 
  287: : parse-libcc-type ( "libcc-type" -- u )
  288:     parse-name libcc-types search-wordlist 0= -13 and throw execute ;
  289: 
  290: : parse-function-types ( "{libcc-type}" "--" "libcc-type" -- )
  291:     here 2 chars allot here begin
  292: 	parse-libcc-type dup 0>= while
  293: 	    c,
  294:     repeat
  295:     drop here swap - over char+ c!
  296:     parse-libcc-type dup 0< -32 and throw swap c! ;
  297: 
  298: : type-letter ( n -- c )
  299:     chars s" nadrfv" drop + c@ ;
  300: 
  301: \ count-stacks
  302: 
  303: : count-stacks-n ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
  304:     1+ ;
  305: 
  306: : count-stacks-a ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
  307:     1+ ;
  308: 
  309: : count-stacks-d ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
  310:     2 + ;
  311: 
  312: : count-stacks-r ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
  313:     swap 1+ swap ;
  314: 
  315: : count-stacks-func ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
  316:     1+ ;
  317: 
  318: : count-stacks-void ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
  319: ;
  320: 
  321: create count-stacks-types
  322: ' count-stacks-n ,
  323: ' count-stacks-a ,
  324: ' count-stacks-d ,
  325: ' count-stacks-r ,
  326: ' count-stacks-func ,
  327: ' count-stacks-void ,
  328: 
  329: : count-stacks ( pars -- fp-change sp-change )
  330:     \ pars is an addr u pair
  331:     0 0 2swap over + swap u+do
  332: 	i c@ cells count-stacks-types + @ execute
  333:     loop ;
  334: 
  335: \ gen-pars
  336: 
  337: : gen-par-n ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
  338:     ." sp[" 1- dup .nb ." ]" ;
  339: 
  340: : gen-par-a ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
  341:     ." (void *)(" gen-par-n ." )" ;
  342: 
  343: : gen-par-d ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
  344:     ." gforth_d2ll(" gen-par-n ." ," gen-par-n ." )" ;
  345: 
  346: : gen-par-r ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
  347:     swap 1- tuck ." fp[" .nb ." ]" ;
  348: 
  349: : gen-par-func ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
  350:     gen-par-a ;
  351: 
  352: : gen-par-void ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
  353:     -32 throw ;
  354: 
  355: create gen-par-types
  356: ' gen-par-n ,
  357: ' gen-par-a ,
  358: ' gen-par-d ,
  359: ' gen-par-r ,
  360: ' gen-par-func ,
  361: ' gen-par-void ,
  362: 
  363: : gen-par ( fp-depth1 sp-depth1 partype -- fp-depth2 sp-depth2 )
  364:     cells gen-par-types + @ execute ;
  365: 
  366: \ the call itself
  367: 
  368: : gen-wrapped-call { d: pars d: c-name fp-change1 sp-change1 -- }
  369:     c-name type ." ("
  370:     fp-change1 sp-change1 pars over + swap u+do 
  371: 	i c@ gen-par
  372: 	i 1+ i' < if
  373: 	    ." ,"
  374: 	endif
  375:     loop
  376:     2drop ." )" ;
  377: 
  378: \ calls for various kinds of return values
  379: 
  380: : gen-wrapped-void ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
  381:     2dup 2>r gen-wrapped-call 2r> ;
  382: 
  383: : gen-wrapped-n ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
  384:     2dup gen-par-n 2>r ." =" gen-wrapped-call 2r> ;
  385: 
  386: : gen-wrapped-a ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
  387:     2dup gen-par-n 2>r ." =(Cell)" gen-wrapped-call 2r> ;
  388: 
  389: : gen-wrapped-d ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
  390:     ." gforth_ll2d(" gen-wrapped-void
  391:     ." ," gen-par-n ." ," gen-par-n ." )" ;
  392: 
  393: : gen-wrapped-r ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
  394:     2dup gen-par-r 2>r ." =" gen-wrapped-call 2r> ;
  395: 
  396: : gen-wrapped-func ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
  397:     gen-wrapped-a ;
  398: 
  399: create gen-wrapped-types
  400: ' gen-wrapped-n ,
  401: ' gen-wrapped-a ,
  402: ' gen-wrapped-d ,
  403: ' gen-wrapped-r ,
  404: ' gen-wrapped-func ,
  405: ' gen-wrapped-void ,
  406: 
  407: : gen-wrapped-stmt ( pars c-name fp-change1 sp-change1 ret -- fp-change sp-change )
  408:     cells gen-wrapped-types + @ execute ;
  409: 
  410: : wrapper-function-name ( addr -- c-addr u )
  411:     \ addr points to the return type index of a c-function descriptor
  412:     count { r-type } count { d: pars }
  413:     pars + count { d: c-name }
  414:     s" gforth_c_" { d: prefix }
  415:     prefix nip c-name nip + pars nip + 3 + { u }
  416:     u allocate throw { c-addr }
  417:     c-addr u
  418:     prefix front-string c-name front-string '_ front-char
  419:     pars bounds u+do
  420: 	i c@ type-letter front-char
  421:     loop
  422:     '_ front-char r-type type-letter front-char assert( dup 0= )
  423:     2drop c-addr u ;
  424: 
  425: : gen-wrapper-function ( addr -- )
  426:     \ addr points to the return type index of a c-function descriptor
  427:     dup { descriptor }
  428:     count { ret } count 2dup { d: pars } chars + count { d: c-name }
  429:     ." void " lib-modulename 2@ type ." _LTX_" descriptor wrapper-function-name 2dup type drop free throw
  430:     .\" (void)\n"
  431:     .\" {\n  Cell MAYBE_UNUSED *sp = gforth_SP;\n  Float MAYBE_UNUSED *fp = gforth_FP;\n  "
  432:     pars c-name 2over count-stacks ret gen-wrapped-stmt .\" ;\n"
  433:     ?dup-if
  434: 	."   gforth_SP = sp+" .nb .\" ;\n"
  435:     endif
  436:     ?dup-if
  437: 	."   gforth_FP = fp+" .nb .\" ;\n"
  438:     endif
  439:     .\" }\n" ;
  440: 
  441: : tempdir ( -- c-addr u )
  442:     s" TMPDIR" getenv dup 0= if
  443:         2drop s" /tmp"
  444:     then ;
  445: 
  446: : gen-filename ( x -- c-addr u )
  447:     \ generates a filename without extension for lib-handle-addr X
  448:     0 <<# ['] #s $10 base-execute #> 
  449:     tempdir s" /gforth_c_" s+ 2swap append #>> ;
  450: 
  451: : init-c-source-file ( -- )
  452:     c-source-file-id @ 0= if
  453:         here 0 , dup lib-handle-addr ! gen-filename 2dup lib-filename 2!
  454:         2dup tempdir nip 1+ /string lib-modulename 2!
  455: 	s" .c" s+ 2dup w/o create-file throw dup c-source-file-id !
  456:         ['] print-c-prefix-lines swap outfile-execute
  457:         drop free throw
  458:     endif ;
  459: 
  460: : c-source-file ( -- file-id )
  461:     c-source-file-id @ assert( dup ) ;
  462: 
  463: : .lib-error ( -- )
  464:     [ifdef] lib-error
  465:         ['] cr stderr outfile-execute
  466:         lib-error ['] type stderr outfile-execute
  467:     [then] ;
  468: 
  469: DEFER compile-wrapper-function ( -- )
  470: :NONAME ( -- )
  471:     c-source-file close-file throw
  472:     0 c-source-file-id !
  473:     [ libtool-command s"  --silent --mode=compile gcc -I " s+
  474:     s" includedir" getenv append ] sliteral
  475:     s"  -O -c " s+ lib-filename 2@ append s" .c -o " append
  476:     lib-filename 2@ append s" .lo" append ( c-addr u )
  477: \    cr 2dup type
  478:     2dup system drop free throw $? abort" libtool compile failed"
  479:     [ libtool-command s"  --silent --mode=link gcc -module -rpath " s+ ] sliteral
  480:     tempdir s+ s"  " append
  481:     lib-filename 2@ append s" .lo -o " append
  482:     lib-filename 2@ append s" .la" append ( c-addr u )
  483:     c-libs @ ['] append-l list-map
  484: \    2dup type cr
  485:     2dup system drop free throw $? abort" libtool link failed"
  486:     lib-filename 2@ s" .la" s+
  487: \    2dup type cr
  488:     2dup open-lib dup 0= if
  489:         .lib-error true abort" open-lib failed"
  490:     endif
  491:     ( lib-handle ) lib-handle-addr @ !
  492:     2dup delete-file throw drop free throw
  493:     lib-filename 2@ s" .c" s+ 2dup delete-file throw drop free throw
  494:     lib-filename 2@ drop free throw 0 0 lib-filename 2! ; IS compile-wrapper-function
  495: \    s" ar rcs xxx.a xxx.o" system
  496: \    $? abort" ar generated error" ;
  497: 
  498: : link-wrapper-function { cff -- sym }
  499:     cff cff-rtype wrapper-function-name { d: wrapper-name }
  500:     wrapper-name cff cff-lha @ @ assert( dup ) lib-sym dup 0= if
  501:         .lib-error -&32 throw
  502:     endif
  503:     wrapper-name drop free throw ;
  504: 
  505: : c-function-ft ( xt-defr xt-cfr "c-name" "{libcc-type}" "--" "libcc-type" -- )
  506:     \ build time/first time action for c-function
  507:     init-c-source-file
  508:     noname create 2, lib-handle-addr @ ,
  509:     parse-name { d: c-name }
  510:     here parse-function-types c-name string,
  511:     ['] gen-wrapper-function c-source-file outfile-execute
  512:   does> ( ... -- ... )
  513:     dup 2@ { xt-defer xt-cfr }
  514:     dup cff-lha @ @ 0= if
  515: 	compile-wrapper-function
  516:     endif
  517:     link-wrapper-function xt-cfr >body !
  518:     xt-cfr xt-defer defer!
  519:     xt-cfr execute ;
  520: 
  521: : c-function-rt ( -- )
  522:     \ run-time definition for c function; addr is the address where
  523:     \ the sym should be stored
  524:     noname create 0 ,
  525:   does> ( ... -- ... )
  526:     @ call-c ;
  527: 
  528: : c-function ( "forth-name" "c-name" "@{type@}" "--" "type" -- ) \ gforth
  529:     \G Define a Forth word @i{forth-name}.  @i{Forth-name} has the
  530:     \G specified stack effect and calls the C function @code{c-name}.
  531:     defer lastxt dup c-function-rt lastxt c-function-ft
  532:     lastxt swap defer! ;
  533: 
  534: : clear-libs ( -- )
  535: \G Clear the list of libs
  536:     c-source-file-id @ if
  537: 	compile-wrapper-function
  538:     endif
  539:     0 c-libs ! ;
  540: clear-libs

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>