File:  [gforth] / gforth / cross.fs
Revision 1.94: download - view: text, annotated - select for diffs
Sun Mar 11 22:50:49 2001 UTC (18 years, 9 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Checked in cross with some part of peephole optimization (doers - not all of
them)
Checked in fontlock-mode coloring version of gforth.el

    1: \ CROSS.FS     The Cross-Compiler                      06oct92py
    2: \ Idea and implementation: Bernd Paysan (py)
    3: 
    4: \ Copyright (C) 1995,1996,1997,1998,1999,2000 Free Software Foundation, Inc.
    5: 
    6: \ This file is part of Gforth.
    7: 
    8: \ Gforth is free software; you can redistribute it and/or
    9: \ modify it under the terms of the GNU General Public License
   10: \ as published by the Free Software Foundation; either version 2
   11: \ of the License, or (at your option) any later version.
   12: 
   13: \ This program is distributed in the hope that it will be useful,
   14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   16: \ GNU General Public License for more details.
   17: 
   18: \ You should have received a copy of the GNU General Public License
   19: \ along with this program; if not, write to the Free Software
   20: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   21: 
   22: 0 
   23: [IF]
   24: 
   25: ToDo:
   26: Crossdoc destination ./doc/crossdoc.fd makes no sense when
   27: cross.fs is uses seperately. jaw
   28: Do we need this char translation with >address and in branchoffset? 
   29: (>body also affected) jaw
   30: Clean up mark> and >resolve stuff jaw
   31: 
   32: [THEN]
   33: 
   34: hex
   35: 
   36: \ debugging for compiling
   37: 
   38: \ print stack at each colon definition
   39: \ : : save-input cr bl word count type restore-input throw .s : ;
   40: 
   41: \ print stack at each created word
   42: \ : create save-input cr bl word count type restore-input throw .s create ;
   43: 
   44: 
   45: \ \ -------------  Setup Vocabularies
   46: 
   47: \ Remark: Vocabulary is not ANS, but it should work...
   48: 
   49: Vocabulary Cross
   50: Vocabulary Target
   51: Vocabulary Ghosts
   52: Vocabulary Minimal
   53: only Forth also Target also also
   54: definitions Forth
   55: 
   56: : T  previous Ghosts also Target ; immediate
   57: : G  Ghosts ; immediate
   58: : H  previous Forth also Cross ; immediate
   59: 
   60: forth definitions
   61: 
   62: : T  previous Ghosts also Target ; immediate
   63: : G  Ghosts ; immediate
   64: 
   65: : >cross  also Cross definitions previous ;
   66: : >target also Target definitions previous ;
   67: : >minimal also Minimal definitions previous ;
   68: 
   69: H
   70: 
   71: >CROSS
   72: 
   73: \ find out whether we are compiling with gforth
   74: 
   75: : defined? bl word find nip ;
   76: defined? emit-file defined? toupper and \ drop 0
   77: [IF]
   78: \ use this in a gforth system
   79: : \GFORTH ; immediate
   80: : \ANSI postpone \ ; immediate
   81: [ELSE]
   82: : \GFORTH postpone \ ; immediate
   83: : \ANSI ; immediate
   84: [THEN]
   85: 
   86: \ANSI : [IFUNDEF] defined? 0= postpone [IF] ; immediate
   87: \ANSI : [IFDEF] defined? postpone [IF] ; immediate
   88: 0 \ANSI drop 1
   89: [IF]
   90: : \G postpone \ ; immediate
   91: : rdrop postpone r> postpone drop ; immediate
   92: : name bl word count ;
   93: : bounds over + swap ;
   94: : scan >r BEGIN dup WHILE over c@ r@ <> WHILE 1 /string REPEAT THEN rdrop ;
   95: : linked here over @ , swap ! ;
   96: : alias create , DOES> @ EXECUTE ;
   97: : defer ['] noop alias ;
   98: : is state @ 
   99:   IF ' >body postpone literal postpone ! 
  100:   ELSE ' >body ! THEN ; immediate
  101: : 0>= 0< 0= ;
  102: : d<> rot <> -rot <> or ;
  103: : toupper dup [char] a [char] z 1+ within IF [char] A [char] a - + THEN ;
  104: Variable ebuf
  105: : emit-file ( c fd -- ior ) swap ebuf c! ebuf 1 chars rot write-file ;
  106: 0a Constant #lf
  107: 0d Constant #cr
  108: 
  109: [IFUNDEF] Warnings Variable Warnings [THEN]
  110: 
  111: \ \ Number parsing					23feb93py
  112: 
  113: \ number? number                                       23feb93py
  114: 
  115: Variable dpl
  116: 
  117: hex
  118: Create bases   10 ,   2 ,   A , 100 ,
  119: \              16     2    10   character
  120: 
  121: \ !! protect BASE saving wrapper against exceptions
  122: : getbase ( addr u -- addr' u' )
  123:     over c@ [char] $ - dup 4 u<
  124:     IF
  125: 	cells bases + @ base ! 1 /string
  126:     ELSE
  127: 	drop
  128:     THEN ;
  129: 
  130: : sign? ( addr u -- addr u flag )
  131:     over c@ [char] - =  dup >r
  132:     IF
  133: 	1 /string
  134:     THEN
  135:     r> ;
  136: 
  137: : s>unumber? ( addr u -- ud flag )
  138:     over [char] ' =
  139:     IF 	\ a ' alone is rather unusual :-)
  140: 	drop char+ c@ 0 true EXIT 
  141:     THEN
  142:     base @ >r  dpl on  getbase
  143:     0. 2swap
  144:     BEGIN ( d addr len )
  145: 	dup >r >number dup
  146:     WHILE \ there are characters left
  147: 	dup r> -
  148:     WHILE \ the last >number parsed something
  149: 	dup 1- dpl ! over c@ [char] . =
  150:     WHILE \ the current char is '.'
  151: 	1 /string
  152:     REPEAT  THEN \ there are unparseable characters left
  153: 	2drop false
  154:     ELSE
  155: 	rdrop 2drop true
  156:     THEN
  157:     r> base ! ;
  158: 
  159: \ ouch, this is complicated; there must be a simpler way - anton
  160: : s>number? ( addr len -- d f )
  161:     \ converts string addr len into d, flag indicates success
  162:     sign? >r
  163:     s>unumber?
  164:     0= IF
  165:         rdrop false
  166:     ELSE \ no characters left, all ok
  167: 	r>
  168: 	IF
  169: 	    dnegate
  170: 	THEN
  171: 	true
  172:     THEN ;
  173: 
  174: : s>number ( addr len -- d )
  175:     \ don't use this, there is no way to tell success
  176:     s>number? drop ;
  177: 
  178: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
  179:     s>number? 0=
  180:     IF
  181: 	2drop false  EXIT
  182:     THEN
  183:     dpl @ dup 0< IF
  184: 	nip
  185:     ELSE
  186: 	1+
  187:     THEN ;
  188: 
  189: : number? ( string -- string 0 / n -1 / d 0> )
  190:     dup >r count snumber? dup if
  191: 	rdrop
  192:     else
  193: 	r> swap
  194:     then ;
  195: 
  196: : number ( string -- d )
  197:     number? ?dup 0= abort" ?"  0<
  198:     IF
  199: 	s>d
  200:     THEN ;
  201: 
  202: [THEN]
  203: 
  204: hex     \ the defualt base for the cross-compiler is hex !!
  205: \ Warnings off
  206: 
  207: \ words that are generaly useful
  208: 
  209: : KB  400 * ;
  210: : >wordlist ( vocabulary-xt -- wordlist-struct )
  211:   also execute get-order swap >r 1- set-order r> ;
  212: 
  213: : umax 2dup u< IF swap THEN drop ;
  214: : umin 2dup u> IF swap THEN drop ;
  215: 
  216: : string, ( c-addr u -- )
  217:     \ puts down string as cstring
  218:     dup c, here swap chars dup allot move ;
  219: 
  220: : ," [char] " parse string, ;
  221: 
  222: : SetValue ( n -- <name> )
  223: \G Same behaviour as "Value" if the <name> is not defined
  224: \G Same behaviour as "to" if <name> is defined
  225: \G SetValue searches in the current vocabulary
  226:   save-input bl word >r restore-input throw r> count
  227:   get-current search-wordlist
  228:   IF	drop >r
  229: 	\ we have to set current to be topmost context wordlist
  230: 	get-order get-order get-current swap 1+ set-order
  231: 	r> ['] to execute
  232: 	set-order
  233:   ELSE Value THEN ;
  234: 
  235: : DefaultValue ( n -- <name> )
  236: \G Same behaviour as "Value" if the <name> is not defined
  237: \G DefaultValue searches in the current vocabulary
  238:  save-input bl word >r restore-input throw r> count
  239:  get-current search-wordlist
  240:  IF bl word drop 2drop ELSE Value THEN ;
  241: 
  242: hex
  243: 
  244: \ 1 Constant Cross-Flag	\ to check whether assembler compiler plug-ins are
  245: 			\ for cross-compiling
  246: \ No! we use "[IFUNDEF]" there to find out whether we are target compiling!!!
  247: 
  248: : comment? ( c-addr u -- c-addr u )
  249:         2dup s" (" compare 0=
  250:         IF    postpone (
  251:         ELSE  2dup s" \" compare 0= IF postpone \ THEN
  252:         THEN ;
  253: 
  254: \ Begin CROSS COMPILER:
  255: 
  256: \ debugging
  257: 
  258: 0 [IF]
  259: 
  260: This implements debugflags for the cross compiler and the compiled
  261: images. It works identical to the has-flags in the environment.
  262: The debugflags are defined in a vocabluary. If the word exists and
  263: its value is true, the flag is switched on.
  264: 
  265: [THEN]
  266: 
  267: >CROSS
  268: 
  269: Vocabulary debugflags	\ debug flags for cross
  270: also debugflags get-order over
  271: Constant debugflags-wl
  272: set-order previous
  273: 
  274: : DebugFlag
  275:   get-current >r debugflags-wl set-current
  276:   SetValue
  277:   r> set-current ;
  278: 
  279: : Debug? ( adr u -- flag )
  280: \G return true if debug flag is defined or switched on
  281:   debugflags-wl search-wordlist
  282:   IF EXECUTE
  283:   ELSE false THEN ;
  284: 
  285: : D? ( <name> -- flag )
  286: \G return true if debug flag is defined or switched on
  287: \G while compiling we do not return the current value but
  288:   bl word count debug? ;
  289: 
  290: : [d?]
  291: \G compile the value-xt so the debug flag can be switched
  292: \G the flag must exist!
  293:   bl word count debugflags-wl search-wordlist
  294:   IF 	compile,
  295:   ELSE  -1 ABORT" unknown debug flag"
  296: 	\ POSTPONE false 
  297:   THEN ; immediate
  298: 
  299: \ \ --------------------	source file
  300: 
  301: decimal
  302: 
  303: Variable cross-file-list
  304: 0 cross-file-list !
  305: Variable target-file-list
  306: 0 target-file-list !
  307: Variable host-file-list
  308: 0 host-file-list !
  309: 
  310: cross-file-list Value file-list
  311: 0 Value source-desc
  312: 
  313: \ file loading
  314: 
  315: : >fl-id   1 cells + ;
  316: : >fl-name 2 cells + ;
  317: 
  318: Variable filelist 0 filelist !
  319: Create NoFile ," #load-file#"
  320: 
  321: : loadfile ( -- adr )
  322:   source-desc ?dup IF >fl-name ELSE NoFile THEN ;
  323: 
  324: : sourcefilename ( -- adr len ) 
  325:   loadfile count ;
  326: 
  327: \ANSI : sourceline# 0 ;
  328: 
  329: \ \ --------------------	path handling from kernel/paths.fs
  330: 
  331: \ paths.fs path file handling                                    03may97jaw
  332: 
  333: \ -Changing the search-path:
  334: \ fpath+ <path> 	adds a directory to the searchpath
  335: \ fpath= <path>|<path>	makes complete now searchpath
  336: \ 			seperator is |
  337: \ .fpath		displays the search path
  338: \ remark I: 
  339: \ a ./ in the beginning of filename is expanded to the directory the
  340: \ current file comes from. ./ can also be included in the search-path!
  341: \ ~+/ loads from the current working directory
  342: 
  343: \ remark II:
  344: \ if there is no sufficient space for the search path increase it!
  345: 
  346: 
  347: \ -Creating custom paths:
  348: 
  349: \ It is possible to use the search mechanism on yourself.
  350: 
  351: \ Make a buffer for the path:
  352: \ create mypath	100 chars , 	\ maximum length (is checked)
  353: \ 		0 ,		\ real len
  354: \ 		100 chars allot \ space for path
  355: \ use the same functions as above with:
  356: \ mypath path+ 
  357: \ mypath path=
  358: \ mypath .path
  359: 
  360: \ do a open with the search path:
  361: \ open-path-file ( adr len path -- fd adr len ior )
  362: \ the file is opened read-only; if the file is not found an error is generated
  363: 
  364: \ questions to: wilke@jwdt.com
  365: 
  366: [IFUNDEF] +place
  367: : +place ( adr len adr )
  368:         2dup >r >r
  369:         dup c@ char+ + swap move
  370:         r> r> dup c@ rot + swap c! ;
  371: [THEN]
  372: 
  373: [IFUNDEF] place
  374: : place ( c-addr1 u c-addr2 )
  375:         2dup c! char+ swap move ;
  376: [THEN]
  377: 
  378: \ if we have path handling, use this and the setup of it
  379: [IFUNDEF] open-fpath-file
  380: 
  381: create sourcepath 1024 chars , 0 , 1024 chars allot \ !! make this dynamic
  382: sourcepath value fpath
  383: 
  384: : also-path ( adr len path^ -- )
  385:   >r
  386:   \ len check
  387:   r@ cell+ @ over + r@ @ u> ABORT" path buffer too small!"
  388:   \ copy into
  389:   tuck r@ cell+ dup @ cell+ + swap cmove
  390:   \ make delimiter
  391:   0 r@ cell+ dup @ cell+ + 2 pick + c! 1 + r> cell+ +!
  392:   ;
  393: 
  394: : only-path ( adr len path^ -- )
  395:   dup 0 swap cell+ ! also-path ;
  396: 
  397: : path+ ( path-addr  "dir" -- ) \ gforth
  398:     \G Add the directory @var{dir} to the search path @var{path-addr}.
  399:     name rot also-path ;
  400: 
  401: : fpath+ ( "dir" ) \ gforth
  402:     \G Add directory @var{dir} to the Forth search path.
  403:     fpath path+ ;
  404: 
  405: : path= ( path-addr "dir1|dir2|dir3" ) \ gforth
  406:     \G Make a complete new search path; the path separator is |.
  407:     name 2dup bounds ?DO i c@ [char] | = IF 0 i c! THEN LOOP
  408:     rot only-path ;
  409: 
  410: : fpath= ( "dir1|dir2|dir3" ) \ gforth
  411:     \G Make a complete new Forth search path; the path separator is |.
  412:     fpath path= ;
  413: 
  414: : path>counted  cell+ dup cell+ swap @ ;
  415: 
  416: : next-path ( adr len -- adr2 len2 )
  417:   2dup 0 scan
  418:   dup 0= IF     2drop 0 -rot 0 -rot EXIT THEN
  419:   >r 1+ -rot r@ 1- -rot
  420:   r> - ;
  421: 
  422: : previous-path ( path^ -- )
  423:   dup path>counted
  424:   BEGIN tuck dup WHILE repeat ;
  425: 
  426: : .path ( path-addr -- ) \ gforth
  427:     \G Display the contents of the search path @var{path-addr}.
  428:     path>counted
  429:     BEGIN next-path dup WHILE type space REPEAT 2drop 2drop ;
  430: 
  431: : .fpath ( -- ) \ gforth
  432:     \G Display the contents of the Forth search path.
  433:     fpath .path ;
  434: 
  435: : absolut-path? ( addr u -- flag ) \ gforth
  436:     \G A path is absolute if it starts with a / or a ~ (~ expansion),
  437:     \G or if it is in the form ./*, extended regexp: ^[/~]|./, or if
  438:     \G it has a colon as second character ("C:...").  Paths simply
  439:     \G containing a / are not absolute!
  440:     2dup 2 u> swap 1+ c@ [char] : = and >r \ dos absoulte: c:/....
  441:     over c@ [char] / = >r
  442:     over c@ [char] ~ = >r
  443:     \ 2dup 3 min S" ../" compare 0= r> or >r \ not catered for in expandtopic
  444:     2 min S" ./" compare 0=
  445:     r> r> r> or or or ;
  446: 
  447: Create ofile 0 c, 255 chars allot
  448: Create tfile 0 c, 255 chars allot
  449: 
  450: : pathsep? dup [char] / = swap [char] \ = or ;
  451: 
  452: : need/   ofile dup c@ + c@ pathsep? 0= IF s" /" ofile +place THEN ;
  453: 
  454: : extractpath ( adr len -- adr len2 )
  455:   BEGIN dup WHILE 1-
  456:         2dup + c@ pathsep? IF EXIT THEN
  457:   REPEAT ;
  458: 
  459: : remove~+ ( -- )
  460:     ofile count 3 min s" ~+/" compare 0=
  461:     IF
  462: 	ofile count 3 /string ofile place
  463:     THEN ;
  464: 
  465: : expandtopic ( -- ) \ stack effect correct? - anton
  466:     \ expands "./" into an absolute name
  467:     ofile count 2 min s" ./" compare 0=
  468:     IF
  469: 	ofile count 1 /string tfile place
  470: 	0 ofile c! sourcefilename extractpath ofile place
  471: 	ofile c@ IF need/ THEN
  472: 	tfile count over c@ pathsep? IF 1 /string THEN
  473: 	ofile +place
  474:     THEN ;
  475: 
  476: : compact.. ( adr len -- adr2 len2 )
  477:     \ deletes phrases like "xy/.." out of our directory name 2dec97jaw
  478:     over swap
  479:     BEGIN  dup  WHILE
  480:         dup >r '/ scan 2dup 4 min s" /../" compare 0=
  481:         IF
  482:             dup r> - >r 4 /string over r> + 4 -
  483:             swap 2dup + >r move dup r> over -
  484:         ELSE
  485:             rdrop dup 1 min /string
  486:         THEN
  487:     REPEAT  drop over - ;
  488: 
  489: : reworkdir ( -- )
  490:   remove~+
  491:   ofile count compact..
  492:   nip ofile c! ;
  493: 
  494: : open-ofile ( -- fid ior )
  495:     \G opens the file whose name is in ofile
  496:     expandtopic reworkdir
  497:     ofile count r/o open-file ;
  498: 
  499: : check-path ( adr1 len1 adr2 len2 -- fd 0 | 0 <>0 )
  500:   0 ofile ! >r >r ofile place need/
  501:   r> r> ofile +place
  502:   open-ofile ;
  503: 
  504: : open-path-file ( addr1 u1 path-addr -- wfileid addr2 u2 0 | ior ) \ gforth
  505:     \G Look in path @var{path-addr} for the file specified by @var{addr1 u1}.
  506:     \G If found, the resulting path and an open file descriptor
  507:     \G are returned. If the file is not found, @var{ior} is non-zero.
  508:   >r
  509:   2dup absolut-path?
  510:   IF    rdrop
  511:         ofile place open-ofile
  512: 	dup 0= IF >r ofile count r> THEN EXIT
  513:   ELSE  r> path>counted
  514:         BEGIN  next-path dup
  515:         WHILE  5 pick 5 pick check-path
  516:         0= IF >r 2drop 2drop r> ofile count 0 EXIT ELSE drop THEN
  517:   REPEAT
  518:         2drop 2drop 2drop -38
  519:   THEN ;
  520: 
  521: : open-fpath-file ( addr1 u1 -- wfileid addr2 u2 0 | ior ) \ gforth
  522:     \G Look in the Forth search path for the file specified by @var{addr1 u1}.
  523:     \G If found, the resulting path and an open file descriptor
  524:     \G are returned. If the file is not found, @var{ior} is non-zero.
  525:     fpath open-path-file ;
  526: 
  527: fpath= ~+
  528: 
  529: [THEN]
  530: 
  531: \ \ --------------------	include require			13may99jaw
  532: 
  533: >CROSS
  534: 
  535: : add-included-file ( adr len -- adr )
  536:   dup >fl-name char+ allocate throw >r
  537:   file-list @ r@ ! r@ file-list !
  538:   r@ >fl-name place r> ;
  539: 
  540: : included? ( c-addr u -- f )
  541:   file-list
  542:   BEGIN	@ dup
  543:   WHILE	>r 2dup r@ >fl-name count compare 0=
  544: 	IF rdrop 2drop true EXIT THEN
  545: 	r>
  546:   REPEAT
  547:   2drop drop false ;	
  548: 
  549: false DebugFlag showincludedfiles
  550: 
  551: : included1 ( fd adr u -- )
  552: \ include file adr u / fd
  553: \ we don't use fd with include-file, because the forth system
  554: \ doesn't know the name of the file to get a nice error report
  555:   [d?] showincludedfiles
  556:   IF	cr ." Including: " 2dup type ." ..." THEN
  557:   rot close-file throw
  558:   source-desc >r
  559:   add-included-file to source-desc 
  560:   sourcefilename
  561:   ['] included catch
  562:   r> to source-desc 
  563:   throw ;
  564: 
  565: : included ( adr len -- )
  566: 	cross-file-list to file-list
  567: 	open-fpath-file throw 
  568:         included1 ;
  569: 
  570: : required ( adr len -- )
  571: 	cross-file-list to file-list
  572: 	open-fpath-file throw \ 2dup cr ." R:" type
  573: 	2dup included?
  574: 	IF 	2drop close-file throw
  575: 	ELSE	included1
  576: 	THEN ;
  577: 
  578: : include bl word count included ;
  579: 
  580: : require bl word count required ;
  581: 
  582: 0 [IF]
  583: 
  584: also forth definitions previous
  585: 
  586: : included ( adr len -- ) included ;
  587: 
  588: : required ( adr len -- ) required ;
  589: 
  590: : include include ;
  591: 
  592: : require require ;
  593: 
  594: [THEN]
  595: 
  596: >CROSS
  597: hex
  598: 
  599: \ \ --------------------        Error Handling                  05aug97jaw
  600: 
  601: \ Flags
  602: 
  603: also forth definitions  \ these values may be predefined before
  604:                         \ the cross-compiler is loaded
  605: 
  606: false DefaultValue stack-warn   	 \ check on empty stack at any definition
  607: false DefaultValue create-forward-warn   \ warn on forward declaration of created words
  608: 
  609: previous >CROSS
  610: 
  611: : .dec
  612:   base @ decimal swap . base ! ;
  613: 
  614: : .sourcepos
  615:   cr sourcefilename type ." :"
  616:   sourceline# .dec ;
  617: 
  618: : warnhead
  619: \G display error-message head
  620: \G perhaps with linenumber and filename
  621:   .sourcepos ." Warning: " ;
  622: 
  623: : empty? depth IF .sourcepos ." Stack not empty!"  THEN ;
  624: 
  625: stack-warn [IF]
  626: : defempty? empty? ;
  627: [ELSE]
  628: : defempty? ; immediate
  629: [THEN]
  630: 
  631: \ \ GhostNames Ghosts                                  9may93jaw
  632: 
  633: \ second name source to search trough list
  634: 
  635: VARIABLE GhostNames
  636: 0 GhostNames !
  637: 
  638: : GhostName ( -- addr )
  639:     align here GhostNames @ , GhostNames ! here 0 ,
  640:     bl word count
  641:     \ 2dup type space
  642:     string, \ !! cfalign ?
  643:     align ;
  644: 
  645: \ Ghost Builder                                        06oct92py
  646: 
  647: \ <T T> new version with temp variable                 10may93jaw
  648: 
  649: VARIABLE VocTemp
  650: 
  651: : <T  get-current VocTemp ! also Ghosts definitions ;
  652: : T>  previous VocTemp @ set-current ;
  653: 
  654: hex
  655: 4711 Constant <fwd>             4712 Constant <res>
  656: 4713 Constant <imm>             4714 Constant <do:>
  657: 4715 Constant <skip>
  658: 
  659: \  Compiler States
  660: 
  661: Variable comp-state
  662: 0 Constant interpreting
  663: 1 Constant compiling
  664: 2 Constant resolving
  665: 3 Constant assembling
  666: 
  667: Defer lit, ( n -- )
  668: Defer alit, ( n -- )
  669: 
  670: Defer branch, ( target-addr -- )	\ compiles a branch
  671: Defer ?branch, ( target-addr -- )	\ compiles a ?branch
  672: Defer branchmark, ( -- branch-addr )	\ reserves room for a branch
  673: Defer ?branchmark, ( -- branch-addr )	\ reserves room for a ?branch
  674: Defer ?domark, ( -- branch-addr )	\ reserves room for a ?do branch
  675: Defer branchto, ( -- )			\ actual program position is target of a branch (do e.g. alignment)
  676: Defer branchtoresolve, ( branch-addr -- ) \ resolves a forward reference from branchmark
  677: Defer branchfrom, ( -- )		\ ?!
  678: Defer branchtomark, ( -- target-addr )	\ marks a branch destination
  679: 
  680: Defer colon, ( tcfa -- )		\ compiles call to tcfa at current position
  681: Defer prim, ( tcfa -- )                 \ compiles a primitive invocation
  682: 					\ at current position
  683: Defer colonmark, ( -- addr )		\ marks a colon call
  684: Defer colon-resolve ( tcfa addr -- )
  685: 
  686: Defer addr-resolve ( target-addr addr -- )
  687: Defer doer-resolve ( ghost res-pnt target-addr addr -- ghost res-pnt )
  688: 
  689: Defer do,	( -- do-token )
  690: Defer ?do,	( -- ?do-token )
  691: Defer for,	( -- for-token )
  692: Defer loop,	( do-token / ?do-token -- )
  693: Defer +loop,	( do-token / ?do-token -- )
  694: Defer next,	( for-token )
  695: 
  696: [IFUNDEF] ca>native
  697: defer ca>native	
  698: [THEN]
  699: 
  700: \ ghost structure
  701: 
  702: : >magic ;		\ type of ghost
  703: : >link cell+ ;		\ pointer where ghost is in target, or if unresolved
  704: 			\ points to the where we have to resolve (linked-list)
  705: : >exec cell+ cell+ ;	\ execution symantics (while target compiling) of ghost
  706: : >comp 3 cells + ;     \ compilation semantics
  707: : >end 4 cells + ;	\ room for additional tags
  708: 			\ for builder (create, variable...) words the
  709: 			\ execution symantics of words built are placed here
  710: 
  711: \ resolve structure
  712: 
  713: : >next ;		\ link to next field
  714: : >tag cell+ ;		\ indecates type of reference: 0: call, 1: address, 2: doer
  715: : >taddr cell+ cell+ ;	
  716: : >ghost 3 cells + ;
  717: : >file 4 cells + ;
  718: : >line 5 cells + ;
  719: 
  720: \ refer variables
  721: 
  722: Variable executed-ghost \ last executed ghost, needed in tcreate and gdoes>
  723: Variable last-ghost	\ last ghost that is created
  724: Variable last-header-ghost \ last ghost definitions with header
  725: 
  726: : (refered) ( ghost addr tag -- )
  727: \G creates a reference to ghost at address taddr
  728:     rot >r here r@ >link @ , r> >link ! 
  729:     ( taddr tag ) ,
  730:     ( taddr ) , 
  731:     last-header-ghost @ , 
  732:     loadfile , 
  733:     sourceline# , 
  734:   ;
  735: 
  736: \ iForth makes only immediate directly after create
  737: \ make atonce trick! ?
  738: 
  739: Variable atonce atonce off
  740: 
  741: : NoExec true ABORT" CROSS: Don't execute ghost, or immediate target word" ;
  742: 
  743: : is-forward   ( ghost -- )
  744:   colonmark, 0 (refered) ; \ compile space for call
  745: 
  746: : GhostHeader <fwd> , 0 , ['] NoExec , ['] is-forward , ;
  747: 
  748: : Make-Ghost ( "name" -- ghost )
  749:   >in @ GhostName swap >in !
  750:   <T Create atonce @ IF immediate atonce off THEN
  751:   here tuck swap ! ghostheader T>
  752:   dup last-ghost !
  753:   DOES> dup executed-ghost ! >exec @ execute ;
  754: 
  755: \ ghost words                                          14oct92py
  756: \                                          changed:    10may93py/jaw
  757: 
  758: : gfind   ( string -- ghost true/1 / string false )
  759: \ searches for string in word-list ghosts
  760:   dup count [ ' ghosts >wordlist ] Literal search-wordlist
  761:   dup IF >r >body nip r>  THEN ;
  762: 
  763: : gdiscover ( xt -- ghost true | xt false )
  764:   GhostNames
  765:   BEGIN @ dup
  766:   WHILE 2dup
  767:         cell+ @ dup >magic @ <fwd> <>
  768:         >r >link @ = r> and
  769:         IF cell+ @ nip true EXIT THEN
  770:   REPEAT
  771:   drop false ;
  772: 
  773: VARIABLE Already
  774: 
  775: : ghost   ( "name" -- ghost )
  776:   Already off
  777:   >in @  bl word gfind   IF  atonce off Already on nip EXIT  THEN
  778:   drop  >in !  Make-Ghost ;
  779: 
  780: : >ghostname ( ghost -- adr len )
  781:   GhostNames
  782:   BEGIN @ dup
  783:   WHILE 2dup cell+ @ =
  784:   UNTIL nip 2 cells + count
  785:   ELSE  2drop 
  786: 	\ true abort" CROSS: Ghostnames inconsistent"
  787: 	s" ?!?!?!"
  788:   THEN ;
  789: 
  790: : .ghost ( ghost -- ) >ghostname type ;
  791: 
  792: \ ' >ghostname ALIAS @name
  793: 
  794: : forward? ( ghost -- flag )
  795:   >magic @ <fwd> = ;
  796: 
  797: : undefined? ( ghost -- flag )
  798:   >magic @ dup <fwd> = swap <skip> = or ;
  799: 
  800: \ Predefined ghosts                                    12dec92py
  801: 
  802: ghost 0=                                        drop
  803: ghost branch    ghost ?branch                   2drop
  804: ghost (do)      ghost (?do)                     2drop
  805: ghost (for)                                     drop
  806: ghost (loop)    ghost (+loop)                   2drop
  807: ghost (next)                                    drop
  808: ghost unloop    ghost ;S                        2drop
  809: ghost lit       ghost (compile) ghost !         2drop drop
  810: ghost (does>)   ghost noop                      2drop
  811: ghost (.")      ghost (S")      ghost (ABORT")  2drop drop ( " )
  812: ghost '                                         drop
  813: ghost :docol    ghost :doesjump ghost :dodoes   2drop drop
  814: ghost :dovar	ghost :dodefer  ghost :dofield  2drop drop
  815: ghost over      ghost =         ghost drop      2drop drop
  816: ghost call      ghost useraddr  ghost execute   2drop drop
  817: ghost +         ghost -         ghost @         2drop drop
  818: ghost 2drop drop
  819: ghost 2dup drop
  820: 
  821: \ \ Parameter for target systems                         06oct92py
  822: 
  823: \ we define it ans like...
  824: wordlist Constant target-environment
  825: 
  826: VARIABLE env-current \ save information of current dictionary to restore with environ>
  827: 
  828: : >ENVIRON get-current env-current ! target-environment set-current ;
  829: : ENVIRON> env-current @ set-current ; 
  830: 
  831: >TARGET
  832: 
  833: : environment? ( adr len -- [ x ] true | false )
  834:   target-environment search-wordlist 
  835:   IF execute true ELSE false THEN ;
  836: 
  837: : e? bl word count T environment? H 0= ABORT" environment variable not defined!" ;
  838: 
  839: : has? 	bl word count T environment? H 
  840: 	IF 	\ environment variable is present, return its value
  841: 	ELSE	\ environment variable is not present, return false
  842: 		false \ debug true ABORT" arg" 
  843: 	THEN ;
  844: 
  845: : $has? T environment? H IF ELSE false THEN ;
  846: 
  847: >ENVIRON get-order get-current swap 1+ set-order
  848: true SetValue compiler
  849: true SetValue cross
  850: true SetValue standard-threading
  851: >TARGET previous
  852: 
  853: 0
  854: [IFDEF] mach-file mach-file count 1 [THEN]
  855: [IFDEF] machine-file machine-file 1 [THEN]
  856: [IF] 	included hex drop
  857: [ELSE]  cr ." No machine description!" ABORT 
  858: [THEN]
  859: 
  860: >ENVIRON
  861: 
  862: T has? ec H
  863: [IF]
  864: false DefaultValue relocate
  865: false DefaultValue file
  866: false DefaultValue OS
  867: false DefaultValue prims
  868: false DefaultValue floating
  869: false DefaultValue glocals
  870: false DefaultValue dcomps
  871: false DefaultValue hash
  872: false DefaultValue xconds
  873: false DefaultValue header
  874: false DefaultValue backtrace
  875: false DefaultValue new-input
  876: [THEN]
  877: 
  878: true DefaultValue interpreter
  879: true DefaultValue ITC
  880: false DefaultValue rom
  881: true DefaultValue standardthreading
  882: 
  883: >TARGET
  884: s" relocate" T environment? H 
  885: [IF]	SetValue NIL
  886: [ELSE]	>ENVIRON T NIL H SetValue relocate
  887: [THEN]
  888: 
  889: >CROSS
  890: 
  891: \ \ Create additional parameters                         19jan95py
  892: 
  893: \ currently cross only works for host machines with address-unit-bits
  894: \ eual to 8 because of s! and sc!
  895: \ but I start to query the environment just to modularize a little bit
  896: 
  897: : check-address-unit-bits ( -- )	
  898: \	s" ADDRESS-UNIT-BITS" environment?
  899: \	IF 8 <> ELSE true THEN
  900: \	ABORT" ADDRESS-UNIT-BITS unknown or not equal to 8!"
  901: 
  902: \	shit, this doesn't work because environment? is only defined for 
  903: \	gforth.fi and not kernl???.fi
  904: 	;
  905: 
  906: check-address-unit-bits
  907: 8 Constant bits/byte	\ we define: byte is address-unit
  908: 
  909: 1 bits/byte lshift Constant maxbyte 
  910: \ this sets byte size for the target machine, (probably right guess) jaw
  911: 
  912: T
  913: NIL		   	Constant TNIL
  914: cell               	Constant tcell
  915: cell<<             	Constant tcell<<
  916: cell>bit           	Constant tcell>bit
  917: bits/char          	Constant tbits/char
  918: bits/char H bits/byte T /      
  919: 			Constant tchar
  920: float             	Constant tfloat
  921: 1 bits/char lshift 	Constant tmaxchar
  922: [IFUNDEF] bits/byte
  923: 8			Constant tbits/byte
  924: [ELSE]
  925: bits/byte		Constant tbits/byte
  926: [THEN]
  927: H
  928: tbits/char bits/byte /	Constant tbyte
  929: 
  930: 
  931: \ Variables                                            06oct92py
  932: 
  933: Variable image
  934: Variable tlast    TNIL tlast !  \ Last name field
  935: Variable tlastcfa \ Last code field
  936: Variable tdoes    \ Resolve does> calls
  937: Variable bit$
  938: 
  939: \ statistics						10jun97jaw
  940: 
  941: Variable headers-named 0 headers-named !
  942: Variable user-vars 0 user-vars !
  943: 
  944: : target>bitmask-size ( u1 -- u2 )
  945:   1- tcell>bit rshift 1+ ;
  946: 
  947: : allocatetarget ( size --- adr )
  948:   dup allocate ABORT" CROSS: No memory for target"
  949:   swap over swap erase ;
  950: 
  951: \ \ memregion.fs
  952: 
  953: 
  954: Variable last-defined-region    \ pointer to last defined region
  955: Variable region-link            \ linked list with all regions
  956: Variable mirrored-link          \ linked list for mirrored regions
  957: 0 dup mirrored-link ! region-link !
  958: 
  959: 
  960: : >rname 6 cells + ;
  961: : >rbm   5 cells + ;
  962: : >rmem  4 cells + ;
  963: : >rlink 3 cells + ;
  964: : >rdp 2 cells + ;
  965: : >rlen cell+ ;
  966: : >rstart ;
  967: 
  968: 
  969: : region ( addr len -- )                \G create a new region
  970:   \ check whether predefined region exists 
  971:   save-input bl word find >r >r restore-input throw r> r> 0= 
  972:   IF	\ make region
  973: 	drop
  974: 	save-input create restore-input throw
  975: 	here last-defined-region !
  976: 	over ( startaddr ) , ( length ) , ( dp ) ,
  977: 	region-link linked 0 , 0 , bl word count string,
  978:   ELSE	\ store new parameters in region
  979:         bl word drop
  980: 	>body >r r@ last-defined-region !
  981: 	r@ >rlen ! dup r@ >rstart ! r> >rdp !
  982:   THEN ;
  983: 
  984: : borders ( region -- startaddr endaddr ) \G returns lower and upper region border
  985:   dup >rstart @ swap >rlen @ over + ;
  986: 
  987: : extent  ( region -- startaddr len )   \G returns the really used area
  988:   dup >rstart @ swap >rdp @ over - ;
  989: 
  990: : area ( region -- startaddr totallen ) \G returns the total area
  991:   dup >rstart @ swap >rlen @ ;
  992: 
  993: : mirrored                              \G mark a region as mirrored
  994:   mirrored-link
  995:   align linked last-defined-region @ , ;
  996: 
  997: : .addr ( u -- )
  998: \G prints a 16 or 32 Bit nice hex value
  999:   base @ >r hex
 1000:   tcell 2 u>
 1001:   IF s>d <# # # # # [char] . hold # # # # #> type
 1002:   ELSE s>d <# # # # # # #> type
 1003:   THEN r> base ! ;
 1004: 
 1005: : .regions                      \G display region statistic
 1006: 
 1007:   \ we want to list the regions in the right order
 1008:   \ so first collect all regions on stack
 1009:   0 region-link @
 1010:   BEGIN dup WHILE dup @ REPEAT drop
 1011:   BEGIN dup
 1012:   WHILE cr
 1013:         0 >rlink - >r
 1014:         r@ >rname count tuck type
 1015:         12 swap - 0 max spaces space
 1016:         ." Start: " r@ >rstart @ dup .addr space
 1017:         ." End: " r@ >rlen @ + .addr space
 1018:         ." DP: " r> >rdp @ .addr
 1019:   REPEAT drop
 1020:   s" rom" T $has? H 0= ?EXIT
 1021:   cr ." Mirrored:"
 1022:   mirrored-link @
 1023:   BEGIN dup
 1024:   WHILE space dup cell+ @ >rname count type @
 1025:   REPEAT drop cr
 1026:   ;
 1027: 
 1028: \ -------- predefined regions
 1029: 
 1030: 0 0 region address-space
 1031: \ total memory addressed and used by the target system
 1032: 
 1033: 0 0 region dictionary
 1034: \ rom area for the compiler
 1035: 
 1036: T has? rom H
 1037: [IF]
 1038: 0 0 region ram-dictionary mirrored
 1039: \ ram area for the compiler
 1040: [ELSE]
 1041: ' dictionary ALIAS ram-dictionary
 1042: [THEN]
 1043: 
 1044: 0 0 region return-stack
 1045: 
 1046: 0 0 region data-stack
 1047: 
 1048: 0 0 region tib-region
 1049: 
 1050: ' dictionary ALIAS rom-dictionary
 1051: 
 1052: 
 1053: : setup-target ( -- )   \G initialize targets memory space
 1054:   s" rom" T $has? H
 1055:   IF  \ check for ram and rom...
 1056:       \ address-space area nip 0<>
 1057:       ram-dictionary area nip 0<>
 1058:       rom-dictionary area nip 0<>
 1059:       and 0=
 1060:       ABORT" CROSS: define address-space, rom- , ram-dictionary, with rom-support!"
 1061:   THEN
 1062:   address-space area nip
 1063:   IF
 1064:       address-space area
 1065:   ELSE
 1066:       dictionary area
 1067:   THEN
 1068:   nip 0=
 1069:   ABORT" CROSS: define at least address-space or dictionary!!"
 1070: 
 1071:   \ allocate target for each region
 1072:   region-link
 1073:   BEGIN @ dup
 1074:   WHILE dup
 1075:         0 >rlink - >r
 1076:         r@ >rlen @
 1077:         IF      \ allocate mem
 1078:                 r@ >rlen @ dup
 1079: 
 1080:                 allocatetarget dup image !
 1081:                 r@ >rmem !
 1082: 
 1083:                 target>bitmask-size allocatetarget
 1084:                 dup bit$ !
 1085:                 r> >rbm !
 1086: 
 1087:         ELSE    r> drop THEN
 1088:    REPEAT drop ;
 1089: 
 1090: \ MakeKernal                                           		22feb99jaw
 1091: 
 1092: : makekernel ( targetsize -- targetsize )
 1093:   dup dictionary >rlen ! setup-target ;
 1094: 
 1095: >MINIMAL
 1096: : makekernel makekernel ;
 1097: >CROSS
 1098: 
 1099: \ \ switched tdp for rom support				03jun97jaw
 1100: 
 1101: \ second value is here to store some maximal value for statistics
 1102: \ tempdp is also embedded here but has nothing to do with rom support
 1103: \ (needs switched dp)
 1104: 
 1105: variable tempdp	0 ,	\ temporary dp for resolving
 1106: variable tempdp-save
 1107: 
 1108: 0 [IF]
 1109: variable romdp 0 ,      \ Dictionary-Pointer for ramarea
 1110: variable ramdp 0 ,      \ Dictionary-Pointer for romarea
 1111: 
 1112: \
 1113: variable sramdp		\ start of ram-area for forth
 1114: variable sromdp		\ start of rom-area for forth
 1115: 
 1116: [THEN]
 1117: 
 1118: 
 1119: 0 value tdp
 1120: variable fixed		\ flag: true: no automatic switching
 1121: 			\	false: switching is done automatically
 1122: 
 1123: \ Switch-Policy:
 1124: \
 1125: \ a header is always compiled into rom
 1126: \ after a created word (create and variable) compilation goes to ram
 1127: \
 1128: \ Be careful: If you want to make the data behind create into rom
 1129: \ you have to put >rom before create!
 1130: 
 1131: variable constflag constflag off
 1132: 
 1133: : activate ( region -- )
 1134: \G next code goes to this region
 1135:   >rdp to tdp ;
 1136: 
 1137: : (switchram)
 1138:   fixed @ ?EXIT s" rom" T $has? H 0= ?EXIT
 1139:   ram-dictionary activate ;
 1140: 
 1141: : switchram
 1142:   constflag @
 1143:   IF constflag off ELSE (switchram) THEN ;
 1144: 
 1145: : switchrom
 1146:   fixed @ ?EXIT rom-dictionary activate ;
 1147: 
 1148: : >tempdp ( addr -- ) 
 1149:   tdp tempdp-save ! tempdp to tdp tdp ! ;
 1150: : tempdp> ( -- )
 1151:   tempdp-save @ to tdp ;
 1152: 
 1153: : >ram  fixed off (switchram) fixed on ;
 1154: : >rom  fixed off switchrom fixed on ;
 1155: : >auto fixed off switchrom ;
 1156: 
 1157: 
 1158: 
 1159: \ : romstart dup sromdp ! romdp ! ;
 1160: \ : ramstart dup sramdp ! ramdp ! ;
 1161: 
 1162: \ default compilation goes to rom
 1163: \ when romable support is off, only the rom switch is used (!!)
 1164: >auto
 1165: 
 1166: : there  tdp @ ;
 1167: 
 1168: >TARGET
 1169: 
 1170: \ \ Target Memory Handling
 1171: 
 1172: \ Byte ordering and cell size                          06oct92py
 1173: 
 1174: : cell+         tcell + ;
 1175: : cells         tcell<< lshift ;
 1176: : chars         tchar * ;
 1177: : char+		tchar + ;
 1178: : floats	tfloat * ;
 1179:     
 1180: >CROSS
 1181: : cell/         tcell<< rshift ;
 1182: >TARGET
 1183: 20 CONSTANT bl
 1184: \ TNIL Constant NIL
 1185: 
 1186: >CROSS
 1187: 
 1188: bigendian
 1189: [IF]
 1190:    : S!  ( n addr -- )  >r s>d r> tcell bounds swap 1-
 1191:      DO  maxbyte ud/mod rot I c!  -1 +LOOP  2drop ;
 1192:    : S@  ( addr -- n )  >r 0 0 r> tcell bounds
 1193:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  LOOP d>s ;
 1194:    : Sc!  ( n addr -- )  >r s>d r> tchar bounds swap 1-
 1195:      DO  maxbyte ud/mod rot I c!  -1 +LOOP  2drop ;
 1196:    : Sc@  ( addr -- n )  >r 0 0 r> tchar bounds
 1197:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  LOOP d>s ;
 1198: [ELSE]
 1199:    : S!  ( n addr -- )  >r s>d r> tcell bounds
 1200:      DO  maxbyte ud/mod rot I c!  LOOP  2drop ;
 1201:    : S@  ( addr -- n )  >r 0 0 r> tcell bounds swap 1-
 1202:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  -1 +LOOP d>s ;
 1203:    : Sc!  ( n addr -- )  >r s>d r> tchar bounds
 1204:      DO  maxbyte ud/mod rot I c!  LOOP  2drop ;
 1205:    : Sc@  ( addr -- n )  >r 0 0 r> tchar bounds swap 1-
 1206:      DO  maxbyte * swap maxbyte um* rot + swap I c@ + swap  -1 +LOOP d>s ;
 1207: [THEN]
 1208: 
 1209: : taddr>region ( taddr -- region | 0 )
 1210: \G finds for a target-address the correct region
 1211: \G returns 0 if taddr is not in range of a target memory region
 1212:   region-link
 1213:   BEGIN @ dup
 1214:   WHILE dup >r
 1215:         0 >rlink - >r
 1216:         r@ >rlen @
 1217:         IF      dup r@ borders within
 1218:                 IF r> r> drop nip EXIT THEN
 1219:         THEN
 1220:         r> drop
 1221:         r>
 1222:   REPEAT
 1223:   2drop 0 ;
 1224: 
 1225: : (>regionimage) ( taddr -- 'taddr )
 1226:   dup
 1227:   \ find region we want to address
 1228:   taddr>region dup 0= ABORT" Address out of range!"
 1229:   >r
 1230:   \ calculate offset in region
 1231:   r@ >rstart @ -
 1232:   \ add regions real address in our memory
 1233:   r> >rmem @ + ;
 1234: 
 1235: \ Bit string manipulation                               06oct92py
 1236: \                                                       9may93jaw
 1237: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
 1238: : bits ( n -- n ) chars Bittable + c@ ;
 1239: 
 1240: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
 1241: : +bit ( addr n -- )  >bit over c@ or swap c! ;
 1242: : -bit ( addr n -- )  >bit invert over c@ and swap c! ;
 1243: 
 1244: : (relon) ( taddr -- )  
 1245:   [ [IFDEF] fd-relocation-table ]
 1246:   s" +" fd-relocation-table write-file throw
 1247:   dup s>d <# #s #> fd-relocation-table write-line throw
 1248:   [ [THEN] ]
 1249:   bit$ @ swap cell/ +bit ;
 1250: 
 1251: : (reloff) ( taddr -- ) 
 1252:   [ [IFDEF] fd-relocation-table ]
 1253:   s" -" fd-relocation-table write-file throw
 1254:   dup s>d <# #s #> fd-relocation-table write-line throw
 1255:   [ [THEN] ]
 1256:   bit$ @ swap cell/ -bit ;
 1257: 
 1258: : (>image) ( taddr -- absaddr ) image @ + ;
 1259: 
 1260: DEFER >image
 1261: DEFER relon
 1262: DEFER reloff
 1263: DEFER correcter
 1264: 
 1265: T has? relocate H
 1266: [IF]
 1267: ' (relon) IS relon
 1268: ' (reloff) IS reloff
 1269: ' (>image) IS >image
 1270: [ELSE]
 1271: ' drop IS relon
 1272: ' drop IS reloff
 1273: ' (>regionimage) IS >image
 1274: [THEN]
 1275: 
 1276: \ Target memory access                                 06oct92py
 1277: 
 1278: : align+  ( taddr -- rest )
 1279:     tcell tuck 1- and - [ tcell 1- ] Literal and ;
 1280: : cfalign+  ( taddr -- rest )
 1281:     \ see kernel.fs:cfaligned
 1282:     /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
 1283: 
 1284: >TARGET
 1285: : aligned ( taddr -- ta-addr )  dup align+ + ;
 1286: \ assumes cell alignment granularity (as GNU C)
 1287: 
 1288: : cfaligned ( taddr1 -- taddr2 )
 1289:     \ see kernel.fs
 1290:     dup cfalign+ + ;
 1291: 
 1292: : @  ( taddr -- w )     >image S@ ;
 1293: : !  ( w taddr -- )     >image S! ;
 1294: : c@ ( taddr -- char )  >image Sc@ ;
 1295: : c! ( char taddr -- )  >image Sc! ;
 1296: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
 1297: : 2! ( x1 x2 taddr -- ) T tuck ! cell+ ! H ;
 1298: 
 1299: \ Target compilation primitives                        06oct92py
 1300: \ included A!                                          16may93jaw
 1301: 
 1302: : here  ( -- there )    there ;
 1303: : allot ( n -- )        tdp +! ;
 1304: : ,     ( w -- )        T here H tcell T allot  ! H ;
 1305: : c,    ( char -- )     T here H tchar T allot c! H ;
 1306: : align ( -- )          T here H align+ 0 ?DO  bl T c, H tchar +LOOP ;
 1307: : cfalign ( -- )
 1308:     T here H cfalign+ 0 ?DO  bl T c, H tchar +LOOP ;
 1309: 
 1310: : >address		dup 0>= IF tbyte / THEN ; \ ?? jaw 
 1311: : A!                    swap >address swap dup relon T ! H ;
 1312: : A,    ( w -- )        >address T here H relon T , H ;
 1313: 
 1314: >CROSS
 1315: 
 1316: : tcmove ( source dest len -- )
 1317: \G cmove in target memory
 1318:   tchar * bounds
 1319:   ?DO  dup T c@ H I T c! H 1+
 1320:   tchar +LOOP  drop ;
 1321: 
 1322: \ \ Load Assembler
 1323: 
 1324: >TARGET
 1325: H also Forth definitions
 1326: 
 1327: : X 	bl word count [ ' target >wordlist ] Literal search-wordlist
 1328: 	IF	state @ IF compile,
 1329: 		ELSE execute THEN
 1330: 	ELSE	-1 ABORT" Cross: access method not supported!"
 1331: 	THEN ; immediate
 1332: 
 1333: [IFDEF] asm-include asm-include [THEN] hex
 1334: 
 1335: previous
 1336: >CROSS H
 1337: 
 1338: \ \ --------------------        Compiler Plug Ins               01aug97jaw
 1339: 
 1340: >TARGET
 1341: DEFER >body             \ we need the system >body
 1342: 			\ and the target >body
 1343: >CROSS
 1344: T 2 cells H VALUE xt>body
 1345: DEFER doprim,	\ compiles start of a primitive
 1346: DEFER docol,   	\ compiles start of a colon definition
 1347: DEFER doer,		
 1348: DEFER fini,      \ compiles end of definition ;s
 1349: DEFER doeshandler,
 1350: DEFER dodoes,
 1351: 
 1352: DEFER ]comp     \ starts compilation
 1353: DEFER comp[     \ ends compilation
 1354: 
 1355: : (prim) T a, H ;				' (prim) IS prim,
 1356: 
 1357: : (cr) >tempdp ]comp prim, comp[ tempdp> ; 	' (cr) IS colon-resolve
 1358: : (ar) T ! H ;					' (ar) IS addr-resolve
 1359: : (dr)  ( ghost res-pnt target-addr addr )
 1360: 	>tempdp drop over 
 1361: 	dup >magic @ <do:> =
 1362: 	IF 	doer,
 1363: 	ELSE	dodoes,
 1364: 	THEN 
 1365: 	tempdp> ;				' (dr) IS doer-resolve
 1366: 
 1367: : (cm) ( -- addr )
 1368:     T here align H
 1369:     -1 prim, ;					' (cm) IS colonmark,
 1370: 
 1371: >TARGET
 1372: : compile, prim, ;
 1373: >CROSS
 1374: 
 1375: : refered ( ghost tag -- )
 1376: \G creates a resolve structure
 1377:     T here aligned H swap (refered)
 1378:   ;
 1379: 
 1380: : killref ( addr ghost -- )
 1381: \G kills a forward reference to ghost at position addr
 1382: \G this is used to eleminate a :dovar refence after making a DOES>
 1383:     dup >magic @ <fwd> <> IF 2drop EXIT THEN
 1384:     swap >r >link
 1385:     BEGIN dup @ dup  ( addr last this )
 1386:     WHILE dup >taddr @ r@ =
 1387:  	 IF   @ over !
 1388: 	 ELSE nip THEN
 1389:     REPEAT rdrop 2drop 
 1390:   ;
 1391: 
 1392: Defer resolve-warning
 1393: 
 1394: : reswarn-test ( ghost res-struct -- ghost res-struct )
 1395:   over cr ." Resolving " .ghost dup ."  in " >ghost @ .ghost ;
 1396: 
 1397: : reswarn-forward ( ghost res-struct -- ghost res-struct )
 1398:   over warnhead .ghost dup ."  is referenced in " 
 1399:   >ghost @ .ghost ;
 1400: 
 1401: \ ' reswarn-test IS resolve-warning
 1402:  
 1403: \ resolve                                              14oct92py
 1404: 
 1405:  : resolve-loop ( ghost resolve-list tcfa -- )
 1406:     >r
 1407:     BEGIN dup WHILE 
 1408: \  	  dup >tag @ 2 = IF reswarn-forward THEN
 1409: 	  resolve-warning 
 1410: 	  r@ over >taddr @ 
 1411: 	  2 pick >tag @
 1412: 	  CASE	0 OF colon-resolve ENDOF
 1413: 		1 OF addr-resolve ENDOF
 1414: 		2 OF doer-resolve ENDOF
 1415: 	  ENDCASE
 1416: 	  @ \ next list element
 1417:     REPEAT 2drop rdrop 
 1418:   ;
 1419: 
 1420: \ : resolve-loop ( ghost tcfa -- ghost tcfa )
 1421: \  >r dup >link @
 1422: \  BEGIN  dup  WHILE  dup T @ H r@ rot T ! H REPEAT  drop r> ;
 1423: 
 1424: \ exists                                                9may93jaw
 1425: 
 1426: Variable TWarnings
 1427: TWarnings on
 1428: Variable Exists-Warnings
 1429: Exists-Warnings on
 1430: 
 1431: : exists ( ghost tcfa -- )
 1432:   over GhostNames
 1433:   BEGIN @ dup
 1434:   WHILE 2dup cell+ @ =
 1435:   UNTIL
 1436:         2 cells + count
 1437:         TWarnings @ Exists-Warnings @ and
 1438:         IF warnhead type ."  exists"
 1439:         ELSE 2drop THEN
 1440:         drop swap >link !
 1441:   ELSE  true abort" CROSS: Ghostnames inconsistent "
 1442:   THEN ;
 1443: 
 1444: : colon-resolved   ( ghost -- )
 1445:     >link @ colon, ; \ compile-call
 1446: : prim-resolved  ( ghost -- )
 1447:     >link @ prim, ;
 1448: 
 1449: : resolve  ( ghost tcfa -- )
 1450: \G resolve referencies to ghost with tcfa
 1451:     \ is ghost resolved?, second resolve means another definition with the
 1452:     \ same name
 1453:     over undefined? 0= IF  exists EXIT THEN
 1454:     \ get linked-list
 1455:     swap >r r@ >link @ swap \ ( list tcfa R: ghost )
 1456:     \ mark ghost as resolved
 1457:     dup r@ >link ! <res> r@ >magic !
 1458:     r@ >comp @ ['] is-forward = IF
 1459: 	['] prim-resolved  r@ >comp !  THEN
 1460:     \ loop through forward referencies
 1461:     r> -rot 
 1462:     comp-state @ >r Resolving comp-state !
 1463:     resolve-loop 
 1464:     r> comp-state !
 1465: 
 1466:     ['] noop IS resolve-warning 
 1467:   ;
 1468: 
 1469: \ gexecute ghost,                                      01nov92py
 1470: 
 1471: : gexecute   ( ghost -- )
 1472:     dup >comp @ execute ;
 1473: 
 1474: : addr,  ( ghost -- )
 1475:   dup forward? IF  1 refered 0 T a, H ELSE >link @ T a, H THEN ;
 1476: 
 1477: \ !! : ghost,     ghost  gexecute ;
 1478: 
 1479: \ .unresolved                                          11may93jaw
 1480: 
 1481: variable ResolveFlag
 1482: 
 1483: \ ?touched                                             11may93jaw
 1484: 
 1485: : ?touched ( ghost -- flag ) dup forward? swap >link @
 1486:                                0 <> and ;
 1487: 
 1488: : .forwarddefs ( ghost -- )
 1489: 	."  appeared in:"
 1490: 	>link
 1491: 	BEGIN	@ dup
 1492: 	WHILE	cr 5 spaces
 1493: 		dup >ghost @ .ghost
 1494: 		."  file " dup >file @ ?dup IF count type ELSE ." CON" THEN
 1495: 		."  line " dup >line @ .dec
 1496: 	REPEAT 
 1497: 	drop ;
 1498: 
 1499: : ?resolved  ( ghostname -- )
 1500:   dup cell+ @ ?touched
 1501:   IF  	dup 
 1502: 	cell+ cell+ count cr type ResolveFlag on 
 1503: 	cell+ @ .forwarddefs
 1504:   ELSE 	drop 
 1505:   THEN ;
 1506: 
 1507: : .unresolved  ( -- )
 1508:   ResolveFlag off cr ." Unresolved: "
 1509:   Ghostnames
 1510:   BEGIN @ dup
 1511:   WHILE dup ?resolved
 1512:   REPEAT drop ResolveFlag @
 1513:   IF
 1514:       -1 abort" Unresolved words!"
 1515:   ELSE
 1516:       ." Nothing!"
 1517:   THEN
 1518:   cr ;
 1519: 
 1520: : .stats
 1521:   base @ >r decimal
 1522:   cr ." named Headers: " headers-named @ . 
 1523:   r> base ! ;
 1524: 
 1525: >MINIMAL
 1526: 
 1527: : .unresolved .unresolved ;
 1528: 
 1529: >CROSS
 1530: \ Header states                                        12dec92py
 1531: 
 1532: bigendian [IF] 0 [ELSE] tcell 1- [THEN] Constant flag+
 1533: : flag! ( w -- )   tlast @ flag+ + dup >r T c@ xor r> c! H ;
 1534: 
 1535: VARIABLE ^imm
 1536: 
 1537: \ !! should be target wordsize specific
 1538: $80 constant alias-mask
 1539: $40 constant immediate-mask
 1540: $20 constant restrict-mask
 1541: 
 1542: >TARGET
 1543: : immediate     immediate-mask flag!
 1544:                 ^imm @ @ dup <imm> = IF  drop  EXIT  THEN
 1545:                 <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
 1546:                 <imm> ^imm @ ! ;
 1547: : restrict      restrict-mask flag! ;
 1548: 
 1549: : isdoer	
 1550: \G define a forth word as doer, this makes obviously only sence on
 1551: \G forth processors such as the PSC1000
 1552: 		<do:> last-header-ghost @ >magic ! ;
 1553: >CROSS
 1554: 
 1555: \ Target Header Creation                               01nov92py
 1556: 
 1557: >TARGET
 1558: : string,  ( addr count -- )
 1559:     dup T c, H bounds  ?DO  I c@ T c, H  LOOP ;
 1560: : lstring, ( addr count -- )
 1561:     dup T , H bounds  ?DO  I c@ T c, H  LOOP ;
 1562: : name,  ( "name" -- )  bl word count T lstring, cfalign H ;
 1563: : view,   ( -- ) ( dummy ) ;
 1564: >CROSS
 1565: 
 1566: \ Target Document Creation (goes to crossdoc.fd)       05jul95py
 1567: 
 1568: s" ./doc/crossdoc.fd" r/w create-file throw value doc-file-id
 1569: \ contains the file-id of the documentation file
 1570: 
 1571: : T-\G ( -- )
 1572:     source >in @ /string doc-file-id write-line throw
 1573:     postpone \ ;
 1574: 
 1575: Variable to-doc  to-doc on
 1576: 
 1577: : cross-doc-entry  ( -- )
 1578:     to-doc @ tlast @ 0<> and	\ not an anonymous (i.e. noname) header
 1579:     IF
 1580: 	s" " doc-file-id write-line throw
 1581: 	s" make-doc " doc-file-id write-file throw
 1582: 
 1583: 	tlast @ >image count 1F and doc-file-id write-file throw
 1584: 	>in @
 1585: 	[char] ( parse 2drop
 1586: 	[char] ) parse doc-file-id write-file throw
 1587: 	s"  )" doc-file-id write-file throw
 1588: 	[char] \ parse 2drop					
 1589: 	T-\G
 1590: 	>in !
 1591:     THEN ;
 1592: 
 1593: \ Target TAGS creation
 1594: 
 1595: s" kernel.TAGS" r/w create-file throw value tag-file-id
 1596: \ contains the file-id of the tags file
 1597: 
 1598: Create tag-beg 2 c,  7F c, bl c,
 1599: Create tag-end 2 c,  bl c, 01 c,
 1600: Create tag-bof 1 c,  0C c,
 1601: 
 1602: 2variable last-loadfilename 0 0 last-loadfilename 2!
 1603: 	    
 1604: : put-load-file-name ( -- )
 1605:     sourcefilename last-loadfilename 2@ d<>
 1606:     IF
 1607: 	tag-bof count tag-file-id write-line throw
 1608: 	sourcefilename 2dup
 1609: 	tag-file-id write-file throw
 1610: 	last-loadfilename 2!
 1611: 	s" ,0" tag-file-id write-line throw
 1612:     THEN ;
 1613: 
 1614: : cross-tag-entry  ( -- )
 1615:     tlast @ 0<>	\ not an anonymous (i.e. noname) header
 1616:     IF
 1617: 	put-load-file-name
 1618: 	source >in @ min tag-file-id write-file throw
 1619: 	tag-beg count tag-file-id write-file throw
 1620: 	tlast @ >image count 1F and tag-file-id write-file throw
 1621: 	tag-end count tag-file-id write-file throw
 1622: 	base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
 1623: \	>in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
 1624: 	s" ,0" tag-file-id write-line throw
 1625: 	base !
 1626:     THEN ;
 1627: 
 1628: \ Check for words
 1629: 
 1630: Defer skip? ' false IS skip?
 1631: 
 1632: : skipdef ( <name> -- )
 1633: \G skip definition of an undefined word in undef-words and
 1634: \G all-words mode
 1635:     ghost dup forward?
 1636:     IF  >magic <skip> swap !
 1637:     ELSE drop THEN ;
 1638: 
 1639: : tdefined? ( -- flag ) \ name
 1640:     ghost undefined? 0= ;
 1641: 
 1642: : defined2? ( -- flag ) \ name
 1643: \G return true for anything else than forward, even for <skip>
 1644: \G that's what we want
 1645:     ghost forward? 0= ;
 1646: 
 1647: : forced? ( -- flag ) \ name
 1648: \G return ture if it is a foreced skip with defskip
 1649:     ghost >magic @ <skip> = ;
 1650: 
 1651: : needed? ( -- flag ) \ name
 1652: \G returns a false flag when
 1653: \G a word is not defined
 1654: \G a forward reference exists
 1655: \G so the definition is not skipped!
 1656:     bl word gfind
 1657:     IF dup undefined?
 1658: 	nip
 1659: 	0=
 1660:     ELSE  drop true  THEN ;
 1661: 
 1662: : doer? ( -- flag ) \ name
 1663:     ghost >magic @ <do:> = ;
 1664: 
 1665: : skip-defs ( -- )
 1666:     BEGIN  refill  WHILE  source -trailing nip 0= UNTIL  THEN ;
 1667: 
 1668: \ Target header creation
 1669: 
 1670: Variable NoHeaderFlag
 1671: NoHeaderFlag off
 1672: 
 1673: : 0.r ( n1 n2 -- ) 
 1674:     base @ >r hex 
 1675:     0 swap <# 0 ?DO # LOOP #> type 
 1676:     r> base ! ;
 1677: 
 1678: : .sym ( adr len -- )
 1679: \G escapes / and \ to produce sed output
 1680:   bounds 
 1681:   DO I c@ dup
 1682: 	CASE	[char] / OF drop ." \/" ENDOF
 1683: 		[char] \ OF drop ." \\" ENDOF
 1684: 		dup OF emit ENDOF
 1685: 	ENDCASE
 1686:     LOOP ;
 1687: 
 1688: : (Theader ( "name" -- ghost )
 1689:     \  >in @ bl word count type 2 spaces >in !
 1690:     \ wordheaders will always be compiled to rom
 1691:     switchrom
 1692:     \ build header in target
 1693:     NoHeaderFlag @
 1694:     IF  NoHeaderFlag off
 1695:     ELSE
 1696: 	T align H view,
 1697: 	tlast @ dup 0> IF tcell - THEN T A, H  there tlast !
 1698: 	1 headers-named +!	\ Statistic
 1699: 	>in @ T name, H >in !
 1700:     THEN
 1701:     T cfalign here H tlastcfa !
 1702:     \ Old Symbol table sed-script
 1703: \    >in @ cr ." sym:s/CFA=" there 4 0.r ." /"  bl word count .sym ." /g" cr >in !
 1704:     ghost
 1705:     \ output symbol table to extra file
 1706:     [ [IFDEF] fd-symbol-table ]
 1707:       base @ hex there s>d <# 8 0 DO # LOOP #> fd-symbol-table write-file throw base !
 1708:       s" :" fd-symbol-table write-file throw
 1709:       dup >ghostname fd-symbol-table write-line throw
 1710:     [ [THEN] ]
 1711:     dup Last-Header-Ghost !
 1712:     dup >magic ^imm !     \ a pointer for immediate
 1713:     Already @
 1714:     IF  dup >end tdoes !
 1715:     ELSE 0 tdoes !
 1716:     THEN
 1717:     alias-mask flag!
 1718:     cross-doc-entry cross-tag-entry ;
 1719: 
 1720: VARIABLE ;Resolve 1 cells allot
 1721: \ this is the resolver information from ":"
 1722: \ resolving is done by ";"
 1723: 
 1724: : Theader  ( "name" -- ghost )
 1725:   (THeader dup there resolve 0 ;Resolve ! ;
 1726: 
 1727: >TARGET
 1728: : Alias    ( cfa -- ) \ name
 1729:     >in @ skip? IF  2drop  EXIT  THEN  >in !
 1730:     dup 0< s" prims" T $has? H 0= and
 1731:     IF
 1732: 	.sourcepos ." needs prim: " >in @ bl word count type >in ! cr
 1733:     THEN
 1734:     (THeader over resolve T A, H alias-mask flag! ;
 1735: : Alias:   ( cfa -- ) \ name
 1736:     >in @ skip? IF  2drop  EXIT  THEN  >in !
 1737:     dup 0< s" prims" T $has? H 0= and
 1738:     IF
 1739: 	.sourcepos ." needs doer: " >in @ bl word count type >in ! cr
 1740:     THEN
 1741:     ghost tuck swap resolve <do:> swap >magic ! ;
 1742: 
 1743: Variable prim#
 1744: : first-primitive ( n -- )  prim# ! ;
 1745: : Primitive  ( -- ) \ name
 1746:     prim# @ T Alias H  -1 prim# +! ;
 1747: >CROSS
 1748: 
 1749: \ Conditionals and Comments                            11may93jaw
 1750: 
 1751: : ;Cond
 1752:   postpone ;
 1753:   swap ! ;  immediate
 1754: 
 1755: : Cond: ( -- ) \ name {code } ;
 1756:   atonce on
 1757:   ghost
 1758:   >exec
 1759:   :NONAME ;
 1760: 
 1761: : restrict? ( -- )
 1762: \ aborts on interprete state - ae
 1763:   state @ 0= ABORT" CROSS: Restricted" ;
 1764: 
 1765: : Comment ( -- )
 1766:   >in @ atonce on ghost swap >in ! ' swap >exec ! ;
 1767: 
 1768: Comment (       Comment \
 1769: 
 1770: \ compile                                              10may93jaw
 1771: 
 1772: : compile  ( -- ) \ name
 1773:   restrict?
 1774:   bl word gfind dup 0= ABORT" CROSS: Can't compile "
 1775:   0> ( immediate? )
 1776:   IF    >exec @ compile,
 1777:   ELSE  postpone literal postpone gexecute  THEN ;
 1778:                                         immediate
 1779: 
 1780: : (cc) compile call T a, H ;		' (cc) IS colon,
 1781: 
 1782: : [G'] 
 1783: \G ticks a ghost and returns its address
 1784:   bl word gfind 0= ABORT" CROSS: Ghost don't exists"
 1785:   state @
 1786:   IF   postpone literal
 1787:   THEN ; immediate
 1788: 
 1789: : ghost>cfa
 1790:   dup undefined? ABORT" CROSS: forward " >link @ ;
 1791:                
 1792: >TARGET
 1793: 
 1794: : '  ( -- cfa ) 
 1795: \ returns the target-cfa of a ghost
 1796:   bl word gfind 0= ABORT" CROSS: Ghost don't exists"
 1797:   ghost>cfa ;
 1798: 
 1799: Cond: [']  T ' H alit, ;Cond
 1800: 
 1801: >CROSS
 1802: 
 1803: : [T']
 1804: \ returns the target-cfa of a ghost, or compiles it as literal
 1805:   postpone [G'] state @ IF postpone ghost>cfa ELSE ghost>cfa THEN ; immediate
 1806: 
 1807: \ \ threading modell					13dec92py
 1808: \ modularized						14jun97jaw
 1809: 
 1810: : fillcfa   ( usedcells -- )
 1811:   T cells H xt>body swap - 0 ?DO 0 X c, tchar +LOOP ;
 1812: 
 1813: : (>body)   ( cfa -- pfa ) xt>body + ;		' (>body) T IS >body H
 1814: 
 1815: : (doer,)   ( ghost -- ) ]comp addr, comp[ 1 fillcfa ;   ' (doer,) IS doer,
 1816: 
 1817: : (docol,)  ( -- ) [G'] :docol doer, ;		' (docol,) IS docol,
 1818: 
 1819: : (doprim,) ( -- )
 1820:   there xt>body + ca>native T a, H 1 fillcfa ;	' (doprim,) IS doprim,
 1821: 
 1822: : (doeshandler,) ( -- ) 
 1823:   T cfalign H compile :doesjump T 0 , H ; 	' (doeshandler,) IS doeshandler,
 1824: 
 1825: : (dodoes,) ( does-action-ghost -- )
 1826:   ]comp [G'] :dodoes gexecute comp[
 1827:   addr,
 1828:   T here H tcell - reloff 2 fillcfa ;		' (dodoes,) IS dodoes,
 1829: 
 1830: : (lit,) ( n -- )   compile lit T  ,  H ;	' (lit,) IS lit,
 1831: 
 1832: \ if we dont produce relocatable code alit, defaults to lit, jaw
 1833: \ this is just for convenience, so we don't have to define alit,
 1834: \ seperately for embedded systems....
 1835: T has? relocate H
 1836: [IF]
 1837: : (alit,) ( n -- )  compile lit T  a, H ;	' (alit,) IS alit,
 1838: [ELSE]
 1839: : (alit,) ( n -- )  lit, ;			' (alit,) IS alit,
 1840: [THEN]
 1841: 
 1842: : (fini,)         compile ;s ;                ' (fini,) IS fini,
 1843: 
 1844: [IFUNDEF] (code) 
 1845: Defer (code)
 1846: Defer (end-code)
 1847: [THEN]
 1848: 
 1849: >TARGET
 1850: : Code
 1851:   defempty?
 1852:   (THeader there resolve
 1853:   [ T e? prims H 0= [IF] T e? ITC H [ELSE] true [THEN] ] [IF]
 1854:   doprim, 
 1855:   [THEN]
 1856:   depth (code) ;
 1857: 
 1858: : Code:
 1859:   defempty?
 1860:     ghost dup there ca>native resolve  <do:> swap >magic !
 1861:     depth (code) ;
 1862: 
 1863: : end-code
 1864:     (end-code)
 1865:     depth ?dup IF   1- <> ABORT" CROSS: Stack changed"
 1866:     ELSE true ABORT" CROSS: Stack empty" THEN
 1867:     ;
 1868: 
 1869: >CROSS
 1870: 
 1871: \ tLiteral                                             12dec92py
 1872: 
 1873: >TARGET
 1874: Cond: \G  T-\G ;Cond
 1875: 
 1876: Cond:  Literal ( n -- )   restrict? lit, ;Cond
 1877: Cond: ALiteral ( n -- )   restrict? alit, ;Cond
 1878: 
 1879: : Char ( "<char>" -- )  bl word char+ c@ ;
 1880: Cond: [Char]   ( "<char>" -- )  restrict? Char  lit, ;Cond
 1881: 
 1882: \ some special literals					27jan97jaw
 1883: 
 1884: \ !! Known Bug: Special Literals and plug-ins work only correct
 1885: \ on targets with char = 8 bit
 1886: 
 1887: Cond: MAXU
 1888:   restrict? 
 1889:   compile lit tcell 0 ?DO FF T c, H LOOP 
 1890:   ;Cond
 1891: 
 1892: Cond: MINI
 1893:   restrict?
 1894:   compile lit bigendian 
 1895:   IF	80 T c, H tcell 1 ?DO 0 T c, H LOOP 
 1896:   ELSE  tcell 1 ?DO 0 T c, H LOOP 80 T c, H
 1897:   THEN
 1898:   ;Cond
 1899:  
 1900: Cond: MAXI
 1901:  restrict?
 1902:  compile lit bigendian 
 1903:  IF 	7F T c, H tcell 1 ?DO FF T c, H LOOP
 1904:  ELSE 	tcell 1 ?DO FF T c, H LOOP 7F T c, H
 1905:  THEN
 1906:  ;Cond
 1907: 
 1908: >CROSS
 1909: \ Target compiling loop                                12dec92py
 1910: \ ">tib trick thrown out                               10may93jaw
 1911: \ number? defined at the top                           11may93jaw
 1912: \ replaced >in by save-input				
 1913: 
 1914: : discard 0 ?DO drop LOOP ;
 1915: 
 1916: \ compiled word might leave items on stack!
 1917: : tcom ( x1 .. xn n name -- )
 1918: \  dup count type space
 1919:   gfind  ?dup
 1920:   IF    >r >r discard r> r>
 1921: 	0> IF	>exec @ execute
 1922: 	ELSE	gexecute  THEN 
 1923: 	EXIT 
 1924:   THEN
 1925:   number? dup  
 1926:   IF	0> IF swap lit,  THEN  lit, discard
 1927:   ELSE	2drop restore-input throw ghost gexecute THEN  ;
 1928: 
 1929: >TARGET
 1930: \ : ; DOES>                                            13dec92py
 1931: \ ]                                                     9may93py/jaw
 1932: 
 1933: : ] state on
 1934:     Compiling comp-state !
 1935:     BEGIN
 1936:         BEGIN save-input bl word
 1937:               dup c@ 0= WHILE drop discard refill 0=
 1938:               ABORT" CROSS: End of file while target compiling"
 1939:         REPEAT
 1940:         tcom
 1941:         state @
 1942:         0=
 1943:     UNTIL ;
 1944: 
 1945: \ by the way: defining a second interpreter (a compiler-)loop
 1946: \             is not allowed if a system should be ans conform
 1947: 
 1948: : : ( -- colon-sys ) \ Name
 1949:   defempty?
 1950:   constflag off \ don't let this flag work over colon defs
 1951: 		\ just to go sure nothing unwanted happens
 1952:   >in @ skip? IF  drop skip-defs  EXIT  THEN  >in !
 1953:   (THeader ;Resolve ! there ;Resolve cell+ !
 1954:   docol, ]comp depth T ] H ;
 1955: 
 1956: : :noname ( -- colon-sys )
 1957:   T cfalign H there docol, 0 ;Resolve ! depth T ] H ;
 1958: 
 1959: Cond: EXIT ( -- )  restrict?  compile ;S  ;Cond
 1960: 
 1961: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
 1962: 
 1963: >CROSS
 1964: : LastXT ;Resolve @ 0= abort" CROSS: no definition for LastXT"
 1965:          ;Resolve cell+ @ ;
 1966: 
 1967: >TARGET
 1968: 
 1969: Cond: recurse ( -- ) Last-Ghost @ gexecute ;Cond
 1970: 
 1971: Cond: ; ( -- ) restrict?
 1972:                depth ?dup IF   1- <> ABORT" CROSS: Stack changed"
 1973:                           ELSE true ABORT" CROSS: Stack empty" THEN
 1974:                fini,
 1975:                comp[
 1976:                state off
 1977:                ;Resolve @
 1978: 	       IF ;Resolve @ ;Resolve cell+ @ resolve
 1979: 	          ['] prim-resolved ;Resolve @ >comp ! THEN
 1980: 		Interpreting comp-state !
 1981:                ;Cond
 1982: Cond: [  restrict? state off Interpreting comp-state ! ;Cond
 1983: 
 1984: >CROSS
 1985: 
 1986: Create GhostDummy ghostheader
 1987: <res> GhostDummy >magic !
 1988: 
 1989: : !does ( does-action -- )
 1990: \ !! zusammenziehen und dodoes, machen!
 1991:     tlastcfa @ [G'] :dovar killref
 1992: \    tlastcfa @ dup there >r tdp ! compile :dodoes r> tdp ! T cell+ ! H ;
 1993: \ !! geht so nicht, da dodoes, ghost will!
 1994:     GhostDummy >link ! GhostDummy 
 1995:     tlastcfa @ >tempdp dodoes, tempdp> ;
 1996: 
 1997: >TARGET
 1998: Cond: DOES> restrict?
 1999:         compile (does>) doeshandler, 
 2000: 	\ resolve words made by builders
 2001: 	tdoes @ ?dup IF  @ T here H resolve THEN
 2002:         ;Cond
 2003: : DOES> switchrom doeshandler, T here H !does depth T ] H ;
 2004: 
 2005: >CROSS
 2006: \ Creation                                             01nov92py
 2007: 
 2008: \ Builder                                               11may93jaw
 2009: 
 2010: : Builder    ( Create-xt do-ghost "name" -- )
 2011: \ builds up a builder in current vocabulary
 2012: \ create-xt is executed when word is interpreted
 2013: \ do:-xt is executet when the created word from builder is executed
 2014: \ for do:-xt an additional entry after the normal ghost-enrys is used
 2015: 
 2016:   Make-Ghost 		( Create-xt do-ghost ghost )
 2017:   rot swap		( do-ghost Create-xt ghost )
 2018:   >exec ! , ;
 2019: 
 2020: : gdoes,  ( ghost -- )
 2021: \ makes the codefield for a word that is built
 2022:   >end @ dup undefined? 0=
 2023:   IF
 2024: 	dup >magic @ <do:> =
 2025: 	IF 	 doer, 
 2026: 	ELSE	dodoes,
 2027: 	THEN
 2028: 	EXIT
 2029:   THEN
 2030: \  compile :dodoes gexecute
 2031: \  T here H tcell - reloff 
 2032:   2 refered 
 2033:   0 fillcfa
 2034:   ;
 2035: 
 2036: : TCreate ( <name> -- )
 2037:   executed-ghost @
 2038:   create-forward-warn
 2039:   IF ['] reswarn-forward IS resolve-warning THEN
 2040:   Theader >r dup gdoes,
 2041: \ stores execution semantic in the built word
 2042: \ if the word already has a semantic (concerns S", IS, .", DOES>)
 2043: \ then keep it
 2044:   >end @
 2045:   dup >exec @ r@ >exec dup @ ['] NoExec =  IF ! ELSE 2drop THEN
 2046:   >comp @ r> >comp ! ;
 2047: 
 2048: : RTCreate ( <name> -- )
 2049: \ creates a new word with code-field in ram
 2050:   executed-ghost @
 2051:   create-forward-warn
 2052:   IF ['] reswarn-forward IS resolve-warning THEN
 2053:   \ make Alias
 2054:   (THeader there 0 T a, H alias-mask flag! ( S executed-ghost new-ghost )
 2055:   \ store  poiter to code-field
 2056:   switchram T cfalign H
 2057:   there swap T ! H
 2058:   there tlastcfa ! 
 2059:   dup there resolve 0 ;Resolve !
 2060:   >r dup gdoes,
 2061: \ stores execution semantic in the built word
 2062: \ if the word already has a semantic (concerns S", IS, .", DOES>)
 2063: \ then keep it
 2064:   >end @ >exec @ r> >exec dup @ ['] NoExec =
 2065:   IF ! ELSE 2drop THEN ;
 2066: 
 2067: : Build:  ( -- [xt] [colon-sys] )
 2068:   :noname postpone TCreate ;
 2069: 
 2070: : BuildSmart:  ( -- [xt] [colon-sys] )
 2071:   :noname
 2072:   [ T has? rom H [IF] ]
 2073:   postpone RTCreate
 2074:   [ [ELSE] ]
 2075:   postpone TCreate 
 2076:   [ [THEN] ] ;
 2077: 
 2078: : g>body ( ghost -- body )
 2079:     >link @ T >body H ;
 2080: : gdoes>  ( ghost -- addr flag )
 2081:   executed-ghost @
 2082:   state @ IF  gexecute true EXIT  THEN
 2083:   g>body false ;
 2084: 
 2085: \ DO: ;DO                                               11may93jaw
 2086: \ changed to ?EXIT                                      10may93jaw
 2087: 
 2088: : DO:     ( -- ghost [xt] [colon-sys] )
 2089:   here ghostheader
 2090:   :noname postpone gdoes> postpone ?EXIT ;
 2091: 
 2092: : by:     ( -- ghost [xt] [colon-sys] ) \ name
 2093:   ghost
 2094:   :noname postpone gdoes> postpone ?EXIT ;
 2095: 
 2096: : ;DO ( ghost [xt] [colon-sys] -- ghost )
 2097:   postpone ;    ( S addr xt )
 2098:   over >exec ! ; immediate
 2099: 
 2100: : compile: ( ghost -- ghost [xt] [colon-sys] )
 2101:     :noname  postpone g>body ;
 2102: : ;compile ( ghost [xt] [colon-sys] -- ghost )
 2103:     postpone ;  over >comp ! ; immediate
 2104: 
 2105: : by      ( -- ghost ) \ Name
 2106:   ghost >end @ ;
 2107: 
 2108: >TARGET
 2109: \ Variables and Constants                              05dec92py
 2110: 
 2111: Build:  ( n -- ) ;
 2112: by: :docon ( ghost -- n ) T @ H ;DO
 2113: compile: alit, compile @ ;compile
 2114: Builder (Constant)
 2115: 
 2116: Build:  ( n -- ) T , H ;
 2117: by (Constant)
 2118: Builder Constant
 2119: 
 2120: Build:  ( n -- ) T A, H ;
 2121: by (Constant)
 2122: Builder AConstant
 2123: 
 2124: Build:  ( d -- ) T , , H ;
 2125: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
 2126: Builder 2Constant
 2127: 
 2128: BuildSmart: ;
 2129: by: :dovar ( ghost -- addr ) ;DO
 2130: compile: alit, ;compile
 2131: Builder Create
 2132: 
 2133: T has? rom H [IF]
 2134: Build: ( -- ) T here 0 , H switchram T align here swap ! 0 , H ( switchrom ) ;
 2135: by (Constant)
 2136: Builder Variable
 2137: [ELSE]
 2138: Build: T 0 , H ;
 2139: by Create
 2140: Builder Variable
 2141: [THEN]
 2142: 
 2143: T has? rom H [IF]
 2144: Build: ( -- ) T here 0 , H switchram T align here swap ! 0 , 0 , H ( switchrom ) ;
 2145: by (Constant)
 2146: Builder 2Variable
 2147: [ELSE]
 2148: Build: T 0 , 0 , H ;
 2149: by Create
 2150: Builder 2Variable
 2151: [THEN]
 2152: 
 2153: T has? rom H [IF]
 2154: Build: ( -- ) T here 0 , H switchram T align here swap ! 0 , H ( switchrom ) ;
 2155: by (Constant)
 2156: Builder AVariable
 2157: [ELSE]
 2158: Build: T 0 A, H ;
 2159: by Create
 2160: Builder AVariable
 2161: [THEN]
 2162: 
 2163: \ User variables                                       04may94py
 2164: 
 2165: >CROSS
 2166: 
 2167: Variable tup  0 tup !
 2168: Variable tudp 0 tudp !
 2169: 
 2170: : u,  ( n -- udp )
 2171:   tup @ tudp @ + T  ! H
 2172:   tudp @ dup T cell+ H tudp ! ;
 2173: 
 2174: : au, ( n -- udp )
 2175:   tup @ tudp @ + T A! H
 2176:   tudp @ dup T cell+ H tudp ! ;
 2177: 
 2178: >TARGET
 2179: 
 2180: Build: 0 u, X , ;
 2181: by: :douser ( ghost -- up-addr )  X @ tup @ + ;DO
 2182: compile: compile useraddr T @ , H ;compile
 2183: Builder User
 2184: 
 2185: Build: 0 u, X , 0 u, drop ;
 2186: by User
 2187: Builder 2User
 2188: 
 2189: Build: 0 au, X , ;
 2190: by User
 2191: Builder AUser
 2192: 
 2193: BuildSmart: T , H ;
 2194: by (Constant)
 2195: Builder Value
 2196: 
 2197: BuildSmart: T A, H ;
 2198: by (Constant)
 2199: Builder AValue
 2200: 
 2201: BuildSmart:  ( -- ) [T'] noop T A, H ;
 2202: by: :dodefer ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
 2203: compile: alit, compile @ compile execute ;compile
 2204: Builder Defer
 2205: 
 2206: Build: ( inter comp -- ) swap T immediate A, A, H ;
 2207: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
 2208: Builder interpret/compile:
 2209: 
 2210: \ Sturctures                                           23feb95py
 2211: 
 2212: >CROSS
 2213: : nalign ( addr1 n -- addr2 )
 2214: \ addr2 is the aligned version of addr1 wrt the alignment size n
 2215:  1- tuck +  swap invert and ;
 2216: >TARGET
 2217: 
 2218: Build: ;
 2219: by: :dofield T @ H + ;DO
 2220: compile: T @ H lit, compile + ;compile
 2221: Builder (Field)
 2222: 
 2223: Build: ( align1 offset1 align size "name" --  align2 offset2 )
 2224:     rot dup T , H ( align1 align size offset1 )
 2225:     + >r nalign r> ;
 2226: by (Field)
 2227: Builder Field
 2228: 
 2229: : struct  T 1 chars 0 H ;
 2230: : end-struct  T 2Constant H ;
 2231: 
 2232: : cell% ( n -- size align )
 2233:     T 1 cells H dup ;
 2234: 
 2235: Build: ( m v -- m' v )  dup T , cell+ H ;
 2236: DO:  abort" Not in cross mode" ;DO
 2237: Builder input-method
 2238: 
 2239: Build: ( m v size -- m v' )  over T , H + ;
 2240: DO:  abort" Not in cross mode" ;DO
 2241: Builder input-var
 2242: 
 2243: \ structural conditionals                              17dec92py
 2244: 
 2245: >CROSS
 2246: : ?struc      ( flag -- )       ABORT" CROSS: unstructured " ;
 2247: : sys?        ( sys -- sys )    dup 0= ?struc ;
 2248: : >mark       ( -- sys )        T here  ( dup ." M" hex. ) 0 , H ;
 2249: 
 2250: : branchoffset ( src dest -- )  - tchar / ; \ ?? jaw
 2251: 
 2252: : >resolve    ( sys -- )        
 2253: 	X here ( dup ." >" hex. ) over branchoffset swap X ! ;
 2254: 
 2255: : <resolve    ( sys -- )
 2256: 	X here ( dup ." <" hex. ) branchoffset X , ;
 2257: 
 2258: :noname compile branch X here branchoffset X , ;
 2259:   IS branch, ( target-addr -- )
 2260: :noname compile ?branch X here branchoffset X , ;
 2261:   IS ?branch, ( target-addr -- )
 2262: :noname compile branch T here 0 , H ;
 2263:   IS branchmark, ( -- branchtoken )
 2264: :noname compile ?branch T here 0 , H ;
 2265:   IS ?branchmark, ( -- branchtoken )
 2266: :noname T here 0 , H ;
 2267:   IS ?domark, ( -- branchtoken )
 2268: :noname dup X @ ?struc X here over branchoffset swap X ! ;
 2269:   IS branchtoresolve, ( branchtoken -- )
 2270: :noname branchto, X here ;
 2271:   IS branchtomark, ( -- target-addr )
 2272: 
 2273: >TARGET
 2274: 
 2275: \ Structural Conditionals                              12dec92py
 2276: 
 2277: Cond: BUT       restrict? sys? swap ;Cond
 2278: Cond: YET       restrict? sys? dup ;Cond
 2279: 
 2280: >CROSS
 2281: 
 2282: Variable tleavings 0 tleavings !
 2283: 
 2284: : (done) ( addr -- )
 2285:     tleavings @
 2286:     BEGIN  dup
 2287:     WHILE
 2288: 	>r dup r@ cell+ @ \ address of branch
 2289: 	u> 0=	   \ lower than DO?	
 2290:     WHILE
 2291: 	r@ 2 cells + @ \ branch token
 2292: 	branchtoresolve,
 2293: 	r@ @ r> free throw
 2294:     REPEAT  r>  THEN
 2295:     tleavings ! drop ;
 2296: 
 2297: >TARGET
 2298: 
 2299: Cond: DONE   ( addr -- )  restrict? (done) ;Cond
 2300: 
 2301: >CROSS
 2302: : (leave) ( branchtoken -- )
 2303:     3 cells allocate throw >r
 2304:     T here H r@ cell+ !
 2305:     r@ 2 cells + !
 2306:     tleavings @ r@ !
 2307:     r> tleavings ! ;
 2308: >TARGET
 2309: 
 2310: Cond: LEAVE     restrict? branchmark, (leave) ;Cond
 2311: Cond: ?LEAVE    restrict? compile 0=  ?branchmark, (leave)  ;Cond
 2312: 
 2313: >CROSS
 2314: \ !!JW ToDo : Move to general tools section
 2315: 
 2316: : to1 ( x1 x2 xn n -- addr )
 2317: \G packs n stack elements in a allocated memory region
 2318:    dup dup 1+ cells allocate throw dup >r swap 1+
 2319:    0 DO tuck ! cell+ LOOP
 2320:    drop r> ;
 2321: : 1to ( addr -- x1 x2 xn )
 2322: \G unpacks the elements saved by to1
 2323:     dup @ swap over cells + swap
 2324:     0 DO  dup @ swap 1 cells -  LOOP
 2325:     free throw ;
 2326: 
 2327: : loop]     branchto, dup <resolve tcell - (done) ;
 2328: 
 2329: : skiploop] ?dup IF branchto, branchtoresolve, THEN ;
 2330: 
 2331: >TARGET
 2332: 
 2333: \ Structural Conditionals                              12dec92py
 2334: 
 2335: >TARGET
 2336: Cond: AHEAD     restrict? branchmark, ;Cond
 2337: Cond: IF        restrict? ?branchmark, ;Cond
 2338: Cond: THEN      restrict? sys? branchto, branchtoresolve, ;Cond
 2339: Cond: ELSE      restrict? sys? compile AHEAD swap compile THEN ;Cond
 2340: 
 2341: Cond: BEGIN     restrict? branchtomark, ;Cond
 2342: Cond: WHILE     restrict? sys? compile IF swap ;Cond
 2343: Cond: AGAIN     restrict? sys? branch, ;Cond
 2344: Cond: UNTIL     restrict? sys? ?branch, ;Cond
 2345: Cond: REPEAT    restrict? over 0= ?struc compile AGAIN compile THEN ;Cond
 2346: 
 2347: Cond: CASE      restrict? 0 ;Cond
 2348: Cond: OF        restrict? 1+ >r compile over compile =
 2349:                 compile IF compile drop r> ;Cond
 2350: Cond: ENDOF     restrict? >r compile ELSE r> ;Cond
 2351: Cond: ENDCASE   restrict? compile drop 0 ?DO  compile THEN  LOOP ;Cond
 2352: 
 2353: \ Structural Conditionals                              12dec92py
 2354: 
 2355: :noname \ ?? i think 0 is too much! jaw
 2356:     0 compile (do)
 2357:     branchtomark,  2 to1 ;
 2358:   IS do, ( -- target-addr )
 2359: 
 2360: \ :noname
 2361: \     compile 2dup compile = compile IF
 2362: \     compile 2drop compile ELSE
 2363: \     compile (do) branchtomark, 2 to1 ;
 2364: \   IS ?do,
 2365:     
 2366: :noname
 2367:     0 compile (?do)  ?domark, (leave)
 2368:     branchtomark,  2 to1 ;
 2369:   IS ?do, ( -- target-addr )
 2370: :noname compile (for) branchtomark, ;
 2371:   IS for, ( -- target-addr )
 2372: :noname 1to compile (loop)  loop] compile unloop skiploop] ;
 2373:   IS loop, ( target-addr -- )
 2374: :noname 1to compile (+loop)  loop] compile unloop skiploop] ;
 2375:   IS +loop, ( target-addr -- )
 2376: :noname compile (next)  loop] compile unloop ;
 2377:   IS next, ( target-addr -- )
 2378: 
 2379: Cond: DO      	restrict? do, ;Cond
 2380: Cond: ?DO     	restrict? ?do, ;Cond
 2381: Cond: FOR	restrict? for, ;Cond
 2382: 
 2383: Cond: LOOP	restrict? sys? loop, ;Cond
 2384: Cond: +LOOP	restrict? sys? +loop, ;Cond
 2385: Cond: NEXT	restrict? sys? next, ;Cond
 2386: 
 2387: \ String words                                         23feb93py
 2388: 
 2389: : ,"            [char] " parse T string, align H ;
 2390: 
 2391: Cond: ."        restrict? compile (.")     T ," H ;Cond ( " )
 2392: Cond: S"        restrict? compile (S")     T ," H ;Cond ( " )
 2393: Cond: ABORT"    restrict? compile (ABORT") T ," H ;Cond ( " )
 2394: 
 2395: Cond: IS        T ' >body H compile ALiteral compile ! ;Cond
 2396: : IS            T >address ' >body ! H ;
 2397: Cond: TO        T ' >body H compile ALiteral compile ! ;Cond
 2398: : TO            T ' >body ! H ;
 2399: 
 2400: Cond: defers	T ' >body @ compile, H ;Cond
 2401: : on		T -1 swap ! H ; 
 2402: : off   	T 0 swap ! H ;
 2403: 
 2404: \ LINKED ERR" ENV" 2ENV"                                18may93jaw
 2405: 
 2406: \ linked list primitive
 2407: : linked        X here over X @ X A, swap X ! ;
 2408: : chained	T linked A, H ;
 2409: 
 2410: : err"   s" ErrLink linked" evaluate T , H
 2411:          [char] " parse T string, align H ;
 2412: 
 2413: : env"  [char] " parse s" EnvLink linked" evaluate
 2414:         T string, align , H ;
 2415: 
 2416: : 2env" [char] " parse s" EnvLink linked" evaluate
 2417:         here >r T string, align , , H
 2418:         r> dup T c@ H 80 and swap T c! H ;
 2419: 
 2420: \ compile must be last                                 22feb93py
 2421: 
 2422: Cond: compile ( -- ) restrict? \ name
 2423:       bl word gfind dup 0= ABORT" CROSS: Can't compile"
 2424:       0> IF    gexecute
 2425:          ELSE  dup >magic @ <imm> =
 2426:                IF   gexecute
 2427:                ELSE compile (compile) addr, THEN THEN ;Cond
 2428: 
 2429: Cond: postpone ( -- ) restrict? \ name
 2430:       bl word gfind dup 0= ABORT" CROSS: Can't compile"
 2431:       0> IF    gexecute
 2432:          ELSE  dup >magic @ <imm> =
 2433:                IF   gexecute
 2434: 	       ELSE compile (compile) addr, THEN THEN ;Cond
 2435: 	   
 2436: \ save-cross                                           17mar93py
 2437: 
 2438: hex
 2439: 
 2440: >CROSS
 2441: Create magic  s" Gforth2x" here over allot swap move
 2442: 
 2443: bigendian 1+ \ strangely, in magic big=0, little=1
 2444: tcell 1 = 0 and or
 2445: tcell 2 = 2 and or
 2446: tcell 4 = 4 and or
 2447: tcell 8 = 6 and or
 2448: tchar 1 = 00 and or
 2449: tchar 2 = 28 and or
 2450: tchar 4 = 50 and or
 2451: tchar 8 = 78 and or
 2452: magic 7 + c!
 2453: 
 2454: : save-cross ( "image-name" "binary-name" -- )
 2455:   bl parse ." Saving to " 2dup type cr
 2456:   w/o bin create-file throw >r
 2457:   TNIL IF
 2458:       s" #! "           r@ write-file throw
 2459:       bl parse          r@ write-file throw
 2460:       s"  --image-file" r@ write-file throw
 2461:       #lf       r@ emit-file throw
 2462:       r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
 2463:       ?do
 2464: 	  bl over emit-file throw
 2465:       loop
 2466:       drop
 2467:       magic 8       r@ write-file throw \ write magic
 2468:   ELSE
 2469:       bl parse 2drop
 2470:   THEN
 2471:   image @ there 
 2472:   r@ write-file throw \ write image
 2473:   TNIL IF
 2474:       bit$  @ there 1- tcell>bit rshift 1+
 2475:                 r@ write-file throw \ write tags
 2476:   THEN
 2477:   r> close-file throw ;
 2478: 
 2479: : save-region ( addr len -- )
 2480:   bl parse w/o bin create-file throw >r
 2481:   swap >image swap r@ write-file throw
 2482:   r> close-file throw ;
 2483: 
 2484: \ \ minimal definitions
 2485: 	   
 2486: >MINIMAL also minimal
 2487: 
 2488: \ Usefull words                                        13feb93py
 2489: 
 2490: : KB  400 * ;
 2491: 
 2492: \ \ [IF] [ELSE] [THEN] ...				14sep97jaw
 2493: 
 2494: \ it is useful to define our own structures and not to rely
 2495: \ on the words in the compiler
 2496: \ The words in the compiler might be defined with vocabularies
 2497: \ this doesn't work with our self-made compile-loop
 2498: 
 2499: Create parsed 20 chars allot	\ store word we parsed
 2500: 
 2501: : upcase
 2502:     parsed count bounds
 2503:     ?DO I c@ toupper I c! LOOP ;
 2504: 
 2505: : [ELSE]
 2506:     1 BEGIN
 2507: 	BEGIN bl word count dup WHILE
 2508: 	    comment? 20 umin parsed place upcase parsed count
 2509: 	    2dup s" [IF]" compare 0= >r 
 2510: 	    2dup s" [IFUNDEF]" compare 0= >r
 2511: 	    2dup s" [IFDEF]" compare 0= r> or r> or
 2512: 	    IF   2drop 1+
 2513: 	    ELSE 2dup s" [ELSE]" compare 0=
 2514: 		IF   2drop 1- dup
 2515: 		    IF 1+
 2516: 		    THEN
 2517: 		ELSE
 2518: 		    2dup s" [ENDIF]" compare 0= >r
 2519: 		    s" [THEN]" compare 0= r> or
 2520: 		    IF 1- THEN
 2521: 		THEN
 2522: 	    THEN
 2523: 	    ?dup 0= ?EXIT
 2524: 	REPEAT
 2525: 	2drop refill 0=
 2526:     UNTIL drop ; immediate
 2527:   
 2528: : [THEN] ( -- ) ; immediate
 2529: 
 2530: : [ENDIF] ( -- ) ; immediate
 2531: 
 2532: : [IF] ( flag -- )
 2533:     0= IF postpone [ELSE] THEN ; immediate 
 2534: 
 2535: Cond: [IF]      postpone [IF] ;Cond
 2536: Cond: [THEN]    postpone [THEN] ;Cond
 2537: Cond: [ELSE]    postpone [ELSE] ;Cond
 2538: 
 2539: \ define new [IFDEF] and [IFUNDEF]                      20may93jaw
 2540: 
 2541: : defined? tdefined? ;
 2542: : needed? needed? ;
 2543: : doer? doer? ;
 2544: 
 2545: \ we want to use IFDEF on compiler directives (e.g. E?) in the source, too
 2546: 
 2547: : directive? 
 2548:   bl word count [ ' target >wordlist ] literal search-wordlist 
 2549:   dup IF nip THEN ;
 2550: 
 2551: : [IFDEF]  >in @ directive? swap >in !
 2552: 	   0= IF tdefined? ELSE name 2drop true THEN
 2553: 	   postpone [IF] ;
 2554: 
 2555: : [IFUNDEF] tdefined? 0= postpone [IF] ;
 2556: 
 2557: Cond: [IFDEF]   postpone [IFDEF] ;Cond
 2558: 
 2559: Cond: [IFUNDEF] postpone [IFUNDEF] ;Cond
 2560: 
 2561: \ C: \- \+ Conditional Compiling                         09jun93jaw
 2562: 
 2563: : C: >in @ tdefined? 0=
 2564:      IF    >in ! X :
 2565:      ELSE drop
 2566:         BEGIN bl word dup c@
 2567:               IF   count comment? s" ;" compare 0= ?EXIT
 2568:               ELSE refill 0= ABORT" CROSS: Out of Input while C:"
 2569:               THEN
 2570:         AGAIN
 2571:      THEN ;
 2572: 
 2573: : d? d? ;
 2574: 
 2575: \G doesn't skip line when debug switch is on
 2576: : \D D? 0= IF postpone \ THEN ;
 2577: 
 2578: \G interprets the line if word is not defined
 2579: : \- tdefined? IF postpone \ THEN ;
 2580: 
 2581: \G interprets the line if word is defined
 2582: : \+ tdefined? 0= IF postpone \ THEN ;
 2583: 
 2584: Cond: \- \- ;Cond
 2585: Cond: \+ \+ ;Cond
 2586: Cond: \D \D ;Cond
 2587: 
 2588: : ?? bl word find IF execute ELSE drop 0 THEN ;
 2589: 
 2590: : needed:
 2591: \G defines ghost for words that we want to be compiled
 2592:   BEGIN >in @ bl word c@ WHILE >in ! ghost drop REPEAT drop ;
 2593: 
 2594: \ words that should be in minimal
 2595: 
 2596: create s-buffer 50 chars allot
 2597: 
 2598: bigendian Constant bigendian
 2599: 
 2600: : here there ;
 2601: : equ constant ;
 2602: : mark there constant ;
 2603: 
 2604: \ compiler directives
 2605: : >ram >ram ;
 2606: : >rom >rom ;
 2607: : >auto >auto ;
 2608: : >tempdp >tempdp ;
 2609: : tempdp> tempdp> ;
 2610: : const constflag on ;
 2611: : warnings name 3 = 0= twarnings ! drop ;
 2612: : | ;
 2613: \ : | NoHeaderFlag on ; \ This is broken (damages the last word)
 2614: 
 2615: : save-cross save-cross ;
 2616: : save-region save-region ;
 2617: : tdump swap >image swap dump ;
 2618: 
 2619: also forth 
 2620: [IFDEF] Label           : Label defempty? Label ; [THEN] 
 2621: [IFDEF] start-macros    : start-macros defempty? start-macros ; [THEN]
 2622: \ [IFDEF] builttag	: builttag builttag ;	[THEN]
 2623: previous
 2624: 
 2625: : s" [char] " parse s-buffer place s-buffer count ; \ for environment?
 2626: : + + ;
 2627: : 1+ 1 + ;
 2628: : 2+ 2 + ;
 2629: : 1- 1- ;
 2630: : - - ;
 2631: : and and ;
 2632: : or or ;
 2633: : 2* 2* ;
 2634: : * * ;
 2635: : / / ;
 2636: : dup dup ;
 2637: : over over ;
 2638: : swap swap ;
 2639: : rot rot ;
 2640: : drop drop ;
 2641: : =   = ;
 2642: : 0=   0= ;
 2643: : lshift lshift ;
 2644: : 2/ 2/ ;
 2645: : . . ;
 2646: 
 2647: : all-words    ['] forced?    IS skip? ;
 2648: : needed-words ['] needed?  IS skip? ;
 2649: : undef-words  ['] defined2? IS skip? ;
 2650: : skipdef skipdef ;
 2651: 
 2652: : \  postpone \ ;  immediate
 2653: : \G T-\G ; immediate
 2654: : (  postpone ( ;  immediate
 2655: : include bl word count included ;
 2656: : require require ;
 2657: : .( [char] ) parse type ;
 2658: : ." [char] " parse type ;
 2659: : cr cr ;
 2660: 
 2661: : times 0 ?DO dup X c, LOOP drop ; \ used for space table creation
 2662: 
 2663: \ only forth also cross also minimal definitions order
 2664: 
 2665: \ cross-compiler words
 2666: 
 2667: : decimal       decimal ;
 2668: : hex           hex ;
 2669: 
 2670: \ : tudp          X tudp ;
 2671: \ : tup           X tup ;
 2672: 
 2673: : doc-off       false to-doc ! ;
 2674: : doc-on        true  to-doc ! ;
 2675: 
 2676: [IFDEF] dbg : dbg dbg ; [THEN]
 2677: 
 2678: \ for debugging...
 2679: : order         order ;
 2680: : hwords         words ;
 2681: : words 	also ghosts words previous ;
 2682: : .s            .s ;
 2683: : bye           bye ;
 2684: 
 2685: \ turnkey direction
 2686: : H forth ; immediate
 2687: : T minimal ; immediate
 2688: : G ghosts ; immediate
 2689: 
 2690: : turnkey 
 2691:    \GFORTH 0 set-order also ghosts
 2692:    \ANSI [ ' ghosts >wordlist ] Literal 1 set-order
 2693:    also target definitions
 2694:    also Minimal also ;
 2695: 
 2696: \ these ones are pefered:
 2697: 
 2698: : lock   turnkey ;
 2699: : unlock previous forth also cross ;
 2700: 
 2701: \ also minimal
 2702: : [[ also unlock ;
 2703: : ]] previous previous also also ;
 2704: 
 2705: unlock definitions also minimal
 2706: : lock   lock ;
 2707: lock
 2708: 
 2709: \ load cross compiler extension defined in mach file
 2710: 
 2711: UNLOCK >CROSS
 2712: 
 2713: [IFDEF] extend-cross extend-cross [THEN]
 2714: 
 2715: LOCK

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>