File:  [gforth] / gforth / extend.fs
Revision 1.31: download - view: text, annotated - select for diffs
Sat Dec 19 13:43:17 1998 UTC (25 years, 3 months ago) by anton
Branches: MAIN
CVS tags: v0-4-0, HEAD
markers now reset included-files
fixed another bug in marker
added/changed some comments

    1: \ EXTEND.FS    CORE-EXT Word not fully tested!         12may93jaw
    2: 
    3: \ Copyright (C) 1995,1998 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: 
   22: \ May be cross-compiled
   23: 
   24: decimal
   25: 
   26: \ .(                                                    12may93jaw
   27: 
   28: : .(   ( compilation "...<paren>" -- ) \ core-ext dot-paren
   29:     [char] ) parse type ; immediate
   30: 
   31: \ VALUE 2>R 2R> 2R@                                     17may93jaw
   32: 
   33: \ !! 2value
   34: 
   35: : 2Literal ( compilation w1 w2 -- ; run-time  -- w1 w2 ) \ double two-literal
   36:     swap postpone Literal  postpone Literal ; immediate restrict
   37: 
   38: ' drop alias d>s ( d -- n ) \ double		d_to_s
   39: 
   40: : m*/ ( d1 n2 u3 -- dqout ) \ double m-star-slash
   41:     >r s>d >r abs -rot
   42:     s>d r> xor r> swap >r >r dabs rot tuck um* 2swap um*
   43:     swap >r 0 d+ r> -rot r@ um/mod -rot r> um/mod nip swap
   44:     r> IF dnegate THEN ;
   45: 
   46: \ CASE OF ENDOF ENDCASE                                 17may93jaw
   47: 
   48: \ just as described in dpANS5
   49: 
   50: 0 CONSTANT case ( compilation  -- case-sys ; run-time  -- ) \ core-ext
   51:     immediate
   52: 
   53: : of ( compilation  -- of-sys ; run-time x1 x2 -- |x1 ) \ core-ext
   54:     \ !! the implementation does not match the stack effect
   55:     1+ >r
   56:     postpone over postpone = postpone if postpone drop
   57:     r> ; immediate
   58: 
   59: : endof ( compilation case-sys1 of-sys -- case-sys2 ; run-time  -- ) \ core-ext end-of
   60:     >r postpone else r> ; immediate
   61: 
   62: : endcase ( compilation case-sys -- ; run-time x -- ) \ core-ext end-case
   63:     postpone drop
   64:     0 ?do postpone then loop ; immediate
   65: 
   66: \ C"                                                    17may93jaw
   67: 
   68: : (c")     "lit ;
   69: 
   70: : CLiteral
   71:     postpone (c") here over char+ allot  place align ; immediate restrict
   72: 
   73: : C" ( compilation "...<quote>" -- ; run-time  -- c-addr ) \ core-ext c-quote
   74:     [char] " parse postpone CLiteral ; immediate restrict
   75: 
   76: \ [COMPILE]                                             17may93jaw
   77: 
   78: : [compile] ( compilation "name" -- ; run-time ? -- ? ) \ core-ext bracket-compile
   79:     comp' drop compile, ; immediate
   80: 
   81: \ CONVERT                                               17may93jaw
   82: 
   83: : convert ( ud1 c-addr1 -- ud2 c-addr2 ) \ core-ext
   84:     \G obsolescent; superseded by @code{>number}.
   85:     char+ true >number drop ;
   86: 
   87: \ ERASE                                                 17may93jaw
   88: 
   89: : erase ( addr len -- ) \ core-ext
   90:     \ !! dependence on "1 chars 1 ="
   91:     ( 0 1 chars um/mod nip )  0 fill ;
   92: : blank ( addr len -- ) \ string
   93:     bl fill ;
   94: 
   95: \ SEARCH                                                02sep94py
   96: 
   97: : search ( c-addr1 u1 c-addr2 u2 -- c-addr3 u3 flag ) \ string
   98:     \ not very efficient; but if we want efficiency, we'll do it as primitive
   99:     2>r 2dup
  100:     begin
  101: 	dup r@ >=
  102:     while
  103: 	over 2r@ swap -text 0= if
  104: 	    2swap 2drop 2r> 2drop true exit
  105: 	endif
  106: 	1 /string
  107:     repeat
  108:     2drop 2r> 2drop false ;
  109: 
  110: \ SOURCE-ID SAVE-INPUT RESTORE-INPUT                    11jun93jaw
  111: 
  112: : source-id ( -- 0 | -1 | fileid ) \ core-ext,file source-i-d
  113:   loadfile @ dup 0= IF  drop sourceline# 0 min  THEN ;
  114: 
  115: : save-input ( -- x1 .. xn n ) \ core-ext
  116:     >in @
  117:     loadfile @
  118:     if
  119: 	loadfile @ file-position throw
  120:     else
  121: 	blk @
  122: 	linestart @
  123:     then
  124:     sourceline#
  125:     >tib @
  126:     source-id
  127:     6 ;
  128: 
  129: : restore-input ( x1 .. xn n -- flag ) \ core-ext
  130:     6 <> -12 and throw
  131:     source-id <> -12 and throw
  132:     >tib !
  133:     >r ( line# )
  134:     loadfile @ 0<>
  135:     if
  136: 	loadfile @ reposition-file throw
  137:     else
  138: 	linestart !
  139: 	blk !
  140: 	sourceline# r@ <> blk @ 0= and loadfile @ 0= and
  141: 	if
  142: 	    drop rdrop true EXIT
  143: 	then
  144:     then
  145:     r> loadline !
  146:     >in !
  147:     false ;
  148: 
  149: \ This things we don't need, but for being complete... jaw
  150: 
  151: \ EXPECT SPAN                                           17may93jaw
  152: 
  153: variable span ( -- a-addr ) \ core-ext
  154: \ obsolescent
  155: 
  156: : expect ( c-addr +len -- ) \ core-ext
  157:     \ obsolescent; use accept
  158:     0 rot over
  159:     BEGIN ( maxlen span c-addr pos1 )
  160: 	key decode ( maxlen span c-addr pos2 flag )
  161: 	>r 2over = r> or
  162:     UNTIL
  163:     2 pick swap /string type
  164:     nip span ! ;
  165: 
  166: \ marker                                               18dec94py
  167: 
  168: \ Marker creates a mark that is removed (including everything 
  169: \ defined afterwards) when executing the mark.
  170: 
  171: : included-files-mark ( -- u )
  172:     included-files 2@ nip
  173:     blk @ 0=
  174:     if \ not input from blocks
  175: 	source-id 1 -1 within
  176: 	if \ input from file
  177: 	    1- \ do not include the last file (hopefully this is the
  178: 	       \ currently included file)
  179: 	then
  180:     then ;  
  181: 
  182: \ hmm, most of the saving appears to be pretty unnecessary: we could
  183: \ derive the wordlists and the words that have to be kept from the
  184: \ saved value of dp value. - anton
  185: 
  186: : marker, ( -- mark )
  187:     here
  188:     included-files-mark ,
  189:     dup A, \ here
  190:     voclink @ A, \ vocabulary list start
  191:     \ for all wordlists, remember wordlist-id (the linked list)
  192:     voclink
  193:     BEGIN
  194: 	@ dup
  195:     WHILE
  196: 	dup 0 wordlist-link - wordlist-id @ A,
  197:     REPEAT
  198:     drop
  199:     \ remember udp
  200:     udp @ , ;
  201: 
  202: : marker! ( mark -- )
  203:     \ reset included files count; resize will happen on next add-included-file
  204:     included-files 2@ drop over @ included-files 2! cell+
  205:     \ rest of marker!
  206:     dup @ swap cell+ ( here rest-of-marker )
  207:     dup @ voclink ! cell+
  208:     \ restore wordlists to former words
  209:     voclink
  210:     BEGIN
  211: 	@ dup 
  212:     WHILE
  213: 	over @ over 0 wordlist-link - wordlist-id !
  214: 	swap cell+ swap
  215:     REPEAT
  216:     drop
  217:     \ rehash wordlists to remove forgotten words
  218:     \ why don't we do this in a single step? - anton
  219:     voclink
  220:     BEGIN
  221: 	@ dup
  222:     WHILE
  223: 	dup 0 wordlist-link - rehash
  224:     REPEAT
  225:     drop
  226:     \ restore udp and dp
  227:     @ udp !  dp !
  228:     \ clean up vocabulary stack
  229:     0 vp @ 0
  230:     ?DO
  231: 	vp cell+ I cells + @ dup here >
  232: 	IF  drop  ELSE  swap 1+  THEN
  233:     LOOP
  234:     dup 0= or set-order \ -1 set-order if order is empty
  235:     get-current here > IF
  236: 	forth-wordlist set-current
  237:     THEN ;
  238: 
  239: : marker ( "mark" -- )
  240:     marker, Create A,
  241: DOES> ( -- )
  242:     @ marker! ;
  243: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>