1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.6.1],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="March 11, 2003"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #default setting that may be changed later:
33: no_dynamic_default=0
34:
35: AC_ARG_ENABLE(force-reg,
36: [ --enable-force-reg Use explicit register declarations if they appear in
37: the machine.h file. This can cause a good speedup,
38: but also incorrect code with some gcc versions on
39: some processors (default disabled).],
40: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
41:
42: AC_ARG_WITH(debug,
43: [ --with-debug specifies option -g to compile with debug info (default)
44: --without-debug omits the -g switch and creates smaller images on
45: machines where "strip" has problems with gcc style
46: debugging informations.],
47: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
48:
49: dnl PEEPHOLE="yes"
50: dnl AC_ARG_WITH(peephole,
51: dnl [ --with-peephole Enable peephole optimization (default)
52: dnl --without-peephole disables peephole optimization. Creates smaller,
53: dnl but slower images.],
54: dnl PEEPHOLE="$withval")
55:
56: #variables mentioned in INSTALL
57: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
58: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
59: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
60: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
61: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
62: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
63: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
64: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
65: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
66: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
67: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no)?])
68:
69: #set up feature test macros, so the tests get them right:
70: # turn on all POSIX, SUSv3, and GNU features if available
71: AC_GNU_SOURCE
72: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
73:
74: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
75: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
76: dnl but not for _XOPEN_SOURCE)
77: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
78: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
79: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
80: # turn on large file support with 64-bit off_t where available
81: AC_SYS_LARGEFILE
82: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
83: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
84:
85: #currently we force direct threading this way. Eventually we should
86: #setup in the arch and engine files right
87:
88: CFLAGS=$CFLAGS
89:
90: AC_PROG_CC
91:
92: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
93:
94: AC_SUBST(CC)
95: AC_SUBST(DEBUGFLAG)
96:
97: dnl gcc-3.2 seems to work fine now
98: dnl AC_MSG_CHECKING(gcc version)
99: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
100: dnl AC_MSG_RESULT($gcc_version)
101: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
102: dnl then
103: dnl no_dynamic_default=1
104: dnl AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
105: dnl fi
106:
107: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
108: OLDLDFLAGS=$LDFLAGS
109: LDFLAGS="$LDFLAGS -export-dynamic"
110: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
111: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
112: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
113: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
114: AC_MSG_RESULT($ac_export_dynamic)
115:
116: #terminology is a bit unusual here: The host is the system on which
117: #gforth will run; the system on which configure will run is the `build'
118: AC_CANONICAL_HOST
119: case "$host_cpu" in
120: hppa*)
121: machine=hppa
122: $srcdir/mkinstalldirs arch/hppa
123: AC_LIBOBJ(../arch/hppa/cache)
124: #LDFLAGS="$LDFLAGS -Xlinker -N"
125: LIBS="$LIBS -L/lib/pa1.1/"
126: ;;
127: sparc*)
128: machine=sparc
129: ;;
130: i386)
131: machine=386
132: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
133: ;;
134: i486)
135: machine=386
136: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
137: ;;
138: i*86)
139: machine=386
140: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
141: CFLAGS_1="$CFLAGS"
142: CFLAGS="$CFLAGS -march=pentium"
143: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
144: ;;
145: #generic should work for IA64
146: # ia64*)
147: # machine=ia64
148: # ;;
149: m68k)
150: machine=m68k
151: CFLAGS="$CFLAGS -fomit-frame-pointer"
152: if test "$host_os" = "nextstep3"
153: then
154: AC_LIBOBJ(termios)
155: fi
156: ;;
157: mips*)
158: machine=mips
159: #dynamic native code has the following problems on MIPS:
160: #
161: #1) J/JAL seems relocatable, but is are only
162: #relocatable within a 256MB-segment. While we try to
163: #get the linker to arrange this, there is no guarantee
164: #that this will succeed (and if the user uses a lot of
165: #memory, it is likely to fail).
166: #
167: #2) The way we generate dynamic native code may
168: #violate MIPS architectural restrictions (in
169: #particular, the delay slots of LW, MFLO, etc.)
170: #
171: #Therefore we disable dynamic native code by default:
172: no_dynamic_default=1
173: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
174: ;;
175: alpha*)
176: machine=alpha
177: #full IEEE FP support for more uniformity across platforms:
178: CFLAGS="$CFLAGS -mieee"
179: ;;
180: power*|rs6000)
181: machine=power
182: $srcdir/mkinstalldirs arch/power
183: AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
184: #long long is broken on (at least) gcc-2.95.* for PPC
185: test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
186: ;;
187: *)
188: AC_MSG_WARN([Using a generic machine description])
189: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
190: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
191: machine=generic
192: #I-cache flushing would be needed for dynamic code generation
193: no_dynamic_default=1
194: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
195: esac
196: AC_SUBST(host)
197:
198: dnl the following macro produces a warning with autoconf-2.1
199: AC_CHECK_SIZEOF(char *)
200: case "$ac_cv_sizeof_char_p" in
201: 2)
202: wordsize=16
203: ;;
204: 4)
205: wordsize=32
206: ;;
207: 8)
208: wordsize=64
209: ;;
210: esac
211:
212: AC_CHECK_SIZEOF(char)
213: AC_CHECK_SIZEOF(short)
214: AC_CHECK_SIZEOF(int)
215: AC_CHECK_SIZEOF(long)
216: AC_CHECK_SIZEOF(long long)
217: AC_CHECK_SIZEOF(intptr_t)
218: AC_CHECK_SIZEOF(int128_t)
219:
220: AC_MSG_CHECKING([for a C type for cells])
221: ac_cv_int_type_cell=none
222: case "$ac_cv_sizeof_char_p" in
223: $ac_cv_sizeof_int)
224: ac_cv_int_type_cell=int
225: ;;
226: $ac_cv_sizeof_short)
227: ac_cv_int_type_cell=short
228: ;;
229: $ac_cv_sizeof_char)
230: ac_cv_int_type_cell=char
231: ;;
232: $ac_cv_sizeof_long)
233: ac_cv_int_type_cell=long
234: ;;
235: $ac_cv_sizeof_long_long)
236: ac_cv_int_type_cell="long long"
237: ;;
238: $ac_cv_sizeof_intptr_t)
239: ac_cv_int_type_cell="intptr_t"
240: ;;
241: $ac_cv_sizeof_int128_t)
242: ac_cv_int_type_cell="int128_t"
243: ;;
244: esac
245: AC_MSG_RESULT($ac_cv_int_type_cell)
246: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
247:
248: AC_MSG_CHECKING([for a C type for double-cells])
249: ac_cv_int_type_double_cell=none
250: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
251: $ac_cv_sizeof_short)
252: ac_cv_int_type_double_cell=short
253: ;;
254: $ac_cv_sizeof_int)
255: ac_cv_int_type_double_cell=int
256: ;;
257: $ac_cv_sizeof_long)
258: ac_cv_int_type_double_cell=long
259: ;;
260: $ac_cv_sizeof_long_long)
261: ac_cv_int_type_double_cell="long long"
262: ;;
263: $ac_cv_sizeof_intptr_t)
264: ac_cv_int_type_double_cell="intptr_t"
265: ;;
266: $ac_cv_sizeof_int128_t)
267: ac_cv_int_type_double_cell="int128_t"
268: ;;
269: esac
270: AC_MSG_RESULT($ac_cv_int_type_double_cell)
271: if test "$ac_cv_int_type_double_cell" = none; then
272: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
273: AC_LIBOBJ(dblsub)
274: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
275: else
276: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
277: fi
278:
279: AC_TYPE_OFF_T
280: AC_CHECK_SIZEOF(off_t)
281: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
282: ac_small_off_t=$?
283: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
284:
285: ENGINE_FLAGS=
286: AC_SUBST(ENGINE_FLAGS)
287:
288: # Try if GCC understands -fno-gcse
289:
290: AC_MSG_CHECKING([if $CC understands -fno-gcse])
291: CFLAGS_1="$CFLAGS"
292: CFLAGS="$CFLAGS -fno-gcse"
293: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
294: CFLAGS="$CFLAGS_1"
295: AC_MSG_RESULT($ac_nogcse)
296:
297: # Try if GCC understands -fno-strict-aliasing
298: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
299: CFLAGS_1="$CFLAGS"
300: CFLAGS="$CFLAGS -fno-strict-aliasing"
301: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
302: CFLAGS="$CFLAGS_1"
303: AC_MSG_RESULT($ac_nostrictaliasing)
304:
305: # Try if GCC understands -fno-cross-jump
306: AC_MSG_CHECKING([if $CC understands -fno-cross-jump])
307: CFLAGS_1="$CFLAGS"
308: CFLAGS="$CFLAGS -fno-cross-jump"
309: AC_TRY_COMPILE(,,ac_nocrossjump=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-cross-jump",ac_nocrossjump=no)
310: CFLAGS="$CFLAGS_1"
311: AC_MSG_RESULT($ac_nocrossjump)
312:
313: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
314: AC_SUBST(asm_fs)
315:
316: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
317: AC_SUBST(disasm_fs)
318:
319: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
320:
321: case "$host_os" in
322: *win32|cygwin)
323: DIRSEP="\\\\"
324: ;;
325: *darwin*)
326: #Darwin uses some funny preprocessor by default; eliminate it:
327: AC_MSG_NOTICE([using -traditional-cpp on Darwin])
328: CFLAGS="$CFLAGS -no-cpp-precomp"
329: DIRSEP="/"
330: ;;
331: *)
332: DIRSEP="/"
333: ;;
334: esac
335: AC_SUBST(DIRSEP)
336: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
337:
338: dnl Now a little support for DOS/DJGCC
339: AC_SUBST(GFORTH_EXE)
340: GFORTH_EXE=""
341: AC_SUBST(GFORTHFAST_EXE)
342: GFORTHFAST_EXE=""
343: AC_SUBST(GFORTHITC_EXE)
344: GFORTHITC_EXE=""
345: AC_SUBST(GFORTHDITC_EXE)
346: GFORTHDITC_EXE=""
347:
348: PATHSEP=":"
349: AC_SUBST(PATHSEP)
350: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
351:
352: AC_SUBST(FORTHSIZES)
353:
354: dnl if test "$PEEPHOLE" = "yes"
355: dnl then
356: dnl PEEPHOLEFLAG="true"
357: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
358: dnl else
359: dnl PEEPHOLEFLAG="false"
360: dnl fi
361: PEEPHOLEFLAG="true"
362: AC_SUBST(PEEPHOLEFLAG)
363:
364: dnl copy commands for systems that don't have links
365: AC_SUBST(LINK_KERNL)
366: LINK_KERNL=""
367:
368: #if test $host_os=dos
369: #then
370: # echo Configuring for DOS!!!
371: # MAKE_EXE="coff2exe gforth"
372: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
373: #fi
374:
375: dnl the following macro produces a warning with autoconf-2.1
376: AC_C_BIGENDIAN
377: AC_SUBST(KERNEL)
378: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
379: if test $ac_cv_c_bigendian = yes; then
380: bytesex=b
381: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
382: else
383: bytesex=l
384: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
385: fi
386:
387: #check how to do asm(".skip 16")
388: AC_MSG_CHECKING([if and how we can waste code space])
389: skipcode=no
390: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
391: do
392: AC_TRY_RUN(
393: int foo(int);
394: main()
395: {
396: exit(foo(0)!=16);
397: }
398: int foo(int x)
399: {
400: if (x) {
401: label1:
402: asm("$i");
403: label2:
404: }
405: return (&&label2)-(&&label1);
406: }
407: ,skipcode=$i; break
408: ,,)
409: done
410: AC_MSG_RESULT($skipcode)
411: if test "$skipcode" = no
412: then
413: no_dynamic_default=1
414: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
415: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
416: else
417: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
418: fi
419:
420: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
421:
422: dnl Checks for programs.
423: AC_PROG_LN_S
424: AC_PROG_INSTALL
425:
426: dnl Checks for library functions
427: dnl This check is just for making later checks link with libm.
428: dnl using sin here is no good idea since it is built-into gcc and typechecked
429: AC_CHECK_LIB(m,asin)
430: AC_CHECK_LIB(dl,dlopen)
431: if test "$host_os" != "nextstep3"
432: then
433: AC_FUNC_MEMCMP
434: fi
435: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
436: AC_FUNC_FSEEKO
437: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
438: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
439: AC_DECL_SYS_SIGLIST
440: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
441: AC_CHECK_FUNCS(expm1 log1p)
442: AC_REPLACE_FUNCS(rint ecvt)
443: dnl No check for select, because our replacement is no good under
444: dnl anything but DOS
445: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
446: AC_FUNC_FNMATCH
447: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
448: AC_CHECK_FUNCS(mmap sysconf getpagesize)
449: AM_PATH_LISPDIR
450:
451: kernel_fi=kernl${wordsize}${bytesex}.fi
452: AC_SUBST(kernel_fi)
453:
454: #this breaks bindists
455: #dnl replace srource directory by absolute value
456: #if test $srcdir = "."; then srcdir=`pwd`
457: #fi
458:
459: AC_SUBST(machine)
460: AC_CONFIG_FILES([
461: Makefile
462: Makedist
463: gforthmi
464: vmgen
465: machpc.fs
466: engine/Makefile
467: doc/version.texi ])
468: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
469: chmod +x gforthmi
470: chmod +x vmgen
471: test -d kernel||mkdir kernel]],[[]])
472: AC_OUTPUT
473:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>