1: \ CROSS.FS The Cross-Compiler 06oct92py
2: \ Idea and implementation: Bernd Paysan (py)
3:
4: \ Copyright (C) 1995,1996,1997,1998,1999,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
5:
6: \ This file is part of Gforth.
7:
8: \ Gforth is free software; you can redistribute it and/or
9: \ modify it under the terms of the GNU General Public License
10: \ as published by the Free Software Foundation; either version 2
11: \ of the License, or (at your option) any later version.
12:
13: \ This program is distributed in the hope that it will be useful,
14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: \ GNU General Public License for more details.
17:
18: \ You should have received a copy of the GNU General Public License
19: \ along with this program; if not, write to the Free Software
20: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
21:
22: 0
23: [IF]
24:
25: ToDo:
26: - Crossdoc destination ./doc/crossdoc.fd makes no sense when
27: cross.fs is used seperately. jaw
28: - Do we need this char translation with >address and in branchoffset?
29: (>body also affected) jaw
30:
31: [THEN]
32:
33: s" compat/strcomp.fs" included
34:
35: hex
36:
37: \ debugging for compiling
38:
39: \ print stack at each colon definition
40: \ : : save-input cr bl word count type restore-input throw .s : ;
41:
42: \ print stack at each created word
43: \ : create save-input cr bl word count type restore-input throw .s create ;
44:
45:
46: \ \ ------------- Setup Vocabularies
47:
48: \ Remark: Vocabulary is not ANS, but it should work...
49:
50: Vocabulary Cross
51: Vocabulary Target
52: Vocabulary Ghosts
53: Vocabulary Minimal
54: only Forth also Target also also
55: definitions Forth
56:
57: : T previous Ghosts also Target ; immediate
58: : G Ghosts ; immediate
59: : H previous Forth also Cross ; immediate
60:
61: forth definitions
62:
63: : T previous Ghosts also Target ; immediate
64: : G Ghosts ; immediate
65:
66:
67: : >cross also Cross definitions previous ;
68: : >target also Target definitions previous ;
69: : >minimal also Minimal definitions previous ;
70:
71: H
72:
73: >CROSS
74:
75: \ Test against this definitions to find out whether we are cross-compiling
76: \ may be usefull for assemblers
77: 0 Constant gforth-cross-indicator
78:
79: \ find out whether we are compiling with gforth
80:
81: : defined? bl word find nip ;
82: defined? emit-file defined? toupper and \ drop 0
83: [IF]
84: \ use this in a gforth system
85: : \GFORTH ; immediate
86: : \ANSI postpone \ ; immediate
87: [ELSE]
88: : \GFORTH postpone \ ; immediate
89: : \ANSI ; immediate
90: [THEN]
91:
92: \ANSI : [IFUNDEF] defined? 0= postpone [IF] ; immediate
93: \ANSI : [IFDEF] defined? postpone [IF] ; immediate
94: 0 \ANSI drop 1
95: [IF]
96: : \G postpone \ ; immediate
97: : rdrop postpone r> postpone drop ; immediate
98: : name bl word count ;
99: : bounds over + swap ;
100: : scan >r BEGIN dup WHILE over c@ r@ <> WHILE 1 /string REPEAT THEN rdrop ;
101: : linked here over @ , swap ! ;
102: : alias create , DOES> @ EXECUTE ;
103: : defer ['] noop alias ;
104: : is state @
105: IF ' >body postpone literal postpone !
106: ELSE ' >body ! THEN ; immediate
107: : 0>= 0< 0= ;
108: : d<> rot <> -rot <> or ;
109: : toupper dup [char] a [char] z 1+ within IF [char] A [char] a - + THEN ;
110: Variable ebuf
111: : emit-file ( c fd -- ior ) swap ebuf c! ebuf 1 chars rot write-file ;
112: 0a Constant #lf
113: 0d Constant #cr
114:
115: [IFUNDEF] Warnings Variable Warnings [THEN]
116:
117: \ \ Number parsing 23feb93py
118:
119: \ number? number 23feb93py
120:
121: Variable dpl
122:
123: hex
124: Create bases 10 , 2 , A , 100 ,
125: \ 16 2 10 character
126:
127: \ !! protect BASE saving wrapper against exceptions
128: : getbase ( addr u -- addr' u' )
129: over c@ [char] $ - dup 4 u<
130: IF
131: cells bases + @ base ! 1 /string
132: ELSE
133: drop
134: THEN ;
135:
136: : sign? ( addr u -- addr u flag )
137: over c@ [char] - = dup >r
138: IF
139: 1 /string
140: THEN
141: r> ;
142:
143: : s>unumber? ( addr u -- ud flag )
144: over [char] ' =
145: IF \ a ' alone is rather unusual :-)
146: drop char+ c@ 0 true EXIT
147: THEN
148: base @ >r dpl on getbase
149: 0. 2swap
150: BEGIN ( d addr len )
151: dup >r >number dup
152: WHILE \ there are characters left
153: dup r> -
154: WHILE \ the last >number parsed something
155: dup 1- dpl ! over c@ [char] . =
156: WHILE \ the current char is '.'
157: 1 /string
158: REPEAT THEN \ there are unparseable characters left
159: 2drop false
160: ELSE
161: rdrop 2drop true
162: THEN
163: r> base ! ;
164:
165: \ ouch, this is complicated; there must be a simpler way - anton
166: : s>number? ( addr len -- d f )
167: \ converts string addr len into d, flag indicates success
168: sign? >r
169: s>unumber?
170: 0= IF
171: rdrop false
172: ELSE \ no characters left, all ok
173: r>
174: IF
175: dnegate
176: THEN
177: true
178: THEN ;
179:
180: : s>number ( addr len -- d )
181: \ don't use this, there is no way to tell success
182: s>number? drop ;
183:
184: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
185: s>number? 0=
186: IF
187: 2drop false EXIT
188: THEN
189: dpl @ dup 0< IF
190: nip
191: ELSE
192: 1+
193: THEN ;
194:
195: : number? ( string -- string 0 / n -1 / d 0> )
196: dup >r count snumber? dup if
197: rdrop
198: else
199: r> swap
200: then ;
201:
202: : number ( string -- d )
203: number? ?dup 0= abort" ?" 0<
204: IF
205: s>d
206: THEN ;
207:
208: [THEN]
209:
210: \ this provides assert( and struct stuff
211: \GFORTH [IFUNDEF] assert1(
212: \GFORTH also forth definitions require assert.fs previous
213: \GFORTH [THEN]
214:
215: >CROSS
216:
217: hex \ the defualt base for the cross-compiler is hex !!
218: \ Warnings off
219:
220: \ words that are generaly useful
221:
222: : KB 400 * ;
223: : >wordlist ( vocabulary-xt -- wordlist-struct )
224: also execute get-order swap >r 1- set-order r> ;
225:
226: : umax 2dup u< IF swap THEN drop ;
227: : umin 2dup u> IF swap THEN drop ;
228:
229: : string, ( c-addr u -- )
230: \ puts down string as cstring
231: dup c, here swap chars dup allot move ;
232:
233: : ," [char] " parse string, ;
234:
235: : SetValue ( n -- <name> )
236: \G Same behaviour as "Value" if the <name> is not defined
237: \G Same behaviour as "to" if <name> is defined
238: \G SetValue searches in the current vocabulary
239: save-input bl word >r restore-input throw r> count
240: get-current search-wordlist
241: IF drop >r
242: \ we have to set current to be topmost context wordlist
243: get-order get-order get-current swap 1+ set-order
244: r> ['] to execute
245: set-order
246: ELSE Value THEN ;
247:
248: : DefaultValue ( n -- <name> )
249: \G Same behaviour as "Value" if the <name> is not defined
250: \G DefaultValue searches in the current vocabulary
251: save-input bl word >r restore-input throw r> count
252: get-current search-wordlist
253: IF bl word drop 2drop ELSE Value THEN ;
254:
255: hex
256:
257: \ FIXME delete`
258: \ 1 Constant Cross-Flag \ to check whether assembler compiler plug-ins are
259: \ for cross-compiling
260: \ No! we use "[IFUNDEF]" there to find out whether we are target compiling!!!
261:
262: \ FIXME move down
263: : comment? ( c-addr u -- c-addr u )
264: 2dup s" (" str=
265: IF postpone (
266: ELSE 2dup s" \" str= IF postpone \ THEN
267: THEN ;
268:
269: : X ( -- <name> )
270: \G The next word in the input is a target word.
271: \G Equivalent to T <name> but without permanent
272: \G switch to target dictionary. Used as prefix e.g. for @, !, here etc.
273: bl word count [ ' target >wordlist ] Literal search-wordlist
274: IF state @ IF compile, ELSE execute THEN
275: ELSE -1 ABORT" Cross: access method not supported!"
276: THEN ; immediate
277:
278: \ Begin CROSS COMPILER:
279:
280: \ debugging
281:
282: 0 [IF]
283:
284: This implements debugflags for the cross compiler and the compiled
285: images. It works identical to the has-flags in the environment.
286: The debugflags are defined in a vocabluary. If the word exists and
287: its value is true, the flag is switched on.
288:
289: [THEN]
290:
291: >CROSS
292:
293: Vocabulary debugflags \ debug flags for cross
294: also debugflags get-order over
295: Constant debugflags-wl
296: set-order previous
297:
298: : DebugFlag
299: get-current >r debugflags-wl set-current
300: SetValue
301: r> set-current ;
302:
303: : Debug? ( adr u -- flag )
304: \G return true if debug flag is defined or switched on
305: debugflags-wl search-wordlist
306: IF EXECUTE
307: ELSE false THEN ;
308:
309: : D? ( <name> -- flag )
310: \G return true if debug flag is defined or switched on
311: \G while compiling we do not return the current value but
312: bl word count debug? ;
313:
314: : [d?]
315: \G compile the value-xt so the debug flag can be switched
316: \G the flag must exist!
317: bl word count debugflags-wl search-wordlist
318: IF compile,
319: ELSE -1 ABORT" unknown debug flag"
320: \ POSTPONE false
321: THEN ; immediate
322:
323: : symentry ( adr len taddr -- )
324: \G Produce a symbol table (an optional symbol address
325: \G map) if wanted
326: [ [IFDEF] fd-symbol-table ]
327: base @ swap hex s>d <# 8 0 DO # LOOP #> fd-symbol-table write-file throw base !
328: s" :" fd-symbol-table write-file throw
329: fd-symbol-table write-line throw
330: [ [ELSE] ]
331: 2drop drop
332: [ [THEN] ] ;
333:
334:
335: \ \ -------------------- source file
336:
337: decimal
338:
339: Variable cross-file-list
340: 0 cross-file-list !
341: Variable target-file-list
342: 0 target-file-list !
343: Variable host-file-list
344: 0 host-file-list !
345:
346: cross-file-list Value file-list
347: 0 Value source-desc
348:
349: \ file loading
350:
351: : >fl-id 1 cells + ;
352: : >fl-name 2 cells + ;
353:
354: Variable filelist 0 filelist !
355: Create NoFile ," #load-file#"
356:
357: : loadfile ( -- adr )
358: source-desc ?dup IF >fl-name ELSE NoFile THEN ;
359:
360: : sourcefilename ( -- adr len )
361: loadfile count ;
362:
363: \ANSI : sourceline# 0 ;
364:
365: \ \ -------------------- path handling from kernel/paths.fs
366:
367: \ paths.fs path file handling 03may97jaw
368:
369: \ -Changing the search-path:
370: \ fpath+ <path> adds a directory to the searchpath
371: \ fpath= <path>|<path> makes complete now searchpath
372: \ seperator is |
373: \ .fpath displays the search path
374: \ remark I:
375: \ a ./ in the beginning of filename is expanded to the directory the
376: \ current file comes from. ./ can also be included in the search-path!
377: \ ~+/ loads from the current working directory
378:
379: \ remark II:
380: \ if there is no sufficient space for the search path increase it!
381:
382:
383: \ -Creating custom paths:
384:
385: \ It is possible to use the search mechanism on yourself.
386:
387: \ Make a buffer for the path:
388: \ create mypath 100 chars , \ maximum length (is checked)
389: \ 0 , \ real len
390: \ 100 chars allot \ space for path
391: \ use the same functions as above with:
392: \ mypath path+
393: \ mypath path=
394: \ mypath .path
395:
396: \ do a open with the search path:
397: \ open-path-file ( adr len path -- fd adr len ior )
398: \ the file is opened read-only; if the file is not found an error is generated
399:
400: \ questions to: wilke@jwdt.com
401:
402: [IFUNDEF] +place
403: : +place ( adr len adr )
404: 2dup >r >r
405: dup c@ char+ + swap move
406: r> r> dup c@ rot + swap c! ;
407: [THEN]
408:
409: [IFUNDEF] place
410: : place ( c-addr1 u c-addr2 )
411: 2dup c! char+ swap move ;
412: [THEN]
413:
414: \ if we have path handling, use this and the setup of it
415: [IFUNDEF] open-fpath-file
416:
417: create sourcepath 1024 chars , 0 , 1024 chars allot \ !! make this dynamic
418: sourcepath value fpath
419:
420: : also-path ( adr len path^ -- )
421: >r
422: \ len check
423: r@ cell+ @ over + r@ @ u> ABORT" path buffer too small!"
424: \ copy into
425: tuck r@ cell+ dup @ cell+ + swap cmove
426: \ make delimiter
427: 0 r@ cell+ dup @ cell+ + 2 pick + c! 1 + r> cell+ +!
428: ;
429:
430: : only-path ( adr len path^ -- )
431: dup 0 swap cell+ ! also-path ;
432:
433: : path+ ( path-addr "dir" -- ) \ gforth
434: \G Add the directory @var{dir} to the search path @var{path-addr}.
435: name rot also-path ;
436:
437: : fpath+ ( "dir" ) \ gforth
438: \G Add directory @var{dir} to the Forth search path.
439: fpath path+ ;
440:
441: : path= ( path-addr "dir1|dir2|dir3" ) \ gforth
442: \G Make a complete new search path; the path separator is |.
443: name 2dup bounds ?DO i c@ [char] | = IF 0 i c! THEN LOOP
444: rot only-path ;
445:
446: : fpath= ( "dir1|dir2|dir3" ) \ gforth
447: \G Make a complete new Forth search path; the path separator is |.
448: fpath path= ;
449:
450: : path>string cell+ dup cell+ swap @ ;
451:
452: : next-path ( adr len -- adr2 len2 )
453: 2dup 0 scan
454: dup 0= IF 2drop 0 -rot 0 -rot EXIT THEN
455: >r 1+ -rot r@ 1- -rot
456: r> - ;
457:
458: : previous-path ( path^ -- )
459: dup path>string
460: BEGIN tuck dup WHILE repeat ;
461:
462: : .path ( path-addr -- ) \ gforth
463: \G Display the contents of the search path @var{path-addr}.
464: path>string
465: BEGIN next-path dup WHILE type space REPEAT 2drop 2drop ;
466:
467: : .fpath ( -- ) \ gforth
468: \G Display the contents of the Forth search path.
469: fpath .path ;
470:
471: : absolut-path? ( addr u -- flag ) \ gforth
472: \G A path is absolute if it starts with a / or a ~ (~ expansion),
473: \G or if it is in the form ./*, extended regexp: ^[/~]|./, or if
474: \G it has a colon as second character ("C:..."). Paths simply
475: \G containing a / are not absolute!
476: 2dup 2 u> swap 1+ c@ [char] : = and >r \ dos absoulte: c:/....
477: over c@ [char] / = >r
478: over c@ [char] ~ = >r
479: \ 2dup S" ../" string-prefix? r> or >r \ not catered for in expandtopic
480: S" ./" string-prefix?
481: r> r> r> or or or ;
482:
483: Create ofile 0 c, 255 chars allot
484: Create tfile 0 c, 255 chars allot
485:
486: : pathsep? dup [char] / = swap [char] \ = or ;
487:
488: : need/ ofile dup c@ + c@ pathsep? 0= IF s" /" ofile +place THEN ;
489:
490: : extractpath ( adr len -- adr len2 )
491: BEGIN dup WHILE 1-
492: 2dup + c@ pathsep? IF EXIT THEN
493: REPEAT ;
494:
495: : remove~+ ( -- )
496: ofile count s" ~+/" string-prefix?
497: IF
498: ofile count 3 /string ofile place
499: THEN ;
500:
501: : expandtopic ( -- ) \ stack effect correct? - anton
502: \ expands "./" into an absolute name
503: ofile count s" ./" string-prefix?
504: IF
505: ofile count 1 /string tfile place
506: 0 ofile c! sourcefilename extractpath ofile place
507: ofile c@ IF need/ THEN
508: tfile count over c@ pathsep? IF 1 /string THEN
509: ofile +place
510: THEN ;
511:
512: : compact.. ( adr len -- adr2 len2 )
513: \ deletes phrases like "xy/.." out of our directory name 2dec97jaw
514: over swap
515: BEGIN dup WHILE
516: dup >r '/ scan 2dup s" /../" string-prefix?
517: IF
518: dup r> - >r 4 /string over r> + 4 -
519: swap 2dup + >r move dup r> over -
520: ELSE
521: rdrop dup 1 min /string
522: THEN
523: REPEAT drop over - ;
524:
525: : reworkdir ( -- )
526: remove~+
527: ofile count compact..
528: nip ofile c! ;
529:
530: : open-ofile ( -- fid ior )
531: \G opens the file whose name is in ofile
532: expandtopic reworkdir
533: ofile count r/o open-file ;
534:
535: : check-path ( adr1 len1 adr2 len2 -- fd 0 | 0 <>0 )
536: 0 ofile ! >r >r ofile place need/
537: r> r> ofile +place
538: open-ofile ;
539:
540: : open-path-file ( addr1 u1 path-addr -- wfileid addr2 u2 0 | ior ) \ gforth
541: \G Look in path @var{path-addr} for the file specified by @var{addr1 u1}.
542: \G If found, the resulting path and an open file descriptor
543: \G are returned. If the file is not found, @var{ior} is non-zero.
544: >r
545: 2dup absolut-path?
546: IF rdrop
547: ofile place open-ofile
548: dup 0= IF >r ofile count r> THEN EXIT
549: ELSE r> path>string
550: BEGIN next-path dup
551: WHILE 5 pick 5 pick check-path
552: 0= IF >r 2drop 2drop r> ofile count 0 EXIT ELSE drop THEN
553: REPEAT
554: 2drop 2drop 2drop -38
555: THEN ;
556:
557: : open-fpath-file ( addr1 u1 -- wfileid addr2 u2 0 | ior ) \ gforth
558: \G Look in the Forth search path for the file specified by @var{addr1 u1}.
559: \G If found, the resulting path and an open file descriptor
560: \G are returned. If the file is not found, @var{ior} is non-zero.
561: fpath open-path-file ;
562:
563: fpath= ~+
564:
565: [THEN]
566:
567: \ \ -------------------- include require 13may99jaw
568:
569: >CROSS
570:
571: : add-included-file ( adr len -- adr )
572: dup >fl-name char+ allocate throw >r
573: file-list @ r@ ! r@ file-list !
574: r@ >fl-name place r> ;
575:
576: : included? ( c-addr u -- f )
577: file-list
578: BEGIN @ dup
579: WHILE >r 2dup r@ >fl-name count str=
580: IF rdrop 2drop true EXIT THEN
581: r>
582: REPEAT
583: 2drop drop false ;
584:
585: false DebugFlag showincludedfiles
586:
587: : included1 ( fd adr u -- )
588: \ include file adr u / fd
589: \ we don't use fd with include-file, because the forth system
590: \ doesn't know the name of the file to get a nice error report
591: [d?] showincludedfiles
592: IF cr ." Including: " 2dup type ." ..." THEN
593: rot close-file throw
594: source-desc >r
595: add-included-file to source-desc
596: sourcefilename
597: ['] included catch
598: r> to source-desc
599: throw ;
600:
601: : included ( adr len -- )
602: cross-file-list to file-list
603: open-fpath-file throw
604: included1 ;
605:
606: : required ( adr len -- )
607: cross-file-list to file-list
608: open-fpath-file throw \ 2dup cr ." R:" type
609: 2dup included?
610: IF 2drop close-file throw
611: ELSE included1
612: THEN ;
613:
614: : include bl word count included ;
615:
616: : require bl word count required ;
617:
618: 0 [IF]
619:
620: also forth definitions previous
621:
622: : included ( adr len -- ) included ;
623:
624: : required ( adr len -- ) required ;
625:
626: : include include ;
627:
628: : require require ;
629:
630: [THEN]
631:
632: >CROSS
633: hex
634:
635: \ \ -------------------- Error Handling 05aug97jaw
636:
637: \ Flags
638:
639: also forth definitions \ these values may be predefined before
640: \ the cross-compiler is loaded
641:
642: false DefaultValue stack-warn \ check on empty stack at any definition
643: false DefaultValue create-forward-warn \ warn on forward declaration of created words
644:
645: previous >CROSS
646:
647: : .dec
648: base @ decimal swap . base ! ;
649:
650: : .sourcepos
651: cr sourcefilename type ." :"
652: sourceline# .dec ;
653:
654: : warnhead
655: \G display error-message head
656: \G perhaps with linenumber and filename
657: .sourcepos ." Warning: " ;
658:
659: : empty? depth IF .sourcepos ." Stack not empty!" THEN ;
660:
661: stack-warn [IF]
662: : defempty? empty? ;
663: [ELSE]
664: : defempty? ; immediate
665: \ : defempty? .sourcepos ;
666: [THEN]
667:
668: \ \ -------------------- Compiler Plug Ins 01aug97jaw
669:
670: >CROSS
671:
672: \ Compiler States
673:
674: Variable comp-state
675: 0 Constant interpreting
676: 1 Constant compiling
677: 2 Constant resolving
678: 3 Constant assembling
679:
680: : compiling? comp-state @ compiling = ;
681:
682: : pi-undefined -1 ABORT" Plugin undefined" ;
683:
684: : Plugin ( -- : pluginname )
685: Create
686: \ for normal cross-compiling only one action
687: \ exists, this fields are identical. For the instant
688: \ simulation environment we need, two actions for each plugin
689: \ the target one and the one that generates the simulation code
690: ['] pi-undefined , \ action
691: ['] pi-undefined , \ target plugin action
692: 8765 , \ plugin magic
693: DOES> perform ;
694:
695: Plugin DummyPlugin
696:
697: : 'PI ( -- addr : pluginname )
698: ' >body dup 2 cells + @ 8765 <> ABORT" not a plugin" ;
699:
700: : plugin-of ( xt -- : pluginname )
701: dup 'PI 2! ;
702:
703: : action-of ( xt -- : plunginname )
704: 'PI cell+ ! ;
705:
706: : TPA ( -- : plugin )
707: \ target plugin action
708: \ executes current target action of plugin
709: 'PI cell+ POSTPONE literal POSTPONE perform ; immediate
710:
711: Variable ppi-temp 0 ppi-temp !
712:
713: : pa:
714: \g define plugin action
715: ppi-temp @ ABORT" pa: definition not closed"
716: 'PI ppi-temp ! :noname ;
717:
718: : ;pa
719: \g end a definition for plugin action
720: POSTPONE ; ppi-temp @ ! 0 ppi-temp ! ; immediate
721:
722:
723: Plugin dlit, ( d -- ) \ compile numerical value the target
724: Plugin lit, ( n -- )
725: Plugin alit, ( n -- )
726:
727: Plugin branch, ( target-addr -- ) \ compiles a branch
728: Plugin ?branch, ( target-addr -- ) \ compiles a ?branch
729: Plugin branchmark, ( -- branch-addr ) \ reserves room for a branch
730: Plugin ?branchmark, ( -- branch-addr ) \ reserves room for a ?branch
731: Plugin ?domark, ( -- branch-addr ) \ reserves room for a ?do branch
732: Plugin branchto, ( -- ) \ actual program position is target of a branch (do e.g. alignment)
733: ' NOOP plugin-of branchto,
734: Plugin branchtoresolve, ( branch-addr -- ) \ resolves a forward reference from branchmark
735: Plugin branchtomark, ( -- target-addr ) \ marks a branch destination
736:
737: Plugin colon, ( tcfa -- ) \ compiles call to tcfa at current position
738: Plugin prim, ( tcfa -- ) \ compiles primitive invocation
739: Plugin colonmark, ( -- addr ) \ marks a colon call
740: Plugin colon-resolve ( tcfa addr -- )
741:
742: Plugin addr-resolve ( target-addr addr -- )
743: Plugin doer-resolve ( ghost res-pnt target-addr addr -- ghost res-pnt )
744:
745: Plugin ncontrols? ( [ xn ... x1 ] n -- ) \ checks wheter n control structures are open
746: Plugin if, ( -- if-token )
747: Plugin else, ( if-token -- if-token )
748: Plugin then, ( if-token -- )
749: Plugin ahead,
750: Plugin begin,
751: Plugin while,
752: Plugin until,
753: Plugin again,
754: Plugin repeat,
755: Plugin cs-swap ( x1 x2 -- x2 x1 )
756:
757: Plugin case, ( -- n )
758: Plugin of, ( n -- x1 n )
759: Plugin endof, ( x1 n -- x2 n )
760: Plugin endcase, ( x1 .. xn n -- )
761:
762: Plugin do, ( -- do-token )
763: Plugin ?do, ( -- ?do-token )
764: Plugin for, ( -- for-token )
765: Plugin loop, ( do-token / ?do-token -- )
766: Plugin +loop, ( do-token / ?do-token -- )
767: Plugin next, ( for-token )
768: Plugin leave, ( -- )
769: Plugin ?leave, ( -- )
770:
771: Plugin ca>native \ Convert a code address to the processors
772: \ native address. This is used in doprim, and
773: \ code/code: primitive definitions word to
774: \ convert the addresses.
775: \ The only target where we need this is the misc
776: \ which is a 16 Bit processor with word addresses
777: \ but the forth system we build has a normal byte
778: \ addressed memory model
779:
780: Plugin doprim, \ compiles start of a primitive
781: Plugin docol, \ compiles start of a colon definition
782: Plugin doer,
783: Plugin fini, \ compiles end of definition ;s
784: Plugin doeshandler,
785: Plugin dodoes,
786:
787: Plugin colon-start
788: ' noop plugin-of colon-start
789: Plugin colon-end
790: ' noop plugin-of colon-end
791:
792: Plugin ]comp \ starts compilation
793: ' noop plugin-of ]comp
794: Plugin comp[ \ ends compilation
795: ' noop plugin-of comp[
796:
797: Plugin t>body \ we need the system >body
798: \ and the target >body
799:
800: >TARGET
801: : >body t>body ;
802:
803:
804: \ Ghost Builder 06oct92py
805:
806: >CROSS
807: hex
808: \ Values for ghost magic
809: 4711 Constant <fwd> 4712 Constant <res>
810: 4713 Constant <imm> 4714 Constant <do:>
811: 4715 Constant <skip>
812:
813: \ Bitmask for ghost flags
814: 1 Constant <unique>
815: 2 Constant <primitive>
816:
817: \ FXIME: move this to general stuff?
818: : set-flag ( addr flag -- )
819: over @ or swap ! ;
820:
821: : reset-flag ( addr flag -- )
822: invert over @ and swap ! ;
823:
824: : get-flag ( addr flag -- f )
825: swap @ and 0<> ;
826:
827:
828: Struct
829:
830: \ link to next ghost (always the first element)
831: cell% field >next-ghost
832:
833: \ type of ghost
834: cell% field >magic
835:
836: \ pointer where ghost is in target, or if unresolved
837: \ points to the where we have to resolve (linked-list)
838: cell% field >link
839:
840: \ execution semantics (while target compiling) of ghost
841: cell% field >exec
842:
843: \ compilation action of this ghost; this is what is
844: \ done to compile a call (or whatever) to this definition.
845: \ E.g. >comp contains the semantic of postpone s"
846: \ whereas >exec-compile contains the semantic of s"
847: cell% field >comp
848:
849: \ Compilation sematics (while parsing) of this ghost. E.g.
850: \ "\" will skip the rest of line.
851: \ These semantics are defined by Cond: and
852: \ if a word is made immediate in instant, then the >exec2 field
853: \ gets copied to here
854: cell% field >exec-compile
855:
856: \ Additional execution semantics of this ghost. This is used
857: \ for code generated by instant and for the doer-xt of created
858: \ words
859: cell% field >exec2
860:
861: cell% field >created
862:
863: \ the xt of the created ghost word itself
864: cell% field >ghost-xt
865:
866: \ pointer to the counted string of the assiciated
867: \ assembler label
868: cell% field >asm-name
869:
870: \ mapped primitives have a special address, so
871: \ we are able to detect them
872: cell% field >asm-dummyaddr
873:
874: \ for builder (create, variable...) words
875: \ the execution symantics of words built are placed here
876: \ this is a doer ghost or a dummy ghost
877: cell% field >do:ghost
878:
879: cell% field >ghost-flags
880:
881: cell% field >ghost-name
882:
883: End-Struct ghost-struct
884:
885: Variable ghost-list
886: 0 ghost-list !
887:
888: Variable executed-ghost \ last executed ghost, needed in tcreate and gdoes>
889: \ Variable last-ghost \ last ghost that is created
890: Variable last-header-ghost \ last ghost definitions with header
891:
892: \ space for ghosts resolve structure
893: \ we create ghosts in a sepearte space
894: \ and not to the current host dp, because this
895: \ gives trouble with instant while compiling and creating
896: \ a ghost for a forward reference
897: \ BTW: we cannot allocate another memory region
898: \ because allot will check the overflow!!
899: Variable cross-space-dp
900: Create cross-space 250000 allot here 100 allot align
901: Constant cross-space-end
902: cross-space cross-space-dp !
903: Variable cross-space-dp-orig
904:
905: : cross-space-used cross-space-dp @ cross-space - ;
906:
907: : >space ( -- )
908: dp @ cross-space-dp-orig !
909: cross-space-dp @ dp ! ;
910:
911: : space> ( -- )
912: dp @ dup cross-space-dp !
913: cross-space-end u> ABORT" CROSS: cross-space overflow"
914: cross-space-dp-orig @ dp ! ;
915:
916: \ this is just for debugging, to see this in the backtrace
917: : execute-exec execute ;
918: : execute-exec2 execute ;
919: : execute-exec-compile execute ;
920:
921: : NoExec
922: executed-ghost @ >exec2 @
923: ?dup
924: IF execute-exec2
925: ELSE true ABORT" CROSS: Don't execute ghost, or immediate target word"
926: THEN ;
927:
928: Defer is-forward
929:
930: : (ghostheader) ( -- )
931: ghost-list linked <fwd> , 0 , ['] NoExec , ['] is-forward ,
932: 0 , 0 , 0 , 0 , 0 , 0 , 0 , 0 , ;
933:
934: : ghostheader ( -- ) (ghostheader) 0 , ;
935:
936: ' Ghosts >wordlist Constant ghosts-wordlist
937:
938: \ the current wordlist for ghost definitions in the host
939: ghosts-wordlist Value current-ghosts
940:
941: : Make-Ghost ( "name" -- ghost )
942: >space
943: \ save current and create in ghost vocabulary
944: get-current >r current-ghosts set-current
945: >in @ Create >in !
946: \ some forth systems like iForth need the immediate directly
947: \ after the word is created
948: \ restore current
949: r> set-current
950: here (ghostheader)
951: bl word count string, align
952: space>
953: \ set ghost-xt field by doing a search
954: dup >ghost-name count
955: current-ghosts search-wordlist
956: 0= ABORT" CROSS: Just created, must be there!"
957: over >ghost-xt !
958: DOES>
959: dup executed-ghost !
960: >exec @ execute-exec ;
961:
962: \ ghost words 14oct92py
963: \ changed: 10may93py/jaw
964:
965: Defer search-ghosts
966:
967: : (search-ghosts) ( adr len -- cfa true | 0 )
968: current-ghosts search-wordlist ;
969:
970: ' (search-ghosts) IS search-ghosts
971:
972: : gsearch ( addr len -- ghost true | 0 )
973: search-ghosts
974: dup IF swap >body swap THEN ;
975:
976: : gfind ( string -- ghost true / string false )
977: \ searches for string in word-list ghosts
978: \ dup count type space
979: dup >r count gsearch
980: dup IF rdrop ELSE r> swap THEN ;
981:
982: : gdiscover ( xt -- ghost true | xt false )
983: >r ghost-list
984: BEGIN @ dup
985: WHILE dup >magic @ <fwd> <>
986: IF dup >link @ r@ =
987: IF rdrop true EXIT THEN
988: THEN
989: REPEAT
990: drop r> false ;
991:
992: : xt>ghost ( xt -- ghost )
993: gdiscover 0= ABORT" CROSS: ghost not found for this xt" ;
994:
995: : Ghost ( "name" -- ghost )
996: >in @ bl word gfind IF nip EXIT THEN
997: drop >in ! Make-Ghost ;
998:
999: : >ghostname ( ghost -- adr len )
1000: >ghost-name count ;
1001:
1002: : forward? ( ghost -- flag )
1003: >magic @ <fwd> = ;
1004:
1005: : undefined? ( ghost -- flag )
1006: >magic @ dup <fwd> = swap <skip> = or ;
1007:
1008: : immediate? ( ghost -- flag )
1009: >magic @ <imm> = ;
1010:
1011: Variable TWarnings
1012: TWarnings on
1013: Variable Exists-Warnings
1014: Exists-Warnings on
1015:
1016: : exists-warning ( ghost -- ghost )
1017: TWarnings @ Exists-Warnings @ and
1018: IF dup >ghostname warnhead type ." exists " THEN ;
1019:
1020: \ : HeaderGhost Ghost ;
1021:
1022: Variable reuse-ghosts reuse-ghosts off
1023:
1024: : HeaderGhost ( "name" -- ghost )
1025: >in @
1026: bl word count
1027: \ 2dup type space
1028: current-ghosts search-wordlist
1029: IF >body dup undefined? reuse-ghosts @ or
1030: IF nip EXIT
1031: ELSE exists-warning
1032: THEN
1033: drop >in !
1034: ELSE >in !
1035: THEN
1036: \ we keep the execution semantics of the prviously
1037: \ defined words, this is a workaround
1038: \ for the redefined \ until vocs work
1039: Make-Ghost ;
1040:
1041: : .ghost ( ghost -- ) >ghostname type ;
1042:
1043: \ ' >ghostname ALIAS @name
1044:
1045: : findghost ( "ghostname" -- ghost )
1046: bl word gfind 0= ABORT" CROSS: Ghost don't exists" ;
1047:
1048: : [G'] ( -- ghost : name )
1049: \G ticks a ghost and returns its address
1050: findghost
1051: state @ IF postpone literal THEN ; immediate
1052:
1053: : g>xt ( ghost -- xt )
1054: \G Returns the xt (cfa) of a ghost. Issues a warning if undefined.
1055: dup undefined? ABORT" CROSS: forward " >link @ ;
1056:
1057: : g>body ( ghost -- body )
1058: \G Returns the body-address (pfa) of a ghost.
1059: \G Issues a warning if undefined (a forward-reference).
1060: g>xt X >body ;
1061:
1062: 1 Constant <label>
1063:
1064: Struct
1065: \ bitmask of address type (not used for now)
1066: cell% field addr-type
1067: \ if this address is an xt, this field points to the ghost
1068: cell% field addr-xt-ghost
1069: \ a bit mask that tells as what part of the cell
1070: \ is refenced from an address pointer, used for assembler generation
1071: cell% field addr-refs
1072: End-Struct addr-struct
1073:
1074: : %allocerase ( align size -- addr )
1075: dup >r %alloc dup r> erase ;
1076:
1077: \ returns the addr struct, define it if 0 reference
1078: : define-addr-struct ( addr -- struct-addr )
1079: dup @ ?dup IF nip EXIT THEN
1080: addr-struct %allocerase tuck swap ! ;
1081:
1082: >cross
1083:
1084: \ Predefined ghosts 12dec92py
1085:
1086: Ghost - drop \ need a ghost otherwise "-" would be treated as a number
1087:
1088: Ghost 0= drop
1089: Ghost branch Ghost ?branch 2drop
1090: Ghost unloop Ghost ;S 2drop
1091: Ghost lit Ghost ! 2drop
1092: Ghost noop drop
1093: Ghost over Ghost = Ghost drop 2drop drop
1094: Ghost 2drop drop
1095: Ghost 2dup drop
1096: Ghost call drop
1097: Ghost @ drop
1098: Ghost useraddr drop
1099: Ghost execute drop
1100: Ghost + drop
1101: Ghost decimal drop
1102: Ghost hex drop
1103: Ghost lit@ drop
1104: Ghost lit-perform drop
1105: Ghost lit+ drop
1106: Ghost does-exec drop
1107:
1108: Ghost :docol Ghost :doesjump Ghost :dodoes 2drop drop
1109: Ghost :dovar drop
1110:
1111: \ \ Parameter for target systems 06oct92py
1112:
1113:
1114: \ we define it ans like...
1115: wordlist Constant target-environment
1116:
1117: \ save information of current dictionary to restore with environ>
1118: Variable env-current
1119:
1120: : >ENVIRON get-current env-current ! target-environment set-current ;
1121: : ENVIRON> env-current @ set-current ;
1122:
1123: >TARGET
1124:
1125: : environment? ( addr len -- [ x ] true | false )
1126: \G returns the content of environment variable and true or
1127: \G false if not present
1128: target-environment search-wordlist
1129: IF EXECUTE true ELSE false THEN ;
1130:
1131: : $has? ( addr len -- x | false )
1132: \G returns the content of environment variable
1133: \G or false if not present
1134: T environment? H dup IF drop THEN ;
1135:
1136: : e? ( "name" -- x )
1137: \G returns the content of environment variable.
1138: \G The variable is expected to exist. If not, issue an error.
1139: bl word count T environment? H
1140: 0= ABORT" environment variable not defined!" ;
1141:
1142: : has? ( "name" --- x | false )
1143: \G returns the content of environment variable
1144: \G or false if not present
1145: bl word count T $has? H ;
1146:
1147:
1148: >ENVIRON get-order get-current swap 1+ set-order
1149: true SetValue compiler
1150: true SetValue cross
1151: true SetValue standard-threading
1152: >TARGET previous
1153:
1154: 0
1155: [IFDEF] mach-file drop mach-file count 1 [THEN]
1156: [IFDEF] machine-file drop machine-file 1 [THEN]
1157: [IF] included hex
1158: [ELSE] cr ." No machine description!" ABORT
1159: [THEN]
1160:
1161: >ENVIRON
1162:
1163: T has? ec H
1164: [IF]
1165: false DefaultValue relocate
1166: false DefaultValue file
1167: false DefaultValue OS
1168: false DefaultValue prims
1169: false DefaultValue floating
1170: false DefaultValue glocals
1171: false DefaultValue dcomps
1172: false DefaultValue hash
1173: false DefaultValue xconds
1174: false DefaultValue header
1175: false DefaultValue backtrace
1176: false DefaultValue new-input
1177: false DefaultValue peephole
1178: false DefaultValue primcentric
1179: false DefaultValue abranch
1180: true DefaultValue f83headerstring
1181: true DefaultValue control-rack
1182: [THEN]
1183:
1184: true DefaultValue gforthcross
1185: true DefaultValue interpreter
1186: true DefaultValue ITC
1187: false DefaultValue rom
1188: false DefaultValue flash
1189: true DefaultValue standardthreading
1190:
1191: \ ANSForth environment stuff
1192: 8 DefaultValue ADDRESS-UNIT-BITS
1193: 255 DefaultValue MAX-CHAR
1194: 255 DefaultValue /COUNTED-STRING
1195:
1196: >TARGET
1197: s" relocate" T environment? H
1198: \ JAW why set NIL to this?!
1199: [IF] drop \ SetValue NIL
1200: [ELSE] >ENVIRON X NIL SetValue relocate
1201: [THEN]
1202: >TARGET
1203:
1204: 0 Constant NIL
1205:
1206: >CROSS
1207:
1208: \ \ Create additional parameters 19jan95py
1209:
1210: \ currently cross only works for host machines with address-unit-bits
1211: \ eual to 8 because of s! and sc!
1212: \ but I start to query the environment just to modularize a little bit
1213:
1214: : check-address-unit-bits ( -- )
1215: \ s" ADDRESS-UNIT-BITS" environment?
1216: \ IF 8 <> ELSE true THEN
1217: \ ABORT" ADDRESS-UNIT-BITS unknown or not equal to 8!"
1218:
1219: \ shit, this doesn't work because environment? is only defined for
1220: \ gforth.fi and not kernl???.fi
1221: ;
1222:
1223: check-address-unit-bits
1224: 8 Constant bits/byte \ we define: byte is address-unit
1225:
1226: 1 bits/byte lshift Constant maxbyte
1227: \ this sets byte size for the target machine, (probably right guess) jaw
1228:
1229: T
1230: NIL Constant TNIL
1231: cell Constant tcell
1232: cell<< Constant tcell<<
1233: cell>bit Constant tcell>bit
1234: bits/char Constant tbits/char
1235: bits/char H bits/byte T /
1236: Constant tchar
1237: float Constant tfloat
1238: 1 bits/char lshift Constant tmaxchar
1239: [IFUNDEF] bits/byte
1240: 8 Constant tbits/byte
1241: [ELSE]
1242: bits/byte Constant tbits/byte
1243: [THEN]
1244: H
1245: tbits/char bits/byte / Constant tbyte
1246:
1247:
1248: \ Variables 06oct92py
1249:
1250: Variable (tlast)
1251: (tlast) Value tlast TNIL tlast ! \ Last name field
1252: Variable tlastcfa \ Last code field
1253:
1254: \ statistics 10jun97jaw
1255:
1256: Variable headers-named 0 headers-named !
1257: Variable user-vars 0 user-vars !
1258:
1259: : target>bitmask-size ( u1 -- u2 )
1260: 1- tcell>bit rshift 1+ ;
1261:
1262: : allocatetarget ( size -- adr )
1263: dup allocate ABORT" CROSS: No memory for target"
1264: swap over swap erase ;
1265:
1266: \ \ memregion.fs
1267:
1268:
1269: Variable last-defined-region \ pointer to last defined region
1270: Variable region-link \ linked list with all regions
1271: Variable mirrored-link \ linked list for mirrored regions
1272: 0 dup mirrored-link ! region-link !
1273:
1274: : >rname 9 cells + ;
1275: : >rtouch 8 cells + ; \ executed when region is accessed
1276: : >rbm 4 cells + ; \ bitfield per cell witch indicates relocation
1277: : >rmem 5 cells + ;
1278: : >rtype 6 cells + ; \ field per cell witch points to a type struct
1279: : >rrom 7 cells + ; \ a -1 indicates that this region is rom
1280: : >rlink 3 cells + ;
1281: : >rdp 2 cells + ;
1282: : >rlen cell+ ;
1283: : >rstart ;
1284:
1285: : (region) ( addr len region -- )
1286: \G change startaddress and length of an existing region
1287: >r r@ last-defined-region !
1288: r@ >rlen ! dup r@ >rstart ! r> >rdp ! ;
1289:
1290: : uninitialized -1 ABORT" CROSS: Region is uninitialized" ;
1291:
1292: : region ( addr len -- "name" )
1293: \G create a new region
1294: \ check whether predefined region exists
1295: save-input bl word find >r >r restore-input throw r> r> 0=
1296: IF \ make region
1297: drop
1298: save-input create restore-input throw
1299: here last-defined-region !
1300: over ( startaddr ) , ( length ) , ( dp ) ,
1301: region-link linked 0 , 0 , 0 , 0 ,
1302: ['] uninitialized ,
1303: bl word count string,
1304: ELSE \ store new parameters in region
1305: bl word drop
1306: >body (region)
1307: THEN ;
1308:
1309: : borders ( region -- startaddr endaddr )
1310: \G returns lower and upper region border
1311: dup >rstart @ swap >rlen @ over + ;
1312:
1313: : extent ( region -- startaddr len )
1314: \G returns the really used area
1315: dup >rstart @ swap >rdp @ over - ;
1316:
1317: : area ( region -- startaddr totallen )
1318: \G returns the total area
1319: dup >rstart @ swap >rlen @ ;
1320:
1321: : dp@ ( region -- dp )
1322: >rdp @ ;
1323:
1324: : mirrored ( -- )
1325: \G mark last defined region as mirrored
1326: mirrored-link
1327: align linked last-defined-region @ , ;
1328:
1329: : writeprotected
1330: \G mark a region as write protected
1331: -1 last-defined-region @ >rrom ! ;
1332:
1333: : .addr ( u -- )
1334: \G prints a 16 or 32 Bit nice hex value
1335: base @ >r hex
1336: tcell 2 u>
1337: IF s>d <# # # # # [char] . hold # # # # #> type
1338: ELSE s>d <# # # # # # #> type
1339: THEN r> base ! space ;
1340:
1341: : .regions \G display region statistic
1342:
1343: \ we want to list the regions in the right order
1344: \ so first collect all regions on stack
1345: 0 region-link @
1346: BEGIN dup WHILE dup @ REPEAT drop
1347: BEGIN dup
1348: WHILE cr
1349: 0 >rlink - >r
1350: r@ >rname count tuck type
1351: 12 swap - 0 max spaces space
1352: ." Start: " r@ >rstart @ dup .addr space
1353: ." End: " r@ >rlen @ + .addr space
1354: ." DP: " r> >rdp @ .addr
1355: REPEAT drop
1356: s" rom" T $has? H 0= ?EXIT
1357: cr ." Mirrored:"
1358: mirrored-link @
1359: BEGIN dup
1360: WHILE space dup cell+ @ >rname count type @
1361: REPEAT drop cr
1362: ;
1363:
1364: \ -------- predefined regions
1365:
1366: 0 0 region address-space
1367: \ total memory addressed and used by the target system
1368:
1369: 0 0 region user-region
1370: \ data for user variables goes here
1371: \ this has to be defined before dictionary or ram-dictionary
1372:
1373: 0 0 region dictionary
1374: \ rom area for the compiler
1375:
1376: T has? rom H
1377: [IF]
1378: 0 0 region ram-dictionary mirrored
1379: \ ram area for the compiler
1380: [ELSE]
1381: ' dictionary ALIAS ram-dictionary
1382: [THEN]
1383:
1384: 0 0 region return-stack
1385:
1386: 0 0 region data-stack
1387:
1388: 0 0 region tib-region
1389:
1390: ' dictionary ALIAS rom-dictionary
1391:
1392: : setup-region ( region -- )
1393: >r
1394: \ allocate mem
1395: r@ >rlen @ allocatetarget
1396: r@ >rmem !
1397:
1398: r@ >rlen @
1399: target>bitmask-size allocatetarget
1400: r@ >rbm !
1401:
1402: r@ >rlen @
1403: tcell / 1+ cells allocatetarget r@ >rtype !
1404:
1405: ['] noop r@ >rtouch !
1406: rdrop ;
1407:
1408: : setup-target ( -- ) \G initialize target's memory space
1409: s" rom" T $has? H
1410: IF \ check for ram and rom...
1411: \ address-space area nip 0<>
1412: ram-dictionary area nip 0<>
1413: rom-dictionary area nip 0<>
1414: and 0=
1415: ABORT" CROSS: define address-space, rom- , ram-dictionary, with rom-support!"
1416: THEN
1417: address-space area nip
1418: IF
1419: address-space area
1420: ELSE
1421: dictionary area
1422: THEN
1423: nip 0=
1424: ABORT" CROSS: define at least address-space or dictionary!!"
1425:
1426: \ allocate target for each region
1427: region-link
1428: BEGIN @ dup
1429: WHILE dup
1430: 0 >rlink - >r
1431: r@ >rlen @
1432: IF r@ setup-region
1433: THEN rdrop
1434: REPEAT drop ;
1435:
1436: \ MakeKernel 22feb99jaw
1437:
1438: : makekernel ( start targetsize -- )
1439: \G convenience word to setup the memory of the target
1440: \G used by main.fs of the c-engine based systems
1441: dictionary (region) setup-target ;
1442:
1443: >MINIMAL
1444: : makekernel makekernel ;
1445: >CROSS
1446:
1447: \ \ switched tdp for rom support 03jun97jaw
1448:
1449: \ second value is here to store some maximal value for statistics
1450: \ tempdp is also embedded here but has nothing to do with rom support
1451: \ (needs switched dp)
1452:
1453: variable tempdp 0 , \ temporary dp for resolving
1454: variable tempdp-save
1455:
1456: 0 [IF]
1457: variable romdp 0 , \ Dictionary-Pointer for ramarea
1458: variable ramdp 0 , \ Dictionary-Pointer for romarea
1459:
1460: \
1461: variable sramdp \ start of ram-area for forth
1462: variable sromdp \ start of rom-area for forth
1463:
1464: [THEN]
1465:
1466: 0 Value current-region
1467: 0 Value tdp
1468: Variable fixed \ flag: true: no automatic switching
1469: \ false: switching is done automatically
1470:
1471: \ Switch-Policy:
1472: \
1473: \ a header is always compiled into rom
1474: \ after a created word (create and variable) compilation goes to ram
1475: \
1476: \ Be careful: If you want to make the data behind create into rom
1477: \ you have to put >rom before create!
1478:
1479: variable constflag constflag off
1480:
1481: : activate ( region -- )
1482: \G next code goes to this region
1483: dup to current-region >rdp to tdp ;
1484:
1485: : (switchram)
1486: fixed @ ?EXIT s" rom" T $has? H 0= ?EXIT
1487: ram-dictionary activate ;
1488:
1489: : switchram
1490: constflag @
1491: IF constflag off ELSE (switchram) THEN ;
1492:
1493: : switchrom
1494: fixed @ ?EXIT rom-dictionary activate ;
1495:
1496: : >tempdp ( addr -- )
1497: tdp tempdp-save ! tempdp to tdp tdp ! ;
1498: : tempdp> ( -- )
1499: tempdp-save @ to tdp ;
1500:
1501: : >ram fixed off (switchram) fixed on ;
1502: : >rom fixed off switchrom fixed on ;
1503: : >auto fixed off switchrom ;
1504:
1505:
1506:
1507: \ : romstart dup sromdp ! romdp ! ;
1508: \ : ramstart dup sramdp ! ramdp ! ;
1509:
1510: \ default compilation goes to rom
1511: \ when romable support is off, only the rom switch is used (!!)
1512: >auto
1513:
1514: : there tdp @ ;
1515:
1516: >TARGET
1517:
1518: \ \ Target Memory Handling
1519:
1520: \ Byte ordering and cell size 06oct92py
1521:
1522: : cell+ tcell + ;
1523: : cells tcell<< lshift ;
1524: : chars tchar * ;
1525: : char+ tchar + ;
1526: : floats tfloat * ;
1527:
1528: >CROSS
1529: : cell/ tcell<< rshift ;
1530: >TARGET
1531: 20 CONSTANT bl
1532: \ TNIL Constant NIL
1533:
1534: >CROSS
1535:
1536: bigendian
1537: [IF]
1538: : DS! ( d addr -- ) tcell bounds swap 1-
1539: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
1540: : DS@ ( addr -- d ) >r 0 0 r> tcell bounds
1541: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP ;
1542: : Sc! ( n addr -- ) >r s>d r> tchar bounds swap 1-
1543: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
1544: : Sc@ ( addr -- n ) >r 0 0 r> tchar bounds
1545: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP d>s ;
1546: [ELSE]
1547: : DS! ( d addr -- ) tcell bounds
1548: DO maxbyte ud/mod rot I c! LOOP 2drop ;
1549: : DS@ ( addr -- n ) >r 0 0 r> tcell bounds swap 1-
1550: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP ;
1551: : Sc! ( n addr -- ) >r s>d r> tchar bounds
1552: DO maxbyte ud/mod rot I c! LOOP 2drop ;
1553: : Sc@ ( addr -- n ) >r 0 0 r> tchar bounds swap 1-
1554: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP d>s ;
1555: [THEN]
1556:
1557: : S! ( n addr -- ) >r s>d r> DS! ;
1558: : S@ ( addr -- n ) DS@ d>s ;
1559:
1560: : taddr>region ( taddr -- region | 0 )
1561: \G finds for a target-address the correct region
1562: \G returns 0 if taddr is not in range of a target memory region
1563: region-link
1564: BEGIN @ dup
1565: WHILE dup >r
1566: 0 >rlink - >r
1567: r@ >rlen @
1568: IF dup r@ borders within
1569: IF r> r> drop nip
1570: dup >rtouch @ EXECUTE EXIT
1571: THEN
1572: THEN
1573: r> drop
1574: r>
1575: REPEAT
1576: 2drop 0 ;
1577:
1578: : taddr>region-abort ( taddr -- region | 0 )
1579: \G Same as taddr>region but aborts if taddr is not
1580: \G a valid address in the target address space
1581: dup taddr>region dup 0=
1582: IF drop cr ." Wrong address: " .addr
1583: -1 ABORT" Address out of range!"
1584: THEN nip ;
1585:
1586: : (>regionimage) ( taddr -- 'taddr )
1587: dup
1588: \ find region we want to address
1589: taddr>region-abort
1590: >r
1591: \ calculate offset in region
1592: r@ >rstart @ -
1593: \ add regions real address in our memory
1594: r> >rmem @ + ;
1595:
1596: : (>regionramimage) ( taddr -- 'taddr )
1597: \G same as (>regionimage) but aborts if the region is rom
1598: dup
1599: \ find region we want to address
1600: taddr>region-abort
1601: >r
1602: r@ >rrom @ ABORT" CROSS: region is write-protected!"
1603: \ calculate offset in region
1604: r@ >rstart @ -
1605: \ add regions real address in our memory
1606: r> >rmem @ + ;
1607:
1608: : (>regionbm) ( taddr -- 'taddr bitmaskbaseaddr )
1609: dup
1610: \ find region we want to address
1611: taddr>region-abort
1612: >r
1613: \ calculate offset in region
1614: r@ >rstart @ -
1615: \ add regions real address in our memory
1616: r> >rbm @ ;
1617:
1618: : (>regiontype) ( taddr -- 'taddr )
1619: dup
1620: \ find region we want to address
1621: taddr>region-abort
1622: >r
1623: \ calculate offset in region
1624: r@ >rstart @ - tcell / cells
1625: \ add regions real address in our memory
1626: r> >rtype @ + ;
1627:
1628: \ Bit string manipulation 06oct92py
1629: \ 9may93jaw
1630: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
1631: : bits ( n -- n ) chars Bittable + c@ ;
1632:
1633: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
1634: : +bit ( addr n -- ) >bit over c@ or swap c! ;
1635: : -bit ( addr n -- ) >bit invert over c@ and swap c! ;
1636:
1637: : @relbit ( taddr -- f ) (>regionbm) swap cell/ >bit swap c@ and ;
1638:
1639: : (relon) ( taddr -- )
1640: [ [IFDEF] fd-relocation-table ]
1641: s" +" fd-relocation-table write-file throw
1642: dup s>d <# #s #> fd-relocation-table write-line throw
1643: [ [THEN] ]
1644: (>regionbm) swap cell/ +bit ;
1645:
1646: : (reloff) ( taddr -- )
1647: [ [IFDEF] fd-relocation-table ]
1648: s" -" fd-relocation-table write-file throw
1649: dup s>d <# #s #> fd-relocation-table write-line throw
1650: [ [THEN] ]
1651: (>regionbm) swap cell/ -bit ;
1652:
1653: DEFER >image
1654: DEFER >ramimage
1655: DEFER relon
1656: DEFER reloff
1657: DEFER correcter
1658:
1659: T has? relocate H
1660: [IF]
1661: ' (relon) IS relon
1662: ' (reloff) IS reloff
1663: ' (>regionimage) IS >image
1664: ' (>regionimage) IS >ramimage
1665: [ELSE]
1666: ' drop IS relon
1667: ' drop IS reloff
1668: ' (>regionimage) IS >image
1669: ' (>regionimage) IS >ramimage
1670: [THEN]
1671:
1672: : enforce-writeprotection ( -- )
1673: ['] (>regionramimage) IS >ramimage ;
1674:
1675: : relax-writeprotection ( -- )
1676: ['] (>regionimage) IS >ramimage ;
1677:
1678: : writeprotection-relaxed? ( -- )
1679: ['] >ramimage >body @ ['] (>regionimage) = ;
1680:
1681: \ Target memory access 06oct92py
1682:
1683: : align+ ( taddr -- rest )
1684: tcell tuck 1- and - [ tcell 1- ] Literal and ;
1685: : cfalign+ ( taddr -- rest )
1686: \ see kernel.fs:cfaligned
1687: /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
1688:
1689: >TARGET
1690: : aligned ( taddr -- ta-addr ) dup align+ + ;
1691: \ assumes cell alignment granularity (as GNU C)
1692:
1693: : cfaligned ( taddr1 -- taddr2 )
1694: \ see kernel.fs
1695: dup cfalign+ + ;
1696:
1697: : @ ( taddr -- w ) >image S@ ;
1698: : ! ( w taddr -- ) >ramimage S! ;
1699: : c@ ( taddr -- char ) >image Sc@ ;
1700: : c! ( char taddr -- ) >ramimage Sc! ;
1701: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
1702: : 2! ( x1 x2 taddr -- ) T tuck ! cell+ ! H ;
1703:
1704: \ Target compilation primitives 06oct92py
1705: \ included A! 16may93jaw
1706:
1707: : here ( -- there ) there ;
1708: : allot ( n -- ) tdp +! ;
1709: : , ( w -- ) T here H tcell T allot ! H ;
1710: : c, ( char -- ) T here H tchar T allot c! H ;
1711: : align ( -- ) T here H align+ 0 ?DO bl T c, H tchar +LOOP ;
1712: : cfalign ( -- )
1713: T here H cfalign+ 0 ?DO bl T c, H tchar +LOOP ;
1714:
1715: : >address dup 0>= IF tbyte / THEN ; \ ?? jaw
1716: : A! swap >address swap dup relon T ! H ;
1717: : A, ( w -- ) >address T here H relon T , H ;
1718:
1719: \ high-level ghosts
1720:
1721: >CROSS
1722:
1723: Ghost (do) Ghost (?do) 2drop
1724: Ghost (for) drop
1725: Ghost (loop) Ghost (+loop) 2drop
1726: Ghost (next) drop
1727: Ghost (does>) Ghost (does>1) Ghost (does>2) 2drop drop
1728: Ghost compile, drop
1729: Ghost (.") Ghost (S") Ghost (ABORT") 2drop drop
1730: Ghost (C") Ghost c(abort") Ghost type 2drop drop
1731: Ghost ' drop
1732:
1733: \ user ghosts
1734:
1735: Ghost state drop
1736:
1737: \ \ -------------------- Host/Target copy etc. 29aug01jaw
1738:
1739:
1740: >CROSS
1741:
1742: : TD! >image DS! ;
1743: : TD@ >image DS@ ;
1744:
1745: : th-count ( taddr -- host-addr len )
1746: \G returns host address of target string
1747: assert1( tbyte 1 = )
1748: dup X c@ swap X char+ >image swap ;
1749:
1750: : ht-move ( haddr taddr len -- )
1751: \G moves data from host-addr to destination in target-addr
1752: \G character by character
1753: swap -rot bounds ?DO I c@ over X c! X char+ LOOP drop ;
1754:
1755: 2Variable last-string
1756: X has? rom [IF] $60 [ELSE] $00 [THEN] Constant header-masks
1757:
1758: : ht-header, ( addr count -- )
1759: dup there swap last-string 2!
1760: dup header-masks or T c, H bounds ?DO I c@ T c, H LOOP ;
1761: : ht-string, ( addr count -- )
1762: dup there swap last-string 2!
1763: dup T c, H bounds ?DO I c@ T c, H LOOP ;
1764: : ht-mem, ( addr count )
1765: bounds ?DO I c@ T c, H LOOP ;
1766:
1767: >TARGET
1768:
1769: : count dup X c@ swap X char+ swap ;
1770:
1771: : on >r -1 -1 r> TD! ;
1772: : off T 0 swap ! H ;
1773:
1774: : tcmove ( source dest len -- )
1775: \G cmove in target memory
1776: tchar * bounds
1777: ?DO dup T c@ H I T c! H 1+
1778: tchar +LOOP drop ;
1779:
1780: : tcallot ( char size -- )
1781: 0 ?DO dup T c, H tchar +LOOP drop ;
1782:
1783: : td, ( d -- )
1784: \G Store a host value as one cell into the target
1785: there tcell X allot TD! ;
1786:
1787: \ \ Load Assembler
1788:
1789: >TARGET
1790: H also Forth definitions
1791:
1792: \ FIXME: should we include the assembler really in the forth
1793: \ dictionary?!?!?!? This conflicts with the existing assembler
1794: \ of the host forth system!!
1795: [IFDEF] asm-include asm-include [THEN] hex
1796:
1797: previous
1798:
1799:
1800: >CROSS
1801:
1802: : (cc) T a, H ; ' (cc) plugin-of colon,
1803: : (prim) T a, H ; ' (prim) plugin-of prim,
1804:
1805: : (cr) >tempdp colon, tempdp> ; ' (cr) plugin-of colon-resolve
1806: : (ar) T ! H ; ' (ar) plugin-of addr-resolve
1807: : (dr) ( ghost res-pnt target-addr addr )
1808: >tempdp drop over
1809: dup >magic @ <do:> =
1810: IF doer,
1811: ELSE dodoes,
1812: THEN
1813: tempdp> ; ' (dr) plugin-of doer-resolve
1814:
1815: : (cm) ( -- addr )
1816: there -1 colon, ; ' (cm) plugin-of colonmark,
1817:
1818: >TARGET
1819: : compile, ( xt -- )
1820: dup xt>ghost >comp @ EXECUTE ;
1821: >CROSS
1822:
1823: \ resolve structure
1824:
1825: : >next ; \ link to next field
1826: : >tag cell+ ; \ indecates type of reference: 0: call, 1: address, 2: doer
1827: : >taddr cell+ cell+ ;
1828: : >ghost 3 cells + ;
1829: : >file 4 cells + ;
1830: : >line 5 cells + ;
1831:
1832: : (refered) ( ghost addr tag -- )
1833: \G creates a reference to ghost at address taddr
1834: >space
1835: rot >link linked
1836: ( taddr tag ) ,
1837: ( taddr ) ,
1838: last-header-ghost @ ,
1839: loadfile ,
1840: sourceline# ,
1841: space>
1842: ;
1843:
1844: : refered ( ghost tag -- )
1845: \G creates a resolve structure
1846: T here aligned H swap (refered)
1847: ;
1848:
1849: : killref ( addr ghost -- )
1850: \G kills a forward reference to ghost at position addr
1851: \G this is used to eleminate a :dovar refence after making a DOES>
1852: dup >magic @ <fwd> <> IF 2drop EXIT THEN
1853: swap >r >link
1854: BEGIN dup @ dup ( addr last this )
1855: WHILE dup >taddr @ r@ =
1856: IF @ over !
1857: ELSE nip THEN
1858: REPEAT rdrop 2drop
1859: ;
1860:
1861: Defer resolve-warning
1862:
1863: : reswarn-test ( ghost res-struct -- ghost res-struct )
1864: over cr ." Resolving " .ghost dup ." in " >ghost @ .ghost ;
1865:
1866: : reswarn-forward ( ghost res-struct -- ghost res-struct )
1867: over warnhead .ghost dup ." is referenced in "
1868: >ghost @ .ghost ;
1869:
1870: \ ' reswarn-test IS resolve-warning
1871:
1872: \ resolve 14oct92py
1873:
1874: : resolve-loop ( ghost resolve-list tcfa -- )
1875: >r
1876: BEGIN dup WHILE
1877: \ dup >tag @ 2 = IF reswarn-forward THEN
1878: resolve-warning
1879: r@ over >taddr @
1880: 2 pick >tag @
1881: CASE 0 OF colon-resolve ENDOF
1882: 1 OF addr-resolve ENDOF
1883: 2 OF doer-resolve ENDOF
1884: ENDCASE
1885: @ \ next list element
1886: REPEAT 2drop rdrop
1887: ;
1888:
1889: \ : resolve-loop ( ghost tcfa -- ghost tcfa )
1890: \ >r dup >link @
1891: \ BEGIN dup WHILE dup T @ H r@ rot T ! H REPEAT drop r> ;
1892:
1893: \ exists 9may93jaw
1894:
1895: : exists ( ghost tcfa -- )
1896: \G print warning and set new target link in ghost
1897: swap exists-warning
1898: >link ! ;
1899:
1900: : colon-resolved ( ghost -- )
1901: \ compiles a call to a colon definition,
1902: \ compile action for >comp field
1903: >link @ colon, ;
1904:
1905: : prim-resolved ( ghost -- )
1906: \ compiles a call to a primitive
1907: >link @ prim, ;
1908:
1909: : (is-forward) ( ghost -- )
1910: colonmark, 0 (refered) ; \ compile space for call
1911: ' (is-forward) IS is-forward
1912:
1913: 0 Value resolved
1914:
1915: : resolve-forward-references ( ghost resolve-list -- )
1916: \ loop through forward referencies
1917: comp-state @ >r Resolving comp-state !
1918: over >link @ resolve-loop
1919: r> comp-state !
1920:
1921: ['] noop IS resolve-warning ;
1922:
1923:
1924: : (resolve) ( ghost tcfa -- ghost resolve-list )
1925: \ check for a valid address, it is a primitive reference
1926: \ otherwise
1927: dup taddr>region 0<> IF
1928: \ define this address in the region address type table
1929: 2dup (>regiontype) define-addr-struct addr-xt-ghost
1930: \ we define new address only if empty
1931: \ this is for not to take over the alias ghost
1932: \ (different ghost, but identical xt)
1933: \ but the very first that really defines it
1934: dup @ 0= IF ! ELSE 2drop THEN
1935: THEN
1936: swap >r
1937: r@ to resolved
1938:
1939: \ r@ >comp @ ['] is-forward =
1940: \ ABORT" >comp action not set on a resolved ghost"
1941:
1942: \ copmile action defaults to colon-resolved
1943: \ if this is not right something must be set before
1944: \ calling resolve
1945: r@ >comp @ ['] is-forward = IF
1946: ['] colon-resolved r@ >comp !
1947: THEN
1948: r@ >link @ swap \ ( list tcfa R: ghost )
1949: \ mark ghost as resolved
1950: r@ >link ! <res> r@ >magic !
1951: r> swap ;
1952:
1953: : resolve ( ghost tcfa -- )
1954: \G resolve referencies to ghost with tcfa
1955: \ is ghost resolved?, second resolve means another
1956: \ definition with the same name
1957: over undefined? 0= IF exists EXIT THEN
1958: (resolve)
1959: ( ghost resolve-list )
1960: resolve-forward-references ;
1961:
1962: : resolve-noforwards ( ghost tcfa -- )
1963: \G Same as resolve but complain if there are any
1964: \G forward references on this ghost
1965: \ is ghost resolved?, second resolve means another
1966: \ definition with the same name
1967: over undefined? 0= IF exists EXIT THEN
1968: (resolve)
1969: IF cr ." No forward references allowed on: " .ghost cr
1970: -1 ABORT" Illegal forward reference"
1971: THEN
1972: drop ;
1973:
1974: \ gexecute ghost, 01nov92py
1975:
1976: : (gexecute) ( ghost -- )
1977: dup >comp @ EXECUTE ;
1978:
1979: : gexecute ( ghost -- )
1980: dup >magic @ <imm> = ABORT" CROSS: gexecute on immediate word"
1981: (gexecute) ;
1982:
1983: : addr, ( ghost -- )
1984: dup forward? IF 1 refered 0 T a, H ELSE >link @ T a, H THEN ;
1985:
1986: \ .unresolved 11may93jaw
1987:
1988: variable ResolveFlag
1989:
1990: \ ?touched 11may93jaw
1991:
1992: : ?touched ( ghost -- flag ) dup forward? swap >link @
1993: 0 <> and ;
1994:
1995: : .forwarddefs ( ghost -- )
1996: ." appeared in:"
1997: >link
1998: BEGIN @ dup
1999: WHILE cr 5 spaces
2000: dup >ghost @ .ghost
2001: ." file " dup >file @ ?dup IF count type ELSE ." CON" THEN
2002: ." line " dup >line @ .dec
2003: REPEAT
2004: drop ;
2005:
2006: : ?resolved ( ghost -- )
2007: dup ?touched
2008: IF ResolveFlag on
2009: dup cr .ghost .forwarddefs
2010: ELSE drop
2011: THEN ;
2012:
2013: : .unresolved ( -- )
2014: ResolveFlag off cr ." Unresolved: "
2015: ghost-list
2016: BEGIN @ dup
2017: WHILE dup ?resolved
2018: REPEAT drop ResolveFlag @
2019: IF
2020: -1 abort" Unresolved words!"
2021: ELSE
2022: ." Nothing!"
2023: THEN
2024: cr ;
2025:
2026: : .stats
2027: base @ >r decimal
2028: cr ." named Headers: " headers-named @ .
2029: r> base ! ;
2030:
2031: >MINIMAL
2032:
2033: : .unresolved .unresolved ;
2034:
2035: >CROSS
2036: \ Header states 12dec92py
2037:
2038: \ : flag! ( 8b -- ) tlast @ dup >r T c@ xor r> c! H ;
2039: X has? f83headerstring bigendian or [IF] 0 [ELSE] tcell 1- [THEN] Constant flag+
2040: : flag! ( w -- ) tlast @ flag+ + dup >r T c@ xor r> c! H ;
2041:
2042: VARIABLE ^imm
2043:
2044: \ !! should be target wordsize specific
2045: $80 constant alias-mask
2046: $40 constant immediate-mask
2047: $20 constant restrict-mask
2048:
2049: >TARGET
2050: : immediate immediate-mask flag!
2051: ^imm @ @ dup <imm> = IF drop EXIT THEN
2052: <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
2053: <imm> ^imm @ ! ;
2054: : restrict restrict-mask flag! ;
2055:
2056: : isdoer
2057: \G define a forth word as doer, this makes obviously only sence on
2058: \G forth processors such as the PSC1000
2059: <do:> last-header-ghost @ >magic ! ;
2060: >CROSS
2061:
2062: \ Target Header Creation 01nov92py
2063:
2064: : ht-lstring, ( addr count -- )
2065: dup T , H bounds ?DO I c@ T c, H LOOP ;
2066:
2067: >TARGET
2068: X has? f83headerstring [IF]
2069: : name, ( "name" -- ) bl word count ht-header, X cfalign ;
2070: [ELSE]
2071: : name, ( "name" -- ) bl word count ht-lstring, X cfalign ;
2072: [THEN]
2073: : view, ( -- ) ( dummy ) ;
2074: >CROSS
2075:
2076: \ Target Document Creation (goes to crossdoc.fd) 05jul95py
2077:
2078: s" ./doc/crossdoc.fd" r/w create-file throw value doc-file-id
2079: \ contains the file-id of the documentation file
2080:
2081: : T-\G ( -- )
2082: source >in @ /string doc-file-id write-line throw
2083: postpone \ ;
2084:
2085: Variable to-doc to-doc on
2086:
2087: : cross-doc-entry ( -- )
2088: to-doc @ tlast @ 0<> and \ not an anonymous (i.e. noname) header
2089: IF
2090: s" " doc-file-id write-line throw
2091: s" make-doc " doc-file-id write-file throw
2092:
2093: Last-Header-Ghost @ >ghostname doc-file-id write-file throw
2094: >in @
2095: [char] ( parse 2drop
2096: [char] ) parse doc-file-id write-file throw
2097: s" )" doc-file-id write-file throw
2098: [char] \ parse 2drop
2099: T-\G
2100: >in !
2101: THEN ;
2102:
2103: \ Target TAGS creation
2104:
2105: s" kernel.TAGS" r/w create-file throw value tag-file-id
2106: s" kernel.tags" r/w create-file throw value vi-tag-file-id
2107: \ contains the file-id of the tags file
2108:
2109: Create tag-beg 1 c, 7F c,
2110: Create tag-end 1 c, 01 c,
2111: Create tag-bof 1 c, 0C c,
2112: Create tag-tab 1 c, 09 c,
2113:
2114: 2variable last-loadfilename 0 0 last-loadfilename 2!
2115:
2116: : put-load-file-name ( -- )
2117: sourcefilename last-loadfilename 2@ d<>
2118: IF
2119: tag-bof count tag-file-id write-line throw
2120: sourcefilename 2dup
2121: tag-file-id write-file throw
2122: last-loadfilename 2!
2123: s" ,0" tag-file-id write-line throw
2124: THEN ;
2125:
2126: : cross-gnu-tag-entry ( -- )
2127: tlast @ 0<> \ not an anonymous (i.e. noname) header
2128: IF
2129: put-load-file-name
2130: source >in @ min tag-file-id write-file throw
2131: tag-beg count tag-file-id write-file throw
2132: Last-Header-Ghost @ >ghostname tag-file-id write-file throw
2133: tag-end count tag-file-id write-file throw
2134: base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
2135: \ >in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
2136: s" ,0" tag-file-id write-line throw
2137: base !
2138: THEN ;
2139:
2140: : cross-vi-tag-entry ( -- )
2141: tlast @ 0<> \ not an anonymous (i.e. noname) header
2142: IF
2143: sourcefilename vi-tag-file-id write-file throw
2144: tag-tab count vi-tag-file-id write-file throw
2145: Last-Header-Ghost @ >ghostname vi-tag-file-id write-file throw
2146: tag-tab count vi-tag-file-id write-file throw
2147: s" /^" vi-tag-file-id write-file throw
2148: source vi-tag-file-id write-file throw
2149: s" $/" vi-tag-file-id write-line throw
2150: THEN ;
2151:
2152: : cross-tag-entry ( -- )
2153: cross-gnu-tag-entry
2154: cross-vi-tag-entry ;
2155:
2156: \ Check for words
2157:
2158: Defer skip? ' false IS skip?
2159:
2160: : skipdef ( "name" -- )
2161: \G skip definition of an undefined word in undef-words and
2162: \G all-words mode
2163: Ghost dup forward?
2164: IF >magic <skip> swap !
2165: ELSE drop THEN ;
2166:
2167: : tdefined? ( "name" -- flag )
2168: Ghost undefined? 0= ;
2169:
2170: : defined2? ( "name" -- flag )
2171: \G return true for anything else than forward, even for <skip>
2172: \G that's what we want
2173: Ghost forward? 0= ;
2174:
2175: : forced? ( "name" -- flag )
2176: \G return ture if it is a foreced skip with defskip
2177: Ghost >magic @ <skip> = ;
2178:
2179: : needed? ( -- flag ) \ name
2180: \G returns a false flag when
2181: \G a word is not defined
2182: \G a forward reference exists
2183: \G so the definition is not skipped!
2184: bl word gfind
2185: IF dup undefined?
2186: nip
2187: 0=
2188: ELSE drop true THEN ;
2189:
2190: : doer? ( "name" -- 0 | addr ) \ name
2191: Ghost dup >magic @ <do:> =
2192: IF >link @ ELSE drop 0 THEN ;
2193:
2194: : skip-defs ( -- )
2195: BEGIN refill WHILE source -trailing nip 0= UNTIL THEN ;
2196:
2197: \ Target header creation
2198:
2199: Variable NoHeaderFlag
2200: NoHeaderFlag off
2201:
2202: : 0.r ( n1 n2 -- )
2203: base @ >r hex
2204: 0 swap <# 0 ?DO # LOOP #> type
2205: r> base ! ;
2206:
2207: : .sym ( adr len -- )
2208: \G escapes / and \ to produce sed output
2209: bounds
2210: DO I c@ dup
2211: CASE [char] / OF drop ." \/" ENDOF
2212: [char] \ OF drop ." \\" ENDOF
2213: dup OF emit ENDOF
2214: ENDCASE
2215: LOOP ;
2216:
2217: Defer setup-execution-semantics ' noop IS setup-execution-semantics
2218: 0 Value lastghost
2219:
2220: : (THeader ( "name" -- ghost )
2221: \ >in @ bl word count type 2 spaces >in !
2222: \ wordheaders will always be compiled to rom
2223: switchrom
2224: \ build header in target
2225: NoHeaderFlag @
2226: IF NoHeaderFlag off
2227: ELSE
2228: T align H view,
2229: tlast @ dup 0> IF tcell - THEN T A, H there tlast !
2230: 1 headers-named +! \ Statistic
2231: >in @ T name, H >in !
2232: THEN
2233: T cfalign here H tlastcfa !
2234: \ Old Symbol table sed-script
2235: \ >in @ cr ." sym:s/CFA=" there 4 0.r ." /" bl word count .sym ." /g" cr >in !
2236: HeaderGhost
2237: \ output symbol table to extra file
2238: dup >ghostname there symentry
2239: dup Last-Header-Ghost ! dup to lastghost
2240: dup >magic ^imm ! \ a pointer for immediate
2241: alias-mask flag!
2242: cross-doc-entry cross-tag-entry
2243: setup-execution-semantics
2244: ;
2245:
2246: \ this is the resolver information from ":"
2247: \ resolving is done by ";"
2248: Variable ;Resolve 1 cells allot
2249:
2250: : hereresolve ( ghost -- )
2251: there resolve 0 ;Resolve ! ;
2252:
2253: : Theader ( "name" -- ghost )
2254: (THeader dup hereresolve ;
2255:
2256: Variable aprim-nr -20 aprim-nr !
2257:
2258: : copy-execution-semantics ( ghost-from ghost-dest -- )
2259: >r
2260: dup >exec @ r@ >exec !
2261: dup >comp @ r@ >comp !
2262: dup >exec2 @ r@ >exec2 !
2263: dup >exec-compile @ r@ >exec-compile !
2264: dup >ghost-xt @ r@ >ghost-xt !
2265: dup >created @ r@ >created !
2266: rdrop drop ;
2267:
2268: >TARGET
2269:
2270: : Alias ( cfa -- ) \ name
2271: >in @ skip? IF 2drop EXIT THEN >in !
2272: (THeader ( S xt ghost )
2273: 2dup swap xt>ghost swap copy-execution-semantics
2274: over resolve T A, H alias-mask flag! ;
2275:
2276: Variable last-prim-ghost
2277: 0 last-prim-ghost !
2278:
2279: : asmprimname, ( ghost -- : name )
2280: dup last-prim-ghost !
2281: >r
2282: here bl word count string, r@ >asm-name !
2283: aprim-nr @ r> >asm-dummyaddr ! ;
2284:
2285: Defer setup-prim-semantics
2286:
2287: : mapprim ( "forthname" "asmlabel" -- )
2288: THeader -1 aprim-nr +! aprim-nr @ T A, H
2289: asmprimname,
2290: setup-prim-semantics ;
2291:
2292: : mapprim: ( "forthname" "asmlabel" -- )
2293: -1 aprim-nr +! aprim-nr @
2294: Ghost tuck swap resolve-noforwards <do:> swap tuck >magic !
2295: asmprimname, ;
2296:
2297: : Doer: ( cfa -- ) \ name
2298: >in @ skip? IF 2drop EXIT THEN >in !
2299: dup 0< s" prims" T $has? H 0= and
2300: IF
2301: .sourcepos ." needs doer: " >in @ bl word count type >in ! cr
2302: THEN
2303: Ghost
2304: tuck swap resolve-noforwards <do:> swap >magic ! ;
2305:
2306: Variable prim#
2307: : first-primitive ( n -- ) prim# ! ;
2308: : group 0 word drop prim# @ 1- -$200 and prim# ! ;
2309: : groupadd ( n -- ) drop ;
2310: : Primitive ( -- ) \ name
2311: >in @ skip? IF drop EXIT THEN >in !
2312: s" prims" T $has? H 0=
2313: IF
2314: .sourcepos ." needs prim: " >in @ bl word count type >in ! cr
2315: THEN
2316: prim# @ (THeader ( S xt ghost )
2317: ['] prim-resolved over >comp !
2318: dup >ghost-flags <primitive> set-flag
2319: over resolve-noforwards T A, H alias-mask flag!
2320: -1 prim# +! ;
2321: >CROSS
2322:
2323: \ Conditionals and Comments 11may93jaw
2324:
2325: \G saves the existing cond action, this is used for redefining in
2326: \G instant
2327: Variable cond-xt-old
2328:
2329: : cond-target ( -- )
2330: \G Compiles semantic of redefined cond into new one
2331: cond-xt-old @ compile, ; immediate restrict
2332:
2333: : ;Cond
2334: postpone ;
2335: swap ! ; immediate
2336:
2337: : Cond: ( "name" -- )
2338: \g defines a conditional or another word that must
2339: \g be executed directly while compiling
2340: \g these words have no interpretative semantics by default
2341: Ghost
2342: >exec-compile
2343: dup @ cond-xt-old !
2344: :NONAME ;
2345:
2346:
2347: : Comment ( -- )
2348: >in @ Ghost swap >in ! ' swap
2349: 2dup >exec-compile ! >exec ! ;
2350:
2351: Comment ( Comment \
2352:
2353: \ compile 10may93jaw
2354:
2355: : compile ( "name" -- ) \ name
2356: findghost
2357: dup >exec-compile @ ?dup
2358: IF nip compile,
2359: ELSE postpone literal postpone gexecute THEN ; immediate restrict
2360:
2361: >TARGET
2362:
2363: : ' ( -- xt )
2364: \G returns the target-cfa of a ghost
2365: bl word gfind 0= ABORT" CROSS: Ghost don't exists"
2366: g>xt ;
2367:
2368: \ FIXME: this works for the current use cases, but is not
2369: \ in all cases correct ;-)
2370: : comp' X ' 0 ;
2371:
2372: Cond: ['] T ' H alit, ;Cond
2373:
2374: >CROSS
2375:
2376: : [T']
2377: \ returns the target-cfa of a ghost, or compiles it as literal
2378: postpone [G']
2379: state @ IF postpone g>xt ELSE g>xt THEN ; immediate
2380:
2381: \ \ threading modell 13dec92py
2382: \ modularized 14jun97jaw
2383:
2384: T 2 cells H Value xt>body
2385:
2386: : (>body) ( cfa -- pfa )
2387: xt>body + ; ' (>body) plugin-of t>body
2388:
2389: : fillcfa ( usedcells -- )
2390: T cells H xt>body swap -
2391: assert1( dup 0 >= )
2392: 0 ?DO 0 X c, tchar +LOOP ;
2393:
2394: : (doer,) ( ghost -- )
2395: addr, 1 fillcfa ; ' (doer,) plugin-of doer,
2396:
2397: : (docol,) ( -- ) [G'] :docol (doer,) ; ' (docol,) plugin-of docol,
2398:
2399: ' NOOP plugin-of ca>native
2400:
2401: : (doprim,) ( -- )
2402: there xt>body + ca>native T a, H 1 fillcfa ; ' (doprim,) plugin-of doprim,
2403:
2404: : (doeshandler,) ( -- )
2405: T cfalign H [G'] :doesjump addr, T 0 , H ; ' (doeshandler,) plugin-of doeshandler,
2406:
2407: : (dodoes,) ( does-action-ghost -- )
2408: ]comp [G'] :dodoes addr, comp[
2409: addr,
2410: \ the relocator in the c engine, does not like the
2411: \ does-address to marked for relocation
2412: [ T e? ec H 0= [IF] ] T here H tcell - reloff [ [THEN] ]
2413: 2 fillcfa ; ' (dodoes,) plugin-of dodoes,
2414:
2415: : (dlit,) ( n -- ) compile lit td, ; ' (dlit,) plugin-of dlit,
2416:
2417: : (lit,) ( n -- ) s>d dlit, ; ' (lit,) plugin-of lit,
2418:
2419: \ if we dont produce relocatable code alit, defaults to lit, jaw
2420: \ this is just for convenience, so we don't have to define alit,
2421: \ seperately for embedded systems....
2422: T has? relocate H
2423: [IF]
2424: : (alit,) ( n -- ) compile lit T a, H ; ' (alit,) plugin-of alit,
2425: [ELSE]
2426: : (alit,) ( n -- ) lit, ; ' (alit,) plugin-of alit,
2427: [THEN]
2428:
2429: : (fini,) compile ;s ; ' (fini,) plugin-of fini,
2430:
2431: [IFUNDEF] (code)
2432: Defer (code)
2433: Defer (end-code)
2434: [THEN]
2435:
2436: >TARGET
2437: : Code
2438: defempty?
2439: (THeader ( ghost )
2440: ['] prim-resolved over >comp !
2441: there resolve-noforwards
2442:
2443: [ T e? prims H 0= [IF] T e? ITC H [ELSE] true [THEN] ] [IF]
2444: doprim,
2445: [THEN]
2446: depth (code) ;
2447:
2448: \ FIXME : no-compile -1 ABORT" this ghost is not for compilation" ;
2449:
2450: : Code:
2451: defempty?
2452: Ghost >r
2453: r@ >ghostname there symentry
2454: r@ there ca>native resolve-noforwards
2455: <do:> r@ >magic !
2456: r> drop
2457: depth (code) ;
2458:
2459: : end-code
2460: (end-code)
2461: depth ?dup IF 1- <> ABORT" CROSS: Stack changed"
2462: ELSE true ABORT" CROSS: Stack empty" THEN
2463: ;
2464:
2465: >CROSS
2466:
2467: \ tLiteral 12dec92py
2468:
2469: >TARGET
2470: Cond: \G T-\G ;Cond
2471:
2472: Cond: Literal ( n -- ) lit, ;Cond
2473: Cond: ALiteral ( n -- ) alit, ;Cond
2474:
2475: : Char ( "<char>" -- ) bl word char+ c@ ;
2476: Cond: [Char] ( "<char>" -- ) Char lit, ;Cond
2477:
2478: : (x#) ( adr len base -- )
2479: base @ >r base ! 0 0 name >number 2drop drop r> base ! ;
2480:
2481: : d# $0a (x#) ;
2482: : h# $010 (x#) ;
2483:
2484: Cond: d# $0a (x#) lit, ;Cond
2485: Cond: h# $010 (x#) lit, ;Cond
2486:
2487: tchar 1 = [IF]
2488: Cond: chars ;Cond
2489: [THEN]
2490:
2491: \ some special literals 27jan97jaw
2492:
2493: Cond: MAXU
2494: -1 s>d dlit,
2495: ;Cond
2496:
2497: tcell 2 = tcell 4 = or tcell 8 = or 0=
2498: [IF]
2499: .( Warning: MINI and MAXI may not work with this host) cr
2500: [THEN]
2501:
2502: Cond: MINI
2503: tcell 2 = IF $8000 ELSE $80000000 THEN 0
2504: tcell 8 = IF swap THEN dlit,
2505: ;Cond
2506:
2507: Cond: MAXI
2508: tcell 2 = IF $7fff ELSE $7fffffff THEN 0
2509: tcell 8 = IF drop -1 swap THEN dlit,
2510: ;Cond
2511:
2512: >CROSS
2513:
2514: \ Target compiling loop 12dec92py
2515: \ ">tib trick thrown out 10may93jaw
2516: \ number? defined at the top 11may93jaw
2517: \ replaced >in by save-input
2518:
2519: : discard 0 ?DO drop LOOP ;
2520:
2521: \ compiled word might leave items on stack!
2522: : tcom ( x1 .. xn n name -- )
2523: \ dup count type space
2524: gfind
2525: IF >r ( discard saved input state ) discard r>
2526: dup >exec-compile @ ?dup
2527: IF nip execute-exec-compile ELSE gexecute THEN
2528: EXIT
2529: THEN
2530: number? dup
2531: IF 0> IF swap lit, THEN lit, discard
2532: ELSE 2drop restore-input throw Ghost gexecute THEN ;
2533:
2534: \ : ; DOES> 13dec92py
2535: \ ] 9may93py/jaw
2536:
2537: >CROSS
2538:
2539: : compiling-state ( -- )
2540: \G set states to compililng
2541: Compiling comp-state !
2542: \ if we have a state in target, change it with the compile state
2543: [G'] state dup undefined? 0=
2544: IF >ghost-xt @ execute X on ELSE drop THEN ;
2545:
2546: : interpreting-state ( -- )
2547: \G set states to interpreting
2548: \ if target has a state variable, change it according to our state
2549: [G'] state dup undefined? 0=
2550: IF >ghost-xt @ execute X off ELSE drop THEN
2551: Interpreting comp-state ! ;
2552:
2553: >TARGET
2554:
2555: : ]
2556: compiling-state
2557: BEGIN
2558: BEGIN save-input bl word
2559: dup c@ 0= WHILE drop discard refill 0=
2560: ABORT" CROSS: End of file while target compiling"
2561: REPEAT
2562: tcom
2563: compiling? 0=
2564: UNTIL ;
2565:
2566: \ by the way: defining a second interpreter (a compiler-)loop
2567: \ is not allowed if a system should be ans conform
2568:
2569: : (:) ( ghost -- )
2570: \ common factor of : and :noname. Prepare ;Resolve and start definition
2571: ;Resolve ! there ;Resolve cell+ !
2572: docol, ]comp colon-start depth T ] H ;
2573:
2574: : : ( -- colon-sys ) \ Name
2575: defempty?
2576: constflag off \ don't let this flag work over colon defs
2577: \ just to go sure nothing unwanted happens
2578: >in @ skip? IF drop skip-defs EXIT THEN >in !
2579: (THeader (:) ;
2580:
2581: : :noname ( -- colon-sys )
2582: switchrom X cfalign there
2583: \ define a nameless ghost
2584: here ghostheader dup last-header-ghost ! dup to lastghost
2585: (:) ;
2586:
2587: Cond: EXIT ( -- ) compile ;S ;Cond
2588:
2589: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
2590:
2591: >CROSS
2592: : LastXT ;Resolve @ 0= abort" CROSS: no definition for LastXT"
2593: ;Resolve cell+ @ ;
2594:
2595: >TARGET
2596:
2597: Cond: recurse ( -- ) Last-Header-Ghost @ gexecute ;Cond
2598:
2599: Cond: ; ( -- )
2600: depth ?dup
2601: IF 1- <> ABORT" CROSS: Stack changed"
2602: ELSE true ABORT" CROSS: Stack empty"
2603: THEN
2604: colon-end
2605: fini,
2606: comp[
2607: ;Resolve @
2608: IF ['] colon-resolved ;Resolve @ >comp !
2609: ;Resolve @ ;Resolve cell+ @ resolve
2610: THEN
2611: interpreting-state
2612: ;Cond
2613:
2614: Cond: [ ( -- ) interpreting-state ;Cond
2615:
2616: >CROSS
2617:
2618: 0 Value created
2619:
2620: : !does ( does-action -- )
2621: tlastcfa @ [G'] :dovar killref
2622: >space here >r ghostheader space>
2623: ['] colon-resolved r@ >comp !
2624: r@ created >do:ghost ! r@ swap resolve
2625: r> tlastcfa @ >tempdp dodoes, tempdp> ;
2626:
2627: Defer instant-interpret-does>-hook ' noop IS instant-interpret-does>-hook
2628:
2629: T has? primcentric H [IF]
2630: : does-resolved ( ghost -- )
2631: compile does-exec g>xt T a, H ;
2632: [ELSE]
2633: : does-resolved ( ghost -- )
2634: g>xt T a, H ;
2635: [THEN]
2636:
2637: : resolve-does>-part ( -- )
2638: \ resolve words made by builders
2639: Last-Header-Ghost @ >do:ghost @ ?dup
2640: IF there resolve THEN ;
2641:
2642: >TARGET
2643: Cond: DOES>
2644: T here H [ T has? primcentric H [IF] ] 5 [ [ELSE] ] 4 [ [THEN] ] T cells
2645: H + alit, compile (does>2) compile ;s
2646: doeshandler, resolve-does>-part
2647: ;Cond
2648:
2649: : DOES>
2650: ['] does-resolved created >comp !
2651: switchrom doeshandler, T here H !does
2652: instant-interpret-does>-hook
2653: depth T ] H ;
2654:
2655: >CROSS
2656: \ Creation 01nov92py
2657:
2658: \ Builder 11may93jaw
2659:
2660: 0 Value built
2661:
2662: : Builder ( Create-xt do-ghost "name" -- )
2663: \ builds up a builder in current vocabulary
2664: \ create-xt is executed when word is interpreted
2665: \ do:-xt is executed when the created word from builder is executed
2666: \ for do:-xt an additional entry after the normal ghost-entrys is used
2667:
2668: ghost to built
2669: built >created @ 0= IF
2670: built >created on
2671: THEN ;
2672:
2673: : gdoes, ( ghost -- )
2674: \ makes the codefield for a word that is built
2675: >do:ghost @ dup undefined? 0=
2676: IF
2677: dup >magic @ <do:> =
2678: IF doer,
2679: ELSE dodoes,
2680: THEN
2681: EXIT
2682: THEN
2683: \ compile :dodoes gexecute
2684: \ T here H tcell - reloff
2685: 2 refered
2686: 0 fillcfa
2687: ;
2688:
2689: : takeover-x-semantics ( S constructor-ghost new-ghost -- )
2690: \g stores execution semantic and compilation semantic in the built word
2691: swap >do:ghost @ 2dup swap >do:ghost !
2692: \ we use the >exec2 field for the semantic of a created word,
2693: \ using exec or exec2 makes no difference for normal cross-compilation
2694: \ but is usefull for instant where the exec field is already
2695: \ defined (e.g. Vocabularies)
2696: 2dup >exec @ swap >exec2 !
2697: >comp @ swap >comp ! ;
2698:
2699: 0 Value createhere
2700:
2701: : create-resolve ( -- )
2702: created createhere resolve 0 ;Resolve ! ;
2703: : create-resolve-immediate ( -- )
2704: create-resolve T immediate H ;
2705:
2706: : TCreate ( <name> -- )
2707: create-forward-warn
2708: IF ['] reswarn-forward IS resolve-warning THEN
2709: executed-ghost @ (Theader
2710: dup >created on dup to created
2711: 2dup takeover-x-semantics
2712: there to createhere drop gdoes, ;
2713:
2714: : RTCreate ( <name> -- )
2715: \ creates a new word with code-field in ram
2716: create-forward-warn
2717: IF ['] reswarn-forward IS resolve-warning THEN
2718: \ make Alias
2719: executed-ghost @ (THeader
2720: dup >created on dup to created
2721: 2dup takeover-x-semantics
2722: there 0 T a, H alias-mask flag!
2723: \ store poiter to code-field
2724: switchram T cfalign H
2725: there swap T ! H
2726: there tlastcfa !
2727: there to createhere drop gdoes, ;
2728:
2729: : Build: ( -- [xt] [colon-sys] )
2730: :noname postpone TCreate ;
2731:
2732: : BuildSmart: ( -- [xt] [colon-sys] )
2733: :noname
2734: [ T has? rom H [IF] ]
2735: postpone RTCreate
2736: [ [ELSE] ]
2737: postpone TCreate
2738: [ [THEN] ] ;
2739:
2740: : ;Build
2741: postpone create-resolve postpone ; built >exec ! ; immediate
2742:
2743: : ;Build-immediate
2744: postpone create-resolve-immediate
2745: postpone ; built >exec ! ; immediate
2746:
2747: : gdoes> ( ghost -- addr flag )
2748: executed-ghost @ g>body ;
2749:
2750: \ DO: ;DO 11may93jaw
2751:
2752: : do:ghost! ( ghost -- ) built >do:ghost ! ;
2753: : doexec! ( xt -- ) built >do:ghost @ >exec ! ;
2754:
2755: : DO: ( -- [xt] [colon-sys] )
2756: here ghostheader do:ghost!
2757: :noname postpone gdoes> ;
2758:
2759: : by: ( -- [xt] [colon-sys] ) \ name
2760: Ghost do:ghost!
2761: :noname postpone gdoes> ;
2762:
2763: : ;DO ( [xt] [colon-sys] -- )
2764: postpone ; doexec! ; immediate
2765:
2766: : by ( -- ) \ Name
2767: Ghost >do:ghost @ do:ghost! ;
2768:
2769: : compile: ( --[xt] [colon-sys] )
2770: \G defines a compile time action for created words
2771: \G by this builder
2772: :noname ;
2773:
2774: : ;compile ( [xt] [colon-sys] -- )
2775: postpone ; built >do:ghost @ >comp ! ; immediate
2776:
2777: \ Variables and Constants 05dec92py
2778:
2779: Builder (Constant)
2780: Build: ( n -- ) ;Build
2781: by: :docon ( target-body-addr -- n ) T @ H ;DO
2782:
2783: Builder Constant
2784: Build: ( n -- ) T , H ;Build
2785: by (Constant)
2786:
2787: Builder AConstant
2788: Build: ( n -- ) T A, H ;Build
2789: by (Constant)
2790:
2791: Builder 2Constant
2792: Build: ( d -- ) T , , H ;Build
2793: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
2794:
2795: Builder Create
2796: BuildSmart: ;Build
2797: by: :dovar ( target-body-addr -- addr ) ;DO
2798:
2799: Builder Variable
2800: T has? rom H [IF]
2801: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , H ( switchrom ) ;Build
2802: by (Constant)
2803: [ELSE]
2804: Build: T 0 , H ;Build
2805: by Create
2806: [THEN]
2807:
2808: Builder 2Variable
2809: T has? rom H [IF]
2810: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , 0 , H ( switchrom ) ;Build
2811: by (Constant)
2812: [ELSE]
2813: Build: T 0 , 0 , H ;Build
2814: by Create
2815: [THEN]
2816:
2817: Builder AVariable
2818: T has? rom H [IF]
2819: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 A, H ( switchrom ) ;Build
2820: by (Constant)
2821: [ELSE]
2822: Build: T 0 A, H ;Build
2823: by Create
2824: [THEN]
2825:
2826: \ User variables 04may94py
2827:
2828: : tup@ user-region >rstart @ ;
2829:
2830: \ Variable tup 0 tup !
2831: \ Variable tudp 0 tudp !
2832:
2833: : u, ( n -- udp )
2834: current-region >r user-region activate
2835: X here swap X , tup@ -
2836: r> activate ;
2837:
2838: : au, ( n -- udp )
2839: current-region >r user-region activate
2840: X here swap X a, tup@ -
2841: r> activate ;
2842:
2843: T has? no-userspace H [IF]
2844:
2845: : buildby
2846: ghost >exec @ built >exec ! ;
2847:
2848: Builder User
2849: buildby Variable
2850: by Variable
2851:
2852: Builder 2User
2853: buildby 2Variable
2854: by 2Variable
2855:
2856: Builder AUser
2857: buildby AVariable
2858: by AVariable
2859:
2860: [ELSE]
2861:
2862: Builder User
2863: Build: 0 u, X , ;Build
2864: by: :douser ( ghost -- up-addr ) X @ tup@ + ;DO
2865:
2866: Builder 2User
2867: Build: 0 u, X , 0 u, drop ;Build
2868: by User
2869:
2870: Builder AUser
2871: Build: 0 au, X , ;Build
2872: by User
2873:
2874: [THEN]
2875:
2876: T has? rom H [IF]
2877: Builder (Value)
2878: Build: ( n -- ) ;Build
2879: by: :dovalue ( target-body-addr -- n ) T @ @ H ;DO
2880:
2881: Builder Value
2882: Build: T here 0 A, H switchram T align here swap ! , H ;Build
2883: by (Value)
2884:
2885: Builder AValue
2886: Build: T here 0 A, H switchram T align here swap ! A, H ;Build
2887: by (Value)
2888: [ELSE]
2889: Builder (Value)
2890: Build: ( n -- ) ;Build
2891: by: :dovalue ( target-body-addr -- n ) T @ H ;DO
2892:
2893: Builder Value
2894: BuildSmart: T , H ;Build
2895: by (Value)
2896:
2897: Builder AValue
2898: BuildSmart: T A, H ;Build
2899: by (Value)
2900: [THEN]
2901:
2902: Defer texecute
2903:
2904: Builder Defer
2905: T has? rom H [IF]
2906: Build: ( -- ) T here 0 A, H switchram T align here swap ! H [T'] noop T A, H ( switchrom ) ;Build
2907: by: :dodefer ( ghost -- ) X @ X @ texecute ;DO
2908: [ELSE]
2909: BuildSmart: ( -- ) [T'] noop T A, H ;Build
2910: by: :dodefer ( ghost -- ) X @ texecute ;DO
2911: [THEN]
2912:
2913: Builder interpret/compile:
2914: Build: ( inter comp -- ) swap T A, A, H ;Build-immediate
2915: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
2916:
2917: \ Sturctures 23feb95py
2918:
2919: : nalign ( addr1 n -- addr2 )
2920: \ addr2 is the aligned version of addr1 wrt the alignment size n
2921: 1- tuck + swap invert and ;
2922:
2923:
2924: Builder (Field)
2925: Build: ;Build
2926: by: :dofield T @ H + ;DO
2927:
2928: Builder Field
2929: Build: ( align1 offset1 align size "name" -- align2 offset2 )
2930: rot dup T , H ( align1 align size offset1 )
2931: + >r nalign r> ;Build
2932: by (Field)
2933:
2934: >TARGET
2935: : struct T 1 chars 0 H ;
2936: : end-struct T 2Constant H ;
2937:
2938: : cell% ( n -- size align )
2939: T 1 cells H dup ;
2940: >CROSS
2941:
2942: \ Input-Methods 01py
2943:
2944: Builder input-method
2945: Build: ( m v -- m' v ) dup T , cell+ H ;Build
2946: DO: abort" Not in cross mode" ;DO
2947:
2948: Builder input-var
2949: Build: ( m v size -- m v' ) over T , H + ;Build
2950: DO: abort" Not in cross mode" ;DO
2951:
2952: \ Peephole optimization 05sep01jaw
2953:
2954: \ this section defines different compilation
2955: \ actions for created words
2956: \ this will help the peephole optimizer
2957: \ I (jaw) took this from bernds latest cross-compiler
2958: \ changes but seperated it from the original
2959: \ Builder words. The final plan is to put this
2960: \ into a seperate file, together with the peephole
2961: \ optimizer for cross
2962:
2963:
2964: T has? primcentric H [IF]
2965:
2966: \ .( loading peephole optimization) cr
2967:
2968: >CROSS
2969:
2970: : (callc) compile call T >body a, H ; ' (callc) plugin-of colon,
2971: : (callcm) T here 0 a, 0 a, H ; ' (callcm) plugin-of colonmark,
2972: : (call-res) >tempdp resolved gexecute tempdp> drop ;
2973: ' (call-res) plugin-of colon-resolve
2974: : (pprim) dup 0< IF $4000 - ELSE
2975: cr ." wrong usage of (prim) "
2976: dup gdiscover IF .ghost ELSE . THEN cr -1 throw THEN
2977: T a, H ; ' (pprim) plugin-of prim,
2978:
2979: \ if we want this, we have to spilt aconstant
2980: \ and constant!!
2981: \ Builder (Constant)
2982: \ compile: g>body X @ lit, ;compile
2983:
2984: Builder (Constant)
2985: compile: g>body compile lit@ T a, H ;compile
2986:
2987: Builder (Value)
2988: compile: g>body compile lit@ T a, H ;compile
2989:
2990: \ this changes also Variable, AVariable and 2Variable
2991: Builder Create
2992: compile: g>body alit, ;compile
2993:
2994: Builder User
2995: compile: g>body compile useraddr T @ , H ;compile
2996:
2997: Builder Defer
2998: compile: g>body compile lit-perform T A, H ;compile
2999:
3000: Builder (Field)
3001: compile: g>body T @ H compile lit+ T , H ;compile
3002:
3003: Builder interpret/compile:
3004: compile: does-resolved ;compile
3005:
3006: Builder input-method
3007: compile: does-resolved ;compile
3008:
3009: Builder input-var
3010: compile: does-resolved ;compile
3011:
3012: [THEN]
3013:
3014: \ structural conditionals 17dec92py
3015:
3016: >CROSS
3017: : (ncontrols?) ( n -- )
3018: \g We expect n open control structures
3019: depth over u<=
3020: ABORT" CROSS: unstructured, stack underflow"
3021: 0 ?DO I pick 0=
3022: ABORT" CROSS: unstructured"
3023: LOOP ; ' (ncontrols?) plugin-of ncontrols?
3024:
3025: \ : ?struc ( flag -- ) ABORT" CROSS: unstructured " ;
3026: \ : sys? ( sys -- sys ) dup 0= ?struc ;
3027:
3028: : >mark ( -- sys ) T here ( dup ." M" hex. ) 0 , H ;
3029:
3030: X has? abranch [IF]
3031: : branchoffset ( src dest -- ) drop ;
3032: : offset, ( n -- ) X A, ;
3033: [ELSE]
3034: : branchoffset ( src dest -- ) - tchar / ; \ ?? jaw
3035: : offset, ( n -- ) X , ;
3036: [THEN]
3037:
3038: :noname compile branch X here branchoffset offset, ;
3039: IS branch, ( target-addr -- )
3040: :noname compile ?branch X here branchoffset offset, ;
3041: IS ?branch, ( target-addr -- )
3042: :noname compile branch T here 0 H offset, ;
3043: IS branchmark, ( -- branchtoken )
3044: :noname compile ?branch T here 0 H offset, ;
3045: IS ?branchmark, ( -- branchtoken )
3046: :noname T here 0 H offset, ;
3047: IS ?domark, ( -- branchtoken )
3048: :noname dup X @ ?struc X here over branchoffset swap X ! ;
3049: IS branchtoresolve, ( branchtoken -- )
3050: :noname branchto, X here ;
3051: IS branchtomark, ( -- target-addr )
3052:
3053: >TARGET
3054:
3055: \ Structural Conditionals 12dec92py
3056:
3057: \ CLEANUP Cond: BUT sys? swap ;Cond
3058: \ CLEANUP Cond: YET sys? dup ;Cond
3059:
3060: >CROSS
3061:
3062: Variable tleavings 0 tleavings !
3063:
3064: : (done) ( do-addr -- )
3065: \G resolve branches of leave and ?leave and ?do
3066: \G do-addr is the address of the beginning of our
3067: \G loop so we can take care of nested loops
3068: tleavings @
3069: BEGIN dup
3070: WHILE
3071: >r dup r@ cell+ @ \ address of branch
3072: u> 0= \ lower than DO?
3073: WHILE
3074: r@ 2 cells + @ \ branch token
3075: branchtoresolve,
3076: r@ @ r> free throw
3077: REPEAT r> THEN
3078: tleavings ! drop ;
3079:
3080: >TARGET
3081:
3082: \ What for? ANS? JAW Cond: DONE ( addr -- ) (done) ;Cond
3083:
3084: >CROSS
3085: : (leave) ( branchtoken -- )
3086: 3 cells allocate throw >r
3087: T here H r@ cell+ !
3088: r@ 2 cells + !
3089: tleavings @ r@ !
3090: r> tleavings ! ;
3091: >TARGET
3092:
3093: : (leave,) ( -- )
3094: branchmark, (leave) ; ' (leave,) plugin-of leave,
3095:
3096: : (?leave,) ( -- )
3097: compile 0= ?branchmark, (leave) ; ' (?leave,) plugin-of ?leave,
3098:
3099: Cond: LEAVE leave, ;Cond
3100: Cond: ?LEAVE ?leave, ;Cond
3101:
3102: >CROSS
3103: \ !!JW ToDo : Move to general tools section
3104:
3105: : to1 ( x1 x2 xn n -- addr )
3106: \G packs n stack elements in am allocated memory region
3107: dup dup 1+ cells allocate throw dup >r swap 1+
3108: 0 DO tuck ! cell+ LOOP
3109: drop r> ;
3110:
3111: : 1to ( addr -- x1 x2 xn )
3112: \G unpacks the elements saved by to1
3113: dup @ swap over cells + swap
3114: 0 DO dup @ swap 1 cells - LOOP
3115: free throw ;
3116:
3117: : loop] ( target-addr -- )
3118: branchto,
3119: dup X here branchoffset offset,
3120: tcell - (done) ;
3121:
3122: : skiploop] ?dup IF branchto, branchtoresolve, THEN ;
3123:
3124: >TARGET
3125:
3126: \ Structural Conditionals 12dec92py
3127:
3128: : (cs-swap) ( x1 x2 -- x2 x1 )
3129: swap ; ' (cs-swap) plugin-of cs-swap
3130:
3131: : (ahead,) branchmark, ; ' (ahead,) plugin-of ahead,
3132:
3133: : (if,) ?branchmark, ; ' (if,) plugin-of if,
3134:
3135: : (then,) branchto, branchtoresolve, ; ' (then,) plugin-of then,
3136:
3137: : (else,) ( ahead ) branchmark,
3138: swap
3139: ( then ) branchto, branchtoresolve, ; ' (else,) plugin-of else,
3140:
3141: : (begin,) branchtomark, ; ' (begin,) plugin-of begin,
3142:
3143: : (while,) ( if ) ?branchmark,
3144: swap ; ' (while,) plugin-of while,
3145:
3146: : (again,) branch, ; ' (again,) plugin-of again,
3147:
3148: : (until,) ?branch, ; ' (until,) plugin-of until,
3149:
3150: : (repeat,) ( again ) branch,
3151: ( then ) branchto, branchtoresolve, ; ' (repeat,) plugin-of repeat,
3152:
3153: : (case,) ( -- n )
3154: 0 ; ' (case,) plugin-of case,
3155:
3156: : (of,) ( n -- x1 n )
3157: 1+ >r
3158: compile over compile =
3159: if, compile drop r> ; ' (of,) plugin-of of,
3160:
3161: : (endof,) ( x1 n -- x2 n )
3162: >r 1 ncontrols? else, r> ; ' (endof,) plugin-of endof,
3163:
3164: : (endcase,) ( x1 .. xn n -- )
3165: compile drop 0 ?DO 1 ncontrols? then, LOOP ; ' (endcase,) plugin-of endcase,
3166:
3167: >TARGET
3168: Cond: AHEAD ahead, ;Cond
3169: Cond: IF if, ;Cond
3170: Cond: THEN 1 ncontrols? then, ;Cond
3171: Cond: ENDIF 1 ncontrols? then, ;Cond
3172: Cond: ELSE 1 ncontrols? else, ;Cond
3173:
3174: Cond: BEGIN begin, ;Cond
3175: Cond: WHILE 1 ncontrols? while, ;Cond
3176: Cond: AGAIN 1 ncontrols? again, ;Cond
3177: Cond: UNTIL 1 ncontrols? until, ;Cond
3178: Cond: REPEAT 2 ncontrols? repeat, ;Cond
3179:
3180: Cond: CASE case, ;Cond
3181: Cond: OF of, ;Cond
3182: Cond: ENDOF endof, ;Cond
3183: Cond: ENDCASE endcase, ;Cond
3184:
3185: \ Structural Conditionals 12dec92py
3186:
3187: : (do,) ( -- target-addr )
3188: \ ?? i think 0 is too much! jaw
3189: 0 compile (do)
3190: branchtomark, 2 to1 ; ' (do,) plugin-of do,
3191:
3192: \ alternative for if no ?do
3193: \ : (do,)
3194: \ compile 2dup compile = compile IF
3195: \ compile 2drop compile ELSE
3196: \ compile (do) branchtomark, 2 to1 ;
3197:
3198: : (?do,) ( -- target-addr )
3199: 0 compile (?do) ?domark, (leave)
3200: branchtomark, 2 to1 ; ' (?do,) plugin-of ?do,
3201:
3202: : (for,) ( -- target-addr )
3203: compile (for) branchtomark, ; ' (for,) plugin-of for,
3204:
3205: : (loop,) ( target-addr -- )
3206: 1to compile (loop) loop]
3207: compile unloop skiploop] ; ' (loop,) plugin-of loop,
3208:
3209: : (+loop,) ( target-addr -- )
3210: 1to compile (+loop) loop]
3211: compile unloop skiploop] ; ' (+loop,) plugin-of +loop,
3212:
3213: : (next,)
3214: compile (next) loop] compile unloop ; ' (next,) plugin-of next,
3215:
3216: Cond: DO do, ;Cond
3217: Cond: ?DO ?do, ;Cond
3218: Cond: FOR for, ;Cond
3219:
3220: Cond: LOOP 1 ncontrols? loop, ;Cond
3221: Cond: +LOOP 1 ncontrols? +loop, ;Cond
3222: Cond: NEXT 1 ncontrols? next, ;Cond
3223:
3224: \ String words 23feb93py
3225:
3226: : ," [char] " parse ht-string, X align ;
3227:
3228: X has? control-rack [IF]
3229: Cond: ." compile (.") T ," H ;Cond
3230: Cond: S" compile (S") T ," H ;Cond
3231: Cond: C" compile (C") T ," H ;Cond
3232: Cond: ABORT" compile (ABORT") T ," H ;Cond
3233: [ELSE]
3234: Cond: ." '" parse tuck 2>r ahead, there 2r> ht-mem, X align
3235: >r then, r> compile ALiteral compile Literal compile type ;Cond
3236: Cond: S" '" parse tuck 2>r ahead, there 2r> ht-mem, X align
3237: >r then, r> compile ALiteral compile Literal ;Cond
3238: Cond: C" ahead, there [char] " parse ht-string, X align
3239: >r then, r> compile ALiteral ;Cond
3240: Cond: ABORT" if, ahead, there [char] " parse ht-string, X align
3241: >r then, r> compile ALiteral compile c(abort") then, ;Cond
3242: [THEN]
3243:
3244: X has? rom [IF]
3245: Cond: IS T ' >body @ H compile ALiteral compile ! ;Cond
3246: : IS T >address ' >body @ ! H ;
3247: Cond: TO T ' >body @ H compile ALiteral compile ! ;Cond
3248: : TO T ' >body @ ! H ;
3249: Cond: CTO T ' >body H compile ALiteral compile ! ;Cond
3250: : CTO T ' >body ! H ;
3251: [ELSE]
3252: Cond: IS T ' >body H compile ALiteral compile ! ;Cond
3253: : IS T >address ' >body ! H ;
3254: Cond: TO T ' >body H compile ALiteral compile ! ;Cond
3255: : TO T ' >body ! H ;
3256: [THEN]
3257:
3258: Cond: defers T ' >body @ compile, H ;Cond
3259:
3260: \ LINKED ERR" ENV" 2ENV" 18may93jaw
3261:
3262: \ linked list primitive
3263: : linked X here over X @ X A, swap X ! ;
3264: : chained T linked A, H ;
3265:
3266: : err" s" ErrLink linked" evaluate T , H
3267: [char] " parse ht-string, X align ;
3268:
3269: : env" [char] " parse s" EnvLink linked" evaluate
3270: ht-string, X align X , ;
3271:
3272: : 2env" [char] " parse s" EnvLink linked" evaluate
3273: here >r ht-string, X align X , X ,
3274: r> dup T c@ H 80 and swap T c! H ;
3275:
3276: \ compile must be last 22feb93py
3277:
3278: Cond: [compile] ( -- ) \ name
3279: \g For immediate words, works even if forward reference
3280: bl word gfind 0= ABORT" CROSS: Can't compile"
3281: (gexecute) ;Cond
3282:
3283: Cond: postpone ( -- ) \ name
3284: bl word gfind 0= ABORT" CROSS: Can't compile"
3285: dup >magic @ <fwd> =
3286: ABORT" CROSS: Can't postpone on forward declaration"
3287: dup >magic @ <imm> =
3288: IF (gexecute)
3289: ELSE >link @ alit, compile compile, THEN ;Cond
3290:
3291: \ save-cross 17mar93py
3292:
3293: hex
3294:
3295: >CROSS
3296: Create magic s" Gforth3x" here over allot swap move
3297:
3298: bigendian 1+ \ strangely, in magic big=0, little=1
3299: tcell 1 = 0 and or
3300: tcell 2 = 2 and or
3301: tcell 4 = 4 and or
3302: tcell 8 = 6 and or
3303: tchar 1 = 00 and or
3304: tchar 2 = 28 and or
3305: tchar 4 = 50 and or
3306: tchar 8 = 78 and or
3307: magic 7 + c!
3308:
3309: : save-cross ( "image-name" "binary-name" -- )
3310: .regions \ s" ec" X $has? IF .regions THEN
3311: bl parse ." Saving to " 2dup type cr
3312: w/o bin create-file throw >r
3313: s" header" X $has? IF
3314: s" #! " r@ write-file throw
3315: bl parse r@ write-file throw
3316: s" --image-file" r@ write-file throw
3317: #lf r@ emit-file throw
3318: r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
3319: ?do
3320: bl over emit-file throw
3321: loop
3322: drop
3323: magic 8 r@ write-file throw \ write magic
3324: ELSE
3325: bl parse 2drop
3326: THEN
3327: >rom dictionary >rmem @ there
3328: s" rom" X $has? IF dictionary >rstart @ - THEN
3329: r@ write-file throw \ write image
3330: s" relocate" X $has? IF
3331: dictionary >rbm @ there 1- tcell>bit rshift 1+
3332: r@ write-file throw \ write tags
3333: THEN
3334: r> close-file throw ;
3335:
3336: : save-region ( addr len -- )
3337: bl parse w/o bin create-file throw >r
3338: swap >image swap r@ write-file throw
3339: r> close-file throw ;
3340:
3341: \ save-asm-region 29aug01jaw
3342:
3343: Variable name-ptr
3344: Create name-buf 200 chars allot
3345: : init-name-buf name-buf name-ptr ! ;
3346: : nb, name-ptr @ c! 1 chars name-ptr +! ;
3347: : $nb, ( adr len -- ) bounds ?DO I c@ nb, LOOP ;
3348: : @nb name-ptr @ name-buf tuck - ;
3349:
3350: \ stores a usefull string representation of the character
3351: \ in the name buffer
3352: : name-char, ( c -- )
3353: dup 'a 'z 1+ within IF nb, EXIT THEN
3354: dup 'A 'Z 1+ within IF $20 + nb, EXIT THEN
3355: dup '0 '9 1+ within IF nb, EXIT THEN
3356: CASE '+ OF s" _PLUS" $nb, ENDOF
3357: '- OF s" _MINUS" $nb, ENDOF
3358: '* OF s" _STAR" $nb, ENDOF
3359: '/ OF s" _SLASH" $nb, ENDOF
3360: '' OF s" _TICK" $nb, ENDOF
3361: '( OF s" _OPAREN" $nb, ENDOF
3362: ') OF s" _CPAREN" $nb, ENDOF
3363: '[ OF s" _OBRACKET" $nb, ENDOF
3364: '] OF s" _CBRACKET" $nb, ENDOF
3365: '! OF s" _STORE" $nb, ENDOF
3366: '@ OF s" _FETCH" $nb, ENDOF
3367: '> OF s" _GREATER" $nb, ENDOF
3368: '< OF s" _LESS" $nb, ENDOF
3369: '= OF s" _EQUAL" $nb, ENDOF
3370: '# OF s" _HASH" $nb, ENDOF
3371: '? OF s" _QUEST" $nb, ENDOF
3372: ': OF s" _COL" $nb, ENDOF
3373: '; OF s" _SEMICOL" $nb, ENDOF
3374: ', OF s" _COMMA" $nb, ENDOF
3375: '. OF s" _DOT" $nb, ENDOF
3376: '" OF s" _DQUOT" $nb, ENDOF
3377: dup
3378: base @ >r hex s>d <# #s 'X hold '_ hold #> $nb, r> base !
3379: ENDCASE ;
3380:
3381: : label-from-ghostname ( ghost -- addr len )
3382: dup >ghostname init-name-buf 'L nb, bounds
3383: ?DO I c@ name-char, LOOP
3384: \ we add the address to a name to make in unique
3385: \ because one name may appear more then once
3386: \ there are names (e.g. boot) that may be reference from other
3387: \ assembler source files, so we declare them as unique
3388: \ and don't add the address suffix
3389: dup >ghost-flags @ <unique> and 0=
3390: IF s" __" $nb, >link @ base @ >r hex 0 <# #s 'L hold #> r> base ! $nb,
3391: ELSE drop
3392: THEN
3393: @nb ;
3394:
3395: \ FIXME why disabled?!
3396: : label-from-ghostnameXX ( ghost -- addr len )
3397: \ same as (label-from-ghostname) but caches generated names
3398: dup >asm-name @ ?dup IF nip count EXIT THEN
3399: \ dup >r (label-from-ghostname) 2dup
3400: align here >r string, align
3401: r> r> >asm-name ! ;
3402:
3403: : primghostdiscover ( xt -- ghost true | xt false )
3404: dup 0= IF false EXIT THEN
3405: >r last-prim-ghost
3406: BEGIN @ dup
3407: WHILE dup >asm-dummyaddr @ r@ =
3408: IF rdrop true EXIT THEN
3409: REPEAT
3410: drop r> false ;
3411:
3412: : gdiscover2 ( xt -- ghost true | xt false )
3413: dup taddr>region 0= IF false EXIT THEN
3414: dup (>regiontype) @ dup 0= IF drop false EXIT THEN
3415: addr-xt-ghost @ dup 0= IF drop false EXIT THEN
3416: nip true ;
3417: \ dup >ghost-name @ IF nip true ELSE drop false THEN ;
3418:
3419: \ generates a label name for the target address
3420: : generate-label-name ( taddr -- addr len )
3421: gdiscover2
3422: IF dup >magic @ <do:> =
3423: IF >asm-name @ count EXIT THEN
3424: label-from-ghostname
3425: ELSE
3426: primghostdiscover
3427: IF >asm-name @ count
3428: ELSE base @ >r hex 0 <# #s 'L hold #> r> base !
3429: THEN
3430: THEN ;
3431:
3432: Variable outfile-fd
3433:
3434: : $out ( adr len -- ) outfile-fd @ write-file throw ;
3435: : nlout newline $out ;
3436: : .ux ( n -- )
3437: base @ hex swap 0 <# #S #> $out base ! ;
3438:
3439: : save-asm-region-part-aligned ( taddr len -- 'taddr 'len )
3440: dup cell/ 0
3441: ?DO nlout s" .word " $out over @relbit
3442: IF over X @ generate-label-name $out
3443: ELSE over X @ s" 0x0" $out .ux
3444: THEN
3445: tcell /string
3446: LOOP ;
3447:
3448: : print-bytes ( taddr len n -- taddr' len' )
3449: over min dup 0>
3450: IF nlout s" .byte " $out 0
3451: ?DO I 0> IF s" , " $out THEN
3452: over X c@ s" 0x0" $out .ux 1 /string
3453: LOOP
3454: THEN ;
3455:
3456: : save-asm-region-part ( addr len -- )
3457: over dup X aligned swap - ?dup
3458: IF print-bytes THEN
3459: save-asm-region-part-aligned
3460: dup dup X aligned swap - ?dup
3461: IF 2 pick @relbit ABORT" relocated field splitted"
3462: print-bytes
3463: THEN
3464: 2drop ;
3465:
3466: : print-label ( taddr -- )
3467: nlout generate-label-name $out s" :" $out ;
3468:
3469: : snl-calc ( taddr taddr2 -- )
3470: tuck over - ;
3471:
3472: : skip-nolables ( taddr -- taddr2 taddr len )
3473: \G skips memory region where no lables are defined
3474: \G starting from taddr+1
3475: \G Labels will be introduced for each reference mark
3476: \G in addr-refs.
3477: \G This word deals with lables at byte addresses as well.
3478: \G The main idea is to have an intro part which
3479: \G skips until the next cell boundary, the middle part
3480: \G which skips whole cells very efficiently and the third
3481: \G part which skips the bytes to the label in a cell
3482: dup 1+ dup (>regiontype)
3483: ( S taddr taddr-realstart type-addr )
3484: dup @ dup IF addr-refs @ THEN
3485: swap >r
3486: over align+ tuck tcell swap - rshift swap 0
3487: ?DO dup 1 and
3488: IF drop rdrop snl-calc UNLOOP EXIT THEN
3489: 2/ swap 1+ swap
3490: LOOP
3491: drop r> cell+
3492: ( S .. taddr2 type-addr ) dup
3493: BEGIN dup @ dup IF addr-refs @ THEN 0= WHILE cell+ REPEAT
3494: dup >r swap - 1 cells / tcell * + r>
3495: ( S .. taddr2+skiplencells type-addr )
3496: @ addr-refs @ 1 tcell lshift or
3497: BEGIN dup 1 and 0= WHILE swap 1+ swap 2/ REPEAT drop
3498: ( S .. taddr2+skiplencells+skiplenbytes )
3499: snl-calc ;
3500:
3501: : insert-label ( taddr -- )
3502: dup 0= IF drop EXIT THEN
3503: \ ignore everything which points outside our memory regions
3504: \ maybe a primitive pointer or whatever
3505: dup taddr>region 0= IF drop EXIT THEN
3506: dup >r (>regiontype) define-addr-struct addr-refs dup @
3507: r> tcell 1- and 1 swap lshift or swap ! ;
3508:
3509: \ this generates a sorted list of addresses which must be labels
3510: \ it scans therefore a whole region
3511: : generate-label-list-region ( taddr len -- )
3512: BEGIN over @relbit IF over X @ insert-label THEN
3513: tcell /string dup 0<
3514: UNTIL 2drop ;
3515:
3516: : generate-label-list ( -- )
3517: region-link
3518: BEGIN @ dup WHILE
3519: dup 0 >rlink - extent
3520: ?dup IF generate-label-list-region ELSE drop THEN
3521: REPEAT drop ;
3522:
3523: : create-outfile ( addr len -- )
3524: w/o bin create-file throw outfile-fd ! ;
3525:
3526: : close-outfile ( -- )
3527: outfile-fd @ close-file throw ;
3528:
3529: : (save-asm-region) ( region -- )
3530: \ ." label list..."
3531: generate-label-list
3532: \ ." ok!" cr
3533: extent ( S taddr len )
3534: over insert-label
3535: 2dup + dup insert-label >r ( R end-label )
3536: ( S taddr len ) drop
3537: BEGIN
3538: dup print-label
3539: dup r@ <> WHILE
3540: skip-nolables save-asm-region-part
3541: REPEAT drop rdrop ;
3542:
3543: : lineout ( addr len -- )
3544: outfile-fd @ write-line throw ;
3545:
3546: : save-asm-region ( region adr len -- )
3547: create-outfile (save-asm-region) close-outfile ;
3548:
3549: \ \ minimal definitions
3550:
3551: >MINIMAL also minimal
3552:
3553: \ Usefull words 13feb93py
3554:
3555: : KB 400 * ;
3556:
3557: \ \ [IF] [ELSE] [THEN] ... 14sep97jaw
3558:
3559: \ it is useful to define our own structures and not to rely
3560: \ on the words in the host system
3561: \ The words in the host system might be defined with vocabularies
3562: \ this doesn't work with our self-made compile-loop
3563:
3564: Create parsed 20 chars allot \ store word we parsed
3565:
3566: : upcase
3567: parsed count bounds
3568: ?DO I c@ toupper I c! LOOP ;
3569:
3570: : [ELSE]
3571: 1 BEGIN
3572: BEGIN bl word count dup WHILE
3573: comment? 20 umin parsed place upcase parsed count
3574: 2dup s" [IF]" str= >r
3575: 2dup s" [IFUNDEF]" str= >r
3576: 2dup s" [IFDEF]" str= r> or r> or
3577: IF 2drop 1+
3578: ELSE 2dup s" [ELSE]" str=
3579: IF 2drop 1- dup
3580: IF 1+
3581: THEN
3582: ELSE
3583: 2dup s" [ENDIF]" str= >r
3584: s" [THEN]" str= r> or
3585: IF 1- THEN
3586: THEN
3587: THEN
3588: ?dup 0= ?EXIT
3589: REPEAT
3590: 2drop refill 0=
3591: UNTIL drop ; immediate
3592:
3593: : [THEN] ( -- ) ; immediate
3594:
3595: : [ENDIF] ( -- ) ; immediate
3596:
3597: : [IF] ( flag -- )
3598: 0= IF postpone [ELSE] THEN ; immediate
3599:
3600: Cond: [IF] postpone [IF] ;Cond
3601: Cond: [THEN] postpone [THEN] ;Cond
3602: Cond: [ELSE] postpone [ELSE] ;Cond
3603:
3604: \ define new [IFDEF] and [IFUNDEF] 20may93jaw
3605:
3606: : defined? tdefined? ;
3607: : needed? needed? ;
3608: : doer? doer? ;
3609:
3610: \ we want to use IFDEF on compiler directives (e.g. E?) in the source, too
3611:
3612: : directive?
3613: bl word count [ ' target >wordlist ] literal search-wordlist
3614: dup IF nip THEN ;
3615:
3616: : [IFDEF] >in @ directive? swap >in !
3617: 0= IF tdefined? ELSE name 2drop true THEN
3618: postpone [IF] ;
3619:
3620: : [IFUNDEF] tdefined? 0= postpone [IF] ;
3621:
3622: Cond: [IFDEF] postpone [IFDEF] ;Cond
3623:
3624: Cond: [IFUNDEF] postpone [IFUNDEF] ;Cond
3625:
3626: \ C: \- \+ Conditional Compiling 09jun93jaw
3627:
3628: : C: >in @ tdefined? 0=
3629: IF >in ! X :
3630: ELSE drop
3631: BEGIN bl word dup c@
3632: IF count comment? s" ;" str= ?EXIT
3633: ELSE refill 0= ABORT" CROSS: Out of Input while C:"
3634: THEN
3635: AGAIN
3636: THEN ;
3637:
3638: : d? d? ;
3639:
3640: : \D ( -- "debugswitch" )
3641: \G doesn't skip line when debug switch is on
3642: D? 0= IF postpone \ THEN ;
3643:
3644: : \- ( -- "wordname" )
3645: \G interprets the line if word is not defined
3646: tdefined? IF postpone \ THEN ;
3647:
3648: : \+ ( -- "wordname" )
3649: \G interprets the line if word is defined
3650: tdefined? 0= IF postpone \ THEN ;
3651:
3652: : \? ( -- "envorinstring" )
3653: \G Skip line if environmental variable evaluates to false
3654: X has? 0= IF postpone \ THEN ;
3655:
3656: Cond: \- \- ;Cond
3657: Cond: \+ \+ ;Cond
3658: Cond: \D \D ;Cond
3659: Cond: \? \? ;Cond
3660:
3661: : ?? bl word find IF execute ELSE drop 0 THEN ;
3662:
3663: : needed:
3664: \G defines ghost for words that we want to be compiled
3665: BEGIN >in @ bl word c@ WHILE >in ! Ghost drop REPEAT drop ;
3666:
3667: \ words that should be in minimal
3668:
3669: create s-buffer 50 chars allot
3670:
3671: bigendian Constant bigendian
3672:
3673: : here there ;
3674: : equ constant ;
3675: : mark there constant ;
3676:
3677: \ compiler directives
3678: : >ram >ram ;
3679: : >rom >rom ;
3680: : >auto >auto ;
3681: : >tempdp >tempdp ;
3682: : tempdp> tempdp> ;
3683: : const constflag on ;
3684:
3685: : Redefinitions-start
3686: \G Starts a redefinition section. Warnings are disabled and
3687: \G existing ghosts are reused. This is used in the kernel
3688: \G where ( and \ and the like are redefined
3689: twarnings off warnings off reuse-ghosts on ;
3690:
3691: : Redefinitions-end
3692: \G Ends a redefinition section. Warnings are enabled again.
3693: twarnings on warnings on reuse-ghosts off ;
3694:
3695: : warnings name 3 =
3696: IF twarnings off warnings off ELSE twarnings on warnings on THEN drop ;
3697:
3698: : | ;
3699: \ : | NoHeaderFlag on ; \ This is broken (damages the last word)
3700:
3701: : save-cross save-cross ;
3702: : save-region save-region ;
3703: : tdump swap >image swap dump ;
3704:
3705: also forth
3706: [IFDEF] Label : Label defempty? Label ; [THEN]
3707: [IFDEF] start-macros : start-macros defempty? start-macros ; [THEN]
3708: \ [IFDEF] builttag : builttag builttag ; [THEN]
3709: previous
3710:
3711: : s" [char] " parse s-buffer place s-buffer count ; \ for environment?
3712: : + + ;
3713: : 1+ 1 + ;
3714: : 2+ 2 + ;
3715: : 1- 1- ;
3716: : - - ;
3717: : and and ;
3718: : or or ;
3719: : 2* 2* ;
3720: : * * ;
3721: : / / ;
3722: : dup dup ;
3723: : ?dup ?dup ;
3724: : over over ;
3725: : swap swap ;
3726: : rot rot ;
3727: : drop drop ;
3728: : 2drop 2drop ;
3729: : = = ;
3730: : <> <> ;
3731: : 0= 0= ;
3732: : lshift lshift ;
3733: : 2/ 2/ ;
3734: : hex. base @ $10 base ! swap . base ! ;
3735: : invert invert ;
3736: : linkstring ( addr u n addr -- )
3737: X here over X @ X , swap X ! X , ht-string, X align ;
3738: \ : . . ;
3739:
3740: : all-words ['] forced? IS skip? ;
3741: : needed-words ['] needed? IS skip? ;
3742: : undef-words ['] defined2? IS skip? ;
3743: : skipdef skipdef ;
3744:
3745: : \ postpone \ ; immediate
3746: : \G T-\G ; immediate
3747: : ( postpone ( ; immediate
3748: : include bl word count included ;
3749: : included swap >image swap included ;
3750: : require require ;
3751: : needs require ;
3752: : .( [char] ) parse type ;
3753: : ERROR" [char] " parse
3754: rot
3755: IF cr ." *** " type ." ***" -1 ABORT" CROSS: Target error, see text above"
3756: ELSE 2drop
3757: THEN ;
3758: : ." [char] " parse type ;
3759: : cr cr ;
3760:
3761: : times 0 ?DO dup X c, LOOP drop ; \ used for space table creation
3762:
3763: \ only forth also cross also minimal definitions order
3764:
3765: \ cross-compiler words
3766:
3767: : decimal decimal [g'] decimal >exec2 @ ?dup IF EXECUTE THEN ;
3768: : hex hex [g'] hex >exec2 @ ?dup IF EXECUTE THEN ;
3769:
3770: \ : tudp X tudp ;
3771: \ : tup X tup ;
3772:
3773: : doc-off false to-doc ! ;
3774: : doc-on true to-doc ! ;
3775:
3776: : declareunique ( "name" -- )
3777: \ Sets the unique flag for a ghost. The assembler output
3778: \ generates labels with the ghostname concatenated with the address
3779: \ while cross-compiling. The address is concatenated
3780: \ because we have double occurences of the same name.
3781: \ If we want to reference the labels from the assembler or C
3782: \ code we declare them unique, so the address is skipped.
3783: Ghost >ghost-flags dup @ <unique> or swap ! ;
3784:
3785: \ [IFDEF] dbg : dbg dbg ; [THEN]
3786:
3787: \ for debugging...
3788: \ : dbg dbg ;
3789: : horder order ;
3790: : hwords words ;
3791: \ : words also ghosts
3792: \ words previous ;
3793: : .s .s ;
3794: : depth depth ;
3795: : bye bye ;
3796:
3797: \ dummy
3798:
3799: \ turnkey direction
3800: : H forth ; immediate
3801: : T minimal ; immediate
3802: : G ghosts ; immediate
3803:
3804:
3805: \ these ones are pefered:
3806:
3807: : unlock previous forth also cross ;
3808:
3809: \ also minimal
3810: >cross
3811:
3812: : turnkey
3813: ghosts-wordlist 1 set-order
3814: also target definitions
3815: also Minimal also ;
3816:
3817: >minimal
3818:
3819: : [[+++
3820: turnkey unlock ;
3821:
3822: unlock definitions also minimal
3823:
3824: : lock turnkey ;
3825:
3826: Defer +++]]-hook
3827: : +++]] +++]]-hook lock ;
3828:
3829: LOCK
3830: \ load cross compiler extension defined in mach file
3831:
3832: UNLOCK >CROSS
3833:
3834: [IFDEF] extend-cross extend-cross [THEN]
3835:
3836: LOCK
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to cross.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth