File:  [gforth] / gforth / configure.in
Revision 1.98: download - view: text, annotated - select for diffs
Tue Jan 7 09:31:19 2003 UTC (16 years, 8 months ago) by anton
Branches: MAIN
CVS tags: HEAD
Some changes for portability to AIX and Darwin
Eliminated the (non-hybrid) direct threading stuff from arch/*/machine.h

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.5.9-20021227],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: #snapshots have numbers major.minor.release-YYYYMMDD
   25: #note that lexicographic ordering must be heeded.
   26: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   27: UPDATED="27 December 2002"
   28: AC_SUBST(UPDATED)
   29: AC_CONFIG_HEADERS(engine/config.h)
   30: 
   31: #default setting that may be changed later:
   32: no_dynamic_default=0
   33: 
   34: AC_ARG_ENABLE(force-reg,
   35: [  --enable-force-reg	  Use explicit register declarations if they appear in
   36: 			  the machine.h file. This can cause a good speedup,
   37: 			  but also incorrect code with some gcc versions on
   38: 			  some processors (default disabled).],
   39: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   40: 
   41: AC_ARG_WITH(debug,
   42: [  --with-debug     specifies option -g to compile with debug info (default)
   43:   --without-debug  omits the -g switch and creates smaller images on
   44:                    machines where "strip" has problems with gcc style
   45:                    debugging informations.],
   46: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   47: 
   48: PEEPHOLE="yes"
   49: AC_ARG_WITH(peephole,
   50: [  --with-peephole	Enable peephole optimization (default)
   51:   --without-peephole	disables peephole optimization. Creates smaller,
   52: 			but slower images.],
   53: PEEPHOLE="$withval")
   54: 
   55: #set up feature test macros, so the tests get them right:
   56: # turn on all POSIX, SUSv3, and GNU features if available
   57: AC_GNU_SOURCE
   58: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   59: 
   60: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   61: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   62: dnl but not for _XOPEN_SOURCE)
   63: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   64: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   65: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   66: # turn on large file support with 64-bit off_t where available
   67: AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   68: AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
   69: 
   70: #currently we force direct threading this way.  Eventually we should
   71: #setup in the arch and engine files right
   72: 
   73: CFLAGS=$CFLAGS
   74: 
   75: AC_PROG_CC
   76: 
   77: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   78: 
   79: AC_SUBST(CC)
   80: AC_SUBST(DEBUGFLAG)
   81: 
   82: dnl gcc-3.2 seems to work fine now
   83: dnl AC_MSG_CHECKING(gcc version)
   84: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
   85: dnl AC_MSG_RESULT($gcc_version)
   86: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
   87: dnl then
   88: dnl    no_dynamic_default=1
   89: dnl    AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
   90: dnl fi
   91: 
   92: dnl the following macro produces a warning with autoconf-2.1
   93: AC_CHECK_SIZEOF(char *)
   94: case "$ac_cv_sizeof_char_p" in
   95:   2)
   96:     wordsize=16
   97:     ;;
   98:   4)
   99:     wordsize=32
  100:     ;;
  101:   8)
  102:     wordsize=64
  103:     ;;
  104: esac
  105: 
  106: AC_CHECK_SIZEOF(char)
  107: AC_CHECK_SIZEOF(short)
  108: AC_CHECK_SIZEOF(int)
  109: AC_CHECK_SIZEOF(long)
  110: AC_CHECK_SIZEOF(long long)
  111: 
  112: AC_MSG_CHECKING([for a C type for cells])
  113: ac_cv_int_type_cell=none
  114: case "$ac_cv_sizeof_char_p" in
  115:   $ac_cv_sizeof_int)
  116:     ac_cv_int_type_cell=int
  117:     ;;
  118:   $ac_cv_sizeof_short)
  119:     ac_cv_int_type_cell=short
  120:     ;;
  121:   $ac_cv_sizeof_char)
  122:     ac_cv_int_type_cell=char
  123:     ;;
  124:   $ac_cv_sizeof_long)
  125:     ac_cv_int_type_cell=long
  126:     ;;
  127:   $ac_cv_sizeof_long_long)
  128:     ac_cv_int_type_cell="long long"
  129:     ;;
  130: esac
  131: AC_MSG_RESULT($ac_cv_int_type_cell)
  132: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  133: 
  134: AC_MSG_CHECKING([for a C type for double-cells])
  135: ac_cv_int_type_double_cell=none
  136: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  137:   $ac_cv_sizeof_short)
  138:     ac_cv_int_type_double_cell=short
  139:     ;;
  140:   $ac_cv_sizeof_int)
  141:     ac_cv_int_type_double_cell=int
  142:     ;;
  143:   $ac_cv_sizeof_long)
  144:     ac_cv_int_type_double_cell=long
  145:     ;;
  146:   $ac_cv_sizeof_long_long)
  147:     ac_cv_int_type_double_cell="long long"
  148:     ;;
  149: esac
  150: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  151: if test "$ac_cv_int_type_double_cell" = none; then
  152: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  153: 	AC_LIBOBJ(dblsub)
  154: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  155: else
  156: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  157: fi
  158: 
  159: AC_TYPE_OFF_T
  160: AC_CHECK_SIZEOF(off_t)
  161: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  162: ac_small_off_t=$?
  163: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  164: 
  165: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  166: OLDLDFLAGS=$LDFLAGS
  167: LDFLAGS="$LDFLAGS -export-dynamic"
  168: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  169: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  170: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  171: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  172: AC_MSG_RESULT($ac_export_dynamic)
  173: 
  174: #terminology is a bit unusual here: The host is the system on which
  175: #gforth will run; the system on which configure will run is the `build'
  176: AC_CANONICAL_HOST
  177: case "$host_cpu" in
  178: 	hppa*)
  179: 		machine=hppa
  180: 		$srcdir/mkinstalldirs arch/hppa
  181: 		AC_LIBOBJ(../arch/hppa/cache)
  182: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  183: 		LIBS="$LIBS -L/lib/pa1.1/"
  184: 		;;
  185: 	sparc*)
  186: 		machine=sparc
  187: 		;;
  188: 	i386)
  189: 		machine=386
  190: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  191: 		;;
  192: 	i486)
  193: 		machine=386
  194: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  195: 		;;
  196: 	i*86)
  197: 		machine=386
  198: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  199: 		CFLAGS_1="$CFLAGS"
  200: 		CFLAGS="$CFLAGS -march=pentium"
  201: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  202: 		;;
  203: #generic should work for IA64
  204: #	ia64*)
  205: #		machine=ia64
  206: #		;;
  207:         m68k)
  208: 		machine=m68k
  209: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  210: 		if test "$host_os" = "nextstep3"
  211: 		then
  212: 			AC_LIBOBJ(termios)
  213: 		fi
  214: 		#I-cache flushing would be needed for dynamic code generation
  215: 		no_dynamic_default=1
  216: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  217: 		;;
  218: 	mips*)
  219: 		machine=mips
  220: 		#dynamic native code has the following problems on MIPS:
  221: 		#
  222: 		#1) J/JAL seems relocatable, but is are only
  223: 		#relocatable within a 256MB-segment.  While we try to
  224: 		#get the linker to arrange this, there is no guarantee
  225: 		#that this will succeed (and if the user uses a lot of
  226: 		#memory, it is likely to fail).
  227: 		#
  228: 		#2) The way we generate dynamic native code may
  229: 		#violate MIPS architectural restrictions (in
  230: 		#particular, the delay slots of LW, MFLO, etc.)
  231: 		#
  232: 		#Therefore we disable dynamic native code by default:
  233: 		no_dynamic_default=1
  234: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  235: 		#link text and data segment into the same 256M region!
  236: 		AC_MSG_CHECKING([whether the linker accepts -T])
  237: 		OLDLDFLAGS=$LDFLAGS
  238: 		LDFLAGS="$LDFLAGS -Xlinker -T -Xlinker 10000000"
  239: 		AC_TRY_LINK(,,ac_link_mips_t=yes,ac_link_mips_t=no)
  240: 		test $ac_link_mips_t = yes||LDFLAGS=$OLDLDFLAGS
  241: 		AC_MSG_RESULT($ac_link_mips_t)
  242: 		AC_MSG_CHECKING([whether the linker accepts -D])
  243: 		OLDLDFLAGS=$LDFLAGS
  244: 		LDFLAGS="$LDFLAGS -Xlinker -D -Xlinker 10400000"
  245: 		AC_TRY_LINK(,,ac_link_mips_d=yes,ac_link_mips_d=no)
  246: 		test $ac_link_mips_d = yes||LDFLAGS=$OLDLDFLAGS
  247: 		AC_MSG_RESULT($ac_link_mips_d)
  248: 		;;
  249: 	alpha*)
  250: 		machine=alpha
  251: 		#full IEEE FP support for more uniformity across platforms:
  252: 		CFLAGS="$CFLAGS -mieee"
  253: 		;;
  254: 	power*|rs6000)
  255: 		machine=power
  256: 		$srcdir/mkinstalldirs arch/power
  257: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  258: 		;;
  259: 	*)
  260: 		AC_MSG_WARN([Using a generic machine description])
  261: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  262: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  263: 		machine=generic
  264: 		#I-cache flushing would be needed for dynamic code generation
  265: 		no_dynamic_default=1
  266: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  267: esac
  268: AC_SUBST(host)
  269: AC_SUBST(ENGINE_FLAGS)
  270: 
  271: # Try if GCC understands -fno-cross-jump
  272: 
  273: CFLAGS_1="$CFLAGS"
  274: CFLAGS="$CFLAGS -fno-cross-jump"
  275: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  276: 
  277: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  278: AC_SUBST(asm_fs)
  279: 
  280: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  281: AC_SUBST(disasm_fs)
  282: 
  283: case "$host_os" in
  284: 	*win32)
  285: 		EXE=".exe"
  286: 		DIRSEP="\\"
  287: 		;;
  288: 	*darwin*)
  289: 		#Darwin uses some funny preprocessor by default; eliminate it:
  290: 		AC_MSG_NOTICE([using -traditional-cpp on Darwin])
  291: 		CFLAGS="$CFLAGS -traditional-cpp"
  292: 		EXE=""
  293: 		DIRSEP="/"
  294: 		;;
  295: 	*)
  296: 		EXE=""
  297: 		DIRSEP="/"
  298: 		;;
  299: esac
  300: AC_SUBST(EXE)
  301: AC_SUBST(DIRSEP)
  302: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  303: 
  304: dnl Now a little support for DOS/DJGCC
  305: AC_SUBST(GFORTH_EXE)
  306: GFORTH_EXE=""
  307: AC_SUBST(GFORTHFAST_EXE)
  308: GFORTHFAST_EXE=""
  309: AC_SUBST(GFORTHITC_EXE)
  310: GFORTHITC_EXE=""
  311: AC_SUBST(GFORTHDITC_EXE)
  312: GFORTHDITC_EXE=""
  313: 
  314: PATHSEP=":"
  315: AC_SUBST(PATHSEP)
  316: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  317: 
  318: AC_SUBST(FORTHSIZES)
  319: 
  320: if test "$PEEPHOLE" = "yes"
  321: then
  322:    PEEPHOLEFLAG="true"
  323:    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  324: else
  325:    PEEPHOLEFLAG="false"
  326: fi
  327: AC_SUBST(PEEPHOLEFLAG)
  328: 
  329: dnl copy commands for systems that don't have links
  330: AC_SUBST(LINK_KERNL)
  331: LINK_KERNL=""
  332: 
  333: #if test $host_os=dos
  334: #then
  335: #  echo Configuring for DOS!!!
  336: #  MAKE_EXE="coff2exe gforth"
  337: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  338: #fi
  339: 
  340: dnl the following macro produces a warning with autoconf-2.1
  341: AC_C_BIGENDIAN
  342: AC_SUBST(KERNEL)
  343: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  344: if test $ac_cv_c_bigendian = yes; then
  345:   bytesex=b
  346:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  347: else
  348:   bytesex=l
  349:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  350: fi
  351: 
  352: #check how to do asm(".skip 16")
  353: AC_MSG_CHECKING([if and how we can waste code space])
  354: skipcode=no
  355: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  356: do
  357: 	AC_TRY_RUN(
  358: int foo(int);
  359: main()
  360: {
  361:   exit(foo(0)!=16);
  362: }
  363: int foo(int x)
  364: {
  365:   if (x) {
  366:   label1:
  367:     asm("$i");
  368:   label2:
  369:   }
  370:   return (&&label2)-(&&label1);
  371: }
  372: 	,skipcode=$i; break
  373: 	,,)
  374: done	
  375: AC_MSG_RESULT($skipcode)
  376: if test "$skipcode" = no
  377: then 
  378:     no_dynamic_default=1
  379:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  380:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  381: else
  382:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  383: fi
  384: 
  385: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  386: 
  387: dnl Checks for programs.
  388: AC_PROG_LN_S
  389: AC_PROG_INSTALL
  390: 
  391: dnl Checks for library functions
  392: dnl This check is just for making later checks link with libm.
  393: dnl using sin here is no good idea since it is built-into gcc and typechecked
  394: AC_CHECK_LIB(m,asin)
  395: AC_CHECK_LIB(dl,dlopen)
  396: if test "$host_os" != "nextstep3"
  397: then
  398: 	AC_FUNC_MEMCMP
  399: fi
  400: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  401: AC_FUNC_FSEEKO
  402: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  403: AC_CHECK_TYPES(stack_t)
  404: AC_DECL_SYS_SIGLIST
  405: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  406: AC_CHECK_FUNCS(expm1 log1p)
  407: AC_REPLACE_FUNCS(rint ecvt)
  408: dnl No check for select, because our replacement is no good under
  409: dnl anything but DOS
  410: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  411: AC_FUNC_FNMATCH
  412: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  413: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  414: AM_PATH_LISPDIR
  415: 
  416: kernel_fi=kernl${wordsize}${bytesex}.fi
  417: AC_SUBST(kernel_fi)
  418: 
  419: #this breaks bindists
  420: #dnl replace srource directory by absolute value
  421: #if test $srcdir = "."; then srcdir=`pwd` 
  422: #fi
  423: 
  424: AC_SUBST(machine)
  425: AC_CONFIG_FILES([
  426: Makefile
  427: Makedist
  428: gforthmi
  429: vmgen
  430: machpc.fs
  431: engine/Makefile
  432: doc/version.texi ])
  433: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  434: chmod +x gforthmi
  435: chmod +x vmgen
  436: test -d kernel||mkdir kernel]],[[]])
  437: AC_OUTPUT
  438: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>