1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010,2011 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.7.9-20120317],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="March 17, 2012"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #remnants from having ltdl as convenience library
33: LTDLDEPS=""
34: LTDLINCL=""
35: LIBLTDL=""
36: LTDL_LDLIBS=""
37: AC_SUBST(LTDLDEPS)
38: AC_SUBST(LTDLINCL)
39: AC_SUBST(LIBLTDL)
40: AC_SUBST(LTDL_LDLIBS)
41:
42: #suppress the "-g -O2" default
43: test "$CFLAGS" || CFLAGS=-O2
44:
45: AC_ARG_ENABLE(force-cdiv,
46: AC_HELP_STRING([--enable-force-cdiv],
47: [ Use the native C division - symmetric - instead of
48: floored division (default disabled).]),
49: ,enable_force_cdiv=no)
50: test "$enable_force_cdiv" = "no"||
51: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
52:
53: AC_SUBST(PROFEXES)
54: AC_SUBST(PROFOBJS)
55: AC_ARG_ENABLE(prof,
56: AC_HELP_STRING([--enable-prof],
57: [ Build gforth-prof, which outputs frequently occuring
58: sequences of primitives.]),
59: ,enable_prof=no)
60: if test "$enable_prof" != "no"; then
61: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
62: fi
63:
64: AC_ARG_WITH(debug,
65: [ --with-debug specifies option -g to compile with debug info
66: --without-debug omits the -g switch and creates smaller images on
67: machines where "strip" has problems with gcc style
68: debugging informations.],
69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
70:
71: GCC_LD="\$(GCC)"
72: EC_MODE="false"
73: NO_EC=""
74: NO_CROSS=""
75: EC=""
76: engine2='engine2$(OPT).o'
77: engine_fast2='engine-fast2$(OPT).o'
78: no_dynamic=""
79: image_i=""
80: signals_o="io.o signals.o"
81:
82: AC_CANONICAL_HOST
83: AC_ARG_WITH(ec,
84: AC_HELP_STRING([--with-ec=<arch>],
85: [ Build gforth for systems without OS.]),
86: [if test "$withval" = "no"; then
87: echo "defining hosted system"
88: else
89: echo "defining standalone system (${withval})"
90: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
91: EC_MODE="true"
92: EC="-ec"
93: NO_EC="#"
94: NO_CROSS="#"
95: engine2=""
96: engine_fast2=""
97: no_dynamic="-DNO_DYNAMIC"
98: image_i="image.i"
99: if test "$withval" != "yes"; then
100: signals_o="io-${withval}.o"
101: else
102: signals_o="io.o"
103: fi
104: if test -f "arch/$host_cpu/${withval}/config.sh"; then
105: source "arch/$host_cpu/${withval}/config.sh"
106: fi
107: GCC_PATH=$(which $CC)
108: LIB_PATH=${GCC_PATH%/*/*}
109: GCC_LD="\$(LD)"
110: platform=${withval}
111: fi])
112:
113: AC_ARG_WITH(cross,
114: AC_HELP_STRING([--with-cross=<arch>],
115: [ Build gforth using a cross compiler.]),
116: [if test "$withval" = "no"; then
117: echo "defining hosted system"
118: else
119: echo "defining cross compiled system (${withval})"
120: if test -f "arch/$host_cpu/${withval}/config.sh"; then
121: source "arch/$host_cpu/${withval}/config.sh"
122: fi
123: GCC_PATH=$(which $CC)
124: LIB_PATH=${GCC_PATH%/*/*}
125: platform=${withval}
126: NO_EC=""
127: NO_CROSS="#"
128: fi])
129:
130: #variables mentioned in INSTALL
131: AC_ARG_VAR(SH, [The shell])
132: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
133: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
134: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
135: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
136: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
137: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
138:
139: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
140: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
141: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
142: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
143: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
144: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
145: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
146: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
147: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
148: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
149: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
150: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
151: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
152: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
153: AC_ARG_VAR(asmcomment, [assembler comment start string])
154: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
155: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
156:
157: #set up feature test macros, so the tests get them right:
158: # turn on all POSIX, SUSv3, and GNU features if available
159: AC_GNU_SOURCE
160: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
161:
162: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
163: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
164: dnl but not for _XOPEN_SOURCE)
165: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
166: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
167: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
168: # turn on large file support with 64-bit off_t where available
169: AC_SYS_LARGEFILE
170: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
171: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
172:
173: #currently we force direct threading this way. Eventually we should
174: #setup in the arch and engine files right
175:
176: AC_PROG_CC
177:
178: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
179:
180: test "x$SH" = "x" && SH="/bin/sh"
181:
182: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
183: test x$condbranch_opt = x &&
184: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
185: condbranch_opt=0
186: else
187: condbranch_opt=1
188: fi
189: AC_MSG_RESULT($condbranch_opt)
190: AC_SUBST(condbranch_opt)
191: AC_SUBST(host_cpu)
192:
193: AC_SUBST(SH)
194: AC_SUBST(CC)
195: AC_SUBST(GCC_LD)
196: AC_SUBST(DEBUGFLAG)
197: AC_SUBST(EC)
198: AC_SUBST(NO_EC)
199: AC_SUBST(NO_CROSS)
200: AC_SUBST(EC_MODE)
201: AC_SUBST(engine2)
202: AC_SUBST(engine_fast2)
203: AC_SUBST(no_dynamic)
204: AC_SUBST(image_i)
205: AC_SUBST(signals_o)
206:
207: #this is used to disable some (not generally essential) part of the
208: #Makefile that some makes don't grok. It would be better to test for
209: #this specific Makefile feature than the make version.
210: AC_MSG_CHECKING(make type)
211: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
212: GNUMAKE='#'
213: test "$make_type" = "GNU Make" && GNUMAKE=''
214: AC_MSG_RESULT($make_type)
215: AC_SUBST(GNUMAKE)
216:
217: if test "$ac_export_dynamic" != yes; then
218: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
219: OLDLDFLAGS=$LDFLAGS
220: LDFLAGS="$LDFLAGS -export-dynamic"
221: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
222: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
223: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
224: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
225: AC_MSG_RESULT($ac_export_dynamic)
226: else
227: LDFLAGS="$LDFLAGS -export-dynamic"
228: fi
229:
230: #terminology is a bit unusual here: The host is the system on which
231: #gforth will run; the system on which configure will run is the `build'
232: case "$host_cpu" in
233: arm*)
234: machine=arm
235: CFLAGS="$CFLAGS -fomit-frame-pointer"
236: if test x$platform = xnxt; then
237: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
238: fi
239: if test -z $arm_cacheflush; then
240: case "$host_os" in
241: *linux*)
242: AC_LIBOBJ(../arch/arm/cacheflush-linux)
243: ;;
244: *)
245: no_dynamic_default=1
246: AC_LIBOBJ(../arch/arm/cacheflush0)
247: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
248: ;;
249: esac
250: else
251: AC_LIBOBJ(../$arm_cacheflush)
252: test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
253: fi
254: #longer skipcodes lead to problems on ARM, and it uses
255: #only 4-byte alignment anyway
256: test "$skipcode" || skipcode="nop"
257: ;;
258: hppa*)
259: machine=hppa
260: AC_LIBOBJ(../arch/hppa/cache)
261: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
262: LDFLAGS="$LDFLAGS -Xlinker -N"
263: LIBS="$LIBS -L/lib/pa1.1/"
264: ;;
265: sparc*)
266: machine=sparc
267: ;;
268: i386)
269: machine=386
270: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
271: ;;
272: i486)
273: machine=386
274: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
275: CFLAGS_1="$CFLAGS"
276: CFLAGS="$CFLAGS -march=i486"
277: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
278: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
279: ;;
280: i*86)
281: machine=386
282: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
283: CFLAGS_1="$CFLAGS"
284: CFLAGS="$CFLAGS -march=pentium -mtune=generic"
285: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
286: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
287: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
288: ;;
289: x86_64)
290: case $CC
291: in
292: *-m32*)
293: machine=386
294: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
295: CFLAGS_1="$CFLAGS"
296: CFLAGS="$CFLAGS -march=athlon64"
297: ;;
298: *)
299: machine=amd64
300: ;;
301: esac
302: ;;
303: ia64*)
304: machine=ia64
305: AC_LIBOBJ(../arch/ia64/flush_icache_block)
306: test "$skipcode" || skipcode="nop.i 0"
307: #".skip 16" passes the test below,
308: # but gives an assembler error in engine
309: ;;
310: m68k)
311: machine=m68k
312: CFLAGS="$CFLAGS -fomit-frame-pointer"
313: if test "$host_os" = "nextstep3"
314: then
315: AC_LIBOBJ(termios)
316: fi
317: ;;
318: mips*)
319: machine=mips
320: AC_LIBOBJ(../arch/mips/check_prim)
321: #dynamic native code has the following problems on MIPS:
322: #
323: #1) J/JAL seems relocatable, but is are only
324: #relocatable within a 256MB-segment. While we try to
325: #get the linker to arrange this, there is no guarantee
326: #that this will succeed (and if the user uses a lot of
327: #memory, it is likely to fail).
328: #
329: #2) The way we generate dynamic native code may
330: #violate MIPS architectural restrictions (in
331: #particular, the delay slots of LW, MFLO, etc.)
332: #
333: #Therefore we disable dynamic native code by default:
334: if test -z "$no_dynamic_default"; then
335: no_dynamic_default=1
336: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
337: fi
338: ;;
339: alpha*)
340: machine=alpha
341: #full IEEE FP support for more uniformity across platforms:
342: CFLAGS="$CFLAGS -mieee"
343: ;;
344: power*|rs6000)
345: machine=power
346: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
347: #long long is broken on (at least) gcc-2.95.* for PPC
348: test x$ac_cv_sizeof_long_long = x &&
349: ($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
350: ac_cv_sizeof_long_long=0
351: #The only architecture with enough callee-saved registers
352: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
353: #or use 2, hardly slower at run-time and starts up faster
354:
355: #the skipcode that is normally selected below does not
356: #work with gcc-3.[34]
357: test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
358: ;;
359: *)
360: AC_MSG_WARN([Using a generic machine description])
361: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
362: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
363: machine=generic
364: #I-cache flushing would be needed for dynamic code generation
365: if test -z $no_dynamic_default; then
366: no_dynamic_default=1
367: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
368: fi
369: esac
370: AC_SUBST(host)
371:
372: MAKEINC=""
373: GFORTH_EXE="true"
374:
375: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
376: if test x$EC_MODE = xtrue
377: then
378: echo "Check for arch/$machine/$platform/gforth.ld"
379: if test -f arch/$machine/$platform/gforth.ld
380: then
381: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
382: if test x$platform = xnxt; then
383: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
384: fi
385: fi
386: if test -f arch/$machine/$platform/make.inc
387: then
388: MAKEINC="include ../arch/$machine/$platform/make.inc"
389: GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
390: fi
391: fi
392: AC_SUBST(MAKEINC)
393:
394: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
395:
396: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
397: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
398: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
399: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
400: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
401: [number of registers in the default stack cache state for gforth-fast and gforth-native])
402:
403: test x$GCC_PR15242_WORKAROUND = x ||
404: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
405: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
406:
407: dnl the following macro produces a warning with autoconf-2.1
408: AC_CHECK_SIZEOF(char *)
409: case "$ac_cv_sizeof_char_p" in
410: 2)
411: wordsize=16
412: ;;
413: 4)
414: wordsize=32
415: ;;
416: 8)
417: wordsize=64
418: ;;
419: esac
420:
421: AC_CHECK_SIZEOF(void *)
422: case "$ac_cv_sizeof_void_p" in
423: 2)
424: vwordsize=16
425: ;;
426: 4)
427: vwordsize=32
428: ;;
429: 8)
430: vwordsize=64
431: ;;
432: esac
433:
434: AC_CHECK_SIZEOF(char)
435: AC_CHECK_SIZEOF(short)
436: AC_CHECK_SIZEOF(int)
437: AC_CHECK_SIZEOF(long)
438: AC_CHECK_SIZEOF(long long)
439: AC_CHECK_SIZEOF(intptr_t)
440: AC_CHECK_SIZEOF(int128_t)
441: AC_CHECK_SIZEOF(uint128_t)
442:
443: AC_MSG_CHECKING([for a C type for cells])
444: ac_cv_int_type_cell=none
445: case "$ac_cv_sizeof_char_p" in
446: $ac_cv_sizeof_int)
447: ac_cv_int_type_cell=int
448: ;;
449: $ac_cv_sizeof_short)
450: ac_cv_int_type_cell=short
451: ;;
452: $ac_cv_sizeof_char)
453: ac_cv_int_type_cell=char
454: ;;
455: $ac_cv_sizeof_long)
456: ac_cv_int_type_cell=long
457: ;;
458: $ac_cv_sizeof_long_long)
459: ac_cv_int_type_cell="long long"
460: ;;
461: $ac_cv_sizeof_intptr_t)
462: ac_cv_int_type_cell="intptr_t"
463: ;;
464: esac
465: AC_MSG_RESULT($ac_cv_int_type_cell)
466: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
467:
468: AC_MSG_CHECKING([for a C type for wydes])
469: ac_cv_wyde_type_cell=none
470: case 2 in
471: $ac_cv_sizeof_int)
472: ac_cv_wyde_type_cell=int
473: ;;
474: $ac_cv_sizeof_short)
475: ac_cv_wyde_type_cell=short
476: ;;
477: $ac_cv_sizeof_char)
478: ac_cv_wyde_type_cell=char
479: ;;
480: $ac_cv_sizeof_long)
481: ac_cv_wyde_type_cell=long
482: ;;
483: $ac_cv_sizeof_long_long)
484: ac_cv_wyde_type_cell="long long"
485: ;;
486: $ac_cv_sizeof_intptr_t)
487: ac_cv_wyde_type_cell="intptr_t"
488: ;;
489: esac
490: AC_MSG_RESULT($ac_cv_wyde_type_cell)
491: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
492:
493: AC_MSG_CHECKING([for a C type for tetrabytes])
494: ac_cv_tetrabyte_type_cell=none
495: case 4 in
496: $ac_cv_sizeof_int)
497: ac_cv_tetrabyte_type_cell=int
498: ;;
499: $ac_cv_sizeof_short)
500: ac_cv_tetrabyte_type_cell=short
501: ;;
502: $ac_cv_sizeof_char)
503: ac_cv_tetrabyte_type_cell=char
504: ;;
505: $ac_cv_sizeof_long)
506: ac_cv_tetrabyte_type_cell=long
507: ;;
508: $ac_cv_sizeof_long_long)
509: ac_cv_tetrabyte_type_cell="long long"
510: ;;
511: $ac_cv_sizeof_intptr_t)
512: ac_cv_tetrabyte_type_cell="intptr_t"
513: ;;
514: esac
515: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
516: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
517:
518: AC_MSG_CHECKING([for a C type for octabytes])
519: ac_cv_octabyte_type_cell=none
520: case 8 in
521: $ac_cv_sizeof_int)
522: ac_cv_octabyte_type_cell=int
523: ;;
524: $ac_cv_sizeof_short)
525: ac_cv_octabyte_type_cell=short
526: ;;
527: $ac_cv_sizeof_char)
528: ac_cv_octabyte_type_cell=char
529: ;;
530: $ac_cv_sizeof_long)
531: ac_cv_octabyte_type_cell=long
532: ;;
533: $ac_cv_sizeof_long_long)
534: ac_cv_octabyte_type_cell="long long"
535: ;;
536: $ac_cv_sizeof_intptr_t)
537: ac_cv_octabyte_type_cell="intptr_t"
538: ;;
539: esac
540: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
541: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
542:
543: AC_MSG_CHECKING([for a C type for double-cells])
544: ac_cv_int_type_double_cell=none
545: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
546: $ac_cv_sizeof_short)
547: ac_cv_int_type_double_cell=short
548: ;;
549: $ac_cv_sizeof_int)
550: ac_cv_int_type_double_cell=int
551: ;;
552: $ac_cv_sizeof_long)
553: ac_cv_int_type_double_cell=long
554: ;;
555: $ac_cv_sizeof_long_long)
556: ac_cv_int_type_double_cell="long long"
557: ;;
558: $ac_cv_sizeof_intptr_t)
559: ac_cv_int_type_double_cell="intptr_t"
560: ;;
561: $ac_cv_sizeof_int128_t)
562: ac_cv_int_type_double_cell="int128_t"
563: ;;
564: esac
565: AC_MSG_RESULT($ac_cv_int_type_double_cell)
566:
567: AC_MSG_CHECKING([for a C type for unsigned double-cells])
568: ac_cv_int_type_double_ucell=none
569: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
570: $ac_cv_sizeof_short)
571: ac_cv_int_type_double_ucell="unsigned short"
572: ;;
573: $ac_cv_sizeof_int)
574: ac_cv_int_type_double_ucell="unsigned int"
575: ;;
576: $ac_cv_sizeof_long)
577: ac_cv_int_type_double_ucell="unsigned long"
578: ;;
579: $ac_cv_sizeof_long_long)
580: ac_cv_int_type_double_ucell="unsigned long long"
581: ;;
582: $ac_cv_sizeof_intptr_t)
583: ac_cv_int_type_double_ucell="unsigned intptr_t"
584: ;;
585: $ac_cv_sizeof_uint128_t)
586: ac_cv_int_type_double_ucell="uint128_t"
587: ;;
588: esac
589: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
590:
591: if test "$ac_cv_int_type_double_cell" != none && \
592: test "$ac_cv_int_type_double_ucell" != none
593: then
594: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
595: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
596: OPTS=-ll
597: else
598: if test "$ac_cv_sizeof_char_p" = 8; then
599: OPTS="-ll -noll"
600: else
601: OPTS=-noll
602: fi
603: fi
604:
605: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
606: OPTS2=''
607: for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
608: OPTS="$OPTS2 $OPTS"
609: else
610: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
611: fi
612: AC_SUBST(OPTS)
613:
614: AC_TYPE_OFF_T
615: AC_CHECK_SIZEOF(off_t)
616: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
617: ac_small_off_t=$?
618: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
619:
620: ENGINE_FLAGS=
621: AC_SUBST(ENGINE_FLAGS)
622:
623: # Try if GCC understands -fno-gcse
624:
625: AC_MSG_CHECKING([if $CC understands -fno-gcse])
626: CFLAGS_1="$CFLAGS"
627: CFLAGS="$CFLAGS -fno-gcse"
628: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
629: CFLAGS="$CFLAGS_1"
630: AC_MSG_RESULT($ac_nogcse)
631:
632: # Try if GCC understands -fno-strict-aliasing
633: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
634: CFLAGS_1="$CFLAGS"
635: CFLAGS="$CFLAGS -fno-strict-aliasing"
636: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
637: CFLAGS="$CFLAGS_1"
638: AC_MSG_RESULT($ac_nostrictaliasing)
639:
640: # Try if GCC understands -fno-crossjumping
641: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
642: CFLAGS_1="$CFLAGS"
643: CFLAGS="$CFLAGS -fno-crossjumping"
644: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
645: CFLAGS="$CFLAGS_1"
646: AC_MSG_RESULT($ac_nocrossjumping)
647:
648: # Try if GCC understands -fno-reorder-blocks
649: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
650: CFLAGS_1="$CFLAGS"
651: CFLAGS="$CFLAGS -fno-reorder-blocks"
652: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
653: CFLAGS="$CFLAGS_1"
654: AC_MSG_RESULT($ac_noreorder_blocks)
655:
656: # Try if GCC understands -falign-labels=1
657: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
658: CFLAGS_1="$CFLAGS"
659: CFLAGS="$CFLAGS -falign-labels=1"
660: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
661: CFLAGS="$CFLAGS_1"
662: AC_MSG_RESULT($ac_align_labels)
663:
664: # Try if GCC understands -falign-loops=1
665: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
666: CFLAGS_1="$CFLAGS"
667: CFLAGS="$CFLAGS -falign-loops=1"
668: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
669: CFLAGS="$CFLAGS_1"
670: AC_MSG_RESULT($ac_align_loops)
671:
672: # Try if GCC understands -falign-jumps=1
673: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
674: CFLAGS_1="$CFLAGS"
675: CFLAGS="$CFLAGS -falign-jumps=1"
676: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
677: CFLAGS="$CFLAGS_1"
678: AC_MSG_RESULT($ac_align_jumps)
679:
680: if test -z "$LIBTOOL_CC"
681: then
682: LIBTOOL_CC="$CC"
683: # Try if GCC understands -Wimplicit-function-declaration
684: AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
685: CFLAGS_1="$CFLAGS"
686: CFLAGS="$CFLAGS -Wimplicit-function-declaration"
687: AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
688: CFLAGS="$CFLAGS_1"
689: AC_MSG_RESULT($ac_align_jumps)
690: fi
691: AC_SUBST(LIBTOOL_CC)
692:
693:
694:
695: # Try if GCC understands __attribute__((unused))
696: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
697: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
698: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
699: AC_MSG_RESULT($MAYBE_UNUSED)
700:
701: # Try if GCC understands __thread
702: AC_MSG_CHECKING([whether gcc understands '__thread'])
703: AC_TRY_COMPILE(,[extern __thread int foo;],PER_THREAD='__thread',)
704: AC_DEFINE_UNQUOTED(PER_THREAD,$PER_THREAD,[storage class for thread-local variables])
705: AC_MSG_RESULT($PER_THREAD)
706:
707: #try if m4 understands -s
708: AC_MSG_CHECKING([how to invoke m4])
709: if m4 -s /dev/null >/dev/null 2>&1; then
710: M4="m4 -s"
711: else
712: M4=m4
713: fi
714: AC_SUBST(M4)
715: AC_MSG_RESULT($M4)
716:
717: #echo "machine='$machine'"
718:
719: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
720: if test x$EC_MODE = xfalse
721: then
722: AS_IF([test -f $srcdir/arch/$machine/asm.fs],
723: [asm_fs=arch/$machine/asm.fs])
724: fi
725: AC_SUBST(asm_fs)
726:
727: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
728: if test x$EC_MODE = xfalse
729: then
730: AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
731: [disasm_fs=arch/$machine/disasm.fs])
732: fi
733: AC_SUBST(disasm_fs)
734:
735: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
736:
737: case "$host_os" in
738: *win32*)
739: # !!!FIXME!!! problems with cygwin and ';' as path separator
740: DIRSEP="\\\\"
741: PATHSEP=";"
742: #we want the builtins of command.com/cmd.exe and its
743: # handling of .com files.
744: #$COMSPEC contains the name of the Windows shell;
745: # the ./ is there, because the bash does not recognize
746: # absolute DOS filenames
747: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
748: ;;
749: *darwin*)
750: #Darwin uses some funny preprocessor by default; eliminate it:
751: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
752: CFLAGS="$CFLAGS -no-cpp-precomp"
753: DIRSEP="/"
754: PATHSEP=":"
755: DEFAULTSYSTEMPREFIX=""
756: #the following magic value was suggested by
757: #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
758: AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
759: ;;
760: *linux*)
761: DIRSEP="/"
762: PATHSEP=":"
763: DEFAULTSYSTEMPREFIX=""
764: if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
765: LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
766: fi
767: ;;
768: *)
769: DIRSEP="/"
770: PATHSEP=":"
771: DEFAULTSYSTEMPREFIX=""
772: ;;
773: esac
774: AC_SUBST(DIRSEP)
775: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
776: AC_SUBST(PATHSEP)
777: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
778: AC_SUBST(DEFAULTSYSTEMPREFIX)
779: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
780: if test -n "$LTDL_LIBRARY_PATH"; then
781: AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
782: fi
783:
784: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
785: #This magic incantation seems to be completely undocumented.
786: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
787:
788: dnl Now a little support for DOS/DJGCC
789: GFORTHFAST_EXE="$GFORTH_EXE"
790: GFORTHITC_EXE="$GFORTH_EXE"
791: GFORTHDITC_EXE="$GFORTH_EXE"
792: AC_SUBST(GFORTH_EXE)
793: AC_SUBST(GFORTHFAST_EXE)
794: AC_SUBST(GFORTHITC_EXE)
795: AC_SUBST(GFORTHDITC_EXE)
796:
797: AC_SUBST(FORTHSIZES)
798:
799: dnl if test "$PEEPHOLE" = "yes"
800: dnl then
801: dnl PEEPHOLEFLAG="true"
802: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
803: dnl else
804: dnl PEEPHOLEFLAG="false"
805: dnl fi
806: PEEPHOLEFLAG="true"
807: AC_SUBST(PEEPHOLEFLAG)
808:
809: dnl copy commands for systems that don't have links
810: AC_SUBST(LINK_KERNL)
811: LINK_KERNL=""
812:
813: #if test $host_os=dos
814: #then
815: # echo Configuring for DOS!!!
816: # MAKE_EXE="coff2exe gforth"
817: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
818: #fi
819:
820: dnl the following macro produces a warning with autoconf-2.1
821: AC_C_BIGENDIAN
822: AC_SUBST(KERNEL)
823: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
824: if test $ac_cv_c_bigendian != no; then
825: bytesex=b
826: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
827: else
828: bytesex=l
829: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
830: fi
831:
832: #check how to do asm(".skip 16")
833: #echo "CFLAGS=$CFLAGS"
834: #echo "ac_link=$ac_link"
835: AC_MSG_CHECKING([if and how we can waste code space])
836: if test -z "$skipcode" && test x$cross_compiling = xyes; then
837: # we cannot perform the AC_TRY_RUN check when cross-compiling.
838: skipcode=no
839: AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
840: elif test -z "$skipcode"; then
841: skipcode=no
842: CFLAGS_1="$CFLAGS"
843: CFLAGS="$CFLAGS $ENGINE_FLAGS"
844: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
845: do
846: AC_TRY_RUN(
847: [int foo(int,int,int);
848: main()
849: {
850: exit(foo(0,0,0)!=16);
851: }
852: int foo(int x, int y, int z)
853: {
854: static void *labels[]={&&label1, &&label2};
855: if (x) {
856: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
857: label1:
858: asm("$i"); /* or ".space 16" or somesuch */
859: label2: ;
860: }
861: {
862: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
863: return labels[1]-labels[0];
864: }
865: }]
866: ,skipcode=$i; break
867: ,,)
868: done
869: CFLAGS=$CFLAGS_1
870: fi
871: AC_MSG_RESULT($skipcode)
872: if test "$skipcode" = no
873: then
874: if test -z $no_dynamic_default; then
875: no_dynamic_default=1
876: AC_MSG_WARN(Disabling default dynamic native code generation)
877: fi
878: AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
879: else
880: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
881: fi
882:
883: AC_MSG_CHECKING([if and how we can do comments in asm statements])
884: #the point here is to get asm statements that look different to
885: #gcc's "optimizer"
886: if test -z "$asmcomment"; then
887: asmcomment=no
888: CFLAGS_1="$CFLAGS"
889: CFLAGS="$CFLAGS $ENGINE_FLAGS"
890: for i in '"# "' '"! "' '"; "'; do
891: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
892: done
893: CFLAGS=$CFLAGS_1
894: fi
895: AC_MSG_RESULT($asmcomment)
896: if test "$asmcomment" != no
897: then
898: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
899: fi
900:
901: test "$no_dynamic_default" || no_dynamic_default=0
902: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
903:
904: dnl Checks for programs.
905: AC_PROG_LN_S
906: AC_PROG_INSTALL
907: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
908:
909: dnl check for the presence of Emacs
910: AC_CHECK_PROGS(EMACS,emacs xemacs)
911: test -n "$EMACS" && gforth_elc=gforth.elc
912: AC_SUBST(gforth_elc)
913:
914: dnl MacOS X has a libtool that does something else
915: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
916:
917: dnl Checks for library functions
918: dnl This check is just for making later checks link with libm.
919: dnl using sin here is no good idea since it is built-into gcc and typechecked
920: AC_CHECK_LIB(m,asin)
921: AC_CHECK_LIB(ltdl,lt_dlinit,LIB_SUFFIX=.la,LIB_SUFFIX=.so)
922: AC_SUBST(LIB_SUFFIX)
923: AC_CHECK_LIB(rt,clock_gettime)
924:
925: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
926: build_libcc_named=build-libcc-named
927: else
928: build_libcc_named=""
929: AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
930: fi
931: AC_SUBST(build_libcc_named)
932:
933:
934: if test -z "$GNU_LIBTOOL"; then
935: AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
936: AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
937: GNU_LIBTOOL=libtool
938: fi
939:
940: #check for libffi 2.x
941: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
942: if test -z "$FFI_H_NAME"; then
943: AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
944: fi
945: AC_SUBST(FFI_H_NAME)
946: AC_CHECK_LIB(ffi,ffi_call,LIBS="$LIBS")
947: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
948: then
949: LIBFFIFLAG="true"
950: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
951: else
952: LIBFFIFLAG="false"
953: fi
954: #check for ffcall libraries
955: #unfortunately, these four calls are separated out into a library each.
956: AC_CHECK_LIB(avcall,__builtin_avcall,LIBS="$LIBS")
957: dnl AC_CHECK_LIB(callback,__vacall_r)
958: dnl AC_CHECK_LIB(vacall,vacall)
959: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
960: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
961: FFCALLFLAG="true"
962: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
963: else
964: FFCALLFLAG="false"
965: fi
966: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
967: AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
968: fi
969: AC_SUBST(LIBFFIFLAG)
970: AC_SUBST(FFCALLFLAG)
971: AC_SUBST(LIBCC_BUILD_SRC)
972: if test "$host_os" != "nextstep3"
973: then
974: AC_FUNC_MEMCMP
975: fi
976: AC_REPLACE_FUNCS(memmove strtoul pow10 sincos strerror strsignal atanh)
977: AC_FUNC_FSEEKO
978: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep clock_gettime)
979: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
980: AC_DECL_SYS_SIGLIST
981: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
982: AC_CHECK_FUNCS(expm1 log1p)
983: AC_REPLACE_FUNCS(rint ecvt)
984: dnl No check for select, because our replacement is no good under
985: dnl anything but DOS
986: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
987: AC_FUNC_FNMATCH
988: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
989: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
990: AM_PATH_LISPDIR
991:
992: kernel_fi=kernl${vwordsize}${bytesex}.fi
993: include_fi=kernl${wordsize}${bytesex}${EC}.fi
994: AC_SUBST(kernel_fi)
995: AC_SUBST(include_fi)
996:
997: # Find installed Gforth
998: AC_MSG_CHECKING([for gforth])
999: GFORTH="`cd / && which gforth 2>/dev/null`"
1000: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
1001: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null && test "$srcdir" = ".") || GFORTH=""
1002: if test -z "$GFORTH"; then
1003: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
1004: GFORTHKER='echo "You need to configure with a gforth in \$PATH to build this part" && false'
1005: kernel_anti_dependence=''
1006: else
1007: GFORTH_FI=`cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`
1008: PREFORTH="$GFORTH -i $GFORTH_FI" ;
1009: KERNLX_FI1=`echo $GFORTH_FI | sed -e s/lib/share/g -e s/gforth.fi/kernl*.fi/g`
1010: KERNLX_FI2=`echo $GFORTH_FI | sed -e s/gforth.fi/kernl*.fi/g`
1011: test -f $KERNLX_FI1 && KERNLX_FI=$KERNLX_FI1
1012: test -f $KERNLX_FI2 && KERNLX_FI=$KERNLX_FI2
1013: GFORTHKER="$GFORTH -i `echo $KERNLX_FI`" ;
1014: kernel_anti_dependence='$(kernel_fi)'
1015: fi
1016: AC_SUBST(PREFORTH)
1017: AC_SUBST(GFORTHKER)
1018: AC_SUBST(kernel_anti_dependence)
1019: AC_MSG_RESULT($PREFORTH)
1020:
1021: #this breaks bindists
1022: #dnl replace srource directory by absolute value
1023: #if test $srcdir = "."; then srcdir=`pwd`
1024: #fi
1025:
1026: AC_SUBST(machine)
1027: AC_CONFIG_FILES([
1028: Makefile
1029: Makedist
1030: gforthmi
1031: vmgen
1032: machpc.fs
1033: envos.fs
1034: preforth
1035: libforth
1036: gforthker
1037: engine/Makefile
1038: engine/libcc.h
1039: doc/version.texi
1040: build-ec ])
1041: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
1042: chmod +x gforthmi
1043: chmod +x vmgen
1044: chmod +x build-ec
1045: chmod +x preforth
1046: chmod +x libforth
1047: chmod +x gforthker
1048: test -d kernel||mkdir kernel
1049: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
1050: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
1051: $srcdir/mkinstalldirs arch/$machine
1052: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],
1053: [PACKAGE_VERSION=$PACKAGE_VERSION
1054: machine=$machine])
1055: AC_OUTPUT
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>