File:  [gforth] / gforth / configure.in
Revision 1.36: download - view: text, annotated - select for diffs
Tue Jul 28 12:29:37 1998 UTC (25 years, 7 months ago) by anton
Branches: MAIN
CVS tags: HEAD
put PPC flush-icache code into _sync_cache_range.c; configure now checks
	for this function (present on AIX).
Made FLUSH_ICACHE calls type-consistent.

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: AC_INIT(engine/engine.c)
   22: 
   23: dnl We use some automake macros here,
   24: dnl but don't use automake for creating Makefile.in
   25: AM_INIT_AUTOMAKE(gforth,0.4.0)
   26: AM_CONFIG_HEADER(engine/config.h)
   27: AM_CYGWIN32
   28: 
   29: AC_ARG_ENABLE(force-reg,
   30: [  --enable-force-reg	  Use explicit register declarations if they appear in
   31: 			  the machine.h file. This can cause a good speedup,
   32: 			  but also incorrect code with some gcc versions on
   33: 			  some processors (default disabled).],
   34: 
   35: AC_DEFINE(FORCE_REG))
   36: dnl this is not quite according to the autoconf manual, it causes a replacement
   37: AC_ARG_ENABLE(direct-threaded,
   38: [  --enable-direct-threaded	Force direct threading. This may not work on
   39: 				some machines and may cause slowdown on others.
   40: 				(default processor-dependent)],
   41: AC_DEFINE(DIRECT_THREADED))
   42: AC_ARG_ENABLE(indirect-threaded,
   43: [  --enable-indirect-threaded	Force indirect threading. This can cause a
   44: 				slowdown on some machines.
   45: 				(default processor-dependent)],
   46: AC_DEFINE(INDIRECT_THREADED))
   47: 
   48: AC_ARG_WITH(debug,
   49: [  --with-debug     specifies option -g to compile with debug info (default)
   50:   --without-debug  omits the -g switch and creates smaller images on
   51:                    machines where "strip" has problems with gcc style
   52:                    debugging informations.],
   53: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   54: 
   55: CFLAGS=$CFLAGS
   56: 
   57: AC_PROG_CC
   58: 
   59: if test "$GCC" = "yes"
   60: then
   61:    echo "Fine, gcc is available"
   62: else
   63:    cat <<'EOF'
   64: Gforth requires GCC-2.0 or higher (it uses GNU C extensions).
   65: It does not work with other C compilers. Please install the GNU C compiler,
   66: and try again (or search for a binary distribution for your platform).
   67: EOF
   68:    exit 1
   69: fi
   70: 
   71: AC_SUBST(CC)
   72: AC_SUBST(GCCLDFLAGS)
   73: AC_SUBST(DEBUGFLAG)
   74: 
   75: dnl the following macro produces a warning with autoconf-2.1
   76: AC_CHECK_SIZEOF(char *)
   77: case "$ac_cv_sizeof_char_p" in
   78:   2)
   79:     wordsize=16
   80:     ;;
   81:   4)
   82:     wordsize=32
   83:     ;;
   84:   8)
   85:     wordsize=64
   86:     ;;
   87: esac
   88: 
   89: AC_CHECK_SIZEOF(short)
   90: AC_CHECK_SIZEOF(int)
   91: AC_CHECK_SIZEOF(long)
   92: AC_CHECK_SIZEOF(long long)
   93: 
   94: ac_cv_int_type_cell=none
   95: case "$ac_cv_sizeof_char_p" in
   96:   $ac_cv_sizeof_short)
   97:     ac_cv_int_type_cell=short
   98:     ;;
   99:   $ac_cv_sizeof_int)
  100:     ac_cv_int_type_cell=int
  101:     ;;
  102:   $ac_cv_sizeof_long)
  103:     ac_cv_int_type_cell=long
  104:     ;;
  105:   $ac_cv_sizeof_long_long)
  106:     ac_cv_int_type_cell="long long"
  107:     ;;
  108: esac
  109: if test "$ac_cv_int_type_cell" != int; then
  110: 	echo "So, sizeof(pointer)!=sizeof(int); looks like a DOS C compiler to me."
  111: 	echo "Since you don't have a proper C on this machine, that's one more reason"
  112: 	echo "to use Forth;-)"
  113: fi
  114: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell)
  115: 
  116: ac_cv_int_type_double_cell=none
  117: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  118:   $ac_cv_sizeof_short)
  119:     ac_cv_int_type_double_cell=short
  120:     ;;
  121:   $ac_cv_sizeof_int)
  122:     ac_cv_int_type_double_cell=int
  123:     ;;
  124:   $ac_cv_sizeof_long)
  125:     ac_cv_int_type_double_cell=long
  126:     ;;
  127:   $ac_cv_sizeof_long_long)
  128:     ac_cv_int_type_double_cell="long long"
  129:     ;;
  130: esac
  131: if test "$ac_cv_int_type_double_cell" = none; then
  132: 	echo "Emulating double-cell arithmetic. This may be slow."
  133: 	echo "If you find this unacceptable, ask the GCC maintainers to provide proper"
  134: 	echo 'long longs for your machine (the GCC manual states that they \"are twice as'
  135: 	echo "long as \`long int\'\")."
  136: 	LIBOBJS="$LIBOBJS dblsub.o"
  137: 	AC_DEFINE(BUGGY_LONG_LONG)
  138: else
  139:   AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell)
  140: fi
  141: 
  142: #terminology is a bit unusual here: The host is the system on which
  143: #gforth will run; the system on which configure will run is the `build'
  144: AC_CANONICAL_HOST
  145: case "$host_cpu" in
  146: 	hppa*)
  147: 		machine=hppa
  148: 		LIBOBJS="$LIBOBJS cache.o"
  149: 		LDFLAGS="-Xlinker -N"
  150: 		LIBS="-L/lib/pa1.1/"
  151: 		if test "${enable_direct_threaded+set}" = ""
  152: 		then
  153: 			AC_DEFINE(DIRECT_THREADED)
  154: 		fi
  155: 		;;
  156: 	sparc*)
  157: 		machine=sparc
  158: 		;;
  159: 	i386)
  160: 		machine=386
  161: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  162: 		if test "${enable_direct_threaded+set}" = "" \
  163: 			-a "${enable_indirect_threaded+set}" = ""
  164: 		then
  165: 			echo "Using direct threaded code on 386"
  166: 			AC_DEFINE(DIRECT_THREADED)
  167: 		fi
  168: 		;;
  169: 	i486)
  170: 		machine=386
  171: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  172: 		if test "${enable_direct_threaded+set}" = "" \
  173: 			-a "${enable_indirect_threaded+set}" = ""
  174: 		then
  175: 			echo "Using direct threaded code on 486"
  176: 			AC_DEFINE(DIRECT_THREADED)
  177: 		fi
  178: 		;;
  179: 	i586|i686)
  180: 		machine=386
  181: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  182: 		if test "${enable_direct_threaded+set}" = "" \
  183: 			-a "${enable_indirect_threaded+set}" = ""
  184: 		then
  185: 			echo "Using indirect threaded code on Pentium and up"
  186: 			AC_DEFINE(INDIRECT_THREADED)
  187: 		fi
  188: 		;;
  189:         m68k)
  190: 		machine=m68k
  191: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  192: 		if test "$host_os" = "nextstep3"
  193: 		then
  194: 			LIBOBJS="$LIBOBJS termios.o"
  195: 		fi
  196: 		;;
  197: 	mips*)
  198: 		machine=mips
  199: 		#link text and data segment into the same 256M region!
  200: 		GCCLDFLAGS="-Xlinker -T -Xlinker 10000000 -Xlinker -D -Xlinker 10400000"
  201: 		;;
  202: 	alpha*)
  203: 		machine=alpha
  204: 		;;
  205: 	power*)
  206: 		machine=power
  207: 		AC_CHECK_FUNC(_sync_cache_range,true,LIBOBJS="$LIBOBJS ../arch/power/_sync_cache_range.o")
  208: 		;;
  209: 	*)
  210: 		echo "No direct threading support for $host_cpu, using indirect threading."
  211: 		echo "Using a generic machine description."
  212: 		echo "I'll assume that C floats and doubles are represented by IEEE single and"
  213: 		echo "double numbers. If this is not so, SF@ etc. will not work correctly."
  214: 		echo "FLUSH-ICACHE will do nothing, so END-CODE may not work properly!"
  215: 		machine=generic
  216: esac
  217: AC_SUBST(host)
  218: AC_SUBST(ENGINE_FLAGS)
  219: 
  220: dnl Now a little support for DOS/DJGCC
  221: AC_SUBST(GFORTH_EXE)
  222: GFORTH_EXE=""
  223: AC_SUBST(GFORTHDITC_EXE)
  224: GFORTHDITC_EXE=""
  225: 
  226: PATHSEP=":"
  227: AC_SUBST(PATHSEP)
  228: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP')
  229: 
  230: AC_SUBST(FORTHSIZES)
  231: 
  232: dnl copy commands for systems that don't have links
  233: AC_SUBST(LINK_KERNL)
  234: LINK_KERNL=""
  235: 
  236: #if test $host_os=dos
  237: #then
  238: #  echo Configuring for DOS!!!
  239: #  MAKE_EXE="coff2exe gforth"
  240: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  241: #fi
  242: 
  243: dnl the following macro produces a warning with autoconf-2.1
  244: AC_C_BIGENDIAN
  245: AC_SUBST(KERNEL)
  246: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  247: if test $ac_cv_c_bigendian = yes; then
  248:   bytesex=b
  249:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  250: else
  251:   bytesex=l
  252:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  253: fi
  254: 
  255: dnl Checks for programs.
  256: AC_PROG_LN_S
  257: dnl AM_PROG_INSTALL #performed by AM_INIT_AUTOMAKE
  258: 
  259: dnl Checks for library functions
  260: dnl This check is just for making later checks link with libm.
  261: dnl using sin here is no good idea since it is built-into gcc and typechecked
  262: AC_CHECK_LIB(m,asin)
  263: AC_CHECK_FUNCS(dlopen)
  264: AC_CHECK_LIB(dl,dlopen)
  265: AC_CHECK_LIB(kernel32,GetModuleHandle)
  266: if test "$host_os" != "nextstep3"
  267: then
  268: 	AC_FUNC_MEMCMP
  269: fi
  270: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  271: AC_CHECK_FUNCS(sys_siglist)
  272: AC_DECL_SYS_SIGLIST
  273: AC_CHECK_FUNC(getopt_long,true,LIBOBJS="$LIBOBJS getopt.o getopt1.o")
  274: AC_CHECK_FUNCS(rint expm1 log1p)
  275: AC_REPLACE_FUNCS(ecvt)
  276: dnl No check for select, because our replacement is no good under
  277: dnl anything but DOS
  278: AC_CHECK_HEADERS(sys/mman.h)
  279: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  280: AM_PATH_LISPDIR
  281: 
  282: kernel_fi=kernl${wordsize}${bytesex}.fi
  283: AC_SUBST(kernel_fi)
  284: 
  285: AC_SUBST(machine)
  286: dnl AC_LINK_FILES(arch/$machine,arch/machine) #no longer needed
  287: AC_OUTPUT([
  288: Makefile
  289: engine/Makefile
  290: doc/version.texi ],echo timestamp > stamp-h)

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>