1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010,2011 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.7.9-20120317],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="March 17, 2012"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #remnants from having ltdl as convenience library
33: LTDLDEPS=""
34: LTDLINCL=""
35: LIBLTDL=""
36: LTDL_LDLIBS=""
37: AC_SUBST(LTDLDEPS)
38: AC_SUBST(LTDLINCL)
39: AC_SUBST(LIBLTDL)
40: AC_SUBST(LTDL_LDLIBS)
41:
42: #suppress the "-g -O2" default
43: test "$CFLAGS" || CFLAGS=-O2
44:
45: AC_ARG_ENABLE(force-cdiv,
46: AC_HELP_STRING([--enable-force-cdiv],
47: [ Use the native C division - symmetric - instead of
48: floored division (default disabled).]),
49: ,enable_force_cdiv=no)
50: test "$enable_force_cdiv" = "no"||
51: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
52:
53: AC_SUBST(PROFEXES)
54: AC_SUBST(PROFOBJS)
55: AC_ARG_ENABLE(prof,
56: AC_HELP_STRING([--enable-prof],
57: [ Build gforth-prof, which outputs frequently occuring
58: sequences of primitives.]),
59: ,enable_prof=no)
60: if test "$enable_prof" != "no"; then
61: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
62: fi
63:
64: AC_ARG_WITH(debug,
65: [ --with-debug specifies option -g to compile with debug info
66: --without-debug omits the -g switch and creates smaller images on
67: machines where "strip" has problems with gcc style
68: debugging informations.],
69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
70:
71: GCC_LD="\$(GCC)"
72: EC_MODE="false"
73: NO_EC=""
74: NO_CROSS=""
75: EC=""
76: engine2='engine2$(OPT).o'
77: engine_fast2='engine-fast2$(OPT).o'
78: no_dynamic=""
79: image_i=""
80: signals_o="io.o signals.o"
81:
82: AC_CANONICAL_HOST
83: AC_ARG_WITH(ec,
84: AC_HELP_STRING([--with-ec=<arch>],
85: [ Build gforth for systems without OS.]),
86: [if test "$withval" = "no"; then
87: echo "defining hosted system"
88: else
89: echo "defining standalone system (${withval})"
90: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
91: EC_MODE="true"
92: EC="-ec"
93: NO_EC="#"
94: NO_CROSS="#"
95: engine2=""
96: engine_fast2=""
97: no_dynamic="-DNO_DYNAMIC"
98: image_i="image.i"
99: if test "$withval" != "yes"; then
100: signals_o="io-${withval}.o"
101: else
102: signals_o="io.o"
103: fi
104: if test -f "arch/$host_cpu/${withval}/config.sh"; then
105: source "arch/$host_cpu/${withval}/config.sh"
106: fi
107: GCC_PATH=$(which $CC)
108: LIB_PATH=${GCC_PATH%/*/*}
109: GCC_LD="\$(LD)"
110: platform=${withval}
111: fi])
112:
113: AC_ARG_WITH(cross,
114: AC_HELP_STRING([--with-cross=<arch>],
115: [ Build gforth using a cross compiler.]),
116: [if test "$withval" = "no"; then
117: echo "defining hosted system"
118: else
119: echo "defining cross compiled system (${withval})"
120: if test -f "arch/$host_cpu/${withval}/config.sh"; then
121: source "arch/$host_cpu/${withval}/config.sh"
122: fi
123: GCC_PATH=$(which $CC)
124: LIB_PATH=${GCC_PATH%/*/*}
125: platform=${withval}
126: NO_EC=""
127: NO_CROSS="#"
128: fi])
129:
130: #variables mentioned in INSTALL
131: AC_ARG_VAR(SH, [The shell])
132: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
133: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
134: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
135: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
136: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
137: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
138:
139: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
140: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
141: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
142: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
143: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
144: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
145: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
146: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
147: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
148: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
149: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
150: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
151: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
152: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
153: AC_ARG_VAR(asmcomment, [assembler comment start string])
154: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
155: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
156:
157: #set up feature test macros, so the tests get them right:
158: # turn on all POSIX, SUSv3, and GNU features if available
159: AC_GNU_SOURCE
160: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
161:
162: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
163: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
164: dnl but not for _XOPEN_SOURCE)
165: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
166: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
167: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
168: # turn on large file support with 64-bit off_t where available
169: AC_SYS_LARGEFILE
170: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
171: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
172:
173: #currently we force direct threading this way. Eventually we should
174: #setup in the arch and engine files right
175:
176: AC_PROG_CC
177:
178: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
179:
180: test "x$SH" = "x" && SH="/bin/sh"
181:
182: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
183: test x$condbranch_opt = x &&
184: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
185: condbranch_opt=0
186: else
187: condbranch_opt=1
188: fi
189: AC_MSG_RESULT($condbranch_opt)
190: AC_SUBST(condbranch_opt)
191: AC_SUBST(host_cpu)
192:
193: AC_SUBST(SH)
194: AC_SUBST(CC)
195: AC_SUBST(GCC_LD)
196: AC_SUBST(DEBUGFLAG)
197: AC_SUBST(EC)
198: AC_SUBST(NO_EC)
199: AC_SUBST(NO_CROSS)
200: AC_SUBST(EC_MODE)
201: AC_SUBST(engine2)
202: AC_SUBST(engine_fast2)
203: AC_SUBST(no_dynamic)
204: AC_SUBST(image_i)
205: AC_SUBST(signals_o)
206:
207: #this is used to disable some (not generally essential) part of the
208: #Makefile that some makes don't grok. It would be better to test for
209: #this specific Makefile feature than the make version.
210: AC_MSG_CHECKING(make type)
211: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
212: GNUMAKE='#'
213: test "$make_type" = "GNU Make" && GNUMAKE=''
214: AC_MSG_RESULT($make_type)
215: AC_SUBST(GNUMAKE)
216:
217: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
218: OLDLDFLAGS=$LDFLAGS
219: LDFLAGS="$LDFLAGS -export-dynamic"
220: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
221: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
222: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
223: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
224: AC_MSG_RESULT($ac_export_dynamic)
225:
226: #terminology is a bit unusual here: The host is the system on which
227: #gforth will run; the system on which configure will run is the `build'
228: case "$host_cpu" in
229: arm*)
230: machine=arm
231: CFLAGS="$CFLAGS -fomit-frame-pointer"
232: if test x$platform = xnxt; then
233: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
234: fi
235: if test -z $arm_cacheflush; then
236: case "$host_os" in
237: *linux*)
238: AC_LIBOBJ(../arch/arm/cacheflush-linux)
239: ;;
240: *)
241: no_dynamic_default=1
242: AC_LIBOBJ(../arch/arm/cacheflush0)
243: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
244: ;;
245: esac
246: else
247: AC_LIBOBJ(../$arm_cacheflush)
248: test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
249: fi
250: #longer skipcodes lead to problems on ARM, and it uses
251: #only 4-byte alignment anyway
252: test "$skipcode" || skipcode="nop"
253: ;;
254: hppa*)
255: machine=hppa
256: AC_LIBOBJ(../arch/hppa/cache)
257: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
258: LDFLAGS="$LDFLAGS -Xlinker -N"
259: LIBS="$LIBS -L/lib/pa1.1/"
260: ;;
261: sparc*)
262: machine=sparc
263: ;;
264: i386)
265: machine=386
266: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
267: ;;
268: i486)
269: machine=386
270: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
271: CFLAGS_1="$CFLAGS"
272: CFLAGS="$CFLAGS -march=i486"
273: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
274: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
275: ;;
276: i*86)
277: machine=386
278: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
279: CFLAGS_1="$CFLAGS"
280: CFLAGS="$CFLAGS -march=pentium -mtune=generic"
281: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
282: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
283: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
284: ;;
285: x86_64)
286: case $CC
287: in
288: *-m32*)
289: machine=386
290: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
291: CFLAGS_1="$CFLAGS"
292: CFLAGS="$CFLAGS -march=athlon64"
293: ;;
294: *)
295: machine=amd64
296: ;;
297: esac
298: ;;
299: ia64*)
300: machine=ia64
301: AC_LIBOBJ(../arch/ia64/flush_icache_block)
302: test "$skipcode" || skipcode="nop.i 0"
303: #".skip 16" passes the test below,
304: # but gives an assembler error in engine
305: ;;
306: m68k)
307: machine=m68k
308: CFLAGS="$CFLAGS -fomit-frame-pointer"
309: if test "$host_os" = "nextstep3"
310: then
311: AC_LIBOBJ(termios)
312: fi
313: ;;
314: mips*)
315: machine=mips
316: AC_LIBOBJ(../arch/mips/check_prim)
317: #dynamic native code has the following problems on MIPS:
318: #
319: #1) J/JAL seems relocatable, but is are only
320: #relocatable within a 256MB-segment. While we try to
321: #get the linker to arrange this, there is no guarantee
322: #that this will succeed (and if the user uses a lot of
323: #memory, it is likely to fail).
324: #
325: #2) The way we generate dynamic native code may
326: #violate MIPS architectural restrictions (in
327: #particular, the delay slots of LW, MFLO, etc.)
328: #
329: #Therefore we disable dynamic native code by default:
330: if test -z "$no_dynamic_default"; then
331: no_dynamic_default=1
332: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
333: fi
334: ;;
335: alpha*)
336: machine=alpha
337: #full IEEE FP support for more uniformity across platforms:
338: CFLAGS="$CFLAGS -mieee"
339: ;;
340: power*|rs6000)
341: machine=power
342: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
343: #long long is broken on (at least) gcc-2.95.* for PPC
344: test x$ac_cv_sizeof_long_long = x &&
345: ($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
346: ac_cv_sizeof_long_long=0
347: #The only architecture with enough callee-saved registers
348: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
349: #or use 2, hardly slower at run-time and starts up faster
350:
351: #the skipcode that is normally selected below does not
352: #work with gcc-3.[34]
353: test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
354: ;;
355: *)
356: AC_MSG_WARN([Using a generic machine description])
357: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
358: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
359: machine=generic
360: #I-cache flushing would be needed for dynamic code generation
361: if test -z $no_dynamic_default; then
362: no_dynamic_default=1
363: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
364: fi
365: esac
366: AC_SUBST(host)
367:
368: MAKEINC=""
369: GFORTH_EXE="true"
370:
371: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
372: if test x$EC_MODE = xtrue
373: then
374: echo "Check for arch/$machine/$platform/gforth.ld"
375: if test -f arch/$machine/$platform/gforth.ld
376: then
377: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
378: if test x$platform = xnxt; then
379: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
380: fi
381: fi
382: if test -f arch/$machine/$platform/make.inc
383: then
384: MAKEINC="include ../arch/$machine/$platform/make.inc"
385: GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
386: fi
387: fi
388: AC_SUBST(MAKEINC)
389:
390: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
391:
392: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
393: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
394: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
395: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
396: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
397: [number of registers in the default stack cache state for gforth-fast and gforth-native])
398:
399: test x$GCC_PR15242_WORKAROUND = x ||
400: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
401: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
402:
403: dnl the following macro produces a warning with autoconf-2.1
404: AC_CHECK_SIZEOF(char *)
405: case "$ac_cv_sizeof_char_p" in
406: 2)
407: wordsize=16
408: ;;
409: 4)
410: wordsize=32
411: ;;
412: 8)
413: wordsize=64
414: ;;
415: esac
416:
417: AC_CHECK_SIZEOF(void *)
418: case "$ac_cv_sizeof_void_p" in
419: 2)
420: vwordsize=16
421: ;;
422: 4)
423: vwordsize=32
424: ;;
425: 8)
426: vwordsize=64
427: ;;
428: esac
429:
430: AC_CHECK_SIZEOF(char)
431: AC_CHECK_SIZEOF(short)
432: AC_CHECK_SIZEOF(int)
433: AC_CHECK_SIZEOF(long)
434: AC_CHECK_SIZEOF(long long)
435: AC_CHECK_SIZEOF(intptr_t)
436: AC_CHECK_SIZEOF(int128_t)
437: AC_CHECK_SIZEOF(uint128_t)
438:
439: AC_MSG_CHECKING([for a C type for cells])
440: ac_cv_int_type_cell=none
441: case "$ac_cv_sizeof_char_p" in
442: $ac_cv_sizeof_int)
443: ac_cv_int_type_cell=int
444: ;;
445: $ac_cv_sizeof_short)
446: ac_cv_int_type_cell=short
447: ;;
448: $ac_cv_sizeof_char)
449: ac_cv_int_type_cell=char
450: ;;
451: $ac_cv_sizeof_long)
452: ac_cv_int_type_cell=long
453: ;;
454: $ac_cv_sizeof_long_long)
455: ac_cv_int_type_cell="long long"
456: ;;
457: $ac_cv_sizeof_intptr_t)
458: ac_cv_int_type_cell="intptr_t"
459: ;;
460: esac
461: AC_MSG_RESULT($ac_cv_int_type_cell)
462: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
463:
464: AC_MSG_CHECKING([for a C type for wydes])
465: ac_cv_wyde_type_cell=none
466: case 2 in
467: $ac_cv_sizeof_int)
468: ac_cv_wyde_type_cell=int
469: ;;
470: $ac_cv_sizeof_short)
471: ac_cv_wyde_type_cell=short
472: ;;
473: $ac_cv_sizeof_char)
474: ac_cv_wyde_type_cell=char
475: ;;
476: $ac_cv_sizeof_long)
477: ac_cv_wyde_type_cell=long
478: ;;
479: $ac_cv_sizeof_long_long)
480: ac_cv_wyde_type_cell="long long"
481: ;;
482: $ac_cv_sizeof_intptr_t)
483: ac_cv_wyde_type_cell="intptr_t"
484: ;;
485: esac
486: AC_MSG_RESULT($ac_cv_wyde_type_cell)
487: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
488:
489: AC_MSG_CHECKING([for a C type for tetrabytes])
490: ac_cv_tetrabyte_type_cell=none
491: case 4 in
492: $ac_cv_sizeof_int)
493: ac_cv_tetrabyte_type_cell=int
494: ;;
495: $ac_cv_sizeof_short)
496: ac_cv_tetrabyte_type_cell=short
497: ;;
498: $ac_cv_sizeof_char)
499: ac_cv_tetrabyte_type_cell=char
500: ;;
501: $ac_cv_sizeof_long)
502: ac_cv_tetrabyte_type_cell=long
503: ;;
504: $ac_cv_sizeof_long_long)
505: ac_cv_tetrabyte_type_cell="long long"
506: ;;
507: $ac_cv_sizeof_intptr_t)
508: ac_cv_tetrabyte_type_cell="intptr_t"
509: ;;
510: esac
511: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
512: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
513:
514: AC_MSG_CHECKING([for a C type for octabytes])
515: ac_cv_octabyte_type_cell=none
516: case 8 in
517: $ac_cv_sizeof_int)
518: ac_cv_octabyte_type_cell=int
519: ;;
520: $ac_cv_sizeof_short)
521: ac_cv_octabyte_type_cell=short
522: ;;
523: $ac_cv_sizeof_char)
524: ac_cv_octabyte_type_cell=char
525: ;;
526: $ac_cv_sizeof_long)
527: ac_cv_octabyte_type_cell=long
528: ;;
529: $ac_cv_sizeof_long_long)
530: ac_cv_octabyte_type_cell="long long"
531: ;;
532: $ac_cv_sizeof_intptr_t)
533: ac_cv_octabyte_type_cell="intptr_t"
534: ;;
535: esac
536: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
537: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
538:
539: AC_MSG_CHECKING([for a C type for double-cells])
540: ac_cv_int_type_double_cell=none
541: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
542: $ac_cv_sizeof_short)
543: ac_cv_int_type_double_cell=short
544: ;;
545: $ac_cv_sizeof_int)
546: ac_cv_int_type_double_cell=int
547: ;;
548: $ac_cv_sizeof_long)
549: ac_cv_int_type_double_cell=long
550: ;;
551: $ac_cv_sizeof_long_long)
552: ac_cv_int_type_double_cell="long long"
553: ;;
554: $ac_cv_sizeof_intptr_t)
555: ac_cv_int_type_double_cell="intptr_t"
556: ;;
557: $ac_cv_sizeof_int128_t)
558: ac_cv_int_type_double_cell="int128_t"
559: ;;
560: esac
561: AC_MSG_RESULT($ac_cv_int_type_double_cell)
562:
563: AC_MSG_CHECKING([for a C type for unsigned double-cells])
564: ac_cv_int_type_double_ucell=none
565: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
566: $ac_cv_sizeof_short)
567: ac_cv_int_type_double_ucell="unsigned short"
568: ;;
569: $ac_cv_sizeof_int)
570: ac_cv_int_type_double_ucell="unsigned int"
571: ;;
572: $ac_cv_sizeof_long)
573: ac_cv_int_type_double_ucell="unsigned long"
574: ;;
575: $ac_cv_sizeof_long_long)
576: ac_cv_int_type_double_ucell="unsigned long long"
577: ;;
578: $ac_cv_sizeof_intptr_t)
579: ac_cv_int_type_double_ucell="unsigned intptr_t"
580: ;;
581: $ac_cv_sizeof_uint128_t)
582: ac_cv_int_type_double_ucell="uint128_t"
583: ;;
584: esac
585: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
586:
587: if test "$ac_cv_int_type_double_cell" != none && \
588: test "$ac_cv_int_type_double_ucell" != none
589: then
590: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
591: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
592: OPTS=-ll
593: else
594: if test "$ac_cv_sizeof_char_p" = 8; then
595: OPTS="-ll -noll"
596: else
597: OPTS=-noll
598: fi
599: fi
600:
601: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
602: OPTS2=''
603: for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
604: OPTS="$OPTS2 $OPTS"
605: else
606: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
607: fi
608: AC_SUBST(OPTS)
609:
610: AC_TYPE_OFF_T
611: AC_CHECK_SIZEOF(off_t)
612: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
613: ac_small_off_t=$?
614: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
615:
616: ENGINE_FLAGS=
617: AC_SUBST(ENGINE_FLAGS)
618:
619: # Try if GCC understands -fno-gcse
620:
621: AC_MSG_CHECKING([if $CC understands -fno-gcse])
622: CFLAGS_1="$CFLAGS"
623: CFLAGS="$CFLAGS -fno-gcse"
624: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
625: CFLAGS="$CFLAGS_1"
626: AC_MSG_RESULT($ac_nogcse)
627:
628: # Try if GCC understands -fno-strict-aliasing
629: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
630: CFLAGS_1="$CFLAGS"
631: CFLAGS="$CFLAGS -fno-strict-aliasing"
632: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
633: CFLAGS="$CFLAGS_1"
634: AC_MSG_RESULT($ac_nostrictaliasing)
635:
636: # Try if GCC understands -fno-crossjumping
637: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
638: CFLAGS_1="$CFLAGS"
639: CFLAGS="$CFLAGS -fno-crossjumping"
640: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
641: CFLAGS="$CFLAGS_1"
642: AC_MSG_RESULT($ac_nocrossjumping)
643:
644: # Try if GCC understands -fno-reorder-blocks
645: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
646: CFLAGS_1="$CFLAGS"
647: CFLAGS="$CFLAGS -fno-reorder-blocks"
648: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
649: CFLAGS="$CFLAGS_1"
650: AC_MSG_RESULT($ac_noreorder_blocks)
651:
652: # Try if GCC understands -falign-labels=1
653: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
654: CFLAGS_1="$CFLAGS"
655: CFLAGS="$CFLAGS -falign-labels=1"
656: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
657: CFLAGS="$CFLAGS_1"
658: AC_MSG_RESULT($ac_align_labels)
659:
660: # Try if GCC understands -falign-loops=1
661: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
662: CFLAGS_1="$CFLAGS"
663: CFLAGS="$CFLAGS -falign-loops=1"
664: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
665: CFLAGS="$CFLAGS_1"
666: AC_MSG_RESULT($ac_align_loops)
667:
668: # Try if GCC understands -falign-jumps=1
669: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
670: CFLAGS_1="$CFLAGS"
671: CFLAGS="$CFLAGS -falign-jumps=1"
672: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
673: CFLAGS="$CFLAGS_1"
674: AC_MSG_RESULT($ac_align_jumps)
675:
676: if test -z "$LIBTOOL_CC"
677: then
678: LIBTOOL_CC="$CC"
679: # Try if GCC understands -Wimplicit-function-declaration
680: AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
681: CFLAGS_1="$CFLAGS"
682: CFLAGS="$CFLAGS -Wimplicit-function-declaration"
683: AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
684: CFLAGS="$CFLAGS_1"
685: AC_MSG_RESULT($ac_align_jumps)
686: fi
687: AC_SUBST(LIBTOOL_CC)
688:
689:
690:
691: # Try if GCC understands __attribute__((unused))
692: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
693: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
694: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
695: AC_MSG_RESULT($MAYBE_UNUSED)
696:
697: # Try if GCC understands __thread
698: AC_MSG_CHECKING([whether gcc understands '__thread'])
699: AC_TRY_COMPILE(,[extern __thread int foo;],PER_THREAD='__thread',)
700: AC_DEFINE_UNQUOTED(PER_THREAD,$PER_THREAD,[storage class for thread-local variables])
701: AC_MSG_RESULT($PER_THREAD)
702:
703: #try if m4 understands -s
704: AC_MSG_CHECKING([how to invoke m4])
705: if m4 -s /dev/null >/dev/null 2>&1; then
706: M4="m4 -s"
707: else
708: M4=m4
709: fi
710: AC_SUBST(M4)
711: AC_MSG_RESULT($M4)
712:
713: #echo "machine='$machine'"
714:
715: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
716: if test x$EC_MODE = xfalse
717: then
718: AS_IF([test -f $srcdir/arch/$machine/asm.fs],
719: [asm_fs=arch/$machine/asm.fs])
720: fi
721: AC_SUBST(asm_fs)
722:
723: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
724: if test x$EC_MODE = xfalse
725: then
726: AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
727: [disasm_fs=arch/$machine/disasm.fs])
728: fi
729: AC_SUBST(disasm_fs)
730:
731: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
732:
733: case "$host_os" in
734: *win32*)
735: # !!!FIXME!!! problems with cygwin and ';' as path separator
736: DIRSEP="\\\\"
737: PATHSEP=";"
738: #we want the builtins of command.com/cmd.exe and its
739: # handling of .com files.
740: #$COMSPEC contains the name of the Windows shell;
741: # the ./ is there, because the bash does not recognize
742: # absolute DOS filenames
743: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
744: ;;
745: *darwin*)
746: #Darwin uses some funny preprocessor by default; eliminate it:
747: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
748: CFLAGS="$CFLAGS -no-cpp-precomp"
749: DIRSEP="/"
750: PATHSEP=":"
751: DEFAULTSYSTEMPREFIX=""
752: #the following magic value was suggested by
753: #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
754: AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
755: ;;
756: *linux*)
757: DIRSEP="/"
758: PATHSEP=":"
759: DEFAULTSYSTEMPREFIX=""
760: if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
761: LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
762: fi
763: ;;
764: *)
765: DIRSEP="/"
766: PATHSEP=":"
767: DEFAULTSYSTEMPREFIX=""
768: ;;
769: esac
770: AC_SUBST(DIRSEP)
771: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
772: AC_SUBST(PATHSEP)
773: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
774: AC_SUBST(DEFAULTSYSTEMPREFIX)
775: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
776: if test -n "$LTDL_LIBRARY_PATH"; then
777: AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
778: fi
779:
780: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
781: #This magic incantation seems to be completely undocumented.
782: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
783:
784: dnl Now a little support for DOS/DJGCC
785: GFORTHFAST_EXE="$GFORTH_EXE"
786: GFORTHITC_EXE="$GFORTH_EXE"
787: GFORTHDITC_EXE="$GFORTH_EXE"
788: AC_SUBST(GFORTH_EXE)
789: AC_SUBST(GFORTHFAST_EXE)
790: AC_SUBST(GFORTHITC_EXE)
791: AC_SUBST(GFORTHDITC_EXE)
792:
793: AC_SUBST(FORTHSIZES)
794:
795: dnl if test "$PEEPHOLE" = "yes"
796: dnl then
797: dnl PEEPHOLEFLAG="true"
798: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
799: dnl else
800: dnl PEEPHOLEFLAG="false"
801: dnl fi
802: PEEPHOLEFLAG="true"
803: AC_SUBST(PEEPHOLEFLAG)
804:
805: dnl copy commands for systems that don't have links
806: AC_SUBST(LINK_KERNL)
807: LINK_KERNL=""
808:
809: #if test $host_os=dos
810: #then
811: # echo Configuring for DOS!!!
812: # MAKE_EXE="coff2exe gforth"
813: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
814: #fi
815:
816: dnl the following macro produces a warning with autoconf-2.1
817: AC_C_BIGENDIAN
818: AC_SUBST(KERNEL)
819: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
820: if test $ac_cv_c_bigendian != no; then
821: bytesex=b
822: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
823: else
824: bytesex=l
825: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
826: fi
827:
828: #check how to do asm(".skip 16")
829: #echo "CFLAGS=$CFLAGS"
830: #echo "ac_link=$ac_link"
831: AC_MSG_CHECKING([if and how we can waste code space])
832: if test -z "$skipcode" && test x$cross_compiling = xyes; then
833: # we cannot perform the AC_TRY_RUN check when cross-compiling.
834: skipcode=no
835: AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
836: elif test -z "$skipcode"; then
837: skipcode=no
838: CFLAGS_1="$CFLAGS"
839: CFLAGS="$CFLAGS $ENGINE_FLAGS"
840: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
841: do
842: AC_TRY_RUN(
843: [int foo(int,int,int);
844: main()
845: {
846: exit(foo(0,0,0)!=16);
847: }
848: int foo(int x, int y, int z)
849: {
850: static void *labels[]={&&label1, &&label2};
851: if (x) {
852: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
853: label1:
854: asm("$i"); /* or ".space 16" or somesuch */
855: label2: ;
856: }
857: {
858: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
859: return labels[1]-labels[0];
860: }
861: }]
862: ,skipcode=$i; break
863: ,,)
864: done
865: CFLAGS=$CFLAGS_1
866: fi
867: AC_MSG_RESULT($skipcode)
868: if test "$skipcode" = no
869: then
870: if test -z $no_dynamic_default; then
871: no_dynamic_default=1
872: AC_MSG_WARN(Disabling default dynamic native code generation)
873: fi
874: AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
875: else
876: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
877: fi
878:
879: AC_MSG_CHECKING([if and how we can do comments in asm statements])
880: #the point here is to get asm statements that look different to
881: #gcc's "optimizer"
882: if test -z "$asmcomment"; then
883: asmcomment=no
884: CFLAGS_1="$CFLAGS"
885: CFLAGS="$CFLAGS $ENGINE_FLAGS"
886: for i in '"# "' '"! "' '"; "'; do
887: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
888: done
889: CFLAGS=$CFLAGS_1
890: fi
891: AC_MSG_RESULT($asmcomment)
892: if test "$asmcomment" != no
893: then
894: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
895: fi
896:
897: test "$no_dynamic_default" || no_dynamic_default=0
898: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
899:
900: dnl Checks for programs.
901: AC_PROG_LN_S
902: AC_PROG_INSTALL
903: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
904:
905: dnl check for the presence of Emacs
906: AC_CHECK_PROGS(EMACS,emacs xemacs)
907: test -n "$EMACS" && gforth_elc=gforth.elc
908: AC_SUBST(gforth_elc)
909:
910: dnl MacOS X has a libtool that does something else
911: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
912:
913: dnl Checks for library functions
914: dnl This check is just for making later checks link with libm.
915: dnl using sin here is no good idea since it is built-into gcc and typechecked
916: AC_CHECK_LIB(m,asin)
917: AC_CHECK_LIB(ltdl,lt_dlinit)
918: AC_CHECK_LIB(rt,clock_gettime)
919:
920: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
921: build_libcc_named=build-libcc-named
922: else
923: build_libcc_named=""
924: AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
925: fi
926: AC_SUBST(build_libcc_named)
927:
928:
929: if test -z "$GNU_LIBTOOL"; then
930: AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
931: AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
932: GNU_LIBTOOL=libtool
933: fi
934:
935: #check for libffi 2.x
936: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
937: if test -z "$FFI_H_NAME"; then
938: AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
939: fi
940: AC_SUBST(FFI_H_NAME)
941: AC_CHECK_LIB(ffi,ffi_call,LIBS="$LIBS")
942: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
943: then
944: LIBFFIFLAG="true"
945: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
946: else
947: LIBFFIFLAG="false"
948: fi
949: #check for ffcall libraries
950: #unfortunately, these four calls are separated out into a library each.
951: AC_CHECK_LIB(avcall,__builtin_avcall,LIBS="$LIBS")
952: dnl AC_CHECK_LIB(callback,__vacall_r)
953: dnl AC_CHECK_LIB(vacall,vacall)
954: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
955: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
956: FFCALLFLAG="true"
957: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
958: else
959: FFCALLFLAG="false"
960: fi
961: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
962: AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
963: fi
964: AC_SUBST(LIBFFIFLAG)
965: AC_SUBST(FFCALLFLAG)
966: AC_SUBST(LIBCC_BUILD_SRC)
967: if test "$host_os" != "nextstep3"
968: then
969: AC_FUNC_MEMCMP
970: fi
971: AC_REPLACE_FUNCS(memmove strtoul pow10 sincos strerror strsignal atanh)
972: AC_FUNC_FSEEKO
973: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep clock_gettime)
974: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
975: AC_DECL_SYS_SIGLIST
976: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
977: AC_CHECK_FUNCS(expm1 log1p)
978: AC_REPLACE_FUNCS(rint ecvt)
979: dnl No check for select, because our replacement is no good under
980: dnl anything but DOS
981: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
982: AC_FUNC_FNMATCH
983: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
984: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
985: AM_PATH_LISPDIR
986:
987: kernel_fi=kernl${vwordsize}${bytesex}.fi
988: include_fi=kernl${wordsize}${bytesex}${EC}.fi
989: AC_SUBST(kernel_fi)
990: AC_SUBST(include_fi)
991:
992: # Find installed Gforth
993: AC_MSG_CHECKING([for gforth])
994: GFORTH="`cd / && which gforth 2>/dev/null`"
995: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
996: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null && test "$srcdir" = ".") || GFORTH=""
997: if test -z "$GFORTH"; then
998: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
999: GFORTHKER='echo "You need to configure with a gforth in \$PATH to build this part" && false'
1000: kernel_anti_dependence=''
1001: else
1002: GFORTH_FI=`cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`
1003: PREFORTH="$GFORTH -i $GFORTH_FI" ;
1004: KERNLX_FI1=`echo $GFORTH_FI | sed -e s/lib/share/g -e s/gforth.fi/kernl*.fi/g`
1005: KERNLX_FI2=`echo $GFORTH_FI | sed -e s/gforth.fi/kernl*.fi/g`
1006: test -f $KERNLX_FI1 && KERNLX_FI=$KERNLX_FI1
1007: test -f $KERNLX_FI2 && KERNLX_FI=$KERNLX_FI2
1008: GFORTHKER="$GFORTH -i `echo $KERNLX_FI`" ;
1009: kernel_anti_dependence='$(kernel_fi)'
1010: fi
1011: AC_SUBST(PREFORTH)
1012: AC_SUBST(GFORTHKER)
1013: AC_SUBST(kernel_anti_dependence)
1014: AC_MSG_RESULT($PREFORTH)
1015:
1016: #this breaks bindists
1017: #dnl replace srource directory by absolute value
1018: #if test $srcdir = "."; then srcdir=`pwd`
1019: #fi
1020:
1021: AC_SUBST(machine)
1022: AC_CONFIG_FILES([
1023: Makefile
1024: Makedist
1025: gforthmi
1026: vmgen
1027: machpc.fs
1028: envos.fs
1029: preforth
1030: libforth
1031: gforthker
1032: engine/Makefile
1033: engine/libcc.h
1034: doc/version.texi
1035: build-ec ])
1036: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
1037: chmod +x gforthmi
1038: chmod +x vmgen
1039: chmod +x build-ec
1040: chmod +x preforth
1041: chmod +x libforth
1042: chmod +x gforthker
1043: test -d kernel||mkdir kernel
1044: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
1045: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
1046: $srcdir/mkinstalldirs arch/$machine
1047: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],
1048: [PACKAGE_VERSION=$PACKAGE_VERSION
1049: machine=$machine])
1050: AC_OUTPUT
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>