1: \ CROSS.FS The Cross-Compiler 06oct92py
2: \ Idea and implementation: Bernd Paysan (py)
3:
4: \ Copyright (C) 1995 Free Software Foundation, Inc.
5:
6: \ This file is part of Gforth.
7:
8: \ Gforth is free software; you can redistribute it and/or
9: \ modify it under the terms of the GNU General Public License
10: \ as published by the Free Software Foundation; either version 2
11: \ of the License, or (at your option) any later version.
12:
13: \ This program is distributed in the hope that it will be useful,
14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: \ GNU General Public License for more details.
17:
18: \ You should have received a copy of the GNU General Public License
19: \ along with this program; if not, write to the Free Software
20: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21:
22: \ Log:
23: \ changed in ; [ to state off 12may93jaw
24: \ included place +place 12may93jaw
25: \ for a created word (variable, constant...)
26: \ is now an alias in the target voabulary.
27: \ this means it is no longer necessary to
28: \ switch between vocabularies for variable
29: \ initialization 12may93jaw
30: \ discovered error in DOES>
31: \ replaced !does with (;code) 16may93jaw
32: \ made complete redesign and
33: \ introduced two vocs method
34: \ to be asure that the right words
35: \ are found 08jun93jaw
36: \ btw: ! works not with 16 bit
37: \ targets 09jun93jaw
38: \ added: 2user and value 11jun93jaw
39:
40: \ include other.fs \ ansforth extentions for cross
41:
42: : string, ( c-addr u -- )
43: \ puts down string as cstring
44: dup c, here swap chars dup allot move ;
45: ' falign Alias cfalign
46: : comment? ( c-addr u -- c-addr u )
47: 2dup s" (" compare 0=
48: IF postpone (
49: ELSE 2dup s" \" compare 0= IF postpone \ THEN
50: THEN ;
51:
52: decimal
53:
54: \ Begin CROSS COMPILER:
55:
56: \ GhostNames 9may93jaw
57: \ second name source to search trough list
58:
59: VARIABLE GhostNames
60: 0 GhostNames !
61: : GhostName ( -- addr )
62: here GhostNames @ , GhostNames ! here 0 ,
63: bl word count
64: \ 2dup type space
65: string, cfalign ;
66:
67: hex
68:
69:
70: Vocabulary Cross
71: Vocabulary Target
72: Vocabulary Ghosts
73: VOCABULARY Minimal
74: only Forth also Target also also
75: definitions Forth
76:
77: : T previous Cross also Target ; immediate
78: : G Ghosts ; immediate
79: : H previous Forth also Cross ; immediate
80:
81: forth definitions
82:
83: : T previous Cross also Target ; immediate
84: : G Ghosts ; immediate
85:
86: : >cross also Cross definitions previous ;
87: : >target also Target definitions previous ;
88: : >minimal also Minimal definitions previous ;
89:
90: H
91:
92: >CROSS
93:
94: \ Variables 06oct92py
95:
96: -1 Constant NIL
97: Variable image
98: Variable tlast NIL tlast ! \ Last name field
99: Variable tlastcfa \ Last code field
100: Variable tdoes \ Resolve does> calls
101: Variable bit$
102: Variable tdp
103: : there tdp @ ;
104:
105: \ Parameter for target systems 06oct92py
106:
107: included
108:
109: \ Create additional parameters 19jan95py
110:
111: T
112: cell Constant tcell
113: cell<< Constant tcell<<
114: cell>bit Constant tcell>bit
115: bits/byte Constant tbits/byte
116: float Constant tfloat
117: 1 bits/byte lshift Constant maxbyte
118: H
119:
120: >TARGET
121:
122: \ Byte ordering and cell size 06oct92py
123:
124: : cell+ tcell + ;
125: : cells tcell<< lshift ;
126: : chars ;
127: : floats tfloat * ;
128:
129: >CROSS
130: : cell/ tcell<< rshift ;
131: >TARGET
132: 20 CONSTANT bl
133: -1 Constant NIL
134: -2 Constant :docol
135: -3 Constant :docon
136: -4 Constant :dovar
137: -5 Constant :douser
138: -6 Constant :dodefer
139: -7 Constant :dofield
140: -8 Constant :dodoes
141: -9 Constant :doesjump
142:
143: >CROSS
144:
145: bigendian
146: [IF]
147: : T! ( n addr -- ) >r s>d r> tcell bounds swap 1-
148: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
149: : T@ ( addr -- n ) >r 0 0 r> tcell bounds
150: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP d>s ;
151: [ELSE]
152: : T! ( n addr -- ) >r s>d r> tcell bounds
153: DO maxbyte ud/mod rot I c! LOOP 2drop ;
154: : T@ ( addr -- n ) >r 0 0 r> tcell bounds swap 1-
155: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP d>s ;
156: [THEN]
157:
158: \ Memory initialisation 05dec92py
159: \ Fixed bug in else part 11may93jaw
160:
161: [IFDEF] Memory \ Memory is a bigFORTH feature
162: also Memory
163: : initmem ( var len -- )
164: 2dup swap handle! >r @ r> erase ;
165: toss
166: [ELSE]
167: : initmem ( var len -- )
168: tuck allocate abort" CROSS: No memory for target"
169: ( len var adr ) dup rot !
170: ( len adr ) swap erase ;
171: [THEN]
172:
173: \ MakeKernal 12dec92py
174:
175: >MINIMAL
176: : makekernel ( targetsize -- targetsize )
177: bit$ over 1- cell>bit rshift 1+ initmem
178: image over initmem tdp off ;
179:
180: >CROSS
181: \ Bit string manipulation 06oct92py
182: \ 9may93jaw
183: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
184: : bits ( n -- n ) chars Bittable + c@ ;
185:
186: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
187: : +bit ( addr n -- ) >bit over c@ or swap c! ;
188: : -bit ( addr n -- ) >bit invert over c@ and swap c! ;
189: : relon ( taddr -- ) bit$ @ swap cell/ +bit ;
190: : reloff ( taddr -- ) bit$ @ swap cell/ -bit ;
191:
192: \ Target memory access 06oct92py
193:
194: : align+ ( taddr -- rest )
195: cell tuck 1- and - [ cell 1- ] Literal and ;
196: : cfalign+ ( taddr -- rest )
197: \ see kernel.fs:cfaligned
198: float tuck 1- and - [ float 1- ] Literal and ;
199:
200: >TARGET
201: : aligned ( taddr -- ta-addr ) dup align+ + ;
202: \ assumes cell alignment granularity (as GNU C)
203:
204: : cfaligned ( taddr1 -- taddr2 )
205: \ see kernel.fs
206: dup cfalign+ + ;
207:
208: >CROSS
209: : >image ( taddr -- absaddr ) image @ + ;
210: >TARGET
211: : @ ( taddr -- w ) >image t@ ;
212: : ! ( w taddr -- ) >image t! ;
213: : c@ ( taddr -- char ) >image c@ ;
214: : c! ( char taddr -- ) >image c! ;
215: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
216: : 2! ( x1 x2 taddr -- ) T swap over ! cell+ ! H ;
217:
218: \ Target compilation primitives 06oct92py
219: \ included A! 16may93jaw
220:
221: : here ( -- there ) there ;
222: : allot ( n -- ) tdp +! ;
223: : , ( w -- ) T here H cell T allot ! H ;
224: : c, ( char -- ) T here 1 allot c! H ;
225: : align ( -- ) T here H align+ 0 ?DO bl T c, H LOOP ;
226: : cfalign ( -- )
227: T here H cfalign+ 0 ?DO bl T c, H LOOP ;
228:
229: : A! dup relon T ! H ;
230: : A, ( w -- ) T here H relon T , H ;
231:
232: >CROSS
233:
234: \ threading modell 13dec92py
235:
236: \ generic threading modell
237: : docol, ( -- ) :docol T A, 0 , H ;
238:
239: >TARGET
240: : >body ( cfa -- pfa ) T cell+ cell+ H ;
241: >CROSS
242:
243: : dodoes, ( -- ) T :doesjump A, 0 , H ;
244:
245: \ Ghost Builder 06oct92py
246:
247: \ <T T> new version with temp variable 10may93jaw
248:
249: VARIABLE VocTemp
250:
251: : <T get-current VocTemp ! also Ghosts definitions ;
252: : T> previous VocTemp @ set-current ;
253:
254: 4711 Constant <fwd> 4712 Constant <res>
255: 4713 Constant <imm>
256:
257: \ iForth makes only immediate directly after create
258: \ make atonce trick! ?
259:
260: Variable atonce atonce off
261:
262: : NoExec true ABORT" CROSS: Don't execute ghost" ;
263:
264: : GhostHeader <fwd> , 0 , ['] NoExec , ;
265:
266: : >magic ; : >link cell+ ; : >exec cell+ cell+ ;
267: : >end 3 cells + ;
268:
269: Variable last-ghost
270: : Make-Ghost ( "name" -- ghost )
271: >in @ GhostName swap >in !
272: <T Create atonce @ IF immediate atonce off THEN
273: here tuck swap ! ghostheader T>
274: DOES> dup last-ghost ! >exec @ execute ;
275:
276: \ ghost words 14oct92py
277: \ changed: 10may93py/jaw
278:
279: : gfind ( string -- ghost true/1 / string false )
280: \ searches for string in word-list ghosts
281: dup count [ ' ghosts >body ] ALiteral search-wordlist
282: dup IF >r >body nip r> THEN ;
283:
284: VARIABLE Already
285:
286: : ghost ( "name" -- ghost )
287: Already off
288: >in @ bl word gfind IF Already on nip EXIT THEN
289: drop >in ! Make-Ghost ;
290:
291: \ resolve 14oct92py
292:
293: : resolve-loop ( ghost tcfa -- ghost tcfa )
294: >r dup >link @
295: BEGIN dup WHILE dup T @ H r@ rot T ! H REPEAT drop r> ;
296:
297: \ exists 9may93jaw
298:
299: : exists ( ghost tcfa -- )
300: over GhostNames
301: BEGIN @ dup
302: WHILE 2dup cell+ @ =
303: UNTIL
304: 2 cells + count cr ." CROSS: Exists: " type 4 spaces drop
305: swap cell+ !
306: ELSE true abort" CROSS: Ghostnames inconsistent "
307: THEN ;
308:
309: : resolve ( ghost tcfa -- )
310: over >magic @ <fwd> <> IF exists EXIT THEN
311: resolve-loop over >link ! <res> swap >magic ! ;
312:
313: \ gexecute ghost, 01nov92py
314:
315: : do-forward ( ghost -- )
316: >link dup @ there rot ! T A, H ;
317: : do-resolve ( ghost -- )
318: >link @ T A, H ;
319:
320: : gexecute ( ghost -- ) dup @
321: <fwd> = IF do-forward ELSE do-resolve THEN ;
322: : ghost, ghost gexecute ;
323:
324: \ .unresolved 11may93jaw
325:
326: variable ResolveFlag
327:
328: \ ?touched 11may93jaw
329:
330: : ?touched ( ghost -- flag ) dup >magic @ <fwd> = swap >link @
331: 0 <> and ;
332:
333: : ?resolved ( ghostname -- )
334: dup cell+ @ ?touched
335: IF cell+ cell+ count cr type ResolveFlag on ELSE drop THEN ;
336:
337: >MINIMAL
338: : .unresolved ( -- )
339: ResolveFlag off cr ." Unresolved: "
340: Ghostnames
341: BEGIN @ dup
342: WHILE dup ?resolved
343: REPEAT drop ResolveFlag @
344: IF
345: abort" Unresolved words!"
346: ELSE
347: ." Nothing!"
348: THEN
349: cr ;
350:
351: >CROSS
352: \ Header states 12dec92py
353:
354: : flag! ( 8b -- ) tlast @ dup >r T c@ xor r> c! H ;
355:
356: VARIABLE ^imm
357:
358: >TARGET
359: : immediate 40 flag!
360: ^imm @ @ dup <imm> = IF drop EXIT THEN
361: <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
362: <imm> ^imm @ ! ;
363: : restrict 20 flag! ;
364: >CROSS
365:
366: \ ALIAS2 ansforth conform alias 9may93jaw
367:
368: : ALIAS2 create here 0 , DOES> @ execute ;
369: \ usage:
370: \ ' <name> alias2 bla !
371:
372: \ Target Header Creation 01nov92py
373:
374: : string, ( addr count -- )
375: dup T c, H bounds ?DO I c@ T c, H LOOP ;
376: : name, ( "name" -- ) bl word count string, T cfalign H ;
377: : view, ( -- ) ( dummy ) ;
378:
379: \ Target Document Creation (goes to crossdoc.fd) 05jul95py
380:
381: s" crossdoc.fd" r/w create-file throw value doc-file-id
382: \ contains the file-id of the documentation file
383:
384: : T-\G ( -- )
385: source >in @ /string doc-file-id write-line throw
386: postpone \ ;
387:
388: Variable to-doc to-doc on
389:
390: : cross-doc-entry ( -- )
391: to-doc @ tlast @ 0<> and \ not an anonymous (i.e. noname) header
392: IF
393: s" " doc-file-id write-line throw
394: s" make-doc " doc-file-id write-file throw
395: tlast @ >image count $1F and doc-file-id write-file throw
396: >in @
397: [char] ( parse 2drop
398: [char] ) parse doc-file-id write-file throw
399: s" )" doc-file-id write-file throw
400: [char] \ parse 2drop
401: T-\G
402: >in !
403: THEN ;
404:
405: \ Target TAGS creation
406:
407: s" kernel.TAGS" r/w create-file throw value tag-file-id
408: \ contains the file-id of the tags file
409:
410: Create tag-beg 2 c, 7F c, bl c,
411: Create tag-end 2 c, bl c, 01 c,
412: Create tag-bof 1 c, 0C c,
413:
414: 2variable last-loadfilename 0 0 last-loadfilename 2!
415:
416: : put-load-file-name ( -- )
417: loadfilename 2@ last-loadfilename 2@ d<>
418: IF
419: tag-bof count tag-file-id write-line throw
420: sourcefilename 2dup
421: tag-file-id write-file throw
422: last-loadfilename 2!
423: s" ,0" tag-file-id write-line throw
424: THEN ;
425:
426: : cross-tag-entry ( -- )
427: tlast @ 0<> \ not an anonymous (i.e. noname) header
428: IF
429: put-load-file-name
430: source >in @ min tag-file-id write-file throw
431: tag-beg count tag-file-id write-file throw
432: tlast @ >image count $1F and tag-file-id write-file throw
433: tag-end count tag-file-id write-file throw
434: base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
435: \ >in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
436: s" ,0" tag-file-id write-line throw
437: base !
438: THEN ;
439:
440: \ Target header creation
441:
442: VARIABLE CreateFlag CreateFlag off
443:
444: : (Theader ( "name" -- ghost ) T align H view,
445: tlast @ dup 0> IF T 1 cells - THEN A, H there tlast !
446: >in @ name, >in ! T here H tlastcfa !
447: CreateFlag @ IF
448: >in @ alias2 swap >in ! \ create alias in target
449: >in @ ghost swap >in !
450: swap also ghosts ' previous swap ! \ tick ghost and store in alias
451: CreateFlag off
452: ELSE ghost THEN
453: dup >magic ^imm ! \ a pointer for immediate
454: Already @ IF dup >end tdoes !
455: ELSE 0 tdoes ! THEN
456: 80 flag!
457: cross-doc-entry cross-tag-entry ;
458:
459: VARIABLE ;Resolve 1 cells allot
460:
461: : Theader ( "name" -- ghost )
462: (THeader dup there resolve 0 ;Resolve ! ;
463:
464: >TARGET
465: : Alias ( cfa -- ) \ name
466: (THeader over resolve T A, H 80 flag! ;
467: >CROSS
468:
469: \ Conditionals and Comments 11may93jaw
470:
471: : ;Cond
472: postpone ;
473: swap ! ; immediate
474:
475: : Cond: ( -- ) \ name {code } ;
476: atonce on
477: ghost
478: >exec
479: :NONAME ;
480:
481: : restrict? ( -- )
482: \ aborts on interprete state - ae
483: state @ 0= ABORT" CROSS: Restricted" ;
484:
485: : Comment ( -- )
486: >in @ atonce on ghost swap >in ! ' swap >exec ! ;
487:
488: Comment ( Comment \
489:
490: \ Predefined ghosts 12dec92py
491:
492: ghost 0= drop
493: ghost branch ghost ?branch 2drop
494: ghost (do) ghost (?do) 2drop
495: ghost (for) drop
496: ghost (loop) ghost (+loop) 2drop
497: ghost (next) drop
498: ghost unloop ghost ;S 2drop
499: ghost lit ghost (compile) ghost ! 2drop drop
500: ghost (does>) ghost noop 2drop
501: ghost (.") ghost (S") ghost (ABORT") 2drop drop
502: ghost ' drop
503:
504: \ compile 10may93jaw
505:
506: : compile ( -- ) \ name
507: restrict?
508: bl word gfind dup 0= ABORT" CROSS: Can't compile "
509: 0> ( immediate? )
510: IF >exec @ compile,
511: ELSE postpone literal postpone gexecute THEN ;
512: immediate
513:
514: >TARGET
515: : ' ( -- cfa ) bl word gfind 0= ABORT" CROSS: undefined "
516: dup >magic @ <fwd> = ABORT" CROSS: forward " >link @ ;
517:
518: Cond: ['] compile lit ghost gexecute ;Cond
519:
520: Cond: chars ;Cond
521:
522: >CROSS
523: \ tLiteral 12dec92py
524:
525: : lit, ( n -- ) compile lit T , H ;
526: : alit, ( n -- ) compile lit T A, H ;
527:
528: >TARGET
529: Cond: \G T-\G ;Cond
530:
531: Cond: Literal ( n -- ) restrict? lit, ;Cond
532: Cond: ALiteral ( n -- ) restrict? alit, ;Cond
533:
534: : Char ( "<char>" -- ) bl word char+ c@ ;
535: Cond: [Char] ( "<char>" -- ) restrict? Char lit, ;Cond
536:
537: >CROSS
538: \ Target compiling loop 12dec92py
539: \ ">tib trick thrown out 10may93jaw
540: \ number? defined at the top 11may93jaw
541:
542: \ compiled word might leave items on stack!
543: : tcom ( in name -- )
544: gfind ?dup IF 0> IF nip >exec @ execute
545: ELSE nip gexecute THEN EXIT THEN
546: number? dup IF 0> IF swap lit, THEN lit, drop
547: ELSE 2drop >in !
548: ghost gexecute THEN ;
549:
550: >TARGET
551: \ : ; DOES> 13dec92py
552: \ ] 9may93py/jaw
553:
554: : ] state on
555: BEGIN
556: BEGIN >in @ bl word
557: dup c@ 0= WHILE 2drop refill 0=
558: ABORT" CROSS: End of file while target compiling"
559: REPEAT
560: tcom
561: state @
562: 0=
563: UNTIL ;
564:
565: \ by the way: defining a second interpreter (a compiler-)loop
566: \ is not allowed if a system should be ans conform
567:
568: : : ( -- colon-sys ) \ Name
569: (THeader ;Resolve ! there ;Resolve cell+ !
570: docol, depth T ] H ;
571:
572: : :noname ( -- colon-sys )
573: T align H there docol, depth T ] H ;
574:
575: Cond: EXIT ( -- ) restrict? compile ;S ;Cond
576:
577: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
578:
579: Cond: ; ( -- ) restrict?
580: depth ?dup IF 1- <> ABORT" CROSS: Stack changed"
581: ELSE true ABORT" CROSS: Stack empty" THEN
582: compile ;S state off
583: ;Resolve @
584: IF ;Resolve @ ;Resolve cell+ @ resolve THEN
585: ;Cond
586: Cond: [ restrict? state off ;Cond
587:
588: >CROSS
589: : !does :dodoes tlastcfa @ tuck T ! cell+ ! H ;
590:
591: >TARGET
592: Cond: DOES> restrict?
593: compile (does>) dodoes, tdoes @ ?dup IF @ T here H resolve THEN
594: ;Cond
595: : DOES> dodoes, T here H !does depth T ] H ;
596:
597: >CROSS
598: \ Creation 01nov92py
599:
600: \ Builder 11may93jaw
601:
602: : Builder ( Create do: "name" -- )
603: >in @ alias2 swap dup >in ! >r >r
604: Make-Ghost rot swap >exec ! ,
605: r> r> >in !
606: also ghosts ' previous swap ! ;
607: \ DOES> dup >exec @ execute ;
608:
609: : gdoes, ( ghost -- ) >end @ dup >magic @ <fwd> <>
610: IF dup >link @ dup 0< IF T A, 0 , H drop EXIT THEN drop THEN
611: :dodoes T A, H gexecute T here H cell - reloff ;
612:
613: : TCreate ( -- )
614: last-ghost @
615: CreateFlag on
616: Theader >r dup gdoes,
617: >end @ >exec @ r> >exec ! ;
618:
619: : Build: ( -- [xt] [colon-sys] )
620: :noname postpone TCreate ;
621:
622: : gdoes> ( ghost -- addr flag )
623: last-ghost @
624: state @ IF gexecute true EXIT THEN
625: cell+ @ T >body H false ;
626:
627: \ DO: ;DO 11may93jaw
628: \ changed to ?EXIT 10may93jaw
629:
630: : DO: ( -- addr [xt] [colon-sys] )
631: here ghostheader
632: :noname postpone gdoes> postpone ?EXIT ;
633:
634: : ;DO ( addr [xt] [colon-sys] -- )
635: postpone ; ( S addr xt )
636: over >exec ! ; immediate
637:
638: : by ( -- addr ) \ Name
639: ghost >end @ ;
640:
641: >TARGET
642: \ Variables and Constants 05dec92py
643:
644: Build: ;
645: DO: ( ghost -- addr ) ;DO
646: Builder Create
647: by Create :dovar resolve
648:
649: Build: T 0 , H ;
650: by Create
651: Builder Variable
652:
653: Build: T 0 A, H ;
654: by Create
655: Builder AVariable
656:
657: \ User variables 04may94py
658:
659: >CROSS
660: Variable tup 0 tup !
661: Variable tudp 0 tudp !
662: : u, ( n -- udp )
663: tup @ tudp @ + T ! H
664: tudp @ dup T cell+ H tudp ! ;
665: : au, ( n -- udp )
666: tup @ tudp @ + T A! H
667: tudp @ dup T cell+ H tudp ! ;
668: >TARGET
669:
670: Build: T 0 u, , H ;
671: DO: ( ghost -- up-addr ) T @ H tup @ + ;DO
672: Builder User
673: by User :douser resolve
674:
675: Build: T 0 u, , 0 u, drop H ;
676: by User
677: Builder 2User
678:
679: Build: T 0 au, , H ;
680: by User
681: Builder AUser
682:
683: Build: ( n -- ) T , H ;
684: DO: ( ghost -- n ) T @ H ;DO
685: Builder Constant
686: by Constant :docon resolve
687:
688: Build: ( n -- ) T A, H ;
689: by Constant
690: Builder AConstant
691:
692: Build: ( d -- ) T , , H ;
693: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
694: Builder 2Constant
695:
696: Build: T 0 , H ;
697: by Constant
698: Builder Value
699:
700: Build: T 0 A, H ;
701: by Constant
702: Builder AValue
703:
704: Build: ( -- ) compile noop ;
705: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
706: Builder Defer
707: by Defer :dodefer resolve
708:
709: Build: ( inter comp -- ) swap T immediate A, A, H ;
710: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
711: Builder interpret/compile:
712:
713: \ Sturctures 23feb95py
714:
715: >CROSS
716: : nalign ( addr1 n -- addr2 )
717: \ addr2 is the aligned version of addr1 wrt the alignment size n
718: 1- tuck + swap invert and ;
719: >TARGET
720:
721: Build: >r rot r@ nalign dup T , H ( align1 size offset )
722: + swap r> nalign ;
723: DO: T @ H + ;DO
724: Builder Field
725: by Field :dofield resolve
726:
727: : struct T 0 1 chars H ;
728: : end-struct T 2Constant H ;
729:
730: : cells: ( n -- size align )
731: T cells 1 cells H ;
732:
733: \ ' 2Constant Alias2 end-struct
734: \ 0 1 T Chars H 2Constant struct
735:
736: \ structural conditionals 17dec92py
737:
738: >CROSS
739: : ?struc ( flag -- ) ABORT" CROSS: unstructured " ;
740: : sys? ( sys -- sys ) dup 0= ?struc ;
741: : >mark ( -- sys ) T here 0 , H ;
742: : >resolve ( sys -- ) T here over - swap ! H ;
743: : <resolve ( sys -- ) T here - , H ;
744: >TARGET
745:
746: \ Structural Conditionals 12dec92py
747:
748: Cond: BUT restrict? sys? swap ;Cond
749: Cond: YET restrict? sys? dup ;Cond
750:
751: >CROSS
752: Variable tleavings
753: >TARGET
754:
755: Cond: DONE ( addr -- ) restrict? tleavings @
756: BEGIN 2dup u> 0= WHILE dup T @ H swap >resolve REPEAT
757: tleavings ! drop ;Cond
758:
759: >CROSS
760: : (leave T here H tleavings @ T , H tleavings ! ;
761: >TARGET
762:
763: Cond: LEAVE restrict? compile branch (leave ;Cond
764: Cond: ?LEAVE restrict? compile 0= compile ?branch (leave ;Cond
765:
766: \ Structural Conditionals 12dec92py
767:
768: Cond: AHEAD restrict? compile branch >mark ;Cond
769: Cond: IF restrict? compile ?branch >mark ;Cond
770: Cond: THEN restrict? sys? dup T @ H ?struc >resolve ;Cond
771: Cond: ELSE restrict? sys? compile AHEAD swap compile THEN ;Cond
772:
773: Cond: BEGIN restrict? T here H ;Cond
774: Cond: WHILE restrict? sys? compile IF swap ;Cond
775: Cond: AGAIN restrict? sys? compile branch <resolve ;Cond
776: Cond: UNTIL restrict? sys? compile ?branch <resolve ;Cond
777: Cond: REPEAT restrict? over 0= ?struc compile AGAIN compile THEN ;Cond
778:
779: \ Structural Conditionals 12dec92py
780:
781: Cond: DO restrict? compile (do) T here H ;Cond
782: Cond: ?DO restrict? compile (?do) (leave T here H ;Cond
783: Cond: FOR restrict? compile (for) T here H ;Cond
784:
785: >CROSS
786: : loop] dup <resolve cell - compile DONE compile unloop ;
787: >TARGET
788:
789: Cond: LOOP restrict? sys? compile (loop) loop] ;Cond
790: Cond: +LOOP restrict? sys? compile (+loop) loop] ;Cond
791: Cond: NEXT restrict? sys? compile (next) loop] ;Cond
792:
793: \ String words 23feb93py
794:
795: : ," [char] " parse string, T align H ;
796:
797: Cond: ." restrict? compile (.") T ," H ;Cond
798: Cond: S" restrict? compile (S") T ," H ;Cond
799: Cond: ABORT" restrict? compile (ABORT") T ," H ;Cond
800:
801: Cond: IS T ' >body H compile ALiteral compile ! ;Cond
802: : IS T ' >body ! H ;
803: Cond: TO T ' >body H compile ALiteral compile ! ;Cond
804: : TO T ' >body ! H ;
805:
806: \ LINKED ERR" ENV" 2ENV" 18may93jaw
807:
808: \ linked list primitive
809: : linked T here over @ A, swap ! H ;
810:
811: : err" s" ErrLink linked" evaluate T , H
812: [char] " parse string, T align H ;
813:
814: : env" [char] " parse s" EnvLink linked" evaluate
815: string, T align , H ;
816:
817: : 2env" [char] " parse s" EnvLink linked" evaluate
818: here >r string, T align , , H
819: r> dup T c@ H 80 and swap T c! H ;
820:
821: \ compile must be last 22feb93py
822:
823: Cond: compile ( -- ) restrict? \ name
824: bl word gfind dup 0= ABORT" CROSS: Can't compile"
825: 0> IF gexecute
826: ELSE dup >magic @ <imm> =
827: IF gexecute
828: ELSE compile (compile) gexecute THEN THEN ;Cond
829:
830: Cond: postpone ( -- ) restrict? \ name
831: bl word gfind dup 0= ABORT" CROSS: Can't compile"
832: 0> IF gexecute
833: ELSE dup >magic @ <imm> =
834: IF gexecute
835: ELSE compile (compile) gexecute THEN THEN ;Cond
836:
837: >MINIMAL
838: also minimal
839: \ Usefull words 13feb93py
840:
841: : KB 400 * ;
842:
843: \ define new [IFDEF] and [IFUNDEF] 20may93jaw
844:
845: : there? bl word gfind IF >magic @ <fwd> <> ELSE drop false THEN ;
846:
847: : [IFDEF] there? postpone [IF] ;
848: : [IFUNDEF] there? 0= postpone [IF] ;
849:
850: \ C: \- \+ Conditional Compiling 09jun93jaw
851:
852: : C: >in @ there? 0=
853: IF >in ! T : H
854: ELSE drop
855: BEGIN bl word dup c@
856: IF count comment? s" ;" compare 0= ?EXIT
857: ELSE refill 0= ABORT" CROSS: Out of Input while C:"
858: THEN
859: AGAIN
860: THEN ;
861:
862: also minimal
863:
864: : \- there? IF postpone \ THEN ;
865: : \+ there? 0= IF postpone \ THEN ;
866:
867: : [IF] postpone [IF] ;
868: : [THEN] postpone [THEN] ;
869: : [ELSE] postpone [ELSE] ;
870:
871: Cond: [IF] [IF] ;Cond
872: Cond: [IFDEF] [IFDEF] ;Cond
873: Cond: [IFUNDEF] [IFUNDEF] ;Cond
874: Cond: [THEN] [THEN] ;Cond
875: Cond: [ELSE] [ELSE] ;Cond
876:
877: \ save-cross 17mar93py
878:
879: \ i'm not interested in bigforth features this time 10may93jaw
880: \ [IFDEF] file
881: \ also file
882: \ [THEN]
883: \ included throw after create-file 11may93jaw
884:
885: bigendian Constant bigendian
886:
887: Create magic s" Gforth10" here over allot swap move
888:
889: char 1 bigendian + cell + magic 7 + c!
890:
891: : save-cross ( "image-name" "binary-name" -- )
892: bl parse ." Saving to " 2dup type cr
893: w/o bin create-file throw >r
894: s" #! " r@ write-file throw
895: bl parse r@ write-file throw
896: s" -i" r@ write-file throw
897: #lf r@ emit-file throw
898: r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
899: ?do
900: bl over emit-file throw
901: loop
902: drop
903: magic 8 r@ write-file throw \ write magic
904: image @ there r@ write-file throw \ write image
905: bit$ @ there 1- cell>bit rshift 1+
906: r@ write-file throw \ write tags
907: r> close-file throw ;
908:
909: \ words that should be in minimal
910:
911: : + + ; : 1- 1- ;
912: : - - ; : 2* 2* ;
913: : * * ; : / / ;
914: : dup dup ; : over over ;
915: : swap swap ; : rot rot ;
916: : drop drop ; : = = ;
917: : lshift lshift ; : 2/ 2/ ;
918: : . . ;
919: cell constant cell
920:
921: \ include bug5.fs
922: \ only forth also minimal definitions
923:
924: : \ postpone \ ; immediate
925: : ( postpone ( ; immediate
926: : include bl word count included ;
927: : .( [char] ) parse type ;
928: : cr cr ;
929:
930: : times 0 ?DO dup T c, H LOOP drop ; \ used for space table creation
931: only forth also minimal definitions
932:
933: \ cross-compiler words
934:
935: : decimal decimal ;
936: : hex hex ;
937:
938: : tudp T tudp H ;
939: : tup T tup H ;
940:
941: : doc-off false T to-doc H ! ;
942: : doc-on true T to-doc H ! ;
943:
944: minimal
945:
946: \ for debugging...
947: : order order ;
948: : words words ;
949: : .s .s ;
950:
951: : bye bye ;
952:
953: \ turnkey direction
954: : H forth ; immediate
955: : T minimal ; immediate
956: : G ghosts ; immediate
957:
958: : turnkey 0 set-order also Target definitions
959: also Minimal also ;
960:
961: \ these ones are pefered:
962:
963: : lock turnkey ;
964: : unlock forth also cross ;
965:
966: unlock definitions also minimal
967: : lock lock ;
968: lock
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>