1: \ command line edit and history support 16oct94py
2:
3: \ Copyright (C) 1995,2000,2003,2004 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: :noname
22: char [char] @ - ;
23: :noname
24: char [char] @ - postpone Literal ;
25: interpret/compile: ctrl ( "<char>" -- ctrl-code )
26:
27: \ command line editing 16oct94py
28:
29: : >string ( span addr pos1 -- span addr pos1 addr2 len )
30: over 3 pick 2 pick chars /string ;
31: : type-rest ( span addr pos1 -- span addr pos1 back )
32: >string tuck type ;
33: : (del) ( max span addr pos1 -- max span addr pos2 )
34: 1- >string over 1+ -rot move
35: rot 1- -rot #bs emit type-rest bl emit 1+ backspaces ;
36: : (ins) ( max span addr pos1 char -- max span addr pos2 )
37: >r >string over 1+ swap move 2dup chars + r> swap c!
38: rot 1+ -rot type-rest 1- backspaces 1+ ;
39: : ?del ( max span addr pos1 -- max span addr pos2 0 )
40: dup IF (del) THEN 0 ;
41: : (ret) type-rest drop true space ;
42: : back dup IF 1- #bs emit ELSE #bell emit THEN 0 ;
43: : forw 2 pick over <> IF 2dup + c@ emit 1+ ELSE #bell emit THEN 0 ;
44: : <del> ( max span addr pos1 -- max span addr pos2 0 )
45: 2 pick over <>
46: IF forw drop (del) ELSE #bell emit THEN 0 ;
47: : eof 2 pick over or 0= IF bye ELSE <del> THEN ;
48:
49: : bindkey ( xt key -- ) cells ctrlkeys + ! ;
50:
51: \ history support 16oct94py
52:
53: 0 Value history \ history file fid
54:
55: 2Variable forward^
56: 2Variable backward^
57: 2Variable end^
58:
59: : force-open ( addr len -- fid )
60: 2dup r/w open-file
61: IF
62: drop r/w create-file throw
63: ELSE
64: nip nip
65: THEN ;
66:
67: s" os-class" environment? [IF] s" unix" str= [ELSE] true [THEN]
68: [IF]
69: : history-file ( -- addr u )
70: s" GFORTHHIST" getenv dup 0= IF
71: 2drop s" ~/.gforth-history"
72: THEN ;
73: [ELSE]
74:
75: : history-dir ( -- addr u )
76: s" TMP" getenv ?dup ?EXIT drop
77: s" TEMP" getenv ?dup ?EXIT drop
78: s" c:/" ;
79:
80: : history-file ( -- addr u )
81: s" GFORTHHIST" getenv ?dup ?EXIT
82: drop
83: history-dir pad place
84: s" /ghist.fs" pad +place pad count ;
85: [THEN]
86:
87: \ moving in history file 16oct94py
88:
89: : clear-line ( max span addr pos1 -- max addr )
90: backspaces over spaces swap backspaces ;
91:
92: : clear-tib ( max span addr pos -- max 0 addr 0 false )
93: clear-line 0 tuck dup ;
94:
95: : hist-pos ( -- ud ) history file-position drop ( throw ) ;
96: : hist-setpos ( ud -- ) history reposition-file drop ( throw ) ;
97:
98: : get-line ( addr len -- len' flag )
99: swap history read-line throw ;
100:
101: : next-line ( max span addr pos1 -- max span addr pos2 false )
102: clear-line
103: forward^ 2@ 2dup hist-setpos backward^ 2!
104: 2dup get-line drop
105: hist-pos forward^ 2!
106: tuck 2dup type 0 ;
107:
108: : find-prev-line ( max addr -- max span addr pos2 )
109: backward^ 2@ forward^ 2!
110: over 2 + negate s>d backward^ 2@ d+ 0. dmax 2dup hist-setpos
111: BEGIN
112: backward^ 2! 2dup get-line WHILE
113: hist-pos 2dup forward^ 2@ d< WHILE
114: rot drop
115: REPEAT 2drop THEN tuck ;
116:
117: : prev-line ( max span addr pos1 -- max span addr pos2 false )
118: clear-line find-prev-line 2dup type 0 ;
119:
120: Create lfpad #lf c,
121:
122: : (enter) ( max span addr pos1 -- max span addr pos2 true )
123: >r end^ 2@ hist-setpos
124: 2dup swap history write-line drop ( throw ) \ don't worry about errors
125: hist-pos 2dup backward^ 2! end^ 2!
126: r> (ret) ;
127:
128: \ some other key commands 16oct94py
129:
130: : first-pos ( max span addr pos1 -- max span addr 0 0 )
131: backspaces 0 0 ;
132: : end-pos ( max span addr pos1 -- max span addr span 0 )
133: type-rest 2drop over 0 ;
134:
135: : extract-word ( addr len -- addr' len' ) dup >r
136: BEGIN 1- dup 0>= WHILE 2dup + c@ bl = UNTIL THEN 1+
137: tuck + r> rot - ;
138:
139: Create prefix-found 0 , 0 ,
140:
141: : sgn ( n -- -1/0/1 )
142: dup 0= IF EXIT THEN 0< 2* 1+ ;
143:
144: : capscomp ( c_addr1 u c_addr2 -- n )
145: swap bounds
146: ?DO dup c@ I c@ <>
147: IF dup c@ toupper I c@ toupper =
148: ELSE true THEN WHILE 1+ LOOP drop 0
149: ELSE c@ toupper I c@ toupper - unloop THEN sgn ;
150:
151: : word-lex ( nfa1 nfa2 -- -1/0/1 )
152: dup 0=
153: IF
154: 2drop 1 EXIT
155: THEN
156: name>string 2>r name>string
157: dup r@ =
158: IF
159: rdrop r> capscomp 0<= EXIT
160: THEN
161: r> <
162: nip rdrop ;
163:
164: : search-voc ( addr len nfa1 nfa2 -- addr len nfa3 )
165: >r
166: BEGIN
167: dup
168: WHILE
169: >r dup r@ name>string nip <=
170: IF
171: 2dup r@ name>string drop capscomp 0=
172: IF
173: r> dup r@ word-lex
174: IF
175: dup prefix-found @ word-lex
176: 0>=
177: IF
178: rdrop dup >r
179: THEN
180: THEN
181: >r
182: THEN
183: THEN
184: r> @
185: REPEAT
186: drop r> ;
187:
188: : prefix-off ( -- ) 0 0 prefix-found 2! ;
189:
190: : prefix-string ( addr len nfa -- addr' len' )
191: dup prefix-found ! ?dup
192: IF
193: name>string rot /string rot drop
194: dup 1+ prefix-found cell+ !
195: ELSE
196: 2drop s" " prefix-off
197: THEN ;
198:
199: : search-prefix ( addr1 len1 -- addr2 len2 )
200: 0 vp dup @ 1- cells over +
201: DO I 2@ <>
202: IF I cell+ @ wordlist-id @ swap search-voc THEN
203: [ -1 cells ] Literal +LOOP
204: prefix-string ;
205:
206: : kill-expand ( max span addr pos1 -- max span addr pos2 )
207: prefix-found cell+ @ 0 ?DO (del) LOOP ;
208:
209: : tib-full? ( max span addr pos addr' len' -- max span addr pos addr1 u flag )
210: 5 pick over 4 pick + prefix-found @ 0<> - < ;
211:
212: : tab-expand ( max span addr pos1 -- max span addr pos2 0 )
213: key? IF #tab (ins) 0 EXIT THEN
214: kill-expand 2dup extract-word dup 0= IF nip EXIT THEN
215: search-prefix tib-full?
216: IF 7 emit 2drop 0 0 prefix-found 2!
217: ELSE bounds ?DO I c@ (ins) LOOP THEN
218: prefix-found @ IF bl (ins) THEN 0 ;
219:
220: : kill-prefix ( key -- key )
221: dup #tab <> IF prefix-off THEN ;
222:
223: [IFUNDEF] everyline defer everyline [THEN]
224:
225: : 8-bit-io ( -- )
226: ['] forw ctrl F bindkey
227: ['] back ctrl B bindkey
228: ['] ?del ctrl H bindkey
229: ['] eof ctrl D bindkey
230: ['] <del> ctrl X bindkey
231: ['] next-line ctrl N bindkey
232: ['] prev-line ctrl P bindkey
233: ['] clear-tib ctrl K bindkey
234: ['] first-pos ctrl A bindkey
235: ['] end-pos ctrl E bindkey
236: ['] (enter) #lf bindkey
237: ['] (enter) #cr bindkey
238: ['] tab-expand #tab bindkey
239: ['] (ins) IS insert-char
240: ['] kill-prefix IS everychar
241: ['] noop IS everyline
242: [ action-of key ] Literal IS key
243: [ action-of emit ] Literal IS emit ;
244:
245: \ UTF-8 support
246:
247: include utf-8.fs
248:
249: : utf-8-cold ( -- )
250: s" LANG" getenv s" .UTF-8" search nip nip
251: IF utf-8-io ELSE 8-bit-io THEN ;
252:
253: ' utf-8-cold INIT8 chained
254:
255: utf-8-cold
256:
257: \ initializing history
258:
259: : get-history ( addr len -- )
260: ['] force-open catch
261: ?dup-if
262: \ !! >stderr
263: \ history-file type ." : " .error cr
264: drop 2drop
265: ['] false ['] false ['] (ret)
266: else
267: to history
268: history file-size throw
269: 2dup forward^ 2! 2dup backward^ 2! end^ 2!
270: ['] next-line ['] prev-line ['] (enter)
271: endif
272: dup #lf bindkey
273: #cr bindkey
274: ctrl P bindkey
275: ctrl N bindkey
276: ;
277:
278: : history-cold ( -- )
279: history-file get-history ;
280:
281: ' history-cold INIT8 chained
282: history-cold
283:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>