File:  [gforth] / gforth / cross.fs
Revision 1.110: download - view: text, annotated - select for diffs
Wed Sep 5 14:25:48 2001 UTC (18 years, 2 months ago) by jwilke
Branches: MAIN
CVS tags: HEAD
cleaned up
EC stuff currently broken

    1: \ CROSS.FS     The Cross-Compiler                      06oct92py
    2: \ Idea and implementation: Bernd Paysan (py)
    3: 
    4: \ Copyright (C) 1995,1996,1997,1998,1999,2000 Free Software Foundation, Inc.
    5: 
    6: \ This file is part of Gforth.
    7: 
    8: \ Gforth is free software; you can redistribute it and/or
    9: \ modify it under the terms of the GNU General Public License
   10: \ as published by the Free Software Foundation; either version 2
   11: \ of the License, or (at your option) any later version.
   12: 
   13: \ This program is distributed in the hope that it will be useful,
   14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   16: \ GNU General Public License for more details.
   17: 
   18: \ You should have received a copy of the GNU General Public License
   19: \ along with this program; if not, write to the Free Software
   20: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   21: 
   22: 0 
   23: [IF]
   24: 
   25: ToDo:
   26: - Crossdoc destination ./doc/crossdoc.fd makes no sense when
   27:   cross.fs is used seperately. jaw
   28: - Do we need this char translation with >address and in branchoffset? 
   29:   (>body also affected) jaw
   30: - MAXU etc. can be done with dlit,
   31: 
   32: [THEN]
   33: 
   34: hex
   35: 
   36: \ debugging for compiling
   37: 
   38: \ print stack at each colon definition
   39: \ : : save-input cr bl word count type restore-input throw .s : ;
   40: 
   41: \ print stack at each created word
   42: \ : create save-input cr bl word count type restore-input throw .s create ;
   43: 
   44: 
   45: \ \ -------------  Setup Vocabularies
   46: 
   47: \ Remark: Vocabulary is not ANS, but it should work...
   48: 
   49: Vocabulary Cross
   50: Vocabulary Target
   51: Vocabulary Ghosts
   52: Vocabulary Minimal
   53: only Forth also Target also also
   54: definitions Forth
   55: 
   56: : T  previous Ghosts also Target ; immediate
   57: : G  Ghosts ; immediate
   58: : H  previous Forth also Cross ; immediate
   59: 
   60: forth definitions
   61: 
   62: : T  previous Ghosts also Target ; immediate
   63: : G  Ghosts ; immediate
   64: 
   65: 
   66: : >cross  also Cross definitions previous ;
   67: : >target also Target definitions previous ;
   68: : >minimal also Minimal definitions previous ;
   69: 
   70: H
   71: 
   72: >CROSS
   73: 
   74: \ find out whether we are compiling with gforth
   75: 
   76: : defined? bl word find nip ;
   77: defined? emit-file defined? toupper and \ drop 0
   78: [IF]
   79: \ use this in a gforth system
   80: : \GFORTH ; immediate
   81: : \ANSI postpone \ ; immediate
   82: [ELSE]
   83: : \GFORTH postpone \ ; immediate
   84: : \ANSI ; immediate
   85: [THEN]
   86: 
   87: \ANSI : [IFUNDEF] defined? 0= postpone [IF] ; immediate
   88: \ANSI : [IFDEF] defined? postpone [IF] ; immediate
   89: 0 \ANSI drop 1
   90: [IF]
   91: : \G postpone \ ; immediate
   92: : rdrop postpone r> postpone drop ; immediate
   93: : name bl word count ;
   94: : bounds over + swap ;
   95: : scan >r BEGIN dup WHILE over c@ r@ <> WHILE 1 /string REPEAT THEN rdrop ;
   96: : linked here over @ , swap ! ;
   97: : alias create , DOES> @ EXECUTE ;
   98: : defer ['] noop alias ;
   99: : is state @ 
  100:   IF ' >body postpone literal postpone ! 
  101:   ELSE ' >body ! THEN ; immediate
  102: : 0>= 0< 0= ;
  103: : d<> rot <> -rot <> or ;
  104: : toupper dup [char] a [char] z 1+ within IF [char] A [char] a - + THEN ;
  105: Variable ebuf
  106: : emit-file ( c fd -- ior ) swap ebuf c! ebuf 1 chars rot write-file ;
  107: 0a Constant #lf
  108: 0d Constant #cr
  109: 
  110: [IFUNDEF] Warnings Variable Warnings [THEN]
  111: 
  112: \ \ Number parsing					23feb93py
  113: 
  114: \ number? number                                       23feb93py
  115: 
  116: Variable dpl
  117: 
  118: hex
  119: Create bases   10 ,   2 ,   A , 100 ,
  120: \              16     2    10   character
  121: 
  122: \ !! protect BASE saving wrapper against exceptions
  123: : getbase ( addr u -- addr' u' )
  124:     over c@ [char] $ - dup 4 u<
  125:     IF
  126: 	cells bases + @ base ! 1 /string
  127:     ELSE
  128: 	drop
  129:     THEN ;
  130: 
  131: : sign? ( addr u -- addr u flag )
  132:     over c@ [char] - =  dup >r
  133:     IF
  134: 	1 /string
  135:     THEN
  136:     r> ;
  137: 
  138: : s>unumber? ( addr u -- ud flag )
  139:     over [char] ' =
  140:     IF 	\ a ' alone is rather unusual :-)
  141: 	drop char+ c@ 0 true EXIT 
  142:     THEN
  143:     base @ >r  dpl on  getbase
  144:     0. 2swap
  145:     BEGIN ( d addr len )
  146: 	dup >r >number dup
  147:     WHILE \ there are characters left
  148: 	dup r> -
  149:     WHILE \ the last >number parsed something
  150: 	dup 1- dpl ! over c@ [char] . =
  151:     WHILE \ the current char is '.'
  152: 	1 /string
  153:     REPEAT  THEN \ there are unparseable characters left
  154: 	2drop false
  155:     ELSE
  156: 	rdrop 2drop true
  157:     THEN
  158:     r> base ! ;
  159: 
  160: \ ouch, this is complicated; there must be a simpler way - anton
  161: : s>number? ( addr len -- d f )
  162:     \ converts string addr len into d, flag indicates success
  163:     sign? >r
  164:     s>unumber?
  165:     0= IF
  166:         rdrop false
  167:     ELSE \ no characters left, all ok
  168: 	r>
  169: 	IF
  170: 	    dnegate
  171: 	THEN
  172: 	true
  173:     THEN ;
  174: 
  175: : s>number ( addr len -- d )
  176:     \ don't use this, there is no way to tell success
  177:     s>number? drop ;
  178: 
  179: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
  180:     s>number? 0=
  181:     IF
  182: 	2drop false  EXIT
  183:     THEN
  184:     dpl @ dup 0< IF
  185: 	nip
  186:     ELSE
  187: 	1+
  188:     THEN ;
  189: 
  190: : number? ( string -- string 0 / n -1 / d 0> )
  191:     dup >r count snumber? dup if
  192: 	rdrop
  193:     else
  194: 	r> swap
  195:     then ;
  196: 
  197: : number ( string -- d )
  198:     number? ?dup 0= abort" ?"  0<
  199:     IF
  200: 	s>d
  201:     THEN ;
  202: 
  203: [THEN]
  204: 
  205: hex     \ the defualt base for the cross-compiler is hex !!
  206: \ Warnings off
  207: 
  208: \ words that are generaly useful
  209: 
  210: : KB  400 * ;
  211: : >wordlist ( vocabulary-xt -- wordlist-struct )
  212:   also execute get-order swap >r 1- set-order r> ;
  213: 
  214: : umax 2dup u< IF swap THEN drop ;
  215: : umin 2dup u> IF swap THEN drop ;
  216: 
  217: : string, ( c-addr u -- )
  218:     \ puts down string as cstring
  219:     dup c, here swap chars dup allot move ;
  220: 
  221: : ," [char] " parse string, ;
  222: 
  223: : SetValue ( n -- <name> )
  224: \G Same behaviour as "Value" if the <name> is not defined
  225: \G Same behaviour as "to" if <name> is defined
  226: \G SetValue searches in the current vocabulary
  227:   save-input bl word >r restore-input throw r> count
  228:   get-current search-wordlist
  229:   IF	drop >r
  230: 	\ we have to set current to be topmost context wordlist
  231: 	get-order get-order get-current swap 1+ set-order
  232: 	r> ['] to execute
  233: 	set-order
  234:   ELSE Value THEN ;
  235: 
  236: : DefaultValue ( n -- <name> )
  237: \G Same behaviour as "Value" if the <name> is not defined
  238: \G DefaultValue searches in the current vocabulary
  239:  save-input bl word >r restore-input throw r> count
  240:  get-current search-wordlist
  241:  IF bl word drop 2drop ELSE Value THEN ;
  242: 
  243: hex
  244: 
  245: \ 1 Constant Cross-Flag	\ to check whether assembler compiler plug-ins are
  246: 			\ for cross-compiling
  247: \ No! we use "[IFUNDEF]" there to find out whether we are target compiling!!!
  248: 
  249: : comment? ( c-addr u -- c-addr u )
  250:         2dup s" (" compare 0=
  251:         IF    postpone (
  252:         ELSE  2dup s" \" compare 0= IF postpone \ THEN
  253:         THEN ;
  254: 
  255: : X 	bl word count [ ' target >wordlist ] Literal search-wordlist
  256: 	IF	state @ IF compile,
  257: 		ELSE execute THEN
  258: 	ELSE	-1 ABORT" Cross: access method not supported!"
  259: 	THEN ; immediate
  260: 
  261: \ Begin CROSS COMPILER:
  262: 
  263: \ debugging
  264: 
  265: 0 [IF]
  266: 
  267: This implements debugflags for the cross compiler and the compiled
  268: images. It works identical to the has-flags in the environment.
  269: The debugflags are defined in a vocabluary. If the word exists and
  270: its value is true, the flag is switched on.
  271: 
  272: [THEN]
  273: 
  274: >CROSS
  275: 
  276: Vocabulary debugflags	\ debug flags for cross
  277: also debugflags get-order over
  278: Constant debugflags-wl
  279: set-order previous
  280: 
  281: : DebugFlag
  282:   get-current >r debugflags-wl set-current
  283:   SetValue
  284:   r> set-current ;
  285: 
  286: : Debug? ( adr u -- flag )
  287: \G return true if debug flag is defined or switched on
  288:   debugflags-wl search-wordlist
  289:   IF EXECUTE
  290:   ELSE false THEN ;
  291: 
  292: : D? ( <name> -- flag )
  293: \G return true if debug flag is defined or switched on
  294: \G while compiling we do not return the current value but
  295:   bl word count debug? ;
  296: 
  297: : [d?]
  298: \G compile the value-xt so the debug flag can be switched
  299: \G the flag must exist!
  300:   bl word count debugflags-wl search-wordlist
  301:   IF 	compile,
  302:   ELSE  -1 ABORT" unknown debug flag"
  303: 	\ POSTPONE false 
  304:   THEN ; immediate
  305: 
  306: \ \ --------------------	source file
  307: 
  308: decimal
  309: 
  310: Variable cross-file-list
  311: 0 cross-file-list !
  312: Variable target-file-list
  313: 0 target-file-list !
  314: Variable host-file-list
  315: 0 host-file-list !
  316: 
  317: cross-file-list Value file-list
  318: 0 Value source-desc
  319: 
  320: \ file loading
  321: 
  322: : >fl-id   1 cells + ;
  323: : >fl-name 2 cells + ;
  324: 
  325: Variable filelist 0 filelist !
  326: Create NoFile ," #load-file#"
  327: 
  328: : loadfile ( -- adr )
  329:   source-desc ?dup IF >fl-name ELSE NoFile THEN ;
  330: 
  331: : sourcefilename ( -- adr len ) 
  332:   loadfile count ;
  333: 
  334: \ANSI : sourceline# 0 ;
  335: 
  336: \ \ --------------------	path handling from kernel/paths.fs
  337: 
  338: \ paths.fs path file handling                                    03may97jaw
  339: 
  340: \ -Changing the search-path:
  341: \ fpath+ <path> 	adds a directory to the searchpath
  342: \ fpath= <path>|<path>	makes complete now searchpath
  343: \ 			seperator is |
  344: \ .fpath		displays the search path
  345: \ remark I: 
  346: \ a ./ in the beginning of filename is expanded to the directory the
  347: \ current file comes from. ./ can also be included in the search-path!
  348: \ ~+/ loads from the current working directory
  349: 
  350: \ remark II:
  351: \ if there is no sufficient space for the search path increase it!
  352: 
  353: 
  354: \ -Creating custom paths:
  355: 
  356: \ It is possible to use the search mechanism on yourself.
  357: 
  358: \ Make a buffer for the path:
  359: \ create mypath	100 chars , 	\ maximum length (is checked)
  360: \ 		0 ,		\ real len
  361: \ 		100 chars allot \ space for path
  362: \ use the same functions as above with:
  363: \ mypath path+ 
  364: \ mypath path=
  365: \ mypath .path
  366: 
  367: \ do a open with the search path:
  368: \ open-path-file ( adr len path -- fd adr len ior )
  369: \ the file is opened read-only; if the file is not found an error is generated
  370: 
  371: \ questions to: wilke@jwdt.com
  372: 
  373: [IFUNDEF] +place
  374: : +place ( adr len adr )
  375:         2dup >r >r
  376:         dup c@ char+ + swap move
  377:         r> r> dup c@ rot + swap c! ;
  378: [THEN]
  379: 
  380: [IFUNDEF] place
  381: : place ( c-addr1 u c-addr2 )
  382:         2dup c! char+ swap move ;
  383: [THEN]
  384: 
  385: \ if we have path handling, use this and the setup of it
  386: [IFUNDEF] open-fpath-file
  387: 
  388: create sourcepath 1024 chars , 0 , 1024 chars allot \ !! make this dynamic
  389: sourcepath value fpath
  390: 
  391: : also-path ( adr len path^ -- )
  392:   >r
  393:   \ len check
  394:   r@ cell+ @ over + r@ @ u> ABORT" path buffer too small!"
  395:   \ copy into
  396:   tuck r@ cell+ dup @ cell+ + swap cmove
  397:   \ make delimiter
  398:   0 r@ cell+ dup @ cell+ + 2 pick + c! 1 + r> cell+ +!
  399:   ;
  400: 
  401: : only-path ( adr len path^ -- )
  402:   dup 0 swap cell+ ! also-path ;
  403: 
  404: : path+ ( path-addr  "dir" -- ) \ gforth
  405:     \G Add the directory @var{dir} to the search path @var{path-addr}.
  406:     name rot also-path ;
  407: 
  408: : fpath+ ( "dir" ) \ gforth
  409:     \G Add directory @var{dir} to the Forth search path.
  410:     fpath path+ ;
  411: 
  412: : path= ( path-addr "dir1|dir2|dir3" ) \ gforth
  413:     \G Make a complete new search path; the path separator is |.
  414:     name 2dup bounds ?DO i c@ [char] | = IF 0 i c! THEN LOOP
  415:     rot only-path ;
  416: 
  417: : fpath= ( "dir1|dir2|dir3" ) \ gforth
  418:     \G Make a complete new Forth search path; the path separator is |.
  419:     fpath path= ;
  420: 
  421: : path>counted  cell+ dup cell+ swap @ ;
  422: 
  423: : next-path ( adr len -- adr2 len2 )
  424:   2dup 0 scan
  425:   dup 0= IF     2drop 0 -rot 0 -rot EXIT THEN
  426:   >r 1+ -rot r@ 1- -rot
  427:   r> - ;
  428: 
  429: : previous-path ( path^ -- )
  430:   dup path>counted
  431:   BEGIN tuck dup WHILE repeat ;
  432: 
  433: : .path ( path-addr -- ) \ gforth
  434:     \G Display the contents of the search path @var{path-addr}.
  435:     path>counted
  436:     BEGIN next-path dup WHILE type space REPEAT 2drop 2drop ;
  437: 
  438: : .fpath ( -- ) \ gforth
  439:     \G Display the contents of the Forth search path.
  440:     fpath .path ;
  441: 
  442: : absolut-path? ( addr u -- flag ) \ gforth
  443:     \G A path is absolute if it starts with a / or a ~ (~ expansion),
  444:     \G or if it is in the form ./*, extended regexp: ^[/~]|./, or if
  445:     \G it has a colon as second character ("C:...").  Paths simply
  446:     \G containing a / are not absolute!
  447:     2dup 2 u> swap 1+ c@ [char] : = and >r \ dos absoulte: c:/....
  448:     over c@ [char] / = >r
  449:     over c@ [char] ~ = >r
  450:     \ 2dup 3 min S" ../" compare 0= r> or >r \ not catered for in expandtopic
  451:     2 min S" ./" compare 0=
  452:     r> r> r> or or or ;
  453: 
  454: Create ofile 0 c, 255 chars allot
  455: Create tfile 0 c, 255 chars allot
  456: 
  457: : pathsep? dup [char] / = swap [char] \ = or ;
  458: 
  459: : need/   ofile dup c@ + c@ pathsep? 0= IF s" /" ofile +place THEN ;
  460: 
  461: : extractpath ( adr len -- adr len2 )
  462:   BEGIN dup WHILE 1-
  463:         2dup + c@ pathsep? IF EXIT THEN
  464:   REPEAT ;
  465: 
  466: : remove~+ ( -- )
  467:     ofile count 3 min s" ~+/" compare 0=
  468:     IF
  469: 	ofile count 3 /string ofile place
  470:     THEN ;
  471: 
  472: : expandtopic ( -- ) \ stack effect correct? - anton
  473:     \ expands "./" into an absolute name
  474:     ofile count 2 min s" ./" compare 0=
  475:     IF
  476: 	ofile count 1 /string tfile place
  477: 	0 ofile c! sourcefilename extractpath ofile place
  478: 	ofile c@ IF need/ THEN
  479: 	tfile count over c@ pathsep? IF 1 /string THEN
  480: 	ofile +place
  481:     THEN ;
  482: 
  483: : compact.. ( adr len -- adr2 len2 )
  484:     \ deletes phrases like "xy/.." out of our directory name 2dec97jaw
  485:     over swap
  486:     BEGIN  dup  WHILE
  487:         dup >r '/ scan 2dup 4 min s" /../" compare 0=
  488:         IF
  489:             dup r> - >r 4 /string over r> + 4 -
  490:             swap 2dup + >r move dup r> over -
  491:         ELSE
  492:             rdrop dup 1 min /string
  493:         THEN
  494:     REPEAT  drop over - ;
  495: 
  496: : reworkdir ( -- )
  497:   remove~+
  498:   ofile count compact..
  499:   nip ofile c! ;
  500: 
  501: : open-ofile ( -- fid ior )
  502:     \G opens the file whose name is in ofile
  503:     expandtopic reworkdir
  504:     ofile count r/o open-file ;
  505: 
  506: : check-path ( adr1 len1 adr2 len2 -- fd 0 | 0 <>0 )
  507:   0 ofile ! >r >r ofile place need/
  508:   r> r> ofile +place
  509:   open-ofile ;
  510: 
  511: : open-path-file ( addr1 u1 path-addr -- wfileid addr2 u2 0 | ior ) \ gforth
  512:     \G Look in path @var{path-addr} for the file specified by @var{addr1 u1}.
  513:     \G If found, the resulting path and an open file descriptor
  514:     \G are returned. If the file is not found, @var{ior} is non-zero.
  515:   >r
  516:   2dup absolut-path?
  517:   IF    rdrop
  518:         ofile place open-ofile
  519: 	dup 0= IF >r ofile count r> THEN EXIT
  520:   ELSE  r> path>counted
  521:         BEGIN  next-path dup
  522:         WHILE  5 pick 5 pick check-path
  523:         0= IF >r 2drop 2drop r> ofile count 0 EXIT ELSE drop THEN
  524:   REPEAT
  525:         2drop 2drop 2drop -38
  526:   THEN ;
  527: 
  528: : open-fpath-file ( addr1 u1 -- wfileid addr2 u2 0 | ior ) \ gforth
  529:     \G Look in the Forth search path for the file specified by @var{addr1 u1}.
  530:     \G If found, the resulting path and an open file descriptor
  531:     \G are returned. If the file is not found, @var{ior} is non-zero.
  532:     fpath open-path-file ;
  533: 
  534: fpath= ~+
  535: 
  536: [THEN]
  537: 
  538: \ \ --------------------	include require			13may99jaw
  539: 
  540: >CROSS
  541: 
  542: : add-included-file ( adr len -- adr )
  543:   dup >fl-name char+ allocate throw >r
  544:   file-list @ r@ ! r@ file-list !
  545:   r@ >fl-name place r> ;
  546: 
  547: : included? ( c-addr u -- f )
  548:   file-list
  549:   BEGIN	@ dup
  550:   WHILE	>r 2dup r@ >fl-name count compare 0=
  551: 	IF rdrop 2drop true EXIT THEN
  552: 	r>
  553:   REPEAT
  554:   2drop drop false ;	
  555: 
  556: false DebugFlag showincludedfiles
  557: 
  558: : included1 ( fd adr u -- )
  559: \ include file adr u / fd
  560: \ we don't use fd with include-file, because the forth system
  561: \ doesn't know the name of the file to get a nice error report
  562:   [d?] showincludedfiles
  563:   IF	cr ." Including: " 2dup type ." ..." THEN
  564:   rot close-file throw
  565:   source-desc >r
  566:   add-included-file to source-desc 
  567:   sourcefilename
  568:   ['] included catch
  569:   r> to source-desc 
  570:   throw ;
  571: 
  572: : included ( adr len -- )
  573: 	cross-file-list to file-list
  574: 	open-fpath-file throw 
  575:         included1 ;
  576: 
  577: : required ( adr len -- )
  578: 	cross-file-list to file-list
  579: 	open-fpath-file throw \ 2dup cr ." R:" type
  580: 	2dup included?
  581: 	IF 	2drop close-file throw
  582: 	ELSE	included1
  583: 	THEN ;
  584: 
  585: : include bl word count included ;
  586: 
  587: : require bl word count required ;
  588: 
  589: 0 [IF]
  590: 
  591: also forth definitions previous
  592: 
  593: : included ( adr len -- ) included ;
  594: 
  595: : required ( adr len -- ) required ;
  596: 
  597: : include include ;
  598: 
  599: : require require ;
  600: 
  601: [THEN]
  602: 
  603: >CROSS
  604: hex
  605: 
  606: \ \ --------------------        Error Handling                  05aug97jaw
  607: 
  608: \ Flags
  609: 
  610: also forth definitions  \ these values may be predefined before
  611:                         \ the cross-compiler is loaded
  612: 
  613: false DefaultValue stack-warn   	 \ check on empty stack at any definition
  614: false DefaultValue create-forward-warn   \ warn on forward declaration of created words
  615: 
  616: previous >CROSS
  617: 
  618: : .dec
  619:   base @ decimal swap . base ! ;
  620: 
  621: : .sourcepos
  622:   cr sourcefilename type ." :"
  623:   sourceline# .dec ;
  624: 
  625: : warnhead
  626: \G display error-message head
  627: \G perhaps with linenumber and filename
  628:   .sourcepos ." Warning: " ;
  629: 
  630: : empty? depth IF .sourcepos ." Stack not empty!"  THEN ;
  631: 
  632: stack-warn [IF]
  633: : defempty? empty? ;
  634: [ELSE]
  635: : defempty? ; immediate
  636: [THEN]
  637: 
  638: \ \ --------------------        Compiler Plug Ins               01aug97jaw
  639: 
  640: >CROSS
  641: 
  642: \ Compiler States
  643: 
  644: Variable comp-state
  645: 0 Constant interpreting
  646: 1 Constant compiling
  647: 2 Constant resolving
  648: 3 Constant assembling
  649: 
  650: : compiling? comp-state @ compiling = ;
  651: 
  652: : pi-undefined -1 ABORT" Plugin undefined" ;
  653: 
  654: : Plugin ( -- : pluginname )
  655:   Create 
  656:   \ for normal cross-compiling only one action
  657:   \ exists, this fields are identical. For the instant
  658:   \ simulation environment we need, two actions for each plugin
  659:   \ the target one and the one that generates the simulation code
  660:   ['] pi-undefined , \ action
  661:   ['] pi-undefined , \ target plugin action
  662:   8765 ,     \ plugin magic
  663:   DOES> perform ;
  664: 
  665: Plugin DummyPlugin
  666: 
  667: : 'PI ( -- addr : pluginname )
  668:   ' >body dup 2 cells + @ 8765 <> ABORT" not a plugin" ;
  669: 
  670: : plugin-of ( xt -- : pluginname )
  671:   dup 'PI 2! ;
  672: 
  673: : action-of ( xt -- : plunginname )
  674:   'PI cell+ ! ;
  675: 
  676: : TPA ( -- : plugin )
  677: \ target plugin action
  678: \ executes current target action of plugin
  679:   'PI cell+ POSTPONE literal POSTPONE perform ; immediate
  680: 
  681: Variable ppi-temp 0 ppi-temp !
  682: 
  683: : pa:
  684: \g define plugin action
  685:   ppi-temp @ ABORT" pa: definition not closed"
  686:   'PI ppi-temp ! :noname ;
  687: 
  688: : ;pa
  689: \g end a definition for plugin action
  690:   POSTPONE ; ppi-temp @ ! 0 ppi-temp ! ; immediate
  691: 
  692: 
  693: Plugin dlit, ( d -- )			\ compile numerical value the target
  694: Plugin lit, ( n -- )
  695: Plugin alit, ( n -- )
  696: 
  697: Plugin branch, ( target-addr -- )	\ compiles a branch
  698: Plugin ?branch, ( target-addr -- )	\ compiles a ?branch
  699: Plugin branchmark, ( -- branch-addr )	\ reserves room for a branch
  700: Plugin ?branchmark, ( -- branch-addr )	\ reserves room for a ?branch
  701: Plugin ?domark, ( -- branch-addr )	\ reserves room for a ?do branch
  702: Plugin branchto, ( -- )			\ actual program position is target of a branch (do e.g. alignment)
  703: ' NOOP plugin-of branchto, 
  704: Plugin branchtoresolve, ( branch-addr -- ) \ resolves a forward reference from branchmark
  705: Plugin branchtomark, ( -- target-addr )	\ marks a branch destination
  706: 
  707: Plugin colon, ( tcfa -- )		\ compiles call to tcfa at current position
  708: Plugin prim, ( tcfa -- )		\ compiles primitive invocation
  709: Plugin colonmark, ( -- addr )		\ marks a colon call
  710: Plugin colon-resolve ( tcfa addr -- )
  711: 
  712: Plugin addr-resolve ( target-addr addr -- )
  713: Plugin doer-resolve ( ghost res-pnt target-addr addr -- ghost res-pnt )
  714: 
  715: Plugin ncontrols? ( [ xn ... x1 ] n -- ) \ checks wheter n control structures are open
  716: Plugin if, 	( -- if-token )
  717: Plugin else,	( if-token -- if-token )
  718: Plugin then,	( if-token -- )
  719: Plugin ahead,
  720: Plugin begin,
  721: Plugin while,
  722: Plugin until,
  723: Plugin again,
  724: Plugin repeat,
  725: Plugin cs-swap	( x1 x2 -- x2 x1 )
  726: 
  727: Plugin case,	( -- n )
  728: Plugin of,	( n -- x1 n )
  729: Plugin endof,	( x1 n -- x2 n )
  730: Plugin endcase,	( x1 .. xn n -- )
  731: 
  732: Plugin do,	( -- do-token )
  733: Plugin ?do,	( -- ?do-token )
  734: Plugin for,	( -- for-token )
  735: Plugin loop,	( do-token / ?do-token -- )
  736: Plugin +loop,	( do-token / ?do-token -- )
  737: Plugin next,	( for-token )
  738: Plugin leave,	( -- )
  739: Plugin ?leave, 	( -- )
  740: 
  741: [IFUNDEF] ca>native
  742: Plugin ca>native	
  743: [THEN]
  744: 
  745: Plugin doprim,	\ compiles start of a primitive
  746: Plugin docol,   	\ compiles start of a colon definition
  747: Plugin doer,		
  748: Plugin fini,      \ compiles end of definition ;s
  749: Plugin doeshandler,
  750: Plugin dodoes,
  751: 
  752: Plugin colon-start
  753: ' noop plugin-of colon-start
  754: Plugin colon-end
  755: ' noop plugin-of colon-end
  756: 
  757: Plugin ]comp     \ starts compilation
  758: ' noop plugin-of ]comp
  759: Plugin comp[     \ ends compilation
  760: ' noop plugin-of comp[
  761: 
  762: Plugin t>body             \ we need the system >body
  763: 			\ and the target >body
  764: 
  765: >TARGET
  766: : >body t>body ;
  767: 
  768: 
  769: \ Ghost Builder                                        06oct92py
  770: 
  771: >CROSS
  772: hex
  773: \ Values for ghost magic
  774: 4711 Constant <fwd>             4712 Constant <res>
  775: 4713 Constant <imm>             4714 Constant <do:>
  776: 4715 Constant <skip>
  777: 
  778: \ Bitmask for ghost flags
  779: 1 Constant <unique>
  780: 2 Constant <primitive>
  781: 
  782: \ FXIME: move this to general stuff?
  783: : set-flag ( addr flag -- )
  784:   over @ or swap ! ;
  785: 
  786: : reset-flag ( addr flag -- )
  787:   invert over @ and swap ! ;
  788: 
  789: : get-flag ( addr flag -- f )
  790:   swap @ and 0<> ;
  791:   
  792: 
  793: Struct
  794: 
  795:   \ link to next ghost (always the first element)
  796:   cell% field >next-ghost
  797: 
  798:   \ type of ghost
  799:   cell% field >magic
  800: 		
  801:   \ pointer where ghost is in target, or if unresolved
  802:   \ points to the where we have to resolve (linked-list)
  803:   cell% field >link
  804: 
  805:   \ execution semantics (while target compiling) of ghost
  806:   cell% field >exec
  807: 
  808:   \ compilation action of this ghost; this is what is
  809:   \ done to compile a call (or whatever) to this definition.
  810:   \ E.g. >comp contains the semantic of postpone s"
  811:   \ whereas >exec-compile contains the semantic of s"
  812:   cell% field >comp
  813: 
  814:   \ Compilation sematics (while parsing) of this ghost. E.g. 
  815:   \ "\" will skip the rest of line.
  816:   \ These semantics are defined by Cond: and
  817:   \ if a word is made immediate in instant, then the >exec2 field
  818:   \ gets copied to here
  819:   cell% field >exec-compile
  820: 
  821:   \ Additional execution semantics of this ghost. This is used
  822:   \ for code generated by instant and for the doer-xt of created
  823:   \ words
  824:   cell% field >exec2
  825: 
  826:   cell% field >created
  827: 
  828:   \ the xt of the created ghost word itself
  829:   cell% field >ghost-xt
  830: 
  831:   \ pointer to the counted string of the assiciated
  832:   \ assembler label
  833:   cell% field >asm-name
  834: 
  835:   \ mapped primitives have a special address, so
  836:   \ we are able to detect them
  837:   cell% field >asm-dummyaddr
  838: 			
  839:   \ for builder (create, variable...) words
  840:   \ the execution symantics of words built are placed here
  841:   \ this is a doer ghost or a dummy ghost
  842:   cell% field >do:ghost
  843: 
  844:   cell% field >ghost-flags
  845: 
  846:   cell% field >ghost-name
  847: 
  848: End-Struct ghost-struct
  849: 
  850: Variable ghost-list
  851: 0 ghost-list !
  852: 
  853: Variable executed-ghost \ last executed ghost, needed in tcreate and gdoes>
  854: \ Variable last-ghost	\ last ghost that is created
  855: Variable last-header-ghost \ last ghost definitions with header
  856: 
  857: \ space for ghosts resolve structure
  858: \ we create ghosts in a sepearte space
  859: \ and not to the current host dp, because this
  860: \ gives trouble with instant while compiling and creating
  861: \ a ghost for a forward reference
  862: \ BTW: we cannot allocate another memory region
  863: \ because allot will check the overflow!!
  864: Variable cross-space-dp
  865: Create cross-space 250000 allot here 100 allot align 
  866: Constant cross-space-end
  867: cross-space cross-space-dp !
  868: Variable cross-space-dp-orig
  869: 
  870: : cross-space-used cross-space-dp @ cross-space - ;
  871: 
  872: : >space ( -- )
  873:   dp @ cross-space-dp-orig !
  874:   cross-space-dp @ dp ! ;
  875: 
  876: : space> ( -- )
  877:   dp @ dup cross-space-dp !
  878:   cross-space-end u> ABORT" CROSS: cross-space overflow"
  879:   cross-space-dp-orig @ dp ! ;
  880: 
  881: \ this is just for debugging, to see this in the backtrace
  882: : execute-exec execute ;
  883: : execute-exec2 execute ;
  884: : execute-exec-compile execute ;
  885: 
  886: : NoExec
  887:   executed-ghost @ >exec2 @
  888:   ?dup 
  889:   IF   execute-exec2
  890:   ELSE true ABORT" CROSS: Don't execute ghost, or immediate target word"
  891:   THEN ;
  892: 
  893: Defer is-forward
  894: 
  895: : (ghostheader) ( -- )
  896:   ghost-list linked <fwd> , 0 , ['] NoExec , ['] is-forward , 
  897:   0 , 0 , 0 , 0 , 0 , 0 , 0 , 0 , ;
  898: 
  899: : ghostheader ( -- ) (ghostheader) 0 , ;
  900: 
  901: ' Ghosts >wordlist Constant ghosts-wordlist
  902: 
  903: \ the current wordlist for ghost definitions in the host
  904: ghosts-wordlist Value current-ghosts
  905: 
  906: : Make-Ghost ( "name" -- ghost )
  907:   >space
  908:   \ save current and create in ghost vocabulary
  909:   get-current >r current-ghosts set-current
  910:   >in @ Create >in !
  911:   \ some forth systems like iForth need the immediate directly
  912:   \ after the word is created
  913:   \ restore current
  914:   r> set-current
  915:   here (ghostheader)
  916:   bl word count string, align
  917:   space>
  918:   \ set ghost-xt field by doing a search
  919:   dup >ghost-name count 
  920:   current-ghosts search-wordlist
  921:   0= ABORT" CROSS: Just created, must be there!"
  922:   over >ghost-xt !
  923:   DOES> 
  924:       dup executed-ghost !
  925:       >exec @ execute-exec ;
  926: 
  927: \ ghost words                                          14oct92py
  928: \                                          changed:    10may93py/jaw
  929: 
  930: Defer search-ghosts
  931: 
  932: : (search-ghosts) ( adr len -- cfa true | 0 )
  933:   current-ghosts search-wordlist ; 
  934: 
  935:   ' (search-ghosts) IS search-ghosts
  936: 
  937: : gsearch ( addr len -- ghost true | 0 )
  938:   search-ghosts
  939:   dup IF swap >body swap THEN ;
  940: 
  941: : gfind   ( string -- ghost true / string false )
  942: \ searches for string in word-list ghosts
  943:   \ dup count type space
  944:   dup >r count gsearch
  945:   dup IF rdrop ELSE r> swap THEN ;
  946: 
  947: : gdiscover ( xt -- ghost true | xt false )
  948:   >r ghost-list
  949:   BEGIN @ dup
  950:   WHILE dup >magic @ <fwd> <>
  951:         IF dup >link @ r@ =
  952:            IF rdrop true EXIT THEN
  953:         THEN
  954:   REPEAT
  955:   drop r> false ;
  956: 
  957: : xt>ghost ( xt -- ghost )
  958:   gdiscover 0= ABORT" CROSS: ghost not found for this xt" ;
  959: 
  960: : Ghost   ( "name" -- ghost )
  961:   >in @ bl word gfind IF  nip EXIT  THEN
  962:   drop  >in !  Make-Ghost ;
  963: 
  964: : >ghostname ( ghost -- adr len )
  965:   >ghost-name count ;
  966: 
  967: : forward? ( ghost -- flag )
  968:   >magic @ <fwd> = ;
  969: 
  970: : undefined? ( ghost -- flag )
  971:   >magic @ dup <fwd> = swap <skip> = or ;
  972: 
  973: : immediate? ( ghost -- flag )
  974:   >magic @ <imm> = ;
  975: 
  976: Variable TWarnings
  977: TWarnings on
  978: Variable Exists-Warnings
  979: Exists-Warnings on
  980: 
  981: : exists-warning ( ghost -- ghost )
  982:   TWarnings @ Exists-Warnings @ and
  983:   IF dup >ghostname warnhead type ."  exists " THEN ;
  984: 
  985: \ : HeaderGhost Ghost ;
  986: 
  987: Variable reuse-ghosts reuse-ghosts off
  988: 
  989: : HeaderGhost ( "name" -- ghost )
  990:   >in @ 
  991:   bl word count 
  992: \  2dup type space
  993:   current-ghosts search-wordlist
  994:   IF  >body dup undefined? reuse-ghosts @ or
  995:       IF   nip EXIT
  996:       ELSE exists-warning 
  997:       THEN
  998:       drop >in ! 
  999:   ELSE >in ! 
 1000:   THEN 
 1001:   \ we keep the execution semantics of the prviously
 1002:   \ defined words, this is a workaround
 1003:   \ for the redefined \ until vocs work
 1004:   Make-Ghost ;
 1005:  
 1006: : .ghost ( ghost -- ) >ghostname type ;
 1007: 
 1008: \ ' >ghostname ALIAS @name
 1009: 
 1010: : [G'] ( -- ghost : name )
 1011: \G ticks a ghost and returns its address
 1012: \  bl word gfind 0= ABORT" CROSS: Ghost don't exists"
 1013:   ghost state @ IF postpone literal THEN ; immediate
 1014: 
 1015: : g>xt ( ghost -- xt )
 1016: \G Returns the xt (cfa) of a ghost. Issues a warning if undefined.
 1017:   dup undefined? ABORT" CROSS: forward " >link @ ;
 1018:    
 1019: : g>body ( ghost -- body )
 1020: \G Returns the body-address (pfa) of a ghost. 
 1021: \G Issues a warning if undefined (a forward-reference).
 1022:   g>xt X >body ;
 1023: 
 1024: 1 Constant <label>
 1025: 
 1026: Struct
 1027:   \ bitmask of address type (not used for now)
 1028:   cell% field addr-type
 1029:   \ if this address is an xt, this field points to the ghost
 1030:   cell% field addr-xt-ghost
 1031:   \ a bit mask that tells as what part of the cell
 1032:   \ is refenced from an address pointer, used for assembler generation
 1033:   cell% field addr-refs
 1034: End-Struct addr-struct
 1035: 
 1036: : %allocerase ( align size -- addr )
 1037:   dup >r %alloc dup r> erase ;
 1038: 
 1039: \ returns the addr struct, define it if 0 reference
 1040: : define-addr-struct ( addr -- struct-addr )
 1041:   dup @ ?dup IF nip EXIT THEN
 1042:   addr-struct %allocerase tuck swap ! ;
 1043: 
 1044: \ Predefined ghosts                                    12dec92py
 1045: 
 1046: Ghost 0=                                        drop
 1047: Ghost branch    Ghost ?branch                   2drop
 1048: Ghost (do)      Ghost (?do)                     2drop
 1049: Ghost (for)                                     drop
 1050: Ghost (loop)    Ghost (+loop)                   2drop
 1051: Ghost (next)                                    drop
 1052: Ghost unloop    Ghost ;S                        2drop
 1053: Ghost lit       Ghost (compile) Ghost !         2drop drop
 1054: Ghost (does>)   Ghost noop                      2drop
 1055: Ghost (.")      Ghost (S")      Ghost (ABORT")  2drop drop
 1056: Ghost '                                         drop
 1057: Ghost :docol    Ghost :doesjump Ghost :dodoes   2drop drop
 1058: Ghost :dovar					drop
 1059: Ghost over      Ghost =         Ghost drop      2drop drop
 1060: Ghost - drop
 1061: Ghost 2drop drop
 1062: Ghost 2dup drop
 1063: 
 1064: 
 1065: 
 1066: \ \ Parameter for target systems                         06oct92py
 1067: 
 1068: 
 1069: >cross
 1070: \ we define it ans like...
 1071: wordlist Constant target-environment
 1072: 
 1073: \ save information of current dictionary to restore with environ>
 1074: Variable env-current 
 1075: 
 1076: : >ENVIRON get-current env-current ! target-environment set-current ;
 1077: : ENVIRON> env-current @ set-current ; 
 1078: 
 1079: >TARGET
 1080: 
 1081: : environment? ( addr len -- [ x ] true | false )
 1082: \G returns the content of environment variable and true or
 1083: \G false if not present
 1084:    target-environment search-wordlist 
 1085:    IF EXECUTE true ELSE false THEN ;
 1086: 
 1087: : $has? ( addr len -- x | false )
 1088: \G returns the content of environment variable 
 1089: \G or false if not present
 1090:    T environment? H dup IF drop THEN ;
 1091: 
 1092: : e? ( "name" -- x )
 1093: \G returns the content of environment variable. 
 1094: \G The variable is expected to exist. If not, issue an error.
 1095:    bl word count T environment? H 
 1096:    0= ABORT" environment variable not defined!" ;
 1097: 
 1098: : has? ( "name" --- x | false )
 1099: \G returns the content of environment variable 
 1100: \G or false if not present
 1101:    bl word count T $has? H ;
 1102: 
 1103: 
 1104: >ENVIRON get-order get-current swap 1+ set-order
 1105: true SetValue compiler
 1106: true SetValue cross
 1107: true SetValue standard-threading
 1108: >TARGET previous
 1109: 
 1110: 0
 1111: [IFDEF] mach-file drop mach-file count 1 [THEN]
 1112: [IFDEF] machine-file drop machine-file 1 [THEN]
 1113: [IF] 	included hex
 1114: [ELSE]  cr ." No machine description!" ABORT 
 1115: [THEN]
 1116: 
 1117: >ENVIRON
 1118: 
 1119: T has? ec H
 1120: [IF]
 1121: false DefaultValue relocate
 1122: false DefaultValue file
 1123: false DefaultValue OS
 1124: false DefaultValue prims
 1125: false DefaultValue floating
 1126: false DefaultValue glocals
 1127: false DefaultValue dcomps
 1128: false DefaultValue hash
 1129: false DefaultValue xconds
 1130: false DefaultValue header
 1131: false DefaultValue backtrace
 1132: false DefaultValue new-input
 1133: false DefaultValue peephole
 1134: [THEN]
 1135: 
 1136: true DefaultValue interpreter
 1137: true DefaultValue ITC
 1138: false DefaultValue rom
 1139: true DefaultValue standardthreading
 1140: 
 1141: >TARGET
 1142: s" relocate" T environment? H 
 1143: \ JAW why set NIL to this?!
 1144: [IF]	drop \ SetValue NIL
 1145: [ELSE]	>ENVIRON T NIL H SetValue relocate
 1146: [THEN]
 1147: 
 1148: >CROSS
 1149: 
 1150: \ \ Create additional parameters                         19jan95py
 1151: 
 1152: \ currently cross only works for host machines with address-unit-bits
 1153: \ eual to 8 because of s! and sc!
 1154: \ but I start to query the environment just to modularize a little bit
 1155: 
 1156: : check-address-unit-bits ( -- )	
 1157: \	s" ADDRESS-UNIT-BITS" environment?
 1158: \	IF 8 <> ELSE true THEN
 1159: \	ABORT" ADDRESS-UNIT-BITS unknown or not equal to 8!"
 1160: 
 1161: \	shit, this doesn't work because environment? is only defined for 
 1162: \	gforth.fi and not kernl???.fi
 1163: 	;
 1164: 
 1165: check-address-unit-bits
 1166: 8 Constant bits/byte	\ we define: byte is address-unit
 1167: 
 1168: 1 bits/byte lshift Constant maxbyte 
 1169: \ this sets byte size for the target machine, (probably right guess) jaw
 1170: 
 1171: T
 1172: NIL		   	Constant TNIL
 1173: cell               	Constant tcell
 1174: cell<<             	Constant tcell<<
 1175: cell>bit           	Constant tcell>bit
 1176: bits/char          	Constant tbits/char
 1177: bits/char H bits/byte T /      
 1178: 			Constant tchar
 1179: float             	Constant tfloat
 1180: 1 bits/char lshift 	Constant tmaxchar
 1181: [IFUNDEF] bits/byte
 1182: 8			Constant tbits/byte
 1183: [ELSE]
 1184: bits/byte		Constant tbits/byte
 1185: [THEN]
 1186: H
 1187: tbits/char bits/byte /	Constant tbyte
 1188: 
 1189: 
 1190: \ Variables                                            06oct92py
 1191: 
 1192: Variable image
 1193: Variable tlast    TNIL tlast !  \ Last name field
 1194: Variable tlastcfa \ Last code field
 1195: Variable bit$
 1196: 
 1197: \ statistics						10jun97jaw
 1198: 
 1199: Variable headers-named 0 headers-named !
 1200: Variable user-vars 0 user-vars !
 1201: 
 1202: : target>bitmask-size ( u1 -- u2 )
 1203:   1- tcell>bit rshift 1+ ;
 1204: 
 1205: : allocatetarget ( size -- adr )
 1206:   dup allocate ABORT" CROSS: No memory for target"
 1207:   swap over swap erase ;
 1208: 
 1209: \ \ memregion.fs
 1210: 
 1211: 
 1212: Variable last-defined-region    \ pointer to last defined region
 1213: Variable region-link            \ linked list with all regions
 1214: Variable mirrored-link          \ linked list for mirrored regions
 1215: 0 dup mirrored-link ! region-link !
 1216: 
 1217: 
 1218: : >rname 7 cells + ;
 1219: : >rbm   4 cells + ;
 1220: : >rmem  5 cells + ;
 1221: : >rtype 6 cells + ;
 1222: : >rlink 3 cells + ;
 1223: : >rdp 2 cells + ;
 1224: : >rlen cell+ ;
 1225: : >rstart ;
 1226: 
 1227: 
 1228: : region ( addr len -- )                
 1229: \G create a new region
 1230:   \ check whether predefined region exists 
 1231:   save-input bl word find >r >r restore-input throw r> r> 0= 
 1232:   IF	\ make region
 1233: 	drop
 1234: 	save-input create restore-input throw
 1235: 	here last-defined-region !
 1236: 	over ( startaddr ) , ( length ) , ( dp ) ,
 1237: 	region-link linked 0 , 0 , 0 , bl word count string,
 1238:   ELSE	\ store new parameters in region
 1239:         bl word drop
 1240: 	>body >r r@ last-defined-region !
 1241: 	r@ >rlen ! dup r@ >rstart ! r> >rdp !
 1242:   THEN ;
 1243: 
 1244: : borders ( region -- startaddr endaddr ) 
 1245: \G returns lower and upper region border
 1246:   dup >rstart @ swap >rlen @ over + ;
 1247: 
 1248: : extent  ( region -- startaddr len )   
 1249: \G returns the really used area
 1250:   dup >rstart @ swap >rdp @ over - ;
 1251: 
 1252: : area ( region -- startaddr totallen ) 
 1253: \G returns the total area
 1254:   dup >rstart @ swap >rlen @ ;
 1255: 
 1256: : mirrored                              
 1257: \G mark a region as mirrored
 1258:   mirrored-link
 1259:   align linked last-defined-region @ , ;
 1260: 
 1261: : .addr ( u -- )
 1262: \G prints a 16 or 32 Bit nice hex value
 1263:   base @ >r hex
 1264:   tcell 2 u>
 1265:   IF s>d <# # # # # [char] . hold # # # # #> type
 1266:   ELSE s>d <# # # # # # #> type
 1267:   THEN r> base ! space ;
 1268: 
 1269: : .regions                      \G display region statistic
 1270: 
 1271:   \ we want to list the regions in the right order
 1272:   \ so first collect all regions on stack
 1273:   0 region-link @
 1274:   BEGIN dup WHILE dup @ REPEAT drop
 1275:   BEGIN dup
 1276:   WHILE cr
 1277:         0 >rlink - >r
 1278:         r@ >rname count tuck type
 1279:         12 swap - 0 max spaces space
 1280:         ." Start: " r@ >rstart @ dup .addr space
 1281:         ." End: " r@ >rlen @ + .addr space
 1282:         ." DP: " r> >rdp @ .addr
 1283:   REPEAT drop
 1284:   s" rom" T $has? H 0= ?EXIT
 1285:   cr ." Mirrored:"
 1286:   mirrored-link @
 1287:   BEGIN dup
 1288:   WHILE space dup cell+ @ >rname count type @
 1289:   REPEAT drop cr
 1290:   ;
 1291: 
 1292: \ -------- predefined regions
 1293: 
 1294: 0 0 region address-space
 1295: \ total memory addressed and used by the target system
 1296: 
 1297: 0 0 region dictionary
 1298: \ rom area for the compiler
 1299: 
 1300: T has? rom H
 1301: [IF]
 1302: 0 0 region ram-dictionary mirrored
 1303: \ ram area for the compiler
 1304: [ELSE]
 1305: ' dictionary ALIAS ram-dictionary
 1306: [THEN]
 1307: 
 1308: 0 0 region return-stack
 1309: 
 1310: 0 0 region data-stack
 1311: 
 1312: 0 0 region tib-region
 1313: 
 1314: ' dictionary ALIAS rom-dictionary
 1315: 
 1316: 
 1317: : setup-target ( -- )   \G initialize target's memory space
 1318:   s" rom" T $has? H
 1319:   IF  \ check for ram and rom...
 1320:       \ address-space area nip 0<>
 1321:       ram-dictionary area nip 0<>
 1322:       rom-dictionary area nip 0<>
 1323:       and 0=
 1324:       ABORT" CROSS: define address-space, rom- , ram-dictionary, with rom-support!"
 1325:   THEN
 1326:   address-space area nip
 1327:   IF
 1328:       address-space area
 1329:   ELSE
 1330:       dictionary area
 1331:   THEN
 1332:   nip 0=
 1333:   ABORT" CROSS: define at least address-space or dictionary!!"
 1334: 
 1335:   \ allocate target for each region
 1336:   region-link
 1337:   BEGIN @ dup
 1338:   WHILE dup
 1339:         0 >rlink - >r
 1340:         r@ >rlen @
 1341:         IF      \ allocate mem
 1342:                 r@ >rlen @ allocatetarget dup image !
 1343:                 r@ >rmem !
 1344: 
 1345:                 r@ >rlen @
 1346:                 target>bitmask-size allocatetarget
 1347:                 dup bit$ !
 1348:                 r@ >rbm !
 1349: 
 1350: 		r@ >rlen @
 1351: 		tcell / 1+ cells allocatetarget r@ >rtype !
 1352: 
 1353: 		rdrop
 1354:         ELSE    r> drop THEN
 1355:    REPEAT drop ;
 1356: 
 1357: \ MakeKernel                                           		22feb99jaw
 1358: 
 1359: : makekernel ( targetsize -- targetsize )
 1360:   dup dictionary >rlen ! setup-target ;
 1361: 
 1362: >MINIMAL
 1363: : makekernel makekernel ;
 1364: >CROSS
 1365: 
 1366: \ \ switched tdp for rom support				03jun97jaw
 1367: 
 1368: \ second value is here to store some maximal value for statistics
 1369: \ tempdp is also embedded here but has nothing to do with rom support
 1370: \ (needs switched dp)
 1371: 
 1372: variable tempdp	0 ,	\ temporary dp for resolving
 1373: variable tempdp-save
 1374: 
 1375: 0 [IF]
 1376: variable romdp 0 ,      \ Dictionary-Pointer for ramarea
 1377: variable ramdp 0 ,      \ Dictionary-Pointer for romarea
 1378: 
 1379: \
 1380: variable sramdp		\ start of ram-area for forth
 1381: variable sromdp		\ start of rom-area for forth
 1382: 
 1383: [THEN]
 1384: 
 1385: 
 1386: 0 value tdp
 1387: variable fixed		\ flag: true: no automatic switching
 1388: 			\	false: switching is done automatically
 1389: 
 1390: \ Switch-Policy:
 1391: \
 1392: \ a header is always compiled into rom
 1393: \ after a created word (create and variable) compilation goes to ram
 1394: \
 1395: \ Be careful: If you want to make the data behind create into rom
 1396: \ you have to put >rom before create!
 1397: 
 1398: variable constflag constflag off
 1399: 
 1400: : activate ( region -- )
 1401: \G next code goes to this region
 1402:   >rdp to tdp ;
 1403: 
 1404: : (switchram)
 1405:   fixed @ ?EXIT s" rom" T $has? H 0= ?EXIT
 1406:   ram-dictionary activate ;
 1407: 
 1408: : switchram
 1409:   constflag @
 1410:   IF constflag off ELSE (switchram) THEN ;
 1411: 
 1412: : switchrom
 1413:   fixed @ ?EXIT rom-dictionary activate ;
 1414: 
 1415: : >tempdp ( addr -- ) 
 1416:   tdp tempdp-save ! tempdp to tdp tdp ! ;
 1417: : tempdp> ( -- )
 1418:   tempdp-save @ to tdp ;
 1419: 
 1420: : >ram  fixed off (switchram) fixed on ;
 1421: : >rom  fixed off switchrom fixed on ;
 1422: : >auto fixed off switchrom ;
 1423: 
 1424: 
 1425: 
 1426: \ : romstart dup sromdp ! romdp ! ;
 1427: \ : ramstart dup sramdp ! ramdp ! ;
 1428: 
 1429: \ default compilation goes to rom
 1430: \ when romable support is off, only the rom switch is used (!!)
 1431: >auto
 1432: 
 1433: : there  tdp @ ;
 1434: 
 1435: >TARGET
 1436: 
 1437: \ \ Target Memory Handling
 1438: 
 1439: \ Byte ordering and cell size                          06oct92py
 1440: 
 1441: : cell+         tcell + ;
 1442: : cells         tcell<< lshift ;
 1443: : chars         tchar * ;
 1444: : char+		tchar + ;
 1445: : floats	tfloat * ;
 1446:     
 1447: >CROSS
 1448: : cell/         tcell<< rshift ;
 1449: >TARGET
 1450: 20 CONSTANT bl
 1451: \ TNIL Constant NIL
 1452: 
 1453: >CROSS
 1454: 
 1455: bigendian
 1456: [IF]
 1457:    : DS!  ( d addr -- )  tcell bounds swap 1-
 1458:      DO  maxbyte ud/mod rot I c!  -1 +LOOP  2drop ;
 1459:    : DS@  ( addr -- d )  >r 0 0 r> tcell bounds
 1460:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  LOOP ;
 1461:    : Sc!  ( n addr -- )  >r s>d r> tchar bounds swap 1-
 1462:      DO  maxbyte ud/mod rot I c!  -1 +LOOP  2drop ;
 1463:    : Sc@  ( addr -- n )  >r 0 0 r> tchar bounds
 1464:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  LOOP d>s ;
 1465: [ELSE]
 1466:    : DS!  ( d addr -- )  tcell bounds
 1467:      DO  maxbyte ud/mod rot I c!  LOOP  2drop ;
 1468:    : DS@  ( addr -- n )  >r 0 0 r> tcell bounds swap 1-
 1469:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  -1 +LOOP ;
 1470:    : Sc!  ( n addr -- )  >r s>d r> tchar bounds
 1471:      DO  maxbyte ud/mod rot I c!  LOOP  2drop ;
 1472:    : Sc@  ( addr -- n )  >r 0 0 r> tchar bounds swap 1-
 1473:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  -1 +LOOP d>s ;
 1474: [THEN]
 1475: 
 1476: : S! ( n addr -- ) >r s>d r> DS! ;
 1477: : S@ ( addr -- n ) DS@ d>s ;
 1478: 
 1479: : taddr>region ( taddr -- region | 0 )
 1480: \G finds for a target-address the correct region
 1481: \G returns 0 if taddr is not in range of a target memory region
 1482:   region-link
 1483:   BEGIN @ dup
 1484:   WHILE dup >r
 1485:         0 >rlink - >r
 1486:         r@ >rlen @
 1487:         IF      dup r@ borders within
 1488:                 IF r> r> drop nip EXIT THEN
 1489:         THEN
 1490:         r> drop
 1491:         r>
 1492:   REPEAT
 1493:   2drop 0 ;
 1494: 
 1495: : taddr>region-abort ( taddr -- region | 0 )
 1496:   dup taddr>region dup 0= 
 1497:   IF    drop cr ." Wrong address: " .addr
 1498:         -1 ABORT" Address out of range!"
 1499:   THEN nip ;
 1500: 
 1501: : (>regionimage) ( taddr -- 'taddr )
 1502:   dup
 1503:   \ find region we want to address
 1504:   taddr>region-abort
 1505:   >r
 1506:   \ calculate offset in region
 1507:   r@ >rstart @ -
 1508:   \ add regions real address in our memory
 1509:   r> >rmem @ + ;
 1510: 
 1511: : (>regionbm) ( taddr -- 'taddr bitmaskbaseaddr )
 1512:   dup
 1513:   \ find region we want to address
 1514:   taddr>region-abort
 1515:   >r
 1516:   \ calculate offset in region
 1517:   r@ >rstart @ -
 1518:   \ add regions real address in our memory
 1519:   r> >rbm @ ;
 1520: 
 1521: : (>regiontype) ( taddr -- 'taddr )
 1522:   dup
 1523:   \ find region we want to address
 1524:   taddr>region-abort
 1525:   >r
 1526:   \ calculate offset in region
 1527:   r@ >rstart @ - tcell / cells
 1528:   \ add regions real address in our memory
 1529:   r> >rtype @ + ;
 1530:   
 1531: \ Bit string manipulation                               06oct92py
 1532: \                                                       9may93jaw
 1533: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
 1534: : bits ( n -- n ) chars Bittable + c@ ;
 1535: 
 1536: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
 1537: : +bit ( addr n -- )  >bit over c@ or swap c! ;
 1538: : -bit ( addr n -- )  >bit invert over c@ and swap c! ;
 1539: 
 1540: : @relbit ( taddr -- f ) (>regionbm) swap cell/ >bit swap c@ and ;
 1541: 
 1542: : (relon) ( taddr -- )  
 1543:   [ [IFDEF] fd-relocation-table ]
 1544:   s" +" fd-relocation-table write-file throw
 1545:   dup s>d <# #s #> fd-relocation-table write-line throw
 1546:   [ [THEN] ]
 1547:   (>regionbm) swap cell/ +bit ;
 1548: 
 1549: : (reloff) ( taddr -- ) 
 1550:   [ [IFDEF] fd-relocation-table ]
 1551:   s" -" fd-relocation-table write-file throw
 1552:   dup s>d <# #s #> fd-relocation-table write-line throw
 1553:   [ [THEN] ]
 1554:   (>regionbm) swap cell/ -bit ;
 1555: 
 1556: : (>image) ( taddr -- absaddr ) image @ + ;
 1557: 
 1558: DEFER >image
 1559: DEFER relon
 1560: DEFER reloff
 1561: DEFER correcter
 1562: 
 1563: T has? relocate H
 1564: [IF]
 1565: ' (relon) IS relon
 1566: ' (reloff) IS reloff
 1567: ' (>regionimage) IS >image
 1568: [ELSE]
 1569: ' drop IS relon
 1570: ' drop IS reloff
 1571: ' (>regionimage) IS >image
 1572: [THEN]
 1573: 
 1574: \ Target memory access                                 06oct92py
 1575: 
 1576: : align+  ( taddr -- rest )
 1577:     tcell tuck 1- and - [ tcell 1- ] Literal and ;
 1578: : cfalign+  ( taddr -- rest )
 1579:     \ see kernel.fs:cfaligned
 1580:     /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
 1581: 
 1582: >TARGET
 1583: : aligned ( taddr -- ta-addr )  dup align+ + ;
 1584: \ assumes cell alignment granularity (as GNU C)
 1585: 
 1586: : cfaligned ( taddr1 -- taddr2 )
 1587:     \ see kernel.fs
 1588:     dup cfalign+ + ;
 1589: 
 1590: : @  ( taddr -- w )     >image S@ ;
 1591: : !  ( w taddr -- )     >image S! ;
 1592: : c@ ( taddr -- char )  >image Sc@ ;
 1593: : c! ( char taddr -- )  >image Sc! ;
 1594: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
 1595: : 2! ( x1 x2 taddr -- ) T tuck ! cell+ ! H ;
 1596: 
 1597: \ Target compilation primitives                        06oct92py
 1598: \ included A!                                          16may93jaw
 1599: 
 1600: : here  ( -- there )    there ;
 1601: : allot ( n -- )        tdp +! ;
 1602: : ,     ( w -- )        T here H tcell T allot  ! H ;
 1603: : c,    ( char -- )     T here H tchar T allot c! H ;
 1604: : align ( -- )          T here H align+ 0 ?DO  bl T c, H tchar +LOOP ;
 1605: : cfalign ( -- )
 1606:     T here H cfalign+ 0 ?DO  bl T c, H tchar +LOOP ;
 1607: 
 1608: : >address		dup 0>= IF tbyte / THEN ; \ ?? jaw 
 1609: : A!                    swap >address swap dup relon T ! H ;
 1610: : A,    ( w -- )        >address T here H relon T , H ;
 1611: 
 1612: 
 1613: \ \ --------------------        Host/Target copy etc.     	29aug01jaw
 1614: 
 1615: 
 1616: >CROSS
 1617: 
 1618: : TD! >image DS! ;
 1619: : TD@ >image DS@ ;
 1620: 
 1621: : th-count ( taddr -- host-addr len )
 1622: \G returns host address of target string
 1623:   assert1( tbyte 1 = )
 1624:   dup X c@ swap X char+ >image swap ;
 1625: 
 1626: : ht-move ( haddr taddr len -- )
 1627: \G moves data from host-addr to destination in target-addr
 1628: \G character by character
 1629:   swap -rot bounds ?DO I c@ over X c! X char+ LOOP drop ;
 1630: 
 1631: 2Variable last-string
 1632: 
 1633: : ht-string,  ( addr count -- )
 1634:   dup there swap last-string 2!
 1635:   dup T c, H bounds  ?DO  I c@ T c, H  LOOP ; 
 1636: 
 1637: >TARGET
 1638: 
 1639: : count dup X c@ swap X char+ swap ;
 1640: 
 1641: : on		-1 -1 rot TD!  ; 
 1642: : off   	T 0 swap ! H ;
 1643: 
 1644: : tcmove ( source dest len -- )
 1645: \G cmove in target memory
 1646:   tchar * bounds
 1647:   ?DO  dup T c@ H I T c! H 1+
 1648:   tchar +LOOP  drop ;
 1649: 
 1650: : td, ( d -- )
 1651: \G Store a host value as one cell into the target
 1652:   there tcell X allot TD! ;
 1653: 
 1654: \ \ Load Assembler
 1655: 
 1656: >TARGET
 1657: H also Forth definitions
 1658: 
 1659: \ FIXME: should we include the assembler really in the forth 
 1660: \ dictionary?!?!?!? This conflicts with the existing assembler 
 1661: \ of the host forth system!!
 1662: [IFDEF] asm-include asm-include [THEN] hex
 1663: 
 1664: previous
 1665: 
 1666: 
 1667: >CROSS
 1668: 
 1669: : (cc) T a, H ;					' (cc) plugin-of colon,
 1670: : (prim) T a, H ;				' (prim) plugin-of prim,
 1671: 
 1672: : (cr) >tempdp ]comp prim, comp[ tempdp> ; 	' (cr) plugin-of colon-resolve
 1673: : (ar) T ! H ;					' (ar) plugin-of addr-resolve
 1674: : (dr)  ( ghost res-pnt target-addr addr )
 1675: 	>tempdp drop over 
 1676: 	dup >magic @ <do:> =
 1677: 	IF 	doer,
 1678: 	ELSE	dodoes,
 1679: 	THEN 
 1680: 	tempdp> ;				' (dr) plugin-of doer-resolve
 1681: 
 1682: : (cm) ( -- addr )
 1683:     T here align H
 1684:     -1 prim, ;					' (cm) plugin-of colonmark,
 1685: 
 1686: >TARGET
 1687: : compile, ( xt -- )
 1688:   dup xt>ghost >comp @ EXECUTE ;
 1689: >CROSS
 1690: 
 1691: \ resolve structure
 1692: 
 1693: : >next ;		\ link to next field
 1694: : >tag cell+ ;		\ indecates type of reference: 0: call, 1: address, 2: doer
 1695: : >taddr cell+ cell+ ;	
 1696: : >ghost 3 cells + ;
 1697: : >file 4 cells + ;
 1698: : >line 5 cells + ;
 1699: 
 1700: : (refered) ( ghost addr tag -- )
 1701: \G creates a reference to ghost at address taddr
 1702:     >space
 1703:     rot >link linked
 1704:     ( taddr tag ) ,
 1705:     ( taddr ) , 
 1706:     last-header-ghost @ , 
 1707:     loadfile , 
 1708:     sourceline# , 
 1709:     space>
 1710:   ;
 1711: 
 1712: : refered ( ghost tag -- )
 1713: \G creates a resolve structure
 1714:     T here aligned H swap (refered)
 1715:   ;
 1716: 
 1717: : killref ( addr ghost -- )
 1718: \G kills a forward reference to ghost at position addr
 1719: \G this is used to eleminate a :dovar refence after making a DOES>
 1720:     dup >magic @ <fwd> <> IF 2drop EXIT THEN
 1721:     swap >r >link
 1722:     BEGIN dup @ dup  ( addr last this )
 1723:     WHILE dup >taddr @ r@ =
 1724:  	 IF   @ over !
 1725: 	 ELSE nip THEN
 1726:     REPEAT rdrop 2drop 
 1727:   ;
 1728: 
 1729: Defer resolve-warning
 1730: 
 1731: : reswarn-test ( ghost res-struct -- ghost res-struct )
 1732:   over cr ." Resolving " .ghost dup ."  in " >ghost @ .ghost ;
 1733: 
 1734: : reswarn-forward ( ghost res-struct -- ghost res-struct )
 1735:   over warnhead .ghost dup ."  is referenced in " 
 1736:   >ghost @ .ghost ;
 1737: 
 1738: \ ' reswarn-test IS resolve-warning
 1739:  
 1740: \ resolve                                              14oct92py
 1741: 
 1742:  : resolve-loop ( ghost resolve-list tcfa -- )
 1743:     >r
 1744:     BEGIN dup WHILE 
 1745: \  	  dup >tag @ 2 = IF reswarn-forward THEN
 1746: 	  resolve-warning 
 1747: 	  r@ over >taddr @ 
 1748: 	  2 pick >tag @
 1749: 	  CASE	0 OF colon-resolve ENDOF
 1750: 		1 OF addr-resolve ENDOF
 1751: 		2 OF doer-resolve ENDOF
 1752: 	  ENDCASE
 1753: 	  @ \ next list element
 1754:     REPEAT 2drop rdrop 
 1755:   ;
 1756: 
 1757: \ : resolve-loop ( ghost tcfa -- ghost tcfa )
 1758: \  >r dup >link @
 1759: \  BEGIN  dup  WHILE  dup T @ H r@ rot T ! H REPEAT  drop r> ;
 1760: 
 1761: \ exists                                                9may93jaw
 1762: 
 1763: : exists ( ghost tcfa -- )
 1764: \G print warning and set new target link in ghost
 1765:   swap exists-warning
 1766:   >link ! ;
 1767: 
 1768: : colon-resolved   ( ghost -- )
 1769:     >link @ colon, ; \ compile-call
 1770: 
 1771: : prim-resolved  ( ghost -- )
 1772:     >link @ prim, ;
 1773: 
 1774: \ FIXME: not used currently
 1775: : does-resolved ( ghost -- )
 1776:     dup g>body alit, >do:ghost @ g>body colon, ;
 1777: 
 1778: : (is-forward)   ( ghost -- )
 1779:   colonmark, 0 (refered) ; \ compile space for call
 1780: ' (is-forward) IS is-forward
 1781: 
 1782: : resolve  ( ghost tcfa -- )
 1783: \G resolve referencies to ghost with tcfa
 1784:     dup taddr>region 0<> IF
 1785:       2dup (>regiontype) define-addr-struct addr-xt-ghost 
 1786: 
 1787:       \ we define new address only if empty
 1788:       \ this is for not to take over the alias ghost
 1789:       \ (different ghost, but identical xt)
 1790:       \ but the very first that really defines it
 1791:       dup @ 0= IF ! ELSE 2drop THEN
 1792:     THEN
 1793: 
 1794:     \ is ghost resolved?, second resolve means another 
 1795:     \ definition with the same name
 1796:     over undefined? 0= IF  exists EXIT THEN
 1797:     \ get linked-list
 1798:     swap >r r@ >link @ swap \ ( list tcfa R: ghost )
 1799:     \ mark ghost as resolved
 1800:     dup r@ >link ! <res> r@ >magic !
 1801:     r@ >comp @ ['] is-forward = IF
 1802: 	['] prim-resolved  r@ >comp !  THEN
 1803:     \ loop through forward referencies
 1804:     r> -rot 
 1805:     comp-state @ >r Resolving comp-state !
 1806:     resolve-loop 
 1807:     r> comp-state !
 1808: 
 1809:     ['] noop IS resolve-warning 
 1810:   ;
 1811: 
 1812: \ gexecute ghost,                                      01nov92py
 1813: 
 1814: : (gexecute)   ( ghost -- )
 1815:   dup >comp @ EXECUTE ;
 1816: 
 1817: : gexecute ( ghost -- )
 1818:   dup >magic @ <imm> = IF -1 ABORT" CROSS: gexecute on immediate word" THEN
 1819:   (gexecute) ;
 1820: 
 1821: : addr,  ( ghost -- )
 1822:   dup forward? IF  1 refered 0 T a, H ELSE >link @ T a, H THEN ;
 1823: 
 1824: \ .unresolved                                          11may93jaw
 1825: 
 1826: variable ResolveFlag
 1827: 
 1828: \ ?touched                                             11may93jaw
 1829: 
 1830: : ?touched ( ghost -- flag ) dup forward? swap >link @
 1831:                                0 <> and ;
 1832: 
 1833: : .forwarddefs ( ghost -- )
 1834:   ."  appeared in:"
 1835:   >link
 1836:   BEGIN	@ dup
 1837:   WHILE	cr 5 spaces
 1838: 	dup >ghost @ .ghost
 1839: 	."  file " dup >file @ ?dup IF count type ELSE ." CON" THEN
 1840: 	."  line " dup >line @ .dec
 1841:   REPEAT 
 1842:   drop ;
 1843: 
 1844: : ?resolved  ( ghost -- )
 1845:   dup ?touched
 1846:   IF  	ResolveFlag on 
 1847: 	dup cr .ghost .forwarddefs
 1848:   ELSE 	drop 
 1849:   THEN ;
 1850: 
 1851: : .unresolved  ( -- )
 1852:   ResolveFlag off cr ." Unresolved: "
 1853:   ghost-list
 1854:   BEGIN @ dup
 1855:   WHILE dup ?resolved
 1856:   REPEAT drop ResolveFlag @
 1857:   IF
 1858:       -1 abort" Unresolved words!"
 1859:   ELSE
 1860:       ." Nothing!"
 1861:   THEN
 1862:   cr ;
 1863: 
 1864: : .stats
 1865:   base @ >r decimal
 1866:   cr ." named Headers: " headers-named @ . 
 1867:   r> base ! ;
 1868: 
 1869: >MINIMAL
 1870: 
 1871: : .unresolved .unresolved ;
 1872: 
 1873: >CROSS
 1874: \ Header states                                        12dec92py
 1875: 
 1876: \ : flag! ( 8b -- )   tlast @ dup >r T c@ xor r> c! H ;
 1877: bigendian [IF] 0 [ELSE] tcell 1- [THEN] Constant flag+
 1878: : flag! ( w -- )   tlast @ flag+ + dup >r T c@ xor r> c! H ;
 1879: 
 1880: VARIABLE ^imm
 1881: 
 1882: \ !! should be target wordsize specific
 1883: $80 constant alias-mask
 1884: $40 constant immediate-mask
 1885: $20 constant restrict-mask
 1886: 
 1887: >TARGET
 1888: : immediate     immediate-mask flag!
 1889:                 ^imm @ @ dup <imm> = IF  drop  EXIT  THEN
 1890:                 <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
 1891:                 <imm> ^imm @ ! ;
 1892: : restrict      restrict-mask flag! ;
 1893: 
 1894: : isdoer	
 1895: \G define a forth word as doer, this makes obviously only sence on
 1896: \G forth processors such as the PSC1000
 1897: 		<do:> last-header-ghost @ >magic ! ;
 1898: >CROSS
 1899: 
 1900: \ Target Header Creation                               01nov92py
 1901: 
 1902: : ht-lstring, ( addr count -- )
 1903:   dup T , H bounds  ?DO  I c@ T c, H  LOOP ;
 1904: 
 1905: >TARGET
 1906: : name,  ( "name" -- )  bl word count ht-lstring, X cfalign ;
 1907: : view,   ( -- ) ( dummy ) ;
 1908: >CROSS
 1909: 
 1910: \ Target Document Creation (goes to crossdoc.fd)       05jul95py
 1911: 
 1912: s" ./doc/crossdoc.fd" r/w create-file throw value doc-file-id
 1913: \ contains the file-id of the documentation file
 1914: 
 1915: : T-\G ( -- )
 1916:     source >in @ /string doc-file-id write-line throw
 1917:     postpone \ ;
 1918: 
 1919: Variable to-doc  to-doc on
 1920: 
 1921: : cross-doc-entry  ( -- )
 1922:     to-doc @ tlast @ 0<> and	\ not an anonymous (i.e. noname) header
 1923:     IF
 1924: 	s" " doc-file-id write-line throw
 1925: 	s" make-doc " doc-file-id write-file throw
 1926: 
 1927: 	Last-Header-Ghost @ >ghostname doc-file-id write-file throw
 1928: 	>in @
 1929: 	[char] ( parse 2drop
 1930: 	[char] ) parse doc-file-id write-file throw
 1931: 	s"  )" doc-file-id write-file throw
 1932: 	[char] \ parse 2drop					
 1933: 	T-\G
 1934: 	>in !
 1935:     THEN ;
 1936: 
 1937: \ Target TAGS creation
 1938: 
 1939: s" kernel.TAGS" r/w create-file throw value tag-file-id
 1940: \ contains the file-id of the tags file
 1941: 
 1942: Create tag-beg 2 c,  7F c, bl c,
 1943: Create tag-end 2 c,  bl c, 01 c,
 1944: Create tag-bof 1 c,  0C c,
 1945: 
 1946: 2variable last-loadfilename 0 0 last-loadfilename 2!
 1947: 	    
 1948: : put-load-file-name ( -- )
 1949:     sourcefilename last-loadfilename 2@ d<>
 1950:     IF
 1951: 	tag-bof count tag-file-id write-line throw
 1952: 	sourcefilename 2dup
 1953: 	tag-file-id write-file throw
 1954: 	last-loadfilename 2!
 1955: 	s" ,0" tag-file-id write-line throw
 1956:     THEN ;
 1957: 
 1958: : cross-tag-entry  ( -- )
 1959:     tlast @ 0<>	\ not an anonymous (i.e. noname) header
 1960:     IF
 1961: 	put-load-file-name
 1962: 	source >in @ min tag-file-id write-file throw
 1963: 	tag-beg count tag-file-id write-file throw
 1964: 	tlast @ >image count 1F and tag-file-id write-file throw
 1965: 	tag-end count tag-file-id write-file throw
 1966: 	base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
 1967: \	>in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
 1968: 	s" ,0" tag-file-id write-line throw
 1969: 	base !
 1970:     THEN ;
 1971: 
 1972: \ Check for words
 1973: 
 1974: Defer skip? ' false IS skip?
 1975: 
 1976: : skipdef ( "name" -- )
 1977: \G skip definition of an undefined word in undef-words and
 1978: \G all-words mode
 1979:     Ghost dup forward?
 1980:     IF  >magic <skip> swap !
 1981:     ELSE drop THEN ;
 1982: 
 1983: : tdefined? ( "name" -- flag ) 
 1984:     Ghost undefined? 0= ;
 1985: 
 1986: : defined2? ( "name" -- flag ) 
 1987: \G return true for anything else than forward, even for <skip>
 1988: \G that's what we want
 1989:     Ghost forward? 0= ;
 1990: 
 1991: : forced? ( "name" -- flag )
 1992: \G return ture if it is a foreced skip with defskip
 1993:     Ghost >magic @ <skip> = ;
 1994: 
 1995: : needed? ( -- flag ) \ name
 1996: \G returns a false flag when
 1997: \G a word is not defined
 1998: \G a forward reference exists
 1999: \G so the definition is not skipped!
 2000:     bl word gfind
 2001:     IF dup undefined?
 2002: 	nip
 2003: 	0=
 2004:     ELSE  drop true  THEN ;
 2005: 
 2006: : doer? ( -- flag ) \ name
 2007:     Ghost >magic @ <do:> = ;
 2008: 
 2009: : skip-defs ( -- )
 2010:     BEGIN  refill  WHILE  source -trailing nip 0= UNTIL  THEN ;
 2011: 
 2012: \ Target header creation
 2013: 
 2014: Variable NoHeaderFlag
 2015: NoHeaderFlag off
 2016: 
 2017: : 0.r ( n1 n2 -- ) 
 2018:     base @ >r hex 
 2019:     0 swap <# 0 ?DO # LOOP #> type 
 2020:     r> base ! ;
 2021: 
 2022: : .sym ( adr len -- )
 2023: \G escapes / and \ to produce sed output
 2024:   bounds 
 2025:   DO I c@ dup
 2026: 	CASE	[char] / OF drop ." \/" ENDOF
 2027: 		[char] \ OF drop ." \\" ENDOF
 2028: 		dup OF emit ENDOF
 2029: 	ENDCASE
 2030:     LOOP ;
 2031: 
 2032: Defer setup-execution-semantics
 2033: 0 Value lastghost
 2034: 
 2035: : (THeader ( "name" -- ghost )
 2036:     \  >in @ bl word count type 2 spaces >in !
 2037:     \ wordheaders will always be compiled to rom
 2038:     switchrom
 2039:     \ build header in target
 2040:     NoHeaderFlag @
 2041:     IF  NoHeaderFlag off
 2042:     ELSE
 2043: 	T align H view,
 2044: 	tlast @ dup 0> IF tcell - THEN T A, H  there tlast !
 2045: 	1 headers-named +!	\ Statistic
 2046: 	>in @ T name, H >in !
 2047:     THEN
 2048:     T cfalign here H tlastcfa !
 2049:     \ Old Symbol table sed-script
 2050: \    >in @ cr ." sym:s/CFA=" there 4 0.r ." /"  bl word count .sym ." /g" cr >in !
 2051:     HeaderGhost
 2052:     \ output symbol table to extra file
 2053:     [ [IFDEF] fd-symbol-table ]
 2054:       base @ hex there s>d <# 8 0 DO # LOOP #> fd-symbol-table write-file throw base !
 2055:       s" :" fd-symbol-table write-file throw
 2056:       dup >ghostname fd-symbol-table write-line throw
 2057:     [ [THEN] ]
 2058:     dup Last-Header-Ghost ! dup to lastghost
 2059:     dup >magic ^imm !     \ a pointer for immediate
 2060:     alias-mask flag!
 2061:     cross-doc-entry cross-tag-entry 
 2062:     setup-execution-semantics
 2063:     ;
 2064: 
 2065: \ this is the resolver information from ":"
 2066: \ resolving is done by ";"
 2067: Variable ;Resolve 1 cells allot
 2068: 
 2069: : hereresolve ( ghost -- )
 2070:   there resolve 0 ;Resolve ! ;
 2071: 
 2072: : Theader  ( "name" -- ghost )
 2073:   (THeader dup hereresolve ;
 2074: 
 2075: Variable aprim-nr -20 aprim-nr !
 2076: 
 2077: : copy-execution-semantics ( ghost-from ghost-dest -- )
 2078:   >r
 2079:   dup >exec @ r@ >exec !
 2080:   dup >exec2 @ r@ >exec2 !
 2081:   dup >exec-compile @ r@ >exec-compile !
 2082:   dup >ghost-xt @ r@ >ghost-xt !
 2083:   dup >created @ r@ >created !
 2084:   rdrop drop ;
 2085: 
 2086: >TARGET
 2087: 
 2088: : Alias    ( cfa -- ) \ name
 2089:   >in @ skip? IF  2drop  EXIT  THEN  >in !
 2090:   (THeader ( S xt ghost )
 2091:   2dup swap xt>ghost swap copy-execution-semantics
 2092:   over resolve T A, H alias-mask flag! ;
 2093: 
 2094: Variable last-prim-ghost
 2095: 0 last-prim-ghost !
 2096: 
 2097: : asmprimname, ( ghost -- : name ) 
 2098:   dup last-prim-ghost !
 2099:   >r
 2100:   here bl word count string, r@ >asm-name !
 2101:   aprim-nr @ r> >asm-dummyaddr ! ;
 2102: 
 2103: Defer setup-prim-semantics
 2104: 
 2105: : aprim   ( -- ) 
 2106:   THeader -1 aprim-nr +! aprim-nr @ T A, H
 2107:   asmprimname, 
 2108:   setup-prim-semantics ;
 2109: 
 2110: : aprim:   ( -- ) 
 2111:   -1 aprim-nr +! aprim-nr @
 2112:   Ghost tuck swap resolve <do:> swap tuck >magic !
 2113:   asmprimname, ;
 2114: 
 2115: : Alias:   ( cfa -- ) \ name
 2116:   >in @ skip? IF  2drop  EXIT  THEN  >in !
 2117:   dup 0< s" prims" T $has? H 0= and
 2118:   IF
 2119:       .sourcepos ." needs doer: " >in @ bl word count type >in ! cr
 2120:   THEN
 2121:   Ghost tuck swap resolve <do:> swap >magic ! ;
 2122: 
 2123: Variable prim#
 2124: : first-primitive ( n -- )  prim# ! ;
 2125: : Primitive  ( -- ) \ name
 2126:   >in @ skip? IF  2drop  EXIT  THEN  >in !
 2127:   dup 0< s" prims" T $has? H 0= and
 2128:   IF
 2129:      .sourcepos ." needs prim: " >in @ bl word count type >in ! cr
 2130:   THEN
 2131:   prim# @ (THeader ( S xt ghost )
 2132:   dup >ghost-flags <primitive> set-flag
 2133:   over resolve T A, H alias-mask flag!
 2134:   -1 prim# +! ;
 2135: >CROSS
 2136: 
 2137: \ Conditionals and Comments                            11may93jaw
 2138: 
 2139: \G saves the existing cond action, this is used for redefining in
 2140: \G instant
 2141: Variable cond-xt-old
 2142: 
 2143: : cond-target ( -- )
 2144: \G Compiles semantic of redefined cond into new one
 2145:   cond-xt-old @ compile, ; immediate restrict
 2146: 
 2147: : ;Cond
 2148:   postpone ;
 2149:   swap ! ;  immediate
 2150: 
 2151: : Cond: ( "name" -- ) 
 2152: \g defines a conditional or another word that must
 2153: \g be executed directly while compiling
 2154: \g these words have no interpretative semantics by default
 2155:   Ghost
 2156:   >exec-compile
 2157:   dup @ cond-xt-old !
 2158:   :NONAME ;
 2159: 
 2160: 
 2161: : Comment ( -- )
 2162:   >in @ Ghost swap >in ! ' swap 
 2163:   2dup >exec-compile ! >exec ! ;
 2164: 
 2165: Comment (       Comment \
 2166: 
 2167: \ compile                                              10may93jaw
 2168: 
 2169: : compile  ( "name" -- ) \ name
 2170: \  bl word gfind 0= ABORT" CROSS: Can't compile "
 2171:   ghost
 2172:   dup >exec-compile @ ?dup
 2173:   IF    nip compile,
 2174:   ELSE  postpone literal postpone gexecute  THEN ;  immediate restrict
 2175:             
 2176: >TARGET
 2177: 
 2178: : '  ( -- xt ) 
 2179: \G returns the target-cfa of a ghost
 2180:   bl word gfind 0= ABORT" CROSS: Ghost don't exists"
 2181:   g>xt ;
 2182: 
 2183: \ FIXME: this works for the current use cases, but is not
 2184: \ in all cases correct ;-) 
 2185: : comp' X ' 0 ;
 2186: 
 2187: Cond: [']  T ' H alit, ;Cond
 2188: 
 2189: >CROSS
 2190: 
 2191: : [T']
 2192: \ returns the target-cfa of a ghost, or compiles it as literal
 2193:   postpone [G'] state @ IF postpone g>xt ELSE g>xt THEN ; immediate
 2194: 
 2195: \ \ threading modell					13dec92py
 2196: \ modularized						14jun97jaw
 2197: 
 2198: T 2 cells H Value xt>body
 2199: 
 2200: : (>body)   ( cfa -- pfa ) 
 2201:   xt>body + ;						' (>body) plugin-of t>body
 2202: 
 2203: : fillcfa   ( usedcells -- )
 2204:   T cells H xt>body swap -
 2205:   assert1( dup 0 >= )
 2206:   0 ?DO 0 X c, tchar +LOOP ;
 2207: 
 2208: : (doer,)   ( ghost -- ) 
 2209:   addr, 1 fillcfa ;   					' (doer,) plugin-of doer,
 2210: 
 2211: : (docol,)  ( -- ) [G'] :docol (doer,) ;		' (docol,) plugin-of docol,
 2212: 
 2213: : (doprim,) ( -- )
 2214:   there xt>body + ca>native T a, H 1 fillcfa ;		' (doprim,) plugin-of doprim,
 2215: 
 2216: : (doeshandler,) ( -- ) 
 2217:   T cfalign H compile :doesjump T 0 , H ; 		' (doeshandler,) plugin-of doeshandler,
 2218: 
 2219: : (dodoes,) ( does-action-ghost -- )
 2220:   ]comp [G'] :dodoes gexecute comp[
 2221:   addr,
 2222:   \ the relocator in the c engine, does not like the
 2223:   \ does-address to marked for relocation
 2224:   [ T e? ec H 0= [IF] ] T here H tcell - reloff [ [THEN] ]
 2225:   2 fillcfa ;						' (dodoes,) plugin-of dodoes,
 2226: 
 2227: : (dlit,) ( n -- ) compile lit td, ;			' (dlit,) plugin-of dlit,
 2228: 
 2229: : (lit,) ( n -- )  s>d dlit, ;				' (lit,) plugin-of lit,
 2230: 
 2231: \ if we dont produce relocatable code alit, defaults to lit, jaw
 2232: \ this is just for convenience, so we don't have to define alit,
 2233: \ seperately for embedded systems....
 2234: T has? relocate H
 2235: [IF]
 2236: : (alit,) ( n -- )  compile lit T  a, H ;		' (alit,) plugin-of alit,
 2237: [ELSE]
 2238: : (alit,) ( n -- )  lit, ;				' (alit,) plugin-of alit,
 2239: [THEN]
 2240: 
 2241: : (fini,)         compile ;s ;				' (fini,) plugin-of fini,
 2242: 
 2243: [IFUNDEF] (code) 
 2244: Defer (code)
 2245: Defer (end-code)
 2246: [THEN]
 2247: 
 2248: >TARGET
 2249: : Code
 2250:   defempty?
 2251:   (THeader there resolve
 2252:   [ T e? prims H 0= [IF] T e? ITC H [ELSE] true [THEN] ] [IF]
 2253:   doprim, 
 2254:   [THEN]
 2255:   depth (code) ;
 2256: 
 2257: : Code:
 2258:   defempty?
 2259:     Ghost dup there ca>native resolve  <do:> swap >magic !
 2260:     depth (code) ;
 2261: 
 2262: : end-code
 2263:     (end-code)
 2264:     depth ?dup IF   1- <> ABORT" CROSS: Stack changed"
 2265:     ELSE true ABORT" CROSS: Stack empty" THEN
 2266:     ;
 2267: 
 2268: >CROSS
 2269: 
 2270: \ tLiteral                                             12dec92py
 2271: 
 2272: >TARGET
 2273: Cond: \G  T-\G ;Cond
 2274: 
 2275: Cond: Literal  ( n -- )   lit, ;Cond
 2276: Cond: ALiteral ( n -- )   alit, ;Cond
 2277: 
 2278: : Char ( "<char>" -- )  bl word char+ c@ ;
 2279: Cond: [Char]   ( "<char>" -- )  Char  lit, ;Cond
 2280: 
 2281: tchar 1 = [IF]
 2282: Cond: chars ;Cond 
 2283: [THEN]
 2284: 
 2285: \ some special literals					27jan97jaw
 2286: 
 2287: \ !! Known Bug: Special Literals and plug-ins work only correct
 2288: \ on 16 and 32 Bit Targets and 32 Bit Hosts!
 2289: 
 2290: \ This section could be done with dlit, now. But first I need
 2291: \ some test code JAW
 2292: 
 2293: Cond: MAXU
 2294:   tcell 1 cells u> 
 2295:   IF	compile lit tcell 0 ?DO FF T c, H LOOP 
 2296:   ELSE	ffffffff lit, THEN
 2297:   ;Cond
 2298: 
 2299: Cond: MINI
 2300:   tcell 1 cells u>
 2301:   IF	compile lit bigendian 
 2302:   	IF	80 T c, H tcell 1 ?DO 0 T c, H LOOP 
 2303:   	ELSE  	tcell 1 ?DO 0 T c, H LOOP 80 T c, H
 2304:   	THEN
 2305:   ELSE	tcell 2 = IF 8000 ELSE 80000000 THEN lit, THEN
 2306:   ;Cond
 2307:  
 2308: Cond: MAXI
 2309:  tcell 1 cells u>
 2310:  IF	compile lit bigendian 
 2311: 	IF 	7F T c, H tcell 1 ?DO FF T c, H LOOP
 2312: 	ELSE 	tcell 1 ?DO FF T c, H LOOP 7F T c, H
 2313:  	THEN
 2314:  ELSE	tcell 2 = IF 7fff ELSE 7fffffff THEN lit, THEN
 2315:  ;Cond
 2316: 
 2317: >CROSS
 2318: \ Target compiling loop                                12dec92py
 2319: \ ">tib trick thrown out                               10may93jaw
 2320: \ number? defined at the top                           11may93jaw
 2321: \ replaced >in by save-input				
 2322: 
 2323: : discard 0 ?DO drop LOOP ;
 2324: 
 2325: \ compiled word might leave items on stack!
 2326: : tcom ( x1 .. xn n name -- )
 2327: \  dup count type space
 2328:   gfind 
 2329:   IF    >r ( discard saved input state ) discard r>
 2330: 	dup >exec-compile @ ?dup
 2331:         IF   nip execute-exec-compile ELSE gexecute  THEN 
 2332: 	EXIT 
 2333:   THEN
 2334:   number? dup  
 2335:   IF	0> IF swap lit,  THEN  lit, discard
 2336:   ELSE	2drop restore-input throw Ghost gexecute THEN  ;
 2337: 
 2338: >TARGET
 2339: \ : ; DOES>                                            13dec92py
 2340: \ ]                                                     9may93py/jaw
 2341: 
 2342: : compiling-state ( -- )
 2343: \G set states to compililng
 2344:     Compiling comp-state !
 2345:     \ if we have a state in target, change it with the compile state
 2346:     [G'] state dup undefined? 0= 
 2347:     IF >ghost-xt @ execute X on ELSE drop THEN ;
 2348: 
 2349: : interpreting-state ( -- )
 2350: \G set states to interpreting
 2351:    \ if target has a state variable, change it according to our state
 2352:    [G'] state dup undefined? 0= 
 2353:    IF >ghost-xt @ execute X off ELSE drop THEN
 2354:    Interpreting comp-state ! ;
 2355: 
 2356: : ] 
 2357:     compiling-state
 2358:     BEGIN
 2359:         BEGIN save-input bl word
 2360:               dup c@ 0= WHILE drop discard refill 0=
 2361:               ABORT" CROSS: End of file while target compiling"
 2362:         REPEAT
 2363:         tcom
 2364:         compiling? 0=
 2365:     UNTIL ;
 2366: 
 2367: \ by the way: defining a second interpreter (a compiler-)loop
 2368: \             is not allowed if a system should be ans conform
 2369: 
 2370: : (:) ( ghost -- ) 
 2371: \ common factor of : and :noname. Prepare ;Resolve and start definition
 2372:    ;Resolve ! there ;Resolve cell+ !
 2373:    docol, ]comp  colon-start depth T ] H ;
 2374: 
 2375: : : ( -- colon-sys ) \ Name
 2376:   defempty?
 2377:   constflag off \ don't let this flag work over colon defs
 2378: 		\ just to go sure nothing unwanted happens
 2379:   >in @ skip? IF  drop skip-defs  EXIT  THEN  >in !
 2380:   (THeader (:) ;
 2381: 
 2382: : :noname ( -- colon-sys )
 2383:   X cfalign there 
 2384:   \ define a nameless ghost
 2385:   here ghostheader dup last-header-ghost ! dup to lastghost
 2386:   (:) ;  
 2387: 
 2388: Cond: EXIT ( -- )   compile ;S  ;Cond
 2389: 
 2390: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
 2391: 
 2392: >CROSS
 2393: : LastXT ;Resolve @ 0= abort" CROSS: no definition for LastXT"
 2394:          ;Resolve cell+ @ ;
 2395: 
 2396: >TARGET
 2397: 
 2398: Cond: recurse ( -- ) Last-Header-Ghost @ gexecute ;Cond
 2399: 
 2400: Cond: ; ( -- ) 
 2401: 	depth ?dup 
 2402: 	IF   1- <> ABORT" CROSS: Stack changed"
 2403: 	ELSE true ABORT" CROSS: Stack empty" 
 2404: 	THEN
 2405: 	colon-end
 2406: 	fini,
 2407: 	comp[
 2408: 	;Resolve @ 
 2409: 	IF 	;Resolve @ ;Resolve cell+ @ resolve 
 2410: 		['] colon-resolved ;Resolve @ >comp !
 2411: 	THEN
 2412: 	interpreting-state
 2413: 	;Cond
 2414: 
 2415: Cond: [ ( -- ) interpreting-state ;Cond
 2416: 
 2417: >CROSS
 2418: 
 2419: Create GhostDummy ghostheader
 2420: <res> GhostDummy >magic !
 2421: 
 2422: : !does ( does-action -- )
 2423: \ !! zusammenziehen und dodoes, machen!
 2424:     tlastcfa @ [G'] :dovar killref
 2425: \    tlastcfa @ dup there >r tdp ! compile :dodoes r> tdp ! T cell+ ! H ;
 2426: \ !! geht so nicht, da dodoes, ghost will!
 2427:     GhostDummy >link ! GhostDummy 
 2428:     tlastcfa @ >tempdp dodoes, tempdp> ;
 2429: 
 2430: 
 2431: Defer instant-interpret-does>-hook
 2432: 
 2433: : resolve-does>-part ( -- )
 2434: \ resolve words made by builders
 2435:   Last-Header-Ghost @ >do:ghost @ ?dup 
 2436:   IF    there resolve 
 2437:         \ TODO: set special DOES> resolver action here
 2438:   THEN ;
 2439: 
 2440: >TARGET
 2441: Cond: DOES>
 2442:         compile (does>) doeshandler,
 2443:         resolve-does>-part
 2444:         ;Cond
 2445: 
 2446: : DOES> switchrom doeshandler, T here H !does 
 2447:   instant-interpret-does>-hook
 2448:   depth T ] H ;
 2449: 
 2450: >CROSS
 2451: \ Creation                                              01nov92py
 2452: 
 2453: \ Builder                                               11may93jaw
 2454: 
 2455: 0 Value built
 2456: 
 2457: : Builder    ( Create-xt do-ghost "name" -- )
 2458: \ builds up a builder in current vocabulary
 2459: \ create-xt is executed when word is interpreted
 2460: \ do:-xt is executed when the created word from builder is executed
 2461: \ for do:-xt an additional entry after the normal ghost-entrys is used
 2462: 
 2463:   ghost to built 
 2464:   built >created @ 0= IF
 2465:     built >created on
 2466:     ['] prim-resolved built >comp ! 
 2467:   THEN ;
 2468: 
 2469: : gdoes,  ( ghost -- )
 2470: \ makes the codefield for a word that is built
 2471:   >do:ghost @ dup undefined? 0=
 2472:   IF
 2473: 	dup >magic @ <do:> =
 2474: 	IF 	 doer, 
 2475: 	ELSE	dodoes,
 2476: 	THEN
 2477: 	EXIT
 2478:   THEN
 2479: \  compile :dodoes gexecute
 2480: \  T here H tcell - reloff 
 2481:   2 refered 
 2482:   0 fillcfa
 2483:   ;
 2484: 
 2485: : takeover-x-semantics ( S constructor-ghost new-ghost -- )
 2486: \g stores execution semantic and compilation semantic in the built word
 2487:    swap >do:ghost @ 
 2488:    \ we use the >exec2 field for the semantic of a created word,
 2489:    \ using exec or exec2 makes no difference for normal cross-compilation
 2490:    \ but is usefull for instant where the exec field is already
 2491:    \ defined (e.g. Vocabularies)
 2492:    2dup >exec @ swap >exec2 ! 
 2493:    >comp @ swap >comp ! ;
 2494: 
 2495: : TCreate ( <name> -- )
 2496:   create-forward-warn
 2497:   IF ['] reswarn-forward IS resolve-warning THEN
 2498:   executed-ghost @ (Theader
 2499:   dup >created on
 2500:   2dup takeover-x-semantics hereresolve gdoes, ;
 2501: 
 2502: : RTCreate ( <name> -- )
 2503: \ creates a new word with code-field in ram
 2504:   create-forward-warn
 2505:   IF ['] reswarn-forward IS resolve-warning THEN
 2506:   \ make Alias
 2507:   executed-ghost @ (THeader 
 2508:   dup >created on
 2509:   2dup takeover-x-semantics
 2510:   there 0 T a, H alias-mask flag!
 2511:   \ store poiter to code-field
 2512:   switchram T cfalign H
 2513:   there swap T ! H
 2514:   there tlastcfa ! 
 2515:   hereresolve gdoes, ;
 2516: 
 2517: : Build:  ( -- [xt] [colon-sys] )
 2518:   :noname postpone TCreate ;
 2519: 
 2520: : BuildSmart:  ( -- [xt] [colon-sys] )
 2521:   :noname
 2522:   [ T has? rom H [IF] ]
 2523:   postpone RTCreate
 2524:   [ [ELSE] ]
 2525:   postpone TCreate 
 2526:   [ [THEN] ] ;
 2527: 
 2528: : ;Build
 2529:   postpone ; built >exec ! ; immediate
 2530: 
 2531: : gdoes>  ( ghost -- addr flag )
 2532:   executed-ghost @ g>body ;
 2533: 
 2534: \ DO: ;DO                                               11may93jaw
 2535: 
 2536: : do:ghost! ( ghost -- ) built >do:ghost ! ;
 2537: : doexec! ( xt -- ) built >do:ghost @ >exec ! ;
 2538: 
 2539: : DO:     ( -- [xt] [colon-sys] )
 2540:   here ghostheader do:ghost!
 2541:   :noname postpone gdoes> ;
 2542: 
 2543: : by:     ( -- [xt] [colon-sys] ) \ name
 2544:   Ghost do:ghost!
 2545:   :noname postpone gdoes> ;
 2546: 
 2547: : ;DO ( [xt] [colon-sys] -- )
 2548:   postpone ; doexec! ; immediate
 2549: 
 2550: : by      ( -- ) \ Name
 2551:   Ghost >do:ghost @ do:ghost! ;
 2552: 
 2553: : compile: ( --[xt] [colon-sys] )
 2554: \G defines a compile time action for created words
 2555: \G by this builder
 2556:   :noname ;
 2557: 
 2558: : ;compile ( [xt] [colon-sys] -- )
 2559:   postpone ; built >do:ghost @ >comp ! ; immediate
 2560: 
 2561: \ Variables and Constants                              05dec92py
 2562: 
 2563: Builder (Constant)
 2564: Build:  ( n -- ) ;Build
 2565: by: :docon ( target-body-addr -- n ) T @ H ;DO
 2566: 
 2567: Builder Constant
 2568: Build:  ( n -- ) T , H ;Build
 2569: by (Constant)
 2570: 
 2571: Builder AConstant
 2572: Build:  ( n -- ) T A, H ;Build
 2573: by (Constant)
 2574: 
 2575: Builder 2Constant
 2576: Build:  ( d -- ) T , , H ;Build
 2577: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
 2578: 
 2579: Builder Create
 2580: BuildSmart: ;Build
 2581: by: :dovar ( target-body-addr -- addr ) ;DO
 2582: 
 2583: Builder Variable
 2584: T has? rom H [IF]
 2585: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , H ( switchrom ) ;Build
 2586: by (Constant)
 2587: [ELSE]
 2588: Build: T 0 , H ;Build
 2589: by Create
 2590: [THEN]
 2591: 
 2592: Builder 2Variable
 2593: T has? rom H [IF]
 2594: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , 0 , H ( switchrom ) ;Build
 2595: by (Constant)
 2596: [ELSE]
 2597: Build: T 0 , 0 , H ;Build
 2598: by Create
 2599: [THEN]
 2600: 
 2601: Builder AVariable
 2602: T has? rom H [IF]
 2603: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 A, H ( switchrom ) ;Build
 2604: by (Constant)
 2605: [ELSE]
 2606: Build: T 0 A, H ;Build
 2607: by Create
 2608: [THEN]
 2609: 
 2610: \ User variables                                       04may94py
 2611: 
 2612: Variable tup  0 tup !
 2613: Variable tudp 0 tudp !
 2614: 
 2615: : u,  ( n -- udp )
 2616:   tup @ tudp @ + T  ! H
 2617:   tudp @ dup T cell+ H tudp ! ;
 2618: 
 2619: : au, ( n -- udp )
 2620:   tup @ tudp @ + T A! H
 2621:   tudp @ dup T cell+ H tudp ! ;
 2622: 
 2623: Builder User
 2624: Build: 0 u, X , ;Build
 2625: by: :douser ( ghost -- up-addr )  X @ tup @ + ;DO
 2626: 
 2627: Builder 2User
 2628: Build: 0 u, X , 0 u, drop ;Build
 2629: by User
 2630: 
 2631: Builder AUser
 2632: Build: 0 au, X , ;Build
 2633: by User
 2634: 
 2635: Builder (Value)
 2636: Build:  ( n -- ) ;Build
 2637: by: :docon ( target-body-addr -- n ) T @ H ;DO
 2638: 
 2639: Builder Value
 2640: BuildSmart: T , H ;Build
 2641: by (Value)
 2642: 
 2643: Builder AValue
 2644: BuildSmart: T A, H ;Build
 2645: by (Value)
 2646: 
 2647: Defer texecute
 2648: 
 2649: Builder Defer
 2650: BuildSmart:  ( -- ) [T'] noop T A, H ;Build
 2651: by: :dodefer ( ghost -- ) X @ texecute ;DO
 2652: 
 2653: Builder interpret/compile:
 2654: Build: ( inter comp -- ) swap T immediate A, A, H ;Build
 2655: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
 2656: 
 2657: \ Sturctures                                           23feb95py
 2658: 
 2659: : nalign ( addr1 n -- addr2 )
 2660: \ addr2 is the aligned version of addr1 wrt the alignment size n
 2661:  1- tuck +  swap invert and ;
 2662: 
 2663: 
 2664: Builder (Field)
 2665: Build: ;Build
 2666: by: :dofield T @ H + ;DO
 2667: 
 2668: Builder Field
 2669: Build: ( align1 offset1 align size "name" --  align2 offset2 )
 2670:     rot dup T , H ( align1 align size offset1 )
 2671:     + >r nalign r> ;Build
 2672: by (Field)
 2673: 
 2674: >TARGET
 2675: : struct  T 1 chars 0 H ;
 2676: : end-struct  T 2Constant H ;
 2677: 
 2678: : cell% ( n -- size align )
 2679:     T 1 cells H dup ;
 2680: >CROSS
 2681: 
 2682: \ Input-Methods                                            01py
 2683: 
 2684: Builder input-method
 2685: Build: ( m v -- m' v )  dup T , cell+ H ;Build
 2686: DO:  abort" Not in cross mode" ;DO
 2687: 
 2688: Builder input-var
 2689: Build: ( m v size -- m v' )  over T , H + ;Build
 2690: DO:  abort" Not in cross mode" ;DO
 2691: 
 2692: \ Peephole optimization					05sep01jaw
 2693: 
 2694: \ this section defines different compilation
 2695: \ actions for created words
 2696: \ this will help the peephole optimizer
 2697: \ I (jaw) took this from bernds lates cross-compiler
 2698: \ changes but seperated it from the original
 2699: \ Builder words. The final plan is to put this
 2700: \ into a seperate file, together with the peephole
 2701: \ optimizer for cross
 2702: 
 2703: 
 2704: T has? peephole H [IF]
 2705: 
 2706: >CROSS
 2707: : (callc) compile call T >body a, H ;		' (callc) plugin-of colon,
 2708: 
 2709: \ if we want this, we have to spilt aconstant
 2710: \ and constant!!
 2711: \ Builder (Constant)
 2712: \ compile: g>body X @ lit, ;compile
 2713: 
 2714: Builder (Constant)
 2715: compile: g>body alit, compile @ ;compile
 2716: 
 2717: Builder (Value)
 2718: compile: g>body alit, compile @ ;compile
 2719: 
 2720: \ this changes also Variable, AVariable and 2Variable
 2721: Builder Create
 2722: \ compile: g>body alit, ;compile
 2723: 
 2724: Builder User
 2725: compile: g>body compile useraddr T @ , H ;compile
 2726: 
 2727: Builder Defer
 2728: compile: g>body alit, compile @ compile execute ;compile
 2729: 
 2730: Builder (Field)
 2731: compile: g>body T @ H lit, compile + ;compile
 2732: 
 2733: [THEN]
 2734: 
 2735: \ structural conditionals                              17dec92py
 2736: 
 2737: >CROSS
 2738: : (ncontrols?) ( n -- ) 
 2739: \g We expect n open control structures
 2740:   depth over u<= 
 2741:   ABORT" CROSS: unstructured, stack underflow"
 2742:   0 ?DO I pick 0= 
 2743:         ABORT" CROSS: unstructured" 
 2744:   LOOP ;					' (ncontrols?) plugin-of ncontrols?
 2745: 
 2746: \ : ?struc      ( flag -- )       ABORT" CROSS: unstructured " ;
 2747: \ : sys?        ( sys -- sys )    dup 0= ?struc ;
 2748: 
 2749: : >mark       ( -- sys )        T here  ( dup ." M" hex. ) 0 , H ;
 2750: 
 2751: : branchoffset ( src dest -- )  - tchar / ; \ ?? jaw
 2752: 
 2753: : >resolve    ( sys -- )        
 2754: 	X here ( dup ." >" hex. ) over branchoffset swap X ! ;
 2755: 
 2756: : <resolve    ( sys -- )
 2757: 	X here ( dup ." <" hex. ) branchoffset X , ;
 2758: 
 2759: :noname compile branch X here branchoffset X , ;
 2760:   IS branch, ( target-addr -- )
 2761: :noname compile ?branch X here branchoffset X , ;
 2762:   IS ?branch, ( target-addr -- )
 2763: :noname compile branch T here 0 , H ;
 2764:   IS branchmark, ( -- branchtoken )
 2765: :noname compile ?branch T here 0 , H ;
 2766:   IS ?branchmark, ( -- branchtoken )
 2767: :noname T here 0 , H ;
 2768:   IS ?domark, ( -- branchtoken )
 2769: :noname dup X @ ?struc X here over branchoffset swap X ! ;
 2770:   IS branchtoresolve, ( branchtoken -- )
 2771: :noname branchto, X here ;
 2772:   IS branchtomark, ( -- target-addr )
 2773: 
 2774: >TARGET
 2775: 
 2776: \ Structural Conditionals                              12dec92py
 2777: 
 2778: \ CLEANUP Cond: BUT       sys? swap ;Cond
 2779: \ CLEANUP Cond: YET       sys? dup ;Cond
 2780: 
 2781: >CROSS
 2782: 
 2783: Variable tleavings 0 tleavings !
 2784: 
 2785: : (done) ( addr -- )
 2786:     tleavings @
 2787:     BEGIN  dup
 2788:     WHILE
 2789: 	>r dup r@ cell+ @ \ address of branch
 2790: 	u> 0=	   \ lower than DO?	
 2791:     WHILE
 2792: 	r@ 2 cells + @ \ branch token
 2793: 	branchtoresolve,
 2794: 	r@ @ r> free throw
 2795:     REPEAT  r>  THEN
 2796:     tleavings ! drop ;
 2797: 
 2798: >TARGET
 2799: 
 2800: \ What for? ANS? JAW Cond: DONE   ( addr -- )  (done) ;Cond
 2801: 
 2802: >CROSS
 2803: : (leave) ( branchtoken -- )
 2804:     3 cells allocate throw >r
 2805:     T here H r@ cell+ !
 2806:     r@ 2 cells + !
 2807:     tleavings @ r@ !
 2808:     r> tleavings ! ;
 2809: >TARGET
 2810: 
 2811: : (leave,) ( -- ) 
 2812:   branchmark, (leave) ; 			' (leave,) plugin-of leave,
 2813: 
 2814: : (?leave,) ( -- )
 2815:   compile 0= ?branchmark, (leave) ; 		' (?leave,) plugin-of ?leave,
 2816: 
 2817: Cond: LEAVE     leave, ;Cond
 2818: Cond: ?LEAVE    ?leave, ;Cond
 2819: 
 2820: >CROSS
 2821: \ !!JW ToDo : Move to general tools section
 2822: 
 2823: : to1 ( x1 x2 xn n -- addr )
 2824: \G packs n stack elements in am allocated memory region
 2825:    dup dup 1+ cells allocate throw dup >r swap 1+
 2826:    0 DO tuck ! cell+ LOOP
 2827:    drop r> ;
 2828: 
 2829: : 1to ( addr -- x1 x2 xn )
 2830: \G unpacks the elements saved by to1
 2831:     dup @ swap over cells + swap
 2832:     0 DO  dup @ swap 1 cells -  LOOP
 2833:     free throw ;
 2834: 
 2835: : loop]     branchto, dup <resolve tcell - (done) ;
 2836: 
 2837: : skiploop] ?dup IF branchto, branchtoresolve, THEN ;
 2838: 
 2839: >TARGET
 2840: 
 2841: \ Structural Conditionals                              12dec92py
 2842: 
 2843: : (cs-swap) ( x1 x2 -- x2 x1 )
 2844:   swap ;					' (cs-swap) plugin-of cs-swap
 2845: 
 2846: : (ahead,) branchmark, ; 			' (ahead,) plugin-of ahead,
 2847: 
 2848: : (if,) ?branchmark, ; 				' (if,) plugin-of if,
 2849: 
 2850: : (then,) branchto, branchtoresolve, ; 		' (then,) plugin-of then,
 2851: 
 2852: : (else,) ( ahead ) branchmark, 
 2853:           swap 
 2854:           ( then ) branchto, branchtoresolve, ;	' (else,) plugin-of else,
 2855: 
 2856: : (begin,) branchtomark, ; 			' (begin,) plugin-of begin,
 2857: 
 2858: : (while,) ( if ) ?branchmark,
 2859:            swap ; 				' (while,) plugin-of while,
 2860: 
 2861: : (again,) branch, ;				' (again,) plugin-of again,
 2862: 
 2863: : (until,) ?branch, ;				' (until,) plugin-of until,
 2864: 
 2865: : (repeat,) ( again ) branch,
 2866:             ( then ) branchto, branchtoresolve, ; ' (repeat,) plugin-of repeat,
 2867: 
 2868: : (case,)   ( -- n )
 2869:   0 ;						' (case,) plugin-of case,
 2870: 
 2871: : (of,) ( n -- x1 n )
 2872:   1+ >r 
 2873:   compile over compile = 
 2874:   if, compile drop r> ;				' (of,) plugin-of of,
 2875: 
 2876: : (endof,) ( x1 n -- x2 n )
 2877:   >r 1 ncontrols? else, r> ;			' (endof,) plugin-of endof,
 2878: 
 2879: : (endcase,) ( x1 .. xn n -- )
 2880:   compile drop 0 ?DO 1 ncontrols? then, LOOP ;	' (endcase,) plugin-of endcase,
 2881: 
 2882: >TARGET
 2883: Cond: AHEAD     ahead, ;Cond
 2884: Cond: IF        if,  ;Cond
 2885: Cond: THEN      1 ncontrols? then, ;Cond
 2886: Cond: ENDIF     1 ncontrols? then, ;Cond
 2887: Cond: ELSE      1 ncontrols? else, ;Cond
 2888: 
 2889: Cond: BEGIN     begin, ;Cond
 2890: Cond: WHILE     1 ncontrols? while, ;Cond
 2891: Cond: AGAIN     1 ncontrols? again, ;Cond
 2892: Cond: UNTIL     1 ncontrols? until, ;Cond
 2893: Cond: REPEAT    2 ncontrols? repeat, ;Cond
 2894: 
 2895: Cond: CASE      case, ;Cond
 2896: Cond: OF        of, ;Cond
 2897: Cond: ENDOF     endof, ;Cond
 2898: Cond: ENDCASE   endcase, ;Cond
 2899: 
 2900: \ Structural Conditionals                              12dec92py
 2901: 
 2902: : (do,) ( -- target-addr )
 2903:   \ ?? i think 0 is too much! jaw
 2904:     0 compile (do)
 2905:     branchtomark,  2 to1 ;			' (do,) plugin-of do,
 2906: 
 2907: \ alternative for if no ?do
 2908: \ : (do,)
 2909: \     compile 2dup compile = compile IF
 2910: \     compile 2drop compile ELSE
 2911: \     compile (do) branchtomark, 2 to1 ;
 2912:     
 2913: : (?do,) ( -- target-addr )
 2914:     0 compile (?do)  ?domark, (leave)
 2915:     branchtomark,  2 to1 ;			' (?do,) plugin-of ?do,
 2916: 
 2917: : (for,) ( -- target-addr )
 2918:   compile (for) branchtomark, ;			' (for,) plugin-of for,
 2919: 
 2920: : (loop,) ( target-addr -- )
 2921:   1to compile (loop)  loop] 
 2922:   compile unloop skiploop] ;			' (loop,) plugin-of loop,
 2923: 
 2924: : (+loop,) ( target-addr -- )
 2925:   1to compile (+loop)  loop] 
 2926:   compile unloop skiploop] ;			' (+loop,) plugin-of +loop,
 2927: 
 2928: : (next,) 
 2929:   compile (next)  loop] compile unloop ;	' (next,) plugin-of next,
 2930: 
 2931: Cond: DO      	do, ;Cond
 2932: Cond: ?DO     	?do, ;Cond
 2933: Cond: FOR	for, ;Cond
 2934: 
 2935: Cond: LOOP	1 ncontrols? loop, ;Cond
 2936: Cond: +LOOP	1 ncontrols? +loop, ;Cond
 2937: Cond: NEXT	1 ncontrols? next, ;Cond
 2938: 
 2939: \ String words                                         23feb93py
 2940: 
 2941: : ,"            [char] " parse ht-string, X align ;
 2942: 
 2943: Cond: ."        compile (.")     T ," H ;Cond
 2944: Cond: S"        compile (S")     T ," H ;Cond
 2945: Cond: C"        compile (C")     T ," H ;Cond
 2946: Cond: ABORT"    compile (ABORT") T ," H ;Cond
 2947: 
 2948: Cond: IS        T ' >body H compile ALiteral compile ! ;Cond
 2949: : IS            T >address ' >body ! H ;
 2950: Cond: TO        T ' >body H compile ALiteral compile ! ;Cond
 2951: : TO            T ' >body ! H ;
 2952: 
 2953: Cond: defers	T ' >body @ compile, H ;Cond
 2954: 
 2955: \ LINKED ERR" ENV" 2ENV"                                18may93jaw
 2956: 
 2957: \ linked list primitive
 2958: : linked        X here over X @ X A, swap X ! ;
 2959: : chained	T linked A, H ;
 2960: 
 2961: : err"   s" ErrLink linked" evaluate T , H
 2962:          [char] " parse ht-string, X align ;
 2963: 
 2964: : env"  [char] " parse s" EnvLink linked" evaluate
 2965:         ht-string, X align X , ;
 2966: 
 2967: : 2env" [char] " parse s" EnvLink linked" evaluate
 2968:         here >r ht-string, X align X , X ,
 2969:         r> dup T c@ H 80 and swap T c! H ;
 2970: 
 2971: \ compile must be last                                 22feb93py
 2972: 
 2973: Cond: [compile] ( -- ) \ name
 2974: \g For immediate words, works even if forward reference
 2975:       bl word gfind 0= ABORT" CROSS: Can't compile"
 2976:       (gexecute) ;Cond
 2977: 	   
 2978: Cond: postpone ( -- ) \ name
 2979:       bl word gfind 0= ABORT" CROSS: Can't compile"
 2980:       dup >magic @ <fwd> =
 2981:       ABORT" CROSS: Can't postpone on forward declaration"
 2982:       dup >magic @ <imm> =
 2983:       IF   (gexecute)
 2984:       ELSE compile (compile) addr, THEN ;Cond
 2985: 	   
 2986: \ save-cross                                           17mar93py
 2987: 
 2988: hex
 2989: 
 2990: >CROSS
 2991: Create magic  s" Gforth2x" here over allot swap move
 2992: 
 2993: bigendian 1+ \ strangely, in magic big=0, little=1
 2994: tcell 1 = 0 and or
 2995: tcell 2 = 2 and or
 2996: tcell 4 = 4 and or
 2997: tcell 8 = 6 and or
 2998: tchar 1 = 00 and or
 2999: tchar 2 = 28 and or
 3000: tchar 4 = 50 and or
 3001: tchar 8 = 78 and or
 3002: magic 7 + c!
 3003: 
 3004: : save-cross ( "image-name" "binary-name" -- )
 3005:   bl parse ." Saving to " 2dup type cr
 3006:   w/o bin create-file throw >r
 3007:   TNIL IF
 3008:       s" #! "           r@ write-file throw
 3009:       bl parse          r@ write-file throw
 3010:       s"  --image-file" r@ write-file throw
 3011:       #lf       r@ emit-file throw
 3012:       r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
 3013:       ?do
 3014: 	  bl over emit-file throw
 3015:       loop
 3016:       drop
 3017:       magic 8       r@ write-file throw \ write magic
 3018:   ELSE
 3019:       bl parse 2drop
 3020:   THEN
 3021:   image @ there 
 3022:   r@ write-file throw \ write image
 3023:   TNIL IF
 3024:       bit$  @ there 1- tcell>bit rshift 1+
 3025:                 r@ write-file throw \ write tags
 3026:   THEN
 3027:   r> close-file throw ;
 3028: 
 3029: : save-region ( addr len -- )
 3030:   bl parse w/o bin create-file throw >r
 3031:   swap >image swap r@ write-file throw
 3032:   r> close-file throw ;
 3033: 
 3034: \ save-asm-region                         		29aug01jaw
 3035: 
 3036: Variable name-ptr
 3037: Create name-buf 200 chars allot
 3038: : init-name-buf name-buf name-ptr ! ;
 3039: : nb, name-ptr @ c! 1 chars name-ptr +! ;
 3040: : $nb, ( adr len -- ) bounds ?DO I c@ nb, LOOP ;
 3041: : @nb name-ptr @ name-buf tuck - ;
 3042: 
 3043: \ stores a usefull string representation of the character
 3044: \ in the name buffer
 3045: : name-char, ( c -- )
 3046:   dup 'a 'z 1+ within IF nb, EXIT THEN
 3047:   dup 'A 'Z 1+ within IF $20 + nb, EXIT THEN
 3048:   dup '0 '9 1+ within IF nb, EXIT THEN
 3049:   CASE '+ OF s" _PLUS" $nb, ENDOF
 3050:        '- OF s" _MINUS" $nb, ENDOF
 3051:        '* OF s" _STAR" $nb, ENDOF
 3052:        '/ OF s" _SLASH" $nb, ENDOF
 3053:        '' OF s" _TICK" $nb, ENDOF
 3054:        '( OF s" _OPAREN" $nb, ENDOF
 3055:        ') OF s" _CPAREN" $nb, ENDOF
 3056:        '[ OF s" _OBRACKET" $nb, ENDOF
 3057:        '] OF s" _CBRACKET" $nb, ENDOF
 3058:        '! OF s" _STORE" $nb, ENDOF
 3059:        '@ OF s" _FETCH" $nb, ENDOF
 3060:        '> OF s" _GREATER" $nb, ENDOF
 3061:        '< OF s" _LESS" $nb, ENDOF
 3062:        '= OF s" _EQUAL" $nb, ENDOF
 3063:        '# OF s" _HASH" $nb, ENDOF
 3064:        '? OF s" _QUEST" $nb, ENDOF
 3065:        ': OF s" _COL" $nb, ENDOF
 3066:        '; OF s" _SEMICOL" $nb, ENDOF
 3067:        ', OF s" _COMMA" $nb, ENDOF
 3068:        '. OF s" _DOT" $nb, ENDOF
 3069:        '" OF s" _DQUOT" $nb, ENDOF
 3070:        dup 
 3071:        base @ >r hex s>d <# #s 'X hold '_ hold #> $nb, r> base !
 3072:   ENDCASE ;
 3073:  
 3074: : label-from-ghostname ( ghost -- addr len )
 3075:   dup >ghostname init-name-buf 'L nb, bounds 
 3076:   ?DO I c@ name-char, LOOP 
 3077:   \ we add the address to a name to make in unique
 3078:   \ because one name may appear more then once
 3079:   \ there are names (e.g. boot) that may be reference from other
 3080:   \ assembler source files, so we declare them as unique
 3081:   \ and don't add the address suffix
 3082:   dup >ghost-flags @ <unique> and 0= 
 3083:   IF   s" __" $nb, >link @ base @ >r hex 0 <# #s 'L hold #> r> base ! $nb, 
 3084:   ELSE drop 
 3085:   THEN
 3086:   @nb ;
 3087: 
 3088: : label-from-ghostnameXX ( ghost -- addr len )
 3089: \ same as (label-from-ghostname) but caches generated names
 3090:   dup >asm-name @ ?dup IF nip count EXIT THEN
 3091:  \ dup >r (label-from-ghostname) 2dup
 3092:   align here >r string, align
 3093:   r> r> >asm-name ! ;
 3094: 
 3095: : primghostdiscover ( xt -- ghost true | xt false )
 3096:   dup 0= IF false EXIT THEN
 3097:   >r last-prim-ghost
 3098:   BEGIN @ dup
 3099:   WHILE dup >asm-dummyaddr @ r@ =
 3100:         IF rdrop true EXIT THEN
 3101:   REPEAT
 3102:   drop r> false ;
 3103: 
 3104: : gdiscover2 ( xt -- ghost true | xt false ) 
 3105:   dup taddr>region 0= IF false EXIT THEN
 3106:   dup (>regiontype) @ dup 0= IF drop false EXIT THEN
 3107:   addr-xt-ghost @ dup 0= IF drop false EXIT THEN
 3108:   nip true ;
 3109: \  dup >ghost-name @ IF nip true ELSE drop false THEN ;
 3110: 
 3111: \ generates a label name for the target address
 3112: : generate-label-name ( taddr -- addr len )
 3113:   gdiscover2
 3114:   IF dup >magic @ <do:> =
 3115:      IF >asm-name @ count EXIT THEN
 3116:      label-from-ghostname
 3117:   ELSE
 3118:      primghostdiscover
 3119:      IF   >asm-name @ count 
 3120:      ELSE base @ >r hex 0 <# #s 'L hold #> r> base !
 3121:      THEN
 3122:   THEN ;
 3123: 
 3124: Variable outfile-fd
 3125: 
 3126: : $out ( adr len -- ) outfile-fd @ write-file throw  ;
 3127: : nlout newline $out ;
 3128: : .ux ( n -- ) 
 3129:   base @ hex swap 0 <# #S #> $out base ! ;
 3130: 
 3131: : save-asm-region-part-aligned ( taddr len -- 'taddr 'len )
 3132:   dup cell/ 0 
 3133:   ?DO nlout s"    .word " $out over @relbit 
 3134:       IF   over X @ generate-label-name $out
 3135:       ELSE over X @ s" 0x0" $out .ux
 3136:       THEN
 3137:       tcell /string
 3138:   LOOP ;
 3139: 
 3140: : print-bytes ( taddr len n -- taddr' len' )
 3141:   over min dup 0> 
 3142:   IF   nlout s"    .byte " $out 0 
 3143:        ?DO  I 0> IF s" , " $out THEN
 3144:             over X c@ s" 0x0" $out .ux 1 /string 
 3145:        LOOP 
 3146:   THEN ;
 3147: 
 3148: : save-asm-region-part ( addr len -- )
 3149:   over dup X aligned swap - ?dup
 3150:   IF   print-bytes THEN
 3151:   save-asm-region-part-aligned
 3152:   dup dup X aligned swap - ?dup
 3153:   IF   2 pick @relbit ABORT" relocated field splitted"
 3154:        print-bytes
 3155:   THEN
 3156:   2drop ;
 3157: 
 3158: : print-label ( taddr -- )
 3159:   nlout generate-label-name $out s" :" $out ;
 3160: 
 3161: : snl-calc ( taddr taddr2 -- )
 3162:   tuck over - ;
 3163: 
 3164: : skip-nolables ( taddr -- taddr2 taddr len )
 3165: \G skips memory region where no lables are defined
 3166: \G starting from taddr+1
 3167: \G Labels will be introduced for each reference mark
 3168: \G in addr-refs.
 3169: \G This word deals with lables at byte addresses as well.
 3170: \G The main idea is to have an intro part which
 3171: \G skips until the next cell boundary, the middle part
 3172: \G which skips whole cells very efficiently and the third
 3173: \G part which skips the bytes to the label in a cell
 3174:   dup 1+ dup (>regiontype) 
 3175:   ( S taddr taddr-realstart type-addr )
 3176:   dup @ dup IF addr-refs @ THEN
 3177:   swap >r
 3178:   over align+ tuck tcell swap - rshift swap 0
 3179:   DO dup 1 and 
 3180:      IF drop rdrop snl-calc UNLOOP EXIT THEN 
 3181:      2/ swap 1+ swap 
 3182:   LOOP
 3183:   drop r> cell+
 3184:   ( S .. taddr2 type-addr ) dup
 3185:   BEGIN dup @ dup IF addr-refs @ THEN 0= WHILE cell+ REPEAT
 3186:   dup >r swap - 1 cells / tcell * + r>
 3187:   ( S .. taddr2+skiplencells type-addr )
 3188:   @ addr-refs @ 1 tcell lshift or
 3189:   BEGIN dup 1 and 0= WHILE swap 1+ swap 2/ REPEAT drop
 3190:   ( S .. taddr2+skiplencells+skiplenbytes )
 3191:   snl-calc ;
 3192: 
 3193: : insert-label ( taddr -- )
 3194:   dup 0= IF drop EXIT THEN
 3195:   \ ignore everything which points outside our memory regions
 3196:   \ maybe a primitive pointer or whatever
 3197:   dup taddr>region 0= IF drop EXIT THEN
 3198:   dup >r (>regiontype) define-addr-struct addr-refs dup @ 
 3199:   r> tcell 1- and 1 swap lshift or swap ! ;
 3200: 
 3201: \ this generates a sorted list of addresses which must be labels
 3202: \ it scans therefore a whole region
 3203: : generate-label-list-region ( taddr len -- )
 3204:   BEGIN over @relbit IF over X @ insert-label THEN
 3205:         tcell /string dup 0< 
 3206:   UNTIL 2drop ;
 3207: 
 3208: : generate-label-list ( -- )
 3209:   region-link
 3210:   BEGIN @ dup WHILE 
 3211:         dup 0 >rlink - extent 
 3212:         ?dup IF generate-label-list-region ELSE drop THEN
 3213:   REPEAT drop ;
 3214: 
 3215: : create-outfile ( addr len -- )
 3216:   w/o bin create-file throw outfile-fd ! ;
 3217: 
 3218: : close-outfile ( -- )
 3219:   outfile-fd @ close-file throw ;
 3220: 
 3221: : (save-asm-region) ( region -- )
 3222:   \ ." label list..."
 3223:   generate-label-list
 3224:   \ ." ok!" cr
 3225:   extent ( S taddr len )
 3226:   over insert-label
 3227:   2dup + dup insert-label >r ( R end-label )
 3228:   ( S taddr len ) drop
 3229:   BEGIN
 3230:      dup print-label
 3231:      dup r@ <> WHILE
 3232:      skip-nolables save-asm-region-part
 3233:   REPEAT drop rdrop ;
 3234: 
 3235: : lineout ( addr len -- )
 3236:   outfile-fd @ write-line throw ;  
 3237: 
 3238: : save-asm-region ( region adr len -- )
 3239:   create-outfile (save-asm-region) close-outfile ;
 3240: 
 3241: \ \ minimal definitions
 3242: 	   
 3243: >MINIMAL also minimal
 3244: 
 3245: \ Usefull words                                        13feb93py
 3246: 
 3247: : KB  400 * ;
 3248: 
 3249: \ \ [IF] [ELSE] [THEN] ...				14sep97jaw
 3250: 
 3251: \ it is useful to define our own structures and not to rely
 3252: \ on the words in the host system
 3253: \ The words in the host system might be defined with vocabularies
 3254: \ this doesn't work with our self-made compile-loop
 3255: 
 3256: Create parsed 20 chars allot	\ store word we parsed
 3257: 
 3258: : upcase
 3259:     parsed count bounds
 3260:     ?DO I c@ toupper I c! LOOP ;
 3261: 
 3262: : [ELSE]
 3263:     1 BEGIN
 3264: 	BEGIN bl word count dup WHILE
 3265: 	    comment? 20 umin parsed place upcase parsed count
 3266: 	    2dup s" [IF]" compare 0= >r 
 3267: 	    2dup s" [IFUNDEF]" compare 0= >r
 3268: 	    2dup s" [IFDEF]" compare 0= r> or r> or
 3269: 	    IF   2drop 1+
 3270: 	    ELSE 2dup s" [ELSE]" compare 0=
 3271: 		IF   2drop 1- dup
 3272: 		    IF 1+
 3273: 		    THEN
 3274: 		ELSE
 3275: 		    2dup s" [ENDIF]" compare 0= >r
 3276: 		    s" [THEN]" compare 0= r> or
 3277: 		    IF 1- THEN
 3278: 		THEN
 3279: 	    THEN
 3280: 	    ?dup 0= ?EXIT
 3281: 	REPEAT
 3282: 	2drop refill 0=
 3283:     UNTIL drop ; immediate
 3284:   
 3285: : [THEN] ( -- ) ; immediate
 3286: 
 3287: : [ENDIF] ( -- ) ; immediate
 3288: 
 3289: : [IF] ( flag -- )
 3290:     0= IF postpone [ELSE] THEN ; immediate 
 3291: 
 3292: Cond: [IF]      postpone [IF] ;Cond
 3293: Cond: [THEN]    postpone [THEN] ;Cond
 3294: Cond: [ELSE]    postpone [ELSE] ;Cond
 3295: 
 3296: \ define new [IFDEF] and [IFUNDEF]                      20may93jaw
 3297: 
 3298: : defined? tdefined? ;
 3299: : needed? needed? ;
 3300: : doer? doer? ;
 3301: 
 3302: \ we want to use IFDEF on compiler directives (e.g. E?) in the source, too
 3303: 
 3304: : directive? 
 3305:   bl word count [ ' target >wordlist ] literal search-wordlist 
 3306:   dup IF nip THEN ;
 3307: 
 3308: : [IFDEF]  >in @ directive? swap >in !
 3309: 	   0= IF tdefined? ELSE name 2drop true THEN
 3310: 	   postpone [IF] ;
 3311: 
 3312: : [IFUNDEF] tdefined? 0= postpone [IF] ;
 3313: 
 3314: Cond: [IFDEF]   postpone [IFDEF] ;Cond
 3315: 
 3316: Cond: [IFUNDEF] postpone [IFUNDEF] ;Cond
 3317: 
 3318: \ C: \- \+ Conditional Compiling                         09jun93jaw
 3319: 
 3320: : C: >in @ tdefined? 0=
 3321:      IF    >in ! X :
 3322:      ELSE drop
 3323:         BEGIN bl word dup c@
 3324:               IF   count comment? s" ;" compare 0= ?EXIT
 3325:               ELSE refill 0= ABORT" CROSS: Out of Input while C:"
 3326:               THEN
 3327:         AGAIN
 3328:      THEN ;
 3329: 
 3330: : d? d? ;
 3331: 
 3332: \G doesn't skip line when debug switch is on
 3333: : \D D? 0= IF postpone \ THEN ;
 3334: 
 3335: \G interprets the line if word is not defined
 3336: : \- tdefined? IF postpone \ THEN ;
 3337: 
 3338: \G interprets the line if word is defined
 3339: : \+ tdefined? 0= IF postpone \ THEN ;
 3340: 
 3341: Cond: \- \- ;Cond
 3342: Cond: \+ \+ ;Cond
 3343: Cond: \D \D ;Cond
 3344: 
 3345: : ?? bl word find IF execute ELSE drop 0 THEN ;
 3346: 
 3347: : needed:
 3348: \G defines ghost for words that we want to be compiled
 3349:   BEGIN >in @ bl word c@ WHILE >in ! Ghost drop REPEAT drop ;
 3350: 
 3351: \ words that should be in minimal
 3352: 
 3353: create s-buffer 50 chars allot
 3354: 
 3355: bigendian Constant bigendian
 3356: 
 3357: : here there ;
 3358: : equ constant ;
 3359: : mark there constant ;
 3360: 
 3361: \ compiler directives
 3362: : >ram >ram ;
 3363: : >rom >rom ;
 3364: : >auto >auto ;
 3365: : >tempdp >tempdp ;
 3366: : tempdp> tempdp> ;
 3367: : const constflag on ;
 3368: 
 3369: : Redefinitions-start
 3370: \G Starts a redefinition section. Warnings are disabled and
 3371: \G existing ghosts are reused. This is used in the kernel
 3372: \G where ( and \ and the like are redefined
 3373:   twarnings off warnings off reuse-ghosts on ;
 3374: 
 3375: : Redefinitions-end
 3376: \G Ends a redefinition section. Warnings are enabled again.
 3377:   twarnings on warnings on reuse-ghosts off ;
 3378: 
 3379: : warnings name 3 = 
 3380:   IF twarnings off warnings off ELSE twarnings on warnings on THEN drop ;
 3381: 
 3382: : | ;
 3383: \ : | NoHeaderFlag on ; \ This is broken (damages the last word)
 3384: 
 3385: : save-cross save-cross ;
 3386: : save-region save-region ;
 3387: : tdump swap >image swap dump ;
 3388: 
 3389: also forth 
 3390: [IFDEF] Label           : Label defempty? Label ; [THEN] 
 3391: [IFDEF] start-macros    : start-macros defempty? start-macros ; [THEN]
 3392: \ [IFDEF] builttag	: builttag builttag ;	[THEN]
 3393: previous
 3394: 
 3395: : s" [char] " parse s-buffer place s-buffer count ; \ for environment?
 3396: : + + ;
 3397: : 1+ 1 + ;
 3398: : 2+ 2 + ;
 3399: : 1- 1- ;
 3400: : - - ;
 3401: : and and ;
 3402: : or or ;
 3403: : 2* 2* ;
 3404: : * * ;
 3405: : / / ;
 3406: : dup dup ;
 3407: : over over ;
 3408: : swap swap ;
 3409: : rot rot ;
 3410: : drop drop ;
 3411: : =   = ;
 3412: : 0=   0= ;
 3413: : lshift lshift ;
 3414: : 2/ 2/ ;
 3415: \ : . . ;
 3416: 
 3417: : all-words    ['] forced?    IS skip? ;
 3418: : needed-words ['] needed?  IS skip? ;
 3419: : undef-words  ['] defined2? IS skip? ;
 3420: : skipdef skipdef ;
 3421: 
 3422: : \  postpone \ ;  immediate
 3423: : \G T-\G ; immediate
 3424: : (  postpone ( ;  immediate
 3425: : include bl word count included ;
 3426: : included swap >image swap included ;
 3427: : require require ;
 3428: : needs require ;
 3429: : .( [char] ) parse type ;
 3430: : ." [char] " parse type ;
 3431: : cr cr ;
 3432: 
 3433: : times 0 ?DO dup X c, LOOP drop ; \ used for space table creation
 3434: 
 3435: \ only forth also cross also minimal definitions order
 3436: 
 3437: \ cross-compiler words
 3438: 
 3439: : decimal       decimal [g'] decimal >exec2 @ ?dup IF EXECUTE THEN ;
 3440: : hex           hex [g'] hex >exec2 @ ?dup IF EXECUTE THEN ;
 3441: 
 3442: \ : tudp          X tudp ;
 3443: \ : tup           X tup ;
 3444: 
 3445: : doc-off       false to-doc ! ;
 3446: : doc-on        true  to-doc ! ;
 3447: 
 3448: : declareunique ( "name" -- )
 3449: \G Sets the unique flag for a ghost. The assembler output
 3450: \G generates labels with the ghostname concatenated with the address
 3451: \G while cross-compiling. The address is concatenated
 3452: \G because we have double occurences of the same name.
 3453: \G If we want to reference the labels from the assembler or C
 3454: \G code we declare them unique, so the address is skipped.
 3455:   Ghost >ghost-flags dup @ <unique> or swap ! ;
 3456: 
 3457: \ [IFDEF] dbg : dbg dbg ; [THEN]
 3458: 
 3459: \ for debugging...
 3460: \ : dbg dbg ;
 3461: : horder         order ;
 3462: : hwords        words ;
 3463: \ : words 	also ghosts 
 3464: \                words previous ;
 3465: : .s            .s ;
 3466: : bye           bye ;
 3467: 
 3468: \ dummy
 3469: : group 0 word drop ;
 3470: 
 3471: \ turnkey direction
 3472: : H forth ; immediate
 3473: : T minimal ; immediate
 3474: : G ghosts ; immediate
 3475: 
 3476: 
 3477: \ these ones are pefered:
 3478: 
 3479: : unlock previous forth also cross ;
 3480: 
 3481: \ also minimal
 3482: >cross
 3483: 
 3484: : turnkey 
 3485:    ghosts-wordlist 1 set-order
 3486:    also target definitions
 3487:    also Minimal also ;
 3488: 
 3489: >minimal
 3490: 
 3491: : [[+++
 3492:   turnkey unlock ;
 3493: 
 3494: unlock definitions also minimal
 3495: 
 3496: : lock   turnkey ;
 3497: 
 3498: Defer +++]]-hook
 3499: : +++]] +++]]-hook lock ;
 3500: 
 3501: LOCK
 3502: \ load cross compiler extension defined in mach file
 3503: 
 3504: UNLOCK >CROSS
 3505: 
 3506: [IFDEF] extend-cross extend-cross [THEN]
 3507: 
 3508: LOCK
 3509: 
 3510: 
 3511: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>