1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: AC_INIT(engine/engine.c)
22:
23: dnl We use some automake macros here,
24: dnl but don't use automake for creating Makefile.in
25: AM_INIT_AUTOMAKE(gforth,0.4.0-19990101)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering bust be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: AM_CONFIG_HEADER(engine/config.h)
30: AM_CYGWIN32
31:
32: AC_ARG_ENABLE(force-reg,
33: [ --enable-force-reg Use explicit register declarations if they appear in
34: the machine.h file. This can cause a good speedup,
35: but also incorrect code with some gcc versions on
36: some processors (default disabled).],
37:
38: AC_DEFINE(FORCE_REG))
39: dnl this is not quite according to the autoconf manual, it causes a replacement
40: AC_ARG_ENABLE(direct-threaded,
41: [ --enable-direct-threaded Force direct threading. This may not work on
42: some machines and may cause slowdown on others.
43: (default processor-dependent)],
44: AC_DEFINE(DIRECT_THREADED))
45: AC_ARG_ENABLE(indirect-threaded,
46: [ --enable-indirect-threaded Force indirect threading. This can cause a
47: slowdown on some machines.
48: (default processor-dependent)],
49: AC_DEFINE(INDIRECT_THREADED))
50:
51: AC_ARG_WITH(debug,
52: [ --with-debug specifies option -g to compile with debug info (default)
53: --without-debug omits the -g switch and creates smaller images on
54: machines where "strip" has problems with gcc style
55: debugging informations.],
56: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
57:
58: CFLAGS=$CFLAGS
59:
60: AC_PROG_CC
61:
62: if test "$GCC" = "yes"
63: then
64: echo "Fine, gcc is available"
65: else
66: cat <<'EOF'
67: Gforth requires GCC-2.0 or higher (it uses GNU C extensions).
68: It does not work with other C compilers. Please install the GNU C compiler,
69: and try again (or search for a binary distribution for your platform).
70: EOF
71: exit 1
72: fi
73:
74: AC_SUBST(CC)
75: AC_SUBST(DEBUGFLAG)
76:
77: dnl the following macro produces a warning with autoconf-2.1
78: AC_CHECK_SIZEOF(char *)
79: case "$ac_cv_sizeof_char_p" in
80: 2)
81: wordsize=16
82: ;;
83: 4)
84: wordsize=32
85: ;;
86: 8)
87: wordsize=64
88: ;;
89: esac
90:
91: AC_CHECK_SIZEOF(char)
92: AC_CHECK_SIZEOF(short)
93: AC_CHECK_SIZEOF(int)
94: AC_CHECK_SIZEOF(long)
95: AC_CHECK_SIZEOF(long long)
96:
97: ac_cv_int_type_cell=none
98: case "$ac_cv_sizeof_char_p" in
99: $ac_cv_sizeof_int)
100: ac_cv_int_type_cell=int
101: ;;
102: $ac_cv_sizeof_short)
103: ac_cv_int_type_cell=short
104: ;;
105: $ac_cv_sizeof_char)
106: ac_cv_int_type_cell=char
107: ;;
108: $ac_cv_sizeof_long)
109: ac_cv_int_type_cell=long
110: ;;
111: $ac_cv_sizeof_long_long)
112: ac_cv_int_type_cell="long long"
113: ;;
114: esac
115: if test "$ac_cv_int_type_cell" != int; then
116: echo "So, sizeof(pointer)!=sizeof(int); looks like a DOS C compiler to me."
117: echo "Since you don't have a proper C on this machine, that's one more reason"
118: echo "to use Forth;-)"
119: fi
120: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell)
121:
122: ac_cv_int_type_double_cell=none
123: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
124: $ac_cv_sizeof_short)
125: ac_cv_int_type_double_cell=short
126: ;;
127: $ac_cv_sizeof_int)
128: ac_cv_int_type_double_cell=int
129: ;;
130: $ac_cv_sizeof_long)
131: ac_cv_int_type_double_cell=long
132: ;;
133: $ac_cv_sizeof_long_long)
134: ac_cv_int_type_double_cell="long long"
135: ;;
136: esac
137: if test "$ac_cv_int_type_double_cell" = none; then
138: echo "Emulating double-cell arithmetic. This may be slow."
139: echo "If you find this unacceptable, ask the GCC maintainers to provide proper"
140: echo 'long longs for your machine (the GCC manual states that they \"are twice as'
141: echo "long as \`long int\'\")."
142: LIBOBJS="$LIBOBJS dblsub.o"
143: AC_DEFINE(BUGGY_LONG_LONG)
144: else
145: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell)
146: fi
147:
148: #terminology is a bit unusual here: The host is the system on which
149: #gforth will run; the system on which configure will run is the `build'
150: AC_CANONICAL_HOST
151: case "$host_cpu" in
152: hppa*)
153: machine=hppa
154: $srcdir/mkinstalldirs arch/hppa
155: LIBOBJS="$LIBOBJS ../arch/hppa/cache.o"
156: LDFLAGS="-Xlinker -N"
157: LIBS="$LIBS -L/lib/pa1.1/"
158: if test "${enable_direct_threaded+set}" = ""
159: then
160: AC_DEFINE(DIRECT_THREADED)
161: fi
162: ;;
163: sparc*)
164: machine=sparc
165: ;;
166: i386)
167: machine=386
168: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
169: if test "${enable_direct_threaded+set}" = "" \
170: -a "${enable_indirect_threaded+set}" = ""
171: then
172: echo "Using direct threaded code on 386"
173: AC_DEFINE(DIRECT_THREADED)
174: fi
175: ;;
176: i486)
177: machine=386
178: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
179: if test "${enable_direct_threaded+set}" = "" \
180: -a "${enable_indirect_threaded+set}" = ""
181: then
182: echo "Using direct threaded code on 486"
183: AC_DEFINE(DIRECT_THREADED)
184: fi
185: ;;
186: i586|i686)
187: machine=386
188: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
189: if test "${enable_direct_threaded+set}" = "" \
190: -a "${enable_indirect_threaded+set}" = ""
191: then
192: echo "Using indirect threaded code on Pentium and up"
193: AC_DEFINE(INDIRECT_THREADED)
194: fi
195: ;;
196: m68k)
197: machine=m68k
198: CFLAGS="$CFLAGS -fomit-frame-pointer"
199: if test "$host_os" = "nextstep3"
200: then
201: LIBOBJS="$LIBOBJS termios.o"
202: fi
203: ;;
204: mips*)
205: machine=mips
206: #link text and data segment into the same 256M region!
207: AC_MSG_CHECKING([whether the linker accepts -T])
208: OLDLDFLAGS=$LDFLAGS
209: LDFLAGS="$LDFLAGS -Xlinker -T -Xlinker 10000000"
210: AC_TRY_LINK(,,ac_link_mips_t=yes,ac_link_mips_t=no)
211: test $ac_link_mips_t = yes||LDFLAGS=$OLDLDFLAGS
212: AC_MSG_RESULT($ac_link_mips_t)
213: test $ac_link_mips_t = yes||(echo cannot link text and data into same 256M region, using indirect threading; AC_DEFINE(INDIRECT_THREADED))
214: AC_MSG_CHECKING([whether the linker accepts -D])
215: OLDLDFLAGS=$LDFLAGS
216: LDFLAGS="$LDFLAGS -Xlinker -D -Xlinker 10400000"
217: AC_TRY_LINK(,,ac_link_mips_d=yes,ac_link_mips_d=no)
218: test $ac_link_mips_d = yes||LDFLAGS=$OLDLDFLAGS
219: AC_MSG_RESULT($ac_link_mips_d)
220: ;;
221: alpha*)
222: machine=alpha
223: ;;
224: power*)
225: machine=power
226: $srcdir/mkinstalldirs arch/power
227: AC_CHECK_FUNC(_sync_cache_range,true,LIBOBJS="$LIBOBJS ../arch/power/_sync_cache_range.o")
228: ;;
229: *)
230: echo "No direct threading support for $host_cpu, using indirect threading."
231: echo "Using a generic machine description."
232: echo "I'll assume that C floats and doubles are represented by IEEE single and"
233: echo "double numbers. If this is not so, SF@ etc. will not work correctly."
234: echo "FLUSH-ICACHE will do nothing, so END-CODE may not work properly!"
235: machine=generic
236: esac
237: AC_SUBST(host)
238: AC_SUBST(ENGINE_FLAGS)
239:
240: case "$host_os" in
241: *win32)
242: EXE=".exe"
243: ;;
244: *)
245: EXE=""
246: ;;
247: esac
248: AC_SUBST(EXE)
249:
250: dnl Now a little support for DOS/DJGCC
251: AC_SUBST(GFORTH_EXE)
252: GFORTH_EXE=""
253: AC_SUBST(GFORTHFAST_EXE)
254: GFORTHFAST_EXE=""
255: AC_SUBST(GFORTHDITC_EXE)
256: GFORTHDITC_EXE=""
257:
258: PATHSEP=":"
259: AC_SUBST(PATHSEP)
260: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP')
261:
262: AC_SUBST(FORTHSIZES)
263:
264: dnl copy commands for systems that don't have links
265: AC_SUBST(LINK_KERNL)
266: LINK_KERNL=""
267:
268: #if test $host_os=dos
269: #then
270: # echo Configuring for DOS!!!
271: # MAKE_EXE="coff2exe gforth"
272: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
273: #fi
274:
275: dnl the following macro produces a warning with autoconf-2.1
276: AC_C_BIGENDIAN
277: AC_SUBST(KERNEL)
278: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
279: if test $ac_cv_c_bigendian = yes; then
280: bytesex=b
281: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
282: else
283: bytesex=l
284: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
285: fi
286:
287: dnl Checks for programs.
288: AC_PROG_LN_S
289: dnl AM_PROG_INSTALL #performed by AM_INIT_AUTOMAKE
290:
291: dnl Checks for library functions
292: dnl This check is just for making later checks link with libm.
293: dnl using sin here is no good idea since it is built-into gcc and typechecked
294: AC_CHECK_LIB(m,asin)
295: AC_CHECK_LIB(dl,dlopen)
296: if test "$host_os" != "nextstep3"
297: then
298: AC_FUNC_MEMCMP
299: fi
300: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
301: AC_CHECK_FUNCS(dlopen sys_siglist)
302: AC_DECL_SYS_SIGLIST
303: AC_CHECK_FUNC(getopt_long,true,LIBOBJS="$LIBOBJS getopt.o getopt1.o")
304: AC_CHECK_FUNCS(rint expm1 log1p)
305: AC_REPLACE_FUNCS(ecvt)
306: dnl No check for select, because our replacement is no good under
307: dnl anything but DOS
308: AC_CHECK_HEADERS(sys/mman.h)
309: AC_CHECK_FUNCS(mmap sysconf getpagesize)
310: AM_PATH_LISPDIR
311:
312: kernel_fi=kernl${wordsize}${bytesex}.fi
313: AC_SUBST(kernel_fi)
314:
315: AC_SUBST(machine)
316: dnl AC_LINK_FILES(arch/$machine,arch/machine) #no longer needed
317: AC_OUTPUT([
318: Makefile
319: Makedist
320: gforthmi
321: engine/Makefile
322: doc/version.texi ],
323: echo timestamp > stamp-h
324: chmod +x gforthmi
325: test -d kernel||mkdir kernel)
326:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>