File:  [gforth] / gforth / debugs.fs
Revision 1.2: download - view: text, annotated - select for diffs
Thu Jul 31 16:17:07 1997 UTC (22 years ago) by anton
Branches: MAIN
CVS tags: HEAD
Added documentation for structures and object.fs
Changed representation of structures from "size align" to "align size",
   and renamed 1 cells: to cell% etc.
added %size and %alignment
fixed search bug
added command-line option --die-on-signal

\ Simple debugging aids

\ Copyright (C) 1995 Free Software Foundation, Inc.

\ This file is part of Gforth.

\ Gforth is free software; you can redistribute it and/or
\ modify it under the terms of the GNU General Public License
\ as published by the Free Software Foundation; either version 2
\ of the License, or (at your option) any later version.

\ This program is distributed in the hope that it will be useful,
\ but WITHOUT ANY WARRANTY; without even the implied warranty of
\ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
\ GNU General Public License for more details.

\ You should have received a copy of the GNU General Public License
\ along with this program; if not, write to the Free Software
\ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.


\ They are meant to support a different style of debugging than the
\ tracing/stepping debuggers used in languages with long turn-around
\ times.

\ IMO, a much better (faster) way in fast-compilig languages is to add
\ printing code at well-selected places, let the program run, look at
\ the output, see where things went wrong, add more printing code, etc.,
\ until the bug is found.

\ We support fast insertion and removal of the printing code.

\ !!Warning: the default debugging actions will destroy the contents
\ of the pictured numeric output string (i.e., don't use ~~ between <#
\ and #>).

require source.fs

defer printdebugdata ( -- ) \ gforth
' .s IS printdebugdata
defer printdebugline ( addr -- ) \ gforth

: (printdebugline) ( addr -- )
    cr print-sourcepos ." :"
    \ it would be nice to print the name of the following word,
    \ but that's not easily possible for primitives
    printdebugdata
    cr ;

' (printdebugline) IS printdebugline

: (~~) ( -- )
    r@ printdebugline
    r> sourcepos %size + >r ;

: ~~ ( compilation  -- ; run-time  -- ) \ gforth tilde-tilde
    POSTPONE (~~) sourcepos, ; immediate


FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>