1: \ CROSS.FS The Cross-Compiler 06oct92py
2: \ Idea and implementation: Bernd Paysan (py)
3:
4: \ Copyright (C) 1995 Free Software Foundation, Inc.
5:
6: \ This file is part of Gforth.
7:
8: \ Gforth is free software; you can redistribute it and/or
9: \ modify it under the terms of the GNU General Public License
10: \ as published by the Free Software Foundation; either version 2
11: \ of the License, or (at your option) any later version.
12:
13: \ This program is distributed in the hope that it will be useful,
14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: \ GNU General Public License for more details.
17:
18: \ You should have received a copy of the GNU General Public License
19: \ along with this program; if not, write to the Free Software
20: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21:
22: \ Log:
23: \ changed in ; [ to state off 12may93jaw
24: \ included place +place 12may93jaw
25: \ for a created word (variable, constant...)
26: \ is now an alias in the target voabulary.
27: \ this means it is no longer necessary to
28: \ switch between vocabularies for variable
29: \ initialization 12may93jaw
30: \ discovered error in DOES>
31: \ replaced !does with (;code) 16may93jaw
32: \ made complete redesign and
33: \ introduced two vocs method
34: \ to be asure that the right words
35: \ are found 08jun93jaw
36: \ btw: ! works not with 16 bit
37: \ targets 09jun93jaw
38: \ added: 2user and value 11jun93jaw
39:
40: \ include other.fs \ ansforth extentions for cross
41:
42: : string, ( c-addr u -- )
43: \ puts down string as cstring
44: dup c, here swap chars dup allot move ;
45: ' falign Alias cfalign
46: : comment? ( c-addr u -- c-addr u )
47: 2dup s" (" compare 0=
48: IF postpone (
49: ELSE 2dup s" \" compare 0= IF postpone \ THEN
50: THEN ;
51:
52: decimal
53:
54: \ Begin CROSS COMPILER:
55:
56: \ GhostNames 9may93jaw
57: \ second name source to search trough list
58:
59: VARIABLE GhostNames
60: 0 GhostNames !
61: : GhostName ( -- addr )
62: here GhostNames @ , GhostNames ! here 0 ,
63: bl word count
64: \ 2dup type space
65: string, cfalign ;
66:
67: hex
68:
69:
70: Vocabulary Cross
71: Vocabulary Target
72: Vocabulary Ghosts
73: VOCABULARY Minimal
74: only Forth also Target also also
75: definitions Forth
76:
77: : T previous Cross also Target ; immediate
78: : G Ghosts ; immediate
79: : H previous Forth also Cross ; immediate
80:
81: forth definitions
82:
83: : T previous Cross also Target ; immediate
84: : G Ghosts ; immediate
85:
86: : >cross also Cross definitions previous ;
87: : >target also Target definitions previous ;
88: : >minimal also Minimal definitions previous ;
89:
90: H
91:
92: >CROSS
93:
94: \ Parameter for target systems 06oct92py
95:
96: mach-file count included
97:
98: also Forth definitions
99:
100: [IFDEF] asm-include asm-include [THEN]
101:
102: previous
103:
104: >CROSS
105:
106: \ Variables 06oct92py
107:
108: Variable image
109: Variable tlast NIL tlast ! \ Last name field
110: Variable tlastcfa \ Last code field
111: Variable tdoes \ Resolve does> calls
112: Variable bit$
113: Variable tdp
114: : there tdp @ ;
115:
116: \ Create additional parameters 19jan95py
117:
118: T
119: cell Constant tcell
120: cell<< Constant tcell<<
121: cell>bit Constant tcell>bit
122: bits/byte Constant tbits/byte
123: float Constant tfloat
124: 1 bits/byte lshift Constant maxbyte
125: H
126:
127: >TARGET
128:
129: \ Byte ordering and cell size 06oct92py
130:
131: : cell+ tcell + ;
132: : cells tcell<< lshift ;
133: : chars ;
134: : floats tfloat * ;
135:
136: >CROSS
137: : cell/ tcell<< rshift ;
138: >TARGET
139: 20 CONSTANT bl
140: -1 Constant NIL
141:
142: >CROSS
143:
144: bigendian
145: [IF]
146: : T! ( n addr -- ) >r s>d r> tcell bounds swap 1-
147: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
148: : T@ ( addr -- n ) >r 0 0 r> tcell bounds
149: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP d>s ;
150: [ELSE]
151: : T! ( n addr -- ) >r s>d r> tcell bounds
152: DO maxbyte ud/mod rot I c! LOOP 2drop ;
153: : T@ ( addr -- n ) >r 0 0 r> tcell bounds swap 1-
154: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP d>s ;
155: [THEN]
156:
157: \ Memory initialisation 05dec92py
158: \ Fixed bug in else part 11may93jaw
159:
160: [IFDEF] Memory \ Memory is a bigFORTH feature
161: also Memory
162: : initmem ( var len -- )
163: 2dup swap handle! >r @ r> erase ;
164: toss
165: [ELSE]
166: : initmem ( var len -- )
167: tuck allocate abort" CROSS: No memory for target"
168: ( len var adr ) dup rot !
169: ( len adr ) swap erase ;
170: [THEN]
171:
172: \ MakeKernal 12dec92py
173:
174: >MINIMAL
175: : makekernel ( targetsize -- targetsize )
176: bit$ over 1- cell>bit rshift 1+ initmem
177: image over initmem tdp off ;
178:
179: >CROSS
180: \ Bit string manipulation 06oct92py
181: \ 9may93jaw
182: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
183: : bits ( n -- n ) chars Bittable + c@ ;
184:
185: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
186: : +bit ( addr n -- ) >bit over c@ or swap c! ;
187: : -bit ( addr n -- ) >bit invert over c@ and swap c! ;
188: : relon ( taddr -- ) bit$ @ swap cell/ +bit ;
189: : reloff ( taddr -- ) bit$ @ swap cell/ -bit ;
190:
191: \ Target memory access 06oct92py
192:
193: : align+ ( taddr -- rest )
194: cell tuck 1- and - [ cell 1- ] Literal and ;
195: : cfalign+ ( taddr -- rest )
196: \ see kernel.fs:cfaligned
197: /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
198:
199: >TARGET
200: : aligned ( taddr -- ta-addr ) dup align+ + ;
201: \ assumes cell alignment granularity (as GNU C)
202:
203: : cfaligned ( taddr1 -- taddr2 )
204: \ see kernel.fs
205: dup cfalign+ + ;
206:
207: >CROSS
208: : >image ( taddr -- absaddr ) image @ + ;
209: >TARGET
210: : @ ( taddr -- w ) >image t@ ;
211: : ! ( w taddr -- ) >image t! ;
212: : c@ ( taddr -- char ) >image c@ ;
213: : c! ( char taddr -- ) >image c! ;
214: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
215: : 2! ( x1 x2 taddr -- ) T swap over ! cell+ ! H ;
216:
217: \ Target compilation primitives 06oct92py
218: \ included A! 16may93jaw
219:
220: : here ( -- there ) there ;
221: : allot ( n -- ) tdp +! ;
222: : , ( w -- ) T here H cell T allot ! H ;
223: : c, ( char -- ) T here 1 allot c! H ;
224: : align ( -- ) T here H align+ 0 ?DO bl T c, H LOOP ;
225: : cfalign ( -- )
226: T here H cfalign+ 0 ?DO bl T c, H LOOP ;
227:
228: : A! dup relon T ! H ;
229: : A, ( w -- ) T here H relon T , H ;
230:
231: >CROSS
232:
233: \ threading modell 13dec92py
234:
235: >TARGET
236: : >body ( cfa -- pfa ) T cell+ cell+ H ;
237: >CROSS
238:
239: \ Ghost Builder 06oct92py
240:
241: \ <T T> new version with temp variable 10may93jaw
242:
243: VARIABLE VocTemp
244:
245: : <T get-current VocTemp ! also Ghosts definitions ;
246: : T> previous VocTemp @ set-current ;
247:
248: 4711 Constant <fwd> 4712 Constant <res>
249: 4713 Constant <imm> 4714 Constant <do:>
250:
251: \ iForth makes only immediate directly after create
252: \ make atonce trick! ?
253:
254: Variable atonce atonce off
255:
256: : NoExec true ABORT" CROSS: Don't execute ghost" ;
257:
258: : GhostHeader <fwd> , 0 , ['] NoExec , ;
259:
260: : >magic ;
261: : >link cell+ ;
262: : >exec cell+ cell+ ;
263: : >end 3 cells + ;
264:
265: Variable last-ghost
266: : Make-Ghost ( "name" -- ghost )
267: >in @ GhostName swap >in !
268: <T Create atonce @ IF immediate atonce off THEN
269: here tuck swap ! ghostheader T>
270: DOES> dup last-ghost ! >exec @ execute ;
271:
272: \ ghost words 14oct92py
273: \ changed: 10may93py/jaw
274:
275: : gfind ( string -- ghost true/1 / string false )
276: \ searches for string in word-list ghosts
277: dup count [ ' ghosts >body ] ALiteral search-wordlist
278: dup IF >r >body nip r> THEN ;
279:
280: VARIABLE Already
281:
282: : ghost ( "name" -- ghost )
283: Already off
284: >in @ bl word gfind IF Already on nip EXIT THEN
285: drop >in ! Make-Ghost ;
286:
287: \ resolve 14oct92py
288:
289: : resolve-loop ( ghost tcfa -- ghost tcfa )
290: >r dup >link @
291: BEGIN dup WHILE dup T @ H r@ rot T ! H REPEAT drop r> ;
292:
293: \ exists 9may93jaw
294:
295: : exists ( ghost tcfa -- )
296: over GhostNames
297: BEGIN @ dup
298: WHILE 2dup cell+ @ =
299: UNTIL
300: 2 cells + count cr ." CROSS: Exists: " type 4 spaces drop
301: swap cell+ !
302: ELSE true abort" CROSS: Ghostnames inconsistent "
303: THEN ;
304:
305: : resolve ( ghost tcfa -- )
306: over >magic @ <fwd> <> IF exists EXIT THEN
307: resolve-loop over >link ! <res> swap >magic ! ;
308:
309: \ gexecute ghost, 01nov92py
310:
311: : do-forward ( ghost -- )
312: >link dup @ there rot ! T A, H ;
313: : do-resolve ( ghost -- )
314: >link @ T A, H ;
315:
316: : gexecute ( ghost -- ) dup @
317: <fwd> = IF do-forward ELSE do-resolve THEN ;
318: : ghost, ghost gexecute ;
319:
320: \ .unresolved 11may93jaw
321:
322: variable ResolveFlag
323:
324: \ ?touched 11may93jaw
325:
326: : ?touched ( ghost -- flag ) dup >magic @ <fwd> = swap >link @
327: 0 <> and ;
328:
329: : ?resolved ( ghostname -- )
330: dup cell+ @ ?touched
331: IF cell+ cell+ count cr type ResolveFlag on ELSE drop THEN ;
332:
333: >MINIMAL
334: : .unresolved ( -- )
335: ResolveFlag off cr ." Unresolved: "
336: Ghostnames
337: BEGIN @ dup
338: WHILE dup ?resolved
339: REPEAT drop ResolveFlag @
340: IF
341: abort" Unresolved words!"
342: ELSE
343: ." Nothing!"
344: THEN
345: cr ;
346:
347: >CROSS
348: \ Header states 12dec92py
349:
350: : flag! ( 8b -- ) tlast @ dup >r T c@ xor r> c! H ;
351:
352: VARIABLE ^imm
353:
354: >TARGET
355: : immediate 40 flag!
356: ^imm @ @ dup <imm> = IF drop EXIT THEN
357: <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
358: <imm> ^imm @ ! ;
359: : restrict 20 flag! ;
360: >CROSS
361:
362: \ ALIAS2 ansforth conform alias 9may93jaw
363:
364: : ALIAS2 create here 0 , DOES> @ execute ;
365: \ usage:
366: \ ' <name> alias2 bla !
367:
368: \ Target Header Creation 01nov92py
369:
370: : string, ( addr count -- )
371: dup T c, H bounds ?DO I c@ T c, H LOOP ;
372: : name, ( "name" -- ) bl word count string, T cfalign H ;
373: : view, ( -- ) ( dummy ) ;
374:
375: \ Target Document Creation (goes to crossdoc.fd) 05jul95py
376:
377: s" crossdoc.fd" r/w create-file throw value doc-file-id
378: \ contains the file-id of the documentation file
379:
380: : T-\G ( -- )
381: source >in @ /string doc-file-id write-line throw
382: postpone \ ;
383:
384: Variable to-doc to-doc on
385:
386: : cross-doc-entry ( -- )
387: to-doc @ tlast @ 0<> and \ not an anonymous (i.e. noname) header
388: IF
389: s" " doc-file-id write-line throw
390: s" make-doc " doc-file-id write-file throw
391: tlast @ >image count $1F and doc-file-id write-file throw
392: >in @
393: [char] ( parse 2drop
394: [char] ) parse doc-file-id write-file throw
395: s" )" doc-file-id write-file throw
396: [char] \ parse 2drop
397: T-\G
398: >in !
399: THEN ;
400:
401: \ Target TAGS creation
402:
403: s" kernel.TAGS" r/w create-file throw value tag-file-id
404: \ contains the file-id of the tags file
405:
406: Create tag-beg 2 c, 7F c, bl c,
407: Create tag-end 2 c, bl c, 01 c,
408: Create tag-bof 1 c, 0C c,
409:
410: 2variable last-loadfilename 0 0 last-loadfilename 2!
411:
412: : put-load-file-name ( -- )
413: loadfilename 2@ last-loadfilename 2@ d<>
414: IF
415: tag-bof count tag-file-id write-line throw
416: sourcefilename 2dup
417: tag-file-id write-file throw
418: last-loadfilename 2!
419: s" ,0" tag-file-id write-line throw
420: THEN ;
421:
422: : cross-tag-entry ( -- )
423: tlast @ 0<> \ not an anonymous (i.e. noname) header
424: IF
425: put-load-file-name
426: source >in @ min tag-file-id write-file throw
427: tag-beg count tag-file-id write-file throw
428: tlast @ >image count $1F and tag-file-id write-file throw
429: tag-end count tag-file-id write-file throw
430: base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
431: \ >in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
432: s" ,0" tag-file-id write-line throw
433: base !
434: THEN ;
435:
436: \ Check for words
437:
438: Defer skip? ' false IS skip?
439:
440: : defined? ( -- flag ) \ name
441: ghost >magic @ <fwd> <> ;
442:
443: : needed? ( -- flag ) \ name
444: ghost dup >magic @ <fwd> =
445: IF >link @ 0<> ELSE drop false THEN ;
446:
447: : doer? ( -- flag ) \ name
448: ghost >magic @ <do:> = ;
449:
450: : skip-defs ( -- )
451: BEGIN refill WHILE source -trailing nip 0= UNTIL THEN ;
452:
453: \ Target header creation
454:
455: VARIABLE CreateFlag CreateFlag off
456:
457: : (Theader ( "name" -- ghost )
458: \ >in @ bl word count type 2 spaces >in !
459: T align H view,
460: tlast @ dup 0> IF T 1 cells - THEN A, H there tlast !
461: >in @ name, >in ! T here H tlastcfa !
462: CreateFlag @ IF
463: >in @ alias2 swap >in ! \ create alias in target
464: >in @ ghost swap >in !
465: swap also ghosts ' previous swap ! \ tick ghost and store in alias
466: CreateFlag off
467: ELSE ghost THEN
468: dup >magic ^imm ! \ a pointer for immediate
469: Already @ IF dup >end tdoes !
470: ELSE 0 tdoes ! THEN
471: 80 flag!
472: cross-doc-entry cross-tag-entry ;
473:
474: VARIABLE ;Resolve 1 cells allot
475:
476: : Theader ( "name" -- ghost )
477: (THeader dup there resolve 0 ;Resolve ! ;
478:
479: >TARGET
480: : Alias ( cfa -- ) \ name
481: >in @ skip? IF 2drop EXIT THEN >in !
482: dup 0< has-prims 0= and
483: IF
484: ." needs prim: " >in @ bl word count type >in ! cr
485: THEN
486: (THeader over resolve T A, H 80 flag! ;
487: : Alias: ( cfa -- ) \ name
488: >in @ skip? IF 2drop EXIT THEN >in !
489: dup 0< has-prims 0= and
490: IF
491: ." needs doer: " >in @ bl word count type >in ! cr
492: THEN
493: ghost tuck swap resolve <do:> swap >magic ! ;
494: >CROSS
495:
496: \ Conditionals and Comments 11may93jaw
497:
498: : ;Cond
499: postpone ;
500: swap ! ; immediate
501:
502: : Cond: ( -- ) \ name {code } ;
503: atonce on
504: ghost
505: >exec
506: :NONAME ;
507:
508: : restrict? ( -- )
509: \ aborts on interprete state - ae
510: state @ 0= ABORT" CROSS: Restricted" ;
511:
512: : Comment ( -- )
513: >in @ atonce on ghost swap >in ! ' swap >exec ! ;
514:
515: Comment ( Comment \
516:
517: \ Predefined ghosts 12dec92py
518:
519: ghost 0= drop
520: ghost branch ghost ?branch 2drop
521: ghost (do) ghost (?do) 2drop
522: ghost (for) drop
523: ghost (loop) ghost (+loop) 2drop
524: ghost (next) drop
525: ghost unloop ghost ;S 2drop
526: ghost lit ghost (compile) ghost ! 2drop drop
527: ghost (does>) ghost noop 2drop
528: ghost (.") ghost (S") ghost (ABORT") 2drop drop
529: ghost ' drop
530: ghost :docol ghost :doesjump ghost :dodoes 2drop drop
531:
532: \ compile 10may93jaw
533:
534: : compile ( -- ) \ name
535: restrict?
536: bl word gfind dup 0= ABORT" CROSS: Can't compile "
537: 0> ( immediate? )
538: IF >exec @ compile,
539: ELSE postpone literal postpone gexecute THEN ;
540: immediate
541:
542: \ generic threading modell
543: : docol, ( -- ) compile :docol T 0 , H ;
544:
545: : dodoes, ( -- ) compile :doesjump T 0 , H ;
546:
547: [IFUNDEF] (code)
548: Defer (code)
549: Defer (end-code)
550: [THEN]
551:
552: >TARGET
553: : Code
554: (THeader there resolve
555: there 2 T cells H + T a, 0 , H
556: depth (code) ;
557:
558: : Code:
559: ghost dup there resolve <do:> swap >magic !
560: depth (code) ;
561:
562: : end-code
563: depth ?dup IF 1- <> ABORT" CROSS: Stack changed"
564: ELSE true ABORT" CROSS: Stack empty" THEN
565: (end-code) ;
566:
567: : ' ( -- cfa ) bl word gfind 0= ABORT" CROSS: undefined "
568: dup >magic @ <fwd> = ABORT" CROSS: forward " >link @ ;
569:
570: Cond: ['] compile lit ghost gexecute ;Cond
571:
572: Cond: chars ;Cond
573:
574: >CROSS
575: \ tLiteral 12dec92py
576:
577: : lit, ( n -- ) compile lit T , H ;
578: : alit, ( n -- ) compile lit T A, H ;
579:
580: >TARGET
581: Cond: \G T-\G ;Cond
582:
583: Cond: Literal ( n -- ) restrict? lit, ;Cond
584: Cond: ALiteral ( n -- ) restrict? alit, ;Cond
585:
586: : Char ( "<char>" -- ) bl word char+ c@ ;
587: Cond: [Char] ( "<char>" -- ) restrict? Char lit, ;Cond
588:
589: \ some special literals 27jan97jaw
590:
591: Cond: MAXU
592: restrict? compile lit
593: tcell 0 ?DO FF T c, H LOOP ;Cond
594:
595: Cond: MINI
596: restrict? compile lit
597: bigendian IF
598: 80 T c, H tcell 1 ?DO 0 T c, H LOOP
599: ELSE
600: tcell 1 ?DO 0 T c, H LOOP 80 T c, H
601: THEN
602: ;Cond
603:
604: Cond: MAXI
605: restrict? compile lit
606: bigendian IF
607: 7F T c, H tcell 1 ?DO FF T c, H LOOP
608: ELSE
609: tcell 1 ?DO FF T c, H LOOP 7F T c, H
610: THEN
611: ;Cond
612:
613: >CROSS
614: \ Target compiling loop 12dec92py
615: \ ">tib trick thrown out 10may93jaw
616: \ number? defined at the top 11may93jaw
617:
618: \ compiled word might leave items on stack!
619: : tcom ( in name -- )
620: gfind ?dup IF 0> IF nip >exec @ execute
621: ELSE nip gexecute THEN EXIT THEN
622: number? dup IF 0> IF swap lit, THEN lit, drop
623: ELSE 2drop >in !
624: ghost gexecute THEN ;
625:
626: >TARGET
627: \ : ; DOES> 13dec92py
628: \ ] 9may93py/jaw
629:
630: : ] state on
631: BEGIN
632: BEGIN >in @ bl word
633: dup c@ 0= WHILE 2drop refill 0=
634: ABORT" CROSS: End of file while target compiling"
635: REPEAT
636: tcom
637: state @
638: 0=
639: UNTIL ;
640:
641: \ by the way: defining a second interpreter (a compiler-)loop
642: \ is not allowed if a system should be ans conform
643:
644: : : ( -- colon-sys ) \ Name
645: >in @ skip? IF drop skip-defs EXIT THEN >in !
646: (THeader ;Resolve ! there ;Resolve cell+ !
647: docol, depth T ] H ;
648:
649: : :noname ( -- colon-sys )
650: T align H there docol, depth T ] H ;
651:
652: Cond: EXIT ( -- ) restrict? compile ;S ;Cond
653:
654: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
655:
656: Cond: ; ( -- ) restrict?
657: depth ?dup IF 1- <> ABORT" CROSS: Stack changed"
658: ELSE true ABORT" CROSS: Stack empty" THEN
659: compile ;S state off
660: ;Resolve @
661: IF ;Resolve @ ;Resolve cell+ @ resolve THEN
662: ;Cond
663: Cond: [ restrict? state off ;Cond
664:
665: >CROSS
666: : !does
667: tlastcfa @ dup there >r tdp ! compile :dodoes r> tdp ! T cell+ ! H ;
668:
669: >TARGET
670: Cond: DOES> restrict?
671: compile (does>) dodoes, tdoes @ ?dup IF @ T here H resolve THEN
672: ;Cond
673: : DOES> dodoes, T here H !does depth T ] H ;
674:
675: >CROSS
676: \ Creation 01nov92py
677:
678: \ Builder 11may93jaw
679:
680: : Builder ( Create do: "name" -- )
681: >in @ alias2 swap dup >in ! >r >r
682: Make-Ghost rot swap >exec ! ,
683: r> r> >in !
684: also ghosts ' previous swap ! ;
685: \ DOES> dup >exec @ execute ;
686:
687: : gdoes, ( ghost -- ) >end @ dup >magic @ <fwd> <>
688: IF
689: dup >magic @ <do:> =
690: IF gexecute T 0 , H EXIT THEN
691: THEN
692: compile :dodoes gexecute T here H cell - reloff ;
693:
694: : TCreate ( -- )
695: last-ghost @
696: CreateFlag on
697: Theader >r dup gdoes,
698: >end @ >exec @ r> >exec ! ;
699:
700: : Build: ( -- [xt] [colon-sys] )
701: :noname postpone TCreate ;
702:
703: : gdoes> ( ghost -- addr flag )
704: last-ghost @
705: state @ IF gexecute true EXIT THEN
706: cell+ @ T >body H false ;
707:
708: \ DO: ;DO 11may93jaw
709: \ changed to ?EXIT 10may93jaw
710:
711: : DO: ( -- addr [xt] [colon-sys] )
712: here ghostheader
713: :noname postpone gdoes> postpone ?EXIT ;
714:
715: : by: ( -- addr [xt] [colon-sys] ) \ name
716: ghost
717: :noname postpone gdoes> postpone ?EXIT ;
718:
719: : ;DO ( addr [xt] [colon-sys] -- )
720: postpone ; ( S addr xt )
721: over >exec ! ; immediate
722:
723: : by ( -- addr ) \ Name
724: ghost >end @ ;
725:
726: >TARGET
727: \ Variables and Constants 05dec92py
728:
729: Build: ;
730: by: :dovar ( ghost -- addr ) ;DO
731: Builder Create
732:
733: Build: T 0 , H ;
734: by Create
735: Builder Variable
736:
737: Build: T 0 A, H ;
738: by Create
739: Builder AVariable
740:
741: \ User variables 04may94py
742:
743: >CROSS
744: Variable tup 0 tup !
745: Variable tudp 0 tudp !
746: : u, ( n -- udp )
747: tup @ tudp @ + T ! H
748: tudp @ dup T cell+ H tudp ! ;
749: : au, ( n -- udp )
750: tup @ tudp @ + T A! H
751: tudp @ dup T cell+ H tudp ! ;
752: >TARGET
753:
754: Build: T 0 u, , H ;
755: by: :douser ( ghost -- up-addr ) T @ H tup @ + ;DO
756: Builder User
757:
758: Build: T 0 u, , 0 u, drop H ;
759: by User
760: Builder 2User
761:
762: Build: T 0 au, , H ;
763: by User
764: Builder AUser
765:
766: Build: ( n -- ) ;
767: by: :docon ( ghost -- n ) T @ H ;DO
768: Builder (Constant)
769:
770: Build: ( n -- ) T , H ;
771: by (Constant)
772: Builder Constant
773:
774: Build: ( n -- ) T A, H ;
775: by (Constant)
776: Builder AConstant
777:
778: Build: ( d -- ) T , , H ;
779: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
780: Builder 2Constant
781:
782: Build: T 0 , H ;
783: by (Constant)
784: Builder Value
785:
786: Build: T 0 A, H ;
787: by (Constant)
788: Builder AValue
789:
790: Build: ( -- ) compile noop ;
791: by: :dodefer ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
792: Builder Defer
793:
794: Build: ( inter comp -- ) swap T immediate A, A, H ;
795: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
796: Builder interpret/compile:
797:
798: \ Sturctures 23feb95py
799:
800: >CROSS
801: : nalign ( addr1 n -- addr2 )
802: \ addr2 is the aligned version of addr1 wrt the alignment size n
803: 1- tuck + swap invert and ;
804: >TARGET
805:
806: Build: ;
807: by: :dofield T @ H + ;DO
808: Builder (Field)
809:
810: Build: >r rot r@ nalign dup T , H ( align1 size offset )
811: + swap r> nalign ;
812: by (Field)
813: Builder Field
814:
815: : struct T 0 1 chars H ;
816: : end-struct T 2Constant H ;
817:
818: : cells: ( n -- size align )
819: T cells 1 cells H ;
820:
821: \ ' 2Constant Alias2 end-struct
822: \ 0 1 T Chars H 2Constant struct
823:
824: \ structural conditionals 17dec92py
825:
826: >CROSS
827: : ?struc ( flag -- ) ABORT" CROSS: unstructured " ;
828: : sys? ( sys -- sys ) dup 0= ?struc ;
829: : >mark ( -- sys ) T here 0 , H ;
830: : >resolve ( sys -- ) T here over - swap ! H ;
831: : <resolve ( sys -- ) T here - , H ;
832: >TARGET
833:
834: \ Structural Conditionals 12dec92py
835:
836: Cond: BUT restrict? sys? swap ;Cond
837: Cond: YET restrict? sys? dup ;Cond
838:
839: >CROSS
840: Variable tleavings
841: >TARGET
842:
843: Cond: DONE ( addr -- ) restrict? tleavings @
844: BEGIN 2dup u> 0= WHILE dup T @ H swap >resolve REPEAT
845: tleavings ! drop ;Cond
846:
847: >CROSS
848: : (leave T here H tleavings @ T , H tleavings ! ;
849: >TARGET
850:
851: Cond: LEAVE restrict? compile branch (leave ;Cond
852: Cond: ?LEAVE restrict? compile 0= compile ?branch (leave ;Cond
853:
854: \ Structural Conditionals 12dec92py
855:
856: Cond: AHEAD restrict? compile branch >mark ;Cond
857: Cond: IF restrict? compile ?branch >mark ;Cond
858: Cond: THEN restrict? sys? dup T @ H ?struc >resolve ;Cond
859: Cond: ELSE restrict? sys? compile AHEAD swap compile THEN ;Cond
860:
861: Cond: BEGIN restrict? T here H ;Cond
862: Cond: WHILE restrict? sys? compile IF swap ;Cond
863: Cond: AGAIN restrict? sys? compile branch <resolve ;Cond
864: Cond: UNTIL restrict? sys? compile ?branch <resolve ;Cond
865: Cond: REPEAT restrict? over 0= ?struc compile AGAIN compile THEN ;Cond
866:
867: \ Structural Conditionals 12dec92py
868:
869: Cond: DO restrict? compile (do) T here H ;Cond
870: Cond: ?DO restrict? compile (?do) (leave T here H ;Cond
871: Cond: FOR restrict? compile (for) T here H ;Cond
872:
873: >CROSS
874: : loop] dup <resolve cell - compile DONE compile unloop ;
875: >TARGET
876:
877: Cond: LOOP restrict? sys? compile (loop) loop] ;Cond
878: Cond: +LOOP restrict? sys? compile (+loop) loop] ;Cond
879: Cond: NEXT restrict? sys? compile (next) loop] ;Cond
880:
881: \ String words 23feb93py
882:
883: : ," [char] " parse string, T align H ;
884:
885: Cond: ." restrict? compile (.") T ," H ;Cond
886: Cond: S" restrict? compile (S") T ," H ;Cond
887: Cond: ABORT" restrict? compile (ABORT") T ," H ;Cond
888:
889: Cond: IS T ' >body H compile ALiteral compile ! ;Cond
890: : IS T ' >body ! H ;
891: Cond: TO T ' >body H compile ALiteral compile ! ;Cond
892: : TO T ' >body ! H ;
893:
894: \ LINKED ERR" ENV" 2ENV" 18may93jaw
895:
896: \ linked list primitive
897: : linked T here over @ A, swap ! H ;
898:
899: : err" s" ErrLink linked" evaluate T , H
900: [char] " parse string, T align H ;
901:
902: : env" [char] " parse s" EnvLink linked" evaluate
903: string, T align , H ;
904:
905: : 2env" [char] " parse s" EnvLink linked" evaluate
906: here >r string, T align , , H
907: r> dup T c@ H 80 and swap T c! H ;
908:
909: \ compile must be last 22feb93py
910:
911: Cond: compile ( -- ) restrict? \ name
912: bl word gfind dup 0= ABORT" CROSS: Can't compile"
913: 0> IF gexecute
914: ELSE dup >magic @ <imm> =
915: IF gexecute
916: ELSE compile (compile) gexecute THEN THEN ;Cond
917:
918: Cond: postpone ( -- ) restrict? \ name
919: bl word gfind dup 0= ABORT" CROSS: Can't compile"
920: 0> IF gexecute
921: ELSE dup >magic @ <imm> =
922: IF gexecute
923: ELSE compile (compile) gexecute THEN THEN ;Cond
924:
925: >MINIMAL
926: also minimal
927: \ Usefull words 13feb93py
928:
929: : KB 400 * ;
930:
931: \ define new [IFDEF] and [IFUNDEF] 20may93jaw
932:
933: : defined? defined? ;
934: : needed? needed? ;
935: : doer? doer? ;
936:
937: : [IFDEF] defined? postpone [IF] ;
938: : [IFUNDEF] defined? 0= postpone [IF] ;
939:
940: \ C: \- \+ Conditional Compiling 09jun93jaw
941:
942: : C: >in @ defined? 0=
943: IF >in ! T : H
944: ELSE drop
945: BEGIN bl word dup c@
946: IF count comment? s" ;" compare 0= ?EXIT
947: ELSE refill 0= ABORT" CROSS: Out of Input while C:"
948: THEN
949: AGAIN
950: THEN ;
951:
952: also minimal
953:
954: : \- defined? IF postpone \ THEN ;
955: : \+ defined? 0= IF postpone \ THEN ;
956:
957: : [IF] postpone [IF] ;
958: : [THEN] postpone [THEN] ;
959: : [ELSE] postpone [ELSE] ;
960:
961: Cond: [IF] [IF] ;Cond
962: Cond: [IFDEF] [IFDEF] ;Cond
963: Cond: [IFUNDEF] [IFUNDEF] ;Cond
964: Cond: [THEN] [THEN] ;Cond
965: Cond: [ELSE] [ELSE] ;Cond
966:
967: \ save-cross 17mar93py
968:
969: \ i'm not interested in bigforth features this time 10may93jaw
970: \ [IFDEF] file
971: \ also file
972: \ [THEN]
973: \ included throw after create-file 11may93jaw
974:
975: bigendian Constant bigendian
976:
977: Create magic s" Gforth10" here over allot swap move
978:
979: char 1 bigendian + cell + magic 7 + c!
980:
981: : save-cross ( "image-name" "binary-name" -- )
982: bl parse ." Saving to " 2dup type cr
983: w/o bin create-file throw >r
984: NIL IF
985: s" #! " r@ write-file throw
986: bl parse r@ write-file throw
987: s" -i" r@ write-file throw
988: #lf r@ emit-file throw
989: r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
990: ?do
991: bl over emit-file throw
992: loop
993: drop
994: magic 8 r@ write-file throw \ write magic
995: ELSE
996: bl parse 2drop
997: THEN
998: image @ there r@ write-file throw \ write image
999: NIL IF
1000: bit$ @ there 1- cell>bit rshift 1+
1001: r@ write-file throw \ write tags
1002: THEN
1003: r> close-file throw ;
1004:
1005: \ words that should be in minimal
1006:
1007: : here there ;
1008: also forth [IFDEF] Label : Label Label ; [THEN] previous
1009: : + + ;
1010: : or or ;
1011: : 1- 1- ;
1012: : - - ;
1013: : 2* 2* ;
1014: : * * ;
1015: : / / ;
1016: : dup dup ;
1017: : over over ;
1018: : swap swap ;
1019: : rot rot ;
1020: : drop drop ;
1021: : = = ;
1022: : 0= 0= ;
1023: : lshift lshift ;
1024: : 2/ 2/ ;
1025: : . . ;
1026:
1027: mach-file count included
1028:
1029: : all-words ['] false IS skip? ;
1030: : needed-words ['] needed? IS skip? ;
1031: : undef-words ['] defined? IS skip? ;
1032:
1033: : \ postpone \ ; immediate
1034: : ( postpone ( ; immediate
1035: : include bl word count included ;
1036: : .( [char] ) parse type ;
1037: : cr cr ;
1038:
1039: : times 0 ?DO dup T c, H LOOP drop ; \ used for space table creation
1040: only forth also minimal definitions
1041:
1042: \ cross-compiler words
1043:
1044: : decimal decimal ;
1045: : hex hex ;
1046:
1047: : tudp T tudp H ;
1048: : tup T tup H ;
1049:
1050: : doc-off false T to-doc H ! ;
1051: : doc-on true T to-doc H ! ;
1052:
1053: minimal
1054:
1055: \ for debugging...
1056: : order order ;
1057: : words words ;
1058: : .s .s ;
1059:
1060: : bye bye ;
1061:
1062: \ turnkey direction
1063: : H forth ; immediate
1064: : T minimal ; immediate
1065: : G ghosts ; immediate
1066:
1067: : turnkey 0 set-order also Target definitions
1068: also Minimal also ;
1069:
1070: \ these ones are pefered:
1071:
1072: : lock turnkey ;
1073: : unlock forth also cross ;
1074:
1075: unlock definitions also minimal
1076: : lock lock ;
1077: lock
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to cross.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth