File:  [gforth] / gforth / fi2c.fs
Revision 1.15: download - view: text, annotated - select for diffs
Sat Feb 17 21:04:15 2007 UTC (12 years, 7 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Changed fi2c so that the included C image can be relocated at read time
Added a libc definition to lib.fs

    1: \ Convert image to C include file
    2: 
    3: \ Copyright (C) 1998,1999,2002,2003 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: require string.fs
   22: 
   23: 0 Value image
   24: 0 Value bitmap
   25: 
   26: Create magicbuf 8 allot
   27: 
   28: Create groups 32 0 [DO] 512 cells allocate throw dup 512 cells erase , [LOOP]
   29: 
   30: : prefix? ( string u1 prefix u2 -- flag )
   31:     tuck 2>r umin 2r> str= ;
   32: 
   33: : read-groups ( addr u -- )
   34:     r/o open-file throw >r  0 0
   35:     BEGIN  pad $100 r@ read-line throw  WHILE
   36: 	    pad swap 2dup s" GROUP(" prefix?
   37: 	    IF  2drop drop 1+ 0  ELSE
   38: 		2dup s" INST_ADDR(" prefix?
   39: 		IF  &10 /string 2dup ') scan nip -
   40: 		    2over cells swap cells groups + @ + $!
   41: 		    1+
   42: 		ELSE  2drop  THEN  THEN
   43:     REPEAT
   44:     2drop r> close-file throw ;
   45: s" prim_lab.i" read-groups
   46: 
   47: Variable bswap?
   48: Variable endian
   49: Variable tchars
   50: Variable tcell
   51: Variable au
   52: 
   53: : t@ ( addr -- x )
   54:     endian @ IF
   55: 	0 swap tcell @ bounds ?DO
   56: 	    8 lshift I c@ or
   57: 	LOOP
   58:     ELSE
   59: 	0 swap tcell @ bounds ?DO
   60: 	    8 rshift I c@ 8 tcell @ 1- * lshift or
   61: 	LOOP
   62:     THEN
   63:     dup 1 8 tcell @ * 1- lshift and negate or ;
   64: 
   65: 1 cells 4 = [IF]
   66: : bswap ( n -- n' )  bswap? @ 0= ?EXIT  0
   67:     over 24 rshift $FF       and or
   68:     over  8 rshift $FF00     and or
   69:     over  8 lshift $FF0000   and or
   70:     over 24 lshift $FF000000 and or nip ;
   71: [THEN]
   72: 
   73: 1 cells 8 = [IF]
   74: : bswap ( n -- n' )  bswap? @ 0= ?EXIT  0
   75:     over 56 rshift $FF               and or
   76:     over 40 rshift $FF00             and or
   77:     over 24 rshift $FF0000           and or
   78:     over  8 rshift $FF000000         and or
   79:     over  8 lshift $FF00000000       and or
   80:     over 24 lshift $FF0000000000     and or
   81:     over 40 lshift $FF000000000000   and or
   82:     over 56 lshift $FF00000000000000 and or
   83:     nip ;
   84: [THEN]
   85: 
   86: : search-magic ( fd -- )  >r
   87:     BEGIN  magicbuf 8 r@ read-file throw  8 =  WHILE
   88: 	magicbuf s" Gforth3" tuck str=  UNTIL
   89:     ELSE  true abort" No magic found"  THEN
   90:     1 magicbuf 7 + c@ 5 rshift 3 and lshift tchars !
   91:     1 magicbuf 7 + c@ 1 rshift 3 and lshift tcell !
   92:     1 magicbuf 7 + c@ 3 rshift 3 and lshift au !
   93:     magicbuf 7 + c@ 1 and 0= dup endian !
   94:     [ pad off 1 pad ! pad c@ 1 = ] Literal = bswap? !
   95:     ." /* Image with " tcell @ . ." bytes cell, " tchars @ . ." bytes per char and " au @ . ." bytes per address unit */" cr
   96:     rdrop ;
   97: 
   98: Create image-header  4 cells allot
   99: Variable image-cells
  100: Variable bitmap-chars
  101: 
  102: : read-header ( fd -- )
  103:     image-header 4 tcell @ * rot read-file throw drop
  104:     image-header 2 tcell @ * + t@ tchars @ * tcell @ / au @ /
  105:     dup image-cells ! 1- 8 / tchars @ / 1+ bitmap-chars !
  106:     image-cells @ tcell @ * allocate throw to image
  107:     bitmap-chars @ allocate throw to bitmap ;
  108: 
  109: : read-dictionary ( fd -- )  >r
  110:     image image-cells @ tcell @ * r> read-file throw drop ;
  111: 
  112: : read-bitmap ( fd -- )  >r
  113:     bitmap bitmap-chars @ tchars @ * r> read-file throw drop ;
  114: 
  115: : .08x ( n -- ) 0 <# tcell  @ 0 ?DO # # LOOP 'x hold '0 hold #> type ;
  116: : .02x ( n -- ) 0 <# tchars @ 0 ?DO # # LOOP 'x hold '0 hold #> type ;
  117: 
  118: : bit@ ( addr n -- flag )
  119:     dup 7 and $80 swap rshift >r 3 rshift + c@ r> and
  120:     0<> ;
  121: 
  122: : .image ( -- )
  123:     image-cells @ 0 ?DO
  124: 	I 1 + I' min I ?DO  space image I tcell @ * + t@
  125: 	    bitmap I bit@ IF
  126: 		dup 0< IF
  127: 		    negate dup $3E00 and 9 rshift swap $1FF and
  128: 		    over cells groups + @ over $1FF and cells +
  129: 		    dup @ 0= IF  drop
  130: 			2dup 0 8 d= IF  2drop s" doesjump"
  131: 			ELSE
  132: 			    <# '] hold 0 #S 2drop '[ hold '] hold
  133: 			    0 #S '[ hold #>
  134: 			THEN
  135: 		    ELSE
  136: 			>r 2drop r> $@
  137: 		    THEN
  138: 		    ." &&" type
  139: 		ELSE
  140: 		    ." image+" tcell @ / .08x
  141: 		THEN
  142: 	    ELSE
  143: 		.08x
  144: 	    THEN  ." ,"
  145: 	LOOP cr
  146:     1 +LOOP ;
  147: 
  148: : .reloc ( -- )
  149:     bitmap-chars @ tchars @ * 0 ?DO
  150: 	I $10 + I' min I ?DO  space
  151: 	    0 I tchars @ bounds ?DO  8 lshift bitmap I + c@ +  LOOP
  152: 	    .02x ." ," tchars @ +LOOP cr
  153: 	$10 +LOOP ;
  154: 
  155: : read-image ( addr u -- )
  156:     r/o bin open-file throw >r
  157:     r@ search-magic
  158:     r@ file-position throw r@ read-header r@ reposition-file throw
  159:     r@ read-dictionary r@ read-bitmap r> close-file throw ;
  160: 
  161: : .imagesize ( -- )
  162:     image-header 3 tcell @ * + t@ tchars @ * tcell @ / au @ / .08x ;
  163: 
  164: : .relocsize ( -- )
  165:     bitmap-chars @ .08x ;
  166: 
  167: : fi2c ( addr u -- )  base @ >r hex
  168:     read-image
  169:     ." #include " '" emit ." forth.h" '" emit cr
  170:     ." void* image[" .imagesize ." ] = {" cr .image ." };" cr
  171:     ." const char reloc_bits[" .relocsize ." ] = {" cr .reloc ." };" cr
  172:     r> base ! ;
  173: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>