Return to extend.fs CVS log

Up to [gforth] / gforth

threw out blocks.fs:include (would confuse users)
added dictionary-end
script? is now set correctly
look and represent now work correctly on the Alpha

    1: \ EXTEND.FS    CORE-EXT Word not fully tested!         12may93jaw
    2: 
    3: \ Copyright (C) 1995 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: 
   22: \ May be cross-compiled
   23: 
   24: decimal
   25: 
   26: \ .(                                                    12may93jaw
   27: 
   28: : .(   ( compilation "...<paren>" -- ) \ core-ext dot-paren
   29:     [char] ) parse type ; immediate
   30: 
   31: \ VALUE 2>R 2R> 2R@                                     17may93jaw
   32: 
   33: \ !! 2value
   34: 
   35: : 2Literal ( compilation w1 w2 -- ; run-time  -- w1 w2 ) \ double two-literal
   36:     swap postpone Literal  postpone Literal ; immediate restrict
   37: 
   38: ' drop alias d>s ( d -- n ) \ double		d_to_s
   39: 
   40: : m*/ ( d1 n2 u3 -- dqout ) \ double m-star-slash
   41:     >r s>d >r abs -rot
   42:     s>d r> xor r> swap >r >r dabs rot tuck um* 2swap um*
   43:     swap >r 0 d+ r> -rot r@ um/mod -rot r> um/mod nip swap
   44:     r> IF dnegate THEN ;
   45: 
   46: \ CASE OF ENDOF ENDCASE                                 17may93jaw
   47: 
   48: \ just as described in dpANS5
   49: 
   50: 0 CONSTANT case ( compilation  -- case-sys ; run-time  -- ) \ core-ext
   51:     immediate
   52: 
   53: : of ( compilation  -- of-sys ; run-time x1 x2 -- |x1 ) \ core-ext
   54:     \ !! the implementation does not match the stack effect
   55:     1+ >r
   56:     postpone over postpone = postpone if postpone drop
   57:     r> ; immediate
   58: 
   59: : endof ( compilation case-sys1 of-sys -- case-sys2 ; run-time  -- ) \ core-ext end-of
   60:     >r postpone else r> ; immediate
   61: 
   62: : endcase ( compilation case-sys -- ; run-time x -- ) \ core-ext end-case
   63:     postpone drop
   64:     0 ?do postpone then loop ; immediate
   65: 
   66: \ C"                                                    17may93jaw
   67: 
   68: : (c")     "lit ;
   69: 
   70: : CLiteral
   71:     postpone (c") here over char+ allot  place align ; immediate restrict
   72: 
   73: : C" ( compilation "...<quote>" -- ; run-time  -- c-addr ) \ core-ext c-quote
   74:     [char] " parse postpone CLiteral ; immediate restrict
   75: 
   76: \ UNUSED                                                17may93jaw
   77: 
   78: : dictionary-end ( -- addr )
   79:     forthstart dup 3 cells + @ + ;
   80: 
   81: : unused ( -- u ) \ core-ext
   82:     dictionary-end here - ;
   83: 
   84: \ [COMPILE]                                             17may93jaw
   85: 
   86: : [compile] ( compilation "name" -- ; run-time ? -- ? ) \ core-ext bracket-compile
   87:     ' compile, ; immediate
   88: 
   89: \ MARKER                                                17may93jaw
   90: 
   91: \ : marker here last @ create , , DOES> dup @ last ! cell+ @ dp ! ;
   92: \ doesn't work now. vocabularies?
   93: 
   94: \ CONVERT                                               17may93jaw
   95: 
   96: : convert ( ud1 c-addr1 -- ud2 c-addr2 ) \ core-ext
   97:     \ obsolescent; superseded by @code{>number}.
   98:     true >number drop ;
   99: 
  100: \ ERASE                                                 17may93jaw
  101: 
  102: : erase ( addr len -- ) \ core-ext
  103:     \ !! dependence on "1 chars 1 ="
  104:     ( 0 1 chars um/mod nip )  0 fill ;
  105: : blank ( addr len -- ) \ string
  106:     bl fill ;
  107: 
  108: \ SEARCH                                                02sep94py
  109: 
  110: : search   ( buf buflen text textlen -- restbuf restlen flag ) \ string
  111:     2over  2 pick - 1+ 3 pick c@ >r
  112:     BEGIN
  113: 	r@ scan dup
  114:     WHILE
  115: 	>r >r  2dup r@ -text
  116: 	0=
  117: 	IF
  118: 	    >r drop 2drop r> r> r> rot + 1- rdrop true
  119: 	    EXIT
  120: 	THEN
  121: 	r> r>  1 /string
  122:     REPEAT
  123:     2drop 2drop  rdrop false ;
  124: 
  125: \ SOURCE-ID SAVE-INPUT RESTORE-INPUT                    11jun93jaw
  126: 
  127: : source-id ( -- 0 | -1 | fileid ) \ core-ext,file source-i-d
  128:   loadfile @ dup 0= IF  drop sourceline# 0 min  THEN ;
  129: 
  130: : save-input ( -- x1 .. xn n ) \ core-ext
  131:     >in @
  132:     loadfile @
  133:     if
  134: 	loadfile @ file-position throw
  135:     else
  136: 	blk @
  137: 	linestart @
  138:     then
  139:     sourceline#
  140:     >tib @
  141:     source-id
  142:     6 ;
  143: 
  144: : restore-input ( x1 .. xn n -- flag ) \ core-ext
  145:     6 <> -12 and throw
  146:     source-id <> -12 and throw
  147:     >tib !
  148:     >r ( line# )
  149:     loadfile @ 0<>
  150:     if
  151: 	loadfile @ reposition-file throw
  152:     else
  153: 	linestart !
  154: 	blk !
  155: 	sourceline# r@ <> blk @ 0= and loadfile @ 0= and
  156: 	if
  157: 	    drop rdrop true EXIT
  158: 	then
  159:     then
  160:     r> loadline !
  161:     >in !
  162:     false ;
  163: 
  164: \ This things we don't need, but for being complete... jaw
  165: 
  166: \ EXPECT SPAN                                           17may93jaw
  167: 
  168: variable span ( -- a-addr ) \ core-ext
  169: \ obsolescent
  170: 
  171: : expect ( c-addr +len -- ) \ core-ext
  172:     \ obsolescent; use accept
  173:     0 rot over
  174:     BEGIN ( maxlen span c-addr pos1 )
  175: 	key decode ( maxlen span c-addr pos2 flag )
  176: 	>r 2over = r> or
  177:     UNTIL
  178:     2 pick swap /string type
  179:     nip span ! ;
  180: