File:  [gforth] / gforth / configure.in
Revision 1.95: download - view: text, annotated - select for diffs
Fri Dec 27 13:31:12 2002 UTC (21 years, 2 months ago) by anton
Branches: MAIN
CVS tags: HEAD
modernized configure.in (with the help of autoupdate)

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.5.9-20021227],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: #snapshots have numbers major.minor.release-YYYYMMDD
   25: #note that lexicographic ordering must be heeded.
   26: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   27: UPDATED="27 December 2002"
   28: AC_SUBST(UPDATED)
   29: AC_CONFIG_HEADERS(engine/config.h)
   30: 
   31: #default setting that may be changed later:
   32: no_dynamic_default=0
   33: 
   34: AC_ARG_ENABLE(force-reg,
   35: [  --enable-force-reg	  Use explicit register declarations if they appear in
   36: 			  the machine.h file. This can cause a good speedup,
   37: 			  but also incorrect code with some gcc versions on
   38: 			  some processors (default disabled).],
   39: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   40: 
   41: AC_ARG_WITH(debug,
   42: [  --with-debug     specifies option -g to compile with debug info (default)
   43:   --without-debug  omits the -g switch and creates smaller images on
   44:                    machines where "strip" has problems with gcc style
   45:                    debugging informations.],
   46: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   47: 
   48: PEEPHOLE="yes"
   49: AC_ARG_WITH(peephole,
   50: [  --with-peephole	Enable peephole optimization (default)
   51:   --without-peephole	disables peephole optimization. Creates smaller,
   52: 			but slower images.],
   53: PEEPHOLE="$withval")
   54: 
   55: #currently we force direct threading this way.  Eventually we should
   56: #setup in the arch and engine files right
   57: 
   58: CFLAGS=$CFLAGS
   59: 
   60: AC_PROG_CC
   61: 
   62: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   63: 
   64: AC_SUBST(CC)
   65: AC_SUBST(DEBUGFLAG)
   66: 
   67: AC_MSG_CHECKING(gcc version)
   68: gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
   69: AC_MSG_RESULT($gcc_version)
   70: if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
   71: then
   72:     no_dynamic_default=1
   73:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
   74: fi
   75: 
   76: dnl the following macro produces a warning with autoconf-2.1
   77: AC_CHECK_SIZEOF(char *)
   78: case "$ac_cv_sizeof_char_p" in
   79:   2)
   80:     wordsize=16
   81:     ;;
   82:   4)
   83:     wordsize=32
   84:     ;;
   85:   8)
   86:     wordsize=64
   87:     ;;
   88: esac
   89: 
   90: AC_CHECK_SIZEOF(char)
   91: AC_CHECK_SIZEOF(short)
   92: AC_CHECK_SIZEOF(int)
   93: AC_CHECK_SIZEOF(long)
   94: AC_CHECK_SIZEOF(long long)
   95: 
   96: AC_MSG_CHECKING([for a C type for cells])
   97: ac_cv_int_type_cell=none
   98: case "$ac_cv_sizeof_char_p" in
   99:   $ac_cv_sizeof_int)
  100:     ac_cv_int_type_cell=int
  101:     ;;
  102:   $ac_cv_sizeof_short)
  103:     ac_cv_int_type_cell=short
  104:     ;;
  105:   $ac_cv_sizeof_char)
  106:     ac_cv_int_type_cell=char
  107:     ;;
  108:   $ac_cv_sizeof_long)
  109:     ac_cv_int_type_cell=long
  110:     ;;
  111:   $ac_cv_sizeof_long_long)
  112:     ac_cv_int_type_cell="long long"
  113:     ;;
  114: esac
  115: AC_MSG_RESULT($ac_cv_int_type_cell)
  116: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  117: 
  118: AC_MSG_CHECKING([for a C type for double-cells])
  119: ac_cv_int_type_double_cell=none
  120: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  121:   $ac_cv_sizeof_short)
  122:     ac_cv_int_type_double_cell=short
  123:     ;;
  124:   $ac_cv_sizeof_int)
  125:     ac_cv_int_type_double_cell=int
  126:     ;;
  127:   $ac_cv_sizeof_long)
  128:     ac_cv_int_type_double_cell=long
  129:     ;;
  130:   $ac_cv_sizeof_long_long)
  131:     ac_cv_int_type_double_cell="long long"
  132:     ;;
  133: esac
  134: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  135: if test "$ac_cv_int_type_double_cell" = none; then
  136: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  137: 	AC_LIBOBJ(dblsub)
  138: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  139: else
  140: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  141: fi
  142: 
  143: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  144: OLDLDFLAGS=$LDFLAGS
  145: LDFLAGS="$LDFLAGS -export-dynamic"
  146: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  147: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  148: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  149: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  150: AC_MSG_RESULT($ac_export_dynamic)
  151: 
  152: #terminology is a bit unusual here: The host is the system on which
  153: #gforth will run; the system on which configure will run is the `build'
  154: AC_CANONICAL_HOST
  155: case "$host_cpu" in
  156: 	hppa*)
  157: 		machine=hppa
  158: 		$srcdir/mkinstalldirs arch/hppa
  159: 		AC_LIBOBJ(../arch/hppa/cache)
  160: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  161: 		LIBS="$LIBS -L/lib/pa1.1/"
  162: 		;;
  163: 	sparc*)
  164: 		machine=sparc
  165: 		;;
  166: 	i386)
  167: 		machine=386
  168: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  169: 		;;
  170: 	i486)
  171: 		machine=386
  172: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  173: 		;;
  174: 	i*86)
  175: 		machine=386
  176: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  177: 		CFLAGS_1="$CFLAGS"
  178: 		CFLAGS="$CFLAGS -march=pentium"
  179: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  180: 		;;
  181: 	ia64*)
  182: 		machine=ia64
  183: 		;;
  184:         m68k)
  185: 		machine=m68k
  186: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  187: 		if test "$host_os" = "nextstep3"
  188: 		then
  189: 			AC_LIBOBJ(termios)
  190: 		fi
  191: 		;;
  192: 	mips*)
  193: 		machine=mips
  194: 		#dynamic native code has the following problems on MIPS:
  195: 		#
  196: 		#1) J/JAL seems relocatable, but is are only
  197: 		#relocatable within a 256MB-segment.  While we try to
  198: 		#get the linker to arrange this, there is no guarantee
  199: 		#that this will succeed (and if the user uses a lot of
  200: 		#memory, it is likely to fail).
  201: 		#
  202: 		#2) The way we generate dynamic native code may
  203: 		#violate MIPS architectural restrictions (in
  204: 		#particular, the delay slots of LW, MFLO, etc.)
  205: 		#
  206: 		#Therefore we disable dynamic native code by default:
  207: 		no_dynamic_default=1
  208: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  209: 		#link text and data segment into the same 256M region!
  210: 		AC_MSG_CHECKING([whether the linker accepts -T])
  211: 		OLDLDFLAGS=$LDFLAGS
  212: 		LDFLAGS="$LDFLAGS -Xlinker -T -Xlinker 10000000"
  213: 		AC_TRY_LINK(,,ac_link_mips_t=yes,ac_link_mips_t=no)
  214: 		test $ac_link_mips_t = yes||LDFLAGS=$OLDLDFLAGS
  215: 		AC_MSG_RESULT($ac_link_mips_t)
  216: 		AC_MSG_CHECKING([whether the linker accepts -D])
  217: 		OLDLDFLAGS=$LDFLAGS
  218: 		LDFLAGS="$LDFLAGS -Xlinker -D -Xlinker 10400000"
  219: 		AC_TRY_LINK(,,ac_link_mips_d=yes,ac_link_mips_d=no)
  220: 		test $ac_link_mips_d = yes||LDFLAGS=$OLDLDFLAGS
  221: 		AC_MSG_RESULT($ac_link_mips_d)
  222: 		;;
  223: 	alpha*)
  224: 		machine=alpha
  225: 		#full IEEE FP support for more uniformity across platforms:
  226: 		CFLAGS="$CFLAGS -mieee"
  227: 		;;
  228: 	power*|rs6000)
  229: 		machine=power
  230: 		$srcdir/mkinstalldirs arch/power
  231: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  232: 		;;
  233: 	*)
  234: 		AC_MSG_WARN([Using a generic machine description])
  235: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  236: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  237: 		machine=generic
  238: esac
  239: AC_SUBST(host)
  240: AC_SUBST(ENGINE_FLAGS)
  241: 
  242: # Try if GCC understands -fno-cross-jump
  243: 
  244: CFLAGS_1="$CFLAGS"
  245: CFLAGS="$CFLAGS -fno-cross-jump"
  246: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  247: 
  248: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  249: AC_SUBST(asm_fs)
  250: 
  251: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  252: AC_SUBST(disasm_fs)
  253: 
  254: case "$host_os" in
  255: 	*win32)
  256: 		EXE=".exe"
  257: 		DIRSEP="\\"
  258: 		;;
  259: 	*)
  260: 		EXE=""
  261: 		DIRSEP="/"
  262: 		;;
  263: esac
  264: AC_SUBST(EXE)
  265: AC_SUBST(DIRSEP)
  266: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  267: 
  268: dnl Now a little support for DOS/DJGCC
  269: AC_SUBST(GFORTH_EXE)
  270: GFORTH_EXE=""
  271: AC_SUBST(GFORTHFAST_EXE)
  272: GFORTHFAST_EXE=""
  273: AC_SUBST(GFORTHITC_EXE)
  274: GFORTHITC_EXE=""
  275: AC_SUBST(GFORTHDITC_EXE)
  276: GFORTHDITC_EXE=""
  277: 
  278: PATHSEP=":"
  279: AC_SUBST(PATHSEP)
  280: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  281: 
  282: AC_SUBST(FORTHSIZES)
  283: 
  284: if test "$PEEPHOLE" = "yes"
  285: then
  286:    PEEPHOLEFLAG="true"
  287:    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  288: else
  289:    PEEPHOLEFLAG="false"
  290: fi
  291: AC_SUBST(PEEPHOLEFLAG)
  292: 
  293: dnl copy commands for systems that don't have links
  294: AC_SUBST(LINK_KERNL)
  295: LINK_KERNL=""
  296: 
  297: #if test $host_os=dos
  298: #then
  299: #  echo Configuring for DOS!!!
  300: #  MAKE_EXE="coff2exe gforth"
  301: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  302: #fi
  303: 
  304: dnl the following macro produces a warning with autoconf-2.1
  305: AC_C_BIGENDIAN
  306: AC_SUBST(KERNEL)
  307: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  308: if test $ac_cv_c_bigendian = yes; then
  309:   bytesex=b
  310:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  311: else
  312:   bytesex=l
  313:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  314: fi
  315: 
  316: #check how to do asm(".skip 16")
  317: AC_MSG_CHECKING([if and how we can waste code space])
  318: skipcode=no
  319: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  320: do
  321: 	AC_TRY_RUN(
  322: int foo(int);
  323: main()
  324: {
  325:   exit(foo(0)!=16);
  326: }
  327: int foo(int x)
  328: {
  329:   if (x) {
  330:   label1:
  331:     asm("$i");
  332:   label2:
  333:   }
  334:   return (&&label2)-(&&label1);
  335: }
  336: 	,skipcode=$i; break
  337: 	,,)
  338: done	
  339: AC_MSG_RESULT($skipcode)
  340: if test "$skipcode" = no
  341: then 
  342:     no_dynamic_default=1
  343:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  344:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  345: else
  346:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  347: fi
  348: 
  349: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  350: 
  351: dnl Checks for programs.
  352: AC_PROG_LN_S
  353: AC_PROG_INSTALL
  354: 
  355: dnl Checks for library functions
  356: dnl This check is just for making later checks link with libm.
  357: dnl using sin here is no good idea since it is built-into gcc and typechecked
  358: AC_CHECK_LIB(m,asin)
  359: AC_CHECK_LIB(dl,dlopen)
  360: if test "$host_os" != "nextstep3"
  361: then
  362: 	AC_FUNC_MEMCMP
  363: fi
  364: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  365: AC_CHECK_FUNCS(dlopen sys_siglist getrusage fseeko ftello)
  366: AC_TYPE_OFF_T
  367: AC_DECL_SYS_SIGLIST
  368: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  369: AC_CHECK_FUNCS(expm1 log1p)
  370: AC_REPLACE_FUNCS(rint ecvt)
  371: dnl No check for select, because our replacement is no good under
  372: dnl anything but DOS
  373: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  374: AC_FUNC_FNMATCH
  375: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  376: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  377: AM_PATH_LISPDIR
  378: 
  379: kernel_fi=kernl${wordsize}${bytesex}.fi
  380: AC_SUBST(kernel_fi)
  381: 
  382: #this breaks bindists
  383: #dnl replace srource directory by absolute value
  384: #if test $srcdir = "."; then srcdir=`pwd` 
  385: #fi
  386: 
  387: AC_SUBST(machine)
  388: AC_CONFIG_FILES([
  389: Makefile
  390: Makedist
  391: gforthmi
  392: vmgen
  393: machpc.fs
  394: engine/Makefile
  395: doc/version.texi ])
  396: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  397: chmod +x gforthmi
  398: chmod +x vmgen
  399: test -d kernel||mkdir kernel]],[[]])
  400: AC_OUTPUT
  401: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>