1: \ lib.fs shared library support package 16aug03py
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: Variable libs 0 libs !
22: \ links between libraries
23: Variable thisproc
24: Variable thislib
25:
26: Variable revdec revdec off
27: \ turn revdec on to compile bigFORTH libraries
28: Variable revarg revarg off
29: \ turn revarg on to compile declarations with reverse arguments
30: Variable legacy legacy off
31: \ turn legacy on to compile bigFORTH legacy libraries
32:
33: Vocabulary c-decl
34: Vocabulary cb-decl
35:
36: : @lib ( lib -- )
37: \G obtains library handle
38: cell+ dup 2 cells + count open-lib
39: dup 0= abort" Library not found" swap ! ;
40:
41: : @proc ( lib addr -- )
42: \G obtains symbol address
43: cell+ tuck cell+ @ count rot cell+ @
44: lib-sym dup 0= abort" Proc not found!" swap ! ;
45:
46: : proc, ( lib -- )
47: \G allocates and initializes proc stub
48: \G stub format:
49: \G linked list in library
50: \G address of proc
51: \G ptr to OS name of symbol as counted string
52: \G threaded code for invocation
53: here dup thisproc !
54: swap 2 cells + dup @ A, !
55: 0 , 0 A, ;
56:
57: Defer legacy-proc ' noop IS legacy-proc
58:
59: : proc: ( lib "name" -- )
60: \G Creates a named proc stub
61: Create proc, 0 also c-decl
62: legacy @ IF legacy-proc THEN
63: DOES> ( x1 .. xn -- r )
64: dup cell+ @ swap 3 cells + >r ;
65:
66: : library ( "name" "file" -- )
67: \G loads library "file" and creates a proc defining word "name"
68: \G library format:
69: \G linked list of libraries
70: \G library handle
71: \G linked list of library's procs
72: \G OS name of library as counted string
73: Create here libs @ A, dup libs !
74: 0 , 0 A, parse-name string, @lib
75: DOES> ( -- ) dup thislib ! proc: ;
76:
77: : init-shared-libs ( -- )
78: defers 'cold libs
79: 0 libs BEGIN @ dup WHILE dup REPEAT drop
80: BEGIN dup WHILE >r
81: r@ @lib
82: r@ 2 cells + BEGIN @ dup WHILE r@ over @proc REPEAT
83: drop rdrop
84: REPEAT drop ;
85:
86: ' init-shared-libs IS 'cold
87:
88: : argtype ( revxt pushxt fwxt "name" -- )
89: Create , , , ;
90:
91: : arg@ ( arg -- argxt pushxt )
92: revarg @ IF 2 cells + @ ['] noop swap ELSE 2@ THEN ;
93:
94: : arg, ( xt -- )
95: dup ['] noop = IF drop EXIT THEN compile, ;
96:
97: : decl, ( 0 arg1 .. argn call start -- )
98: 2@ compile, >r
99: revdec @ IF 0 >r
100: BEGIN dup WHILE >r REPEAT
101: BEGIN r> dup WHILE arg@ arg, REPEAT drop
102: BEGIN dup WHILE arg, REPEAT drop
103: ELSE 0 >r
104: BEGIN dup WHILE arg@ arg, >r REPEAT drop
105: BEGIN r> dup WHILE arg, REPEAT drop
106: THEN
107: r> compile, postpone EXIT ;
108:
109: : symbol, ( "c-symbol" -- )
110: here thisproc @ 2 cells + ! parse-name s,
111: thislib @ thisproc @ @proc ;
112:
113: : rettype ( endxt startxt "name" -- )
114: Create 2,
115: DOES> decl, symbol, previous revarg off ;
116:
117: also c-decl definitions
118:
119: : <rev> revarg on ;
120:
121: ' av-int ' av-int-r ' >r argtype int
122: ' av-float ' av-float-r ' f>l argtype sf
123: ' av-double ' av-double-r ' f>l argtype df
124: ' av-longlong ' av-longlong-r ' 2>r argtype llong
125: ' av-ptr ' av-ptr-r ' >r argtype ptr
126:
127: ' av-call-void ' av-start-void rettype (void)
128: ' av-call-int ' av-start-int rettype (int)
129: ' av-call-float ' av-start-float rettype (sf)
130: ' av-call-double ' av-start-double rettype (fp)
131: ' av-call-longlong ' av-start-longlong rettype (llong)
132: ' av-call-ptr ' av-start-ptr rettype (ptr)
133:
134: : (addr) postpone EXIT drop symbol, previous revarg off ;
135:
136: previous definitions
137:
138: \ legacy support for old library interfaces
139: \ interface to old vararg stuff not implemented yet
140:
141: also c-decl
142:
143: :noname ( n 0 -- 0 int1 .. intn )
144: legacy @ 0< revarg !
145: swap 0 ?DO int LOOP (int)
146: ; IS legacy-proc
147:
148: : (int) ( n -- )
149: >r ' execute r> 0 ?DO int LOOP (int) ;
150: : (void) ( n -- )
151: >r ' execute r> 0 ?DO int LOOP (void) ;
152: : (float) ( n -- )
153: >r ' execute r> 0 ?DO df LOOP (fp) ;
154:
155: previous
156:
157: \ callback stuff
158:
159: Variable callbacks
160: \G link between callbacks
161:
162: : callback ( -- )
163: Create 0 ] postpone >r also cb-decl
164: DOES>
165: Create here >r 0 , callbacks @ A, r@ callbacks !
166: swap postpone Literal postpone call , postpone EXIT
167: r> dup cell+ cell+ alloc-callback swap !
168: DOES> @ ;
169:
170: : callback; ( 0 xt1 .. xtn -- )
171: BEGIN over WHILE compile, REPEAT
172: postpone r> postpone execute compile, drop
173: postpone EXIT postpone [ previous ; immediate
174:
175: : va-ret ( xt xt -- )
176: Create A, A, immediate
177: DOES> 2@ compile, ;
178:
179: : init-callbacks ( -- )
180: defers 'cold callbacks 1 cells -
181: BEGIN cell+ @ dup WHILE dup cell+ cell+ alloc-callback over !
182: REPEAT drop ;
183:
184: ' init-callbacks IS 'cold
185:
186: also cb-decl definitions
187:
188: \ arguments
189:
190: ' va-arg-int Alias int
191: ' va-arg-float Alias sf
192: ' va-arg-double Alias df
193: ' va-arg-longlong Alias llong
194: ' va-arg-ptr Alias ptr
195:
196: ' va-return-void ' va-start-void va-ret (void)
197: ' va-return-int ' va-start-int va-ret (int)
198: ' va-return-float ' va-start-float va-ret (sf)
199: ' va-return-double ' va-start-double va-ret (fp)
200: ' va-return-longlong ' va-start-longlong va-ret (llong)
201: ' va-return-ptr ' va-start-ptr va-ret (ptr)
202:
203: previous definitions
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>