File:  [gforth] / gforth / float.fs
Revision 1.13: download - view: text, annotated - select for diffs
Mon Feb 6 18:14:33 1995 UTC (24 years, 8 months ago) by anton
Branches: MAIN
CVS tags: HEAD
The bodies of words are now maxaligned

    1: \ High level floating point                            14jan94py
    2: 
    3: 1 cells 4 = [IF]
    4: ' cells   Alias sfloats
    5: ' cell+   Alias sfloat+
    6: ' align   Alias sfalign
    7: ' aligned Alias sfaligned
    8: [ELSE]
    9: : sfloats  2* 2* ;
   10: : sfloat+  4 + ;
   11: : sfaligned ( addr -- addr' )  3 + -4 and ;
   12: : sfalign ( -- )  here dup sfaligned swap ?DO  bl c,  LOOP ;
   13: [THEN]
   14: 
   15: 1 floats 8 = [IF]
   16: ' floats   Alias dfloats
   17: ' float+   Alias dfloat+
   18: ' falign   Alias dfalign
   19: ' faligned Alias dfaligned
   20: [ELSE]
   21: : dfloats  2* 2* 2* ;
   22: : dfloat+  8 + ;
   23: : dfaligned ( addr -- addr' )  7 + -8 and ;
   24: : dfalign ( -- )  here dup dfaligned swap ?DO  bl c,  LOOP ;
   25: [THEN]
   26: 
   27: : f, ( f -- )  here 1 floats allot f! ;
   28: 
   29: : fconstant  ( r -- )
   30:     Create f,
   31:     DOES> f@ ;
   32: 
   33: : fdepth  ( -- n )  f0 @ fp@ - [ 1 floats ] Literal / ;
   34: 
   35: : FLit ( -- r )  r> faligned dup f@ float+ >r ;
   36: : FLiteral ( r -- )  postpone FLit  falign f, ;  immediate
   37: 
   38: &15 Value precision
   39: : set-precision  to precision ;
   40: 
   41: : scratch ( r -- addr len )
   42:   pad precision - precision ;
   43: 
   44: : zeros ( n -- )   0 max 0 ?DO  '0 emit  LOOP ;
   45: 
   46: : -zeros ( addr u -- addr' u' )
   47:   BEGIN  dup  WHILE  1- 2dup + c@ '0 <>  UNTIL  1+  THEN ;
   48: 
   49: : f$ ( f -- n )  scratch represent 0=
   50:   IF  2drop  scratch 3 min type  rdrop  EXIT  THEN
   51:   IF  '- emit  THEN ;
   52: 
   53: : f.  ( r -- )  f$ dup >r 0<
   54:   IF    '0 emit
   55:   ELSE  scratch r@ min type  r@ precision - zeros  THEN
   56:   '. emit r@ negate zeros
   57:   scratch r> 0 max /string 0 max -zeros type space ;
   58: \ I'm afraid this does not really implement ansi semantics wrt precision.
   59: \ Shouldn't precision indicate the number of places shown after the point?
   60: 
   61: : fe. ( r -- )  f$ 1- s>d 3 fm/mod 3 * >r 1+ >r
   62:   scratch r@ min type '. emit  scratch r> /string type
   63:   'E emit r> . ;
   64: 
   65: : fs. ( r -- )  f$ 1-
   66:   scratch over c@ emit '. emit 1 /string type
   67:   'E emit . ;
   68: 
   69: : sfnumber ( c-addr u -- r / )
   70:     2dup >float
   71:     IF
   72: 	2drop state @
   73: 	IF
   74: 	    postpone FLiteral
   75: 	THEN
   76:     ELSE
   77: 	defers notfound
   78:     THEN ;
   79: 
   80: ' sfnumber IS notfound
   81: 
   82: : fvariable ( -- )
   83:     Create 0e0 f, ;
   84:     \ does> ( -- f-addr )
   85: 
   86: 1e0 fasin 2e0 f* fconstant pi
   87: 
   88: : f2*  2e0 f* ;
   89: : f2/  .5e0 f* ;
   90: : 1/f  1e0 fswap f/ ;
   91: 
   92: 
   93: \ We now have primitives for these, so we need not define them
   94: 
   95: \ : falog ( f -- 10^f )  [ 10e0 fln ] FLiteral f* fexp ;
   96: 
   97: \ : fsinh    fexpm1 fdup fdup 1e0 f+ f/ f+ f2/ ;
   98: \ : fcosh    fexp fdup 1/f f+ f2/ ;
   99: \ : ftanh    f2* fexpm1 fdup 2e0 f+ f/ ;
  100: 
  101: \ : fatanh   fdup f0< >r fabs 1e0 fover f- f/  f2* flnp1 f2/
  102: \            r> IF  fnegate  THEN ;
  103: \ : facosh   fdup fdup f* 1e0 f- fsqrt f+ fln ;
  104: \ : fasinh   fdup fdup f* 1e0 f+ fsqrt f/ fatanh ;
  105: 
  106: : f~ ( f1 f2 f3 -- flag )  fdup f0= IF  fdrop f= EXIT  THEN
  107:   fdup f0>   IF  frot frot f- fabs fswap
  108:            ELSE  fnegate frot frot fover fabs fover fabs f+ frot frot
  109:                  f- fabs frot frot f*  THEN  f< ;
  110: 
  111: : f.s  ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0 
  112:   ?DO  dup i - 1- floats fp@ + f@ f.  LOOP  drop ; 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>