File:  [gforth] / gforth / float.fs
Revision 1.68: download - view: text, annotated - select for diffs
Mon Dec 31 15:25:18 2012 UTC (6 years, 7 months ago) by anton
Branches: MAIN
CVS tags: HEAD
updated copyright year

    1: \ High level floating point                            14jan94py
    2: 
    3: \ Copyright (C) 1995,1997,2003,2004,2005,2006,2007,2009,2010,2011,2012 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: \ 1 cells 4 = [IF]
   21: \ ' cells   Alias sfloats
   22: \ ' cell+   Alias sfloat+
   23: \ ' align   Alias sfalign
   24: \ ' aligned Alias sfaligned
   25: \ [ELSE]
   26: \ : sfloats  2* 2* ;
   27: \ : sfloat+  4 + ;
   28: \ : sfaligned ( addr -- addr' )  3 + -4 and ;
   29: \ : sfalign ( -- )  here dup sfaligned swap ?DO  bl c,  LOOP ;
   30: \ [THEN]
   31: 
   32: \ 1 floats 8 = [IF]
   33: \ ' floats   Alias dfloats
   34: \ ' float+   Alias dfloat+
   35: \ ' falign   Alias dfalign
   36: \ ' faligned Alias dfaligned
   37: \ [ELSE]
   38: \ : dfloats  2* 2* 2* ;
   39: \ : dfloat+  8 + ;
   40: \ : dfaligned ( addr -- addr' )  7 + -8 and ;
   41: \ : dfalign ( -- )  here dup dfaligned swap ?DO  bl c,  LOOP ;
   42: \ [THEN]
   43: 
   44: : sfalign ( -- ) \ float-ext s-f-align
   45:     \G If the data-space pointer is not single-float-aligned, reserve
   46:     \G enough space to align it.
   47:     here dup sfaligned swap ?DO  bl c,  LOOP ;
   48: : dfalign ( -- ) \ float-ext d-f-align
   49:     \G If the data-space pointer is not double-float-aligned, reserve
   50:     \G enough space to align it.
   51:     here dup dfaligned swap ?DO  bl c,  LOOP ;
   52: 
   53: (Field) sfloat+ ( sf-addr1 -- sf-addr2 ) \ float-ext s-float-plus
   54: \G @code{1 sfloats +}.
   55:     1 sfloats ,
   56: 
   57: (Field) dfloat+ ( df-addr1 -- df-addr2 ) \ float-ext d-float-plus
   58: \G @code{1 dfloats +}.
   59:     1 dfloats ,
   60:     
   61: : f, ( f -- ) \ gforth
   62:     \G Reserve data space for one floating-point number and store
   63:     \G @i{f} in the space.
   64:     here 1 floats allot f! ;
   65: 
   66: : fconstant  ( r "name" -- ) \ float f-constant
   67:     Create f,
   68: DOES> ( -- r )
   69:     f@ ;
   70: 
   71: : fdepth ( -- +n ) \ float f-depth
   72:     \G @i{+n} is the current number of (floating-point) values on the
   73:     \G floating-point stack.
   74:     fp0 @ fp@ - [ 1 floats ] Literal / ;
   75: 
   76: : FLiteral ( compilation r -- ; run-time -- r ) \ float f-literal
   77:     \G Compile appropriate code such that, at run-time, @i{r} is placed
   78:     \G on the (floating-point) stack. Interpretation semantics are undefined.
   79:     BEGIN  here cell+ cell+ dup faligned <>  WHILE  postpone noop  REPEAT
   80:     postpone ahead here >r f, postpone then
   81:     r> postpone literal postpone f@ ;  immediate
   82: 
   83: &15 Value precision ( -- u ) \ float-ext
   84: \G @i{u} is the number of significant digits currently used by
   85: \G @code{F.} @code{FE.} and @code{FS.} 
   86: : set-precision ( u -- ) \ float-ext
   87:     \G Set the number of significant digits currently used by
   88:     \G @code{F.} @code{FE.} and @code{FS.} to @i{u}.
   89:     to precision ;
   90: 
   91: : scratch ( -- addr len )
   92:   pad precision - precision ;
   93: 
   94: : zeros ( n -- )   0 max 0 ?DO  '0 emit  LOOP ;
   95: 
   96: : -zeros ( addr u -- addr' u' )
   97:   BEGIN  dup  WHILE  1- 2dup + c@ '0 <>  UNTIL  1+  THEN ;
   98: 
   99: : f$ ( f -- n )  scratch represent 0=
  100:   IF  2drop  scratch 3 min type  rdrop  EXIT  THEN
  101:   IF  '- emit  THEN ;
  102: 
  103: : f.  ( r -- ) \ float-ext f-dot
  104: \G Display (the floating-point number) @i{r} without exponent,
  105: \G followed by a space.
  106:   f$ dup >r 0<=
  107:   IF    '0 emit
  108:   ELSE  scratch r@ min type  r@ precision - zeros  THEN
  109:   '. emit r@ negate zeros
  110:   scratch r> 0 max /string 0 max -zeros type space ;
  111: \ I'm afraid this does not really implement ansi semantics wrt precision.
  112: \ Shouldn't precision indicate the number of places shown after the point?
  113: 
  114: \ Why do you think so? ANS Forth appears ambiguous on this point. -anton.
  115: 
  116: : fe. ( r -- ) \ float-ext f-e-dot
  117: \G Display @i{r} using engineering notation (with exponent dividable
  118: \G by 3), followed by a space.
  119:   f$ 1- s>d 3 fm/mod 3 * >r 1+ >r
  120:   scratch r@ tuck min tuck - >r type r> zeros
  121:   '. emit scratch r> /string type
  122:   'E emit r> . ;
  123: 
  124: : fs. ( r -- ) \ float-ext f-s-dot
  125: \G Display @i{r} using scientific notation (with exponent), followed
  126: \G by a space.
  127:   f$ 1-
  128:   scratch over c@ emit '. emit 1 /string type
  129:   'E emit . ;
  130: 
  131: [IFDEF] fp-char
  132: : sfnumber ( c-addr u -- r true | false )
  133:     fp-char @ >float1 ;
  134: 
  135: Create si-prefixes ," PTGMk munpf"
  136: si-prefixes count bl scan drop Constant zero-exp
  137: 
  138: : prefix-number ( c-addr u -- r true | false )
  139:     si-prefixes count bounds DO
  140: 	2dup I c@ scan nip dup 0<> IF
  141: 	    1 = IF  1- fp-char @  ELSE  I c@  THEN
  142: 	    >float1
  143: 	    dup IF  1000 s>f zero-exp I - s>f f** f*  THEN
  144: 	    UNLOOP  EXIT  THEN  drop
  145:     LOOP
  146:     sfnumber ;
  147: [ELSE]
  148: : sfnumber ( c-addr u -- r true | false )
  149:     >float ;
  150: : prefix-number  sfnumber ;
  151: [THEN]
  152: 
  153: [ifdef] recognizer:
  154:     [IFDEF] 2lit,
  155: 	: flit, postpone Fliteral ;
  156: 	:noname ['] noop ;
  157: 	:noname ['] flit, ;
  158:     [ELSE]
  159: 	' noop
  160: 	:noname postpone Fliteral ;
  161:     [THEN]
  162:     dup
  163:     recognizer: r:fnumber
  164: 
  165:     : fnum-recognizer ( addr u -- float int-table | addr u r:fail )
  166: 	2dup prefix-number
  167: 	IF
  168: 	    2drop r:fnumber  EXIT
  169: 	THEN
  170: 	r:fail ;
  171: 
  172: ' fnum-recognizer
  173: forth-recognizer get-recognizers
  174: 1+ forth-recognizer set-recognizers
  175: [else]
  176: [ifundef] compiler-notfound1
  177: defer compiler-notfound1
  178: ' no.extensions IS compiler-notfound1
  179: 
  180: :noname compiler-notfound1 execute ; is compiler-notfound
  181: 
  182: defer interpreter-notfound1
  183: ' no.extensions IS interpreter-notfound1
  184: 
  185: :noname interpreter-notfound1 execute ; is interpreter-notfound
  186: [then]
  187: 
  188: :noname ( c-addr u -- ... xt )
  189:     2dup sfnumber
  190:     IF
  191: 	2drop [comp'] FLiteral
  192:     ELSE
  193: 	defers compiler-notfound1
  194:     ENDIF ;
  195: IS compiler-notfound1
  196: 
  197: :noname ( c-addr u -- ... xt )
  198:     2dup sfnumber
  199:     IF
  200: 	2drop ['] noop
  201:     ELSE
  202: 	defers interpreter-notfound1
  203:     ENDIF ;
  204: IS interpreter-notfound1
  205: [then]
  206: 
  207: : fvariable ( "name" -- ) \ float f-variable
  208:     Create 0.0E0 f, ;
  209:     \ does> ( -- f-addr )
  210: 
  211: 1.0e0 fasin 2.0e0 f* fconstant pi ( -- r ) \ gforth
  212: \G @code{Fconstant} -- @i{r} is the value pi; the ratio of a circle's area
  213: \G to its diameter.
  214: 
  215: : f2* ( r1 -- r2 ) \ gforth
  216:     \G Multiply @i{r1} by 2.0e0
  217:     2.0e0 f* ;
  218: 
  219: : f2/ ( r1 -- r2 ) \ gforth
  220:     \G Multiply @i{r1} by 0.5e0
  221:     0.5e0 f* ;
  222: 
  223: : 1/f ( r1 -- r2 ) \ gforth
  224:     \G Divide 1.0e0 by @i{r1}.
  225:     1.0e0 fswap f/ ;
  226: 
  227: get-current environment-wordlist set-current
  228: 1.7976931348623157e308 FConstant max-float
  229: set-current
  230: 
  231: \ We now have primitives for these, so we need not define them
  232: 
  233: \ : falog ( f -- 10^f )  [ 10.0e0 fln ] FLiteral f* fexp ;
  234: 
  235: \ : fsinh    fexpm1 fdup fdup 1.0e0 f+ f/ f+ f2/ ;
  236: \ : fcosh    fexp fdup 1/f f+ f2/ ;
  237: \ : ftanh    f2* fexpm1 fdup 2.0e0 f+ f/ ;
  238: 
  239: \ : fatanh   fdup f0< >r fabs 1.0e0 fover f- f/  f2* flnp1 f2/
  240: \            r> IF  fnegate  THEN ;
  241: \ : facosh   fdup fdup f* 1.0e0 f- fsqrt f+ fln ;
  242: \ : fasinh   fdup fdup f* 1.0e0 f+ fsqrt f/ fatanh ;
  243: 
  244: : f~abs ( r1 r2 r3 -- flag ) \ gforth
  245:     \G Approximate equality with absolute error: |r1-r2|<r3.
  246:     frot frot f- fabs fswap f< ;
  247: 
  248: : f~rel ( r1 r2 r3 -- flag ) \ gforth
  249:     \G Approximate equality with relative error: |r1-r2|<r3*|r1+r2|.
  250: 	frot frot fover fabs fover fabs f+ frot frot
  251: 	f- fabs frot frot f* f< ;
  252: 
  253: : f~ ( r1 r2 r3 -- flag ) \ float-ext f-proximate
  254:     \G ANS Forth medley for comparing r1 and r2 for equality: r3>0:
  255:     \G @code{f~abs}; r3=0: bitwise comparison; r3<0: @code{fnegate f~rel}.
  256:     fdup f0=
  257:     IF \ bitwise comparison
  258: 	fp@ float+ 1 floats over float+ over str=
  259: 	fdrop fdrop fdrop
  260: 	EXIT
  261:     THEN
  262:     fdup f0>
  263:     IF
  264: 	f~abs
  265:     ELSE
  266: 	fnegate f~rel
  267:     THEN ;
  268: 
  269: -0e 8 0 [do] fp@ [i] + c@ $80 = [if] [i] constant fsign-offset [then] [loop]
  270: 
  271: : fcopysign ( r1 r2 -- r3 ) \ gforth
  272: \G r3 takes its absolute value from r1 and its sign from r2
  273:     \ !! implementation relies on IEEE DP format
  274:     fp@ fsign-offset + dup c@ $80 and >r ( r1 r2 addr-r1sign )
  275:     float+ dup c@ $7f and r> or swap c!
  276:     fdrop ;
  277: 
  278: \ proposals from Krishna Myeni in <cjsp2d$47l$1@ngspool-d02.news.aol.com>
  279: \ not sure if they are a good idea
  280: 
  281: : ftrunc ( r1 -- r2 ) \ X:ftrunc
  282:     \ round towards 0
  283:     fdup fabs floor fswap fcopysign ;
  284: 
  285: : FMOD ( r1 r2 -- r )
  286:     \ remainder of r1/r2
  287:     FOVER FOVER F/ ftrunc F* F- ;
  288: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>