File:  [gforth] / gforth / fi2c.fs
Revision 1.11: download - view: text, annotated - select for diffs
Wed Nov 21 10:01:47 2001 UTC (22 years, 4 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
fixed fi2c.fs address size bug

    1: \ Convert image to C include file
    2: 
    3: \ Copyright (C) 1998,1999 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 0 Value image
   22: 0 Value bitmap
   23: 
   24: Create magicbuf 8 allot
   25: 
   26: Variable bswap?
   27: Variable tchars
   28: Variable tcell
   29: Variable au
   30: 
   31: : bswap ( n -- n' )  bswap? @ 0= ?EXIT  0
   32:     over 24 rshift $FF       and or
   33:     over  8 rshift $FF00     and or
   34:     over  8 lshift $FF0000   and or
   35:     over 24 lshift $FF000000 and or nip ;
   36: 
   37: : search-magic ( fd -- )  >r
   38:     BEGIN  magicbuf 8 r@ read-file throw  8 =  WHILE
   39: 	magicbuf s" Gforth2" tuck compare 0=  UNTIL
   40:     ELSE  true abort" No magic found"  THEN
   41:     1 magicbuf 7 + c@ 5 rshift 3 and lshift tchars !
   42:     1 magicbuf 7 + c@ 1 rshift 3 and lshift tcell !
   43:     1 magicbuf 7 + c@ 3 rshift 3 and lshift au !
   44:     magicbuf 7 + c@ 1 and 0=
   45:     [ pad off 1 pad ! pad c@ 1 = ] Literal = bswap? !
   46:     ." /* Image with " tcell @ . ." bytes cell, " tchars @ . ." bytes per char and " au @ . ." bytes per address unit */" cr
   47:     rdrop ;
   48: 
   49: Create image-header  4 cells allot
   50: Variable image-cells
   51: Variable bitmap-chars
   52: 
   53: : read-header ( fd -- )
   54:     image-header 4 cells rot read-file throw drop
   55:     image-header 2 cells + @ bswap tchars @ * tcell @ / au @ /
   56:     dup image-cells ! 1- 8 / tchars @ / 1+ bitmap-chars !
   57:     image-cells @ cells allocate throw to image
   58:     bitmap-chars @ allocate throw to bitmap ;
   59: 
   60: : read-dictionary ( fd -- )  >r
   61:     image image-cells @ cells r> read-file throw drop ;
   62: 
   63: : read-bitmap ( fd -- )  >r
   64:     bitmap bitmap-chars @ tchars @ * r> read-file throw drop ;
   65: 
   66: : .08x ( n -- ) 0 <# tcell  @ 0 ?DO # # LOOP 'x hold '0 hold #> type ;
   67: : .02x ( n -- ) 0 <# tchars @ 0 ?DO # # LOOP 'x hold '0 hold #> type ;
   68: 
   69: : .image ( -- )
   70:     image-cells @ 0 ?DO
   71: 	I 4 + I' min I ?DO  space image I cells + @ bswap .08x ." ," LOOP cr
   72: 	4 +LOOP ;
   73: 
   74: : .reloc ( -- )
   75:     bitmap-chars @ tchars @ * 0 ?DO
   76: 	I $10 + I' min I ?DO  space
   77: 	    0 I tchars @ bounds ?DO  8 lshift bitmap I + c@ +  LOOP
   78: 	    .02x ." ," tchars @ +LOOP cr
   79: 	$10 +LOOP ;
   80: 
   81: : read-image ( addr u -- )
   82:     r/o bin open-file throw >r
   83:     r@ search-magic
   84:     r@ file-position throw r@ read-header r@ reposition-file throw
   85:     r@ read-dictionary r@ read-bitmap r> close-file throw ;
   86: 
   87: : .imagesize ( -- )
   88:     image-header 3 cells + @ tchars @ * tcell @ / au @ / bswap .08x ;
   89: 
   90: : .relocsize ( -- )
   91:     bitmap-chars @ .08x ;
   92: 
   93: : fi2c ( addr u -- )  base @ >r hex
   94:     read-image
   95:     ." #include " '" emit ." forth.h" '" emit cr
   96:     ." Cell image[" .imagesize ." ] = {" cr .image ." };" cr
   97:     ." const char reloc_bits[" .relocsize ." ] = {" cr .reloc ." };" cr
   98:     r> base ! ;
   99: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>