1: \ CROSS.FS The Cross-Compiler 06oct92py
2: \ Idea and implementation: Bernd Paysan (py)
3:
4: \ Copyright (C) 1995,1996,1997,1998,1999,2000 Free Software Foundation, Inc.
5:
6: \ This file is part of Gforth.
7:
8: \ Gforth is free software; you can redistribute it and/or
9: \ modify it under the terms of the GNU General Public License
10: \ as published by the Free Software Foundation; either version 2
11: \ of the License, or (at your option) any later version.
12:
13: \ This program is distributed in the hope that it will be useful,
14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: \ GNU General Public License for more details.
17:
18: \ You should have received a copy of the GNU General Public License
19: \ along with this program; if not, write to the Free Software
20: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
21:
22: 0
23: [IF]
24:
25: ToDo:
26: - Crossdoc destination ./doc/crossdoc.fd makes no sense when
27: cross.fs is used seperately. jaw
28: - Do we need this char translation with >address and in branchoffset?
29: (>body also affected) jaw
30: - MAXU etc. can be done with dlit,
31:
32: [THEN]
33:
34: hex
35:
36: \ debugging for compiling
37:
38: \ print stack at each colon definition
39: \ : : save-input cr bl word count type restore-input throw .s : ;
40:
41: \ print stack at each created word
42: \ : create save-input cr bl word count type restore-input throw .s create ;
43:
44:
45: \ \ ------------- Setup Vocabularies
46:
47: \ Remark: Vocabulary is not ANS, but it should work...
48:
49: Vocabulary Cross
50: Vocabulary Target
51: Vocabulary Ghosts
52: Vocabulary Minimal
53: only Forth also Target also also
54: definitions Forth
55:
56: : T previous Ghosts also Target ; immediate
57: : G Ghosts ; immediate
58: : H previous Forth also Cross ; immediate
59:
60: forth definitions
61:
62: : T previous Ghosts also Target ; immediate
63: : G Ghosts ; immediate
64:
65:
66: : >cross also Cross definitions previous ;
67: : >target also Target definitions previous ;
68: : >minimal also Minimal definitions previous ;
69:
70: H
71:
72: >CROSS
73:
74: \ find out whether we are compiling with gforth
75:
76: : defined? bl word find nip ;
77: defined? emit-file defined? toupper and \ drop 0
78: [IF]
79: \ use this in a gforth system
80: : \GFORTH ; immediate
81: : \ANSI postpone \ ; immediate
82: [ELSE]
83: : \GFORTH postpone \ ; immediate
84: : \ANSI ; immediate
85: [THEN]
86:
87: \ANSI : [IFUNDEF] defined? 0= postpone [IF] ; immediate
88: \ANSI : [IFDEF] defined? postpone [IF] ; immediate
89: 0 \ANSI drop 1
90: [IF]
91: : \G postpone \ ; immediate
92: : rdrop postpone r> postpone drop ; immediate
93: : name bl word count ;
94: : bounds over + swap ;
95: : scan >r BEGIN dup WHILE over c@ r@ <> WHILE 1 /string REPEAT THEN rdrop ;
96: : linked here over @ , swap ! ;
97: : alias create , DOES> @ EXECUTE ;
98: : defer ['] noop alias ;
99: : is state @
100: IF ' >body postpone literal postpone !
101: ELSE ' >body ! THEN ; immediate
102: : 0>= 0< 0= ;
103: : d<> rot <> -rot <> or ;
104: : toupper dup [char] a [char] z 1+ within IF [char] A [char] a - + THEN ;
105: Variable ebuf
106: : emit-file ( c fd -- ior ) swap ebuf c! ebuf 1 chars rot write-file ;
107: 0a Constant #lf
108: 0d Constant #cr
109:
110: [IFUNDEF] Warnings Variable Warnings [THEN]
111:
112: \ \ Number parsing 23feb93py
113:
114: \ number? number 23feb93py
115:
116: Variable dpl
117:
118: hex
119: Create bases 10 , 2 , A , 100 ,
120: \ 16 2 10 character
121:
122: \ !! protect BASE saving wrapper against exceptions
123: : getbase ( addr u -- addr' u' )
124: over c@ [char] $ - dup 4 u<
125: IF
126: cells bases + @ base ! 1 /string
127: ELSE
128: drop
129: THEN ;
130:
131: : sign? ( addr u -- addr u flag )
132: over c@ [char] - = dup >r
133: IF
134: 1 /string
135: THEN
136: r> ;
137:
138: : s>unumber? ( addr u -- ud flag )
139: over [char] ' =
140: IF \ a ' alone is rather unusual :-)
141: drop char+ c@ 0 true EXIT
142: THEN
143: base @ >r dpl on getbase
144: 0. 2swap
145: BEGIN ( d addr len )
146: dup >r >number dup
147: WHILE \ there are characters left
148: dup r> -
149: WHILE \ the last >number parsed something
150: dup 1- dpl ! over c@ [char] . =
151: WHILE \ the current char is '.'
152: 1 /string
153: REPEAT THEN \ there are unparseable characters left
154: 2drop false
155: ELSE
156: rdrop 2drop true
157: THEN
158: r> base ! ;
159:
160: \ ouch, this is complicated; there must be a simpler way - anton
161: : s>number? ( addr len -- d f )
162: \ converts string addr len into d, flag indicates success
163: sign? >r
164: s>unumber?
165: 0= IF
166: rdrop false
167: ELSE \ no characters left, all ok
168: r>
169: IF
170: dnegate
171: THEN
172: true
173: THEN ;
174:
175: : s>number ( addr len -- d )
176: \ don't use this, there is no way to tell success
177: s>number? drop ;
178:
179: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
180: s>number? 0=
181: IF
182: 2drop false EXIT
183: THEN
184: dpl @ dup 0< IF
185: nip
186: ELSE
187: 1+
188: THEN ;
189:
190: : number? ( string -- string 0 / n -1 / d 0> )
191: dup >r count snumber? dup if
192: rdrop
193: else
194: r> swap
195: then ;
196:
197: : number ( string -- d )
198: number? ?dup 0= abort" ?" 0<
199: IF
200: s>d
201: THEN ;
202:
203: [THEN]
204:
205: hex \ the defualt base for the cross-compiler is hex !!
206: \ Warnings off
207:
208: \ words that are generaly useful
209:
210: : KB 400 * ;
211: : >wordlist ( vocabulary-xt -- wordlist-struct )
212: also execute get-order swap >r 1- set-order r> ;
213:
214: : umax 2dup u< IF swap THEN drop ;
215: : umin 2dup u> IF swap THEN drop ;
216:
217: : string, ( c-addr u -- )
218: \ puts down string as cstring
219: dup c, here swap chars dup allot move ;
220:
221: : ," [char] " parse string, ;
222:
223: : SetValue ( n -- <name> )
224: \G Same behaviour as "Value" if the <name> is not defined
225: \G Same behaviour as "to" if <name> is defined
226: \G SetValue searches in the current vocabulary
227: save-input bl word >r restore-input throw r> count
228: get-current search-wordlist
229: IF drop >r
230: \ we have to set current to be topmost context wordlist
231: get-order get-order get-current swap 1+ set-order
232: r> ['] to execute
233: set-order
234: ELSE Value THEN ;
235:
236: : DefaultValue ( n -- <name> )
237: \G Same behaviour as "Value" if the <name> is not defined
238: \G DefaultValue searches in the current vocabulary
239: save-input bl word >r restore-input throw r> count
240: get-current search-wordlist
241: IF bl word drop 2drop ELSE Value THEN ;
242:
243: hex
244:
245: \ 1 Constant Cross-Flag \ to check whether assembler compiler plug-ins are
246: \ for cross-compiling
247: \ No! we use "[IFUNDEF]" there to find out whether we are target compiling!!!
248:
249: : comment? ( c-addr u -- c-addr u )
250: 2dup s" (" compare 0=
251: IF postpone (
252: ELSE 2dup s" \" compare 0= IF postpone \ THEN
253: THEN ;
254:
255: : X bl word count [ ' target >wordlist ] Literal search-wordlist
256: IF state @ IF compile,
257: ELSE execute THEN
258: ELSE -1 ABORT" Cross: access method not supported!"
259: THEN ; immediate
260:
261: \ Begin CROSS COMPILER:
262:
263: \ debugging
264:
265: 0 [IF]
266:
267: This implements debugflags for the cross compiler and the compiled
268: images. It works identical to the has-flags in the environment.
269: The debugflags are defined in a vocabluary. If the word exists and
270: its value is true, the flag is switched on.
271:
272: [THEN]
273:
274: >CROSS
275:
276: Vocabulary debugflags \ debug flags for cross
277: also debugflags get-order over
278: Constant debugflags-wl
279: set-order previous
280:
281: : DebugFlag
282: get-current >r debugflags-wl set-current
283: SetValue
284: r> set-current ;
285:
286: : Debug? ( adr u -- flag )
287: \G return true if debug flag is defined or switched on
288: debugflags-wl search-wordlist
289: IF EXECUTE
290: ELSE false THEN ;
291:
292: : D? ( <name> -- flag )
293: \G return true if debug flag is defined or switched on
294: \G while compiling we do not return the current value but
295: bl word count debug? ;
296:
297: : [d?]
298: \G compile the value-xt so the debug flag can be switched
299: \G the flag must exist!
300: bl word count debugflags-wl search-wordlist
301: IF compile,
302: ELSE -1 ABORT" unknown debug flag"
303: \ POSTPONE false
304: THEN ; immediate
305:
306: \ \ -------------------- source file
307:
308: decimal
309:
310: Variable cross-file-list
311: 0 cross-file-list !
312: Variable target-file-list
313: 0 target-file-list !
314: Variable host-file-list
315: 0 host-file-list !
316:
317: cross-file-list Value file-list
318: 0 Value source-desc
319:
320: \ file loading
321:
322: : >fl-id 1 cells + ;
323: : >fl-name 2 cells + ;
324:
325: Variable filelist 0 filelist !
326: Create NoFile ," #load-file#"
327:
328: : loadfile ( -- adr )
329: source-desc ?dup IF >fl-name ELSE NoFile THEN ;
330:
331: : sourcefilename ( -- adr len )
332: loadfile count ;
333:
334: \ANSI : sourceline# 0 ;
335:
336: \ \ -------------------- path handling from kernel/paths.fs
337:
338: \ paths.fs path file handling 03may97jaw
339:
340: \ -Changing the search-path:
341: \ fpath+ <path> adds a directory to the searchpath
342: \ fpath= <path>|<path> makes complete now searchpath
343: \ seperator is |
344: \ .fpath displays the search path
345: \ remark I:
346: \ a ./ in the beginning of filename is expanded to the directory the
347: \ current file comes from. ./ can also be included in the search-path!
348: \ ~+/ loads from the current working directory
349:
350: \ remark II:
351: \ if there is no sufficient space for the search path increase it!
352:
353:
354: \ -Creating custom paths:
355:
356: \ It is possible to use the search mechanism on yourself.
357:
358: \ Make a buffer for the path:
359: \ create mypath 100 chars , \ maximum length (is checked)
360: \ 0 , \ real len
361: \ 100 chars allot \ space for path
362: \ use the same functions as above with:
363: \ mypath path+
364: \ mypath path=
365: \ mypath .path
366:
367: \ do a open with the search path:
368: \ open-path-file ( adr len path -- fd adr len ior )
369: \ the file is opened read-only; if the file is not found an error is generated
370:
371: \ questions to: wilke@jwdt.com
372:
373: [IFUNDEF] +place
374: : +place ( adr len adr )
375: 2dup >r >r
376: dup c@ char+ + swap move
377: r> r> dup c@ rot + swap c! ;
378: [THEN]
379:
380: [IFUNDEF] place
381: : place ( c-addr1 u c-addr2 )
382: 2dup c! char+ swap move ;
383: [THEN]
384:
385: \ if we have path handling, use this and the setup of it
386: [IFUNDEF] open-fpath-file
387:
388: create sourcepath 1024 chars , 0 , 1024 chars allot \ !! make this dynamic
389: sourcepath value fpath
390:
391: : also-path ( adr len path^ -- )
392: >r
393: \ len check
394: r@ cell+ @ over + r@ @ u> ABORT" path buffer too small!"
395: \ copy into
396: tuck r@ cell+ dup @ cell+ + swap cmove
397: \ make delimiter
398: 0 r@ cell+ dup @ cell+ + 2 pick + c! 1 + r> cell+ +!
399: ;
400:
401: : only-path ( adr len path^ -- )
402: dup 0 swap cell+ ! also-path ;
403:
404: : path+ ( path-addr "dir" -- ) \ gforth
405: \G Add the directory @var{dir} to the search path @var{path-addr}.
406: name rot also-path ;
407:
408: : fpath+ ( "dir" ) \ gforth
409: \G Add directory @var{dir} to the Forth search path.
410: fpath path+ ;
411:
412: : path= ( path-addr "dir1|dir2|dir3" ) \ gforth
413: \G Make a complete new search path; the path separator is |.
414: name 2dup bounds ?DO i c@ [char] | = IF 0 i c! THEN LOOP
415: rot only-path ;
416:
417: : fpath= ( "dir1|dir2|dir3" ) \ gforth
418: \G Make a complete new Forth search path; the path separator is |.
419: fpath path= ;
420:
421: : path>counted cell+ dup cell+ swap @ ;
422:
423: : next-path ( adr len -- adr2 len2 )
424: 2dup 0 scan
425: dup 0= IF 2drop 0 -rot 0 -rot EXIT THEN
426: >r 1+ -rot r@ 1- -rot
427: r> - ;
428:
429: : previous-path ( path^ -- )
430: dup path>counted
431: BEGIN tuck dup WHILE repeat ;
432:
433: : .path ( path-addr -- ) \ gforth
434: \G Display the contents of the search path @var{path-addr}.
435: path>counted
436: BEGIN next-path dup WHILE type space REPEAT 2drop 2drop ;
437:
438: : .fpath ( -- ) \ gforth
439: \G Display the contents of the Forth search path.
440: fpath .path ;
441:
442: : absolut-path? ( addr u -- flag ) \ gforth
443: \G A path is absolute if it starts with a / or a ~ (~ expansion),
444: \G or if it is in the form ./*, extended regexp: ^[/~]|./, or if
445: \G it has a colon as second character ("C:..."). Paths simply
446: \G containing a / are not absolute!
447: 2dup 2 u> swap 1+ c@ [char] : = and >r \ dos absoulte: c:/....
448: over c@ [char] / = >r
449: over c@ [char] ~ = >r
450: \ 2dup 3 min S" ../" compare 0= r> or >r \ not catered for in expandtopic
451: 2 min S" ./" compare 0=
452: r> r> r> or or or ;
453:
454: Create ofile 0 c, 255 chars allot
455: Create tfile 0 c, 255 chars allot
456:
457: : pathsep? dup [char] / = swap [char] \ = or ;
458:
459: : need/ ofile dup c@ + c@ pathsep? 0= IF s" /" ofile +place THEN ;
460:
461: : extractpath ( adr len -- adr len2 )
462: BEGIN dup WHILE 1-
463: 2dup + c@ pathsep? IF EXIT THEN
464: REPEAT ;
465:
466: : remove~+ ( -- )
467: ofile count 3 min s" ~+/" compare 0=
468: IF
469: ofile count 3 /string ofile place
470: THEN ;
471:
472: : expandtopic ( -- ) \ stack effect correct? - anton
473: \ expands "./" into an absolute name
474: ofile count 2 min s" ./" compare 0=
475: IF
476: ofile count 1 /string tfile place
477: 0 ofile c! sourcefilename extractpath ofile place
478: ofile c@ IF need/ THEN
479: tfile count over c@ pathsep? IF 1 /string THEN
480: ofile +place
481: THEN ;
482:
483: : compact.. ( adr len -- adr2 len2 )
484: \ deletes phrases like "xy/.." out of our directory name 2dec97jaw
485: over swap
486: BEGIN dup WHILE
487: dup >r '/ scan 2dup 4 min s" /../" compare 0=
488: IF
489: dup r> - >r 4 /string over r> + 4 -
490: swap 2dup + >r move dup r> over -
491: ELSE
492: rdrop dup 1 min /string
493: THEN
494: REPEAT drop over - ;
495:
496: : reworkdir ( -- )
497: remove~+
498: ofile count compact..
499: nip ofile c! ;
500:
501: : open-ofile ( -- fid ior )
502: \G opens the file whose name is in ofile
503: expandtopic reworkdir
504: ofile count r/o open-file ;
505:
506: : check-path ( adr1 len1 adr2 len2 -- fd 0 | 0 <>0 )
507: 0 ofile ! >r >r ofile place need/
508: r> r> ofile +place
509: open-ofile ;
510:
511: : open-path-file ( addr1 u1 path-addr -- wfileid addr2 u2 0 | ior ) \ gforth
512: \G Look in path @var{path-addr} for the file specified by @var{addr1 u1}.
513: \G If found, the resulting path and an open file descriptor
514: \G are returned. If the file is not found, @var{ior} is non-zero.
515: >r
516: 2dup absolut-path?
517: IF rdrop
518: ofile place open-ofile
519: dup 0= IF >r ofile count r> THEN EXIT
520: ELSE r> path>counted
521: BEGIN next-path dup
522: WHILE 5 pick 5 pick check-path
523: 0= IF >r 2drop 2drop r> ofile count 0 EXIT ELSE drop THEN
524: REPEAT
525: 2drop 2drop 2drop -38
526: THEN ;
527:
528: : open-fpath-file ( addr1 u1 -- wfileid addr2 u2 0 | ior ) \ gforth
529: \G Look in the Forth search path for the file specified by @var{addr1 u1}.
530: \G If found, the resulting path and an open file descriptor
531: \G are returned. If the file is not found, @var{ior} is non-zero.
532: fpath open-path-file ;
533:
534: fpath= ~+
535:
536: [THEN]
537:
538: \ \ -------------------- include require 13may99jaw
539:
540: >CROSS
541:
542: : add-included-file ( adr len -- adr )
543: dup >fl-name char+ allocate throw >r
544: file-list @ r@ ! r@ file-list !
545: r@ >fl-name place r> ;
546:
547: : included? ( c-addr u -- f )
548: file-list
549: BEGIN @ dup
550: WHILE >r 2dup r@ >fl-name count compare 0=
551: IF rdrop 2drop true EXIT THEN
552: r>
553: REPEAT
554: 2drop drop false ;
555:
556: false DebugFlag showincludedfiles
557:
558: : included1 ( fd adr u -- )
559: \ include file adr u / fd
560: \ we don't use fd with include-file, because the forth system
561: \ doesn't know the name of the file to get a nice error report
562: [d?] showincludedfiles
563: IF cr ." Including: " 2dup type ." ..." THEN
564: rot close-file throw
565: source-desc >r
566: add-included-file to source-desc
567: sourcefilename
568: ['] included catch
569: r> to source-desc
570: throw ;
571:
572: : included ( adr len -- )
573: cross-file-list to file-list
574: open-fpath-file throw
575: included1 ;
576:
577: : required ( adr len -- )
578: cross-file-list to file-list
579: open-fpath-file throw \ 2dup cr ." R:" type
580: 2dup included?
581: IF 2drop close-file throw
582: ELSE included1
583: THEN ;
584:
585: : include bl word count included ;
586:
587: : require bl word count required ;
588:
589: 0 [IF]
590:
591: also forth definitions previous
592:
593: : included ( adr len -- ) included ;
594:
595: : required ( adr len -- ) required ;
596:
597: : include include ;
598:
599: : require require ;
600:
601: [THEN]
602:
603: >CROSS
604: hex
605:
606: \ \ -------------------- Error Handling 05aug97jaw
607:
608: \ Flags
609:
610: also forth definitions \ these values may be predefined before
611: \ the cross-compiler is loaded
612:
613: false DefaultValue stack-warn \ check on empty stack at any definition
614: false DefaultValue create-forward-warn \ warn on forward declaration of created words
615:
616: previous >CROSS
617:
618: : .dec
619: base @ decimal swap . base ! ;
620:
621: : .sourcepos
622: cr sourcefilename type ." :"
623: sourceline# .dec ;
624:
625: : warnhead
626: \G display error-message head
627: \G perhaps with linenumber and filename
628: .sourcepos ." Warning: " ;
629:
630: : empty? depth IF .sourcepos ." Stack not empty!" THEN ;
631:
632: stack-warn [IF]
633: : defempty? empty? ;
634: [ELSE]
635: : defempty? ; immediate
636: [THEN]
637:
638: \ \ -------------------- Compiler Plug Ins 01aug97jaw
639:
640: >CROSS
641:
642: \ Compiler States
643:
644: Variable comp-state
645: 0 Constant interpreting
646: 1 Constant compiling
647: 2 Constant resolving
648: 3 Constant assembling
649:
650: : compiling? comp-state @ compiling = ;
651:
652: : pi-undefined -1 ABORT" Plugin undefined" ;
653:
654: : Plugin ( -- : pluginname )
655: Create
656: \ for normal cross-compiling only one action
657: \ exists, this fields are identical. For the instant
658: \ simulation environment we need, two actions for each plugin
659: \ the target one and the one that generates the simulation code
660: ['] pi-undefined , \ action
661: ['] pi-undefined , \ target plugin action
662: 8765 , \ plugin magic
663: DOES> perform ;
664:
665: Plugin DummyPlugin
666:
667: : 'PI ( -- addr : pluginname )
668: ' >body dup 2 cells + @ 8765 <> ABORT" not a plugin" ;
669:
670: : plugin-of ( xt -- : pluginname )
671: dup 'PI 2! ;
672:
673: : action-of ( xt -- : plunginname )
674: 'PI cell+ ! ;
675:
676: : TPA ( -- : plugin )
677: \ target plugin action
678: \ executes current target action of plugin
679: 'PI cell+ POSTPONE literal POSTPONE perform ; immediate
680:
681: Variable ppi-temp 0 ppi-temp !
682:
683: : pa:
684: \g define plugin action
685: ppi-temp @ ABORT" pa: definition not closed"
686: 'PI ppi-temp ! :noname ;
687:
688: : ;pa
689: \g end a definition for plugin action
690: POSTPONE ; ppi-temp @ ! 0 ppi-temp ! ; immediate
691:
692:
693: Plugin dlit, ( d -- ) \ compile numerical value the target
694: Plugin lit, ( n -- )
695: Plugin alit, ( n -- )
696:
697: Plugin branch, ( target-addr -- ) \ compiles a branch
698: Plugin ?branch, ( target-addr -- ) \ compiles a ?branch
699: Plugin branchmark, ( -- branch-addr ) \ reserves room for a branch
700: Plugin ?branchmark, ( -- branch-addr ) \ reserves room for a ?branch
701: Plugin ?domark, ( -- branch-addr ) \ reserves room for a ?do branch
702: Plugin branchto, ( -- ) \ actual program position is target of a branch (do e.g. alignment)
703: ' NOOP plugin-of branchto,
704: Plugin branchtoresolve, ( branch-addr -- ) \ resolves a forward reference from branchmark
705: Plugin branchtomark, ( -- target-addr ) \ marks a branch destination
706:
707: Plugin colon, ( tcfa -- ) \ compiles call to tcfa at current position
708: Plugin prim, ( tcfa -- ) \ compiles primitive invocation
709: Plugin colonmark, ( -- addr ) \ marks a colon call
710: Plugin colon-resolve ( tcfa addr -- )
711:
712: Plugin addr-resolve ( target-addr addr -- )
713: Plugin doer-resolve ( ghost res-pnt target-addr addr -- ghost res-pnt )
714:
715: Plugin ncontrols? ( [ xn ... x1 ] n -- ) \ checks wheter n control structures are open
716: Plugin if, ( -- if-token )
717: Plugin else, ( if-token -- if-token )
718: Plugin then, ( if-token -- )
719: Plugin ahead,
720: Plugin begin,
721: Plugin while,
722: Plugin until,
723: Plugin again,
724: Plugin repeat,
725: Plugin cs-swap ( x1 x2 -- x2 x1 )
726:
727: Plugin case, ( -- n )
728: Plugin of, ( n -- x1 n )
729: Plugin endof, ( x1 n -- x2 n )
730: Plugin endcase, ( x1 .. xn n -- )
731:
732: Plugin do, ( -- do-token )
733: Plugin ?do, ( -- ?do-token )
734: Plugin for, ( -- for-token )
735: Plugin loop, ( do-token / ?do-token -- )
736: Plugin +loop, ( do-token / ?do-token -- )
737: Plugin next, ( for-token )
738: Plugin leave, ( -- )
739: Plugin ?leave, ( -- )
740:
741: [IFUNDEF] ca>native
742: Plugin ca>native
743: [THEN]
744:
745: Plugin doprim, \ compiles start of a primitive
746: Plugin docol, \ compiles start of a colon definition
747: Plugin doer,
748: Plugin fini, \ compiles end of definition ;s
749: Plugin doeshandler,
750: Plugin dodoes,
751:
752: Plugin colon-start
753: ' noop plugin-of colon-start
754: Plugin colon-end
755: ' noop plugin-of colon-end
756:
757: Plugin ]comp \ starts compilation
758: ' noop plugin-of ]comp
759: Plugin comp[ \ ends compilation
760: ' noop plugin-of comp[
761:
762: Plugin t>body \ we need the system >body
763: \ and the target >body
764:
765: >TARGET
766: : >body t>body ;
767:
768:
769: \ Ghost Builder 06oct92py
770:
771: >CROSS
772: hex
773: \ Values for ghost magic
774: 4711 Constant <fwd> 4712 Constant <res>
775: 4713 Constant <imm> 4714 Constant <do:>
776: 4715 Constant <skip>
777:
778: \ Bitmask for ghost flags
779: 1 Constant <unique>
780: 2 Constant <primitive>
781:
782: \ FXIME: move this to general stuff?
783: : set-flag ( addr flag -- )
784: over @ or swap ! ;
785:
786: : reset-flag ( addr flag -- )
787: invert over @ and swap ! ;
788:
789: : get-flag ( addr flag -- f )
790: swap @ and 0<> ;
791:
792:
793: Struct
794:
795: \ link to next ghost (always the first element)
796: cell% field >next-ghost
797:
798: \ type of ghost
799: cell% field >magic
800:
801: \ pointer where ghost is in target, or if unresolved
802: \ points to the where we have to resolve (linked-list)
803: cell% field >link
804:
805: \ execution semantics (while target compiling) of ghost
806: cell% field >exec
807:
808: \ compilation action of this ghost; this is what is
809: \ done to compile a call (or whatever) to this definition.
810: \ E.g. >comp contains the semantic of postpone s"
811: \ whereas >exec-compile contains the semantic of s"
812: cell% field >comp
813:
814: \ Compilation sematics (while parsing) of this ghost. E.g.
815: \ "\" will skip the rest of line.
816: \ These semantics are defined by Cond: and
817: \ if a word is made immediate in instant, then the >exec2 field
818: \ gets copied to here
819: cell% field >exec-compile
820:
821: \ Additional execution semantics of this ghost. This is used
822: \ for code generated by instant and for the doer-xt of created
823: \ words
824: cell% field >exec2
825:
826: cell% field >created
827:
828: \ the xt of the created ghost word itself
829: cell% field >ghost-xt
830:
831: \ pointer to the counted string of the assiciated
832: \ assembler label
833: cell% field >asm-name
834:
835: \ mapped primitives have a special address, so
836: \ we are able to detect them
837: cell% field >asm-dummyaddr
838:
839: \ for builder (create, variable...) words
840: \ the execution symantics of words built are placed here
841: \ this is a doer ghost or a dummy ghost
842: cell% field >do:ghost
843:
844: cell% field >ghost-flags
845:
846: cell% field >ghost-name
847:
848: End-Struct ghost-struct
849:
850: Variable ghost-list
851: 0 ghost-list !
852:
853: Variable executed-ghost \ last executed ghost, needed in tcreate and gdoes>
854: \ Variable last-ghost \ last ghost that is created
855: Variable last-header-ghost \ last ghost definitions with header
856:
857: \ space for ghosts resolve structure
858: \ we create ghosts in a sepearte space
859: \ and not to the current host dp, because this
860: \ gives trouble with instant while compiling and creating
861: \ a ghost for a forward reference
862: \ BTW: we cannot allocate another memory region
863: \ because allot will check the overflow!!
864: Variable cross-space-dp
865: Create cross-space 250000 allot here 100 allot align
866: Constant cross-space-end
867: cross-space cross-space-dp !
868: Variable cross-space-dp-orig
869:
870: : cross-space-used cross-space-dp @ cross-space - ;
871:
872: : >space ( -- )
873: dp @ cross-space-dp-orig !
874: cross-space-dp @ dp ! ;
875:
876: : space> ( -- )
877: dp @ dup cross-space-dp !
878: cross-space-end u> ABORT" CROSS: cross-space overflow"
879: cross-space-dp-orig @ dp ! ;
880:
881: \ this is just for debugging, to see this in the backtrace
882: : execute-exec execute ;
883: : execute-exec2 execute ;
884: : execute-exec-compile execute ;
885:
886: : NoExec
887: executed-ghost @ >exec2 @
888: ?dup
889: IF execute-exec2
890: ELSE true ABORT" CROSS: Don't execute ghost, or immediate target word"
891: THEN ;
892:
893: Defer is-forward
894:
895: : (ghostheader) ( -- )
896: ghost-list linked <fwd> , 0 , ['] NoExec , ['] is-forward ,
897: 0 , 0 , 0 , 0 , 0 , 0 , 0 , 0 , ;
898:
899: : ghostheader ( -- ) (ghostheader) 0 , ;
900:
901: ' Ghosts >wordlist Constant ghosts-wordlist
902:
903: \ the current wordlist for ghost definitions in the host
904: ghosts-wordlist Value current-ghosts
905:
906: : Make-Ghost ( "name" -- ghost )
907: >space
908: \ save current and create in ghost vocabulary
909: get-current >r current-ghosts set-current
910: >in @ Create >in !
911: \ some forth systems like iForth need the immediate directly
912: \ after the word is created
913: \ restore current
914: r> set-current
915: here (ghostheader)
916: bl word count string, align
917: space>
918: \ set ghost-xt field by doing a search
919: dup >ghost-name count
920: current-ghosts search-wordlist
921: 0= ABORT" CROSS: Just created, must be there!"
922: over >ghost-xt !
923: DOES>
924: dup executed-ghost !
925: >exec @ execute-exec ;
926:
927: \ ghost words 14oct92py
928: \ changed: 10may93py/jaw
929:
930: Defer search-ghosts
931:
932: : (search-ghosts) ( adr len -- cfa true | 0 )
933: current-ghosts search-wordlist ;
934:
935: ' (search-ghosts) IS search-ghosts
936:
937: : gsearch ( addr len -- ghost true | 0 )
938: search-ghosts
939: dup IF swap >body swap THEN ;
940:
941: : gfind ( string -- ghost true / string false )
942: \ searches for string in word-list ghosts
943: \ dup count type space
944: dup >r count gsearch
945: dup IF rdrop ELSE r> swap THEN ;
946:
947: : gdiscover ( xt -- ghost true | xt false )
948: >r ghost-list
949: BEGIN @ dup
950: WHILE dup >magic @ <fwd> <>
951: IF dup >link @ r@ =
952: IF rdrop true EXIT THEN
953: THEN
954: REPEAT
955: drop r> false ;
956:
957: : xt>ghost ( xt -- ghost )
958: gdiscover 0= ABORT" CROSS: ghost not found for this xt" ;
959:
960: : Ghost ( "name" -- ghost )
961: >in @ bl word gfind IF nip EXIT THEN
962: drop >in ! Make-Ghost ;
963:
964: : >ghostname ( ghost -- adr len )
965: >ghost-name count ;
966:
967: : forward? ( ghost -- flag )
968: >magic @ <fwd> = ;
969:
970: : undefined? ( ghost -- flag )
971: >magic @ dup <fwd> = swap <skip> = or ;
972:
973: : immediate? ( ghost -- flag )
974: >magic @ <imm> = ;
975:
976: Variable TWarnings
977: TWarnings on
978: Variable Exists-Warnings
979: Exists-Warnings on
980:
981: : exists-warning ( ghost -- ghost )
982: TWarnings @ Exists-Warnings @ and
983: IF dup >ghostname warnhead type ." exists " THEN ;
984:
985: \ : HeaderGhost Ghost ;
986:
987: Variable reuse-ghosts reuse-ghosts off
988:
989: 1 [IF] \ FIXME: define when vocs are ready
990: : HeaderGhost ( "name" -- ghost )
991: >in @
992: bl word count
993: \ 2dup type space
994: current-ghosts search-wordlist
995: IF >body dup undefined? reuse-ghosts @ or
996: IF nip EXIT
997: ELSE exists-warning
998: THEN
999: drop >in !
1000: ELSE >in !
1001: THEN
1002: \ we keep the execution semantics of the prviously
1003: \ defined words, this is a workaround
1004: \ for the redefined \ until vocs work
1005: Make-Ghost ;
1006: [THEN]
1007:
1008:
1009: : .ghost ( ghost -- ) >ghostname type ;
1010:
1011: \ ' >ghostname ALIAS @name
1012:
1013: : [G'] ( -- ghost : name )
1014: \G ticks a ghost and returns its address
1015: \ bl word gfind 0= ABORT" CROSS: Ghost don't exists"
1016: ghost state @ IF postpone literal THEN ; immediate
1017:
1018: : g>xt ( ghost -- xt )
1019: \G Returns the xt (cfa) of a ghost. Issues a warning if undefined.
1020: dup undefined? ABORT" CROSS: forward " >link @ ;
1021:
1022: : g>body ( ghost -- body )
1023: \G Returns the body-address (pfa) of a ghost.
1024: \G Issues a warning if undefined (a forward-reference).
1025: g>xt X >body ;
1026:
1027: 1 Constant <label>
1028:
1029: Struct
1030: \ bitmask of address type (not used for now)
1031: cell% field addr-type
1032: \ if this address is an xt, this field points to the ghost
1033: cell% field addr-xt-ghost
1034: \ a bit mask that tells as what part of the cell
1035: \ is refenced from an address pointer, used for assembler generation
1036: cell% field addr-refs
1037: End-Struct addr-struct
1038:
1039: : %allocerase ( align size -- addr )
1040: dup >r %alloc dup r> erase ;
1041:
1042: \ returns the addr struct, define it if 0 reference
1043: : define-addr-struct ( addr -- struct-addr )
1044: dup @ ?dup IF nip EXIT THEN
1045: addr-struct %allocerase tuck swap ! ;
1046:
1047: \ Predefined ghosts 12dec92py
1048:
1049: Ghost 0= drop
1050: Ghost branch Ghost ?branch 2drop
1051: Ghost (do) Ghost (?do) 2drop
1052: Ghost (for) drop
1053: Ghost (loop) Ghost (+loop) 2drop
1054: Ghost (next) drop
1055: Ghost unloop Ghost ;S 2drop
1056: Ghost lit Ghost (compile) Ghost ! 2drop drop
1057: Ghost (does>) Ghost noop 2drop
1058: Ghost (.") Ghost (S") Ghost (ABORT") 2drop drop
1059: Ghost ' drop
1060: Ghost :docol Ghost :doesjump Ghost :dodoes 2drop drop
1061: Ghost :dovar drop
1062: Ghost over Ghost = Ghost drop 2drop drop
1063: Ghost - drop
1064: Ghost 2drop drop
1065: Ghost 2dup drop
1066:
1067:
1068:
1069: \ \ Parameter for target systems 06oct92py
1070:
1071:
1072: >cross
1073: \ we define it ans like...
1074: wordlist Constant target-environment
1075:
1076: \ save information of current dictionary to restore with environ>
1077: Variable env-current
1078:
1079: : >ENVIRON get-current env-current ! target-environment set-current ;
1080: : ENVIRON> env-current @ set-current ;
1081:
1082: >TARGET
1083:
1084: : environment? ( addr len -- [ x ] true | false )
1085: \G returns the content of environment variable and true or
1086: \G false if not present
1087: target-environment search-wordlist
1088: IF EXECUTE true ELSE false THEN ;
1089:
1090: : $has? ( addr len -- x | false )
1091: \G returns the content of environment variable
1092: \G or false if not present
1093: T environment? H dup IF drop THEN ;
1094:
1095: : e? ( "name" -- x )
1096: \G returns the content of environment variable.
1097: \G The variable is expected to exist. If not, issue an error.
1098: bl word count T environment? H
1099: 0= ABORT" environment variable not defined!" ;
1100:
1101: : has? ( "name" --- x | false )
1102: \G returns the content of environment variable
1103: \G or false if not present
1104: bl word count T $has? H ;
1105:
1106:
1107: >ENVIRON get-order get-current swap 1+ set-order
1108: true SetValue compiler
1109: true SetValue cross
1110: true SetValue standard-threading
1111: >TARGET previous
1112:
1113: 0
1114: [IFDEF] mach-file drop mach-file count 1 [THEN]
1115: [IFDEF] machine-file drop machine-file 1 [THEN]
1116: [IF] included hex
1117: [ELSE] cr ." No machine description!" ABORT
1118: [THEN]
1119:
1120: >ENVIRON
1121:
1122: T has? ec H
1123: [IF]
1124: false DefaultValue relocate
1125: false DefaultValue file
1126: false DefaultValue OS
1127: false DefaultValue prims
1128: false DefaultValue floating
1129: false DefaultValue glocals
1130: false DefaultValue dcomps
1131: false DefaultValue hash
1132: false DefaultValue xconds
1133: false DefaultValue header
1134: false DefaultValue backtrace
1135: false DefaultValue new-input
1136: false DefaultValue peephole
1137: [THEN]
1138:
1139: true DefaultValue interpreter
1140: true DefaultValue ITC
1141: false DefaultValue rom
1142: true DefaultValue standardthreading
1143:
1144: >TARGET
1145: s" relocate" T environment? H
1146: \ JAW why set NIL to this?!
1147: [IF] drop \ SetValue NIL
1148: [ELSE] >ENVIRON T NIL H SetValue relocate
1149: [THEN]
1150:
1151: >CROSS
1152:
1153: \ \ Create additional parameters 19jan95py
1154:
1155: \ currently cross only works for host machines with address-unit-bits
1156: \ eual to 8 because of s! and sc!
1157: \ but I start to query the environment just to modularize a little bit
1158:
1159: : check-address-unit-bits ( -- )
1160: \ s" ADDRESS-UNIT-BITS" environment?
1161: \ IF 8 <> ELSE true THEN
1162: \ ABORT" ADDRESS-UNIT-BITS unknown or not equal to 8!"
1163:
1164: \ shit, this doesn't work because environment? is only defined for
1165: \ gforth.fi and not kernl???.fi
1166: ;
1167:
1168: check-address-unit-bits
1169: 8 Constant bits/byte \ we define: byte is address-unit
1170:
1171: 1 bits/byte lshift Constant maxbyte
1172: \ this sets byte size for the target machine, (probably right guess) jaw
1173:
1174: T
1175: NIL Constant TNIL
1176: cell Constant tcell
1177: cell<< Constant tcell<<
1178: cell>bit Constant tcell>bit
1179: bits/char Constant tbits/char
1180: bits/char H bits/byte T /
1181: Constant tchar
1182: float Constant tfloat
1183: 1 bits/char lshift Constant tmaxchar
1184: [IFUNDEF] bits/byte
1185: 8 Constant tbits/byte
1186: [ELSE]
1187: bits/byte Constant tbits/byte
1188: [THEN]
1189: H
1190: tbits/char bits/byte / Constant tbyte
1191:
1192:
1193: \ Variables 06oct92py
1194:
1195: Variable image
1196: Variable tlast TNIL tlast ! \ Last name field
1197: Variable tlastcfa \ Last code field
1198: Variable bit$
1199:
1200: \ statistics 10jun97jaw
1201:
1202: Variable headers-named 0 headers-named !
1203: Variable user-vars 0 user-vars !
1204:
1205: : target>bitmask-size ( u1 -- u2 )
1206: 1- tcell>bit rshift 1+ ;
1207:
1208: : allocatetarget ( size -- adr )
1209: dup allocate ABORT" CROSS: No memory for target"
1210: swap over swap erase ;
1211:
1212: \ \ memregion.fs
1213:
1214:
1215: Variable last-defined-region \ pointer to last defined region
1216: Variable region-link \ linked list with all regions
1217: Variable mirrored-link \ linked list for mirrored regions
1218: 0 dup mirrored-link ! region-link !
1219:
1220:
1221: : >rname 7 cells + ;
1222: : >rbm 4 cells + ;
1223: : >rmem 5 cells + ;
1224: : >rtype 6 cells + ;
1225: : >rlink 3 cells + ;
1226: : >rdp 2 cells + ;
1227: : >rlen cell+ ;
1228: : >rstart ;
1229:
1230:
1231: : region ( addr len -- )
1232: \G create a new region
1233: \ check whether predefined region exists
1234: save-input bl word find >r >r restore-input throw r> r> 0=
1235: IF \ make region
1236: drop
1237: save-input create restore-input throw
1238: here last-defined-region !
1239: over ( startaddr ) , ( length ) , ( dp ) ,
1240: region-link linked 0 , 0 , 0 , bl word count string,
1241: ELSE \ store new parameters in region
1242: bl word drop
1243: >body >r r@ last-defined-region !
1244: r@ >rlen ! dup r@ >rstart ! r> >rdp !
1245: THEN ;
1246:
1247: : borders ( region -- startaddr endaddr )
1248: \G returns lower and upper region border
1249: dup >rstart @ swap >rlen @ over + ;
1250:
1251: : extent ( region -- startaddr len )
1252: \G returns the really used area
1253: dup >rstart @ swap >rdp @ over - ;
1254:
1255: : area ( region -- startaddr totallen )
1256: \G returns the total area
1257: dup >rstart @ swap >rlen @ ;
1258:
1259: : mirrored
1260: \G mark a region as mirrored
1261: mirrored-link
1262: align linked last-defined-region @ , ;
1263:
1264: : .addr ( u -- )
1265: \G prints a 16 or 32 Bit nice hex value
1266: base @ >r hex
1267: tcell 2 u>
1268: IF s>d <# # # # # [char] . hold # # # # #> type
1269: ELSE s>d <# # # # # # #> type
1270: THEN r> base ! space ;
1271:
1272: : .regions \G display region statistic
1273:
1274: \ we want to list the regions in the right order
1275: \ so first collect all regions on stack
1276: 0 region-link @
1277: BEGIN dup WHILE dup @ REPEAT drop
1278: BEGIN dup
1279: WHILE cr
1280: 0 >rlink - >r
1281: r@ >rname count tuck type
1282: 12 swap - 0 max spaces space
1283: ." Start: " r@ >rstart @ dup .addr space
1284: ." End: " r@ >rlen @ + .addr space
1285: ." DP: " r> >rdp @ .addr
1286: REPEAT drop
1287: s" rom" T $has? H 0= ?EXIT
1288: cr ." Mirrored:"
1289: mirrored-link @
1290: BEGIN dup
1291: WHILE space dup cell+ @ >rname count type @
1292: REPEAT drop cr
1293: ;
1294:
1295: \ -------- predefined regions
1296:
1297: 0 0 region address-space
1298: \ total memory addressed and used by the target system
1299:
1300: 0 0 region dictionary
1301: \ rom area for the compiler
1302:
1303: T has? rom H
1304: [IF]
1305: 0 0 region ram-dictionary mirrored
1306: \ ram area for the compiler
1307: [ELSE]
1308: ' dictionary ALIAS ram-dictionary
1309: [THEN]
1310:
1311: 0 0 region return-stack
1312:
1313: 0 0 region data-stack
1314:
1315: 0 0 region tib-region
1316:
1317: ' dictionary ALIAS rom-dictionary
1318:
1319:
1320: : setup-target ( -- ) \G initialize target's memory space
1321: s" rom" T $has? H
1322: IF \ check for ram and rom...
1323: \ address-space area nip 0<>
1324: ram-dictionary area nip 0<>
1325: rom-dictionary area nip 0<>
1326: and 0=
1327: ABORT" CROSS: define address-space, rom- , ram-dictionary, with rom-support!"
1328: THEN
1329: address-space area nip
1330: IF
1331: address-space area
1332: ELSE
1333: dictionary area
1334: THEN
1335: nip 0=
1336: ABORT" CROSS: define at least address-space or dictionary!!"
1337:
1338: \ allocate target for each region
1339: region-link
1340: BEGIN @ dup
1341: WHILE dup
1342: 0 >rlink - >r
1343: r@ >rlen @
1344: IF \ allocate mem
1345: r@ >rlen @ allocatetarget dup image !
1346: r@ >rmem !
1347:
1348: r@ >rlen @
1349: target>bitmask-size allocatetarget
1350: dup bit$ !
1351: r@ >rbm !
1352:
1353: r@ >rlen @
1354: tcell / 1+ cells allocatetarget r@ >rtype !
1355:
1356: rdrop
1357: ELSE r> drop THEN
1358: REPEAT drop ;
1359:
1360: \ MakeKernel 22feb99jaw
1361:
1362: : makekernel ( targetsize -- targetsize )
1363: dup dictionary >rlen ! setup-target ;
1364:
1365: >MINIMAL
1366: : makekernel makekernel ;
1367: >CROSS
1368:
1369: \ \ switched tdp for rom support 03jun97jaw
1370:
1371: \ second value is here to store some maximal value for statistics
1372: \ tempdp is also embedded here but has nothing to do with rom support
1373: \ (needs switched dp)
1374:
1375: variable tempdp 0 , \ temporary dp for resolving
1376: variable tempdp-save
1377:
1378: 0 [IF]
1379: variable romdp 0 , \ Dictionary-Pointer for ramarea
1380: variable ramdp 0 , \ Dictionary-Pointer for romarea
1381:
1382: \
1383: variable sramdp \ start of ram-area for forth
1384: variable sromdp \ start of rom-area for forth
1385:
1386: [THEN]
1387:
1388:
1389: 0 value tdp
1390: variable fixed \ flag: true: no automatic switching
1391: \ false: switching is done automatically
1392:
1393: \ Switch-Policy:
1394: \
1395: \ a header is always compiled into rom
1396: \ after a created word (create and variable) compilation goes to ram
1397: \
1398: \ Be careful: If you want to make the data behind create into rom
1399: \ you have to put >rom before create!
1400:
1401: variable constflag constflag off
1402:
1403: : activate ( region -- )
1404: \G next code goes to this region
1405: >rdp to tdp ;
1406:
1407: : (switchram)
1408: fixed @ ?EXIT s" rom" T $has? H 0= ?EXIT
1409: ram-dictionary activate ;
1410:
1411: : switchram
1412: constflag @
1413: IF constflag off ELSE (switchram) THEN ;
1414:
1415: : switchrom
1416: fixed @ ?EXIT rom-dictionary activate ;
1417:
1418: : >tempdp ( addr -- )
1419: tdp tempdp-save ! tempdp to tdp tdp ! ;
1420: : tempdp> ( -- )
1421: tempdp-save @ to tdp ;
1422:
1423: : >ram fixed off (switchram) fixed on ;
1424: : >rom fixed off switchrom fixed on ;
1425: : >auto fixed off switchrom ;
1426:
1427:
1428:
1429: \ : romstart dup sromdp ! romdp ! ;
1430: \ : ramstart dup sramdp ! ramdp ! ;
1431:
1432: \ default compilation goes to rom
1433: \ when romable support is off, only the rom switch is used (!!)
1434: >auto
1435:
1436: : there tdp @ ;
1437:
1438: >TARGET
1439:
1440: \ \ Target Memory Handling
1441:
1442: \ Byte ordering and cell size 06oct92py
1443:
1444: : cell+ tcell + ;
1445: : cells tcell<< lshift ;
1446: : chars tchar * ;
1447: : char+ tchar + ;
1448: : floats tfloat * ;
1449:
1450: >CROSS
1451: : cell/ tcell<< rshift ;
1452: >TARGET
1453: 20 CONSTANT bl
1454: \ TNIL Constant NIL
1455:
1456: >CROSS
1457:
1458: bigendian
1459: [IF]
1460: : DS! ( d addr -- ) tcell bounds swap 1-
1461: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
1462: : DS@ ( addr -- d ) >r 0 0 r> tcell bounds
1463: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP ;
1464: : Sc! ( n addr -- ) >r s>d r> tchar bounds swap 1-
1465: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
1466: : Sc@ ( addr -- n ) >r 0 0 r> tchar bounds
1467: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP d>s ;
1468: [ELSE]
1469: : DS! ( d addr -- ) tcell bounds
1470: DO maxbyte ud/mod rot I c! LOOP 2drop ;
1471: : DS@ ( addr -- n ) >r 0 0 r> tcell bounds swap 1-
1472: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP ;
1473: : Sc! ( n addr -- ) >r s>d r> tchar bounds
1474: DO maxbyte ud/mod rot I c! LOOP 2drop ;
1475: : Sc@ ( addr -- n ) >r 0 0 r> tchar bounds swap 1-
1476: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP d>s ;
1477: [THEN]
1478:
1479: : S! ( n addr -- ) >r s>d r> DS! ;
1480: : S@ ( addr -- n ) DS@ d>s ;
1481:
1482: : taddr>region ( taddr -- region | 0 )
1483: \G finds for a target-address the correct region
1484: \G returns 0 if taddr is not in range of a target memory region
1485: region-link
1486: BEGIN @ dup
1487: WHILE dup >r
1488: 0 >rlink - >r
1489: r@ >rlen @
1490: IF dup r@ borders within
1491: IF r> r> drop nip EXIT THEN
1492: THEN
1493: r> drop
1494: r>
1495: REPEAT
1496: 2drop 0 ;
1497:
1498: : taddr>region-abort ( taddr -- region | 0 )
1499: dup taddr>region dup 0=
1500: IF drop cr ." Wrong address: " .addr
1501: -1 ABORT" Address out of range!"
1502: THEN nip ;
1503:
1504: : (>regionimage) ( taddr -- 'taddr )
1505: dup
1506: \ find region we want to address
1507: taddr>region-abort
1508: >r
1509: \ calculate offset in region
1510: r@ >rstart @ -
1511: \ add regions real address in our memory
1512: r> >rmem @ + ;
1513:
1514: : (>regionbm) ( taddr -- 'taddr bitmaskbaseaddr )
1515: dup
1516: \ find region we want to address
1517: taddr>region-abort
1518: >r
1519: \ calculate offset in region
1520: r@ >rstart @ -
1521: \ add regions real address in our memory
1522: r> >rbm @ ;
1523:
1524: : (>regiontype) ( taddr -- 'taddr )
1525: dup
1526: \ find region we want to address
1527: taddr>region-abort
1528: >r
1529: \ calculate offset in region
1530: r@ >rstart @ - tcell / cells
1531: \ add regions real address in our memory
1532: r> >rtype @ + ;
1533:
1534: \ Bit string manipulation 06oct92py
1535: \ 9may93jaw
1536: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
1537: : bits ( n -- n ) chars Bittable + c@ ;
1538:
1539: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
1540: : +bit ( addr n -- ) >bit over c@ or swap c! ;
1541: : -bit ( addr n -- ) >bit invert over c@ and swap c! ;
1542:
1543: : @relbit ( taddr -- f ) (>regionbm) swap cell/ >bit swap c@ and ;
1544:
1545: : (relon) ( taddr -- )
1546: [ [IFDEF] fd-relocation-table ]
1547: s" +" fd-relocation-table write-file throw
1548: dup s>d <# #s #> fd-relocation-table write-line throw
1549: [ [THEN] ]
1550: (>regionbm) swap cell/ +bit ;
1551:
1552: : (reloff) ( taddr -- )
1553: [ [IFDEF] fd-relocation-table ]
1554: s" -" fd-relocation-table write-file throw
1555: dup s>d <# #s #> fd-relocation-table write-line throw
1556: [ [THEN] ]
1557: (>regionbm) swap cell/ -bit ;
1558:
1559: : (>image) ( taddr -- absaddr ) image @ + ;
1560:
1561: DEFER >image
1562: DEFER relon
1563: DEFER reloff
1564: DEFER correcter
1565:
1566: T has? relocate H
1567: [IF]
1568: ' (relon) IS relon
1569: ' (reloff) IS reloff
1570: ' (>regionimage) IS >image
1571: [ELSE]
1572: ' drop IS relon
1573: ' drop IS reloff
1574: ' (>regionimage) IS >image
1575: [THEN]
1576:
1577: \ Target memory access 06oct92py
1578:
1579: : align+ ( taddr -- rest )
1580: tcell tuck 1- and - [ tcell 1- ] Literal and ;
1581: : cfalign+ ( taddr -- rest )
1582: \ see kernel.fs:cfaligned
1583: /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
1584:
1585: >TARGET
1586: : aligned ( taddr -- ta-addr ) dup align+ + ;
1587: \ assumes cell alignment granularity (as GNU C)
1588:
1589: : cfaligned ( taddr1 -- taddr2 )
1590: \ see kernel.fs
1591: dup cfalign+ + ;
1592:
1593: : @ ( taddr -- w ) >image S@ ;
1594: : ! ( w taddr -- ) >image S! ;
1595: : c@ ( taddr -- char ) >image Sc@ ;
1596: : c! ( char taddr -- ) >image Sc! ;
1597: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
1598: : 2! ( x1 x2 taddr -- ) T tuck ! cell+ ! H ;
1599:
1600: \ Target compilation primitives 06oct92py
1601: \ included A! 16may93jaw
1602:
1603: : here ( -- there ) there ;
1604: : allot ( n -- ) tdp +! ;
1605: : , ( w -- ) T here H tcell T allot ! H ;
1606: : c, ( char -- ) T here H tchar T allot c! H ;
1607: : align ( -- ) T here H align+ 0 ?DO bl T c, H tchar +LOOP ;
1608: : cfalign ( -- )
1609: T here H cfalign+ 0 ?DO bl T c, H tchar +LOOP ;
1610:
1611: : >address dup 0>= IF tbyte / THEN ; \ ?? jaw
1612: : A! swap >address swap dup relon T ! H ;
1613: : A, ( w -- ) >address T here H relon T , H ;
1614:
1615:
1616: \ \ -------------------- Host/Target copy etc. 29aug01jaw
1617:
1618:
1619: >CROSS
1620:
1621: : TD! >image DS! ;
1622: : TD@ >image DS@ ;
1623:
1624: : th-count ( taddr -- host-addr len )
1625: \G returns host address of target string
1626: assert1( tbyte 1 = )
1627: dup X c@ swap X char+ >image swap ;
1628:
1629: : ht-move ( haddr taddr len -- )
1630: \G moves data from host-addr to destination in target-addr
1631: \G character by character
1632: swap -rot bounds ?DO I c@ over X c! X char+ LOOP drop ;
1633:
1634: 2Variable last-string
1635:
1636: : ht-string, ( addr count -- )
1637: dup there swap last-string 2!
1638: dup T c, H bounds ?DO I c@ T c, H LOOP ;
1639:
1640: >TARGET
1641:
1642: : count dup X c@ swap X char+ swap ;
1643: \ FIXME -1 on 64 bit machines?!?!
1644: : on T -1 swap ! H ;
1645: : off T 0 swap ! H ;
1646:
1647: : tcmove ( source dest len -- )
1648: \G cmove in target memory
1649: tchar * bounds
1650: ?DO dup T c@ H I T c! H 1+
1651: tchar +LOOP drop ;
1652:
1653: : td, ( d -- )
1654: \G Store a host value as one cell into the target
1655: there tcell X allot TD! ;
1656:
1657: \ \ Load Assembler
1658:
1659: >TARGET
1660: H also Forth definitions
1661:
1662: \ FIXME: should we include the assembler really in the forth
1663: \ dictionary?!?!?!? This conflicts with the existing assembler
1664: \ of the host forth system!!
1665: [IFDEF] asm-include asm-include [THEN] hex
1666:
1667: previous
1668:
1669:
1670: >CROSS
1671:
1672: : (cc) T a, H ; ' (cc) plugin-of colon,
1673: : (prim) T a, H ; ' (prim) plugin-of prim,
1674:
1675: : (cr) >tempdp ]comp prim, comp[ tempdp> ; ' (cr) plugin-of colon-resolve
1676: : (ar) T ! H ; ' (ar) plugin-of addr-resolve
1677: : (dr) ( ghost res-pnt target-addr addr )
1678: >tempdp drop over
1679: dup >magic @ <do:> =
1680: IF doer,
1681: ELSE dodoes,
1682: THEN
1683: tempdp> ; ' (dr) plugin-of doer-resolve
1684:
1685: : (cm) ( -- addr )
1686: T here align H
1687: -1 colon, ; ' (cm) plugin-of colonmark,
1688:
1689: >TARGET
1690: : compile, ( xt -- )
1691: dup xt>ghost >comp @ EXECUTE ;
1692: >CROSS
1693:
1694: \ resolve structure
1695:
1696: : >next ; \ link to next field
1697: : >tag cell+ ; \ indecates type of reference: 0: call, 1: address, 2: doer
1698: : >taddr cell+ cell+ ;
1699: : >ghost 3 cells + ;
1700: : >file 4 cells + ;
1701: : >line 5 cells + ;
1702:
1703: : (refered) ( ghost addr tag -- )
1704: \G creates a reference to ghost at address taddr
1705: >space
1706: rot >link linked
1707: ( taddr tag ) ,
1708: ( taddr ) ,
1709: last-header-ghost @ ,
1710: loadfile ,
1711: sourceline# ,
1712: space>
1713: ;
1714:
1715: : refered ( ghost tag -- )
1716: \G creates a resolve structure
1717: T here aligned H swap (refered)
1718: ;
1719:
1720: : killref ( addr ghost -- )
1721: \G kills a forward reference to ghost at position addr
1722: \G this is used to eleminate a :dovar refence after making a DOES>
1723: dup >magic @ <fwd> <> IF 2drop EXIT THEN
1724: swap >r >link
1725: BEGIN dup @ dup ( addr last this )
1726: WHILE dup >taddr @ r@ =
1727: IF @ over !
1728: ELSE nip THEN
1729: REPEAT rdrop 2drop
1730: ;
1731:
1732: Defer resolve-warning
1733:
1734: : reswarn-test ( ghost res-struct -- ghost res-struct )
1735: over cr ." Resolving " .ghost dup ." in " >ghost @ .ghost ;
1736:
1737: : reswarn-forward ( ghost res-struct -- ghost res-struct )
1738: over warnhead .ghost dup ." is referenced in "
1739: >ghost @ .ghost ;
1740:
1741: \ ' reswarn-test IS resolve-warning
1742:
1743: \ resolve 14oct92py
1744:
1745: : resolve-loop ( ghost resolve-list tcfa -- )
1746: >r
1747: BEGIN dup WHILE
1748: \ dup >tag @ 2 = IF reswarn-forward THEN
1749: resolve-warning
1750: r@ over >taddr @
1751: 2 pick >tag @
1752: CASE 0 OF colon-resolve ENDOF
1753: 1 OF addr-resolve ENDOF
1754: 2 OF doer-resolve ENDOF
1755: ENDCASE
1756: @ \ next list element
1757: REPEAT 2drop rdrop
1758: ;
1759:
1760: \ : resolve-loop ( ghost tcfa -- ghost tcfa )
1761: \ >r dup >link @
1762: \ BEGIN dup WHILE dup T @ H r@ rot T ! H REPEAT drop r> ;
1763:
1764: \ exists 9may93jaw
1765:
1766: : exists ( ghost tcfa -- )
1767: \G print warning and set new target link in ghost
1768: swap exists-warning
1769: >link ! ;
1770:
1771: : colon-resolved ( ghost -- )
1772: >link @ colon, ; \ compile-call
1773:
1774: : prim-resolved ( ghost -- )
1775: >link @ prim, ;
1776:
1777: \ FIXME: not activated
1778: : does-resolved ( ghost -- )
1779: dup g>body alit, >do:ghost @ g>body colon, ;
1780:
1781: : (is-forward) ( ghost -- )
1782: colonmark, 0 (refered) ; \ compile space for call
1783: ' (is-forward) IS is-forward
1784:
1785: : resolve ( ghost tcfa -- )
1786: \G resolve referencies to ghost with tcfa
1787: dup taddr>region 0<> IF
1788: 2dup (>regiontype) define-addr-struct addr-xt-ghost
1789:
1790: \ we define new address only if empty
1791: \ this is for not to take over the alias ghost
1792: \ (different ghost, but identical xt)
1793: \ but the very first that really defines it
1794: dup @ 0= IF ! ELSE 2drop THEN
1795: THEN
1796:
1797: \ is ghost resolved?, second resolve means another
1798: \ definition with the same name
1799: over undefined? 0= IF exists EXIT THEN
1800: \ get linked-list
1801: swap >r r@ >link @ swap \ ( list tcfa R: ghost )
1802: \ mark ghost as resolved
1803: dup r@ >link ! <res> r@ >magic !
1804: r@ >comp @ ['] is-forward = IF
1805: ['] prim-resolved r@ >comp ! THEN
1806: \ loop through forward referencies
1807: r> -rot
1808: comp-state @ >r Resolving comp-state !
1809: resolve-loop
1810: r> comp-state !
1811:
1812: ['] noop IS resolve-warning
1813: ;
1814:
1815: \ gexecute ghost, 01nov92py
1816:
1817: \ FIXME cleanup
1818: \ : is-resolved ( ghost -- )
1819: \ >link @ colon, ; \ compile-call
1820:
1821: : (gexecute) ( ghost -- )
1822: dup >comp @ EXECUTE ;
1823:
1824: : gexecute ( ghost -- )
1825: dup >magic @ <imm> = IF -1 ABORT" CROSS: gexecute on immediate word" THEN
1826: (gexecute) ;
1827:
1828: : addr, ( ghost -- )
1829: dup forward? IF 1 refered 0 T a, H ELSE >link @ T a, H THEN ;
1830:
1831: \ !! : ghost, ghost gexecute ;
1832:
1833: \ .unresolved 11may93jaw
1834:
1835: variable ResolveFlag
1836:
1837: \ ?touched 11may93jaw
1838:
1839: : ?touched ( ghost -- flag ) dup forward? swap >link @
1840: 0 <> and ;
1841:
1842: : .forwarddefs ( ghost -- )
1843: ." appeared in:"
1844: >link
1845: BEGIN @ dup
1846: WHILE cr 5 spaces
1847: dup >ghost @ .ghost
1848: ." file " dup >file @ ?dup IF count type ELSE ." CON" THEN
1849: ." line " dup >line @ .dec
1850: REPEAT
1851: drop ;
1852:
1853: : ?resolved ( ghost -- )
1854: dup ?touched
1855: IF ResolveFlag on
1856: dup cr .ghost .forwarddefs
1857: ELSE drop
1858: THEN ;
1859:
1860: : .unresolved ( -- )
1861: ResolveFlag off cr ." Unresolved: "
1862: ghost-list
1863: BEGIN @ dup
1864: WHILE dup ?resolved
1865: REPEAT drop ResolveFlag @
1866: IF
1867: -1 abort" Unresolved words!"
1868: ELSE
1869: ." Nothing!"
1870: THEN
1871: cr ;
1872:
1873: : .stats
1874: base @ >r decimal
1875: cr ." named Headers: " headers-named @ .
1876: r> base ! ;
1877:
1878: >MINIMAL
1879:
1880: : .unresolved .unresolved ;
1881:
1882: >CROSS
1883: \ Header states 12dec92py
1884:
1885: \ : flag! ( 8b -- ) tlast @ dup >r T c@ xor r> c! H ;
1886: bigendian [IF] 0 [ELSE] tcell 1- [THEN] Constant flag+
1887: : flag! ( w -- ) tlast @ flag+ + dup >r T c@ xor r> c! H ;
1888:
1889: VARIABLE ^imm
1890:
1891: \ !! should be target wordsize specific
1892: $80 constant alias-mask
1893: $40 constant immediate-mask
1894: $20 constant restrict-mask
1895:
1896: >TARGET
1897: : immediate immediate-mask flag!
1898: ^imm @ @ dup <imm> = IF drop EXIT THEN
1899: <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
1900: <imm> ^imm @ ! ;
1901: : restrict restrict-mask flag! ;
1902:
1903: : isdoer
1904: \G define a forth word as doer, this makes obviously only sence on
1905: \G forth processors such as the PSC1000
1906: <do:> last-header-ghost @ >magic ! ;
1907: >CROSS
1908:
1909: \ Target Header Creation 01nov92py
1910:
1911: : ht-lstring, ( addr count -- )
1912: dup T , H bounds ?DO I c@ T c, H LOOP ;
1913:
1914: >TARGET
1915: : name, ( "name" -- ) bl word count ht-lstring, X cfalign ;
1916: : view, ( -- ) ( dummy ) ;
1917: >CROSS
1918:
1919: \ Target Document Creation (goes to crossdoc.fd) 05jul95py
1920:
1921: s" ./doc/crossdoc.fd" r/w create-file throw value doc-file-id
1922: \ contains the file-id of the documentation file
1923:
1924: : T-\G ( -- )
1925: source >in @ /string doc-file-id write-line throw
1926: postpone \ ;
1927:
1928: Variable to-doc to-doc on
1929:
1930: : cross-doc-entry ( -- )
1931: to-doc @ tlast @ 0<> and \ not an anonymous (i.e. noname) header
1932: IF
1933: s" " doc-file-id write-line throw
1934: s" make-doc " doc-file-id write-file throw
1935:
1936: Last-Header-Ghost @ >ghostname doc-file-id write-file throw
1937: >in @
1938: [char] ( parse 2drop
1939: [char] ) parse doc-file-id write-file throw
1940: s" )" doc-file-id write-file throw
1941: [char] \ parse 2drop
1942: T-\G
1943: >in !
1944: THEN ;
1945:
1946: \ Target TAGS creation
1947:
1948: s" kernel.TAGS" r/w create-file throw value tag-file-id
1949: \ contains the file-id of the tags file
1950:
1951: Create tag-beg 2 c, 7F c, bl c,
1952: Create tag-end 2 c, bl c, 01 c,
1953: Create tag-bof 1 c, 0C c,
1954:
1955: 2variable last-loadfilename 0 0 last-loadfilename 2!
1956:
1957: : put-load-file-name ( -- )
1958: sourcefilename last-loadfilename 2@ d<>
1959: IF
1960: tag-bof count tag-file-id write-line throw
1961: sourcefilename 2dup
1962: tag-file-id write-file throw
1963: last-loadfilename 2!
1964: s" ,0" tag-file-id write-line throw
1965: THEN ;
1966:
1967: : cross-tag-entry ( -- )
1968: tlast @ 0<> \ not an anonymous (i.e. noname) header
1969: IF
1970: put-load-file-name
1971: source >in @ min tag-file-id write-file throw
1972: tag-beg count tag-file-id write-file throw
1973: tlast @ >image count 1F and tag-file-id write-file throw
1974: tag-end count tag-file-id write-file throw
1975: base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
1976: \ >in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
1977: s" ,0" tag-file-id write-line throw
1978: base !
1979: THEN ;
1980:
1981: \ Check for words
1982:
1983: Defer skip? ' false IS skip?
1984:
1985: : skipdef ( "name" -- )
1986: \G skip definition of an undefined word in undef-words and
1987: \G all-words mode
1988: Ghost dup forward?
1989: IF >magic <skip> swap !
1990: ELSE drop THEN ;
1991:
1992: : tdefined? ( "name" -- flag )
1993: Ghost undefined? 0= ;
1994:
1995: : defined2? ( "name" -- flag )
1996: \G return true for anything else than forward, even for <skip>
1997: \G that's what we want
1998: Ghost forward? 0= ;
1999:
2000: : forced? ( "name" -- flag )
2001: \G return ture if it is a foreced skip with defskip
2002: Ghost >magic @ <skip> = ;
2003:
2004: : needed? ( -- flag ) \ name
2005: \G returns a false flag when
2006: \G a word is not defined
2007: \G a forward reference exists
2008: \G so the definition is not skipped!
2009: bl word gfind
2010: IF dup undefined?
2011: nip
2012: 0=
2013: ELSE drop true THEN ;
2014:
2015: : doer? ( -- flag ) \ name
2016: Ghost >magic @ <do:> = ;
2017:
2018: : skip-defs ( -- )
2019: BEGIN refill WHILE source -trailing nip 0= UNTIL THEN ;
2020:
2021: \ Target header creation
2022:
2023: Variable NoHeaderFlag
2024: NoHeaderFlag off
2025:
2026: : 0.r ( n1 n2 -- )
2027: base @ >r hex
2028: 0 swap <# 0 ?DO # LOOP #> type
2029: r> base ! ;
2030:
2031: : .sym ( adr len -- )
2032: \G escapes / and \ to produce sed output
2033: bounds
2034: DO I c@ dup
2035: CASE [char] / OF drop ." \/" ENDOF
2036: [char] \ OF drop ." \\" ENDOF
2037: dup OF emit ENDOF
2038: ENDCASE
2039: LOOP ;
2040:
2041: Defer setup-execution-semantics
2042: 0 Value lastghost
2043:
2044: : (THeader ( "name" -- ghost )
2045: \ >in @ bl word count type 2 spaces >in !
2046: \ wordheaders will always be compiled to rom
2047: switchrom
2048: \ build header in target
2049: NoHeaderFlag @
2050: IF NoHeaderFlag off
2051: ELSE
2052: T align H view,
2053: tlast @ dup 0> IF tcell - THEN T A, H there tlast !
2054: 1 headers-named +! \ Statistic
2055: >in @ T name, H >in !
2056: THEN
2057: T cfalign here H tlastcfa !
2058: \ Old Symbol table sed-script
2059: \ >in @ cr ." sym:s/CFA=" there 4 0.r ." /" bl word count .sym ." /g" cr >in !
2060: HeaderGhost
2061: \ output symbol table to extra file
2062: [ [IFDEF] fd-symbol-table ]
2063: base @ hex there s>d <# 8 0 DO # LOOP #> fd-symbol-table write-file throw base !
2064: s" :" fd-symbol-table write-file throw
2065: dup >ghostname fd-symbol-table write-line throw
2066: [ [THEN] ]
2067: dup Last-Header-Ghost ! dup to lastghost
2068: dup >magic ^imm ! \ a pointer for immediate
2069: alias-mask flag!
2070: cross-doc-entry cross-tag-entry
2071: setup-execution-semantics
2072: ;
2073:
2074: \ this is the resolver information from ":"
2075: \ resolving is done by ";"
2076: Variable ;Resolve 1 cells allot
2077:
2078: : hereresolve ( ghost -- )
2079: there resolve 0 ;Resolve ! ;
2080:
2081: : Theader ( "name" -- ghost )
2082: (THeader dup hereresolve ;
2083:
2084: Variable aprim-nr -20 aprim-nr !
2085:
2086: : copy-execution-semantics ( ghost-from ghost-dest -- )
2087: >r
2088: dup >exec @ r@ >exec !
2089: dup >exec2 @ r@ >exec2 !
2090: dup >exec-compile @ r@ >exec-compile !
2091: dup >ghost-xt @ r@ >ghost-xt !
2092: dup >created @ r@ >created !
2093: rdrop drop ;
2094:
2095: >TARGET
2096:
2097: : Alias ( cfa -- ) \ name
2098: >in @ skip? IF 2drop EXIT THEN >in !
2099: (THeader ( S xt ghost )
2100: 2dup swap xt>ghost swap copy-execution-semantics
2101: over resolve T A, H alias-mask flag! ;
2102:
2103: Variable last-prim-ghost
2104: 0 last-prim-ghost !
2105:
2106: : asmprimname, ( ghost -- : name )
2107: dup last-prim-ghost !
2108: >r
2109: here bl word count string, r@ >asm-name !
2110: aprim-nr @ r> >asm-dummyaddr ! ;
2111:
2112: Defer setup-prim-semantics
2113:
2114: : aprim ( -- )
2115: THeader -1 aprim-nr +! aprim-nr @ T A, H
2116: asmprimname,
2117: setup-prim-semantics ;
2118:
2119: : aprim: ( -- )
2120: -1 aprim-nr +! aprim-nr @
2121: Ghost tuck swap resolve <do:> swap tuck >magic !
2122: asmprimname, ;
2123:
2124: : Alias: ( cfa -- ) \ name
2125: >in @ skip? IF 2drop EXIT THEN >in !
2126: dup 0< s" prims" T $has? H 0= and
2127: IF
2128: .sourcepos ." needs doer: " >in @ bl word count type >in ! cr
2129: THEN
2130: Ghost tuck swap resolve <do:> swap >magic ! ;
2131:
2132: Variable prim#
2133: : first-primitive ( n -- ) prim# ! ;
2134: : Primitive ( -- ) \ name
2135: >in @ skip? IF 2drop EXIT THEN >in !
2136: dup 0< s" prims" T $has? H 0= and
2137: IF
2138: .sourcepos ." needs prim: " >in @ bl word count type >in ! cr
2139: THEN
2140: prim# @ (THeader ( S xt ghost )
2141: dup >ghost-flags <primitive> set-flag
2142: over resolve T A, H alias-mask flag!
2143: -1 prim# +! ;
2144: >CROSS
2145:
2146: \ Conditionals and Comments 11may93jaw
2147:
2148: \G saves the existing cond action, this is used for redefining in
2149: \G instant
2150: Variable cond-xt-old
2151:
2152: : cond-target ( -- )
2153: \G Compiles semantic of redefined cond into new one
2154: cond-xt-old @ compile, ; immediate restrict
2155:
2156: : ;Cond
2157: postpone ;
2158: swap ! ; immediate
2159:
2160: : Cond: ( "name" -- )
2161: \g defines a conditional or another word that must
2162: \g be executed directly while compiling
2163: \g these words have no interpretative semantics by default
2164: Ghost
2165: >exec-compile
2166: dup @ cond-xt-old !
2167: :NONAME ;
2168:
2169:
2170: : Comment ( -- )
2171: >in @ Ghost swap >in ! ' swap
2172: 2dup >exec-compile ! >exec ! ;
2173:
2174: Comment ( Comment \
2175:
2176: \ compile 10may93jaw
2177:
2178: : compile ( "name" -- ) \ name
2179: \ bl word gfind 0= ABORT" CROSS: Can't compile "
2180: ghost
2181: dup >exec-compile @ ?dup
2182: IF nip compile,
2183: ELSE postpone literal postpone gexecute THEN ; immediate restrict
2184:
2185: >TARGET
2186:
2187: : ' ( -- xt )
2188: \G returns the target-cfa of a ghost
2189: bl word gfind 0= ABORT" CROSS: Ghost don't exists"
2190: g>xt ;
2191:
2192: \ FIXME: this works for the current use cases, but is not
2193: \ in all cases correct ;-)
2194: : comp' X ' 0 ;
2195:
2196: Cond: ['] T ' H alit, ;Cond
2197:
2198: >CROSS
2199:
2200: : [T']
2201: \ returns the target-cfa of a ghost, or compiles it as literal
2202: postpone [G'] state @ IF postpone g>xt ELSE g>xt THEN ; immediate
2203:
2204: \ \ threading modell 13dec92py
2205: \ modularized 14jun97jaw
2206:
2207: T 2 cells H Value xt>body
2208:
2209: : (>body) ( cfa -- pfa )
2210: xt>body + ; ' (>body) plugin-of t>body
2211:
2212: : fillcfa ( usedcells -- )
2213: T cells H xt>body swap -
2214: assert1( dup 0 >= )
2215: 0 ?DO 0 X c, tchar +LOOP ;
2216:
2217: : (doer,) ( ghost -- )
2218: addr, 1 fillcfa ; ' (doer,) plugin-of doer,
2219:
2220: : (docol,) ( -- ) [G'] :docol (doer,) ; ' (docol,) plugin-of docol,
2221:
2222: : (doprim,) ( -- )
2223: there xt>body + ca>native T a, H 1 fillcfa ; ' (doprim,) plugin-of doprim,
2224:
2225: : (doeshandler,) ( -- )
2226: T cfalign H compile :doesjump T 0 , H ; ' (doeshandler,) plugin-of doeshandler,
2227:
2228: : (dodoes,) ( does-action-ghost -- )
2229: ]comp [G'] :dodoes gexecute comp[
2230: addr,
2231: \ the relocator in the c engine, does not like the
2232: \ does-address to marked for relocation
2233: [ T e? ec H 0= [IF] ] T here H tcell - reloff [ [THEN] ]
2234: 2 fillcfa ; ' (dodoes,) plugin-of dodoes,
2235:
2236: : (dlit,) ( n -- ) compile lit td, ; ' (dlit,) plugin-of dlit,
2237:
2238: : (lit,) ( n -- ) s>d dlit, ; ' (lit,) plugin-of lit,
2239:
2240: \ if we dont produce relocatable code alit, defaults to lit, jaw
2241: \ this is just for convenience, so we don't have to define alit,
2242: \ seperately for embedded systems....
2243: T has? relocate H
2244: [IF]
2245: : (alit,) ( n -- ) compile lit T a, H ; ' (alit,) plugin-of alit,
2246: [ELSE]
2247: : (alit,) ( n -- ) lit, ; ' (alit,) plugin-of alit,
2248: [THEN]
2249:
2250: : (fini,) compile ;s ; ' (fini,) plugin-of fini,
2251:
2252: [IFUNDEF] (code)
2253: Defer (code)
2254: Defer (end-code)
2255: [THEN]
2256:
2257: >TARGET
2258: : Code
2259: defempty?
2260: (THeader there resolve
2261: [ T e? prims H 0= [IF] T e? ITC H [ELSE] true [THEN] ] [IF]
2262: doprim,
2263: [THEN]
2264: depth (code) ;
2265:
2266: : Code:
2267: defempty?
2268: Ghost dup there ca>native resolve <do:> swap >magic !
2269: depth (code) ;
2270:
2271: : end-code
2272: (end-code)
2273: depth ?dup IF 1- <> ABORT" CROSS: Stack changed"
2274: ELSE true ABORT" CROSS: Stack empty" THEN
2275: ;
2276:
2277: >CROSS
2278:
2279: \ tLiteral 12dec92py
2280:
2281: >TARGET
2282: Cond: \G T-\G ;Cond
2283:
2284: Cond: Literal ( n -- ) lit, ;Cond
2285: Cond: ALiteral ( n -- ) alit, ;Cond
2286:
2287: : Char ( "<char>" -- ) bl word char+ c@ ;
2288: Cond: [Char] ( "<char>" -- ) Char lit, ;Cond
2289:
2290: tchar 1 = [IF]
2291: Cond: chars ;Cond
2292: [THEN]
2293:
2294: \ some special literals 27jan97jaw
2295:
2296: \ !! Known Bug: Special Literals and plug-ins work only correct
2297: \ on 16 and 32 Bit Targets and 32 Bit Hosts!
2298:
2299: \ This section could be done with dlit, now. But first I need
2300: \ some test code JAW
2301:
2302: Cond: MAXU
2303: tcell 1 cells u>
2304: IF compile lit tcell 0 ?DO FF T c, H LOOP
2305: ELSE ffffffff lit, THEN
2306: ;Cond
2307:
2308: Cond: MINI
2309: tcell 1 cells u>
2310: IF compile lit bigendian
2311: IF 80 T c, H tcell 1 ?DO 0 T c, H LOOP
2312: ELSE tcell 1 ?DO 0 T c, H LOOP 80 T c, H
2313: THEN
2314: ELSE tcell 2 = IF 8000 ELSE 80000000 THEN lit, THEN
2315: ;Cond
2316:
2317: Cond: MAXI
2318: tcell 1 cells u>
2319: IF compile lit bigendian
2320: IF 7F T c, H tcell 1 ?DO FF T c, H LOOP
2321: ELSE tcell 1 ?DO FF T c, H LOOP 7F T c, H
2322: THEN
2323: ELSE tcell 2 = IF 7fff ELSE 7fffffff THEN lit, THEN
2324: ;Cond
2325:
2326: >CROSS
2327: \ Target compiling loop 12dec92py
2328: \ ">tib trick thrown out 10may93jaw
2329: \ number? defined at the top 11may93jaw
2330: \ replaced >in by save-input
2331:
2332: : discard 0 ?DO drop LOOP ;
2333:
2334: \ compiled word might leave items on stack!
2335: : tcom ( x1 .. xn n name -- )
2336: \ dup count type space
2337: gfind
2338: IF >r ( discard saved input state ) discard r>
2339: dup >exec-compile @ ?dup
2340: IF nip execute-exec-compile ELSE gexecute THEN
2341: EXIT
2342: THEN
2343: number? dup
2344: IF 0> IF swap lit, THEN lit, discard
2345: ELSE 2drop restore-input throw Ghost gexecute THEN ;
2346:
2347: >TARGET
2348: \ : ; DOES> 13dec92py
2349: \ ] 9may93py/jaw
2350:
2351: : compiling-state ( -- )
2352: \G set states to compililng
2353: Compiling comp-state !
2354: \ if we have a state in target, change it with the compile state
2355: [G'] state dup undefined? 0=
2356: IF >ghost-xt @ execute X on ELSE drop THEN ;
2357:
2358: : interpreting-state ( -- )
2359: \G set states to interpreting
2360: \ if target has a state variable, change it according to our state
2361: [G'] state dup undefined? 0=
2362: IF >ghost-xt @ execute X off ELSE drop THEN
2363: Interpreting comp-state ! ;
2364:
2365: : ]
2366: compiling-state
2367: BEGIN
2368: BEGIN save-input bl word
2369: dup c@ 0= WHILE drop discard refill 0=
2370: ABORT" CROSS: End of file while target compiling"
2371: REPEAT
2372: tcom
2373: compiling? 0=
2374: UNTIL ;
2375:
2376: \ by the way: defining a second interpreter (a compiler-)loop
2377: \ is not allowed if a system should be ans conform
2378:
2379: : : ( -- colon-sys ) \ Name
2380: defempty?
2381: constflag off \ don't let this flag work over colon defs
2382: \ just to go sure nothing unwanted happens
2383: >in @ skip? IF drop skip-defs EXIT THEN >in !
2384: (THeader ;Resolve ! there ;Resolve cell+ !
2385: docol, ]comp colon-start depth T ] H ;
2386:
2387: : :noname ( -- colon-sys )
2388: X cfalign
2389: \ FIXME: cleanup!!!!!!!!
2390: \ idtentical to : with dummy ghost?!
2391: here ghostheader dup ;Resolve ! dup last-header-ghost ! to lastghost
2392: there ;Resolve cell+ !
2393: there docol, ]comp
2394: colon-start depth T ] H ;
2395:
2396: Cond: EXIT ( -- ) compile ;S ;Cond
2397:
2398: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
2399:
2400: >CROSS
2401: : LastXT ;Resolve @ 0= abort" CROSS: no definition for LastXT"
2402: ;Resolve cell+ @ ;
2403:
2404: >TARGET
2405:
2406: Cond: recurse ( -- ) Last-Header-Ghost @ gexecute ;Cond
2407:
2408: Cond: ; ( -- )
2409: depth ?dup
2410: IF 1- <> ABORT" CROSS: Stack changed"
2411: ELSE true ABORT" CROSS: Stack empty"
2412: THEN
2413: colon-end
2414: fini,
2415: comp[
2416: ;Resolve @
2417: IF ;Resolve @ ;Resolve cell+ @ resolve
2418: ['] colon-resolved ;Resolve @ >comp !
2419: THEN
2420: interpreting-state
2421: ;Cond
2422:
2423: Cond: [ ( -- ) interpreting-state ;Cond
2424:
2425: >CROSS
2426:
2427: Create GhostDummy ghostheader
2428: <res> GhostDummy >magic !
2429:
2430: : !does ( does-action -- )
2431: \ !! zusammenziehen und dodoes, machen!
2432: tlastcfa @ [G'] :dovar killref
2433: \ tlastcfa @ dup there >r tdp ! compile :dodoes r> tdp ! T cell+ ! H ;
2434: \ !! geht so nicht, da dodoes, ghost will!
2435: GhostDummy >link ! GhostDummy
2436: tlastcfa @ >tempdp dodoes, tempdp> ;
2437:
2438:
2439: Defer instant-interpret-does>-hook
2440:
2441: : resolve-does>-part ( -- )
2442: \ resolve words made by builders
2443: Last-Header-Ghost @ >do:ghost @ ?dup
2444: IF there resolve
2445: \ TODO: set special DOES> resolver action here
2446: THEN ;
2447:
2448: >TARGET
2449: Cond: DOES>
2450: compile (does>) doeshandler,
2451: resolve-does>-part
2452: ;Cond
2453:
2454: : DOES> switchrom doeshandler, T here H !does
2455: instant-interpret-does>-hook
2456: depth T ] H ;
2457:
2458: >CROSS
2459: \ Creation 01nov92py
2460:
2461: \ Builder 11may93jaw
2462:
2463: : Builder ( Create-xt do-ghost "name" -- )
2464: \ builds up a builder in current vocabulary
2465: \ create-xt is executed when word is interpreted
2466: \ do:-xt is executed when the created word from builder is executed
2467: \ for do:-xt an additional entry after the normal ghost-entrys is used
2468:
2469: Make-Ghost ( Create-xt do-ghost ghost )
2470: dup >created on
2471: rot swap ( do-ghost Create-xt ghost )
2472: tuck >exec !
2473: tuck >do:ghost !
2474: ['] prim-resolved over >comp !
2475: drop ;
2476:
2477: : gdoes, ( ghost -- )
2478: \ makes the codefield for a word that is built
2479: >do:ghost @ dup undefined? 0=
2480: IF
2481: dup >magic @ <do:> =
2482: IF doer,
2483: ELSE dodoes,
2484: THEN
2485: EXIT
2486: THEN
2487: \ compile :dodoes gexecute
2488: \ T here H tcell - reloff
2489: 2 refered
2490: 0 fillcfa
2491: ;
2492:
2493: : takeover-x-semantics ( S constructor-ghost new-ghost -- )
2494: \g stores execution semantic and compilation semantic in the built word
2495: \g if the word already has a semantic (concerns S", IS, .", DOES>)
2496: \g then keep it
2497: swap >do:ghost @
2498: \ we use the >exec2 field for the semantic of a crated word,
2499: \ so predefined semantics e.g. for ....
2500: \ FIXME: find an example in the normal kernel!!!
2501: 2dup >exec @ swap >exec2 !
2502: >comp @ swap >comp ! ;
2503: \ old version of this:
2504: \ >exec dup @ ['] NoExec =
2505: \ IF swap >do:ghost @ >exec @ swap ! ELSE 2drop THEN ;
2506:
2507: : TCreate ( <name> -- )
2508: create-forward-warn
2509: IF ['] reswarn-forward IS resolve-warning THEN
2510: executed-ghost @ (Theader
2511: dup >created on
2512: 2dup takeover-x-semantics hereresolve gdoes, ;
2513:
2514: : RTCreate ( <name> -- )
2515: \ creates a new word with code-field in ram
2516: create-forward-warn
2517: IF ['] reswarn-forward IS resolve-warning THEN
2518: \ make Alias
2519: executed-ghost @ (THeader
2520: dup >created on
2521: 2dup takeover-x-semantics
2522: there 0 T a, H alias-mask flag!
2523: \ store poiter to code-field
2524: switchram T cfalign H
2525: there swap T ! H
2526: there tlastcfa !
2527: hereresolve gdoes, ;
2528:
2529: : Build: ( -- [xt] [colon-sys] )
2530: :noname postpone TCreate ;
2531:
2532: : BuildSmart: ( -- [xt] [colon-sys] )
2533: :noname
2534: [ T has? rom H [IF] ]
2535: postpone RTCreate
2536: [ [ELSE] ]
2537: postpone TCreate
2538: [ [THEN] ] ;
2539:
2540: : gdoes> ( ghost -- addr flag )
2541: executed-ghost @
2542: \ FIXME: cleanup
2543: \ compiling? ABORT" CROSS: Executing gdoes> while compiling"
2544: \ ?! compiling? IF gexecute true EXIT THEN
2545: g>body ( false ) ;
2546:
2547: \ DO: ;DO 11may93jaw
2548: \ changed to ?EXIT 10may93jaw
2549:
2550: : DO: ( -- do-ghost [xt] [colon-sys] )
2551: here ghostheader
2552: :noname postpone gdoes> ( postpone ?EXIT ) ;
2553:
2554: : by: ( -- do-ghost [xt] [colon-sys] ) \ name
2555: Ghost
2556: :noname postpone gdoes> ( postpone ?EXIT ) ;
2557:
2558: : ;DO ( do-ghost [xt] [colon-sys] -- do-ghost )
2559: postpone ; ( S addr xt )
2560: over >exec ! ; immediate
2561:
2562: : by ( -- do-ghost ) \ Name
2563: Ghost >do:ghost @ ;
2564:
2565: : compile: ( do-ghost -- do-ghost [xt] [colon-sys] )
2566: \G defines a compile time action for created words
2567: \G by this builder
2568: :noname ;
2569:
2570: : ;compile ( do-ghost [xt] [colon-sys] -- do-ghost )
2571: postpone ; over >comp ! ; immediate
2572:
2573:
2574:
2575: >TARGET
2576: \ Variables and Constants 05dec92py
2577:
2578: Build: ( n -- ) ;
2579: by: :docon ( target-body-addr -- n ) T @ H ;DO
2580: Builder (Constant)
2581:
2582: Build: ( n -- ) T , H ;
2583: by (Constant)
2584: Builder Constant
2585:
2586: Build: ( n -- ) T A, H ;
2587: by (Constant)
2588: Builder AConstant
2589:
2590: Build: ( d -- ) T , , H ;
2591: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
2592: Builder 2Constant
2593:
2594: BuildSmart: ;
2595: by: :dovar ( target-body-addr -- addr ) ;DO
2596: Builder Create
2597:
2598: T has? rom H [IF]
2599: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , H ( switchrom ) ;
2600: by (Constant)
2601: Builder Variable
2602: [ELSE]
2603: Build: T 0 , H ;
2604: by Create
2605: Builder Variable
2606: [THEN]
2607:
2608: T has? rom H [IF]
2609: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , 0 , H ( switchrom ) ;
2610: by (Constant)
2611: Builder 2Variable
2612: [ELSE]
2613: Build: T 0 , 0 , H ;
2614: by Create
2615: Builder 2Variable
2616: [THEN]
2617:
2618: T has? rom H [IF]
2619: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 A, H ( switchrom ) ;
2620: by (Constant)
2621: Builder AVariable
2622: [ELSE]
2623: Build: T 0 A, H ;
2624: by Create
2625: Builder AVariable
2626: [THEN]
2627:
2628: \ User variables 04may94py
2629:
2630: >CROSS
2631:
2632: Variable tup 0 tup !
2633: Variable tudp 0 tudp !
2634:
2635: : u, ( n -- udp )
2636: tup @ tudp @ + T ! H
2637: tudp @ dup T cell+ H tudp ! ;
2638:
2639: : au, ( n -- udp )
2640: tup @ tudp @ + T A! H
2641: tudp @ dup T cell+ H tudp ! ;
2642:
2643: >TARGET
2644:
2645: Build: 0 u, X , ;
2646: by: :douser ( ghost -- up-addr ) X @ tup @ + ;DO
2647: Builder User
2648:
2649: Build: 0 u, X , 0 u, drop ;
2650: by User
2651: Builder 2User
2652:
2653: Build: 0 au, X , ;
2654: by User
2655: Builder AUser
2656:
2657: BuildSmart: T , H ;
2658: by (Constant)
2659: Builder Value
2660:
2661: BuildSmart: T A, H ;
2662: by (Constant)
2663: Builder AValue
2664:
2665: Defer texecute
2666:
2667: BuildSmart: ( -- ) [T'] noop T A, H ;
2668: by: :dodefer ( ghost -- ) X @ texecute ;DO
2669: Builder Defer
2670:
2671: Build: ( inter comp -- ) swap T immediate A, A, H ;
2672: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
2673: Builder interpret/compile:
2674:
2675: \ Sturctures 23feb95py
2676:
2677: >CROSS
2678: : nalign ( addr1 n -- addr2 )
2679: \ addr2 is the aligned version of addr1 wrt the alignment size n
2680: 1- tuck + swap invert and ;
2681: >TARGET
2682:
2683: Build: ;
2684: by: :dofield T @ H + ;DO
2685: Builder (Field)
2686:
2687: Build: ( align1 offset1 align size "name" -- align2 offset2 )
2688: rot dup T , H ( align1 align size offset1 )
2689: + >r nalign r> ;
2690: by (Field)
2691: Builder Field
2692:
2693: : struct T 1 chars 0 H ;
2694: : end-struct T 2Constant H ;
2695:
2696: : cell% ( n -- size align )
2697: T 1 cells H dup ;
2698:
2699: \ Input-Methods 01py
2700:
2701: Build: ( m v -- m' v ) dup T , cell+ H ;
2702: DO: abort" Not in cross mode" ;DO
2703: Builder input-method
2704:
2705: Build: ( m v size -- m v' ) over T , H + ;
2706: DO: abort" Not in cross mode" ;DO
2707: Builder input-var
2708:
2709:
2710:
2711:
2712: \ structural conditionals 17dec92py
2713:
2714: >CROSS
2715: : (ncontrols?) ( n -- )
2716: \g We expect n open control structures
2717: depth over u<=
2718: ABORT" CROSS: unstructured, stack underflow"
2719: 0 ?DO I pick 0=
2720: ABORT" CROSS: unstructured"
2721: LOOP ; ' (ncontrols?) plugin-of ncontrols?
2722:
2723: \ : ?struc ( flag -- ) ABORT" CROSS: unstructured " ;
2724: \ : sys? ( sys -- sys ) dup 0= ?struc ;
2725:
2726: : >mark ( -- sys ) T here ( dup ." M" hex. ) 0 , H ;
2727:
2728: : branchoffset ( src dest -- ) - tchar / ; \ ?? jaw
2729:
2730: : >resolve ( sys -- )
2731: X here ( dup ." >" hex. ) over branchoffset swap X ! ;
2732:
2733: : <resolve ( sys -- )
2734: X here ( dup ." <" hex. ) branchoffset X , ;
2735:
2736: :noname compile branch X here branchoffset X , ;
2737: IS branch, ( target-addr -- )
2738: :noname compile ?branch X here branchoffset X , ;
2739: IS ?branch, ( target-addr -- )
2740: :noname compile branch T here 0 , H ;
2741: IS branchmark, ( -- branchtoken )
2742: :noname compile ?branch T here 0 , H ;
2743: IS ?branchmark, ( -- branchtoken )
2744: :noname T here 0 , H ;
2745: IS ?domark, ( -- branchtoken )
2746: :noname dup X @ ?struc X here over branchoffset swap X ! ;
2747: IS branchtoresolve, ( branchtoken -- )
2748: :noname branchto, X here ;
2749: IS branchtomark, ( -- target-addr )
2750:
2751: >TARGET
2752:
2753: \ Structural Conditionals 12dec92py
2754:
2755: \ CLEANUP Cond: BUT sys? swap ;Cond
2756: \ CLEANUP Cond: YET sys? dup ;Cond
2757:
2758: >CROSS
2759:
2760: Variable tleavings 0 tleavings !
2761:
2762: : (done) ( addr -- )
2763: tleavings @
2764: BEGIN dup
2765: WHILE
2766: >r dup r@ cell+ @ \ address of branch
2767: u> 0= \ lower than DO?
2768: WHILE
2769: r@ 2 cells + @ \ branch token
2770: branchtoresolve,
2771: r@ @ r> free throw
2772: REPEAT r> THEN
2773: tleavings ! drop ;
2774:
2775: >TARGET
2776:
2777: \ What for? ANS? JAW Cond: DONE ( addr -- ) (done) ;Cond
2778:
2779: >CROSS
2780: : (leave) ( branchtoken -- )
2781: 3 cells allocate throw >r
2782: T here H r@ cell+ !
2783: r@ 2 cells + !
2784: tleavings @ r@ !
2785: r> tleavings ! ;
2786: >TARGET
2787:
2788: : (leave,) ( -- )
2789: branchmark, (leave) ; ' (leave,) plugin-of leave,
2790:
2791: : (?leave,) ( -- )
2792: compile 0= ?branchmark, (leave) ; ' (?leave,) plugin-of ?leave,
2793:
2794: Cond: LEAVE leave, ;Cond
2795: Cond: ?LEAVE ?leave, ;Cond
2796:
2797: >CROSS
2798: \ !!JW ToDo : Move to general tools section
2799:
2800: : to1 ( x1 x2 xn n -- addr )
2801: \G packs n stack elements in am allocated memory region
2802: dup dup 1+ cells allocate throw dup >r swap 1+
2803: 0 DO tuck ! cell+ LOOP
2804: drop r> ;
2805:
2806: : 1to ( addr -- x1 x2 xn )
2807: \G unpacks the elements saved by to1
2808: dup @ swap over cells + swap
2809: 0 DO dup @ swap 1 cells - LOOP
2810: free throw ;
2811:
2812: : loop] branchto, dup <resolve tcell - (done) ;
2813:
2814: : skiploop] ?dup IF branchto, branchtoresolve, THEN ;
2815:
2816: >TARGET
2817:
2818: \ Structural Conditionals 12dec92py
2819:
2820: : (cs-swap) ( x1 x2 -- x2 x1 )
2821: swap ; ' (cs-swap) plugin-of cs-swap
2822:
2823: : (ahead,) branchmark, ; ' (ahead,) plugin-of ahead,
2824:
2825: : (if,) ?branchmark, ; ' (if,) plugin-of if,
2826:
2827: : (then,) branchto, branchtoresolve, ; ' (then,) plugin-of then,
2828:
2829: : (else,) ( ahead ) branchmark,
2830: swap
2831: ( then ) branchto, branchtoresolve, ; ' (else,) plugin-of else,
2832:
2833: : (begin,) branchtomark, ; ' (begin,) plugin-of begin,
2834:
2835: : (while,) ( if ) ?branchmark,
2836: swap ; ' (while,) plugin-of while,
2837:
2838: : (again,) branch, ; ' (again,) plugin-of again,
2839:
2840: : (until,) ?branch, ; ' (until,) plugin-of until,
2841:
2842: : (repeat,) ( again ) branch,
2843: ( then ) branchto, branchtoresolve, ; ' (repeat,) plugin-of repeat,
2844:
2845: : (case,) ( -- n )
2846: 0 ; ' (case,) plugin-of case,
2847:
2848: : (of,) ( n -- x1 n )
2849: 1+ >r
2850: compile over compile =
2851: if, compile drop r> ; ' (of,) plugin-of of,
2852:
2853: : (endof,) ( x1 n -- x2 n )
2854: >r 1 ncontrols? else, r> ; ' (endof,) plugin-of endof,
2855:
2856: : (endcase,) ( x1 .. xn n -- )
2857: compile drop 0 ?DO 1 ncontrols? then, LOOP ; ' (endcase,) plugin-of endcase,
2858:
2859: >TARGET
2860: Cond: AHEAD ahead, ;Cond
2861: Cond: IF if, ;Cond
2862: Cond: THEN 1 ncontrols? then, ;Cond
2863: Cond: ENDIF 1 ncontrols? then, ;Cond
2864: Cond: ELSE 1 ncontrols? else, ;Cond
2865:
2866: Cond: BEGIN begin, ;Cond
2867: Cond: WHILE 1 ncontrols? while, ;Cond
2868: Cond: AGAIN 1 ncontrols? again, ;Cond
2869: Cond: UNTIL 1 ncontrols? until, ;Cond
2870: Cond: REPEAT 2 ncontrols? repeat, ;Cond
2871:
2872: Cond: CASE case, ;Cond
2873: Cond: OF of, ;Cond
2874: Cond: ENDOF endof, ;Cond
2875: Cond: ENDCASE endcase, ;Cond
2876:
2877: \ Structural Conditionals 12dec92py
2878:
2879: : (do,) ( -- target-addr )
2880: \ ?? i think 0 is too much! jaw
2881: 0 compile (do)
2882: branchtomark, 2 to1 ; ' (do,) plugin-of do,
2883:
2884: \ alternative for if no ?do
2885: \ : (do,)
2886: \ compile 2dup compile = compile IF
2887: \ compile 2drop compile ELSE
2888: \ compile (do) branchtomark, 2 to1 ;
2889:
2890: : (?do,) ( -- target-addr )
2891: 0 compile (?do) ?domark, (leave)
2892: branchtomark, 2 to1 ; ' (?do,) plugin-of ?do,
2893:
2894: : (for,) ( -- target-addr )
2895: compile (for) branchtomark, ; ' (for,) plugin-of for,
2896:
2897: : (loop,) ( target-addr -- )
2898: 1to compile (loop) loop]
2899: compile unloop skiploop] ; ' (loop,) plugin-of loop,
2900:
2901: : (+loop,) ( target-addr -- )
2902: 1to compile (+loop) loop]
2903: compile unloop skiploop] ; ' (+loop,) plugin-of +loop,
2904:
2905: : (next,)
2906: compile (next) loop] compile unloop ; ' (next,) plugin-of next,
2907:
2908: Cond: DO do, ;Cond
2909: Cond: ?DO ?do, ;Cond
2910: Cond: FOR for, ;Cond
2911:
2912: Cond: LOOP 1 ncontrols? loop, ;Cond
2913: Cond: +LOOP 1 ncontrols? +loop, ;Cond
2914: Cond: NEXT 1 ncontrols? next, ;Cond
2915:
2916: \ String words 23feb93py
2917:
2918: : ," [char] " parse ht-string, X align ;
2919:
2920: Cond: ." compile (.") T ," H ;Cond
2921: Cond: S" compile (S") T ," H ;Cond
2922: Cond: C" compile (C") T ," H ;Cond
2923: Cond: ABORT" compile (ABORT") T ," H ;Cond
2924:
2925: Cond: IS T ' >body H compile ALiteral compile ! ;Cond
2926: : IS T >address ' >body ! H ;
2927: Cond: TO T ' >body H compile ALiteral compile ! ;Cond
2928: : TO T ' >body ! H ;
2929:
2930: Cond: defers T ' >body @ compile, H ;Cond
2931:
2932: \ LINKED ERR" ENV" 2ENV" 18may93jaw
2933:
2934: \ linked list primitive
2935: : linked X here over X @ X A, swap X ! ;
2936: : chained T linked A, H ;
2937:
2938: : err" s" ErrLink linked" evaluate T , H
2939: [char] " parse ht-string, X align ;
2940:
2941: : env" [char] " parse s" EnvLink linked" evaluate
2942: ht-string, X align X , ;
2943:
2944: : 2env" [char] " parse s" EnvLink linked" evaluate
2945: here >r ht-string, X align X , X ,
2946: r> dup T c@ H 80 and swap T c! H ;
2947:
2948: \ compile must be last 22feb93py
2949:
2950: Cond: [compile] ( -- ) \ name
2951: \g For immediate words, works even if forward reference
2952: bl word gfind 0= ABORT" CROSS: Can't compile"
2953: (gexecute) ;Cond
2954:
2955: Cond: postpone ( -- ) \ name
2956: bl word gfind 0= ABORT" CROSS: Can't compile"
2957: dup >magic @ <fwd> =
2958: ABORT" CROSS: Can't postpone on forward declaration"
2959: dup >magic @ <imm> =
2960: IF (gexecute)
2961: ELSE compile (compile) addr, THEN ;Cond
2962:
2963: \ save-cross 17mar93py
2964:
2965: hex
2966:
2967: >CROSS
2968: Create magic s" Gforth2x" here over allot swap move
2969:
2970: bigendian 1+ \ strangely, in magic big=0, little=1
2971: tcell 1 = 0 and or
2972: tcell 2 = 2 and or
2973: tcell 4 = 4 and or
2974: tcell 8 = 6 and or
2975: tchar 1 = 00 and or
2976: tchar 2 = 28 and or
2977: tchar 4 = 50 and or
2978: tchar 8 = 78 and or
2979: magic 7 + c!
2980:
2981: : save-cross ( "image-name" "binary-name" -- )
2982: bl parse ." Saving to " 2dup type cr
2983: w/o bin create-file throw >r
2984: TNIL IF
2985: s" #! " r@ write-file throw
2986: bl parse r@ write-file throw
2987: s" --image-file" r@ write-file throw
2988: #lf r@ emit-file throw
2989: r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
2990: ?do
2991: bl over emit-file throw
2992: loop
2993: drop
2994: magic 8 r@ write-file throw \ write magic
2995: ELSE
2996: bl parse 2drop
2997: THEN
2998: image @ there
2999: r@ write-file throw \ write image
3000: TNIL IF
3001: bit$ @ there 1- tcell>bit rshift 1+
3002: r@ write-file throw \ write tags
3003: THEN
3004: r> close-file throw ;
3005:
3006: : save-region ( addr len -- )
3007: bl parse w/o bin create-file throw >r
3008: swap >image swap r@ write-file throw
3009: r> close-file throw ;
3010:
3011: 1 [IF]
3012:
3013: Variable name-ptr
3014: Create name-buf 200 chars allot
3015: : init-name-buf name-buf name-ptr ! ;
3016: : nb, name-ptr @ c! 1 chars name-ptr +! ;
3017: : $nb, ( adr len -- ) bounds ?DO I c@ nb, LOOP ;
3018: : @nb name-ptr @ name-buf tuck - ;
3019:
3020: \ stores a usefull string representation of the character
3021: \ in the name buffer
3022: : name-char, ( c -- )
3023: dup 'a 'z 1+ within IF nb, EXIT THEN
3024: dup 'A 'Z 1+ within IF $20 + nb, EXIT THEN
3025: dup '0 '9 1+ within IF nb, EXIT THEN
3026: CASE '+ OF s" _PLUS" $nb, ENDOF
3027: '- OF s" _MINUS" $nb, ENDOF
3028: '* OF s" _STAR" $nb, ENDOF
3029: '/ OF s" _SLASH" $nb, ENDOF
3030: '' OF s" _TICK" $nb, ENDOF
3031: '( OF s" _OPAREN" $nb, ENDOF
3032: ') OF s" _CPAREN" $nb, ENDOF
3033: '[ OF s" _OBRACKET" $nb, ENDOF
3034: '] OF s" _CBRACKET" $nb, ENDOF
3035: '! OF s" _STORE" $nb, ENDOF
3036: '@ OF s" _FETCH" $nb, ENDOF
3037: '> OF s" _GREATER" $nb, ENDOF
3038: '< OF s" _LESS" $nb, ENDOF
3039: '= OF s" _EQUAL" $nb, ENDOF
3040: '# OF s" _HASH" $nb, ENDOF
3041: '? OF s" _QUEST" $nb, ENDOF
3042: ': OF s" _COL" $nb, ENDOF
3043: '; OF s" _SEMICOL" $nb, ENDOF
3044: ', OF s" _COMMA" $nb, ENDOF
3045: '. OF s" _DOT" $nb, ENDOF
3046: '" OF s" _DQUOT" $nb, ENDOF
3047: dup
3048: base @ >r hex s>d <# #s 'X hold '_ hold #> $nb, r> base !
3049: ENDCASE ;
3050:
3051: : label-from-ghostname ( ghost -- addr len )
3052: dup >ghostname init-name-buf 'L nb, bounds
3053: ?DO I c@ name-char, LOOP
3054: \ we add the address to a name to make in unique
3055: \ because one name may appear more then once
3056: \ there are names (e.g. boot) that may be reference from other
3057: \ assembler source files, so we declare them as unique
3058: \ and don't add the address suffix
3059: dup >ghost-flags @ <unique> and 0=
3060: IF s" __" $nb, >link @ base @ >r hex 0 <# #s 'L hold #> r> base ! $nb,
3061: ELSE drop
3062: THEN
3063: @nb ;
3064:
3065: : label-from-ghostnameXX ( ghost -- addr len )
3066: \ same as (label-from-ghostname) but caches generated names
3067: dup >asm-name @ ?dup IF nip count EXIT THEN
3068: \ dup >r (label-from-ghostname) 2dup
3069: align here >r string, align
3070: r> r> >asm-name ! ;
3071:
3072: : primghostdiscover ( xt -- ghost true | xt false )
3073: dup 0= IF false EXIT THEN
3074: >r last-prim-ghost
3075: BEGIN @ dup
3076: WHILE dup >asm-dummyaddr @ r@ =
3077: IF rdrop true EXIT THEN
3078: REPEAT
3079: drop r> false ;
3080:
3081: : gdiscover2 ( xt -- ghost true | xt false )
3082: dup taddr>region 0= IF false EXIT THEN
3083: dup (>regiontype) @ dup 0= IF drop false EXIT THEN
3084: addr-xt-ghost @ dup 0= IF drop false EXIT THEN
3085: nip true ;
3086: \ dup >ghost-name @ IF nip true ELSE drop false THEN ;
3087:
3088: \ generates a label name for the target address
3089: : generate-label-name ( taddr -- addr len )
3090: gdiscover2
3091: IF dup >magic @ <do:> =
3092: IF >asm-name @ count EXIT THEN
3093: label-from-ghostname
3094: ELSE
3095: primghostdiscover
3096: IF >asm-name @ count
3097: ELSE base @ >r hex 0 <# #s 'L hold #> r> base !
3098: THEN
3099: THEN ;
3100:
3101: Variable outfile-fd
3102:
3103: : $out ( adr len -- ) outfile-fd @ write-file throw ;
3104: : nlout newline $out ;
3105: : .ux ( n -- )
3106: base @ hex swap 0 <# #S #> $out base ! ;
3107:
3108: : save-asm-region-part-aligned ( taddr len -- 'taddr 'len )
3109: dup cell/ 0
3110: ?DO nlout s" .word " $out over @relbit
3111: IF over X @ generate-label-name $out
3112: ELSE over X @ s" 0x0" $out .ux
3113: THEN
3114: tcell /string
3115: LOOP ;
3116:
3117: : print-bytes ( taddr len n -- taddr' len' )
3118: over min dup 0>
3119: IF nlout s" .byte " $out 0
3120: ?DO I 0> IF s" , " $out THEN
3121: over X c@ s" 0x0" $out .ux 1 /string
3122: LOOP
3123: THEN ;
3124:
3125: : save-asm-region-part ( addr len -- )
3126: over dup X aligned swap - ?dup
3127: IF print-bytes THEN
3128: save-asm-region-part-aligned
3129: dup dup X aligned swap - ?dup
3130: IF 2 pick @relbit ABORT" relocated field splitted"
3131: print-bytes
3132: THEN
3133: 2drop ;
3134:
3135: : print-label ( taddr -- )
3136: nlout generate-label-name $out s" :" $out ;
3137:
3138: : snl-calc ( taddr taddr2 -- )
3139: tuck over - ;
3140:
3141: : skip-nolables ( taddr -- taddr2 taddr len )
3142: \G skips memory region where no lables are defined
3143: \G starting from taddr+1
3144: \G Labels will be introduced for each reference mark
3145: \G in addr-refs.
3146: \G This word deals with lables at byte addresses as well.
3147: \G The main idea is to have an intro part which
3148: \G skips until the next cell boundary, the middle part
3149: \G which skips whole cells very efficiently and the third
3150: \G part which skips the bytes to the label in a cell
3151: dup 1+ dup (>regiontype)
3152: ( S taddr taddr-realstart type-addr )
3153: dup @ dup IF addr-refs @ THEN
3154: swap >r
3155: over align+ tuck tcell swap - rshift swap 0
3156: DO dup 1 and
3157: IF drop rdrop snl-calc UNLOOP EXIT THEN
3158: 2/ swap 1+ swap
3159: LOOP
3160: drop r> cell+
3161: ( S .. taddr2 type-addr ) dup
3162: BEGIN dup @ dup IF addr-refs @ THEN 0= WHILE cell+ REPEAT
3163: dup >r swap - 1 cells / tcell * + r>
3164: ( S .. taddr2+skiplencells type-addr )
3165: @ addr-refs @ 1 tcell lshift or
3166: BEGIN dup 1 and 0= WHILE swap 1+ swap 2/ REPEAT drop
3167: ( S .. taddr2+skiplencells+skiplenbytes )
3168: snl-calc ;
3169:
3170: : insert-label ( taddr -- )
3171: dup 0= IF drop EXIT THEN
3172: \ ignore everything which points outside our memory regions
3173: \ maybe a primitive pointer or whatever
3174: dup taddr>region 0= IF drop EXIT THEN
3175: dup >r (>regiontype) define-addr-struct addr-refs dup @
3176: r> tcell 1- and 1 swap lshift or swap ! ;
3177:
3178: \ this generates a sorted list of addresses which must be labels
3179: \ it scans therefore a whole region
3180: : generate-label-list-region ( taddr len -- )
3181: BEGIN over @relbit IF over X @ insert-label THEN
3182: tcell /string dup 0<
3183: UNTIL 2drop ;
3184:
3185: : generate-label-list ( -- )
3186: region-link
3187: BEGIN @ dup WHILE
3188: dup 0 >rlink - extent
3189: ?dup IF generate-label-list-region ELSE drop THEN
3190: REPEAT drop ;
3191:
3192: : create-outfile ( addr len -- )
3193: w/o bin create-file throw outfile-fd ! ;
3194:
3195: : close-outfile ( -- )
3196: outfile-fd @ close-file throw ;
3197:
3198: : (save-asm-region) ( region -- )
3199: \ ." label list..."
3200: generate-label-list
3201: \ ." ok!" cr
3202: extent ( S taddr len )
3203: over insert-label
3204: 2dup + dup insert-label >r ( R end-label )
3205: ( S taddr len ) drop
3206: BEGIN
3207: dup print-label
3208: dup r@ <> WHILE
3209: skip-nolables save-asm-region-part
3210: REPEAT drop rdrop ;
3211:
3212: : lineout ( addr len -- )
3213: outfile-fd @ write-line throw ;
3214:
3215: : save-asm-region ( region adr len -- )
3216: create-outfile (save-asm-region) close-outfile ;
3217:
3218: [THEN]
3219:
3220: \ \ minimal definitions
3221:
3222: >MINIMAL also minimal
3223:
3224: \ Usefull words 13feb93py
3225:
3226: : KB 400 * ;
3227:
3228: \ \ [IF] [ELSE] [THEN] ... 14sep97jaw
3229:
3230: \ it is useful to define our own structures and not to rely
3231: \ on the words in the compiler
3232: \ The words in the compiler might be defined with vocabularies
3233: \ this doesn't work with our self-made compile-loop
3234:
3235: Create parsed 20 chars allot \ store word we parsed
3236:
3237: : upcase
3238: parsed count bounds
3239: ?DO I c@ toupper I c! LOOP ;
3240:
3241: : [ELSE]
3242: 1 BEGIN
3243: BEGIN bl word count dup WHILE
3244: comment? 20 umin parsed place upcase parsed count
3245: 2dup s" [IF]" compare 0= >r
3246: 2dup s" [IFUNDEF]" compare 0= >r
3247: 2dup s" [IFDEF]" compare 0= r> or r> or
3248: IF 2drop 1+
3249: ELSE 2dup s" [ELSE]" compare 0=
3250: IF 2drop 1- dup
3251: IF 1+
3252: THEN
3253: ELSE
3254: 2dup s" [ENDIF]" compare 0= >r
3255: s" [THEN]" compare 0= r> or
3256: IF 1- THEN
3257: THEN
3258: THEN
3259: ?dup 0= ?EXIT
3260: REPEAT
3261: 2drop refill 0=
3262: UNTIL drop ; immediate
3263:
3264: : [THEN] ( -- ) ; immediate
3265:
3266: : [ENDIF] ( -- ) ; immediate
3267:
3268: : [IF] ( flag -- )
3269: 0= IF postpone [ELSE] THEN ; immediate
3270:
3271: Cond: [IF] postpone [IF] ;Cond
3272: Cond: [THEN] postpone [THEN] ;Cond
3273: Cond: [ELSE] postpone [ELSE] ;Cond
3274:
3275: \ define new [IFDEF] and [IFUNDEF] 20may93jaw
3276:
3277: : defined? tdefined? ;
3278: : needed? needed? ;
3279: : doer? doer? ;
3280:
3281: \ we want to use IFDEF on compiler directives (e.g. E?) in the source, too
3282:
3283: : directive?
3284: bl word count [ ' target >wordlist ] literal search-wordlist
3285: dup IF nip THEN ;
3286:
3287: : [IFDEF] >in @ directive? swap >in !
3288: 0= IF tdefined? ELSE name 2drop true THEN
3289: postpone [IF] ;
3290:
3291: : [IFUNDEF] tdefined? 0= postpone [IF] ;
3292:
3293: Cond: [IFDEF] postpone [IFDEF] ;Cond
3294:
3295: Cond: [IFUNDEF] postpone [IFUNDEF] ;Cond
3296:
3297: \ C: \- \+ Conditional Compiling 09jun93jaw
3298:
3299: : C: >in @ tdefined? 0=
3300: IF >in ! X :
3301: ELSE drop
3302: BEGIN bl word dup c@
3303: IF count comment? s" ;" compare 0= ?EXIT
3304: ELSE refill 0= ABORT" CROSS: Out of Input while C:"
3305: THEN
3306: AGAIN
3307: THEN ;
3308:
3309: : d? d? ;
3310:
3311: \G doesn't skip line when debug switch is on
3312: : \D D? 0= IF postpone \ THEN ;
3313:
3314: \G interprets the line if word is not defined
3315: : \- tdefined? IF postpone \ THEN ;
3316:
3317: \G interprets the line if word is defined
3318: : \+ tdefined? 0= IF postpone \ THEN ;
3319:
3320: Cond: \- \- ;Cond
3321: Cond: \+ \+ ;Cond
3322: Cond: \D \D ;Cond
3323:
3324: : ?? bl word find IF execute ELSE drop 0 THEN ;
3325:
3326: : needed:
3327: \G defines ghost for words that we want to be compiled
3328: BEGIN >in @ bl word c@ WHILE >in ! Ghost drop REPEAT drop ;
3329:
3330: \ words that should be in minimal
3331:
3332: create s-buffer 50 chars allot
3333:
3334: bigendian Constant bigendian
3335:
3336: : here there ;
3337: : equ constant ;
3338: : mark there constant ;
3339:
3340: \ compiler directives
3341: : >ram >ram ;
3342: : >rom >rom ;
3343: : >auto >auto ;
3344: : >tempdp >tempdp ;
3345: : tempdp> tempdp> ;
3346: : const constflag on ;
3347:
3348: : Redefinitions-start
3349: \G Starts a redefinition section. Warnings are disabled and
3350: \G existing ghosts are reused. This is used in the kernel
3351: \G where ( and \ and the like are redefined
3352: twarnings off warnings off reuse-ghosts on ;
3353:
3354: : Redefinitions-end
3355: \G Ends a redefinition section. Warnings are enabled again.
3356: twarnings on warnings on reuse-ghosts off ;
3357:
3358: : warnings name 3 =
3359: IF twarnings off warnings off ELSE twarnings on warnings on THEN drop ;
3360:
3361: : | ;
3362: \ : | NoHeaderFlag on ; \ This is broken (damages the last word)
3363:
3364: : save-cross save-cross ;
3365: : save-region save-region ;
3366: : tdump swap >image swap dump ;
3367:
3368: also forth
3369: [IFDEF] Label : Label defempty? Label ; [THEN]
3370: [IFDEF] start-macros : start-macros defempty? start-macros ; [THEN]
3371: \ [IFDEF] builttag : builttag builttag ; [THEN]
3372: previous
3373:
3374: : s" [char] " parse s-buffer place s-buffer count ; \ for environment?
3375: : + + ;
3376: : 1+ 1 + ;
3377: : 2+ 2 + ;
3378: : 1- 1- ;
3379: : - - ;
3380: : and and ;
3381: : or or ;
3382: : 2* 2* ;
3383: : * * ;
3384: : / / ;
3385: : dup dup ;
3386: : over over ;
3387: : swap swap ;
3388: : rot rot ;
3389: : drop drop ;
3390: : = = ;
3391: : 0= 0= ;
3392: : lshift lshift ;
3393: : 2/ 2/ ;
3394: \ : . . ;
3395:
3396: : all-words ['] forced? IS skip? ;
3397: : needed-words ['] needed? IS skip? ;
3398: : undef-words ['] defined2? IS skip? ;
3399: : skipdef skipdef ;
3400:
3401: : \ postpone \ ; immediate
3402: : \G T-\G ; immediate
3403: : ( postpone ( ; immediate
3404: : include bl word count included ;
3405: : included swap >image swap included ;
3406: : require require ;
3407: : needs require ;
3408: : .( [char] ) parse type ;
3409: : ." [char] " parse type ;
3410: : cr cr ;
3411:
3412: : times 0 ?DO dup X c, LOOP drop ; \ used for space table creation
3413:
3414: \ only forth also cross also minimal definitions order
3415:
3416: \ cross-compiler words
3417:
3418: : decimal decimal [g'] decimal >exec2 @ ?dup IF EXECUTE THEN ;
3419: : hex hex [g'] hex >exec2 @ ?dup IF EXECUTE THEN ;
3420:
3421: \ : tudp X tudp ;
3422: \ : tup X tup ;
3423:
3424: : doc-off false to-doc ! ;
3425: : doc-on true to-doc ! ;
3426:
3427: : declareunique ( "name" -- )
3428: \G Sets the unique flag for a ghost. The assembler output
3429: \G generates labels with the ghostname concatenated with the address
3430: \G while cross-compiling. The address is concatenated
3431: \G because we have double occurences of the same name.
3432: \G If we want to reference the labels from the assembler or C
3433: \G code we declare them unique, so the address is skipped.
3434: Ghost >ghost-flags dup @ <unique> or swap ! ;
3435:
3436: \ [IFDEF] dbg : dbg dbg ; [THEN]
3437:
3438: \ for debugging...
3439: \ : dbg dbg ;
3440: : horder order ;
3441: : hwords words ;
3442: \ : words also ghosts
3443: \ words previous ;
3444: : .s .s ;
3445: : bye bye ;
3446:
3447: \ dummy
3448: : group 0 word drop ;
3449:
3450: \ turnkey direction
3451: : H forth ; immediate
3452: : T minimal ; immediate
3453: : G ghosts ; immediate
3454:
3455:
3456: \ these ones are pefered:
3457:
3458: : unlock previous forth also cross ;
3459:
3460: \ also minimal
3461: >cross
3462:
3463: : turnkey
3464: ghosts-wordlist 1 set-order
3465: also target definitions
3466: also Minimal also ;
3467:
3468: >minimal
3469:
3470: : [[+++
3471: turnkey unlock ;
3472:
3473: unlock definitions also minimal
3474:
3475: : lock turnkey ;
3476:
3477: Defer +++]]-hook
3478: : +++]] +++]]-hook lock ;
3479:
3480: LOCK
3481: \ load cross compiler extension defined in mach file
3482:
3483: UNLOCK >CROSS
3484:
3485: [IFDEF] extend-cross extend-cross [THEN]
3486:
3487: LOCK
3488:
3489:
3490:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>