1: dnl Process this file with autoconf to produce a configure script.
2: AC_INIT(engine.c)
3:
4: AC_ARG_ENABLE(force-reg,
5: [ --enable-force-reg Use explicit register declarations if they appear in
6: the machine.h file. This can cause a good speedup,
7: but also incorrect code with some gcc versions on
8: some processors (default disabled).],
9:
10: AC_DEFINE(FORCE_REG))
11: dnl this is not quite according to the autoconf manual, it causes a replacement
12: AC_ARG_ENABLE(direct-threaded,
13: [ --enable-direct-threaded Force direct threading. This may not work on
14: some machines and may cause slowdown on others.
15: (default processor-dependent)],
16: AC_DEFINE(DIRECT_THREADED))
17: AC_ARG_ENABLE(indirect-threaded,
18: [ --enable-indirect-threaded Force indirect threading. This can cause a
19: slowdown on some machines.
20: (default processor-dependent)],
21: AC_DEFINE(INDIRECT_THREADED))
22:
23: #terminology is a bit unusual here: The host is the system on which
24: #gforth will run; the system on which configure will run is the `build'
25: AC_CANONICAL_HOST
26: case "$host_cpu" in
27: hppa*)
28: mach_h=hppa
29: LIBOBJS="cache.o"
30: ;;
31: sparc*)
32: mach_h=sparc
33: ;;
34: i386|i486|i586)
35: mach_h=386
36: #!! direct/indirect threading switch
37: #!! -m486 flag
38: ;;
39: m68*)
40: mach_h=m68k
41: ;;
42: mips*)
43: mach_h=mips
44: #!! link text and data segment into the same 256M region!
45: #!! does cacheflush work on OSs other than Ultrix?
46: ;;
47: *)
48: echo "No direct threading support for $host_cpu, using indirect threading."
49: echo "Using a generic 32-bit machine description. It will only work if char * AND"
50: echo "long values have 32 bits."
51: echo "I'll assume that C floats and doubles are represented by IEEE single and"
52: echo "double numbers. If this is not so, SF@ etc. will not work correctly."
53: mach_h=32bit
54: esac
55:
56: dnl Now a little support for DOS/DJGCC
57: AC_SUBST(MAKE_EXE)
58: MAKE_EXE=""
59:
60: dnl copy commands for systems that don't have links
61: AC_SUBST(LINK_KERNL32L)
62: LINK_KERNL32L=""
63: AC_SUBST(LINK_KERNL32B)
64: LINK_KERNL32B=""
65:
66: #if test $host_os=dos
67: #then
68: # echo Configuring for DOS!!!
69: # MAKE_EXE="coff2exe gforth"
70: # LINK_KERNL32L='$(CP) kernl32l.fi gforth.fi'
71: #fi
72:
73: dnl the following macro produces a warning with autoconf-2.1
74: AC_C_BIGENDIAN
75: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
76: if test $ac_cv_c_bigendian = yes; then
77: bytesex=b
78: else
79: bytesex=l
80: fi
81:
82: dnl Checks for programs.
83: AC_PROG_LN_S
84: AC_PROG_INSTALL
85:
86: dnl Checks for library functions
87: dnl This check is just for making later checks link with libm.
88: dnl using sin here is no good idea since it is built-into gcc and typechecked
89: AC_CHECK_LIB(m,asin)
90: AC_FUNC_MEMCMP
91: AC_REPLACE_FUNCS(memmove strtoul)
92: AC_CHECK_FUNC(getopt_long,getop_long="",getopt_long="getopt.o getopt1.o")
93: AC_SUBST(getopt_long)
94: AC_CHECK_FUNCS(rint expm1 log1p)
95: AC_REPLACE_FUNCS(ecvt)
96: dnl No check for select, because our replacement is no good under
97: dnl anything but DOS
98:
99: dnl autoconf requires (implicitly) that AC_LINK_FILES is used only once
100: AC_LINK_FILES(${mach_h}.h kernl32${bytesex}.fi,machine.h gforth.fi)
101: AC_OUTPUT(Makefile)
102:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>