File:  [gforth] / gforth / glocals.fs
Revision 1.42: download - view: text, annotated - select for diffs
Sat May 15 20:00:20 1999 UTC (24 years, 10 months ago) by anton
Branches: MAIN
CVS tags: HEAD
documentation changes
factored out f~abs and f~rel from f~

    1: \ A powerful locals implementation
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: 
   22: \ More documentation can be found in the manual and in
   23: \ http://www.complang.tuwien.ac.at/papers/ertl94l.ps.gz
   24: 
   25: \ Local variables are quite important for writing readable programs, but
   26: \ IMO (anton) they are the worst part of the standard. There they are very
   27: \ restricted and have an ugly interface.
   28: 
   29: \ So, we implement the locals wordset, but do not recommend using
   30: \ locals-ext (which is a really bad user interface for locals).
   31: 
   32: \ We also have a nice and powerful user-interface for locals: locals are
   33: \ defined with
   34: 
   35: \ { local1 local2 ... }
   36: \ or
   37: \ { local1 local2 ... -- ... }
   38: \ (anything after the -- is just a comment)
   39: 
   40: \ Every local in this list consists of an optional type specification
   41: \ and a name. If there is only the name, it stands for a cell-sized
   42: \ value (i.e., you get the value of the local variable, not it's
   43: \ address). The following type specifiers stand before the name:
   44: 
   45: \ Specifier	Type	Access
   46: \ W:		Cell	value
   47: \ W^		Cell	address
   48: \ D:		Double	value
   49: \ D^		Double	address
   50: \ F:		Float	value
   51: \ F^		Float	address
   52: \ C:		Char	value
   53: \ C^		Char	address
   54: 
   55: \ The local variables are initialized with values from the appropriate
   56: \ stack. In contrast to the examples in the standard document our locals
   57: \ take the arguments in the expected way: The last local gets the top of
   58: \ stack, the second last gets the second stack item etc. An example:
   59: 
   60: \ : CX* { F: Ar  F: Ai  F: Br  F: Bi -- Cr Ci }
   61: \ \ complex multiplication
   62: \  Ar Br f* Ai Bi f* f-
   63: \  Ar Bi f* Ai Br f* f+ ;
   64: 
   65: \ There will also be a way to add user types, but it is not yet decided,
   66: \ how. Ideas are welcome.
   67: 
   68: \ Locals defined in this manner live until (!! see below). 
   69: \ Their names can be used during this time to get
   70: \ their value or address; The addresses produced in this way become
   71: \ invalid at the end of the lifetime.
   72: 
   73: \ Values can be changed with TO, but this is not recomended (TO is a
   74: \ kludge and words lose the single-assignment property, which makes them
   75: \ harder to analyse).
   76: 
   77: \ As for the internals, we use a special locals stack. This eliminates
   78: \ the problems and restrictions of reusing the return stack and allows
   79: \ to store floats as locals: the return stack is not guaranteed to be
   80: \ aligned correctly, but our locals stack must be float-aligned between
   81: \ words.
   82: 
   83: \ Other things about the internals are pretty unclear now.
   84: 
   85: \ Currently locals may only be
   86: \ defined at the outer level and TO is not supported.
   87: 
   88: require search.fs
   89: require float.fs
   90: 
   91: : compile-@local ( n -- ) \ gforth compile-fetch-local
   92:  case
   93:     0       of postpone @local0 endof
   94:     1 cells of postpone @local1 endof
   95:     2 cells of postpone @local2 endof
   96:     3 cells of postpone @local3 endof
   97:    ( otherwise ) dup postpone @local# ,
   98:  endcase ;
   99: 
  100: : compile-f@local ( n -- ) \ gforth compile-f-fetch-local
  101:  case
  102:     0        of postpone f@local0 endof
  103:     1 floats of postpone f@local1 endof
  104:    ( otherwise ) dup postpone f@local# ,
  105:  endcase ;
  106: 
  107: \ locals stuff needed for control structures
  108: 
  109: : compile-lp+! ( n -- ) \ gforth	compile-l-p-plus-store
  110:     dup negate locals-size +!
  111:     0 over = if
  112:     else -1 cells  over = if postpone lp-
  113:     else  1 floats over = if postpone lp+
  114:     else  2 floats over = if postpone lp+2
  115:     else postpone lp+!# dup ,
  116:     then then then then drop ;
  117: 
  118: : adjust-locals-size ( n -- ) \ gforth
  119:     \ sets locals-size to n and generates an appropriate lp+!
  120:     locals-size @ swap - compile-lp+! ;
  121: 
  122: \ the locals stack grows downwards (see primitives)
  123: \ of the local variables of a group (in braces) the leftmost is on top,
  124: \ i.e. by going onto the locals stack the order is reversed.
  125: \ there are alignment gaps if necessary.
  126: \ lp must have the strictest alignment (usually float) across calls;
  127: \ for simplicity we align it strictly for every group.
  128: 
  129: slowvoc @
  130: slowvoc on \ we want a linked list for the vocabulary locals
  131: vocabulary locals \ this contains the local variables
  132: ' locals >body wordlist-id ' locals-list >body !
  133: slowvoc !
  134: 
  135: create locals-buffer 1000 allot \ !! limited and unsafe
  136:     \ here the names of the local variables are stored
  137:     \ we would have problems storing them at the normal dp
  138: 
  139: variable locals-dp \ so here's the special dp for locals.
  140: 
  141: : alignlp-w ( n1 -- n2 )
  142:     \ cell-align size and generate the corresponding code for aligning lp
  143:     aligned dup adjust-locals-size ;
  144: 
  145: : alignlp-f ( n1 -- n2 )
  146:     faligned dup adjust-locals-size ;
  147: 
  148: \ a local declaration group (the braces stuff) is compiled by calling
  149: \ the appropriate compile-pushlocal for the locals, starting with the
  150: \ righmost local; the names are already created earlier, the
  151: \ compile-pushlocal just inserts the offsets from the frame base.
  152: 
  153: : compile-pushlocal-w ( a-addr -- ) ( run-time: w -- )
  154: \ compiles a push of a local variable, and adjusts locals-size
  155: \ stores the offset of the local variable to a-addr
  156:     locals-size @ alignlp-w cell+ dup locals-size !
  157:     swap !
  158:     postpone >l ;
  159: 
  160: \ locals list operations
  161: 
  162: : common-list ( list1 list2 -- list3 ) \ gforth-internal
  163: \ list1 and list2 are lists, where the heads are at higher addresses than
  164: \ the tail. list3 is the largest sublist of both lists.
  165:  begin
  166:    2dup u<>
  167:  while
  168:    2dup u>
  169:    if
  170:      swap
  171:    then
  172:    @
  173:  repeat
  174:  drop ;
  175: 
  176: : sub-list? ( list1 list2 -- f ) \ gforth-internal
  177: \ true iff list1 is a sublist of list2
  178:  begin
  179:    2dup u<
  180:  while
  181:    @
  182:  repeat
  183:  = ;
  184: 
  185: : list-size ( list -- u ) \ gforth-internal
  186:     \ size of the locals frame represented by list
  187:     0 ( list n )
  188:     begin
  189: 	over 0<>
  190:     while
  191: 	over
  192: 	((name>)) >body @ max
  193: 	swap @ swap ( get next )
  194:     repeat
  195:     faligned nip ;
  196: 
  197: : set-locals-size-list ( list -- )
  198:     dup locals-list !
  199:     list-size locals-size ! ;
  200: 
  201: : check-begin ( list -- )
  202: \ warn if list is not a sublist of locals-list
  203:  locals-list @ sub-list? 0= if
  204:    \ !! print current position
  205:    ." compiler was overly optimistic about locals at a BEGIN" cr
  206:    \ !! print assumption and reality
  207:  then ;
  208: 
  209: : compile-pushlocal-f ( a-addr -- ) ( run-time: f -- )
  210:     locals-size @ alignlp-f float+ dup locals-size !
  211:     swap !
  212:     postpone f>l ;
  213: 
  214: : compile-pushlocal-d ( a-addr -- ) ( run-time: w1 w2 -- )
  215:     locals-size @ alignlp-w cell+ cell+ dup locals-size !
  216:     swap !
  217:     postpone swap postpone >l postpone >l ;
  218: 
  219: : compile-pushlocal-c ( a-addr -- ) ( run-time: w -- )
  220:     -1 chars compile-lp+!
  221:     locals-size @ swap !
  222:     postpone lp@ postpone c! ;
  223: 
  224: : create-local ( " name" -- a-addr )
  225:     \ defines the local "name"; the offset of the local shall be
  226:     \ stored in a-addr
  227:     create
  228: 	immediate restrict
  229: 	here 0 , ( place for the offset ) ;
  230: 
  231: : lp-offset ( n1 -- n2 )
  232: \ converts the offset from the frame start to an offset from lp and
  233: \ i.e., the address of the local is lp+locals_size-offset
  234:   locals-size @ swap - ;
  235: 
  236: : lp-offset, ( n -- )
  237: \ converts the offset from the frame start to an offset from lp and
  238: \ adds it as inline argument to a preceding locals primitive
  239:   lp-offset , ;
  240: 
  241: vocabulary locals-types \ this contains all the type specifyers, -- and }
  242: locals-types definitions
  243: 
  244: : W: ( "name" -- a-addr xt ) \ gforth w-colon
  245:     create-local
  246: 	\ xt produces the appropriate locals pushing code when executed
  247: 	['] compile-pushlocal-w
  248:     does> ( Compilation: -- ) ( Run-time: -- w )
  249:         \ compiles a local variable access
  250: 	@ lp-offset compile-@local ;
  251: 
  252: : W^ ( "name" -- a-addr xt ) \ gforth w-caret
  253:     create-local
  254: 	['] compile-pushlocal-w
  255:     does> ( Compilation: -- ) ( Run-time: -- w )
  256: 	postpone laddr# @ lp-offset, ;
  257: 
  258: : F: ( "name" -- a-addr xt ) \ gforth f-colon
  259:     create-local
  260: 	['] compile-pushlocal-f
  261:     does> ( Compilation: -- ) ( Run-time: -- w )
  262: 	@ lp-offset compile-f@local ;
  263: 
  264: : F^ ( "name" -- a-addr xt ) \ gforth f-caret
  265:     create-local
  266: 	['] compile-pushlocal-f
  267:     does> ( Compilation: -- ) ( Run-time: -- w )
  268: 	postpone laddr# @ lp-offset, ;
  269: 
  270: : D: ( "name" -- a-addr xt ) \ gforth d-colon
  271:     create-local
  272: 	['] compile-pushlocal-d
  273:     does> ( Compilation: -- ) ( Run-time: -- w )
  274: 	postpone laddr# @ lp-offset, postpone 2@ ;
  275: 
  276: : D^ ( "name" -- a-addr xt ) \ gforth d-caret
  277:     create-local
  278: 	['] compile-pushlocal-d
  279:     does> ( Compilation: -- ) ( Run-time: -- w )
  280: 	postpone laddr# @ lp-offset, ;
  281: 
  282: : C: ( "name" -- a-addr xt ) \ gforth c-colon
  283:     create-local
  284: 	['] compile-pushlocal-c
  285:     does> ( Compilation: -- ) ( Run-time: -- w )
  286: 	postpone laddr# @ lp-offset, postpone c@ ;
  287: 
  288: : C^ ( "name" -- a-addr xt ) \ gforth c-caret
  289:     create-local
  290: 	['] compile-pushlocal-c
  291:     does> ( Compilation: -- ) ( Run-time: -- w )
  292: 	postpone laddr# @ lp-offset, ;
  293: 
  294: \ you may want to make comments in a locals definitions group:
  295: ' \ alias \ ( -- ) \ core-ext,block-ext backslash
  296: \G Comment till the end of the line if @code{BLK} contains 0 (i.e.,
  297: \G while not loading a block), parse and discard the remainder of the
  298: \G parse area. Otherwise, parse and discard all subsequent characters
  299: \G in the parse area corresponding to the current line.
  300: immediate
  301: 
  302: ' ( alias ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ core,file	paren
  303: \G Comment, usually till the next @code{)}: parse and discard all
  304: \G subsequent characters in the parse area until ")" is
  305: \G encountered. During interactive input, an end-of-line also acts as
  306: \G a comment terminator. For file input, it does not; if the
  307: \G end-of-file is encountered whilst parsing for the ")" delimiter,
  308: \G Gforth will generate a warning.
  309: immediate
  310: 
  311: forth definitions
  312: 
  313: \ the following gymnastics are for declaring locals without type specifier.
  314: \ we exploit a feature of our dictionary: every wordlist
  315: \ has it's own methods for finding words etc.
  316: \ So we create a vocabulary new-locals, that creates a 'w:' local named x
  317: \ when it is asked if it contains x.
  318: 
  319: also locals-types
  320: 
  321: : new-locals-find ( caddr u w -- nfa )
  322: \ this is the find method of the new-locals vocabulary
  323: \ make a new local with name caddr u; w is ignored
  324: \ the returned nfa denotes a word that produces what W: produces
  325: \ !! do the whole thing without nextname
  326:     drop nextname
  327:     ['] W: >name ;
  328: 
  329: previous
  330: 
  331: : new-locals-reveal ( -- )
  332:   true abort" this should not happen: new-locals-reveal" ;
  333: 
  334: create new-locals-map ( -- wordlist-map )
  335: ' new-locals-find A,
  336: ' new-locals-reveal A,
  337: ' drop A, \ rehash method
  338: ' drop A,
  339: 
  340: new-locals-map mappedwordlist Constant new-locals-wl
  341: 
  342: \ slowvoc @
  343: \ slowvoc on
  344: \ vocabulary new-locals
  345: \ slowvoc !
  346: \ new-locals-map ' new-locals >body wordlist-map A! \ !! use special access words
  347: 
  348: variable old-dpp
  349: 
  350: \ and now, finally, the user interface words
  351: : { ( -- lastxt wid 0 ) \ gforth open-brace
  352:     dp old-dpp !
  353:     locals-dp dpp !
  354:     lastxt get-current
  355:     get-order new-locals-wl swap 1+ set-order
  356:     also locals definitions locals-types
  357:     0 TO locals-wordlist
  358:     0 postpone [ ; immediate
  359: 
  360: locals-types definitions
  361: 
  362: : } ( lastxt wid 0 a-addr1 xt1 ... -- ) \ gforth close-brace
  363:     \ ends locals definitions
  364:     ] old-dpp @ dpp !
  365:     begin
  366: 	dup
  367:     while
  368: 	execute
  369:     repeat
  370:     drop
  371:     locals-size @ alignlp-f locals-size ! \ the strictest alignment
  372:     previous previous
  373:     set-current lastcfa !
  374:     locals-list 0 wordlist-id - TO locals-wordlist ;
  375: 
  376: : -- ( addr wid 0 ... -- ) \ gforth dash-dash
  377:     }
  378:     [char] } parse 2drop ;
  379: 
  380: forth definitions
  381: 
  382: \ A few thoughts on automatic scopes for locals and how they can be
  383: \ implemented:
  384: 
  385: \ We have to combine locals with the control structures. My basic idea
  386: \ was to start the life of a local at the declaration point. The life
  387: \ would end at any control flow join (THEN, BEGIN etc.) where the local
  388: \ is lot live on both input flows (note that the local can still live in
  389: \ other, later parts of the control flow). This would make a local live
  390: \ as long as you expected and sometimes longer (e.g. a local declared in
  391: \ a BEGIN..UNTIL loop would still live after the UNTIL).
  392: 
  393: \ The following example illustrates the problems of this approach:
  394: 
  395: \ { z }
  396: \ if
  397: \   { x }
  398: \ begin
  399: \   { y }
  400: \ [ 1 cs-roll ] then
  401: \   ...
  402: \ until
  403: 
  404: \ x lives only until the BEGIN, but the compiler does not know this
  405: \ until it compiles the UNTIL (it can deduce it at the THEN, because at
  406: \ that point x lives in no thread, but that does not help much). This is
  407: \ solved by optimistically assuming at the BEGIN that x lives, but
  408: \ warning at the UNTIL that it does not. The user is then responsible
  409: \ for checking that x is only used where it lives.
  410: 
  411: \ The produced code might look like this (leaving out alignment code):
  412: 
  413: \ >l ( z )
  414: \ ?branch <then>
  415: \ >l ( x )
  416: \ <begin>:
  417: \ >l ( y )
  418: \ lp+!# 8 ( RIP: x,y )
  419: \ <then>:
  420: \ ...
  421: \ lp+!# -4 ( adjust lp to <begin> state )
  422: \ ?branch <begin>
  423: \ lp+!# 4 ( undo adjust )
  424: 
  425: \ The BEGIN problem also has another incarnation:
  426: 
  427: \ AHEAD
  428: \ BEGIN
  429: \   x
  430: \ [ 1 CS-ROLL ] THEN
  431: \   { x }
  432: \   ...
  433: \ UNTIL
  434: 
  435: \ should be legal: The BEGIN is not a control flow join in this case,
  436: \ since it cannot be entered from the top; therefore the definition of x
  437: \ dominates the use. But the compiler processes the use first, and since
  438: \ it does not look ahead to notice the definition, it will complain
  439: \ about it. Here's another variation of this problem:
  440: 
  441: \ IF
  442: \   { x }
  443: \ ELSE
  444: \   ...
  445: \ AHEAD
  446: \ BEGIN
  447: \   x
  448: \ [ 2 CS-ROLL ] THEN
  449: \   ...
  450: \ UNTIL
  451: 
  452: \ In this case x is defined before the use, and the definition dominates
  453: \ the use, but the compiler does not know this until it processes the
  454: \ UNTIL. So what should the compiler assume does live at the BEGIN, if
  455: \ the BEGIN is not a control flow join? The safest assumption would be
  456: \ the intersection of all locals lists on the control flow
  457: \ stack. However, our compiler assumes that the same variables are live
  458: \ as on the top of the control flow stack. This covers the following case:
  459: 
  460: \ { x }
  461: \ AHEAD
  462: \ BEGIN
  463: \   x
  464: \ [ 1 CS-ROLL ] THEN
  465: \   ...
  466: \ UNTIL
  467: 
  468: \ If this assumption is too optimistic, the compiler will warn the user.
  469: 
  470: \ Implementation:
  471: 
  472: \ explicit scoping
  473: 
  474: : scope ( compilation  -- scope ; run-time  -- ) \ gforth
  475:     cs-push-part scopestart ; immediate
  476: 
  477: : adjust-locals-list ( wid -- )
  478:     locals-list @ common-list
  479:     dup list-size adjust-locals-size
  480:     locals-list ! ;
  481: 
  482: : endscope ( compilation scope -- ; run-time  -- ) \ gforth
  483:     scope?
  484:     drop  adjust-locals-list ; immediate
  485: 
  486: \ adapt the hooks
  487: 
  488: : locals-:-hook ( sys -- sys addr xt n )
  489:     \ addr is the nfa of the defined word, xt its xt
  490:     DEFERS :-hook
  491:     last @ lastcfa @
  492:     clear-leave-stack
  493:     0 locals-size !
  494:     locals-buffer locals-dp !
  495:     0 locals-list !
  496:     dead-code off
  497:     defstart ;
  498: 
  499: : locals-;-hook ( sys addr xt sys -- sys )
  500:     def?
  501:     0 TO locals-wordlist
  502:     0 adjust-locals-size ( not every def ends with an exit )
  503:     lastcfa ! last !
  504:     DEFERS ;-hook ;
  505: 
  506: \ THEN (another control flow from before joins the current one):
  507: \ The new locals-list is the intersection of the current locals-list and
  508: \ the orig-local-list. The new locals-size is the (alignment-adjusted)
  509: \ size of the new locals-list. The following code is generated:
  510: \ lp+!# (current-locals-size - orig-locals-size)
  511: \ <then>:
  512: \ lp+!# (orig-locals-size - new-locals-size)
  513: 
  514: \ Of course "lp+!# 0" is not generated. Still this is admittedly a bit
  515: \ inefficient, e.g. if there is a locals declaration between IF and
  516: \ ELSE. However, if ELSE generates an appropriate "lp+!#" before the
  517: \ branch, there will be none after the target <then>.
  518: 
  519: : (then-like) ( orig -- )
  520:     dead-orig =
  521:     if
  522: 	>resolve drop
  523:     else
  524:         dead-code @
  525:         if
  526: 	    >resolve set-locals-size-list dead-code off
  527: 	else \ both live
  528: 	    over list-size adjust-locals-size
  529: 	    >resolve
  530: 	    adjust-locals-list
  531: 	then
  532:     then ;
  533: 
  534: : (begin-like) ( -- )
  535:     dead-code @ if
  536: 	\ set up an assumption of the locals visible here.  if the
  537: 	\ users want something to be visible, they have to declare
  538: 	\ that using ASSUME-LIVE
  539: 	backedge-locals @ set-locals-size-list
  540:     then
  541:     dead-code off ;
  542: 
  543: \ AGAIN (the current control flow joins another, earlier one):
  544: \ If the dest-locals-list is not a subset of the current locals-list,
  545: \ issue a warning (see below). The following code is generated:
  546: \ lp+!# (current-local-size - dest-locals-size)
  547: \ branch <begin>
  548: 
  549: : (again-like) ( dest -- addr )
  550:     over list-size adjust-locals-size
  551:     swap check-begin  POSTPONE unreachable ;
  552: 
  553: \ UNTIL (the current control flow may join an earlier one or continue):
  554: \ Similar to AGAIN. The new locals-list and locals-size are the current
  555: \ ones. The following code is generated:
  556: \ ?branch-lp+!# <begin> (current-local-size - dest-locals-size)
  557: 
  558: : (until-like) ( list addr xt1 xt2 -- )
  559:     \ list and addr are a fragment of a cs-item
  560:     \ xt1 is the conditional branch without lp adjustment, xt2 is with
  561:     >r >r
  562:     locals-size @ 2 pick list-size - dup if ( list dest-addr adjustment )
  563: 	r> drop r> compile,
  564: 	swap <resolve ( list adjustment ) ,
  565:     else ( list dest-addr adjustment )
  566: 	drop
  567: 	r> compile, <resolve
  568: 	r> drop
  569:     then ( list )
  570:     check-begin ;
  571: 
  572: : (exit-like) ( -- )
  573:     0 adjust-locals-size ;
  574: 
  575: ' locals-:-hook IS :-hook
  576: ' locals-;-hook IS ;-hook
  577: 
  578: ' (then-like)  IS then-like
  579: ' (begin-like) IS begin-like
  580: ' (again-like) IS again-like
  581: ' (until-like) IS until-like
  582: ' (exit-like)  IS exit-like
  583: 
  584: \ The words in the locals dictionary space are not deleted until the end
  585: \ of the current word. This is a bit too conservative, but very simple.
  586: 
  587: \ There are a few cases to consider: (see above)
  588: 
  589: \ after AGAIN, AHEAD, EXIT (the current control flow is dead):
  590: \ We have to special-case the above cases against that. In this case the
  591: \ things above are not control flow joins. Everything should be taken
  592: \ over from the live flow. No lp+!# is generated.
  593: 
  594: \ About warning against uses of dead locals. There are several options:
  595: 
  596: \ 1) Do not complain (After all, this is Forth;-)
  597: 
  598: \ 2) Additional restrictions can be imposed so that the situation cannot
  599: \ arise; the programmer would have to introduce explicit scoping
  600: \ declarations in cases like the above one. I.e., complain if there are
  601: \ locals that are live before the BEGIN but not before the corresponding
  602: \ AGAIN (replace DO etc. for BEGIN and UNTIL etc. for AGAIN).
  603: 
  604: \ 3) The real thing: i.e. complain, iff a local lives at a BEGIN, is
  605: \ used on a path starting at the BEGIN, and does not live at the
  606: \ corresponding AGAIN. This is somewhat hard to implement. a) How does
  607: \ the compiler know when it is working on a path starting at a BEGIN
  608: \ (consider "{ x } if begin [ 1 cs-roll ] else x endif again")? b) How
  609: \ is the usage info stored?
  610: 
  611: \ For now I'll resort to alternative 2. When it produces warnings they
  612: \ will often be spurious, but warnings should be rare. And better
  613: \ spurious warnings now and then than days of bug-searching.
  614: 
  615: \ Explicit scoping of locals is implemented by cs-pushing the current
  616: \ locals-list and -size (and an unused cell, to make the size equal to
  617: \ the other entries) at the start of the scope, and restoring them at
  618: \ the end of the scope to the intersection, like THEN does.
  619: 
  620: 
  621: \ And here's finally the ANS standard stuff
  622: 
  623: : (local) ( addr u -- ) \ local paren-local-paren
  624:     \ a little space-inefficient, but well deserved ;-)
  625:     \ In exchange, there are no restrictions whatsoever on using (local)
  626:     \ as long as you use it in a definition
  627:     dup
  628:     if
  629: 	nextname POSTPONE { [ also locals-types ] W: } [ previous ]
  630:     else
  631: 	2drop
  632:     endif ;
  633: 
  634: : >definer ( xt -- definer )
  635:     \ this gives a unique identifier for the way the xt was defined
  636:     \ words defined with different does>-codes have different definers
  637:     \ the definer can be used for comparison and in definer!
  638:     dup >does-code
  639:     ?dup-if
  640: 	nip 1 or
  641:     else
  642: 	>code-address
  643:     then ;
  644: 
  645: : definer! ( definer xt -- )
  646:     \ gives the word represented by xt the behaviour associated with definer
  647:     over 1 and if
  648: 	swap [ 1 invert ] literal and does-code!
  649:     else
  650: 	code-address!
  651:     then ;
  652: 
  653: :noname
  654:     ' dup >definer [ ' locals-wordlist ] literal >definer =
  655:     if
  656: 	>body !
  657:     else
  658: 	-&32 throw
  659:     endif ;
  660: :noname
  661:     0 0 0. 0.0e0 { c: clocal w: wlocal d: dlocal f: flocal }
  662:     comp' drop dup >definer
  663:     case
  664: 	[ ' locals-wordlist ] literal >definer \ value
  665: 	OF >body POSTPONE Aliteral POSTPONE ! ENDOF
  666: 	\ !! dependent on c: etc. being does>-defining words
  667: 	\ this works, because >definer uses >does-code in this case,
  668: 	\ which produces a relocatable address
  669: 	[ comp' clocal drop >definer ] literal
  670: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE c! ENDOF
  671: 	[ comp' wlocal drop >definer ] literal
  672: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE ! ENDOF
  673: 	[ comp' dlocal drop >definer ] literal
  674: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE 2! ENDOF
  675: 	[ comp' flocal drop >definer ] literal
  676: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE f! ENDOF
  677: 	-&32 throw
  678:     endcase ;
  679: interpret/compile: TO ( c|w|d|r "name" -- ) \ core-ext,local
  680: 
  681: : locals|
  682:     \ don't use 'locals|'! use '{'! A portable and free '{'
  683:     \ implementation is compat/anslocals.fs
  684:     BEGIN
  685: 	name 2dup s" |" compare 0<>
  686:     WHILE
  687: 	(local)
  688:     REPEAT
  689:     drop 0 (local) ; immediate restrict

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>