File:  [gforth] / gforth / history.fs
Revision 1.72: download - view: text, annotated - select for diffs
Tue Jul 15 16:11:49 2008 UTC (11 years, 6 months ago) by anton
Branches: MAIN
CVS tags: v0-7-0, HEAD
updated copyright years
updated copyright-blacklist (added libltdl)
updated distributed files (don't distribute files without distribution terms)
added copyright to preforth.in and build-ec.in

    1: \ command line edit and history support                 16oct94py
    2: 
    3: \ Copyright (C) 1995,2000,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: : ctrl-i ( "<char>" -- c )
   21:     char toupper $40 xor ;
   22: 
   23: ' ctrl-i
   24: :noname
   25:     ctrl-i postpone Literal ;
   26: interpret/compile: ctrl  ( "<char>" -- ctrl-code )
   27: 
   28: \ command line editing                                  16oct94py
   29: 
   30: : >string  ( span addr pos1 -- span addr pos1 addr2 len )
   31:   over 3 pick 2 pick chars /string ;
   32: 
   33: : bindkey ( xt key -- )  cells ctrlkeys + ! ;
   34: 
   35: \ history support                                       16oct94py
   36: 
   37: 0 Value history \ history file fid
   38: 
   39: 2Variable forward^
   40: 2Variable backward^
   41: 2Variable end^
   42: 
   43: : force-open ( addr len -- fid )
   44:     2dup r/w open-file
   45:     IF
   46: 	drop r/w create-file throw
   47:     ELSE
   48: 	nip nip
   49:     THEN ;
   50: 
   51: s" os-class" environment? [IF] s" unix" str= [ELSE] true [THEN] 
   52: [IF]
   53: : history-file ( -- addr u )
   54:     s" GFORTHHIST" getenv dup 0= IF
   55: 	2drop s" ~/.gforth-history"
   56:     THEN ;
   57: [ELSE]
   58: 
   59: : history-dir ( -- addr u )
   60:   s" TMP" getenv ?dup ?EXIT drop
   61:   s" TEMP" getenv ?dup ?EXIT drop
   62:   s" c:/" ;
   63: 
   64: : history-file ( -- addr u )
   65:   s" GFORTHHIST" getenv ?dup ?EXIT
   66:   drop
   67:   history-dir pad place
   68:   s" /ghist.fs" pad +place pad count ;
   69: [THEN]
   70: 
   71: \ moving in history file                               16oct94py
   72: 
   73: defer back-restore ( u -- )
   74: defer cur-correct ( addr u -- )
   75: ' backspaces IS back-restore
   76: ' 2drop IS cur-correct
   77: 
   78: Variable linew
   79: Variable screenw
   80: : linew-off  linew off cols screenw ! ;
   81: 
   82: [IFDEF] x-width
   83: : clear-line ( max span addr pos1 -- max addr )
   84:     drop linew @ back-restore over over swap x-width
   85:     dup spaces back-restore nip linew off ;
   86: [ELSE]
   87: : clear-line ( max span addr pos1 -- max addr )
   88:   back-restore over spaces swap back-restore ;
   89: [THEN]
   90: \ : clear-tib ( max span addr pos -- max 0 addr 0 false )
   91: \   clear-line 0 tuck dup ;
   92: 
   93: : hist-pos    ( -- ud )  history file-position drop ( throw ) ;
   94: : hist-setpos ( ud -- )  history reposition-file drop ( throw ) ;
   95: 
   96: : get-line ( addr len -- len' flag )
   97:   swap history read-line throw ;
   98: 
   99: : next-line  ( max span addr pos1 -- max span addr pos2 false )
  100:   clear-line
  101:   forward^ 2@ 2dup hist-setpos backward^ 2!
  102:   2dup get-line drop
  103:   hist-pos  forward^ 2!
  104:   tuck 2dup type 2dup cur-correct 0 ;
  105: 
  106: : find-prev-line ( max addr -- max span addr pos2 )
  107:   backward^ 2@ forward^ 2!
  108:   over 2 + negate s>d backward^ 2@ d+ 0. dmax 2dup hist-setpos
  109:   BEGIN
  110:       backward^ 2!   2dup get-line  WHILE
  111:       hist-pos 2dup forward^ 2@ d<  WHILE
  112:       rot drop
  113:   REPEAT  2drop  THEN  tuck ;
  114: 
  115: : prev-line  ( max span addr pos1 -- max span addr pos2 false )
  116:     clear-line find-prev-line 2dup type 2dup cur-correct 0 ;
  117: 
  118: \ Create lfpad #lf c,
  119: 
  120: : (enter)  ( max span addr pos1 -- max span addr pos2 true )
  121:   >r end^ 2@ hist-setpos
  122:   2dup swap history write-line drop ( throw ) \ don't worry about errors
  123:   hist-pos 2dup backward^ 2! end^ 2!
  124:   r> (ret) ;
  125: 
  126: : extract-word ( addr len -- addr' len' )  dup >r
  127:   BEGIN  1- dup 0>=  WHILE  2dup + c@ bl =  UNTIL  THEN  1+
  128:   tuck + r> rot - ;
  129: 
  130: Create prefix-found  0 , 0 ,
  131: 
  132: : sgn ( n -- -1/0/1 )
  133:  dup 0= IF EXIT THEN  0< 2* 1+ ;
  134: 
  135: : capscomp  ( c_addr1 u c_addr2 -- n )
  136:  swap bounds
  137:  ?DO  dup c@ I c@ <>
  138:      IF  dup c@ toupper I c@ toupper =
  139:      ELSE  true  THEN  WHILE  1+  LOOP  drop 0
  140:  ELSE  c@ toupper I c@ toupper - unloop  THEN  sgn ;
  141: 
  142: : word-lex ( nfa1 nfa2 -- -1/0/1 )
  143:     dup 0=
  144:     IF
  145: 	2drop 1  EXIT
  146:     THEN
  147:     name>string 2>r name>string
  148:     dup r@ =
  149:     IF
  150: 	rdrop r> capscomp 0<= EXIT
  151:     THEN
  152:     r> <
  153:     nip rdrop ;
  154: 
  155: : search-voc ( addr len nfa1 nfa2 -- addr len nfa3 )
  156:     >r
  157:     BEGIN
  158: 	dup
  159:     WHILE
  160: 	>r dup r@ name>string nip <=
  161: 	IF
  162: 	    2dup r@ name>string drop capscomp  0=
  163: 	    IF
  164: 		r> dup r@ word-lex
  165: 		IF
  166: 		    dup prefix-found @ word-lex
  167: 		    0>=
  168: 		    IF
  169: 			rdrop dup >r
  170: 		    THEN
  171: 		THEN
  172: 		>r
  173: 	    THEN
  174: 	THEN
  175: 	r> @
  176:     REPEAT
  177:     drop r> ;
  178: 
  179: : prefix-off ( -- )  0 0 prefix-found 2! ;
  180: 
  181: : prefix-string ( addr len nfa -- addr' len' )
  182:     dup prefix-found !  ?dup
  183:     IF
  184: 	name>string rot /string rot drop
  185: 	dup 1+ prefix-found cell+ !
  186:     ELSE
  187: 	2drop s" " prefix-off
  188:     THEN ;
  189: 
  190: : search-prefix  ( addr1 len1 -- addr2 len2 )
  191:     0 vp dup @ 1- cells over +
  192:     DO  I 2@ <>
  193:         IF  I cell+ @ wordlist-id @ swap  search-voc  THEN
  194: 	[ -1 cells ] Literal +LOOP
  195:     prefix-string ;
  196: 
  197: : tib-full? ( max span addr pos addr' len' -- max span addr pos addr1 u flag )
  198:     5 pick over 4 pick + prefix-found @ 0<> - < ;
  199: 
  200: : kill-prefix  ( key -- key )
  201:   dup #tab <> IF  prefix-off  THEN ;
  202: 
  203: \ UTF-8 support
  204: 
  205: require utf-8.fs
  206: 
  207: [IFUNDEF] #esc  27 Constant #esc  [THEN]
  208: 
  209: : at-deltaxy ( dx dy -- )
  210:     over 0< over 0= and IF  drop abs backspaces  EXIT  THEN
  211:     base @ >r decimal
  212:     ?dup IF
  213: 	#esc emit '[ emit  dup abs 0 .r 0< IF  'A  ELSE  'B  THEN  emit
  214:     THEN
  215:     ?dup IF
  216: 	#esc emit '[ emit  dup abs 0 .r 0< IF  'D  ELSE  'C  THEN  emit
  217:     THEN  r> base ! ;
  218: 
  219: \ : cygwin? ( -- flag ) s" TERM" getenv s" cygwin" str= ;
  220: \ : at-xy? ( -- x y )
  221: \     key? drop \ make sure prep_terminal() is executed
  222: \     #esc emit ." [6n"  0 0
  223: \     BEGIN  key dup 'R <>  WHILE
  224: \ 	    dup '; = IF  drop  swap  ELSE
  225: \ 		dup '0 '9 1+ within  IF  '0 - swap 10 * +  ELSE
  226: \ 		    drop  THEN  THEN
  227: \     REPEAT  drop 1- swap 1- ;
  228: \ : cursor@ ( -- n )  at-xy? screenw @ * + ;
  229: \ : cursor! ( n -- )  screenw @ /mod at-xy ;
  230: : xcur-correct  ( addr u -- )  x-width linew ! ;
  231: 
  232: ' xcur-correct IS cur-correct
  233: 
  234: : xback-restore ( u -- )
  235:     screenw @ /mod negate swap negate swap at-deltaxy ;
  236: : .rest ( addr pos1 -- addr pos1 )
  237:     linew @ xback-restore 2dup type 2dup cur-correct ;
  238: : .all ( span addr pos1 -- span addr pos1 )
  239:     linew @ xback-restore >r 2dup swap type 2dup swap cur-correct r> ;
  240: 
  241: : xretype ( max span addr pos1 -- max span addr pos1 f )
  242:     .all cols screenw @ >r screenw !
  243:     linew @ screenw @ / linew @ r@ / max
  244:     screenw @ r> - * 0 max
  245:     dup spaces linew +! .rest false ;
  246: 
  247: \ In the following, addr max is the buffer, addr span is the current
  248: \ string in the buffer, and pos1 is the cursor position in the buffer.
  249: 
  250: : <xins>  ( max span addr pos1 xc -- max span addr pos2 )
  251:     >r  2over r@ xc-size + u< IF  ( max span addr pos1 R:xc )
  252: 	rdrop bell  EXIT  THEN
  253:     >string over r@ xc-size + swap move
  254:     2dup chars + r@ swap r@ xc-size xc!+? 2drop drop
  255:     r> xc-size >r  rot r@ chars + -rot r> chars + ;
  256: : (xins)  ( max span addr pos1 xc -- max span addr pos2 )
  257:     <xins> key? 0= IF  .all .rest  THEN ;
  258: : xback  ( max span addr pos1 -- max span addr pos2 f )
  259:     dup  IF  over + xchar- over -  0 max .all .rest
  260:     ELSE  bell  THEN 0 ;
  261: : xforw  ( max span addr pos1 -- max span addr pos2 f )
  262:     2 pick over <> IF  over + xc@+ xemit over -  ELSE  bell  THEN
  263:     2dup cur-correct 0 ;
  264: : (xdel)  ( max span addr pos1 -- max span addr pos2 )
  265:     over + dup xchar- tuck - >r over -
  266:     >string over r@ + -rot move
  267:     rot r> - -rot ;
  268: : ?xdel ( max span addr pos1 -- max span addr pos2 0 )
  269:   dup  IF  (xdel) .all 2 spaces 2 linew +! .rest  THEN  0 ;
  270: : <xdel> ( max span addr pos1 -- max span addr pos2 0 )
  271:   2 pick over <>
  272:     IF  xforw drop (xdel) .all 2 spaces 2 linew +! .rest
  273:     ELSE  bell  THEN  0 ;
  274: : xeof  2 pick over or 0=  IF  bye  ELSE  <xdel>  THEN ;
  275: 
  276: : xfirst-pos  ( max span addr pos1 -- max span addr 0 0 )
  277:   drop 0 .all .rest 0 ;
  278: : xend-pos  ( max span addr pos1 -- max span addr span 0 )
  279:   drop over .all 0 ;
  280: 
  281: 
  282: : xclear-line ( max span addr pos1 -- max addr )
  283:     2dup x-width dup xback-restore dup spaces xback-restore drop nip ;
  284: : xclear-tib ( max span addr pos -- max 0 addr 0 false )
  285:     xclear-line 0 tuck dup ;
  286: 
  287: : (xenter)  ( max span addr pos1 -- max span addr pos2 true )
  288:     >r end^ 2@ hist-setpos
  289:     2dup swap history write-line drop ( throw ) \ don't worry about errors
  290:     hist-pos 2dup backward^ 2! end^ 2!
  291:     r> .all space true ;
  292: 
  293: : xkill-expand ( max span addr pos1 -- max span addr pos2 )
  294:     prefix-found cell+ @ ?dup IF  >r
  295: 	r@ - >string over r@ + -rot move
  296: 	rot r@ - -rot .all r@ spaces r> back-restore .rest THEN ;
  297: 
  298: : insert   ( string length buffer size -- )
  299:     rot over min >r  r@ - ( left over )
  300:     over dup r@ +  rot move   r> move  ;
  301: 
  302: : xtab-expand ( max span addr pos1 -- max span addr pos2 0 )
  303:     key? IF  #tab (xins) 0  EXIT  THEN
  304:     xkill-expand 2dup extract-word dup 0= IF  nip EXIT  THEN
  305:     search-prefix tib-full?
  306:     IF    bell  2drop  prefix-off
  307:     ELSE  dup >r
  308: 	2>r >string r@ + 2r> 2swap insert
  309: 	r@ + rot r> + -rot
  310:     THEN
  311:     prefix-found @ IF  bl (xins)  ELSE  .all .rest  THEN  0 ;
  312: 
  313: : xchar-history ( -- )
  314:     ['] xforw        ctrl F bindkey
  315:     ['] xback        ctrl B bindkey
  316:     ['] ?xdel        ctrl H bindkey
  317:     ['] xeof         ctrl D bindkey
  318:     ['] <xdel>       ctrl X bindkey
  319:     ['] xclear-tib   ctrl K bindkey
  320:     ['] xfirst-pos   ctrl A bindkey
  321:     ['] xend-pos     ctrl E bindkey
  322:     ['] xretype      ctrl L bindkey
  323:     history IF  ['] (xenter)     #lf    bindkey  THEN
  324:     history IF  ['] (xenter)     #cr    bindkey  THEN
  325:     ['] xtab-expand  #tab   bindkey
  326:     ['] (xins)       IS insert-char
  327:     ['] kill-prefix  IS everychar
  328: [ifdef] everyline
  329:     ['] linew-off     IS everyline
  330: [endif]
  331:     ['] xback-restore IS back-restore
  332:     ['] xcur-correct  IS cur-correct
  333: ;
  334: 
  335: xchar-history
  336: 
  337: \ initializing history
  338: 
  339: : get-history ( addr len -- )
  340:     ['] force-open catch
  341:     ?dup-if
  342: 	\ !! >stderr
  343:         \ history-file type ." : " .error cr
  344: 	drop 2drop 0 to history
  345: 	['] false ['] false ['] (ret)
  346:     else
  347: 	to history
  348: 	history file-size throw
  349: 	2dup forward^ 2! 2dup backward^ 2! end^ 2!
  350: 	['] next-line ['] prev-line ['] (enter)
  351:     endif
  352:     dup #lf bindkey
  353:         #cr bindkey
  354:      ctrl P bindkey
  355:      ctrl N bindkey
  356: ;
  357: 
  358: : history-cold ( -- )
  359:     history-file get-history xchar-history ;
  360: 
  361: :noname ( -- )
  362:     defers 'cold
  363:     history-cold
  364: ; is 'cold
  365: 
  366: history-cold
  367: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>