1: \ command line edit and history support 16oct94py
2:
3: \ Copyright (C) 1995,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: : ctrl-i ( "<char>" -- c )
22: char toupper $40 xor ;
23:
24: ' ctrl-i
25: :noname
26: ctrl-i postpone Literal ;
27: interpret/compile: ctrl ( "<char>" -- ctrl-code )
28:
29: \ command line editing 16oct94py
30:
31: : >string ( span addr pos1 -- span addr pos1 addr2 len )
32: over 3 pick 2 pick chars /string ;
33:
34: : bindkey ( xt key -- ) cells ctrlkeys + ! ;
35:
36: \ history support 16oct94py
37:
38: 0 Value history \ history file fid
39:
40: 2Variable forward^
41: 2Variable backward^
42: 2Variable end^
43:
44: : force-open ( addr len -- fid )
45: 2dup r/w open-file
46: IF
47: drop r/w create-file throw
48: ELSE
49: nip nip
50: THEN ;
51:
52: s" os-class" environment? [IF] s" unix" str= [ELSE] true [THEN]
53: [IF]
54: : history-file ( -- addr u )
55: s" GFORTHHIST" getenv dup 0= IF
56: 2drop s" ~/.gforth-history"
57: THEN ;
58: [ELSE]
59:
60: : history-dir ( -- addr u )
61: s" TMP" getenv ?dup ?EXIT drop
62: s" TEMP" getenv ?dup ?EXIT drop
63: s" c:/" ;
64:
65: : history-file ( -- addr u )
66: s" GFORTHHIST" getenv ?dup ?EXIT
67: drop
68: history-dir pad place
69: s" /ghist.fs" pad +place pad count ;
70: [THEN]
71:
72: \ moving in history file 16oct94py
73:
74: defer back-restore ( u -- )
75: defer cur-correct ( addr u -- )
76: ' backspaces IS back-restore
77: ' 2drop IS cur-correct
78:
79: Variable linew
80: Variable screenw
81:
82: : linew-off linew off form nip screenw ! ;
83:
84: [IFDEF] x-width
85: : clear-line ( max span addr pos1 -- max addr )
86: drop linew @ back-restore over over swap x-width
87: dup spaces back-restore nip linew off ;
88: [ELSE]
89: : clear-line ( max span addr pos1 -- max addr )
90: back-restore over spaces swap back-restore ;
91: [THEN]
92: \ : clear-tib ( max span addr pos -- max 0 addr 0 false )
93: \ clear-line 0 tuck dup ;
94:
95: : hist-pos ( -- ud ) history file-position drop ( throw ) ;
96: : hist-setpos ( ud -- ) history reposition-file drop ( throw ) ;
97:
98: : get-line ( addr len -- len' flag )
99: swap history read-line throw ;
100:
101: : next-line ( max span addr pos1 -- max span addr pos2 false )
102: clear-line
103: forward^ 2@ 2dup hist-setpos backward^ 2!
104: 2dup get-line drop
105: hist-pos forward^ 2!
106: tuck 2dup type 2dup cur-correct 0 ;
107:
108: : find-prev-line ( max addr -- max span addr pos2 )
109: backward^ 2@ forward^ 2!
110: over 2 + negate s>d backward^ 2@ d+ 0. dmax 2dup hist-setpos
111: BEGIN
112: backward^ 2! 2dup get-line WHILE
113: hist-pos 2dup forward^ 2@ d< WHILE
114: rot drop
115: REPEAT 2drop THEN tuck ;
116:
117: : prev-line ( max span addr pos1 -- max span addr pos2 false )
118: clear-line find-prev-line 2dup type 2dup cur-correct 0 ;
119:
120: \ Create lfpad #lf c,
121:
122: : (enter) ( max span addr pos1 -- max span addr pos2 true )
123: >r end^ 2@ hist-setpos
124: 2dup swap history write-line drop ( throw ) \ don't worry about errors
125: hist-pos 2dup backward^ 2! end^ 2!
126: r> (ret) ;
127:
128: : extract-word ( addr len -- addr' len' ) dup >r
129: BEGIN 1- dup 0>= WHILE 2dup + c@ bl = UNTIL THEN 1+
130: tuck + r> rot - ;
131:
132: Create prefix-found 0 , 0 ,
133:
134: : sgn ( n -- -1/0/1 )
135: dup 0= IF EXIT THEN 0< 2* 1+ ;
136:
137: : capscomp ( c_addr1 u c_addr2 -- n )
138: swap bounds
139: ?DO dup c@ I c@ <>
140: IF dup c@ toupper I c@ toupper =
141: ELSE true THEN WHILE 1+ LOOP drop 0
142: ELSE c@ toupper I c@ toupper - unloop THEN sgn ;
143:
144: : word-lex ( nfa1 nfa2 -- -1/0/1 )
145: dup 0=
146: IF
147: 2drop 1 EXIT
148: THEN
149: name>string 2>r name>string
150: dup r@ =
151: IF
152: rdrop r> capscomp 0<= EXIT
153: THEN
154: r> <
155: nip rdrop ;
156:
157: : search-voc ( addr len nfa1 nfa2 -- addr len nfa3 )
158: >r
159: BEGIN
160: dup
161: WHILE
162: >r dup r@ name>string nip <=
163: IF
164: 2dup r@ name>string drop capscomp 0=
165: IF
166: r> dup r@ word-lex
167: IF
168: dup prefix-found @ word-lex
169: 0>=
170: IF
171: rdrop dup >r
172: THEN
173: THEN
174: >r
175: THEN
176: THEN
177: r> @
178: REPEAT
179: drop r> ;
180:
181: : prefix-off ( -- ) 0 0 prefix-found 2! ;
182:
183: : prefix-string ( addr len nfa -- addr' len' )
184: dup prefix-found ! ?dup
185: IF
186: name>string rot /string rot drop
187: dup 1+ prefix-found cell+ !
188: ELSE
189: 2drop s" " prefix-off
190: THEN ;
191:
192: : search-prefix ( addr1 len1 -- addr2 len2 )
193: 0 vp dup @ 1- cells over +
194: DO I 2@ <>
195: IF I cell+ @ wordlist-id @ swap search-voc THEN
196: [ -1 cells ] Literal +LOOP
197: prefix-string ;
198:
199: : tib-full? ( max span addr pos addr' len' -- max span addr pos addr1 u flag )
200: 5 pick over 4 pick + prefix-found @ 0<> - < ;
201:
202: : kill-prefix ( key -- key )
203: dup #tab <> IF prefix-off THEN ;
204:
205: \ UTF-8 support
206:
207: require utf-8.fs
208:
209: [IFUNDEF] #esc 27 Constant #esc [THEN]
210:
211: : at-deltaxy ( dx dy -- ) base @ >r decimal
212: ?dup IF
213: #esc emit '[ emit dup abs 0 .r 0< IF 'A ELSE 'B THEN emit
214: THEN
215: ?dup IF
216: #esc emit '[ emit dup abs 0 .r 0< IF 'D ELSE 'C THEN emit
217: THEN r> base ! ;
218:
219: \ : cygwin? ( -- flag ) s" TERM" getenv s" cygwin" str= ;
220: \ : at-xy? ( -- x y )
221: \ key? drop \ make sure prep_terminal() is executed
222: \ #esc emit ." [6n" 0 0
223: \ BEGIN key dup 'R <> WHILE
224: \ dup '; = IF drop swap ELSE
225: \ dup '0 '9 1+ within IF '0 - swap 10 * + ELSE
226: \ drop THEN THEN
227: \ REPEAT drop 1- swap 1- ;
228: \ : cursor@ ( -- n ) at-xy? screenw @ * + ;
229: \ : cursor! ( n -- ) screenw @ /mod at-xy ;
230: : xcur-correct ( addr u -- ) x-width linew ! ;
231:
232: ' xcur-correct IS cur-correct
233:
234: : xback-restore ( u -- )
235: screenw @ /mod negate swap negate swap at-deltaxy ;
236: : .rest ( addr pos1 -- addr pos1 )
237: linew @ xback-restore 2dup type 2dup cur-correct ;
238: : .all ( span addr pos1 -- span addr pos1 )
239: linew @ xback-restore >r 2dup swap type 2dup swap cur-correct r> ;
240:
241: : xretype ( max span addr pos1 -- max span addr pos1 f )
242: .all form nip screenw @ >r screenw !
243: linew @ screenw @ / linew @ r@ / max
244: screenw @ r> - * 0 max
245: dup spaces linew +! .rest false ;
246:
247: \ In the following, addr max is the buffer, addr span is the current
248: \ string in the buffer, and pos1 is the cursor position in the buffer.
249:
250: : <xins> ( max span addr pos1 xc -- max span addr pos2 )
251: >r 2over r@ xc-size + u< IF ( max span addr pos1 R:xc )
252: rdrop bell EXIT THEN
253: >string over r@ xc-size + swap move
254: 2dup chars + r@ swap r@ xc-size xc!+? 2drop drop
255: r> xc-size >r rot r@ chars + -rot r> chars + ;
256: : (xins) ( max span addr pos1 xc -- max span addr pos2 )
257: <xins> key? 0= IF .all .rest THEN ;
258: : xback ( max span addr pos1 -- max span addr pos2 f )
259: dup IF over + xchar- over - 0 max .all .rest
260: ELSE bell THEN 0 ;
261: : xforw ( max span addr pos1 -- max span addr pos2 f )
262: 2 pick over <> IF over + xc@+ xemit over - ELSE bell THEN
263: 2dup cur-correct 0 ;
264: : (xdel) ( max span addr pos1 -- max span addr pos2 )
265: over + dup xchar- tuck - >r over -
266: >string over r@ + -rot move
267: rot r> - -rot ;
268: : ?xdel ( max span addr pos1 -- max span addr pos2 0 )
269: dup IF (xdel) .all 2 spaces 2 linew +! .rest THEN 0 ;
270: : <xdel> ( max span addr pos1 -- max span addr pos2 0 )
271: 2 pick over <>
272: IF xforw drop (xdel) .all 2 spaces 2 linew +! .rest
273: ELSE bell THEN 0 ;
274: : xeof 2 pick over or 0= IF bye ELSE <xdel> THEN ;
275:
276: : xfirst-pos ( max span addr pos1 -- max span addr 0 0 )
277: drop 0 .all .rest 0 ;
278: : xend-pos ( max span addr pos1 -- max span addr span 0 )
279: drop over .all 0 ;
280:
281:
282: : xclear-line ( max span addr pos1 -- max addr )
283: 2dup x-width dup xback-restore dup spaces xback-restore drop nip ;
284: : xclear-tib ( max span addr pos -- max 0 addr 0 false )
285: xclear-line 0 tuck dup ;
286:
287: : (xenter) ( max span addr pos1 -- max span addr pos2 true )
288: >r end^ 2@ hist-setpos
289: 2dup swap history write-line drop ( throw ) \ don't worry about errors
290: hist-pos 2dup backward^ 2! end^ 2!
291: r> .all space true ;
292:
293: : xkill-expand ( max span addr pos1 -- max span addr pos2 )
294: prefix-found cell+ @ ?dup IF >r
295: r@ - >string over r@ + -rot move
296: rot r@ - -rot .all r@ spaces r> back-restore .rest THEN ;
297:
298: : insert ( string length buffer size -- )
299: rot over min >r r@ - ( left over )
300: over dup r@ + rot move r> move ;
301:
302: : xtab-expand ( max span addr pos1 -- max span addr pos2 0 )
303: key? IF #tab (xins) 0 EXIT THEN
304: xkill-expand 2dup extract-word dup 0= IF nip EXIT THEN
305: search-prefix tib-full?
306: IF bell 2drop prefix-off
307: ELSE dup >r
308: 2>r >string r@ + 2r> 2swap insert
309: r@ + rot r> + -rot
310: THEN
311: prefix-found @ IF bl (xins) ELSE .all .rest THEN 0 ;
312:
313: : xchar-history ( -- )
314: ['] xforw ctrl F bindkey
315: ['] xback ctrl B bindkey
316: ['] ?xdel ctrl H bindkey
317: ['] xeof ctrl D bindkey
318: ['] <xdel> ctrl X bindkey
319: ['] xclear-tib ctrl K bindkey
320: ['] xfirst-pos ctrl A bindkey
321: ['] xend-pos ctrl E bindkey
322: ['] xretype ctrl L bindkey
323: history IF ['] (xenter) #lf bindkey THEN
324: history IF ['] (xenter) #cr bindkey THEN
325: ['] xtab-expand #tab bindkey
326: ['] (xins) IS insert-char
327: ['] kill-prefix IS everychar
328: ['] linew-off IS everyline
329: ['] xback-restore IS back-restore
330: ['] xcur-correct IS cur-correct
331: ;
332:
333: xchar-history
334:
335: \ initializing history
336:
337: : get-history ( addr len -- )
338: ['] force-open catch
339: ?dup-if
340: \ !! >stderr
341: \ history-file type ." : " .error cr
342: drop 2drop 0 to history
343: ['] false ['] false ['] (ret)
344: else
345: to history
346: history file-size throw
347: 2dup forward^ 2! 2dup backward^ 2! end^ 2!
348: ['] next-line ['] prev-line ['] (enter)
349: endif
350: dup #lf bindkey
351: #cr bindkey
352: ctrl P bindkey
353: ctrl N bindkey
354: ;
355:
356: : history-cold ( -- )
357: history-file get-history xchar-history ;
358:
359: :noname ( -- )
360: defers 'cold
361: history-cold
362: ; is 'cold
363:
364: history-cold
365:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to history.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth