File:  [gforth] / gforth / cross.fs
Revision 1.183: download - view: text, annotated - select for diffs
Mon Aug 27 13:33:48 2012 UTC (7 years, 2 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Make gforth compile again

    1: \ CROSS.FS     The Cross-Compiler                      06oct92py
    2: \ Idea and implementation: Bernd Paysan (py)
    3: 
    4: \ Copyright (C) 1995,1996,1997,1998,1999,2000,2003,2004,2005,2006,2007,2009,2010,2011 Free Software Foundation, Inc.
    5: 
    6: \ This file is part of Gforth.
    7: 
    8: \ Gforth is free software; you can redistribute it and/or
    9: \ modify it under the terms of the GNU General Public License
   10: \ as published by the Free Software Foundation, either version 3
   11: \ of the License, or (at your option) any later version.
   12: 
   13: \ This program is distributed in the hope that it will be useful,
   14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   16: \ GNU General Public License for more details.
   17: 
   18: \ You should have received a copy of the GNU General Public License
   19: \ along with this program. If not, see http://www.gnu.org/licenses/.
   20: 
   21: 0 
   22: [IF]
   23: 
   24: ToDo:
   25: - Crossdoc destination ./doc/crossdoc.fd makes no sense when
   26:   cross.fs is used seperately. jaw
   27: - Do we need this char translation with >address and in branchoffset? 
   28:   (>body also affected) jaw
   29: 
   30: [THEN]
   31: 
   32: s" compat/strcomp.fs" included
   33: 
   34: hex
   35: 
   36: \ debugging for compiling
   37: 
   38: \ print stack at each colon definition
   39: \ : : save-input cr bl word count type restore-input throw .s : ;
   40: 
   41: \ print stack at each created word
   42: \ : create save-input cr bl word count type restore-input throw .s create ;
   43: 
   44: 
   45: \ \ -------------  Setup Vocabularies
   46: 
   47: \ Remark: Vocabulary is not ANS, but it should work...
   48: 
   49: Vocabulary Cross
   50: Vocabulary Target
   51: Vocabulary Ghosts
   52: Vocabulary Minimal
   53: only Forth also Target also also
   54: definitions Forth
   55: 
   56: : T  previous Ghosts also Target ; immediate
   57: : G  Ghosts ; immediate
   58: : H  previous Forth also Cross ; immediate
   59: 
   60: forth definitions
   61: 
   62: : T  previous Ghosts also Target ; immediate
   63: : G  Ghosts ; immediate
   64: 
   65: 
   66: : >cross  also Cross definitions previous ;
   67: : >target also Target definitions previous ;
   68: : >minimal also Minimal definitions previous ;
   69: 
   70: H
   71: 
   72: >CROSS
   73: 
   74: \ Test against this definitions to find out whether we are cross-compiling
   75: \ may be usefull for assemblers
   76: 0 Constant gforth-cross-indicator
   77: 
   78: \ find out whether we are compiling with gforth
   79: 
   80: : defined? bl word find nip ;
   81: defined? emit-file defined? toupper and \ drop 0
   82: [IF]
   83: \ use this in a gforth system
   84: : \GFORTH ; immediate
   85: : \ANSI postpone \ ; immediate
   86: [ELSE]
   87: : \GFORTH postpone \ ; immediate
   88: : \ANSI ; immediate
   89: [THEN]
   90: 
   91: \ANSI : [IFUNDEF] defined? 0= postpone [IF] ; immediate
   92: \ANSI : [IFDEF] defined? postpone [IF] ; immediate
   93: 0 \ANSI drop 1
   94: [IF]
   95: : \G postpone \ ; immediate
   96: : rdrop postpone r> postpone drop ; immediate
   97: : name bl word count ;
   98: : bounds over + swap ;
   99: : scan >r BEGIN dup WHILE over c@ r@ <> WHILE 1 /string REPEAT THEN rdrop ;
  100: : linked here over @ , swap ! ;
  101: : alias create , DOES> @ EXECUTE ;
  102: : defer ['] noop alias ;
  103: : is state @ 
  104:   IF ' >body postpone literal postpone ! 
  105:   ELSE ' >body ! THEN ; immediate
  106: : 0>= 0< 0= ;
  107: : d<> rot <> -rot <> or ;
  108: : toupper dup [char] a [char] z 1+ within IF [char] A [char] a - + THEN ;
  109: Variable ebuf
  110: : emit-file ( c fd -- ior ) swap ebuf c! ebuf 1 chars rot write-file ;
  111: 0a Constant #lf
  112: 0d Constant #cr
  113: 
  114: [IFUNDEF] Warnings Variable Warnings [THEN]
  115: 
  116: \ \ Number parsing					23feb93py
  117: 
  118: \ number? number                                       23feb93py
  119: 
  120: Variable dpl
  121: 
  122: hex
  123: Create bases   10 ,   2 ,   A , 100 ,
  124: \              16     2    10   character
  125: 
  126: \ !! protect BASE saving wrapper against exceptions
  127: : getbase ( addr u -- addr' u' )
  128:     over c@ [char] $ - dup 4 u<
  129:     IF
  130: 	cells bases + @ base ! 1 /string
  131:     ELSE
  132: 	drop
  133:     THEN ;
  134: 
  135: : sign? ( addr u -- addr u flag )
  136:     over c@ [char] - =  dup >r
  137:     IF
  138: 	1 /string
  139:     THEN
  140:     r> ;
  141: 
  142: : s>unumber? ( addr u -- ud flag )
  143:     over [char] ' =
  144:     IF 	\ a ' alone is rather unusual :-)
  145: 	drop char+ c@ 0 true EXIT 
  146:     THEN
  147:     base @ >r  dpl on  getbase
  148:     0. 2swap
  149:     BEGIN ( d addr len )
  150: 	dup >r >number dup
  151:     WHILE \ there are characters left
  152: 	dup r> -
  153:     WHILE \ the last >number parsed something
  154: 	dup 1- dpl ! over c@ [char] . =
  155:     WHILE \ the current char is '.'
  156: 	1 /string
  157:     REPEAT  THEN \ there are unparseable characters left
  158: 	2drop false
  159:     ELSE
  160: 	rdrop 2drop true
  161:     THEN
  162:     r> base ! ;
  163: 
  164: \ ouch, this is complicated; there must be a simpler way - anton
  165: : s>number? ( addr len -- d f )
  166:     \ converts string addr len into d, flag indicates success
  167:     sign? >r
  168:     s>unumber?
  169:     0= IF
  170:         rdrop false
  171:     ELSE \ no characters left, all ok
  172: 	r>
  173: 	IF
  174: 	    dnegate
  175: 	THEN
  176: 	true
  177:     THEN ;
  178: 
  179: : s>number ( addr len -- d )
  180:     \ don't use this, there is no way to tell success
  181:     s>number? drop ;
  182: 
  183: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
  184:     s>number? 0=
  185:     IF
  186: 	2drop false  EXIT
  187:     THEN
  188:     dpl @ dup 0< IF
  189: 	nip
  190:     ELSE
  191: 	1+
  192:     THEN ;
  193: 
  194: : (number?) ( string -- string 0 / n -1 / d 0> )
  195:     dup >r count snumber? dup if
  196: 	rdrop
  197:     else
  198: 	r> swap
  199:     then ;
  200: 
  201: : number ( string -- d )
  202:     (number?) ?dup 0= abort" ?"  0<
  203:     IF
  204: 	s>d
  205:     THEN ;
  206: 
  207: [THEN]
  208: 
  209: [IFUNDEF] (number?) : (number?) number? ; [THEN]
  210: 
  211: \ this provides assert( and struct stuff
  212: \GFORTH [IFUNDEF] assert1(
  213: \GFORTH also forth definitions require assert.fs previous
  214: \GFORTH [THEN]
  215: 
  216: >CROSS
  217: 
  218: hex     \ the defualt base for the cross-compiler is hex !!
  219: \ Warnings off
  220: 
  221: \ words that are generaly useful
  222: 
  223: : KB  400 * ;
  224: : >wordlist ( vocabulary-xt -- wordlist-struct )
  225:   also execute get-order swap >r 1- set-order r> ;
  226: 
  227: : umax 2dup u< IF swap THEN drop ;
  228: : umin 2dup u> IF swap THEN drop ;
  229: 
  230: : string, ( c-addr u -- )
  231:     \ puts down string as cstring
  232:     dup c, here swap chars dup allot move ;
  233: 
  234: : ," [char] " parse string, ;
  235: 
  236: : SetValue ( n -- <name> )
  237: \G Same behaviour as "Value" if the <name> is not defined
  238: \G Same behaviour as "to" if <name> is defined
  239: \G SetValue searches in the current vocabulary
  240:   save-input bl word >r restore-input throw r> count
  241:   get-current search-wordlist
  242:   IF	drop >r
  243: 	\ we have to set current to be topmost context wordlist
  244: 	get-order get-order get-current swap 1+ set-order
  245: 	r> ['] to execute
  246: 	set-order
  247:   ELSE Value THEN ;
  248: 
  249: : DefaultValue ( n -- <name> )
  250: \G Same behaviour as "Value" if the <name> is not defined
  251: \G DefaultValue searches in the current vocabulary
  252:  save-input bl word >r restore-input throw r> count
  253:  get-current search-wordlist
  254:  IF bl word drop 2drop ELSE Value THEN ;
  255: 
  256: hex
  257: 
  258: \ FIXME delete`
  259: \ 1 Constant Cross-Flag	\ to check whether assembler compiler plug-ins are
  260: 			\ for cross-compiling
  261: \ No! we use "[IFUNDEF]" there to find out whether we are target compiling!!!
  262: 
  263: \ FIXME move down
  264: : comment? ( c-addr u -- c-addr u )
  265:         2dup s" (" str=
  266:         IF    postpone (
  267:         ELSE  2dup s" \" str= IF postpone \ THEN
  268:         THEN ;
  269: 
  270: : X ( -- <name> )
  271: \G The next word in the input is a target word.
  272: \G Equivalent to T <name> but without permanent
  273: \G switch to target dictionary. Used as prefix e.g. for @, !, here etc.
  274:   bl word count [ ' target >wordlist ] Literal search-wordlist
  275:   IF state @ IF compile, ELSE execute THEN
  276:   ELSE	-1 ABORT" Cross: access method not supported!"
  277:   THEN ; immediate
  278: 
  279: \ Begin CROSS COMPILER:
  280: 
  281: \ debugging
  282: 
  283: 0 [IF]
  284: 
  285: This implements debugflags for the cross compiler and the compiled
  286: images. It works identical to the has-flags in the environment.
  287: The debugflags are defined in a vocabluary. If the word exists and
  288: its value is true, the flag is switched on.
  289: 
  290: [THEN]
  291: 
  292: >CROSS
  293: 
  294: Vocabulary debugflags	\ debug flags for cross
  295: also debugflags get-order over
  296: Constant debugflags-wl
  297: set-order previous
  298: 
  299: : DebugFlag
  300:   get-current >r debugflags-wl set-current
  301:   SetValue
  302:   r> set-current ;
  303: 
  304: : Debug? ( adr u -- flag )
  305: \G return true if debug flag is defined or switched on
  306:   debugflags-wl search-wordlist
  307:   IF EXECUTE
  308:   ELSE false THEN ;
  309: 
  310: : D? ( <name> -- flag )
  311: \G return true if debug flag is defined or switched on
  312: \G while compiling we do not return the current value but
  313:   bl word count debug? ;
  314: 
  315: : [d?]
  316: \G compile the value-xt so the debug flag can be switched
  317: \G the flag must exist!
  318:   bl word count debugflags-wl search-wordlist
  319:   IF 	compile,
  320:   ELSE  -1 ABORT" unknown debug flag"
  321: 	\ POSTPONE false 
  322:   THEN ; immediate
  323: 
  324: : symentry ( adr len taddr -- )
  325: \G Produce a symbol table (an optional symbol address
  326: \G map) if wanted
  327:     [ [IFDEF] fd-symbol-table ]
  328:       base @ swap hex s>d <# 8 0 DO # LOOP #> fd-symbol-table write-file throw base !
  329:       s" :" fd-symbol-table write-file throw
  330:       fd-symbol-table write-line throw
  331:     [ [ELSE] ]
  332:       2drop drop
  333:     [ [THEN] ] ;
  334: 
  335: 
  336: \ \ --------------------	source file
  337: 
  338: decimal
  339: 
  340: Variable cross-file-list
  341: 0 cross-file-list !
  342: Variable target-file-list
  343: 0 target-file-list !
  344: Variable host-file-list
  345: 0 host-file-list !
  346: 
  347: cross-file-list Value file-list
  348: 0 Value source-desc
  349: 
  350: \ file loading
  351: 
  352: : >fl-id   1 cells + ;
  353: : >fl-name 2 cells + ;
  354: 
  355: Variable filelist 0 filelist !
  356: Create NoFile ," #load-file#"
  357: 
  358: : loadfile ( -- adr )
  359:   source-desc ?dup IF >fl-name ELSE NoFile THEN ;
  360: 
  361: : sourcefilename ( -- adr len ) 
  362:   loadfile count ;
  363: 
  364: \ANSI : sourceline# 0 ;
  365: 
  366: \ \ --------------------	path handling from kernel/paths.fs
  367: 
  368: \ paths.fs path file handling                                    03may97jaw
  369: 
  370: \ -Changing the search-path:
  371: \ fpath+ <path> 	adds a directory to the searchpath
  372: \ fpath= <path>|<path>	makes complete now searchpath
  373: \ 			seperator is |
  374: \ .fpath		displays the search path
  375: \ remark I: 
  376: \ a ./ in the beginning of filename is expanded to the directory the
  377: \ current file comes from. ./ can also be included in the search-path!
  378: \ ~+/ loads from the current working directory
  379: 
  380: \ remark II:
  381: \ if there is no sufficient space for the search path increase it!
  382: 
  383: 
  384: \ -Creating custom paths:
  385: 
  386: \ It is possible to use the search mechanism on yourself.
  387: 
  388: \ Make a buffer for the path:
  389: \ create mypath	100 chars , 	\ maximum length (is checked)
  390: \ 		0 ,		\ real len
  391: \ 		100 chars allot \ space for path
  392: \ use the same functions as above with:
  393: \ mypath path+ 
  394: \ mypath path=
  395: \ mypath .path
  396: 
  397: \ do a open with the search path:
  398: \ open-path-file ( adr len path -- fd adr len ior )
  399: \ the file is opened read-only; if the file is not found an error is generated
  400: 
  401: \ questions to: wilke@jwdt.com
  402: 
  403: [IFUNDEF] +place
  404: : +place ( adr len adr )
  405:         2dup >r >r
  406:         dup c@ char+ + swap move
  407:         r> r> dup c@ rot + swap c! ;
  408: [THEN]
  409: 
  410: [IFUNDEF] place
  411: : place ( c-addr1 u c-addr2 )
  412:         2dup c! char+ swap move ;
  413: [THEN]
  414: 
  415: \ if we have path handling, use this and the setup of it
  416: [IFUNDEF] open-fpath-file
  417: 
  418: create sourcepath 1024 chars , 0 , 1024 chars allot \ !! make this dynamic
  419: sourcepath value fpath
  420: 
  421: : also-path ( adr len path^ -- )
  422:   >r
  423:   \ len check
  424:   r@ cell+ @ over + r@ @ u> ABORT" path buffer too small!"
  425:   \ copy into
  426:   tuck r@ cell+ dup @ cell+ + swap cmove
  427:   \ make delimiter
  428:   0 r@ cell+ dup @ cell+ + 2 pick + c! 1 + r> cell+ +!
  429:   ;
  430: 
  431: : only-path ( adr len path^ -- )
  432:   dup 0 swap cell+ ! also-path ;
  433: 
  434: : path+ ( path-addr  "dir" -- ) \ gforth
  435:     \G Add the directory @var{dir} to the search path @var{path-addr}.
  436:     name rot also-path ;
  437: 
  438: : fpath+ ( "dir" ) \ gforth
  439:     \G Add directory @var{dir} to the Forth search path.
  440:     fpath path+ ;
  441: 
  442: : path= ( path-addr "dir1|dir2|dir3" ) \ gforth
  443:     \G Make a complete new search path; the path separator is |.
  444:     name 2dup bounds ?DO i c@ [char] | = IF 0 i c! THEN LOOP
  445:     rot only-path ;
  446: 
  447: : fpath= ( "dir1|dir2|dir3" ) \ gforth
  448:     \G Make a complete new Forth search path; the path separator is |.
  449:     fpath path= ;
  450: 
  451: : path>string  cell+ dup cell+ swap @ ;
  452: 
  453: : next-path ( adr len -- adr2 len2 )
  454:   2dup 0 scan
  455:   dup 0= IF     2drop 0 -rot 0 -rot EXIT THEN
  456:   >r 1+ -rot r@ 1- -rot
  457:   r> - ;
  458: 
  459: : previous-path ( path^ -- )
  460:   dup path>string
  461:   BEGIN tuck dup WHILE repeat ;
  462: 
  463: : .path ( path-addr -- ) \ gforth
  464:     \G Display the contents of the search path @var{path-addr}.
  465:     path>string
  466:     BEGIN next-path dup WHILE type space REPEAT 2drop 2drop ;
  467: 
  468: : .fpath ( -- ) \ gforth
  469:     \G Display the contents of the Forth search path.
  470:     fpath .path ;
  471: 
  472: : absolut-path? ( addr u -- flag ) \ gforth
  473:     \G A path is absolute if it starts with a / or a ~ (~ expansion),
  474:     \G or if it is in the form ./*, extended regexp: ^[/~]|./, or if
  475:     \G it has a colon as second character ("C:...").  Paths simply
  476:     \G containing a / are not absolute!
  477:     2dup 2 u> swap 1+ c@ [char] : = and >r \ dos absoulte: c:/....
  478:     over c@ [char] / = >r
  479:     over c@ [char] ~ = >r
  480:     \ 2dup S" ../" string-prefix? r> or >r \ not catered for in expandtopic
  481:     S" ./" string-prefix?
  482:     r> r> r> or or or ;
  483: 
  484: Create ofile 0 c, 255 chars allot
  485: Create tfile 0 c, 255 chars allot
  486: 
  487: : pathsep? dup [char] / = swap [char] \ = or ;
  488: 
  489: : need/   ofile dup c@ + c@ pathsep? 0= IF s" /" ofile +place THEN ;
  490: 
  491: : extractpath ( adr len -- adr len2 )
  492:   BEGIN dup WHILE 1-
  493:         2dup + c@ pathsep? IF EXIT THEN
  494:   REPEAT ;
  495: 
  496: : remove~+ ( -- )
  497:     ofile count s" ~+/" string-prefix?
  498:     IF
  499: 	ofile count 3 /string ofile place
  500:     THEN ;
  501: 
  502: : expandtopic ( -- ) \ stack effect correct? - anton
  503:     \ expands "./" into an absolute name
  504:     ofile count s" ./" string-prefix?
  505:     IF
  506: 	ofile count 1 /string tfile place
  507: 	0 ofile c! sourcefilename extractpath ofile place
  508: 	ofile c@ IF need/ THEN
  509: 	tfile count over c@ pathsep? IF 1 /string THEN
  510: 	ofile +place
  511:     THEN ;
  512: 
  513: : compact.. ( adr len -- adr2 len2 )
  514:     \ deletes phrases like "xy/.." out of our directory name 2dec97jaw
  515:     over swap
  516:     BEGIN  dup  WHILE
  517:         dup >r '/ scan 2dup s" /../" string-prefix?
  518:         IF
  519:             dup r> - >r 4 /string over r> + 4 -
  520:             swap 2dup + >r move dup r> over -
  521:         ELSE
  522:             rdrop dup 1 min /string
  523:         THEN
  524:     REPEAT  drop over - ;
  525: 
  526: : reworkdir ( -- )
  527:   remove~+
  528:   ofile count compact..
  529:   nip ofile c! ;
  530: 
  531: : open-ofile ( -- fid ior )
  532:     \G opens the file whose name is in ofile
  533:     expandtopic reworkdir
  534:     ofile count r/o open-file ;
  535: 
  536: : check-path ( adr1 len1 adr2 len2 -- fd 0 | 0 <>0 )
  537:   0 ofile ! >r >r ofile place need/
  538:   r> r> ofile +place
  539:   open-ofile ;
  540: 
  541: : open-path-file ( addr1 u1 path-addr -- wfileid addr2 u2 0 | ior ) \ gforth
  542:     \G Look in path @var{path-addr} for the file specified by @var{addr1 u1}.
  543:     \G If found, the resulting path and an open file descriptor
  544:     \G are returned. If the file is not found, @var{ior} is non-zero.
  545:   >r
  546:   2dup absolut-path?
  547:   IF    rdrop
  548:         ofile place open-ofile
  549: 	dup 0= IF >r ofile count r> THEN EXIT
  550:   ELSE  r> path>string
  551:         BEGIN  next-path dup
  552:         WHILE  5 pick 5 pick check-path
  553:         0= IF >r 2drop 2drop r> ofile count 0 EXIT ELSE drop THEN
  554:   REPEAT
  555:         2drop 2drop 2drop -38
  556:   THEN ;
  557: 
  558: : open-fpath-file ( addr1 u1 -- wfileid addr2 u2 0 | ior ) \ gforth
  559:     \G Look in the Forth search path for the file specified by @var{addr1 u1}.
  560:     \G If found, the resulting path and an open file descriptor
  561:     \G are returned. If the file is not found, @var{ior} is non-zero.
  562:     fpath open-path-file ;
  563: 
  564: fpath= ~+
  565: 
  566: [THEN]
  567: 
  568: \ \ --------------------	include require			13may99jaw
  569: 
  570: >CROSS
  571: 
  572: : add-included-file ( adr len -- adr )
  573:   dup >fl-name char+ allocate throw >r
  574:   file-list @ r@ ! r@ file-list !
  575:   r@ >fl-name place r> ;
  576: 
  577: : included? ( c-addr u -- f )
  578:   file-list
  579:   BEGIN	@ dup
  580:   WHILE	>r 2dup r@ >fl-name count str=
  581: 	IF rdrop 2drop true EXIT THEN
  582: 	r>
  583:   REPEAT
  584:   2drop drop false ;	
  585: 
  586: false DebugFlag showincludedfiles
  587: 
  588: : included1 ( fd adr u -- )
  589: \ include file adr u / fd
  590: \ we don't use fd with include-file, because the forth system
  591: \ doesn't know the name of the file to get a nice error report
  592:   [d?] showincludedfiles
  593:   IF	cr ." Including: " 2dup type ." ..." THEN
  594:   rot close-file throw
  595:   source-desc >r
  596:   add-included-file to source-desc 
  597:   sourcefilename
  598:   ['] included catch
  599:   r> to source-desc 
  600:   throw ;
  601: 
  602: : included ( adr len -- )
  603: 	cross-file-list to file-list
  604: 	open-fpath-file throw 
  605:         included1 ;
  606: 
  607: : required ( adr len -- )
  608: 	cross-file-list to file-list
  609: 	open-fpath-file throw \ 2dup cr ." R:" type
  610: 	2dup included?
  611: 	IF 	2drop close-file throw
  612: 	ELSE	included1
  613: 	THEN ;
  614: 
  615: : include bl word count included ;
  616: 
  617: : require bl word count required ;
  618: 
  619: 0 [IF]
  620: 
  621: also forth definitions previous
  622: 
  623: : included ( adr len -- ) included ;
  624: 
  625: : required ( adr len -- ) required ;
  626: 
  627: : include include ;
  628: 
  629: : require require ;
  630: 
  631: [THEN]
  632: 
  633: >CROSS
  634: hex
  635: 
  636: \ \ --------------------        Error Handling                  05aug97jaw
  637: 
  638: \ Flags
  639: 
  640: also forth definitions  \ these values may be predefined before
  641:                         \ the cross-compiler is loaded
  642: 
  643: false DefaultValue stack-warn   	 \ check on empty stack at any definition
  644: false DefaultValue create-forward-warn   \ warn on forward declaration of created words
  645: 
  646: previous >CROSS
  647: 
  648: : .dec
  649:   base @ decimal swap . base ! ;
  650: 
  651: : .sourcepos
  652:   cr sourcefilename type ." :"
  653:   sourceline# .dec ;
  654: 
  655: : warnhead
  656: \G display error-message head
  657: \G perhaps with linenumber and filename
  658:   .sourcepos ." Warning: " ;
  659: 
  660: : empty? depth IF .sourcepos ." Stack not empty!"  THEN ;
  661: 
  662: stack-warn [IF]
  663: : defempty? empty? ;
  664: [ELSE]
  665: : defempty? ; immediate
  666: \ : defempty? .sourcepos ; 
  667: [THEN]
  668: 
  669: \ \ --------------------        Compiler Plug Ins               01aug97jaw
  670: 
  671: >CROSS
  672: 
  673: \ Compiler States
  674: 
  675: Variable comp-state
  676: 0 Constant interpreting
  677: 1 Constant compiling
  678: 2 Constant resolving
  679: 3 Constant assembling
  680: 
  681: : compiling? comp-state @ compiling = ;
  682: 
  683: : pi-undefined -1 ABORT" Plugin undefined" ;
  684: 
  685: : Plugin ( -- : pluginname )
  686:   Create 
  687:   \ for normal cross-compiling only one action
  688:   \ exists, this fields are identical. For the instant
  689:   \ simulation environment we need, two actions for each plugin
  690:   \ the target one and the one that generates the simulation code
  691:   ['] pi-undefined , \ action
  692:   ['] pi-undefined , \ target plugin action
  693:   8765 ,     \ plugin magic
  694:   DOES> perform ;
  695: 
  696: Plugin DummyPlugin
  697: 
  698: : 'PI ( -- addr : pluginname )
  699:   ' >body dup 2 cells + @ 8765 <> ABORT" not a plugin" ;
  700: 
  701: : plugin-of ( xt -- : pluginname )
  702:   dup 'PI 2! ;
  703: 
  704: : action-of ( xt -- : plunginname )
  705:   'PI cell+ ! ;
  706: 
  707: : TPA ( -- : plugin )
  708: \ target plugin action
  709: \ executes current target action of plugin
  710:   'PI cell+ POSTPONE literal POSTPONE perform ; immediate
  711: 
  712: Variable ppi-temp 0 ppi-temp !
  713: 
  714: : pa:
  715: \g define plugin action
  716:   ppi-temp @ ABORT" pa: definition not closed"
  717:   'PI ppi-temp ! :noname ;
  718: 
  719: : ;pa
  720: \g end a definition for plugin action
  721:   POSTPONE ; ppi-temp @ ! 0 ppi-temp ! ; immediate
  722: 
  723: 
  724: Plugin dlit, ( d -- )			\ compile numerical value the target
  725: Plugin lit, ( n -- )
  726: Plugin alit, ( n -- )
  727: 
  728: Plugin branch, ( target-addr -- )	\ compiles a branch
  729: Plugin ?branch, ( target-addr -- )	\ compiles a ?branch
  730: Plugin branchmark, ( -- branch-addr )	\ reserves room for a branch
  731: Plugin ?branchmark, ( -- branch-addr )	\ reserves room for a ?branch
  732: Plugin ?domark, ( -- branch-addr )	\ reserves room for a ?do branch
  733: Plugin branchto, ( -- )			\ actual program position is target of a branch (do e.g. alignment)
  734: ' NOOP plugin-of branchto, 
  735: Plugin branchtoresolve, ( branch-addr -- ) \ resolves a forward reference from branchmark
  736: Plugin branchtomark, ( -- target-addr )	\ marks a branch destination
  737: 
  738: Plugin colon, ( tcfa -- )		\ compiles call to tcfa at current position
  739: Plugin prim, ( tcfa -- )		\ compiles primitive invocation
  740: Plugin colonmark, ( -- addr )		\ marks a colon call
  741: Plugin colon-resolve ( tcfa addr -- )
  742: 
  743: Plugin addr-resolve ( target-addr addr -- )
  744: Plugin doer-resolve ( ghost res-pnt target-addr addr -- ghost res-pnt )
  745: 
  746: Plugin ncontrols? ( [ xn ... x1 ] n -- ) \ checks wheter n control structures are open
  747: Plugin if, 	( -- if-token )
  748: Plugin else,	( if-token -- if-token )
  749: Plugin then,	( if-token -- )
  750: Plugin ahead,
  751: Plugin begin,
  752: Plugin while,
  753: Plugin until,
  754: Plugin again,
  755: Plugin repeat,
  756: Plugin cs-swap	( x1 x2 -- x2 x1 )
  757: 
  758: Plugin case,	( -- n )
  759: Plugin of,	( n -- x1 n )
  760: Plugin endof,	( x1 n -- x2 n )
  761: Plugin endcase,	( x1 .. xn n -- )
  762: 
  763: Plugin do,	( -- do-token )
  764: Plugin ?do,	( -- ?do-token )
  765: Plugin for,	( -- for-token )
  766: Plugin loop,	( do-token / ?do-token -- )
  767: Plugin +loop,	( do-token / ?do-token -- )
  768: Plugin -loop,	( do-token / ?do-token -- )
  769: Plugin next,	( for-token )
  770: Plugin leave,	( -- )
  771: Plugin ?leave, 	( -- )
  772: 
  773: Plugin ca>native  \ Convert a code address to the processors
  774:                   \ native address. This is used in doprim, and
  775:                   \ code/code: primitive definitions word to
  776:                   \ convert the addresses.
  777:                   \ The only target where we need this is the misc
  778:                   \ which is a 16 Bit processor with word addresses
  779:                   \ but the forth system we build has a normal byte
  780:                   \ addressed memory model    
  781: 
  782: Plugin doprim,	\ compiles start of a primitive
  783: Plugin docol,   	\ compiles start of a colon definition
  784: Plugin doer,		
  785: Plugin fini,      \ compiles end of definition ;s
  786: Plugin doeshandler,
  787: Plugin dodoes,
  788: 
  789: Plugin colon-start
  790: ' noop plugin-of colon-start
  791: Plugin colon-end
  792: ' noop plugin-of colon-end
  793: 
  794: Plugin ]comp     \ starts compilation
  795: ' noop plugin-of ]comp
  796: Plugin comp[     \ ends compilation
  797: ' noop plugin-of comp[
  798: 
  799: Plugin t>body             \ we need the system >body
  800: 			\ and the target >body
  801: 
  802: >TARGET
  803: : >body t>body ;
  804: 
  805: 
  806: \ Ghost Builder                                        06oct92py
  807: 
  808: >CROSS
  809: hex
  810: \ Values for ghost magic
  811: 4711 Constant <fwd>             4712 Constant <res>
  812: 4713 Constant <imm>             4714 Constant <do:>
  813: 4715 Constant <skip>
  814: 
  815: \ Bitmask for ghost flags
  816: 1 Constant <unique>
  817: 2 Constant <primitive>
  818: 
  819: \ FXIME: move this to general stuff?
  820: : set-flag ( addr flag -- )
  821:   over @ or swap ! ;
  822: 
  823: : reset-flag ( addr flag -- )
  824:   invert over @ and swap ! ;
  825: 
  826: : get-flag ( addr flag -- f )
  827:   swap @ and 0<> ;
  828:   
  829: 
  830: Struct
  831: 
  832:   \ link to next ghost (always the first element)
  833:   cell% field >next-ghost
  834: 
  835:   \ type of ghost
  836:   cell% field >magic
  837: 		
  838:   \ pointer where ghost is in target, or if unresolved
  839:   \ points to the where we have to resolve (linked-list)
  840:   cell% field >link
  841: 
  842:   \ execution semantics (while target compiling) of ghost
  843:   cell% field >exec
  844: 
  845:   \ compilation action of this ghost; this is what is
  846:   \ done to compile a call (or whatever) to this definition.
  847:   \ E.g. >comp contains the semantic of postpone s"
  848:   \ whereas >exec-compile contains the semantic of s"
  849:   cell% field >comp
  850: 
  851:   \ Compilation sematics (while parsing) of this ghost. E.g. 
  852:   \ "\" will skip the rest of line.
  853:   \ These semantics are defined by Cond: and
  854:   \ if a word is made immediate in instant, then the >exec2 field
  855:   \ gets copied to here
  856:   cell% field >exec-compile
  857: 
  858:   \ Additional execution semantics of this ghost. This is used
  859:   \ for code generated by instant and for the doer-xt of created
  860:   \ words
  861:   cell% field >exec2
  862: 
  863:   cell% field >created
  864: 
  865:   \ the xt of the created ghost word itself
  866:   cell% field >ghost-xt
  867: 
  868:   \ pointer to the counted string of the assiciated
  869:   \ assembler label
  870:   cell% field >asm-name
  871: 
  872:   \ mapped primitives have a special address, so
  873:   \ we are able to detect them
  874:   cell% field >asm-dummyaddr
  875: 			
  876:   \ for builder (create, variable...) words
  877:   \ the execution symantics of words built are placed here
  878:   \ this is a doer ghost or a dummy ghost
  879:   cell% field >do:ghost
  880: 
  881:   cell% field >ghost-flags
  882: 
  883:   cell% field >ghost-name
  884: 
  885: End-Struct ghost-struct
  886: 
  887: Variable ghost-list
  888: 0 ghost-list !
  889: 
  890: Variable executed-ghost \ last executed ghost, needed in tcreate and gdoes>
  891: \ Variable last-ghost	\ last ghost that is created
  892: Variable last-header-ghost \ last ghost definitions with header
  893: 
  894: \ space for ghosts resolve structure
  895: \ we create ghosts in a sepearte space
  896: \ and not to the current host dp, because this
  897: \ gives trouble with instant while compiling and creating
  898: \ a ghost for a forward reference
  899: \ BTW: we cannot allocate another memory region
  900: \ because allot will check the overflow!!
  901: Variable cross-space-dp
  902: Create cross-space 250000 allot here 100 allot align 
  903: Constant cross-space-end
  904: cross-space cross-space-dp !
  905: Variable cross-space-dp-orig
  906: 
  907: : cross-space-used cross-space-dp @ cross-space - ;
  908: 
  909: : >space ( -- )
  910:   dp @ cross-space-dp-orig !
  911:   cross-space-dp @ dp ! ;
  912: 
  913: : space> ( -- )
  914:   dp @ dup cross-space-dp !
  915:   cross-space-end u> ABORT" CROSS: cross-space overflow"
  916:   cross-space-dp-orig @ dp ! ;
  917: 
  918: \ this is just for debugging, to see this in the backtrace
  919: : execute-exec execute ;
  920: : execute-exec2 execute ;
  921: : execute-exec-compile execute ;
  922: 
  923: : NoExec
  924:   executed-ghost @ >exec2 @
  925:   ?dup 
  926:   IF   execute-exec2
  927:   ELSE true ABORT" CROSS: Don't execute ghost, or immediate target word"
  928:   THEN ;
  929: 
  930: Defer is-forward
  931: 
  932: : (ghostheader) ( -- )
  933:     ghost-list linked <fwd> , 0 , ['] NoExec , ['] is-forward ,
  934:     0 , 0 , 0 , 0 , 0 , 0 , 0 , 0 , ;
  935: 
  936: : ghostheader ( -- ) (ghostheader) 0 , ;
  937: 
  938: ' Ghosts >wordlist Constant ghosts-wordlist
  939: 
  940: \ the current wordlist for ghost definitions in the host
  941: ghosts-wordlist Value current-ghosts
  942: 
  943: : Make-Ghost ( "name" -- ghost )
  944:   >space
  945:   \ save current and create in ghost vocabulary
  946:   get-current >r current-ghosts set-current
  947:   >in @ Create >in !
  948:   \ some forth systems like iForth need the immediate directly
  949:   \ after the word is created
  950:   \ restore current
  951:   r> set-current
  952:   here (ghostheader)
  953:   bl word count string, align
  954:   space>
  955:   \ set ghost-xt field by doing a search
  956:   dup >ghost-name count 
  957:   current-ghosts search-wordlist
  958:   0= ABORT" CROSS: Just created, must be there!"
  959:   over >ghost-xt !
  960:   DOES> 
  961:       dup executed-ghost !
  962:       >exec @ execute-exec ;
  963: 
  964: \ ghost words                                          14oct92py
  965: \                                          changed:    10may93py/jaw
  966: 
  967: Defer search-ghosts
  968: 
  969: : (search-ghosts) ( adr len -- cfa true | 0 )
  970:   current-ghosts search-wordlist ; 
  971: 
  972:   ' (search-ghosts) IS search-ghosts
  973: 
  974: : gsearch ( addr len -- ghost true | 0 )
  975:   search-ghosts
  976:   dup IF swap >body swap THEN ;
  977: 
  978: : gfind   ( string -- ghost true / string false )
  979: \ searches for string in word-list ghosts
  980:   \ dup count type space
  981:   dup >r count gsearch
  982:   dup IF rdrop ELSE r> swap THEN ;
  983: 
  984: : gdiscover ( xt -- ghost true | xt false )
  985:   >r ghost-list
  986:   BEGIN @ dup
  987:   WHILE dup >magic @ <fwd> <>
  988:         IF dup >link @ r@ =
  989:            IF rdrop true EXIT THEN
  990:         THEN
  991:   REPEAT
  992:   drop r> false ;
  993: 
  994: : xt>ghost ( xt -- ghost )
  995:   gdiscover 0= ABORT" CROSS: ghost not found for this xt" ;
  996: 
  997: : Ghost   ( "name" -- ghost )
  998:   >in @ bl word gfind IF  nip EXIT  THEN
  999:   drop  >in !  Make-Ghost ;
 1000: 
 1001: : >ghostname ( ghost -- adr len )
 1002:   >ghost-name count ;
 1003: 
 1004: : forward? ( ghost -- flag )
 1005:   >magic @ <fwd> = ;
 1006: 
 1007: : undefined? ( ghost -- flag )
 1008:   >magic @ dup <fwd> = swap <skip> = or ;
 1009: 
 1010: : immediate? ( ghost -- flag )
 1011:   >magic @ <imm> = ;
 1012: 
 1013: Variable TWarnings
 1014: TWarnings on
 1015: Variable Exists-Warnings
 1016: Exists-Warnings on
 1017: 
 1018: : exists-warning ( ghost -- ghost )
 1019:   TWarnings @ Exists-Warnings @ and
 1020:   IF dup >ghostname warnhead type ."  exists " THEN ;
 1021: 
 1022: \ : HeaderGhost Ghost ;
 1023: 
 1024: Variable reuse-ghosts reuse-ghosts off
 1025: 
 1026: : HeaderGhost ( "name" -- ghost )
 1027:   >in @ 
 1028:   bl word count 
 1029: \  2dup type space
 1030:   current-ghosts search-wordlist
 1031:   IF  >body dup undefined? reuse-ghosts @ or
 1032:       IF   nip EXIT
 1033:       ELSE exists-warning 
 1034:       THEN
 1035:       drop >in ! 
 1036:   ELSE >in ! 
 1037:   THEN 
 1038:   \ we keep the execution semantics of the prviously
 1039:   \ defined words, this is a workaround
 1040:   \ for the redefined \ until vocs work
 1041:   Make-Ghost ;
 1042:  
 1043: : .ghost ( ghost -- ) >ghostname type ;
 1044: 
 1045: \ ' >ghostname ALIAS @name
 1046: 
 1047: : findghost ( "ghostname" -- ghost ) 
 1048:   bl word gfind 0= ABORT" CROSS: Ghost don't exists" ;
 1049: 
 1050: : [G'] ( -- ghost : name )
 1051: \G ticks a ghost and returns its address
 1052:   findghost
 1053:   state @ IF postpone literal THEN ; immediate
 1054: 
 1055: : g>xt ( ghost -- xt )
 1056: \G Returns the xt (cfa) of a ghost. Issues a warning if undefined.
 1057:   dup undefined? ABORT" CROSS: forward " >link @ ;
 1058:    
 1059: : g>body ( ghost -- body )
 1060: \G Returns the body-address (pfa) of a ghost. 
 1061: \G Issues a warning if undefined (a forward-reference).
 1062:   g>xt X >body ;
 1063: 
 1064: 1 Constant <label>
 1065: 
 1066: Struct
 1067:   \ bitmask of address type (not used for now)
 1068:   cell% field addr-type
 1069:   \ if this address is an xt, this field points to the ghost
 1070:   cell% field addr-xt-ghost
 1071:   \ a bit mask that tells as what part of the cell
 1072:   \ is refenced from an address pointer, used for assembler generation
 1073:   cell% field addr-refs
 1074: End-Struct addr-struct
 1075: 
 1076: : %allocerase ( align size -- addr )
 1077:   dup >r %alloc dup r> erase ;
 1078: 
 1079: \ returns the addr struct, define it if 0 reference
 1080: : define-addr-struct ( addr -- struct-addr )
 1081:   dup @ ?dup IF nip EXIT THEN
 1082:   addr-struct %allocerase tuck swap ! ;
 1083: 
 1084: >cross
 1085: 
 1086: \ Predefined ghosts                                    12dec92py
 1087: 
 1088: Ghost - drop \ need a ghost otherwise "-" would be treated as a number
 1089: 
 1090: Ghost 0=                                        drop
 1091: Ghost branch    Ghost ?branch                   2drop
 1092: Ghost unloop    Ghost ;S                        2drop
 1093: Ghost lit       Ghost !                         2drop
 1094: Ghost noop                                      drop
 1095: Ghost over      Ghost =         Ghost drop      2drop drop
 1096: Ghost 2drop drop
 1097: Ghost 2dup drop
 1098: Ghost call drop
 1099: Ghost @ drop
 1100: Ghost useraddr drop
 1101: Ghost execute drop
 1102: Ghost + drop
 1103: Ghost decimal drop
 1104: Ghost hex drop
 1105: Ghost lit@ drop
 1106: Ghost lit-perform drop
 1107: Ghost lit+ drop
 1108: Ghost does-exec drop
 1109: 
 1110: Ghost :docol    Ghost :doesjump Ghost :dodoes   2drop drop
 1111: Ghost :dovar					drop
 1112: 
 1113: \ \ Parameter for target systems                         06oct92py
 1114: 
 1115: 
 1116: \ we define it ans like...
 1117: wordlist Constant target-environment
 1118: 
 1119: \ save information of current dictionary to restore with environ>
 1120: Variable env-current 
 1121: 
 1122: : >ENVIRON get-current env-current ! target-environment set-current ;
 1123: : ENVIRON> env-current @ set-current ; 
 1124: 
 1125: >TARGET
 1126: 
 1127: : environment? ( addr len -- [ x ] true | false )
 1128: \G returns the content of environment variable and true or
 1129: \G false if not present
 1130:    target-environment search-wordlist 
 1131:    IF EXECUTE true ELSE false THEN ;
 1132: 
 1133: : $has? ( addr len -- x | false )
 1134: \G returns the content of environment variable 
 1135: \G or false if not present
 1136:    T environment? H dup IF drop THEN ;
 1137: 
 1138: : e? ( "name" -- x )
 1139: \G returns the content of environment variable. 
 1140: \G The variable is expected to exist. If not, issue an error.
 1141:    bl word count T environment? H 
 1142:    0= ABORT" environment variable not defined!" ;
 1143: 
 1144: : has? ( "name" --- x | false )
 1145: \G returns the content of environment variable 
 1146: \G or false if not present
 1147:    bl word count T $has? H ;
 1148: 
 1149: 
 1150: >ENVIRON get-order get-current swap 1+ set-order
 1151: true SetValue compiler
 1152: true SetValue cross
 1153: true SetValue standard-threading
 1154: >TARGET previous
 1155: 
 1156: 0
 1157: [IFDEF] mach-file drop mach-file count 1 [THEN]
 1158: [IFDEF] machine-file drop machine-file 1 [THEN]
 1159: [IF] 	included hex
 1160: [ELSE]  cr ." No machine description!" ABORT 
 1161: [THEN]
 1162: 
 1163: >ENVIRON
 1164: 
 1165: T has? ec H
 1166: [IF]
 1167: false DefaultValue relocate
 1168: false DefaultValue file
 1169: false DefaultValue OS
 1170: false DefaultValue prims
 1171: false DefaultValue floating
 1172: false DefaultValue glocals
 1173: false DefaultValue dcomps
 1174: false DefaultValue hash
 1175: false DefaultValue xconds
 1176: false DefaultValue header
 1177: false DefaultValue backtrace
 1178: false DefaultValue new-input
 1179: false DefaultValue peephole
 1180: false DefaultValue primcentric
 1181: false DefaultValue abranch
 1182: true DefaultValue f83headerstring
 1183: true DefaultValue control-rack
 1184: [THEN]
 1185: 
 1186: true DefaultValue gforthcross
 1187: true DefaultValue interpreter
 1188: true DefaultValue ITC
 1189: false DefaultValue rom
 1190: false DefaultValue flash
 1191: true DefaultValue standardthreading
 1192: 
 1193: \ ANSForth environment  stuff
 1194: 8 DefaultValue ADDRESS-UNIT-BITS
 1195: 255 DefaultValue MAX-CHAR
 1196: 255 DefaultValue /COUNTED-STRING
 1197: 
 1198: >TARGET
 1199: s" relocate" T environment? H 
 1200: \ JAW why set NIL to this?!
 1201: [IF]	drop \ SetValue NIL
 1202: [ELSE]	>ENVIRON X NIL SetValue relocate
 1203: [THEN]
 1204: >TARGET
 1205: 
 1206: 0 Constant NIL
 1207: 
 1208: >CROSS
 1209: 
 1210: \ \ Create additional parameters                         19jan95py
 1211: 
 1212: \ currently cross only works for host machines with address-unit-bits
 1213: \ eual to 8 because of s! and sc!
 1214: \ but I start to query the environment just to modularize a little bit
 1215: 
 1216: : check-address-unit-bits ( -- )	
 1217: \	s" ADDRESS-UNIT-BITS" environment?
 1218: \	IF 8 <> ELSE true THEN
 1219: \	ABORT" ADDRESS-UNIT-BITS unknown or not equal to 8!"
 1220: 
 1221: \	shit, this doesn't work because environment? is only defined for 
 1222: \	gforth.fi and not kernl???.fi
 1223: 	;
 1224: 
 1225: check-address-unit-bits
 1226: 8 Constant bits/byte	\ we define: byte is address-unit
 1227: 
 1228: 1 bits/byte lshift Constant maxbyte 
 1229: \ this sets byte size for the target machine, (probably right guess) jaw
 1230: 
 1231: T
 1232: NIL		   	Constant TNIL
 1233: cell               	Constant tcell
 1234: cell<<             	Constant tcell<<
 1235: cell>bit           	Constant tcell>bit
 1236: bits/char          	Constant tbits/char
 1237: bits/char H bits/byte T /      
 1238: 			Constant tchar
 1239: float             	Constant tfloat
 1240: 1 bits/char lshift 	Constant tmaxchar
 1241: [IFUNDEF] bits/byte
 1242: 8			Constant tbits/byte
 1243: [ELSE]
 1244: bits/byte		Constant tbits/byte
 1245: [THEN]
 1246: H
 1247: tbits/char bits/byte /	Constant tbyte
 1248: 
 1249: : >signed ( u -- n )
 1250:     1 tbits/char tcell * 1- lshift 2dup and
 1251:     IF  negate or  ELSE  drop  THEN ;
 1252: 
 1253: \ Variables                                            06oct92py
 1254: 
 1255: Variable (tlast)    
 1256: (tlast) Value tlast TNIL tlast !  \ Last name field
 1257: Variable tlastcfa \ Last code field
 1258: 
 1259: \ statistics						10jun97jaw
 1260: 
 1261: Variable headers-named 0 headers-named !
 1262: Variable user-vars 0 user-vars !
 1263: 
 1264: : target>bitmask-size ( u1 -- u2 )
 1265:   1- tcell>bit rshift 1+ ;
 1266: 
 1267: : allocatetarget ( size -- adr )
 1268:   dup allocate ABORT" CROSS: No memory for target"
 1269:   swap over swap erase ;
 1270: 
 1271: \ \ memregion.fs
 1272: 
 1273: 
 1274: Variable last-defined-region    \ pointer to last defined region
 1275: Variable region-link            \ linked list with all regions
 1276: Variable mirrored-link          \ linked list for mirrored regions
 1277: 0 dup mirrored-link ! region-link !
 1278: 
 1279: : >rname 9 cells + ;
 1280: : >rtouch 8 cells + ; \ executed when region is accessed
 1281: : >rbm   4 cells + ; \ bitfield per cell witch indicates relocation
 1282: : >rmem  5 cells + ;
 1283: : >rtype 6 cells + ; \ field per cell witch points to a type struct
 1284: : >rrom 7 cells + ;  \ a -1 indicates that this region is rom
 1285: : >rlink 3 cells + ;
 1286: : >rdp 2 cells + ;
 1287: : >rlen cell+ ;
 1288: : >rstart ;
 1289: 
 1290: : (region) ( addr len region -- )
 1291: \G change startaddress and length of an existing region
 1292:   >r r@ last-defined-region !
 1293:   r@ >rlen ! dup r@ >rstart ! r> >rdp ! ;
 1294: 
 1295: : uninitialized -1 ABORT" CROSS: Region is uninitialized" ;
 1296: 
 1297: : region ( addr len -- "name" )                
 1298: \G create a new region
 1299:   \ check whether predefined region exists 
 1300:   save-input bl word find >r >r restore-input throw r> r> 0= 
 1301:   IF	\ make region
 1302: 	drop
 1303: 	save-input create restore-input throw
 1304: 	here last-defined-region !
 1305: 	over ( startaddr ) , ( length ) , ( dp ) ,
 1306: 	region-link linked 0 , 0 , 0 , 0 , 
 1307:         ['] uninitialized ,
 1308:         bl word count string,
 1309:   ELSE	\ store new parameters in region
 1310:         bl word drop
 1311: 	>body (region)
 1312:   THEN ;
 1313: 
 1314: : borders ( region -- startaddr endaddr ) 
 1315: \G returns lower and upper region border
 1316:   dup >rstart @ swap >rlen @ over + ;
 1317: 
 1318: : extent  ( region -- startaddr len )   
 1319: \G returns the really used area
 1320:   dup >rstart @ swap >rdp @ over - ;
 1321: 
 1322: : area ( region -- startaddr totallen ) 
 1323: \G returns the total area
 1324:   dup >rstart @ swap >rlen @ ;
 1325: 
 1326: : dp@ ( region -- dp )
 1327:   >rdp @ ;
 1328: 
 1329: : mirrored ( -- )                              
 1330: \G mark last defined region as mirrored
 1331:   mirrored-link
 1332:   align linked last-defined-region @ , ;
 1333: 
 1334: : writeprotected
 1335: \G mark a region as write protected
 1336:   -1 last-defined-region @ >rrom ! ;
 1337: 
 1338: : .addr ( u -- )
 1339: \G prints a 16 or 32 Bit nice hex value
 1340:   base @ >r hex
 1341:   tcell 2 u>
 1342:   IF s>d <# # # # # [char] . hold # # # # #> type
 1343:   ELSE s>d <# # # # # # #> type
 1344:   THEN r> base ! space ;
 1345: 
 1346: : .regions                      \G display region statistic
 1347: 
 1348:   \ we want to list the regions in the right order
 1349:   \ so first collect all regions on stack
 1350:   0 region-link @
 1351:   BEGIN dup WHILE dup @ REPEAT drop
 1352:   BEGIN dup
 1353:   WHILE cr
 1354:         0 >rlink - >r
 1355:         r@ >rname count tuck type
 1356:         12 swap - 0 max spaces space
 1357:         ." Start: " r@ >rstart @ dup .addr space
 1358:         ." End: " r@ >rlen @ + .addr space
 1359:         ." DP: " r> >rdp @ .addr
 1360:   REPEAT drop
 1361:   s" rom" T $has? H 0= ?EXIT
 1362:   cr ." Mirrored:"
 1363:   mirrored-link @
 1364:   BEGIN dup
 1365:   WHILE space dup cell+ @ >rname count type @
 1366:   REPEAT drop cr
 1367:   ;
 1368: 
 1369: \ -------- predefined regions
 1370: 
 1371: 0 0 region address-space
 1372: \ total memory addressed and used by the target system
 1373: 
 1374: 0 0 region user-region
 1375: \ data for user variables goes here
 1376: \ this has to be defined before dictionary or ram-dictionary
 1377: 
 1378: 0 0 region dictionary
 1379: \ rom area for the compiler
 1380: 
 1381: T has? rom H
 1382: [IF]
 1383: 0 0 region ram-dictionary mirrored
 1384: \ ram area for the compiler
 1385: [ELSE]
 1386: ' dictionary ALIAS ram-dictionary
 1387: [THEN]
 1388: 
 1389: 0 0 region return-stack
 1390: 
 1391: 0 0 region data-stack
 1392: 
 1393: 0 0 region tib-region
 1394: 
 1395: ' dictionary ALIAS rom-dictionary
 1396: 
 1397: : setup-region ( region -- )
 1398:   >r
 1399:   \ allocate mem
 1400:   r@ >rlen @ allocatetarget
 1401:   r@ >rmem !
 1402: 
 1403:   r@ >rlen @
 1404:   target>bitmask-size allocatetarget
 1405:   r@ >rbm !
 1406: 
 1407:   r@ >rlen @
 1408:   tcell / 1+ cells allocatetarget r@ >rtype !
 1409: 
 1410:   ['] noop r@ >rtouch !
 1411:   rdrop ;
 1412: 
 1413: : setup-target ( -- )   \G initialize target's memory space
 1414:   s" rom" T $has? H
 1415:   IF  \ check for ram and rom...
 1416:       \ address-space area nip 0<>
 1417:       ram-dictionary area nip 0<>
 1418:       rom-dictionary area nip 0<>
 1419:       and 0=
 1420:       ABORT" CROSS: define address-space, rom- , ram-dictionary, with rom-support!"
 1421:   THEN
 1422:   address-space area nip
 1423:   IF
 1424:       address-space area
 1425:   ELSE
 1426:       dictionary area
 1427:   THEN
 1428:   nip 0=
 1429:   ABORT" CROSS: define at least address-space or dictionary!!"
 1430: 
 1431:   \ allocate target for each region
 1432:   region-link
 1433:   BEGIN @ dup
 1434:   WHILE dup
 1435:         0 >rlink - >r
 1436:         r@ >rlen @
 1437:         IF      r@ setup-region
 1438:         THEN    rdrop
 1439:    REPEAT drop ;
 1440: 
 1441: \ MakeKernel                                           		22feb99jaw
 1442: 
 1443: : makekernel ( start targetsize -- )
 1444: \G convenience word to setup the memory of the target
 1445: \G used by main.fs of the c-engine based systems
 1446:   dictionary (region) setup-target ;
 1447: 
 1448: >MINIMAL
 1449: : makekernel makekernel ;
 1450: >CROSS
 1451: 
 1452: \ \ switched tdp for rom support				03jun97jaw
 1453: 
 1454: \ second value is here to store some maximal value for statistics
 1455: \ tempdp is also embedded here but has nothing to do with rom support
 1456: \ (needs switched dp)
 1457: 
 1458: variable tempdp	0 ,	\ temporary dp for resolving
 1459: variable tempdp-save
 1460: 
 1461: 0 [IF]
 1462: variable romdp 0 ,      \ Dictionary-Pointer for ramarea
 1463: variable ramdp 0 ,      \ Dictionary-Pointer for romarea
 1464: 
 1465: \
 1466: variable sramdp		\ start of ram-area for forth
 1467: variable sromdp		\ start of rom-area for forth
 1468: 
 1469: [THEN]
 1470: 
 1471: 0 Value current-region
 1472: 0 Value tdp
 1473: Variable fixed		\ flag: true: no automatic switching
 1474: 			\	false: switching is done automatically
 1475: 
 1476: \ Switch-Policy:
 1477: \
 1478: \ a header is always compiled into rom
 1479: \ after a created word (create and variable) compilation goes to ram
 1480: \
 1481: \ Be careful: If you want to make the data behind create into rom
 1482: \ you have to put >rom before create!
 1483: 
 1484: variable constflag constflag off
 1485: 
 1486: : activate ( region -- )
 1487: \G next code goes to this region
 1488:   dup to current-region >rdp to tdp ;
 1489: 
 1490: : (switchram)
 1491:   fixed @ ?EXIT s" rom" T $has? H 0= ?EXIT
 1492:   ram-dictionary activate ;
 1493: 
 1494: : switchram
 1495:   constflag @
 1496:   IF constflag off ELSE (switchram) THEN ;
 1497: 
 1498: : switchrom
 1499:   fixed @ ?EXIT rom-dictionary activate ;
 1500: 
 1501: : >tempdp ( addr -- ) 
 1502:   tdp tempdp-save ! tempdp to tdp tdp ! ;
 1503: : tempdp> ( -- )
 1504:   tempdp-save @ to tdp ;
 1505: 
 1506: : >ram  fixed off (switchram) fixed on ;
 1507: : >rom  fixed off switchrom fixed on ;
 1508: : >auto fixed off switchrom ;
 1509: 
 1510: 
 1511: 
 1512: \ : romstart dup sromdp ! romdp ! ;
 1513: \ : ramstart dup sramdp ! ramdp ! ;
 1514: 
 1515: \ default compilation goes to rom
 1516: \ when romable support is off, only the rom switch is used (!!)
 1517: >auto
 1518: 
 1519: : there  tdp @ ;
 1520: 
 1521: >TARGET
 1522: 
 1523: \ \ Target Memory Handling
 1524: 
 1525: \ Byte ordering and cell size                          06oct92py
 1526: 
 1527: : cell+         tcell + ;
 1528: : cells         tcell<< lshift ;
 1529: : chars         tchar * ;
 1530: : char+		tchar + ;
 1531: : floats	tfloat * ;
 1532:     
 1533: >CROSS
 1534: : cell/         tcell<< rshift ;
 1535: >TARGET
 1536: 20 CONSTANT bl
 1537: \ TNIL Constant NIL
 1538: 
 1539: >CROSS
 1540: 
 1541: bigendian
 1542: [IF]
 1543:    : DS!  ( d addr -- )  tcell bounds swap 1-
 1544:      DO  maxbyte ud/mod rot I c!  -1 +LOOP  2drop ;
 1545:    : DS@  ( addr -- d )  >r 0 0 r> tcell bounds
 1546:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  LOOP ;
 1547:    : Sc!  ( n addr -- )  >r s>d r> tchar bounds swap 1-
 1548:      DO  maxbyte ud/mod rot I c!  -1 +LOOP  2drop ;
 1549:    : Sc@  ( addr -- n )  >r 0 0 r> tchar bounds
 1550:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  LOOP d>s ;
 1551: [ELSE]
 1552:    : DS!  ( d addr -- )  tcell bounds
 1553:      DO  maxbyte ud/mod rot I c!  LOOP  2drop ;
 1554:    : DS@  ( addr -- n )  >r 0 0 r> tcell bounds swap 1-
 1555:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  -1 +LOOP ;
 1556:    : Sc!  ( n addr -- )  >r s>d r> tchar bounds
 1557:      DO  maxbyte ud/mod rot I c!  LOOP  2drop ;
 1558:    : Sc@  ( addr -- n )  >r 0 0 r> tchar bounds swap 1-
 1559:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  -1 +LOOP d>s ;
 1560: [THEN]
 1561: 
 1562: : S! ( n addr -- ) >r s>d r> DS! ;
 1563: : S@ ( addr -- n ) DS@ d>s ;
 1564: 
 1565: : taddr>region ( taddr -- region | 0 )
 1566: \G finds for a target-address the correct region
 1567: \G returns 0 if taddr is not in range of a target memory region
 1568:   region-link
 1569:   BEGIN @ dup
 1570:   WHILE dup >r
 1571:         0 >rlink - >r
 1572:         r@ >rlen @
 1573:         IF      dup r@ borders within
 1574:                 IF r> r> drop nip 
 1575:                    dup >rtouch @ EXECUTE EXIT 
 1576:                 THEN
 1577:         THEN
 1578:         r> drop
 1579:         r>
 1580:   REPEAT
 1581:   2drop 0 ;
 1582: 
 1583: : taddr>region-abort ( taddr -- region | 0 )
 1584: \G Same as taddr>region but aborts if taddr is not
 1585: \G a valid address in the target address space
 1586:   dup taddr>region dup 0= 
 1587:   IF    drop cr ." Wrong address: " .addr
 1588:         -1 ABORT" Address out of range!"
 1589:   THEN nip ;
 1590: 
 1591: : (>regionimage) ( taddr -- 'taddr )
 1592:   dup
 1593:   \ find region we want to address
 1594:   taddr>region-abort
 1595:   >r
 1596:   \ calculate offset in region
 1597:   r@ >rstart @ -
 1598:   \ add regions real address in our memory
 1599:   r> >rmem @ + ;
 1600: 
 1601: : (>regionramimage) ( taddr -- 'taddr )
 1602: \G same as (>regionimage) but aborts if the region is rom
 1603:   dup
 1604:   \ find region we want to address
 1605:   taddr>region-abort
 1606:   >r
 1607:   r@ >rrom @ ABORT" CROSS: region is write-protected!"
 1608:   \ calculate offset in region
 1609:   r@ >rstart @ -
 1610:   \ add regions real address in our memory
 1611:   r> >rmem @ + ;
 1612: 
 1613: : (>regionbm) ( taddr -- 'taddr bitmaskbaseaddr )
 1614:   dup
 1615:   \ find region we want to address
 1616:   taddr>region-abort
 1617:   >r
 1618:   \ calculate offset in region
 1619:   r@ >rstart @ -
 1620:   \ add regions real address in our memory
 1621:   r> >rbm @ ;
 1622: 
 1623: : (>regiontype) ( taddr -- 'taddr )
 1624:   dup
 1625:   \ find region we want to address
 1626:   taddr>region-abort
 1627:   >r
 1628:   \ calculate offset in region
 1629:   r@ >rstart @ - tcell / cells
 1630:   \ add regions real address in our memory
 1631:   r> >rtype @ + ;
 1632:   
 1633: \ Bit string manipulation                               06oct92py
 1634: \                                                       9may93jaw
 1635: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
 1636: : bits ( n -- n ) chars Bittable + c@ ;
 1637: 
 1638: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
 1639: : +bit ( addr n -- )  >bit over c@ or swap c! ;
 1640: : -bit ( addr n -- )  >bit invert over c@ and swap c! ;
 1641: 
 1642: : @relbit ( taddr -- f ) (>regionbm) swap cell/ >bit swap c@ and ;
 1643: 
 1644: : (relon) ( taddr -- )  
 1645:   [ [IFDEF] fd-relocation-table ]
 1646:   s" +" fd-relocation-table write-file throw
 1647:   dup s>d <# #s #> fd-relocation-table write-line throw
 1648:   [ [THEN] ]
 1649:   (>regionbm) swap cell/ +bit ;
 1650: 
 1651: : (reloff) ( taddr -- ) 
 1652:   [ [IFDEF] fd-relocation-table ]
 1653:   s" -" fd-relocation-table write-file throw
 1654:   dup s>d <# #s #> fd-relocation-table write-line throw
 1655:   [ [THEN] ]
 1656:   (>regionbm) swap cell/ -bit ;
 1657: 
 1658: DEFER >image
 1659: DEFER >ramimage
 1660: DEFER relon
 1661: DEFER reloff
 1662: DEFER correcter
 1663: 
 1664: T has? relocate H
 1665: [IF]
 1666: ' (relon) IS relon
 1667: ' (reloff) IS reloff
 1668: ' (>regionimage) IS >image
 1669: ' (>regionimage) IS >ramimage
 1670: [ELSE]
 1671: ' drop IS relon
 1672: ' drop IS reloff
 1673: ' (>regionimage) IS >image
 1674: ' (>regionimage) IS >ramimage
 1675: [THEN]
 1676: 
 1677: : enforce-writeprotection ( -- )
 1678:   ['] (>regionramimage) IS >ramimage ;
 1679: 
 1680: : relax-writeprotection ( -- )
 1681:   ['] (>regionimage) IS >ramimage ;
 1682: 
 1683: : writeprotection-relaxed? ( -- )
 1684:   ['] >ramimage >body @ ['] (>regionimage) = ;
 1685: 
 1686: \ Target memory access                                 06oct92py
 1687: 
 1688: : align+  ( taddr -- rest )
 1689:     tcell tuck 1- and - [ tcell 1- ] Literal and ;
 1690: : cfalign+  ( taddr -- rest )
 1691:     \ see kernel.fs:cfaligned
 1692:     /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
 1693: 
 1694: >TARGET
 1695: : aligned ( taddr -- ta-addr )  dup align+ + ;
 1696: \ assumes cell alignment granularity (as GNU C)
 1697: 
 1698: : cfaligned ( taddr1 -- taddr2 )
 1699:     \ see kernel.fs
 1700:     dup cfalign+ + ;
 1701: 
 1702: : @  ( taddr -- w )     >image S@ ;
 1703: : !  ( w taddr -- )     >ramimage S! ;
 1704: : c@ ( taddr -- char )  >image Sc@ ;
 1705: : c! ( char taddr -- )  >ramimage Sc! ;
 1706: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
 1707: : 2! ( x1 x2 taddr -- ) T tuck ! cell+ ! H ;
 1708: 
 1709: \ Target compilation primitives                        06oct92py
 1710: \ included A!                                          16may93jaw
 1711: 
 1712: : here  ( -- there )    there ;
 1713: : allot ( n -- )        tdp +! ;
 1714: : ,     ( w -- )        T here H tcell T allot  ! H ;
 1715: : c,    ( char -- )     T here H tchar T allot c! H ;
 1716: : align ( -- )          T here H align+ 0 ?DO  bl T c, H tchar +LOOP ;
 1717: : cfalign ( -- )
 1718:     T here H cfalign+ 0 ?DO  bl T c, H tchar +LOOP ;
 1719: 
 1720: : >address		dup 0>= IF tbyte / THEN ; \ ?? jaw 
 1721: : A!                    swap >address swap dup relon T ! H ;
 1722: : A,    ( w -- )        >address T here H relon T , H ;
 1723: 
 1724: \ high-level ghosts
 1725: 
 1726: >CROSS
 1727: 
 1728: Ghost (do)      Ghost (?do)                     2drop
 1729: Ghost (for)                                     drop
 1730: Ghost (loop)    Ghost (+loop)   Ghost (-loop)   2drop drop
 1731: Ghost (next)                                    drop
 1732: Ghost !does                                     drop
 1733: Ghost compile,                                  drop
 1734: Ghost (.")      Ghost (S")      Ghost (ABORT")  2drop drop
 1735: Ghost (C")      Ghost c(abort") Ghost type      2drop drop
 1736: Ghost '                                         drop
 1737: 
 1738: \ user ghosts
 1739: 
 1740: Ghost state drop
 1741: 
 1742: \ \ --------------------        Host/Target copy etc.     	29aug01jaw
 1743: 
 1744: 
 1745: >CROSS
 1746: 
 1747: : TD! >image DS! ;
 1748: : TD@ >image DS@ ;
 1749: 
 1750: : th-count ( taddr -- host-addr len )
 1751: \G returns host address of target string
 1752:   assert1( tbyte 1 = )
 1753:   dup X c@ swap X char+ >image swap ;
 1754: 
 1755: : ht-move ( haddr taddr len -- )
 1756: \G moves data from host-addr to destination in target-addr
 1757: \G character by character
 1758:   swap -rot bounds ?DO I c@ over X c! X char+ LOOP drop ;
 1759: 
 1760: 2Variable last-string
 1761: X has? rom [IF] $60 [ELSE] $00 [THEN] Constant header-masks
 1762: 
 1763: : ht-header,  ( addr count -- )
 1764:   dup there swap last-string 2!
 1765:     dup header-masks or T c, H bounds  ?DO  I c@ T c, H  LOOP ;
 1766: : ht-string,  ( addr count -- )
 1767:   dup there swap last-string 2!
 1768:     dup T c, H bounds  ?DO  I c@ T c, H  LOOP ;
 1769: : ht-mem, ( addr count )
 1770:     bounds ?DO  I c@  T c, H  LOOP ;
 1771: 
 1772: >TARGET
 1773: 
 1774: : count dup X c@ swap X char+ swap ;
 1775: 
 1776: : on		>r -1 -1 r> TD!  ; 
 1777: : off   	T 0 swap ! H ;
 1778: 
 1779: : tcmove ( source dest len -- )
 1780: \G cmove in target memory
 1781:   tchar * bounds
 1782:   ?DO  dup T c@ H I T c! H 1+
 1783:   tchar +LOOP  drop ;
 1784: 
 1785: : tcallot ( char size -- )
 1786:     0 ?DO  dup T c, H  tchar +LOOP  drop ;
 1787: 
 1788: : td, ( d -- )
 1789: \G Store a host value as one cell into the target
 1790:   there tcell X allot TD! ;
 1791: 
 1792: \ \ Load Assembler
 1793: 
 1794: >TARGET
 1795: H also Forth definitions
 1796: 
 1797: \ FIXME: should we include the assembler really in the forth 
 1798: \ dictionary?!?!?!? This conflicts with the existing assembler 
 1799: \ of the host forth system!!
 1800: [IFDEF] asm-include asm-include [THEN] hex
 1801: 
 1802: previous
 1803: 
 1804: 
 1805: >CROSS
 1806: 
 1807: : (cc) T a, H ;					' (cc) plugin-of colon,
 1808: : (prim) T a, H ;				' (prim) plugin-of prim,
 1809: 
 1810: : (cr) >tempdp colon, tempdp> ;                 ' (cr) plugin-of colon-resolve
 1811: : (ar) T ! H ;					' (ar) plugin-of addr-resolve
 1812: : (dr)  ( ghost res-pnt target-addr addr )
 1813: 	>tempdp drop over 
 1814: 	dup >magic @ <do:> =
 1815: 	IF 	doer,
 1816: 	ELSE	dodoes,
 1817: 	THEN 
 1818: 	tempdp> ;				' (dr) plugin-of doer-resolve
 1819: 
 1820: : (cm) ( -- addr )
 1821:     there -1 colon, ;				' (cm) plugin-of colonmark,
 1822: 
 1823: >TARGET
 1824: : compile, ( xt -- )
 1825:   dup xt>ghost >comp @ EXECUTE ;
 1826: >CROSS
 1827: 
 1828: \ resolve structure
 1829: 
 1830: : >next ;		\ link to next field
 1831: : >tag cell+ ;		\ indecates type of reference: 0: call, 1: address, 2: doer
 1832: : >taddr cell+ cell+ ;	
 1833: : >ghost 3 cells + ;
 1834: : >file 4 cells + ;
 1835: : >line 5 cells + ;
 1836: 
 1837: : (refered) ( ghost addr tag -- )
 1838: \G creates a reference to ghost at address taddr
 1839:     >space
 1840:     rot >link linked
 1841:     ( taddr tag ) ,
 1842:     ( taddr ) , 
 1843:     last-header-ghost @ , 
 1844:     loadfile , 
 1845:     sourceline# , 
 1846:     space>
 1847: ;
 1848: 
 1849: : refered ( ghost tag -- )
 1850: \G creates a resolve structure
 1851:     T here aligned H swap (refered)
 1852:   ;
 1853: 
 1854: : killref ( addr ghost -- )
 1855: \G kills a forward reference to ghost at position addr
 1856: \G this is used to eleminate a :dovar refence after making a DOES>
 1857:     dup >magic @ <fwd> <> IF 2drop EXIT THEN
 1858:     swap >r >link
 1859:     BEGIN dup @ dup  ( addr last this )
 1860:     WHILE dup >taddr @ r@ =
 1861:  	 IF   @ over !
 1862: 	 ELSE nip THEN
 1863:     REPEAT rdrop 2drop 
 1864:   ;
 1865: 
 1866: Defer resolve-warning
 1867: 
 1868: : reswarn-test ( ghost res-struct -- ghost res-struct )
 1869:   over cr ." Resolving " .ghost dup ."  in " >ghost @ .ghost ;
 1870: 
 1871: : reswarn-forward ( ghost res-struct -- ghost res-struct )
 1872:   over warnhead .ghost dup ."  is referenced in " 
 1873:   >ghost @ .ghost ;
 1874: 
 1875: \ ' reswarn-test IS resolve-warning
 1876:  
 1877: \ resolve                                              14oct92py
 1878: 
 1879:  : resolve-loop ( ghost resolve-list tcfa -- )
 1880:     >r
 1881:     BEGIN dup WHILE 
 1882: \  	  dup >tag @ 2 = IF reswarn-forward THEN
 1883: 	  resolve-warning 
 1884: 	  r@ over >taddr @ 
 1885: 	  2 pick >tag @
 1886: 	  CASE	0 OF colon-resolve ENDOF
 1887: 		1 OF addr-resolve ENDOF
 1888: 		2 OF doer-resolve ENDOF
 1889: 	  ENDCASE
 1890: 	  @ \ next list element
 1891:     REPEAT 2drop rdrop 
 1892:   ;
 1893: 
 1894: \ : resolve-loop ( ghost tcfa -- ghost tcfa )
 1895: \  >r dup >link @
 1896: \  BEGIN  dup  WHILE  dup T @ H r@ rot T ! H REPEAT  drop r> ;
 1897: 
 1898: \ exists                                                9may93jaw
 1899: 
 1900: : exists ( ghost tcfa -- )
 1901: \G print warning and set new target link in ghost
 1902:   swap exists-warning
 1903:   >link ! ;
 1904: 
 1905: : colon-resolved   ( ghost -- )
 1906: \ compiles a call to a colon definition,
 1907: \ compile action for >comp field
 1908:     >link @ colon, ; 
 1909: 
 1910: : prim-resolved  ( ghost -- )
 1911: \ compiles a call to a primitive
 1912:     >link @ prim, ;
 1913: 
 1914: : (is-forward)   ( ghost -- )
 1915:     colonmark, 0 (refered) ; \ compile space for call
 1916: ' (is-forward) IS is-forward
 1917: 
 1918: 0 Value resolved
 1919: 
 1920: : resolve-forward-references ( ghost resolve-list -- )
 1921:     \ loop through forward referencies
 1922:     comp-state @ >r Resolving comp-state !
 1923:     over >link @ resolve-loop 
 1924:     r> comp-state !
 1925: 
 1926:     ['] noop IS resolve-warning ;
 1927: 
 1928: 
 1929: : (resolve) ( ghost tcfa -- ghost resolve-list )
 1930:     \ check for a valid address, it is a primitive reference
 1931:     \ otherwise
 1932:     dup taddr>region 0<> IF
 1933:       \ define this address in the region address type table
 1934:       2dup (>regiontype) define-addr-struct addr-xt-ghost 
 1935:       \ we define new address only if empty
 1936:       \ this is for not to take over the alias ghost
 1937:       \ (different ghost, but identical xt)
 1938:       \ but the very first that really defines it
 1939:       dup @ 0= IF ! ELSE 2drop THEN
 1940:     THEN
 1941:     swap >r
 1942:     r@ to resolved
 1943: 
 1944: \    r@ >comp @ ['] is-forward =
 1945: \    ABORT" >comp action not set on a resolved ghost"
 1946: 
 1947:     \ copmile action defaults to colon-resolved
 1948:     \ if this is not right something must be set before
 1949:     \ calling resolve
 1950:     r@ >comp @ ['] is-forward = IF
 1951:        ['] colon-resolved r@ >comp !
 1952:    THEN
 1953:     r@ >link @ swap \ ( list tcfa R: ghost )
 1954:     \ mark ghost as resolved
 1955:     r@ >link ! <res> r@ >magic !
 1956:     r> swap ;
 1957: 
 1958: : resolve  ( ghost tcfa -- )
 1959: \G resolve referencies to ghost with tcfa
 1960:     \ is ghost resolved?, second resolve means another 
 1961:     \ definition with the same name
 1962:     over undefined? 0= IF  exists EXIT THEN
 1963:     (resolve)
 1964:     ( ghost resolve-list )
 1965:     resolve-forward-references ;
 1966: 
 1967: : resolve-noforwards ( ghost tcfa -- )
 1968: \G Same as resolve but complain if there are any
 1969: \G forward references on this ghost
 1970:    \ is ghost resolved?, second resolve means another 
 1971:    \ definition with the same name
 1972:    over undefined? 0= IF  exists EXIT THEN
 1973:    (resolve)
 1974:    IF cr ." No forward references allowed on: " .ghost cr
 1975:       -1 ABORT" Illegal forward reference"
 1976:    THEN
 1977:    drop ;
 1978: 
 1979: \ gexecute ghost,                                      01nov92py
 1980: 
 1981: : (gexecute)   ( ghost -- )
 1982:   dup >comp @ EXECUTE ;
 1983: 
 1984: : gexecute ( ghost -- )
 1985:   dup >magic @ <imm> = ABORT" CROSS: gexecute on immediate word"
 1986:   (gexecute) ;
 1987: 
 1988: : addr,  ( ghost -- )
 1989:   dup forward? IF  1 refered 0 T a, H ELSE >link @ T a, H THEN ;
 1990: 
 1991: \ .unresolved                                          11may93jaw
 1992: 
 1993: variable ResolveFlag
 1994: 
 1995: \ ?touched                                             11may93jaw
 1996: 
 1997: : ?touched ( ghost -- flag ) dup forward? swap >link @
 1998:                                0 <> and ;
 1999: 
 2000: : .forwarddefs ( ghost -- )
 2001:   ."  appeared in:"
 2002:   >link
 2003:   BEGIN	@ dup
 2004:   WHILE	cr 5 spaces
 2005: 	dup >ghost @ .ghost
 2006: 	."  file " dup >file @ ?dup IF count type ELSE ." CON" THEN
 2007: 	."  line " dup >line @ .dec
 2008:   REPEAT 
 2009:   drop ;
 2010: 
 2011: : ?resolved  ( ghost -- )
 2012:   dup ?touched
 2013:   IF  	ResolveFlag on 
 2014: 	dup cr .ghost .forwarddefs
 2015:   ELSE 	drop 
 2016:   THEN ;
 2017: 
 2018: : .unresolved  ( -- )
 2019:   ResolveFlag off cr ." Unresolved: "
 2020:   ghost-list
 2021:   BEGIN @ dup
 2022:   WHILE dup ?resolved
 2023:   REPEAT drop ResolveFlag @
 2024:   IF
 2025:       -1 abort" Unresolved words!"
 2026:   ELSE
 2027:       ." Nothing!"
 2028:   THEN
 2029:   cr ;
 2030: 
 2031: : .stats
 2032:   base @ >r decimal
 2033:   cr ." named Headers: " headers-named @ . 
 2034:   r> base ! ;
 2035: 
 2036: >MINIMAL
 2037: 
 2038: : .unresolved .unresolved ;
 2039: 
 2040: >CROSS
 2041: \ Header states                                        12dec92py
 2042: 
 2043: \ : flag! ( 8b -- )   tlast @ dup >r T c@ xor r> c! H ;
 2044: X has? f83headerstring bigendian or [IF] 0 [ELSE] tcell 1- [THEN] Constant flag+
 2045: : flag! ( w -- )   tlast @ flag+ + dup >r T c@ xor r> c! H ;
 2046: 
 2047: VARIABLE ^imm
 2048: 
 2049: \ !! should be target wordsize specific
 2050: $80 constant alias-mask
 2051: $40 constant immediate-mask
 2052: $20 constant restrict-mask
 2053: 
 2054: >TARGET
 2055: : immediate     immediate-mask flag!
 2056:                 ^imm @ @ dup <imm> = IF  drop  EXIT  THEN
 2057:                 <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
 2058:                 <imm> ^imm @ ! ;
 2059: : restrict      restrict-mask flag! ;
 2060: : compile-only  restrict-mask flag! ;
 2061: 
 2062: : isdoer	
 2063: \G define a forth word as doer, this makes obviously only sence on
 2064: \G forth processors such as the PSC1000
 2065: 		<do:> last-header-ghost @ >magic ! ;
 2066: >CROSS
 2067: 
 2068: \ Target Header Creation                               01nov92py
 2069: 
 2070: : ht-lstring, ( addr count -- )
 2071:   dup T , H bounds  ?DO  I c@ T c, H  LOOP ;
 2072: 
 2073: >TARGET
 2074: X has? f83headerstring [IF]
 2075: : name,  ( "name" -- )  bl word count ht-header, X cfalign ;
 2076: [ELSE]
 2077: : name,  ( "name" -- )  bl word count ht-lstring, X cfalign ;
 2078: [THEN]
 2079: : view,   ( -- ) ( dummy ) ;
 2080: >CROSS
 2081: 
 2082: \ Target Document Creation (goes to crossdoc.fd)       05jul95py
 2083: 
 2084: s" ./doc/crossdoc.fd" r/w create-file throw value doc-file-id
 2085: \ contains the file-id of the documentation file
 2086: 
 2087: : T-\G ( -- )
 2088:     source >in @ /string doc-file-id write-line throw
 2089:     postpone \ ;
 2090: 
 2091: Variable to-doc  to-doc on
 2092: 
 2093: : cross-doc-entry  ( -- )
 2094:     to-doc @ tlast @ 0<> and	\ not an anonymous (i.e. noname) header
 2095:     IF
 2096: 	s" " doc-file-id write-line throw
 2097: 	s" make-doc " doc-file-id write-file throw
 2098: 
 2099: 	Last-Header-Ghost @ >ghostname doc-file-id write-file throw
 2100: 	>in @
 2101: 	[char] ( parse 2drop
 2102: 	[char] ) parse doc-file-id write-file throw
 2103: 	s"  )" doc-file-id write-file throw
 2104: 	[char] \ parse 2drop					
 2105: 	T-\G
 2106: 	>in !
 2107:     THEN ;
 2108: 
 2109: \ Target TAGS creation
 2110: 
 2111: s" kernel.TAGS" r/w create-file throw value tag-file-id
 2112: s" kernel.tags" r/w create-file throw value vi-tag-file-id
 2113: \ contains the file-id of the tags file
 2114: 
 2115: Create tag-beg 1 c,  7F c,
 2116: Create tag-end 1 c,  01 c,
 2117: Create tag-bof 1 c,  0C c,
 2118: Create tag-tab 1 c,  09 c,
 2119: 
 2120: 2variable last-loadfilename 0 0 last-loadfilename 2!
 2121: 	    
 2122: : put-load-file-name ( -- )
 2123:     sourcefilename last-loadfilename 2@ d<>
 2124:     IF
 2125: 	tag-bof count tag-file-id write-line throw
 2126: 	sourcefilename 2dup
 2127: 	tag-file-id write-file throw
 2128: 	last-loadfilename 2!
 2129: 	s" ,0" tag-file-id write-line throw
 2130:     THEN ;
 2131: 
 2132: : put-cross-gnu-tag-entry  ( addr u -- )
 2133:     tlast @ 0<>	\ not an anonymous (i.e. noname) header
 2134:     IF
 2135: 	put-load-file-name
 2136: 	source >in @ min tag-file-id write-file throw
 2137: 	tag-beg count tag-file-id write-file throw
 2138: 	tag-file-id write-file throw
 2139: 	tag-end count tag-file-id write-file throw
 2140: 	base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
 2141: \	>in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
 2142: 	s" ,0" tag-file-id write-line throw
 2143: 	base !
 2144:     ELSE  2drop  THEN ;
 2145: 
 2146: : cross-gnu-tag-entry  ( -- )
 2147:     Last-Header-Ghost @ >ghostname put-cross-gnu-tag-entry ;
 2148: 
 2149: : put-cross-vi-tag-entry ( addr u -- )
 2150:     tlast @ 0<>	\ not an anonymous (i.e. noname) header
 2151:     IF
 2152: 	sourcefilename vi-tag-file-id write-file throw
 2153: 	tag-tab count vi-tag-file-id write-file throw
 2154: 	vi-tag-file-id write-file throw
 2155: 	tag-tab count vi-tag-file-id write-file throw
 2156: 	s" /^" vi-tag-file-id write-file throw
 2157: 	source vi-tag-file-id write-file throw
 2158: 	s" $/" vi-tag-file-id write-line throw
 2159:     ELSE  2drop  THEN ;
 2160: 
 2161: : cross-vi-tag-entry ( -- )
 2162:     Last-Header-Ghost @ >ghostname put-cross-vi-tag-entry ;
 2163: 
 2164: : cross-tag-entry ( -- )
 2165:     cross-gnu-tag-entry
 2166:     cross-vi-tag-entry ;
 2167: 
 2168: : put-cross-tag-entry ( addr u -- )
 2169:     2dup put-cross-gnu-tag-entry
 2170:     put-cross-vi-tag-entry ;
 2171: 
 2172: : cross-record-name ( -- )
 2173:     >in @ parse-name put-cross-tag-entry >in ! ;
 2174: 
 2175: \ Check for words
 2176: 
 2177: Defer skip? ' false IS skip?
 2178: 
 2179: : skipdef ( "name" -- )
 2180: \G skip definition of an undefined word in undef-words and
 2181: \G all-words mode
 2182:     Ghost dup forward?
 2183:     IF  >magic <skip> swap !
 2184:     ELSE drop THEN ;
 2185: 
 2186: : tdefined? ( "name" -- flag ) 
 2187:     Ghost undefined? 0= ;
 2188: 
 2189: : defined2? ( "name" -- flag ) 
 2190: \G return true for anything else than forward, even for <skip>
 2191: \G that's what we want
 2192:     Ghost forward? 0= ;
 2193: 
 2194: : forced? ( "name" -- flag )
 2195: \G return ture if it is a foreced skip with defskip
 2196:     Ghost >magic @ <skip> = ;
 2197: 
 2198: : needed? ( -- flag ) \ name
 2199: \G returns a false flag when
 2200: \G a word is not defined
 2201: \G a forward reference exists
 2202: \G so the definition is not skipped!
 2203:     bl word gfind
 2204:     IF dup undefined?
 2205: 	nip
 2206: 	0=
 2207:     ELSE  drop true  THEN ;
 2208: 
 2209: : doer? ( "name" -- 0 | addr ) \ name
 2210:     Ghost dup >magic @ <do:> = 
 2211:     IF >link @ ELSE drop 0 THEN ;
 2212: 
 2213: : skip-defs ( -- )
 2214:     BEGIN  refill  WHILE  source -trailing nip 0= UNTIL  THEN ;
 2215: 
 2216: \ Target header creation
 2217: 
 2218: Variable NoHeaderFlag
 2219: NoHeaderFlag off
 2220: 
 2221: : 0.r ( n1 n2 -- ) 
 2222:     base @ >r hex 
 2223:     0 swap <# 0 ?DO # LOOP #> type 
 2224:     r> base ! ;
 2225: 
 2226: : .sym ( adr len -- )
 2227: \G escapes / and \ to produce sed output
 2228:   bounds 
 2229:   DO I c@ dup
 2230: 	CASE	[char] / OF drop ." \/" ENDOF
 2231: 		[char] \ OF drop ." \\" ENDOF
 2232: 		dup OF emit ENDOF
 2233: 	ENDCASE
 2234:     LOOP ;
 2235: 
 2236: Defer setup-execution-semantics  ' noop IS setup-execution-semantics
 2237: 0 Value lastghost
 2238: 
 2239: : (THeader ( "name" -- ghost )
 2240:     \  >in @ bl word count type 2 spaces >in !
 2241:     \ wordheaders will always be compiled to rom
 2242:     switchrom
 2243:     \ build header in target
 2244:     NoHeaderFlag @
 2245:     IF  NoHeaderFlag off
 2246:     ELSE
 2247: 	T align H view,
 2248: 	tlast @ dup 0> IF tcell - THEN T A, H  there tlast !
 2249: 	1 headers-named +!	\ Statistic
 2250: 	>in @ T name, H >in !
 2251:     THEN
 2252:     T cfalign here H tlastcfa !
 2253:     \ Old Symbol table sed-script
 2254: \    >in @ cr ." sym:s/CFA=" there 4 0.r ." /"  bl word count .sym ." /g" cr >in !
 2255:     HeaderGhost
 2256:     \ output symbol table to extra file
 2257:     dup >ghostname there symentry
 2258:     dup Last-Header-Ghost ! dup to lastghost
 2259:     dup >magic ^imm !     \ a pointer for immediate
 2260:     alias-mask flag!
 2261:     cross-doc-entry cross-tag-entry 
 2262:     setup-execution-semantics
 2263:     ;
 2264: 
 2265: \ this is the resolver information from ":"
 2266: \ resolving is done by ";"
 2267: Variable ;Resolve 1 cells allot
 2268: 
 2269: : hereresolve ( ghost -- )
 2270:   there resolve 0 ;Resolve ! ;
 2271: 
 2272: : Theader  ( "name" -- ghost )
 2273:   (THeader dup hereresolve ;
 2274: 
 2275: Variable aprim-nr -20 aprim-nr !
 2276: 
 2277: : copy-execution-semantics ( ghost-from ghost-dest -- )
 2278:   >r
 2279:   dup >exec @ r@ >exec !
 2280:   dup >comp @ r@ >comp !
 2281:   dup >exec2 @ r@ >exec2 !
 2282:   dup >exec-compile @ r@ >exec-compile !
 2283:   dup >ghost-xt @ r@ >ghost-xt !
 2284:   dup >created @ r@ >created !
 2285:   rdrop drop ;
 2286: 
 2287: >TARGET
 2288: 
 2289: : Alias    ( cfa -- ) \ name
 2290:   >in @ skip? IF  2drop  EXIT  THEN  >in !
 2291:   (THeader ( S xt ghost )
 2292:   2dup swap xt>ghost swap copy-execution-semantics
 2293:   over resolve T A, H alias-mask flag! ;
 2294: 
 2295: Variable last-prim-ghost
 2296: 0 last-prim-ghost !
 2297: 
 2298: : asmprimname, ( ghost -- : name ) 
 2299:   dup last-prim-ghost !
 2300:   >r
 2301:   here bl word count string, r@ >asm-name !
 2302:   aprim-nr @ r> >asm-dummyaddr ! ;
 2303: 
 2304: Defer setup-prim-semantics
 2305: 
 2306: : mapprim   ( "forthname" "asmlabel" -- ) 
 2307:   THeader -1 aprim-nr +! aprim-nr @ T A, H
 2308:   asmprimname, 
 2309:   setup-prim-semantics ;
 2310: 
 2311: : mapprim:   ( "forthname" "asmlabel" -- ) 
 2312:   -1 aprim-nr +! aprim-nr @
 2313:   Ghost tuck swap resolve-noforwards <do:> swap tuck >magic !
 2314:   asmprimname, ;
 2315: 
 2316: : Doer:   ( cfa -- ) \ name
 2317:   >in @ skip? IF  2drop  EXIT  THEN  >in !
 2318:   dup 0< s" prims" T $has? H 0= and
 2319:   IF
 2320:       .sourcepos ." needs doer: " >in @ bl word count type >in ! cr
 2321:   THEN
 2322:   Ghost
 2323:   tuck swap resolve-noforwards <do:> swap >magic ! ;
 2324: 
 2325: Variable prim#
 2326: : first-primitive ( n -- )  prim# ! ;
 2327: : group 0 word drop prim# @ 1- -$200 and prim# ! ;
 2328: : groupadd  ( n -- )  drop ;
 2329: : Primitive  ( -- ) \ name
 2330:   >in @ skip? IF  drop  EXIT  THEN  >in !
 2331:   s" prims" T $has? H 0=
 2332:   IF
 2333:      .sourcepos ." needs prim: " >in @ bl word count type >in ! cr
 2334:   THEN
 2335:   prim# @ (THeader ( S xt ghost )
 2336:   ['] prim-resolved over >comp !
 2337:   dup >ghost-flags <primitive> set-flag
 2338:   s" EC" T $has? H 0=
 2339:   IF
 2340:       over resolve-noforwards T A, H
 2341:       alias-mask flag!
 2342:   ELSE
 2343:       T here H resolve-noforwards T A, H
 2344:   THEN
 2345:   -1 prim# +! ;
 2346: >CROSS
 2347: 
 2348: \ Conditionals and Comments                            11may93jaw
 2349: 
 2350: \G saves the existing cond action, this is used for redefining in
 2351: \G instant
 2352: Variable cond-xt-old
 2353: 
 2354: : cond-target ( -- )
 2355: \G Compiles semantic of redefined cond into new one
 2356:   cond-xt-old @ compile, ; immediate restrict
 2357: 
 2358: : ;Cond
 2359:   postpone ;
 2360:   swap ! ;  immediate
 2361: 
 2362: : Cond: ( "name" -- ) 
 2363: \g defines a conditional or another word that must
 2364: \g be executed directly while compiling
 2365: \g these words have no interpretative semantics by default
 2366:   Ghost
 2367:   >exec-compile
 2368:   dup @ cond-xt-old !
 2369:   :NONAME ;
 2370: 
 2371: 
 2372: : Comment ( -- )
 2373:   >in @ Ghost swap >in ! ' swap 
 2374:   2dup >exec-compile ! >exec ! ;
 2375: 
 2376: Comment (       Comment \
 2377: 
 2378: \ compile                                              10may93jaw
 2379: 
 2380: : compile  ( "name" -- ) \ name
 2381:   findghost
 2382:   dup >exec-compile @ ?dup
 2383:   IF    nip compile,
 2384:   ELSE  postpone literal postpone gexecute  THEN ;  immediate restrict
 2385:             
 2386: >TARGET
 2387: 
 2388: : '  ( -- xt ) 
 2389: \G returns the target-cfa of a ghost
 2390:   bl word gfind 0= ABORT" CROSS: Ghost don't exists"
 2391:   g>xt ;
 2392: 
 2393: \ FIXME: this works for the current use cases, but is not
 2394: \ in all cases correct ;-) 
 2395: : comp' X ' 0 ;
 2396: 
 2397: Cond: [']  T ' H alit, ;Cond
 2398: 
 2399: >CROSS
 2400: 
 2401: : [T']
 2402: \ returns the target-cfa of a ghost, or compiles it as literal
 2403:   postpone [G'] 
 2404:   state @ IF postpone g>xt ELSE g>xt THEN ; immediate
 2405: 
 2406: \ \ threading modell					13dec92py
 2407: \ modularized						14jun97jaw
 2408: 
 2409: T 2 cells H Value xt>body
 2410: 
 2411: : (>body)   ( cfa -- pfa ) 
 2412:   xt>body + ;						' (>body) plugin-of t>body
 2413: 
 2414: : fillcfa   ( usedcells -- )
 2415:   T cells H xt>body swap -
 2416:   assert1( dup 0 >= )
 2417:   0 ?DO 0 X c, tchar +LOOP ;
 2418: 
 2419: : (doer,)   ( ghost -- ) 
 2420:   addr, 1 fillcfa ;   					' (doer,) plugin-of doer,
 2421: 
 2422: : (docol,)  ( -- ) [G'] :docol (doer,) ;		' (docol,) plugin-of docol,
 2423: 
 2424:                                                         ' NOOP plugin-of ca>native
 2425: 
 2426: : (doprim,) ( -- )
 2427:   there xt>body + ca>native T a, H 1 fillcfa ;		' (doprim,) plugin-of doprim,
 2428: 
 2429: : (doeshandler,) ( -- ) 
 2430:     T H ; 					' (doeshandler,) plugin-of doeshandler,
 2431: 
 2432: : (dodoes,) ( does-action-ghost -- )
 2433:   ]comp [G'] :dodoes addr, comp[
 2434:   addr,
 2435:   2 fillcfa ;						' (dodoes,) plugin-of dodoes,
 2436: 
 2437: : (dlit,) ( n -- ) compile lit td, ;			' (dlit,) plugin-of dlit,
 2438: 
 2439: : (lit,) ( n -- )  s>d dlit, ;				' (lit,) plugin-of lit,
 2440: 
 2441: \ if we dont produce relocatable code alit, defaults to lit, jaw
 2442: \ this is just for convenience, so we don't have to define alit,
 2443: \ seperately for embedded systems....
 2444: T has? relocate H
 2445: [IF]
 2446: : (alit,) ( n -- )  compile lit T  a, H ;		' (alit,) plugin-of alit,
 2447: [ELSE]
 2448: : (alit,) ( n -- )  lit, ;				' (alit,) plugin-of alit,
 2449: [THEN]
 2450: 
 2451: : (fini,)         compile ;s ;				' (fini,) plugin-of fini,
 2452: 
 2453: [IFUNDEF] (code) 
 2454: Defer (code)
 2455: Defer (end-code)
 2456: [THEN]
 2457: 
 2458: >TARGET
 2459: : Code
 2460:   defempty?
 2461:   (THeader ( ghost )
 2462:   ['] prim-resolved over >comp !
 2463:   there resolve-noforwards
 2464:   
 2465:   [ T e? prims H 0= [IF] T e? ITC H [ELSE] true [THEN] ] [IF]
 2466:   doprim, 
 2467:   [THEN]
 2468:   depth (code) ;
 2469: 
 2470: \ FIXME : no-compile -1 ABORT" this ghost is not for compilation" ;
 2471: 
 2472: : Code:
 2473:   defempty?
 2474:     Ghost >r 
 2475:     r@ >ghostname there symentry
 2476:     r@ there ca>native resolve-noforwards
 2477:     <do:> r@ >magic !
 2478:     r> drop
 2479:     depth (code) ;
 2480: 
 2481: : end-code
 2482:     (end-code)
 2483:     depth ?dup IF   1- <> ABORT" CROSS: Stack changed"
 2484:     ELSE true ABORT" CROSS: Stack empty" THEN
 2485:     ;
 2486: 
 2487: >CROSS
 2488: 
 2489: \ tLiteral                                             12dec92py
 2490: 
 2491: >TARGET
 2492: Cond: \G  T-\G ;Cond
 2493: 
 2494: Cond: Literal  ( n -- )   lit, ;Cond
 2495: Cond: ALiteral ( n -- )   alit, ;Cond
 2496: 
 2497: : Char ( "<char>" -- )  bl word char+ c@ ;
 2498: Cond: [Char]   ( "<char>" -- )  Char  lit, ;Cond
 2499: 
 2500: : (x#) ( adr len base -- )
 2501:   base @ >r base ! 0 0 name >number 2drop drop r> base ! ;
 2502: 
 2503: : d# $0a (x#) ;
 2504: : h# $010 (x#) ;
 2505: 
 2506: Cond: d# $0a (x#) lit, ;Cond
 2507: Cond: h# $010 (x#) lit, ;Cond
 2508: 
 2509: tchar 1 = [IF]
 2510: Cond: chars ;Cond 
 2511: [THEN]
 2512: 
 2513: \ some special literals					27jan97jaw
 2514: 
 2515: Cond: MAXU
 2516:   -1 s>d dlit,
 2517:   ;Cond
 2518: 
 2519: tcell 2 = tcell 4 = or tcell 8 = or 0=
 2520: [IF]
 2521: .( Warning: MINI and MAXI may not work with this host) cr
 2522: [THEN]
 2523: 
 2524: Cond: MINI
 2525:   tcell 2 = IF $8000 ELSE $80000000 THEN 0
 2526:   tcell 8 = IF swap THEN dlit,
 2527:   ;Cond
 2528:  
 2529: Cond: MAXI
 2530:   tcell 2 = IF $7fff ELSE $7fffffff THEN 0
 2531:   tcell 8 = IF drop -1 swap THEN dlit,
 2532:   ;Cond
 2533: 
 2534: >CROSS
 2535: 
 2536: \ Target compiling loop                                12dec92py
 2537: \ ">tib trick thrown out                               10may93jaw
 2538: \ number? defined at the top                           11may93jaw
 2539: \ replaced >in by save-input				
 2540: 
 2541: : discard 0 ?DO drop LOOP ;
 2542: 
 2543: \ compiled word might leave items on stack!
 2544: : tcom ( x1 .. xn n name -- )
 2545: \  dup count type space
 2546:   gfind 
 2547:   IF    >r ( discard saved input state ) discard r>
 2548: 	dup >exec-compile @ ?dup
 2549:         IF   nip execute-exec-compile ELSE gexecute  THEN 
 2550: 	EXIT 
 2551:   THEN
 2552:   (number?) dup  
 2553:   IF	0> IF swap lit,  THEN  lit, discard
 2554:   ELSE	2drop restore-input throw Ghost gexecute THEN  ;
 2555: 
 2556: \ : ; DOES>                                            13dec92py
 2557: \ ]                                                     9may93py/jaw
 2558: 
 2559: >CROSS
 2560: 
 2561: : compiling-state ( -- )
 2562: \G set states to compililng
 2563:     Compiling comp-state !
 2564:     \ if we have a state in target, change it with the compile state
 2565:     [G'] state dup undefined? 0= 
 2566:     IF >ghost-xt @ execute X on ELSE drop THEN ;
 2567: 
 2568: : interpreting-state ( -- )
 2569: \G set states to interpreting
 2570:    \ if target has a state variable, change it according to our state
 2571:    [G'] state dup undefined? 0= 
 2572:    IF >ghost-xt @ execute X off ELSE drop THEN
 2573:    Interpreting comp-state ! ;
 2574: 
 2575: >TARGET
 2576: 
 2577: : ] 
 2578:     compiling-state
 2579:     BEGIN
 2580:         BEGIN save-input bl word
 2581:               dup c@ 0= WHILE drop discard refill 0=
 2582:               ABORT" CROSS: End of file while target compiling"
 2583:         REPEAT
 2584:         tcom
 2585:         compiling? 0=
 2586:     UNTIL ;
 2587: 
 2588: \ by the way: defining a second interpreter (a compiler-)loop
 2589: \             is not allowed if a system should be ans conform
 2590: 
 2591: : (:) ( ghost -- ) 
 2592: \ common factor of : and :noname. Prepare ;Resolve and start definition
 2593:    ;Resolve ! there ;Resolve cell+ !
 2594:    docol, ]comp  colon-start depth T ] H ;
 2595: 
 2596: : : ( -- colon-sys ) \ Name
 2597:   defempty?
 2598:   constflag off \ don't let this flag work over colon defs
 2599: 		\ just to go sure nothing unwanted happens
 2600:   >in @ skip? IF  drop skip-defs  EXIT  THEN  >in !
 2601:   (THeader (:) ;
 2602: 
 2603: : :noname ( -- colon-sys )
 2604:   switchrom X cfalign there 
 2605:   \ define a nameless ghost
 2606:   here ghostheader dup last-header-ghost ! dup to lastghost
 2607:   (:) ;  
 2608: 
 2609: Cond: EXIT ( -- )   compile ;S  ;Cond
 2610: 
 2611: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
 2612: 
 2613: >CROSS
 2614: : LastXT ;Resolve @ 0= abort" CROSS: no definition for LastXT"
 2615:          ;Resolve cell+ @ ;
 2616: 
 2617: >TARGET
 2618: 
 2619: Cond: recurse ( -- ) Last-Header-Ghost @ gexecute ;Cond
 2620: 
 2621: Cond: ; ( -- ) 
 2622: 	depth ?dup 
 2623: 	IF   1- <> ABORT" CROSS: Stack changed"
 2624: 	ELSE true ABORT" CROSS: Stack empty" 
 2625: 	THEN
 2626: 	colon-end
 2627: 	fini,
 2628: 	comp[
 2629: 	;Resolve @ 
 2630: 	IF  ['] colon-resolved ;Resolve @ >comp !
 2631: 	    ;Resolve @ ;Resolve cell+ @ resolve 
 2632: 	THEN
 2633: 	interpreting-state
 2634: 	;Cond
 2635: 
 2636: Cond: [ ( -- ) interpreting-state ;Cond
 2637: 
 2638: >CROSS
 2639: 
 2640: 0 Value created
 2641: 
 2642: : !does ( does-action -- )
 2643:     tlastcfa @ [G'] :dovar killref
 2644:     >space here >r ghostheader space>
 2645:     ['] colon-resolved r@ >comp !
 2646:     r@ created >do:ghost ! r@ swap resolve
 2647:     r> tlastcfa @ >tempdp dodoes, tempdp> ;
 2648: 
 2649: Defer instant-interpret-does>-hook  ' noop IS instant-interpret-does>-hook
 2650: 
 2651: T has? primcentric H [IF]
 2652: : does-resolved ( ghost -- )
 2653: \    g>xt dup T >body H alit, compile call T cell+ @ a, H ;
 2654:     compile does-exec g>xt T a, H ;
 2655: [ELSE]
 2656: : does-resolved ( ghost -- )
 2657:     g>xt T a, H ;
 2658: [THEN]
 2659: 
 2660: : resolve-does>-part ( -- )
 2661: \ resolve words made by builders
 2662:   Last-Header-Ghost @ >do:ghost @ ?dup 
 2663:   IF  there resolve  THEN ;
 2664: 
 2665: >TARGET
 2666: Cond: DOES>
 2667:         T here H [ T has? primcentric H [IF] ] 5 [ [ELSE] ] 4 [ [THEN] ] T cells
 2668:         H + alit, compile !does compile ;s
 2669:         doeshandler, resolve-does>-part
 2670:         ;Cond
 2671: 
 2672: : DOES>
 2673:     ['] does-resolved created >comp !
 2674:     switchrom doeshandler, T here H !does 
 2675:     instant-interpret-does>-hook
 2676:     depth T ] H ;
 2677: 
 2678: >CROSS
 2679: \ Creation                                              01nov92py
 2680: 
 2681: \ Builder                                               11may93jaw
 2682: 
 2683: 0 Value built
 2684: 
 2685: : Builder    ( Create-xt do-ghost "name" -- )
 2686: \ builds up a builder in current vocabulary
 2687: \ create-xt is executed when word is interpreted
 2688: \ do:-xt is executed when the created word from builder is executed
 2689: \ for do:-xt an additional entry after the normal ghost-entrys is used
 2690: 
 2691:   ghost to built 
 2692:   built >created @ 0= IF
 2693:     built >created on
 2694:   THEN ;
 2695: 
 2696: : gdoes,  ( ghost -- )
 2697: \ makes the codefield for a word that is built
 2698:   >do:ghost @ dup undefined? 0=
 2699:   IF
 2700: 	dup >magic @ <do:> =
 2701: 	IF 	 doer, 
 2702: 	ELSE	dodoes,
 2703: 	THEN
 2704: 	EXIT
 2705:   THEN
 2706: \  compile :dodoes gexecute
 2707: \  T here H tcell - reloff 
 2708:   2 refered 
 2709:   0 fillcfa
 2710:   ;
 2711: 
 2712: : takeover-x-semantics ( S constructor-ghost new-ghost -- )
 2713:    \g stores execution semantic and compilation semantic in the built word
 2714:    swap >do:ghost @ 2dup swap >do:ghost !
 2715:    \ we use the >exec2 field for the semantic of a created word,
 2716:    \ using exec or exec2 makes no difference for normal cross-compilation
 2717:    \ but is usefull for instant where the exec field is already
 2718:    \ defined (e.g. Vocabularies)
 2719:    2dup >exec @ swap >exec2 ! 
 2720:    >comp @ swap >comp ! ;
 2721: 
 2722: 0 Value createhere
 2723: 
 2724: : create-resolve ( -- )
 2725:     created createhere resolve 0 ;Resolve ! ;
 2726: : create-resolve-immediate ( -- )
 2727:     create-resolve T immediate H ;
 2728: 
 2729: : TCreate ( <name> -- )
 2730:   create-forward-warn
 2731:   IF ['] reswarn-forward IS resolve-warning THEN
 2732:   executed-ghost @ (Theader
 2733:   dup >created on  dup to created
 2734:   2dup takeover-x-semantics
 2735:   there to createhere drop gdoes, ;
 2736: 
 2737: : RTCreate ( <name> -- )
 2738: \ creates a new word with code-field in ram
 2739:   create-forward-warn
 2740:   IF ['] reswarn-forward IS resolve-warning THEN
 2741:   \ make Alias
 2742:   executed-ghost @ (THeader 
 2743:   dup >created on  dup to created
 2744:   2dup takeover-x-semantics
 2745:   there 0 T a, H alias-mask flag!
 2746:   \ store poiter to code-field
 2747:   switchram T cfalign H
 2748:   there swap T ! H
 2749:   there tlastcfa ! 
 2750:   there to createhere drop gdoes, ;
 2751: 
 2752: : Build:  ( -- [xt] [colon-sys] )
 2753:   :noname postpone TCreate ;
 2754: 
 2755: : BuildSmart:  ( -- [xt] [colon-sys] )
 2756:   :noname
 2757:   [ T has? rom H [IF] ]
 2758:   postpone RTCreate
 2759:   [ [ELSE] ]
 2760:   postpone TCreate 
 2761:   [ [THEN] ] ;
 2762: 
 2763: : ;Build
 2764:   postpone create-resolve postpone ; built >exec ! ; immediate
 2765: 
 2766: : ;Build-immediate
 2767:     postpone create-resolve-immediate
 2768:     postpone ; built >exec ! ; immediate
 2769: 
 2770: : gdoes>  ( ghost -- addr flag )
 2771:   executed-ghost @ g>body ;
 2772: 
 2773: \ DO: ;DO                                               11may93jaw
 2774: 
 2775: : do:ghost! ( ghost -- ) built >do:ghost ! ;
 2776: : doexec! ( xt -- ) built >do:ghost @ >exec ! ;
 2777: 
 2778: : DO:     ( -- [xt] [colon-sys] )
 2779:   here ghostheader do:ghost!
 2780:   :noname postpone gdoes> ;
 2781: 
 2782: : by:     ( -- [xt] [colon-sys] ) \ name
 2783:   Ghost do:ghost!
 2784:   :noname postpone gdoes> ;
 2785: 
 2786: : ;DO ( [xt] [colon-sys] -- )
 2787:   postpone ; doexec! ; immediate
 2788: 
 2789: : by      ( -- ) \ Name
 2790:   Ghost >do:ghost @ do:ghost! ;
 2791: 
 2792: : compile: ( --[xt] [colon-sys] )
 2793: \G defines a compile time action for created words
 2794: \G by this builder
 2795:   :noname ;
 2796: 
 2797: : ;compile ( [xt] [colon-sys] -- )
 2798:   postpone ; built >do:ghost @ >comp ! ; immediate
 2799: 
 2800: \ Variables and Constants                              05dec92py
 2801: 
 2802: Builder (Constant)
 2803: Build:  ( n -- ) ;Build
 2804: by: :docon ( target-body-addr -- n ) T @ H ;DO
 2805: 
 2806: Builder Constant
 2807: Build:  ( n -- ) T , H ;Build
 2808: by (Constant)
 2809: 
 2810: Builder AConstant
 2811: Build:  ( n -- ) T A, H ;Build
 2812: by (Constant)
 2813: 
 2814: Builder 2Constant
 2815: Build:  ( d -- ) T , , H ;Build
 2816: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
 2817: 
 2818: Builder Create
 2819: BuildSmart: ;Build
 2820: by: :dovar ( target-body-addr -- addr ) ;DO
 2821: 
 2822: Builder Variable
 2823: T has? rom H [IF]
 2824: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , H ( switchrom ) ;Build
 2825: by (Constant)
 2826: [ELSE]
 2827: Build: T 0 , H ;Build
 2828: by Create
 2829: [THEN]
 2830: 
 2831: Builder 2Variable
 2832: T has? rom H [IF]
 2833: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , 0 , H ( switchrom ) ;Build
 2834: by (Constant)
 2835: [ELSE]
 2836: Build: T 0 , 0 , H ;Build
 2837: by Create
 2838: [THEN]
 2839: 
 2840: Builder AVariable
 2841: T has? rom H [IF]
 2842: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 A, H ( switchrom ) ;Build
 2843: by (Constant)
 2844: [ELSE]
 2845: Build: T 0 A, H ;Build
 2846: by Create
 2847: [THEN]
 2848: 
 2849: \ User variables                                       04may94py
 2850: 
 2851: : tup@ user-region >rstart @ ;
 2852: 
 2853: \ Variable tup  0 tup !
 2854: \ Variable tudp 0 tudp !
 2855: 
 2856: : u,  ( n -- udp )
 2857:   current-region >r user-region activate
 2858:   X here swap X , tup@ -
 2859:   r> activate ;
 2860: 
 2861: : au, ( n -- udp )
 2862:   current-region >r user-region activate
 2863:   X here swap X a, tup@ - 
 2864:   r> activate ;
 2865: 
 2866: T has? no-userspace H [IF]
 2867: 
 2868: : buildby
 2869:   ghost >exec @ built >exec ! ;
 2870: 
 2871: Builder User
 2872: buildby Variable
 2873: by Variable
 2874: 
 2875: Builder 2User
 2876: buildby 2Variable
 2877: by 2Variable
 2878: 
 2879: Builder AUser
 2880: buildby AVariable
 2881: by AVariable
 2882: 
 2883: [ELSE]
 2884: 
 2885: Builder User
 2886: Build: 0 u, X , ;Build
 2887: by: :douser ( ghost -- up-addr )  X @ tup@ + ;DO
 2888: 
 2889: Builder 2User
 2890: Build: 0 u, X , 0 u, drop ;Build
 2891: by User
 2892: 
 2893: Builder AUser
 2894: Build: 0 au, X , ;Build
 2895: by User
 2896: 
 2897: [THEN]
 2898: 
 2899: T has? rom H [IF]
 2900: Builder (Value)
 2901: Build:  ( n -- ) ;Build
 2902: by: :dovalue ( target-body-addr -- n ) T @ @ H ;DO
 2903: 
 2904: Builder Value
 2905: Build: T here 0 A, H switchram T align here swap ! , H ;Build
 2906: by (Value)
 2907: 
 2908: Builder AValue
 2909: Build: T here 0 A, H switchram T align here swap ! A, H ;Build
 2910: by (Value)
 2911: [ELSE]
 2912: Builder (Value)
 2913: Build:  ( n -- ) ;Build
 2914: by: :dovalue ( target-body-addr -- n ) T @ H ;DO
 2915: 
 2916: Builder Value
 2917: BuildSmart: T , H ;Build
 2918: by (Value)
 2919: 
 2920: Builder AValue
 2921: BuildSmart: T A, H ;Build
 2922: by (Value)
 2923: [THEN]
 2924: 
 2925: Defer texecute
 2926: 
 2927: Builder Defer
 2928: T has? rom H [IF]
 2929:     Build: ( -- )  T here 0 A, H switchram T align here swap ! H [T'] noop T A, H ( switchrom ) ;Build
 2930:     by: :dodefer ( ghost -- ) X @ X @ texecute ;DO
 2931: [ELSE]
 2932:     BuildSmart:  ( -- ) [T'] noop T A, H ;Build
 2933:     by: :dodefer ( ghost -- ) X @ texecute ;DO
 2934: [THEN]
 2935: 
 2936: Builder interpret/compile:
 2937: Build: ( inter comp -- ) swap T A, A, H ;Build-immediate
 2938: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
 2939: 
 2940: \ Sturctures                                           23feb95py
 2941: 
 2942: : nalign ( addr1 n -- addr2 )
 2943: \ addr2 is the aligned version of addr1 wrt the alignment size n
 2944:  1- tuck +  swap invert and ;
 2945: 
 2946: 
 2947: Builder (Field)
 2948: Build: ;Build
 2949: by: :dofield T @ H + ;DO
 2950: 
 2951: Builder Field
 2952: Build: ( align1 offset1 align size "name" --  align2 offset2 )
 2953:     rot dup T , H ( align1 align size offset1 )
 2954:     + >r nalign r> ;Build
 2955: by (Field)
 2956: 
 2957: >TARGET
 2958: : struct  T 1 chars 0 H ;
 2959: : end-struct  T 2Constant H ;
 2960: 
 2961: : cell% ( n -- size align )
 2962:     T 1 cells H dup ;
 2963: >CROSS
 2964: 
 2965: \ ABI-CODE support
 2966: Builder (ABI-CODE)
 2967: Build: ;Build
 2968: by: :doabicode noop ;DO
 2969: 
 2970: BUILDER (;abi-code)
 2971: Build: ;Build
 2972: by: :do;abicode noop ;DO
 2973: 
 2974: \ Input-Methods                                            01py
 2975: 
 2976: Builder input-method
 2977: Build: ( m v -- m' v )  dup T , cell+ H ;Build
 2978: DO:  abort" Not in cross mode" ;DO
 2979: 
 2980: Builder input-var
 2981: Build: ( m v size -- m v' )  over T , H + ;Build
 2982: DO:  abort" Not in cross mode" ;DO
 2983: 
 2984: \ Mini-OOF
 2985: 
 2986: Builder method
 2987: Build: ( m v -- m' v )  over T , swap cell+ swap H ;Build
 2988: DO:  abort" Not in cross mode" ;DO
 2989: 
 2990: Builder var
 2991: Build: ( m v size -- m v+size )  over T , H + ;Build
 2992: DO: ( o -- addr ) T @ H + ;DO
 2993: 
 2994: Builder end-class
 2995: Build: ( addr m v -- )
 2996:    T here >r , dup , 2 cells H ?DO T ['] noop , 1 cells H +LOOP
 2997:    T cell+ dup cell+ r> rot @ 2 cells /string move H ;Build
 2998: by Create
 2999: 
 3000: : class ( class -- class methods vars ) dup T 2@ H ;
 3001: : defines ( xt class -- )  T ' >body @ + ! H ;
 3002: 
 3003: \ Peephole optimization					05sep01jaw
 3004: 
 3005: \ this section defines different compilation
 3006: \ actions for created words
 3007: \ this will help the peephole optimizer
 3008: \ I (jaw) took this from bernds latest cross-compiler
 3009: \ changes but seperated it from the original
 3010: \ Builder words. The final plan is to put this
 3011: \ into a seperate file, together with the peephole
 3012: \ optimizer for cross
 3013: 
 3014: 
 3015: T has? primcentric H [IF]
 3016: 
 3017: \ .( loading peephole optimization) cr
 3018: 
 3019: >CROSS
 3020: 
 3021: : (callc) compile call T >body a, H ;		' (callc) plugin-of colon,
 3022: : (callcm) T here 0 a, 0 a, H ;                 ' (callcm) plugin-of colonmark,
 3023: : (call-res) >tempdp resolved gexecute tempdp> drop ;
 3024:                                                 ' (call-res) plugin-of colon-resolve
 3025: T has? ec H [IF]
 3026: : (pprim) T @ H >signed dup 0< IF  $4000 -  ELSE
 3027:     cr ." wrong usage of (prim) "
 3028:     dup gdiscover IF  .ghost  ELSE  .  THEN  cr -1 throw  THEN
 3029:     T a, H ;					' (pprim) plugin-of prim,
 3030: [ELSE]
 3031: : (pprim) dup 0< IF  $4000 -  ELSE
 3032:     cr ." wrong usage of (prim) "
 3033:     dup gdiscover IF  .ghost  ELSE  .  THEN  cr -1 throw  THEN
 3034:     T a, H ;					' (pprim) plugin-of prim,
 3035: [THEN]
 3036: 
 3037: \ if we want this, we have to spilt aconstant
 3038: \ and constant!!
 3039: \ Builder (Constant)
 3040: \ compile: g>body X @ lit, ;compile
 3041: 
 3042: Builder (Constant)
 3043: compile: g>body compile lit@ T a, H ;compile
 3044: 
 3045: Builder (Value)
 3046: compile: g>body compile lit@ T a, H ;compile
 3047: 
 3048: \ this changes also Variable, AVariable and 2Variable
 3049: Builder Create
 3050: compile: g>body alit, ;compile
 3051: 
 3052: Builder User
 3053: compile: g>body compile useraddr T @ , H ;compile
 3054: 
 3055: Builder Defer
 3056: compile: g>body compile lit-perform T A, H ;compile
 3057: 
 3058: Builder (Field)
 3059: compile: g>body T @ H compile lit+ T here H reloff T , H ;compile
 3060: 
 3061: Builder interpret/compile:
 3062: compile: does-resolved ;compile
 3063: 
 3064: Builder input-method
 3065: compile: does-resolved ;compile
 3066: 
 3067: Builder input-var
 3068: compile: does-resolved ;compile
 3069: 
 3070: [THEN]
 3071: 
 3072: \ structural conditionals                              17dec92py
 3073: 
 3074: >CROSS
 3075: : (ncontrols?) ( n -- ) 
 3076: \g We expect n open control structures
 3077:   depth over u<= 
 3078:   ABORT" CROSS: unstructured, stack underflow"
 3079:   0 ?DO I pick 0= 
 3080:         ABORT" CROSS: unstructured" 
 3081:   LOOP ;					' (ncontrols?) plugin-of ncontrols?
 3082: 
 3083: \ : ?struc      ( flag -- )       ABORT" CROSS: unstructured " ;
 3084: \ : sys?        ( sys -- sys )    dup 0= ?struc ;
 3085: 
 3086: : >mark       ( -- sys )        T here  0 , H ;
 3087: 
 3088: X has? abranch [IF]
 3089:     : branchoffset ( src dest -- )  drop ;
 3090:     : offset, ( n -- )  X A, ;
 3091: [ELSE]
 3092:     : branchoffset ( src dest -- )  - tchar / ; \ ?? jaw
 3093:     : offset, ( n -- )  X , ;
 3094: [THEN]
 3095: 
 3096: :noname compile branch X here branchoffset offset, ;
 3097:   IS branch, ( target-addr -- )
 3098: :noname compile ?branch X here branchoffset offset, ;
 3099:   IS ?branch, ( target-addr -- )
 3100: :noname compile branch T here 0 H offset, ;
 3101:   IS branchmark, ( -- branchtoken )
 3102: :noname compile ?branch T here 0 H offset, ;
 3103:   IS ?branchmark, ( -- branchtoken )
 3104: :noname T here 0 H offset, ;
 3105:   IS ?domark, ( -- branchtoken )
 3106: :noname dup X @ ?struc X here over branchoffset swap X ! ;
 3107:   IS branchtoresolve, ( branchtoken -- )
 3108: :noname branchto, X here ;
 3109:   IS branchtomark, ( -- target-addr )
 3110: 
 3111: >TARGET
 3112: 
 3113: \ Structural Conditionals                              12dec92py
 3114: 
 3115: \ CLEANUP Cond: BUT       sys? swap ;Cond
 3116: \ CLEANUP Cond: YET       sys? dup ;Cond
 3117: 
 3118: >CROSS
 3119: 
 3120: Variable tleavings 0 tleavings !
 3121: 
 3122: : (done) ( do-addr -- )
 3123: \G resolve branches of leave and ?leave and ?do
 3124: \G do-addr is the address of the beginning of our
 3125: \G loop so we can take care of nested loops
 3126:     tleavings @
 3127:     BEGIN  dup
 3128:     WHILE
 3129: 	>r dup r@ cell+ @ \ address of branch
 3130: 	u> 0=	   \ lower than DO?	
 3131:     WHILE
 3132: 	r@ 2 cells + @ \ branch token
 3133: 	branchtoresolve,
 3134: 	r@ @ r> free throw
 3135:     REPEAT  r>  THEN
 3136:     tleavings ! drop ;
 3137: 
 3138: >TARGET
 3139: 
 3140: \ What for? ANS? JAW Cond: DONE   ( addr -- )  (done) ;Cond
 3141: 
 3142: >CROSS
 3143: : (leave) ( branchtoken -- )
 3144:     3 cells allocate throw >r
 3145:     T here H r@ cell+ !
 3146:     r@ 2 cells + !
 3147:     tleavings @ r@ !
 3148:     r> tleavings ! ;
 3149: >TARGET
 3150: 
 3151: : (leave,) ( -- ) 
 3152:   branchmark, (leave) ; 			' (leave,) plugin-of leave,
 3153: 
 3154: : (?leave,) ( -- )
 3155:   compile 0= ?branchmark, (leave) ; 		' (?leave,) plugin-of ?leave,
 3156: 
 3157: Cond: LEAVE     leave, ;Cond
 3158: Cond: ?LEAVE    ?leave, ;Cond
 3159: 
 3160: >CROSS
 3161: \ !!JW ToDo : Move to general tools section
 3162: 
 3163: : to1 ( x1 x2 xn n -- addr )
 3164: \G packs n stack elements in am allocated memory region
 3165:    dup dup 1+ cells allocate throw dup >r swap 1+
 3166:    0 DO tuck ! cell+ LOOP
 3167:    drop r> ;
 3168: 
 3169: : 1to ( addr -- x1 x2 xn )
 3170: \G unpacks the elements saved by to1
 3171:     dup @ swap over cells + swap
 3172:     0 DO  dup @ swap 1 cells -  LOOP
 3173:     free throw ;
 3174: 
 3175: : loop] ( target-addr -- )
 3176:   branchto, 
 3177:   dup 	X here branchoffset offset, 
 3178:   tcell - (done) ;
 3179: 
 3180: : skiploop] ?dup IF branchto, branchtoresolve, THEN ;
 3181: 
 3182: >TARGET
 3183: 
 3184: \ Structural Conditionals                              12dec92py
 3185: 
 3186: : (cs-swap) ( x1 x2 -- x2 x1 )
 3187:   swap ;					' (cs-swap) plugin-of cs-swap
 3188: 
 3189: : (ahead,) branchmark, ; 			' (ahead,) plugin-of ahead,
 3190: 
 3191: : (if,) ?branchmark, ; 				' (if,) plugin-of if,
 3192: 
 3193: : (then,) branchto, branchtoresolve, ; 		' (then,) plugin-of then,
 3194: 
 3195: : (else,) ( ahead ) branchmark, 
 3196:           swap 
 3197:           ( then ) branchto, branchtoresolve, ;	' (else,) plugin-of else,
 3198: 
 3199: : (begin,) branchtomark, ; 			' (begin,) plugin-of begin,
 3200: 
 3201: : (while,) ( if ) ?branchmark,
 3202:            swap ; 				' (while,) plugin-of while,
 3203: 
 3204: : (again,) branch, ;				' (again,) plugin-of again,
 3205: 
 3206: : (until,) ?branch, ;				' (until,) plugin-of until,
 3207: 
 3208: : (repeat,) ( again ) branch,
 3209:             ( then ) branchto, branchtoresolve, ; ' (repeat,) plugin-of repeat,
 3210: 
 3211: : (case,)   ( -- n )
 3212:   0 ;						' (case,) plugin-of case,
 3213: 
 3214: : (of,) ( n -- x1 n )
 3215:   1+ >r 
 3216:   compile over compile = 
 3217:   if, compile drop r> ;				' (of,) plugin-of of,
 3218: 
 3219: : (endof,) ( x1 n -- x2 n )
 3220:   >r 1 ncontrols? else, r> ;			' (endof,) plugin-of endof,
 3221: 
 3222: : (endcase,) ( x1 .. xn n -- )
 3223:   compile drop 0 ?DO 1 ncontrols? then, LOOP ;	' (endcase,) plugin-of endcase,
 3224: 
 3225: >TARGET
 3226: Cond: AHEAD     ahead, ;Cond
 3227: Cond: IF        if,  ;Cond
 3228: Cond: THEN      1 ncontrols? then, ;Cond
 3229: Cond: ENDIF     1 ncontrols? then, ;Cond
 3230: Cond: ELSE      1 ncontrols? else, ;Cond
 3231: 
 3232: Cond: BEGIN     begin, ;Cond
 3233: Cond: WHILE     1 ncontrols? while, ;Cond
 3234: Cond: AGAIN     1 ncontrols? again, ;Cond
 3235: Cond: UNTIL     1 ncontrols? until, ;Cond
 3236: Cond: REPEAT    2 ncontrols? repeat, ;Cond
 3237: 
 3238: Cond: CASE      case, ;Cond
 3239: Cond: OF        of, ;Cond
 3240: Cond: ENDOF     endof, ;Cond
 3241: Cond: ENDCASE   endcase, ;Cond
 3242: 
 3243: \ Structural Conditionals                              12dec92py
 3244: 
 3245: : (do,) ( -- target-addr )
 3246:   \ ?? i think 0 is too much! jaw
 3247:     0 compile (do)
 3248:     branchtomark,  2 to1 ;			' (do,) plugin-of do,
 3249: 
 3250: \ alternative for if no ?do
 3251: \ : (do,)
 3252: \     compile 2dup compile = compile IF
 3253: \     compile 2drop compile ELSE
 3254: \     compile (do) branchtomark, 2 to1 ;
 3255:     
 3256: : (?do,) ( -- target-addr )
 3257:     0 compile (?do)  ?domark, (leave)
 3258:     branchtomark,  2 to1 ;			' (?do,) plugin-of ?do,
 3259: 
 3260: : (for,) ( -- target-addr )
 3261:   compile (for) branchtomark, ;			' (for,) plugin-of for,
 3262: 
 3263: : (loop,) ( target-addr -- )
 3264:   1to compile (loop)  loop] 
 3265:   compile unloop skiploop] ;			' (loop,) plugin-of loop,
 3266: 
 3267: : (+loop,) ( target-addr -- )
 3268:   1to compile (+loop)  loop] 
 3269:   compile unloop skiploop] ;			' (+loop,) plugin-of +loop,
 3270: 
 3271: : (-loop,) ( target-addr -- )
 3272:   1to compile (-loop)  loop] 
 3273:   compile unloop skiploop] ;			' (-loop,) plugin-of -loop,
 3274: 
 3275: : (next,) 
 3276:   compile (next)  loop] compile unloop ;	' (next,) plugin-of next,
 3277: 
 3278: Cond: DO      	do, ;Cond
 3279: Cond: ?DO     	?do, ;Cond
 3280: Cond: FOR	for, ;Cond
 3281: 
 3282: Cond: LOOP	1 ncontrols? loop, ;Cond
 3283: Cond: +LOOP	1 ncontrols? +loop, ;Cond
 3284: Cond: -LOOP	1 ncontrols? -loop, ;Cond
 3285: Cond: NEXT	1 ncontrols? next, ;Cond
 3286: 
 3287: \ String words                                         23feb93py
 3288: 
 3289: : ,"            [char] " parse ht-string, X align ;
 3290: 
 3291: X has? control-rack [IF]
 3292: Cond: ."        compile (.")     T ," H ;Cond
 3293: Cond: S"        compile (S")     T ," H ;Cond
 3294: Cond: C"        compile (C")     T ," H ;Cond
 3295: Cond: ABORT"    compile (ABORT") T ," H ;Cond
 3296: [ELSE]
 3297: Cond: ."        '" parse tuck 2>r ahead, there 2r> ht-mem, X align
 3298:                 >r then, r> compile ALiteral compile Literal compile type ;Cond
 3299: Cond: S"        '" parse tuck 2>r ahead, there 2r> ht-mem, X align
 3300:                 >r then, r> compile ALiteral compile Literal ;Cond
 3301: Cond: C"        ahead, there [char] " parse ht-string, X align
 3302:                 >r then, r> compile ALiteral ;Cond
 3303: Cond: ABORT"    if, ahead, there [char] " parse ht-string, X align
 3304:                 >r then, r> compile ALiteral compile c(abort") then, ;Cond
 3305: [THEN]
 3306: 
 3307: X has? rom [IF]
 3308: Cond: IS        cross-record-name T ' >body @ H compile ALiteral compile ! ;Cond
 3309: : IS            cross-record-name T >address ' >body @ ! H ;
 3310: Cond: TO        T ' >body @ H compile ALiteral compile ! ;Cond
 3311: : TO            T ' >body @ ! H ;
 3312: Cond: CTO       T ' >body H compile ALiteral compile ! ;Cond
 3313: : CTO           T ' >body ! H ;
 3314: [ELSE]
 3315: Cond: IS        cross-record-name T ' >body H compile ALiteral compile ! ;Cond
 3316: : IS            cross-record-name T >address ' >body ! H ;
 3317: Cond: TO        T ' >body H compile ALiteral compile ! ;Cond
 3318: : TO            T ' >body ! H ;
 3319: [THEN]
 3320: 
 3321: Cond: defers	T ' >body @ compile, H ;Cond
 3322: 
 3323: \ LINKED ERR" ENV" 2ENV"                                18may93jaw
 3324: 
 3325: \ linked list primitive
 3326: : linked        X here over X @ X A, swap X ! ;
 3327: : chained	T linked A, H ;
 3328: 
 3329: : err"   s" ErrLink linked" evaluate T , H
 3330:          [char] " parse ht-string, X align ;
 3331: 
 3332: : env"  [char] " parse s" EnvLink linked" evaluate
 3333:         ht-string, X align X , ;
 3334: 
 3335: : 2env" [char] " parse s" EnvLink linked" evaluate
 3336:         here >r ht-string, X align X , X ,
 3337:         r> dup T c@ H 80 and swap T c! H ;
 3338: 
 3339: \ compile must be last                                 22feb93py
 3340: 
 3341: Cond: [compile] ( -- ) \ name
 3342: \g For immediate words, works even if forward reference
 3343:       bl word gfind 0= ABORT" CROSS: Can't compile"
 3344:       (gexecute) ;Cond
 3345: 	   
 3346: Cond: postpone ( -- ) \ name
 3347:       bl word gfind 0= ABORT" CROSS: Can't compile"
 3348:       dup >magic @ <fwd> =
 3349:       ABORT" CROSS: Can't postpone on forward declaration"
 3350:       dup >magic @ <imm> =
 3351:       IF   (gexecute)
 3352:       ELSE >link @ alit, compile compile,  THEN ;Cond
 3353: 	   
 3354: \ save-cross                                           17mar93py
 3355: 
 3356: hex
 3357: 
 3358: >CROSS
 3359: Create magic  s" Gforth4x" here over allot swap move
 3360: 
 3361: bigendian 1+ \ strangely, in magic big=0, little=1
 3362: tcell 1 = 0 and or
 3363: tcell 2 = 2 and or
 3364: tcell 4 = 4 and or
 3365: tcell 8 = 6 and or
 3366: tchar 1 = 00 and or
 3367: tchar 2 = 28 and or
 3368: tchar 4 = 50 and or
 3369: tchar 8 = 78 and or
 3370: magic 7 + c!
 3371: 
 3372: : save-cross ( "image-name" "binary-name" -- )
 3373:   .regions \  s" ec" X $has? IF  .regions  THEN
 3374:   bl parse ." Saving to " 2dup type cr
 3375:   w/o bin create-file throw >r
 3376:   s" header" X $has? IF
 3377:       s" #! "           r@ write-file throw
 3378:       bl parse          r@ write-file throw
 3379:       s"  --image-file" r@ write-file throw
 3380:       #lf       r@ emit-file throw
 3381:       r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
 3382:       ?do
 3383: 	  bl over emit-file throw
 3384:       loop
 3385:       drop
 3386:       magic 8       r@ write-file throw \ write magic
 3387:   ELSE
 3388:       bl parse 2drop
 3389:   THEN
 3390:   >rom dictionary >rmem @ there
 3391:   s" rom" X $has? IF  dictionary >rstart @ -  THEN
 3392:   r@ write-file throw \ write image
 3393:   s" relocate" X $has? IF
 3394:       dictionary >rbm @ there 1- tcell>bit rshift 1+
 3395:                 r@ write-file throw \ write tags
 3396:   THEN
 3397:   r> close-file throw ;
 3398: 
 3399: : save-region ( addr len -- )
 3400:   bl parse w/o bin create-file throw >r
 3401:   swap >image swap r@ write-file throw
 3402:   r> close-file throw ;
 3403: 
 3404: \ save-asm-region                         		29aug01jaw
 3405: 
 3406: Variable name-ptr
 3407: Create name-buf 200 chars allot
 3408: : init-name-buf name-buf name-ptr ! ;
 3409: : nb, name-ptr @ c! 1 chars name-ptr +! ;
 3410: : $nb, ( adr len -- ) bounds ?DO I c@ nb, LOOP ;
 3411: : @nb name-ptr @ name-buf tuck - ;
 3412: 
 3413: \ stores a usefull string representation of the character
 3414: \ in the name buffer
 3415: : name-char, ( c -- )
 3416:   dup 'a 'z 1+ within IF nb, EXIT THEN
 3417:   dup 'A 'Z 1+ within IF $20 + nb, EXIT THEN
 3418:   dup '0 '9 1+ within IF nb, EXIT THEN
 3419:   CASE '+ OF s" _PLUS" $nb, ENDOF
 3420:        '- OF s" _MINUS" $nb, ENDOF
 3421:        '* OF s" _STAR" $nb, ENDOF
 3422:        '/ OF s" _SLASH" $nb, ENDOF
 3423:        '' OF s" _TICK" $nb, ENDOF
 3424:        '( OF s" _OPAREN" $nb, ENDOF
 3425:        ') OF s" _CPAREN" $nb, ENDOF
 3426:        '[ OF s" _OBRACKET" $nb, ENDOF
 3427:        '] OF s" _CBRACKET" $nb, ENDOF
 3428:        '! OF s" _STORE" $nb, ENDOF
 3429:        '@ OF s" _FETCH" $nb, ENDOF
 3430:        '> OF s" _GREATER" $nb, ENDOF
 3431:        '< OF s" _LESS" $nb, ENDOF
 3432:        '= OF s" _EQUAL" $nb, ENDOF
 3433:        '# OF s" _HASH" $nb, ENDOF
 3434:        '? OF s" _QUEST" $nb, ENDOF
 3435:        ': OF s" _COL" $nb, ENDOF
 3436:        '; OF s" _SEMICOL" $nb, ENDOF
 3437:        ', OF s" _COMMA" $nb, ENDOF
 3438:        '. OF s" _DOT" $nb, ENDOF
 3439:        '" OF s" _DQUOT" $nb, ENDOF
 3440:        dup 
 3441:        base @ >r hex s>d <# #s 'X hold '_ hold #> $nb, r> base !
 3442:   ENDCASE ;
 3443:  
 3444: : label-from-ghostname ( ghost -- addr len )
 3445:   dup >ghostname init-name-buf 'L nb, bounds 
 3446:   ?DO I c@ name-char, LOOP 
 3447:   \ we add the address to a name to make in unique
 3448:   \ because one name may appear more then once
 3449:   \ there are names (e.g. boot) that may be reference from other
 3450:   \ assembler source files, so we declare them as unique
 3451:   \ and don't add the address suffix
 3452:   dup >ghost-flags @ <unique> and 0= 
 3453:   IF   s" __" $nb, >link @ base @ >r hex 0 <# #s 'L hold #> r> base ! $nb, 
 3454:   ELSE drop 
 3455:   THEN
 3456:   @nb ;
 3457: 
 3458: \ FIXME why disabled?!
 3459: : label-from-ghostnameXX ( ghost -- addr len )
 3460: \ same as (label-from-ghostname) but caches generated names
 3461:   dup >asm-name @ ?dup IF nip count EXIT THEN
 3462:  \ dup >r (label-from-ghostname) 2dup
 3463:   align here >r string, align
 3464:   r> r> >asm-name ! ;
 3465: 
 3466: : primghostdiscover ( xt -- ghost true | xt false )
 3467:   dup 0= IF false EXIT THEN
 3468:   >r last-prim-ghost
 3469:   BEGIN @ dup
 3470:   WHILE dup >asm-dummyaddr @ r@ =
 3471:         IF rdrop true EXIT THEN
 3472:   REPEAT
 3473:   drop r> false ;
 3474: 
 3475: : gdiscover2 ( xt -- ghost true | xt false ) 
 3476:   dup taddr>region 0= IF false EXIT THEN
 3477:   dup (>regiontype) @ dup 0= IF drop false EXIT THEN
 3478:   addr-xt-ghost @ dup 0= IF drop false EXIT THEN
 3479:   nip true ;
 3480: \  dup >ghost-name @ IF nip true ELSE drop false THEN ;
 3481: 
 3482: \ generates a label name for the target address
 3483: : generate-label-name ( taddr -- addr len )
 3484:   gdiscover2
 3485:   IF dup >magic @ <do:> =
 3486:      IF >asm-name @ count EXIT THEN
 3487:      label-from-ghostname
 3488:   ELSE
 3489:      primghostdiscover
 3490:      IF   >asm-name @ count 
 3491:      ELSE base @ >r hex 0 <# #s 'L hold #> r> base !
 3492:      THEN
 3493:   THEN ;
 3494: 
 3495: Variable outfile-fd
 3496: 
 3497: : $out ( adr len -- ) outfile-fd @ write-file throw  ;
 3498: : nlout newline $out ;
 3499: : .ux ( n -- ) 
 3500:   base @ hex swap 0 <# #S #> $out base ! ;
 3501: 
 3502: : save-asm-region-part-aligned ( taddr len -- 'taddr 'len )
 3503:   dup cell/ 0 
 3504:   ?DO nlout s"    .word " $out over @relbit 
 3505:       IF   over X @ generate-label-name $out
 3506:       ELSE over X @ s" 0x0" $out .ux
 3507:       THEN
 3508:       tcell /string
 3509:   LOOP ;
 3510: 
 3511: : print-bytes ( taddr len n -- taddr' len' )
 3512:   over min dup 0> 
 3513:   IF   nlout s"    .byte " $out 0 
 3514:        ?DO  I 0> IF s" , " $out THEN
 3515:             over X c@ s" 0x0" $out .ux 1 /string 
 3516:        LOOP 
 3517:   THEN ;
 3518: 
 3519: : save-asm-region-part ( addr len -- )
 3520:   over dup X aligned swap - ?dup
 3521:   IF   print-bytes THEN
 3522:   save-asm-region-part-aligned
 3523:   dup dup X aligned swap - ?dup
 3524:   IF   2 pick @relbit ABORT" relocated field splitted"
 3525:        print-bytes
 3526:   THEN
 3527:   2drop ;
 3528: 
 3529: : print-label ( taddr -- )
 3530:   nlout generate-label-name $out s" :" $out ;
 3531: 
 3532: : snl-calc ( taddr taddr2 -- )
 3533:   tuck over - ;
 3534: 
 3535: : skip-nolables ( taddr -- taddr2 taddr len )
 3536: \G skips memory region where no lables are defined
 3537: \G starting from taddr+1
 3538: \G Labels will be introduced for each reference mark
 3539: \G in addr-refs.
 3540: \G This word deals with lables at byte addresses as well.
 3541: \G The main idea is to have an intro part which
 3542: \G skips until the next cell boundary, the middle part
 3543: \G which skips whole cells very efficiently and the third
 3544: \G part which skips the bytes to the label in a cell
 3545:   dup 1+ dup (>regiontype) 
 3546:   ( S taddr taddr-realstart type-addr )
 3547:   dup @ dup IF addr-refs @ THEN
 3548:   swap >r
 3549:   over align+ tuck tcell swap - rshift swap 0
 3550:   ?DO dup 1 and 
 3551:      IF drop rdrop snl-calc UNLOOP EXIT THEN 
 3552:      2/ swap 1+ swap 
 3553:   LOOP
 3554:   drop r> cell+
 3555:   ( S .. taddr2 type-addr ) dup
 3556:   BEGIN dup @ dup IF addr-refs @ THEN 0= WHILE cell+ REPEAT
 3557:   dup >r swap - 1 cells / tcell * + r>
 3558:   ( S .. taddr2+skiplencells type-addr )
 3559:   @ addr-refs @ 1 tcell lshift or
 3560:   BEGIN dup 1 and 0= WHILE swap 1+ swap 2/ REPEAT drop
 3561:   ( S .. taddr2+skiplencells+skiplenbytes )
 3562:   snl-calc ;
 3563: 
 3564: : insert-label ( taddr -- )
 3565:   dup 0= IF drop EXIT THEN
 3566:   \ ignore everything which points outside our memory regions
 3567:   \ maybe a primitive pointer or whatever
 3568:   dup taddr>region 0= IF drop EXIT THEN
 3569:   dup >r (>regiontype) define-addr-struct addr-refs dup @ 
 3570:   r> tcell 1- and 1 swap lshift or swap ! ;
 3571: 
 3572: \ this generates a sorted list of addresses which must be labels
 3573: \ it scans therefore a whole region
 3574: : generate-label-list-region ( taddr len -- )
 3575:   BEGIN over @relbit IF over X @ insert-label THEN
 3576:         tcell /string dup 0< 
 3577:   UNTIL 2drop ;
 3578: 
 3579: : generate-label-list ( -- )
 3580:   region-link
 3581:   BEGIN @ dup WHILE 
 3582:         dup 0 >rlink - extent 
 3583:         ?dup IF generate-label-list-region ELSE drop THEN
 3584:   REPEAT drop ;
 3585: 
 3586: : create-outfile ( addr len -- )
 3587:   w/o bin create-file throw outfile-fd ! ;
 3588: 
 3589: : close-outfile ( -- )
 3590:   outfile-fd @ close-file throw ;
 3591: 
 3592: : (save-asm-region) ( region -- )
 3593:   \ ." label list..."
 3594:   generate-label-list
 3595:   \ ." ok!" cr
 3596:   extent ( S taddr len )
 3597:   over insert-label
 3598:   2dup + dup insert-label >r ( R end-label )
 3599:   ( S taddr len ) drop
 3600:   BEGIN
 3601:      dup print-label
 3602:      dup r@ <> WHILE
 3603:      skip-nolables save-asm-region-part
 3604:   REPEAT drop rdrop ;
 3605: 
 3606: : lineout ( addr len -- )
 3607:   outfile-fd @ write-line throw ;  
 3608: 
 3609: : save-asm-region ( region adr len -- )
 3610:   create-outfile (save-asm-region) close-outfile ;
 3611: 
 3612: \ \ minimal definitions
 3613: 	   
 3614: >MINIMAL also minimal
 3615: 
 3616: \ Usefull words                                        13feb93py
 3617: 
 3618: : KB  400 * ;
 3619: 
 3620: \ \ [IF] [ELSE] [THEN] ...				14sep97jaw
 3621: 
 3622: \ it is useful to define our own structures and not to rely
 3623: \ on the words in the host system
 3624: \ The words in the host system might be defined with vocabularies
 3625: \ this doesn't work with our self-made compile-loop
 3626: 
 3627: Create parsed 20 chars allot	\ store word we parsed
 3628: 
 3629: : upcase
 3630:     parsed count bounds
 3631:     ?DO I c@ toupper I c! LOOP ;
 3632: 
 3633: : [ELSE]
 3634:     1 BEGIN
 3635: 	BEGIN bl word count dup WHILE
 3636: 	    comment? 20 umin parsed place upcase parsed count
 3637: 	    2dup s" [IF]" str= >r 
 3638: 	    2dup s" [IFUNDEF]" str= >r
 3639: 	    2dup s" [IFDEF]" str= r> or r> or
 3640: 	    IF   2drop 1+
 3641: 	    ELSE 2dup s" [ELSE]" str=
 3642: 		IF   2drop 1- dup
 3643: 		    IF 1+
 3644: 		    THEN
 3645: 		ELSE
 3646: 		    2dup s" [ENDIF]" str= >r
 3647: 		    s" [THEN]" str= r> or
 3648: 		    IF 1- THEN
 3649: 		THEN
 3650: 	    THEN
 3651: 	    ?dup 0= ?EXIT
 3652: 	REPEAT
 3653: 	2drop refill 0=
 3654:     UNTIL drop ; immediate
 3655:   
 3656: : [THEN] ( -- ) ; immediate
 3657: 
 3658: : [ENDIF] ( -- ) ; immediate
 3659: 
 3660: : [IF] ( flag -- )
 3661:     0= IF postpone [ELSE] THEN ; immediate 
 3662: 
 3663: Cond: [IF]      postpone [IF] ;Cond
 3664: Cond: [THEN]    postpone [THEN] ;Cond
 3665: Cond: [ELSE]    postpone [ELSE] ;Cond
 3666: 
 3667: \ define new [IFDEF] and [IFUNDEF]                      20may93jaw
 3668: 
 3669: : defined? tdefined? ;
 3670: : needed? needed? ;
 3671: : doer? doer? ;
 3672: 
 3673: \ we want to use IFDEF on compiler directives (e.g. E?) in the source, too
 3674: 
 3675: : directive? 
 3676:   bl word count [ ' target >wordlist ] literal search-wordlist 
 3677:   dup IF nip THEN ;
 3678: 
 3679: : [IFDEF]  >in @ directive? swap >in !
 3680: 	   0= IF tdefined? ELSE name 2drop true THEN
 3681: 	   postpone [IF] ;
 3682: 
 3683: : [IFUNDEF] tdefined? 0= postpone [IF] ;
 3684: 
 3685: Cond: [IFDEF]   postpone [IFDEF] ;Cond
 3686: 
 3687: Cond: [IFUNDEF] postpone [IFUNDEF] ;Cond
 3688: 
 3689: \ C: \- \+ Conditional Compiling                         09jun93jaw
 3690: 
 3691: : C: >in @ tdefined? 0=
 3692:      IF    >in ! X :
 3693:      ELSE drop
 3694:         BEGIN bl word dup c@
 3695:               IF   count comment? s" ;" str= ?EXIT
 3696:               ELSE refill 0= ABORT" CROSS: Out of Input while C:"
 3697:               THEN
 3698:         AGAIN
 3699:      THEN ;
 3700: 
 3701: : d? d? ;
 3702: 
 3703: : \D ( -- "debugswitch" ) 
 3704: \G doesn't skip line when debug switch is on
 3705:     D? 0= IF postpone \ THEN ;
 3706: 
 3707: : \- ( -- "wordname" )
 3708: \G interprets the line if word is not defined
 3709:    tdefined? IF postpone \ THEN ;
 3710: 
 3711: : \+ ( -- "wordname" )
 3712: \G interprets the line if word is defined
 3713:    tdefined? 0= IF postpone \ THEN ;
 3714: 
 3715: : \? ( -- "envorinstring" )
 3716: \G Skip line if environmental variable evaluates to false
 3717:    X has? 0= IF postpone \ THEN ;
 3718: 
 3719: Cond: \- \- ;Cond
 3720: Cond: \+ \+ ;Cond
 3721: Cond: \D \D ;Cond
 3722: Cond: \? \? ;Cond
 3723: 
 3724: : ?? bl word find IF execute ELSE drop 0 THEN ;
 3725: 
 3726: : needed:
 3727: \G defines ghost for words that we want to be compiled
 3728:   BEGIN >in @ bl word c@ WHILE >in ! Ghost drop REPEAT drop ;
 3729: 
 3730: \ words that should be in minimal
 3731: 
 3732: create s-buffer 50 chars allot
 3733: 
 3734: bigendian Constant bigendian
 3735: 
 3736: : here there ;
 3737: : equ constant ;
 3738: : mark there constant ;
 3739: 
 3740: \ compiler directives
 3741: : >ram >ram ;
 3742: : >rom >rom ;
 3743: : >auto >auto ;
 3744: : >tempdp >tempdp ;
 3745: : tempdp> tempdp> ;
 3746: : const constflag on ;
 3747: 
 3748: : Redefinitions-start
 3749: \G Starts a redefinition section. Warnings are disabled and
 3750: \G existing ghosts are reused. This is used in the kernel
 3751: \G where ( and \ and the like are redefined
 3752:   twarnings off warnings off reuse-ghosts on ;
 3753: 
 3754: : Redefinitions-end
 3755: \G Ends a redefinition section. Warnings are enabled again.
 3756:   twarnings on warnings on reuse-ghosts off ;
 3757: 
 3758: : warnings name 3 = 
 3759:   IF twarnings off warnings off ELSE twarnings on warnings on THEN drop ;
 3760: 
 3761: : | ;
 3762: \ : | NoHeaderFlag on ; \ This is broken (damages the last word)
 3763: 
 3764: : save-cross save-cross ;
 3765: : save-region save-region ;
 3766: : tdump swap >image swap dump ;
 3767: 
 3768: also forth 
 3769: [IFDEF] Label           : Label defempty? Label ; [THEN] 
 3770: [IFDEF] start-macros    : start-macros defempty? start-macros ; [THEN]
 3771: \ [IFDEF] builttag	: builttag builttag ;	[THEN]
 3772: previous
 3773: 
 3774: : s" [char] " parse s-buffer place s-buffer count ; \ for environment?
 3775: : + + ;
 3776: : 1+ 1 + ;
 3777: : 2+ 2 + ;
 3778: : 1- 1- ;
 3779: : - - ;
 3780: : and and ;
 3781: : or or ;
 3782: : 2* 2* ;
 3783: : * * ;
 3784: : / / ;
 3785: : dup dup ;
 3786: : ?dup ?dup ;
 3787: : over over ;
 3788: : swap swap ;
 3789: : rot rot ;
 3790: : drop drop ;
 3791: : 2drop 2drop ;
 3792: : =   = ;
 3793: : <>  <> ;
 3794: : 0=   0= ;
 3795: : lshift lshift ;
 3796: : 2/ 2/ ;
 3797: : hex. base @ $10 base ! swap . base ! ;
 3798: : invert invert ;
 3799: : linkstring ( addr u n addr -- )
 3800:     X here over X @ X , swap X ! X , ht-string, X align ;
 3801: \ : . . ;
 3802: 
 3803: : all-words    ['] forced?    IS skip? ;
 3804: : needed-words ['] needed?  IS skip? ;
 3805: : undef-words  ['] defined2? IS skip? ;
 3806: : skipdef skipdef ;
 3807: 
 3808: : \  postpone \ ;  immediate
 3809: : \G T-\G ; immediate
 3810: : (  postpone ( ;  immediate
 3811: : include bl word count included ;
 3812: : included swap >image swap included ;
 3813: : require require ;
 3814: : needs require ;
 3815: : .( [char] ) parse type ;
 3816: : ERROR" [char] " parse 
 3817:   rot 
 3818:   IF cr ." *** " type ."  ***" -1 ABORT" CROSS: Target error, see text above" 
 3819:   ELSE 2drop 
 3820:   THEN ;
 3821: : ." [char] " parse type ;
 3822: : cr cr ;
 3823: 
 3824: : times 0 ?DO dup X c, LOOP drop ; \ used for space table creation
 3825: 
 3826: \ only forth also cross also minimal definitions order
 3827: 
 3828: \ cross-compiler words
 3829: 
 3830: : decimal       decimal [g'] decimal >exec2 @ ?dup IF EXECUTE THEN ;
 3831: : hex           hex [g'] hex >exec2 @ ?dup IF EXECUTE THEN ;
 3832: 
 3833: \ : tudp          X tudp ;
 3834: \ : tup           X tup ;
 3835: 
 3836: : doc-off       false to-doc ! ;
 3837: : doc-on        true  to-doc ! ;
 3838: 
 3839: : declareunique ( "name" -- )
 3840: \ Sets the unique flag for a ghost. The assembler output
 3841: \ generates labels with the ghostname concatenated with the address
 3842: \ while cross-compiling. The address is concatenated
 3843: \ because we have double occurences of the same name.
 3844: \ If we want to reference the labels from the assembler or C
 3845: \ code we declare them unique, so the address is skipped.
 3846:   Ghost >ghost-flags dup @ <unique> or swap ! ;
 3847: 
 3848: \ [IFDEF] dbg : dbg dbg ; [THEN]
 3849: 
 3850: \ for debugging...
 3851: \ : dbg dbg ;
 3852: : horder         order ;
 3853: : hwords        words ;
 3854: \ : words 	also ghosts 
 3855: \                words previous ;
 3856: : .s            .s ;
 3857: : depth         depth ;
 3858: : bye           bye ;
 3859: 
 3860: \ dummy
 3861: 
 3862: \ turnkey direction
 3863: : H forth ; immediate
 3864: : T minimal ; immediate
 3865: : G ghosts ; immediate
 3866: 
 3867: 
 3868: \ these ones are pefered:
 3869: 
 3870: : unlock previous forth also cross ;
 3871: 
 3872: \ also minimal
 3873: >cross
 3874: 
 3875: : turnkey 
 3876:    ghosts-wordlist 1 set-order
 3877:    also target definitions
 3878:    also Minimal also ;
 3879: 
 3880: >minimal
 3881: 
 3882: : [[+++
 3883:   turnkey unlock ;
 3884: 
 3885: unlock definitions also minimal
 3886: 
 3887: : lock   turnkey ;
 3888: 
 3889: Defer +++]]-hook
 3890: : +++]] +++]]-hook lock ;
 3891: 
 3892: LOCK
 3893: \ load cross compiler extension defined in mach file
 3894: 
 3895: UNLOCK >CROSS
 3896: 
 3897: [IFDEF] extend-cross extend-cross [THEN]
 3898: 
 3899: LOCK

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>