File:  [gforth] / gforth / configure.in
Revision 1.320: download - view: text, annotated - select for diffs
Sun Oct 21 21:55:19 2012 UTC (6 years, 10 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Added project.properties, changed FPU to vfp (no v3)

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010,2011 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation, either version 3
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.7.9-20121007],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: AC_PREREQ(2.54)
   25: #snapshots have numbers major.minor.release-YYYYMMDD
   26: #note that lexicographic ordering must be heeded.
   27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   28: UPDATED="October 7, 2012"
   29: AC_SUBST(UPDATED)
   30: AC_CONFIG_HEADERS(engine/config.h)
   31: 
   32: #remnants from having ltdl as convenience library
   33: LTDLDEPS=""
   34: LTDLINCL=""
   35: LIBLTDL=""
   36: LTDL_LDLIBS=""
   37: AC_SUBST(LTDLDEPS)
   38: AC_SUBST(LTDLINCL)
   39: AC_SUBST(LIBLTDL)
   40: AC_SUBST(LTDL_LDLIBS)
   41: 
   42: #suppress the "-g -O2" default
   43: test "$CFLAGS" || CFLAGS=-O2
   44: 
   45: AC_ARG_ENABLE(force-cdiv,
   46: 	AC_HELP_STRING([--enable-force-cdiv],
   47: 		       [  Use the native C division - symmetric - instead of
   48: 		          floored division (default disabled).]),
   49: 	,enable_force_cdiv=no)
   50: test "$enable_force_cdiv" = "no"||
   51:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   52: 
   53: AC_SUBST(PROFEXES)
   54: AC_SUBST(PROFOBJS)
   55: AC_ARG_ENABLE(prof,
   56: 	AC_HELP_STRING([--enable-prof],
   57: 			[ Build gforth-prof, which outputs frequently occuring
   58:                           sequences of primitives.]),
   59: 	,enable_prof=no)
   60: if test "$enable_prof" != "no"; then
   61:   PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
   62: fi
   63: 
   64: AC_ARG_WITH(debug,
   65: [  --with-debug		  specifies option -g to compile with debug info
   66:   --without-debug	  omits the -g switch and creates smaller images on
   67: 			  machines where "strip" has problems with gcc style
   68: 			  debugging informations.],
   69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   70: 
   71: GCC_LD="\$(GCC)"
   72: EC_MODE="false"
   73: NO_EC=""
   74: NO_CROSS=""
   75: EC=""
   76: engine2='engine2$(OPT).o'
   77: engine_fast2='engine-fast2$(OPT).o'
   78: no_dynamic=""
   79: image_i=""
   80: signals_o="io.o signals.o"
   81: 
   82: AC_CANONICAL_HOST
   83: AC_ARG_WITH(ec,
   84: 	AC_HELP_STRING([--with-ec=<arch>],
   85: 			[  Build gforth for systems without OS.]),
   86: [if test "$withval" = "no"; then
   87:   echo "defining hosted system"
   88: else
   89:   echo "defining standalone system (${withval})"
   90:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
   91:   EC_MODE="true"
   92:   EC="-ec"
   93:   NO_EC="#"
   94:   NO_CROSS="#"
   95:   engine2=""
   96:   engine_fast2=""
   97:   no_dynamic="-DNO_DYNAMIC"
   98:   image_i="image.i"
   99:   if test "$withval" != "yes"; then
  100:     signals_o="io-${withval}.o"
  101:   else
  102:     signals_o="io.o"
  103:   fi
  104:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  105:     source "arch/$host_cpu/${withval}/config.sh"
  106:   fi
  107:   GCC_PATH=$(which $CC)
  108:   LIB_PATH=${GCC_PATH%/*/*}
  109:   GCC_LD="\$(LD)"
  110:   platform=${withval}
  111: fi])
  112: 
  113: AC_ARG_ENABLE(lib,
  114: 	AC_HELP_STRING([--enable-lib],
  115: 		       [  Compile Gforth as shared library (default disabled).]),
  116: 	,enable_lib=no)
  117: if test "$enable_lib" != "no"; then
  118:    AC_DEFINE(HAS_LIB,,[Define if you want to build as shared library])
  119:    libengines=libgforths
  120:    libinstall=libinstall
  121:    LIB_VERSION=0:8:0
  122: fi
  123: AC_SUBST(libengines)
  124: AC_SUBST(libinstall)
  125: AC_SUBST(LIB_VERSION)
  126: 
  127: AC_ARG_WITH(cross,
  128: 	AC_HELP_STRING([--with-cross=<arch>],
  129: 			[  Build gforth using a cross compiler.]),
  130: [if test "$withval" = "no"; then
  131:   echo "defining hosted system"
  132: else
  133:   echo "defining cross compiled system (${withval})"
  134:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  135:     source "arch/$host_cpu/${withval}/config.sh"
  136:   fi
  137:   GCC_PATH=$(which $CC)
  138:   LIB_PATH=${GCC_PATH%/*/*}
  139:   platform=${withval}
  140:   NO_EC=""
  141:   NO_CROSS="#"
  142: fi])
  143: 
  144: AC_ARG_WITH(arch,
  145: 	AC_HELP_STRING([--with-arch=<arch>],
  146: 			[  Build gforth binaries with <arch> postfix]),
  147: [if test "$withval" = "no"; then
  148:   ARCH=""
  149: else
  150:   ARCH=-${withval}
  151: fi])
  152: AC_SUBST(ARCH)
  153: 
  154: #variables mentioned in INSTALL
  155: AC_ARG_VAR(SH, [The shell])
  156: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
  157: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  158: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  159: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  160: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  161: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
  162: 
  163: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  164: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  165: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  166: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  167: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  168: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  169: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  170: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  171: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  172: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  173: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  174: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  175: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  176: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  177: AC_ARG_VAR(asmcomment, [assembler comment start string])
  178: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  179: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
  180: 
  181: #set up feature test macros, so the tests get them right:
  182: # turn on all POSIX, SUSv3, and GNU features if available
  183: AC_GNU_SOURCE
  184: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  185: 
  186: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  187: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  188: dnl but not for _XOPEN_SOURCE)
  189: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  190: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  191: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  192: # turn on large file support with 64-bit off_t where available
  193: AC_SYS_LARGEFILE
  194: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  195: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  196: 
  197: #currently we force direct threading this way.  Eventually we should
  198: #setup in the arch and engine files right
  199: 
  200: AC_PROG_CC
  201: 
  202: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  203: 
  204: test "x$SH" = "x" && SH="/bin/sh"
  205: 
  206: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  207: test x$condbranch_opt = x && 
  208: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
  209:    condbranch_opt=0
  210: else
  211:    condbranch_opt=1
  212: fi
  213: AC_MSG_RESULT($condbranch_opt)
  214: AC_SUBST(condbranch_opt)
  215: AC_SUBST(host_cpu)
  216: 
  217: AC_SUBST(SH)
  218: AC_SUBST(CC)
  219: AC_SUBST(GCC_LD)
  220: AC_SUBST(DEBUGFLAG)
  221: AC_SUBST(EC)
  222: AC_SUBST(NO_EC)
  223: AC_SUBST(NO_CROSS)
  224: AC_SUBST(EC_MODE)
  225: AC_SUBST(engine2)
  226: AC_SUBST(engine_fast2)
  227: AC_SUBST(no_dynamic)
  228: AC_SUBST(image_i)
  229: AC_SUBST(signals_o)
  230: AC_SUBST(mi_prefix)
  231: 
  232: #this is used to disable some (not generally essential) part of the
  233: #Makefile that some makes don't grok.  It would be better to test for
  234: #this specific Makefile feature than the make version.
  235: AC_MSG_CHECKING(make type)
  236: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  237: GNUMAKE='#'
  238: test "$make_type" = "GNU Make" && GNUMAKE=''
  239: AC_MSG_RESULT($make_type)
  240: AC_SUBST(GNUMAKE)
  241: 
  242: if test "$ac_export_dynamic" != yes; then
  243:   AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  244:   OLDLDFLAGS=$LDFLAGS
  245:   LDFLAGS="$LDFLAGS -export-dynamic"
  246:   dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  247:   dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  248:   AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  249:   test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  250:   AC_MSG_RESULT($ac_export_dynamic)
  251: else
  252:   LDFLAGS="$LDFLAGS -export-dynamic"
  253: fi
  254: 
  255: #terminology is a bit unusual here: The host is the system on which
  256: #gforth will run; the system on which configure will run is the `build'
  257: case "$host_cpu" in
  258: 	arm*)
  259: 		machine=arm
  260: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  261: 		if test x$platform = xnxt; then
  262: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  263: 		fi
  264: 		case "$host_os" in
  265: 		     *android*)
  266: 			CFLAGS="$CFLAGS -march=armv7-a -mfloat-abi=softfp -mfpu=vfp"
  267: 			;;
  268: 		esac
  269: 		if test -z $arm_cacheflush; then
  270: 		   case "$host_os" in
  271: 		     *linux*)
  272: 			AC_LIBOBJ(../arch/arm/cacheflush-linux) 
  273: 			;;
  274: 		     *)   
  275: 			no_dynamic_default=1
  276: 			AC_LIBOBJ(../arch/arm/cacheflush0)
  277: 			AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  278: 			;;
  279:                    esac
  280:                 else
  281:                    AC_LIBOBJ(../$arm_cacheflush)
  282:                    test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
  283: 		fi
  284:                 #longer skipcodes lead to problems on ARM, and it uses
  285:                 #only 4-byte alignment anyway
  286: 		test "$skipcode" || skipcode="nop"
  287: 		;;
  288: 	hppa*)
  289: 		machine=hppa
  290: 		AC_LIBOBJ(../arch/hppa/cache)
  291: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  292: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  293: 		LIBS="$LIBS -L/lib/pa1.1/"
  294: 		;;
  295: 	sparc*)
  296: 		machine=sparc
  297: 		;;
  298: 	i386)
  299: 		machine=386
  300: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  301: 		;;
  302: 	i486)
  303: 		machine=386
  304: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  305: 		CFLAGS_1="$CFLAGS"
  306: 		CFLAGS="$CFLAGS -march=i486"
  307: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  308: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  309: 		;;
  310: 	i*86)
  311: 		machine=386
  312: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  313: 		CFLAGS_1="$CFLAGS"
  314: 		CFLAGS="$CFLAGS -march=pentium -mtune=generic"
  315: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
  316: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  317: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  318: 		;;
  319: 	x86_64)
  320: 		case $CC
  321: 		in
  322: 		    *-m32*)
  323: 		    	machine=386
  324: 			CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  325: 			CFLAGS_1="$CFLAGS"
  326: 			CFLAGS="$CFLAGS -march=athlon64"
  327: 			;;
  328: 		    *)
  329: 		    	machine=amd64
  330: 			;;
  331: 		esac
  332: 		;;
  333: 	ia64*)
  334: 		machine=ia64
  335: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  336: 		test "$skipcode" || skipcode="nop.i 0"
  337: 		#".skip 16" passes the test below,
  338: 		# but gives an assembler error in engine
  339: 		;;
  340:         m68k)
  341: 		machine=m68k
  342: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  343: 		if test "$host_os" = "nextstep3"
  344: 		then
  345: 			AC_LIBOBJ(termios)
  346: 		fi
  347: 		;;
  348: 	mips*)
  349: 		machine=mips
  350: 		AC_LIBOBJ(../arch/mips/check_prim) 
  351: 		#dynamic native code has the following problems on MIPS:
  352: 		#
  353: 		#1) J/JAL seems relocatable, but is are only
  354: 		#relocatable within a 256MB-segment.  While we try to
  355: 		#get the linker to arrange this, there is no guarantee
  356: 		#that this will succeed (and if the user uses a lot of
  357: 		#memory, it is likely to fail).
  358: 		#
  359: 		#2) The way we generate dynamic native code may
  360: 		#violate MIPS architectural restrictions (in
  361: 		#particular, the delay slots of LW, MFLO, etc.)
  362: 		#
  363: 		#Therefore we disable dynamic native code by default:
  364: 		if test -z "$no_dynamic_default"; then
  365: 		    no_dynamic_default=1
  366: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  367: 		fi
  368: 		;;
  369: 	alpha*)
  370: 		machine=alpha
  371: 		#full IEEE FP support for more uniformity across platforms:
  372: 		CFLAGS="$CFLAGS -mieee"
  373: 		;;
  374: 	power*|rs6000)
  375: 		machine=power
  376: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  377: 		#long long is broken on (at least) gcc-2.95.* for PPC
  378: 		test x$ac_cv_sizeof_long_long = x && 
  379: 		($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
  380:                      ac_cv_sizeof_long_long=0
  381:                 #The only architecture with enough callee-saved registers
  382:                 test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
  383:                 #or use 2, hardly slower at run-time and starts up faster
  384: 
  385:                 #the skipcode that is normally selected below does not
  386:                 #work with gcc-3.[34]
  387: 		test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
  388: 		;;
  389: 	*)
  390: 		AC_MSG_WARN([Using a generic machine description])
  391: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  392: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  393: 		machine=generic
  394: 		#I-cache flushing would be needed for dynamic code generation
  395: 		if test -z $no_dynamic_default; then
  396: 		    no_dynamic_default=1
  397: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  398: 		fi
  399: esac
  400: AC_SUBST(host)
  401: 
  402: MAKEINC=""
  403: GFORTH_EXE="true"
  404: 
  405: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  406: if test x$EC_MODE = xtrue
  407: then
  408: 	echo "Check for arch/$machine/$platform/gforth.ld"
  409: 	if test -f arch/$machine/$platform/gforth.ld
  410: 	then
  411: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  412: 		if test x$platform = xnxt; then
  413: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  414: 		fi
  415: 	fi
  416: 	if test -f arch/$machine/$platform/make.inc
  417: 	then
  418: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  419: 		GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
  420: 	fi
  421: fi
  422: AC_SUBST(MAKEINC)
  423: 
  424: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  425: 
  426: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
  427: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
  428: 		   [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
  429: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  430: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  431: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  432: 
  433: test x$GCC_PR15242_WORKAROUND = x ||
  434: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  435:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  436: 
  437: dnl the following macro produces a warning with autoconf-2.1
  438: AC_CHECK_SIZEOF(char *)
  439: case "$ac_cv_sizeof_char_p" in
  440:   2)
  441:     wordsize=16
  442:     ;;
  443:   4)
  444:     wordsize=32
  445:     ;;
  446:   8)
  447:     wordsize=64
  448:     ;;
  449: esac
  450: 
  451: AC_CHECK_SIZEOF(void *)
  452: case "$ac_cv_sizeof_void_p" in
  453:   2)
  454:     vwordsize=16
  455:     ;;
  456:   4)
  457:     vwordsize=32
  458:     ;;
  459:   8)
  460:     vwordsize=64
  461:     ;;
  462: esac
  463: 
  464: AC_CHECK_SIZEOF(char)
  465: AC_CHECK_SIZEOF(short)
  466: AC_CHECK_SIZEOF(int)
  467: AC_CHECK_SIZEOF(long)
  468: AC_CHECK_SIZEOF(long long)
  469: AC_CHECK_SIZEOF(intptr_t)
  470: AC_CHECK_SIZEOF(int128_t)
  471: AC_CHECK_SIZEOF(uint128_t)
  472: 
  473: AC_MSG_CHECKING([for a C type for cells])
  474: ac_cv_int_type_cell=none
  475: case "$ac_cv_sizeof_char_p" in
  476:   $ac_cv_sizeof_int)
  477:     ac_cv_int_type_cell=int
  478:     ;;
  479:   $ac_cv_sizeof_short)
  480:     ac_cv_int_type_cell=short
  481:     ;;
  482:   $ac_cv_sizeof_char)
  483:     ac_cv_int_type_cell=char
  484:     ;;
  485:   $ac_cv_sizeof_long)
  486:     ac_cv_int_type_cell=long
  487:     ;;
  488:   $ac_cv_sizeof_long_long)
  489:     ac_cv_int_type_cell="long long"
  490:     ;;
  491:   $ac_cv_sizeof_intptr_t)
  492:     ac_cv_int_type_cell="intptr_t"
  493:     ;;
  494: esac
  495: AC_MSG_RESULT($ac_cv_int_type_cell)
  496: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  497: 
  498: AC_MSG_CHECKING([for a C type for wydes])
  499: ac_cv_wyde_type_cell=none
  500: case 2 in
  501:   $ac_cv_sizeof_int)
  502:     ac_cv_wyde_type_cell=int
  503:     ;;
  504:   $ac_cv_sizeof_short)
  505:     ac_cv_wyde_type_cell=short
  506:     ;;
  507:   $ac_cv_sizeof_char)
  508:     ac_cv_wyde_type_cell=char
  509:     ;;
  510:   $ac_cv_sizeof_long)
  511:     ac_cv_wyde_type_cell=long
  512:     ;;
  513:   $ac_cv_sizeof_long_long)
  514:     ac_cv_wyde_type_cell="long long"
  515:     ;;
  516:   $ac_cv_sizeof_intptr_t)
  517:     ac_cv_wyde_type_cell="intptr_t"
  518:     ;;
  519: esac
  520: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  521: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  522: 
  523: AC_MSG_CHECKING([for a C type for tetrabytes])
  524: ac_cv_tetrabyte_type_cell=none
  525: case 4 in
  526:   $ac_cv_sizeof_int)
  527:     ac_cv_tetrabyte_type_cell=int
  528:     ;;
  529:   $ac_cv_sizeof_short)
  530:     ac_cv_tetrabyte_type_cell=short
  531:     ;;
  532:   $ac_cv_sizeof_char)
  533:     ac_cv_tetrabyte_type_cell=char
  534:     ;;
  535:   $ac_cv_sizeof_long)
  536:     ac_cv_tetrabyte_type_cell=long
  537:     ;;
  538:   $ac_cv_sizeof_long_long)
  539:     ac_cv_tetrabyte_type_cell="long long"
  540:     ;;
  541:   $ac_cv_sizeof_intptr_t)
  542:     ac_cv_tetrabyte_type_cell="intptr_t"
  543:     ;;
  544: esac
  545: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  546: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  547: 
  548: AC_MSG_CHECKING([for a C type for octabytes])
  549: ac_cv_octabyte_type_cell=none
  550: case 8 in
  551:   $ac_cv_sizeof_int)
  552:     ac_cv_octabyte_type_cell=int
  553:     ;;
  554:   $ac_cv_sizeof_short)
  555:     ac_cv_octabyte_type_cell=short
  556:     ;;
  557:   $ac_cv_sizeof_char)
  558:     ac_cv_octabyte_type_cell=char
  559:     ;;
  560:   $ac_cv_sizeof_long)
  561:     ac_cv_octabyte_type_cell=long
  562:     ;;
  563:   $ac_cv_sizeof_long_long)
  564:     ac_cv_octabyte_type_cell="long long"
  565:     ;;
  566:   $ac_cv_sizeof_intptr_t)
  567:     ac_cv_octabyte_type_cell="intptr_t"
  568:     ;;
  569: esac
  570: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
  571: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
  572: 
  573: AC_MSG_CHECKING([for a C type for double-cells])
  574: ac_cv_int_type_double_cell=none
  575: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  576:   $ac_cv_sizeof_short)
  577:     ac_cv_int_type_double_cell=short
  578:     ;;
  579:   $ac_cv_sizeof_int)
  580:     ac_cv_int_type_double_cell=int
  581:     ;;
  582:   $ac_cv_sizeof_long)
  583:     ac_cv_int_type_double_cell=long
  584:     ;;
  585:   $ac_cv_sizeof_long_long)
  586:     ac_cv_int_type_double_cell="long long"
  587:     ;;
  588:   $ac_cv_sizeof_intptr_t)
  589:     ac_cv_int_type_double_cell="intptr_t"
  590:     ;;
  591:   $ac_cv_sizeof_int128_t)
  592:     ac_cv_int_type_double_cell="int128_t"
  593:     ;;
  594: esac
  595: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  596: 
  597: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  598: ac_cv_int_type_double_ucell=none
  599: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  600:   $ac_cv_sizeof_short)
  601:     ac_cv_int_type_double_ucell="unsigned short"
  602:     ;;
  603:   $ac_cv_sizeof_int)
  604:     ac_cv_int_type_double_ucell="unsigned int"
  605:     ;;
  606:   $ac_cv_sizeof_long)
  607:     ac_cv_int_type_double_ucell="unsigned long"
  608:     ;;
  609:   $ac_cv_sizeof_long_long)
  610:     ac_cv_int_type_double_ucell="unsigned long long"
  611:     ;;
  612:   $ac_cv_sizeof_intptr_t)
  613:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  614:     ;;
  615:   $ac_cv_sizeof_uint128_t)
  616:     ac_cv_int_type_double_ucell="uint128_t"
  617:     ;;
  618: esac
  619: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  620: 
  621: if test "$ac_cv_int_type_double_cell" != none && \
  622:    test "$ac_cv_int_type_double_ucell" != none
  623: then
  624: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  625: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  626:         OPTS=-ll
  627: else
  628:         if test "$ac_cv_sizeof_char_p" = 8; then
  629:            OPTS="-ll -noll"
  630:         else
  631:            OPTS=-noll
  632:         fi
  633: fi
  634: 
  635: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
  636:    OPTS2=''
  637:    for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
  638:    OPTS="$OPTS2 $OPTS"
  639: else
  640:   AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
  641: fi
  642: AC_SUBST(OPTS)
  643: 
  644: AC_TYPE_OFF_T
  645: AC_CHECK_SIZEOF(off_t)
  646: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  647: ac_small_off_t=$?
  648: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  649: 
  650: ENGINE_FLAGS=
  651: AC_SUBST(ENGINE_FLAGS)
  652: 
  653: # Try if GCC understands -fno-gcse
  654: 
  655: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  656: CFLAGS_1="$CFLAGS"
  657: CFLAGS="$CFLAGS -fno-gcse"
  658: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  659: CFLAGS="$CFLAGS_1"
  660: AC_MSG_RESULT($ac_nogcse)
  661: 
  662: # Try if GCC understands -fno-strict-aliasing
  663: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  664: CFLAGS_1="$CFLAGS"
  665: CFLAGS="$CFLAGS -fno-strict-aliasing"
  666: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  667: CFLAGS="$CFLAGS_1"
  668: AC_MSG_RESULT($ac_nostrictaliasing)
  669: 
  670: # Try if GCC understands -fno-crossjumping
  671: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  672: CFLAGS_1="$CFLAGS"
  673: CFLAGS="$CFLAGS -fno-crossjumping"
  674: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  675: CFLAGS="$CFLAGS_1"
  676: AC_MSG_RESULT($ac_nocrossjumping)
  677: 
  678: # Try if GCC understands -fno-reorder-blocks
  679: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  680: CFLAGS_1="$CFLAGS"
  681: CFLAGS="$CFLAGS -fno-reorder-blocks"
  682: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  683: CFLAGS="$CFLAGS_1"
  684: AC_MSG_RESULT($ac_noreorder_blocks)
  685: 
  686: # Try if GCC understands -falign-labels=1
  687: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  688: CFLAGS_1="$CFLAGS"
  689: CFLAGS="$CFLAGS -falign-labels=1"
  690: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  691: CFLAGS="$CFLAGS_1"
  692: AC_MSG_RESULT($ac_align_labels)
  693: 
  694: # Try if GCC understands -falign-loops=1
  695: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
  696: CFLAGS_1="$CFLAGS"
  697: CFLAGS="$CFLAGS -falign-loops=1"
  698: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
  699: CFLAGS="$CFLAGS_1"
  700: AC_MSG_RESULT($ac_align_loops)
  701: 
  702: # Try if GCC understands -falign-jumps=1
  703: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
  704: CFLAGS_1="$CFLAGS"
  705: CFLAGS="$CFLAGS -falign-jumps=1"
  706: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
  707: CFLAGS="$CFLAGS_1"
  708: AC_MSG_RESULT($ac_align_jumps)
  709: 
  710: if test -z "$LIBTOOL_CC"
  711: then
  712:   LIBTOOL_CC="$CC"
  713:   # Try if GCC understands -Wimplicit-function-declaration
  714:   AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
  715:   CFLAGS_1="$CFLAGS"
  716:   CFLAGS="$CFLAGS -Wimplicit-function-declaration"
  717:   AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
  718:   CFLAGS="$CFLAGS_1"
  719:   AC_MSG_RESULT($ac_align_jumps)
  720: fi
  721: AC_SUBST(LIBTOOL_CC)
  722: 
  723: 
  724: 
  725: # Try if GCC understands __attribute__((unused))
  726: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  727: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  728: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  729: AC_MSG_RESULT($MAYBE_UNUSED)
  730: 
  731: # Try if GCC understands __thread
  732: AC_CACHE_CHECK([whether gcc understands '__thread'], [ac_cv_thread],
  733:      [AC_TRY_COMPILE(,[extern __thread int foo;],
  734:                         [ac_cv_thread=yes],
  735:                         [ac_cv_thread=no])])
  736: test x$ac_cv_thread = xyes && PER_THREAD='__thread'
  737: AC_DEFINE_UNQUOTED(PER_THREAD,$PER_THREAD,[storage class for thread-local variables])
  738: 
  739: #try if m4 understands -s
  740: AC_MSG_CHECKING([how to invoke m4])
  741: if m4 -s /dev/null >/dev/null 2>&1; then
  742:  M4="m4 -s"
  743: else
  744:  M4=m4
  745: fi
  746: AC_SUBST(M4)
  747: AC_MSG_RESULT($M4)
  748: 
  749: #echo "machine='$machine'"
  750: 
  751: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  752: if test x$EC_MODE = xfalse
  753: then
  754:   AS_IF([test -f $srcdir/arch/$machine/asm.fs],
  755:         [asm_fs=arch/$machine/asm.fs])
  756: fi
  757: AC_SUBST(asm_fs)
  758: 
  759: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  760: if test x$EC_MODE = xfalse
  761: then
  762:   AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
  763:    	[disasm_fs=arch/$machine/disasm.fs])
  764: fi
  765: AC_SUBST(disasm_fs)
  766: 
  767: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  768: 
  769: case "$host_os" in
  770: 	*darwin*)
  771: 		#dar*win* must be first, not to confuse with cygwin, win32 or similar
  772: 		#Darwin uses some funny preprocessor by default; eliminate it:
  773: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  774: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  775: 		DIRSEP="/"
  776: 		PATHSEP=":"
  777: 		DEFAULTSYSTEMPREFIX=""
  778:                 #the following magic value was suggested by
  779:                 #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
  780:                 AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
  781: 		;;
  782: 	*win*)
  783: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  784: 		DIRSEP="/" # normal dirsep
  785: 		PATHSEP=":" # colon as pathsep
  786: 		#we don't want the builtins of command.com/cmd.exe and its
  787: 		# handling of .com files.
  788: 		#$COMSPEC contains the name of the Windows shell;
  789: 		# the ./ is there, because the bash does not recognize
  790: 		# absolute DOS filenames
  791: 		DEFAULTSYSTEMPREFIX="" #"./${COMSPEC//\\/\\\\\\\\} /c "
  792: 		;;
  793: 	*linux*)
  794: 		DIRSEP="/"
  795: 		PATHSEP=":"
  796: 		DEFAULTSYSTEMPREFIX=""
  797: 		if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
  798: 		   LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
  799: 		fi
  800: 		;;
  801: 	*)
  802: 		DIRSEP="/"
  803: 		PATHSEP=":"
  804: 		DEFAULTSYSTEMPREFIX=""
  805: 		;;
  806: esac
  807: AC_SUBST(DIRSEP)
  808: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  809: AC_SUBST(PATHSEP)
  810: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  811: AC_SUBST(DEFAULTSYSTEMPREFIX)
  812: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  813: if test -n "$LTDL_LIBRARY_PATH"; then
  814:    AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
  815: fi                                                                
  816: 
  817: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  818: #This magic incantation  seems to be completely undocumented.
  819: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  820: 
  821: dnl Now a little support for DOS/DJGCC
  822: GFORTHFAST_EXE="$GFORTH_EXE"
  823: GFORTHITC_EXE="$GFORTH_EXE"
  824: GFORTHDITC_EXE="$GFORTH_EXE"
  825: AC_SUBST(GFORTH_EXE)
  826: AC_SUBST(GFORTHFAST_EXE)
  827: AC_SUBST(GFORTHITC_EXE)
  828: AC_SUBST(GFORTHDITC_EXE)
  829: 
  830: AC_SUBST(FORTHSIZES)
  831: 
  832: dnl if test "$PEEPHOLE" = "yes"
  833: dnl then
  834: dnl    PEEPHOLEFLAG="true"
  835: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  836: dnl else
  837: dnl    PEEPHOLEFLAG="false"
  838: dnl fi
  839: PEEPHOLEFLAG="true"
  840: AC_SUBST(PEEPHOLEFLAG)
  841: 
  842: dnl copy commands for systems that don't have links
  843: AC_SUBST(LINK_KERNL)
  844: LINK_KERNL=""
  845: 
  846: #if test $host_os=dos
  847: #then
  848: #  echo Configuring for DOS!!!
  849: #  MAKE_EXE="coff2exe gforth"
  850: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  851: #fi
  852: 
  853: dnl the following macro produces a warning with autoconf-2.1
  854: AC_C_BIGENDIAN
  855: AC_SUBST(KERNEL)
  856: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  857: if test $ac_cv_c_bigendian != no; then
  858:   bytesex=b
  859:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  860: else
  861:   bytesex=l
  862:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  863: fi
  864: 
  865: #check how to do asm(".skip 16")
  866: #echo "CFLAGS=$CFLAGS"
  867: #echo "ac_link=$ac_link"
  868: AC_MSG_CHECKING([if and how we can waste code space])
  869: if test -z "$skipcode" && test x$cross_compiling = xyes; then
  870:    # we cannot perform the AC_TRY_RUN check when cross-compiling.  
  871:    skipcode=no
  872:    AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
  873: elif test -z "$skipcode"; then
  874:     skipcode=no
  875:     CFLAGS_1="$CFLAGS"
  876:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  877:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  878:     do
  879: 	AC_TRY_RUN(
  880: [int foo(int,int,int);
  881: main()
  882: {
  883:   exit(foo(0,0,0)!=16);
  884: }
  885: int foo(int x, int y, int z)
  886: {
  887:   static void *labels[]={&&label1, &&label2};
  888:   if (x) {
  889:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  890:   label1:
  891:     asm("$i"); /* or ".space 16" or somesuch */
  892:   label2: ;
  893:   }
  894:   {
  895:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  896:   return labels[1]-labels[0];
  897:   }
  898: }]
  899: 	,skipcode=$i; break
  900: 	,,)
  901:     done
  902:     CFLAGS=$CFLAGS_1
  903: fi
  904: AC_MSG_RESULT($skipcode)
  905: if test "$skipcode" = no
  906: then 
  907:     if test -z $no_dynamic_default; then
  908: 	no_dynamic_default=1
  909: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  910:     fi
  911:     AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
  912: else
  913:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  914: fi
  915: 
  916: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  917: #the point here is to get asm statements that look different to
  918: #gcc's "optimizer"
  919: if test -z "$asmcomment"; then
  920:     asmcomment=no
  921:     CFLAGS_1="$CFLAGS"
  922:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  923:     for i in '"# "' '"! "' '"; "'; do
  924: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  925:     done
  926:     CFLAGS=$CFLAGS_1
  927: fi
  928: AC_MSG_RESULT($asmcomment)
  929: if test "$asmcomment" != no
  930: then 
  931:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  932: fi
  933: 
  934: test "$no_dynamic_default" || no_dynamic_default=0
  935: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  936: 
  937: dnl Checks for programs.
  938: AC_PROG_LN_S
  939: AC_PROG_INSTALL
  940: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  941: 
  942: dnl check for the presence of Emacs
  943: AC_CHECK_PROGS(EMACS,emacs xemacs)
  944: test -n "$EMACS" && gforth_elc=gforth.elc
  945: AC_SUBST(gforth_elc)
  946: 
  947: dnl MacOS X has a libtool that does something else
  948: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
  949: 
  950: dnl Checks for library functions
  951: dnl This check is just for making later checks link with libm.
  952: dnl using sin here is no good idea since it is built-into gcc and typechecked
  953: AC_CHECK_LIB(m,asin)
  954: AC_CHECK_LIB(ltdl,lt_dlinit)
  955: dnl ,LIB_SUFFIX=.la,LIB_SUFFIX=.so)
  956: if test "x$ac_cv_lib_ltdl_lt_dlinit" = xyes; then
  957:   LIB_SUFFIX=.la
  958: else
  959:   LIB_SUFFIX=.so
  960: fi
  961: AC_SUBST(LIB_SUFFIX)
  962: AC_CHECK_LIB(rt,clock_gettime)
  963: 
  964: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
  965:   build_libcc_named=build-libcc-named
  966: else
  967:   AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
  968: fi
  969: AC_SUBST(build_libcc_named)
  970: 
  971: 
  972: if test -z "$GNU_LIBTOOL"; then
  973:   AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
  974:   AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
  975:   GNU_LIBTOOL=libtool
  976: fi
  977: 
  978: #check for libffi 2.x
  979: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
  980: if test -z "$FFI_H_NAME"; then
  981:   AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
  982: fi
  983: AC_SUBST(FFI_H_NAME)
  984: AC_CHECK_LIB(ffi,ffi_call,LIBS="$LIBS")
  985: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
  986: then
  987:   LIBFFIFLAG="true"
  988:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
  989: else
  990:   LIBFFIFLAG="false"
  991: fi
  992: #check for ffcall libraries
  993: #unfortunately, these four calls are separated out into a library each.
  994: AC_CHECK_LIB(avcall,__builtin_avcall,LIBS="$LIBS")
  995: dnl AC_CHECK_LIB(callback,__vacall_r)
  996: dnl AC_CHECK_LIB(vacall,vacall)
  997: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
  998: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
  999:   FFCALLFLAG="true"
 1000:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
 1001: else
 1002:   FFCALLFLAG="false"
 1003: fi
 1004: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
 1005:   AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
 1006: fi
 1007: AC_SUBST(LIBFFIFLAG)
 1008: AC_SUBST(FFCALLFLAG)
 1009: AC_SUBST(LIBCC_BUILD_SRC)
 1010: if test "$host_os" != "nextstep3"
 1011: then
 1012: 	AC_FUNC_MEMCMP
 1013: fi
 1014: AC_REPLACE_FUNCS(memmove strtoul pow10 sincos strerror strsignal atanh)
 1015: AC_FUNC_FSEEKO
 1016: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep clock_gettime)
 1017: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
 1018: AC_DECL_SYS_SIGLIST
 1019: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
 1020: AC_CHECK_FUNCS(expm1 log1p)
 1021: AC_REPLACE_FUNCS(rint ecvt)
 1022: dnl No check for select, because our replacement is no good under
 1023: dnl anything but DOS
 1024: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
 1025: AC_FUNC_FNMATCH
 1026: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
 1027: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
 1028: AM_PATH_LISPDIR
 1029: 
 1030: kernel_fi=kernl${vwordsize}${bytesex}.fi
 1031: include_fi=kernl${wordsize}${bytesex}${EC}.fi
 1032: AC_SUBST(kernel_fi)
 1033: AC_SUBST(include_fi)
 1034: 
 1035: # Find installed Gforth
 1036: AC_MSG_CHECKING([for gforth])
 1037: GFORTH="`cd / && which gforth 2>/dev/null`"
 1038: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
 1039: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null  && test "$srcdir" = ".") || GFORTH=""
 1040: if test -z "$GFORTH"; then
 1041:   PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
 1042:   GFORTHKER='echo "You need to configure with a gforth in \$PATH to build this part" && false'
 1043:   kernel_anti_dependence=''
 1044: else
 1045:   GFORTH_FI=`cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`
 1046:   PREFORTH="$GFORTH -i $GFORTH_FI" ;
 1047:   KERNLX_FI1=`echo $GFORTH_FI | sed -e s/lib[64]*/share/g -e s/gforth.fi/kernl*.fi/g`
 1048:   KERNLX_FI2=`echo $GFORTH_FI | sed -e s/gforth.fi/kernl*.fi/g`
 1049:   test -f $KERNLX_FI1 && KERNLX_FI=$KERNLX_FI1
 1050:   test -f $KERNLX_FI2 && KERNLX_FI=$KERNLX_FI2
 1051:   GFORTHKER="$GFORTH -i `echo $KERNLX_FI`" ;
 1052:   kernel_anti_dependence='$(kernel_fi)'
 1053: fi
 1054: AC_SUBST(PREFORTH)
 1055: AC_SUBST(GFORTHKER)
 1056: AC_SUBST(kernel_anti_dependence)
 1057: AC_MSG_RESULT($PREFORTH)
 1058: AC_DEFINE_UNQUOTED(KERNEL, "$kernel_fi", [The kernel to load in the image])
 1059: AC_DEFINE_UNQUOTED(ARCH, "$machine", [architecture to run on ])
 1060: 
 1061: #this breaks bindists
 1062: #dnl replace srource directory by absolute value
 1063: #if test $srcdir = "."; then srcdir=`pwd` 
 1064: #fi
 1065: 
 1066: AC_SUBST(machine)
 1067: AC_CONFIG_FILES([
 1068: Makefile
 1069: Makedist
 1070: gforthmi
 1071: gforthmi.sh
 1072: vmgen
 1073: machpc.fs
 1074: envos.fs
 1075: preforth
 1076: libforth
 1077: gforthker
 1078: engine/Makefile
 1079: engine/libcc.h
 1080: doc/version.texi
 1081: build-ec ])
 1082: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
 1083: chmod +x gforthmi
 1084: chmod +x vmgen
 1085: chmod +x build-ec
 1086: chmod +x preforth
 1087: chmod +x libforth
 1088: chmod +x gforthker
 1089: test -d kernel||mkdir kernel
 1090: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
 1091: $srcdir/mkinstalldirs include/gforth$ARCH/$PACKAGE_VERSION
 1092: $srcdir/mkinstalldirs arch/$machine
 1093: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth$ARCH/$PACKAGE_VERSION]],
 1094: [PACKAGE_VERSION=$PACKAGE_VERSION
 1095:  machine=$machine
 1096:  ARCH=$ARCH])
 1097: AC_OUTPUT

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>