File:  [gforth] / gforth / configure.in
Revision 1.301: download - view: text, annotated - select for diffs
Mon Mar 19 21:51:38 2012 UTC (12 years ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Debian distribution creation

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010,2011 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation, either version 3
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.7.9-20120317],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: AC_PREREQ(2.54)
   25: #snapshots have numbers major.minor.release-YYYYMMDD
   26: #note that lexicographic ordering must be heeded.
   27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   28: UPDATED="March 17, 2012"
   29: AC_SUBST(UPDATED)
   30: AC_CONFIG_HEADERS(engine/config.h)
   31: 
   32: #remnants from having ltdl as convenience library
   33: LTDLDEPS=""
   34: LTDLINCL=""
   35: LIBLTDL=""
   36: LTDL_LDLIBS=""
   37: AC_SUBST(LTDLDEPS)
   38: AC_SUBST(LTDLINCL)
   39: AC_SUBST(LIBLTDL)
   40: AC_SUBST(LTDL_LDLIBS)
   41: 
   42: #suppress the "-g -O2" default
   43: test "$CFLAGS" || CFLAGS=-O2
   44: 
   45: AC_ARG_ENABLE(force-cdiv,
   46: 	AC_HELP_STRING([--enable-force-cdiv],
   47: 		       [  Use the native C division - symmetric - instead of
   48: 		          floored division (default disabled).]),
   49: 	,enable_force_cdiv=no)
   50: test "$enable_force_cdiv" = "no"||
   51:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   52: 
   53: AC_SUBST(PROFEXES)
   54: AC_SUBST(PROFOBJS)
   55: AC_ARG_ENABLE(prof,
   56: 	AC_HELP_STRING([--enable-prof],
   57: 			[ Build gforth-prof, which outputs frequently occuring
   58:                           sequences of primitives.]),
   59: 	,enable_prof=no)
   60: if test "$enable_prof" != "no"; then
   61:   PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
   62: fi
   63: 
   64: AC_ARG_WITH(debug,
   65: [  --with-debug		  specifies option -g to compile with debug info
   66:   --without-debug	  omits the -g switch and creates smaller images on
   67: 			  machines where "strip" has problems with gcc style
   68: 			  debugging informations.],
   69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   70: 
   71: GCC_LD="\$(GCC)"
   72: EC_MODE="false"
   73: NO_EC=""
   74: NO_CROSS=""
   75: EC=""
   76: engine2='engine2$(OPT).o'
   77: engine_fast2='engine-fast2$(OPT).o'
   78: no_dynamic=""
   79: image_i=""
   80: signals_o="io.o signals.o"
   81: 
   82: AC_CANONICAL_HOST
   83: AC_ARG_WITH(ec,
   84: 	AC_HELP_STRING([--with-ec=<arch>],
   85: 			[  Build gforth for systems without OS.]),
   86: [if test "$withval" = "no"; then
   87:   echo "defining hosted system"
   88: else
   89:   echo "defining standalone system (${withval})"
   90:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
   91:   EC_MODE="true"
   92:   EC="-ec"
   93:   NO_EC="#"
   94:   NO_CROSS="#"
   95:   engine2=""
   96:   engine_fast2=""
   97:   no_dynamic="-DNO_DYNAMIC"
   98:   image_i="image.i"
   99:   if test "$withval" != "yes"; then
  100:     signals_o="io-${withval}.o"
  101:   else
  102:     signals_o="io.o"
  103:   fi
  104:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  105:     source "arch/$host_cpu/${withval}/config.sh"
  106:   fi
  107:   GCC_PATH=$(which $CC)
  108:   LIB_PATH=${GCC_PATH%/*/*}
  109:   GCC_LD="\$(LD)"
  110:   platform=${withval}
  111: fi])
  112: 
  113: AC_ARG_WITH(cross,
  114: 	AC_HELP_STRING([--with-cross=<arch>],
  115: 			[  Build gforth using a cross compiler.]),
  116: [if test "$withval" = "no"; then
  117:   echo "defining hosted system"
  118: else
  119:   echo "defining cross compiled system (${withval})"
  120:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  121:     source "arch/$host_cpu/${withval}/config.sh"
  122:   fi
  123:   GCC_PATH=$(which $CC)
  124:   LIB_PATH=${GCC_PATH%/*/*}
  125:   platform=${withval}
  126:   NO_EC=""
  127:   NO_CROSS="#"
  128: fi])
  129: 
  130: #variables mentioned in INSTALL
  131: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
  132: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  133: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  134: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  135: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  136: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
  137: 
  138: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  139: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  140: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  141: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  142: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  143: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  144: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  145: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  146: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  147: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  148: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  149: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  150: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  151: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  152: AC_ARG_VAR(asmcomment, [assembler comment start string])
  153: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  154: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
  155: 
  156: #set up feature test macros, so the tests get them right:
  157: # turn on all POSIX, SUSv3, and GNU features if available
  158: AC_GNU_SOURCE
  159: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  160: 
  161: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  162: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  163: dnl but not for _XOPEN_SOURCE)
  164: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  165: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  166: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  167: # turn on large file support with 64-bit off_t where available
  168: AC_SYS_LARGEFILE
  169: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  170: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  171: 
  172: #currently we force direct threading this way.  Eventually we should
  173: #setup in the arch and engine files right
  174: 
  175: AC_PROG_CC
  176: 
  177: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  178: 
  179: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  180: test x$condbranch_opt = x && 
  181: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
  182:    condbranch_opt=0
  183: else
  184:    condbranch_opt=1
  185: fi
  186: AC_MSG_RESULT($condbranch_opt)
  187: AC_SUBST(condbranch_opt)
  188: AC_SUBST(host_cpu)
  189: 
  190: AC_SUBST(CC)
  191: AC_SUBST(GCC_LD)
  192: AC_SUBST(DEBUGFLAG)
  193: AC_SUBST(EC)
  194: AC_SUBST(NO_EC)
  195: AC_SUBST(NO_CROSS)
  196: AC_SUBST(EC_MODE)
  197: AC_SUBST(engine2)
  198: AC_SUBST(engine_fast2)
  199: AC_SUBST(no_dynamic)
  200: AC_SUBST(image_i)
  201: AC_SUBST(signals_o)
  202: 
  203: #this is used to disable some (not generally essential) part of the
  204: #Makefile that some makes don't grok.  It would be better to test for
  205: #this specific Makefile feature than the make version.
  206: AC_MSG_CHECKING(make type)
  207: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  208: GNUMAKE='#'
  209: test "$make_type" = "GNU Make" && GNUMAKE=''
  210: AC_MSG_RESULT($make_type)
  211: AC_SUBST(GNUMAKE)
  212: 
  213: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  214: OLDLDFLAGS=$LDFLAGS
  215: LDFLAGS="$LDFLAGS -export-dynamic"
  216: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  217: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  218: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  219: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  220: AC_MSG_RESULT($ac_export_dynamic)
  221: 
  222: #terminology is a bit unusual here: The host is the system on which
  223: #gforth will run; the system on which configure will run is the `build'
  224: case "$host_cpu" in
  225: 	arm*)
  226: 		machine=arm
  227: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  228: 		if test x$platform = xnxt; then
  229: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  230: 		fi
  231: 		if test -z $arm_cacheflush; then
  232: 		   case "$host_os" in
  233: 		     *linux*)
  234: 			AC_LIBOBJ(../arch/arm/cacheflush-linux) 
  235: 			;;
  236: 		     *)   
  237: 			no_dynamic_default=1
  238: 			AC_LIBOBJ(../arch/arm/cacheflush0)
  239: 			AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  240: 			;;
  241:                    esac
  242:                 else
  243:                    AC_LIBOBJ(../$arm_cacheflush)
  244:                    test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
  245: 		fi
  246:                 #longer skipcodes lead to problems on ARM, and it uses
  247:                 #only 4-byte alignment anyway
  248: 		test "$skipcode" || skipcode="nop"
  249: 		;;
  250: 	hppa*)
  251: 		machine=hppa
  252: 		AC_LIBOBJ(../arch/hppa/cache)
  253: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  254: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  255: 		LIBS="$LIBS -L/lib/pa1.1/"
  256: 		;;
  257: 	sparc*)
  258: 		machine=sparc
  259: 		;;
  260: 	i386)
  261: 		machine=386
  262: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  263: 		;;
  264: 	i486)
  265: 		machine=386
  266: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  267: 		CFLAGS_1="$CFLAGS"
  268: 		CFLAGS="$CFLAGS -march=i486"
  269: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  270: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  271: 		;;
  272: 	i*86)
  273: 		machine=386
  274: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  275: 		CFLAGS_1="$CFLAGS"
  276: 		CFLAGS="$CFLAGS -march=pentium -mtune=generic"
  277: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
  278: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  279: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  280: 		;;
  281: 	x86_64)
  282: 		case $CC
  283: 		in
  284: 		    *-m32*)
  285: 		    	machine=386
  286: 			CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  287: 			CFLAGS_1="$CFLAGS"
  288: 			CFLAGS="$CFLAGS -march=athlon64"
  289: 			;;
  290: 		    *)
  291: 		    	machine=amd64
  292: 			;;
  293: 		esac
  294: 		;;
  295: 	ia64*)
  296: 		machine=ia64
  297: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  298: 		test "$skipcode" || skipcode="nop.i 0"
  299: 		#".skip 16" passes the test below,
  300: 		# but gives an assembler error in engine
  301: 		;;
  302:         m68k)
  303: 		machine=m68k
  304: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  305: 		if test "$host_os" = "nextstep3"
  306: 		then
  307: 			AC_LIBOBJ(termios)
  308: 		fi
  309: 		;;
  310: 	mips*)
  311: 		machine=mips
  312: 		AC_LIBOBJ(../arch/mips/check_prim) 
  313: 		#dynamic native code has the following problems on MIPS:
  314: 		#
  315: 		#1) J/JAL seems relocatable, but is are only
  316: 		#relocatable within a 256MB-segment.  While we try to
  317: 		#get the linker to arrange this, there is no guarantee
  318: 		#that this will succeed (and if the user uses a lot of
  319: 		#memory, it is likely to fail).
  320: 		#
  321: 		#2) The way we generate dynamic native code may
  322: 		#violate MIPS architectural restrictions (in
  323: 		#particular, the delay slots of LW, MFLO, etc.)
  324: 		#
  325: 		#Therefore we disable dynamic native code by default:
  326: 		if test -z "$no_dynamic_default"; then
  327: 		    no_dynamic_default=1
  328: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  329: 		fi
  330: 		;;
  331: 	alpha*)
  332: 		machine=alpha
  333: 		#full IEEE FP support for more uniformity across platforms:
  334: 		CFLAGS="$CFLAGS -mieee"
  335: 		;;
  336: 	power*|rs6000)
  337: 		machine=power
  338: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  339: 		#long long is broken on (at least) gcc-2.95.* for PPC
  340: 		test x$ac_cv_sizeof_long_long = x && 
  341: 		($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
  342:                      ac_cv_sizeof_long_long=0
  343:                 #The only architecture with enough callee-saved registers
  344:                 test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
  345:                 #or use 2, hardly slower at run-time and starts up faster
  346: 
  347:                 #the skipcode that is normally selected below does not
  348:                 #work with gcc-3.[34]
  349: 		test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
  350: 		;;
  351: 	*)
  352: 		AC_MSG_WARN([Using a generic machine description])
  353: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  354: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  355: 		machine=generic
  356: 		#I-cache flushing would be needed for dynamic code generation
  357: 		if test -z $no_dynamic_default; then
  358: 		    no_dynamic_default=1
  359: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  360: 		fi
  361: esac
  362: AC_SUBST(host)
  363: 
  364: MAKEINC=""
  365: GFORTH_EXE="true"
  366: 
  367: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  368: if test x$EC_MODE = xtrue
  369: then
  370: 	echo "Check for arch/$machine/$platform/gforth.ld"
  371: 	if test -f arch/$machine/$platform/gforth.ld
  372: 	then
  373: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  374: 		if test x$platform = xnxt; then
  375: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  376: 		fi
  377: 	fi
  378: 	if test -f arch/$machine/$platform/make.inc
  379: 	then
  380: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  381: 		GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
  382: 	fi
  383: fi
  384: AC_SUBST(MAKEINC)
  385: 
  386: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  387: 
  388: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
  389: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
  390: 		   [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
  391: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  392: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  393: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  394: 
  395: test x$GCC_PR15242_WORKAROUND = x ||
  396: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  397:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  398: 
  399: dnl the following macro produces a warning with autoconf-2.1
  400: AC_CHECK_SIZEOF(char *)
  401: case "$ac_cv_sizeof_char_p" in
  402:   2)
  403:     wordsize=16
  404:     ;;
  405:   4)
  406:     wordsize=32
  407:     ;;
  408:   8)
  409:     wordsize=64
  410:     ;;
  411: esac
  412: 
  413: AC_CHECK_SIZEOF(void *)
  414: case "$ac_cv_sizeof_void_p" in
  415:   2)
  416:     vwordsize=16
  417:     ;;
  418:   4)
  419:     vwordsize=32
  420:     ;;
  421:   8)
  422:     vwordsize=64
  423:     ;;
  424: esac
  425: 
  426: AC_CHECK_SIZEOF(char)
  427: AC_CHECK_SIZEOF(short)
  428: AC_CHECK_SIZEOF(int)
  429: AC_CHECK_SIZEOF(long)
  430: AC_CHECK_SIZEOF(long long)
  431: AC_CHECK_SIZEOF(intptr_t)
  432: AC_CHECK_SIZEOF(int128_t)
  433: AC_CHECK_SIZEOF(uint128_t)
  434: 
  435: AC_MSG_CHECKING([for a C type for cells])
  436: ac_cv_int_type_cell=none
  437: case "$ac_cv_sizeof_char_p" in
  438:   $ac_cv_sizeof_int)
  439:     ac_cv_int_type_cell=int
  440:     ;;
  441:   $ac_cv_sizeof_short)
  442:     ac_cv_int_type_cell=short
  443:     ;;
  444:   $ac_cv_sizeof_char)
  445:     ac_cv_int_type_cell=char
  446:     ;;
  447:   $ac_cv_sizeof_long)
  448:     ac_cv_int_type_cell=long
  449:     ;;
  450:   $ac_cv_sizeof_long_long)
  451:     ac_cv_int_type_cell="long long"
  452:     ;;
  453:   $ac_cv_sizeof_intptr_t)
  454:     ac_cv_int_type_cell="intptr_t"
  455:     ;;
  456: esac
  457: AC_MSG_RESULT($ac_cv_int_type_cell)
  458: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  459: 
  460: AC_MSG_CHECKING([for a C type for wydes])
  461: ac_cv_wyde_type_cell=none
  462: case 2 in
  463:   $ac_cv_sizeof_int)
  464:     ac_cv_wyde_type_cell=int
  465:     ;;
  466:   $ac_cv_sizeof_short)
  467:     ac_cv_wyde_type_cell=short
  468:     ;;
  469:   $ac_cv_sizeof_char)
  470:     ac_cv_wyde_type_cell=char
  471:     ;;
  472:   $ac_cv_sizeof_long)
  473:     ac_cv_wyde_type_cell=long
  474:     ;;
  475:   $ac_cv_sizeof_long_long)
  476:     ac_cv_wyde_type_cell="long long"
  477:     ;;
  478:   $ac_cv_sizeof_intptr_t)
  479:     ac_cv_wyde_type_cell="intptr_t"
  480:     ;;
  481: esac
  482: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  483: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  484: 
  485: AC_MSG_CHECKING([for a C type for tetrabytes])
  486: ac_cv_tetrabyte_type_cell=none
  487: case 4 in
  488:   $ac_cv_sizeof_int)
  489:     ac_cv_tetrabyte_type_cell=int
  490:     ;;
  491:   $ac_cv_sizeof_short)
  492:     ac_cv_tetrabyte_type_cell=short
  493:     ;;
  494:   $ac_cv_sizeof_char)
  495:     ac_cv_tetrabyte_type_cell=char
  496:     ;;
  497:   $ac_cv_sizeof_long)
  498:     ac_cv_tetrabyte_type_cell=long
  499:     ;;
  500:   $ac_cv_sizeof_long_long)
  501:     ac_cv_tetrabyte_type_cell="long long"
  502:     ;;
  503:   $ac_cv_sizeof_intptr_t)
  504:     ac_cv_tetrabyte_type_cell="intptr_t"
  505:     ;;
  506: esac
  507: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  508: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  509: 
  510: AC_MSG_CHECKING([for a C type for octabytes])
  511: ac_cv_octabyte_type_cell=none
  512: case 8 in
  513:   $ac_cv_sizeof_int)
  514:     ac_cv_octabyte_type_cell=int
  515:     ;;
  516:   $ac_cv_sizeof_short)
  517:     ac_cv_octabyte_type_cell=short
  518:     ;;
  519:   $ac_cv_sizeof_char)
  520:     ac_cv_octabyte_type_cell=char
  521:     ;;
  522:   $ac_cv_sizeof_long)
  523:     ac_cv_octabyte_type_cell=long
  524:     ;;
  525:   $ac_cv_sizeof_long_long)
  526:     ac_cv_octabyte_type_cell="long long"
  527:     ;;
  528:   $ac_cv_sizeof_intptr_t)
  529:     ac_cv_octabyte_type_cell="intptr_t"
  530:     ;;
  531: esac
  532: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
  533: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
  534: 
  535: AC_MSG_CHECKING([for a C type for double-cells])
  536: ac_cv_int_type_double_cell=none
  537: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  538:   $ac_cv_sizeof_short)
  539:     ac_cv_int_type_double_cell=short
  540:     ;;
  541:   $ac_cv_sizeof_int)
  542:     ac_cv_int_type_double_cell=int
  543:     ;;
  544:   $ac_cv_sizeof_long)
  545:     ac_cv_int_type_double_cell=long
  546:     ;;
  547:   $ac_cv_sizeof_long_long)
  548:     ac_cv_int_type_double_cell="long long"
  549:     ;;
  550:   $ac_cv_sizeof_intptr_t)
  551:     ac_cv_int_type_double_cell="intptr_t"
  552:     ;;
  553:   $ac_cv_sizeof_int128_t)
  554:     ac_cv_int_type_double_cell="int128_t"
  555:     ;;
  556: esac
  557: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  558: 
  559: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  560: ac_cv_int_type_double_ucell=none
  561: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  562:   $ac_cv_sizeof_short)
  563:     ac_cv_int_type_double_ucell="unsigned short"
  564:     ;;
  565:   $ac_cv_sizeof_int)
  566:     ac_cv_int_type_double_ucell="unsigned int"
  567:     ;;
  568:   $ac_cv_sizeof_long)
  569:     ac_cv_int_type_double_ucell="unsigned long"
  570:     ;;
  571:   $ac_cv_sizeof_long_long)
  572:     ac_cv_int_type_double_ucell="unsigned long long"
  573:     ;;
  574:   $ac_cv_sizeof_intptr_t)
  575:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  576:     ;;
  577:   $ac_cv_sizeof_uint128_t)
  578:     ac_cv_int_type_double_ucell="uint128_t"
  579:     ;;
  580: esac
  581: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  582: 
  583: if test "$ac_cv_int_type_double_cell" != none && \
  584:    test "$ac_cv_int_type_double_ucell" != none
  585: then
  586: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  587: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  588:         OPTS=-ll
  589: else
  590:         if test "$ac_cv_sizeof_char_p" = 8; then
  591:            OPTS="-ll -noll"
  592:         else
  593:            OPTS=-noll
  594:         fi
  595: fi
  596: 
  597: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
  598:    OPTS2=''
  599:    for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
  600:    OPTS="$OPTS2 $OPTS"
  601: else
  602:   AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
  603: fi
  604: AC_SUBST(OPTS)
  605: 
  606: AC_TYPE_OFF_T
  607: AC_CHECK_SIZEOF(off_t)
  608: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  609: ac_small_off_t=$?
  610: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  611: 
  612: ENGINE_FLAGS=
  613: AC_SUBST(ENGINE_FLAGS)
  614: 
  615: # Try if GCC understands -fno-gcse
  616: 
  617: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  618: CFLAGS_1="$CFLAGS"
  619: CFLAGS="$CFLAGS -fno-gcse"
  620: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  621: CFLAGS="$CFLAGS_1"
  622: AC_MSG_RESULT($ac_nogcse)
  623: 
  624: # Try if GCC understands -fno-strict-aliasing
  625: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  626: CFLAGS_1="$CFLAGS"
  627: CFLAGS="$CFLAGS -fno-strict-aliasing"
  628: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  629: CFLAGS="$CFLAGS_1"
  630: AC_MSG_RESULT($ac_nostrictaliasing)
  631: 
  632: # Try if GCC understands -fno-crossjumping
  633: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  634: CFLAGS_1="$CFLAGS"
  635: CFLAGS="$CFLAGS -fno-crossjumping"
  636: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  637: CFLAGS="$CFLAGS_1"
  638: AC_MSG_RESULT($ac_nocrossjumping)
  639: 
  640: # Try if GCC understands -fno-reorder-blocks
  641: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  642: CFLAGS_1="$CFLAGS"
  643: CFLAGS="$CFLAGS -fno-reorder-blocks"
  644: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  645: CFLAGS="$CFLAGS_1"
  646: AC_MSG_RESULT($ac_noreorder_blocks)
  647: 
  648: # Try if GCC understands -falign-labels=1
  649: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  650: CFLAGS_1="$CFLAGS"
  651: CFLAGS="$CFLAGS -falign-labels=1"
  652: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  653: CFLAGS="$CFLAGS_1"
  654: AC_MSG_RESULT($ac_align_labels)
  655: 
  656: # Try if GCC understands -falign-loops=1
  657: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
  658: CFLAGS_1="$CFLAGS"
  659: CFLAGS="$CFLAGS -falign-loops=1"
  660: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
  661: CFLAGS="$CFLAGS_1"
  662: AC_MSG_RESULT($ac_align_loops)
  663: 
  664: # Try if GCC understands -falign-jumps=1
  665: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
  666: CFLAGS_1="$CFLAGS"
  667: CFLAGS="$CFLAGS -falign-jumps=1"
  668: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
  669: CFLAGS="$CFLAGS_1"
  670: AC_MSG_RESULT($ac_align_jumps)
  671: 
  672: if test -z "$LIBTOOL_CC"
  673: then
  674:   LIBTOOL_CC="$CC"
  675:   # Try if GCC understands -Wimplicit-function-declaration
  676:   AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
  677:   CFLAGS_1="$CFLAGS"
  678:   CFLAGS="$CFLAGS -Wimplicit-function-declaration"
  679:   AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
  680:   CFLAGS="$CFLAGS_1"
  681:   AC_MSG_RESULT($ac_align_jumps)
  682: fi
  683: AC_SUBST(LIBTOOL_CC)
  684: 
  685: 
  686: 
  687: # Try if GCC understands __attribute__((unused))
  688: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  689: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  690: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  691: AC_MSG_RESULT($MAYBE_UNUSED)
  692: 
  693: # Try if GCC understands __thread
  694: AC_MSG_CHECKING([whether gcc understands '__thread'])
  695: AC_TRY_COMPILE(,[extern __thread int foo;],PER_THREAD='__thread',)
  696: AC_DEFINE_UNQUOTED(PER_THREAD,$PER_THREAD,[storage class for thread-local variables])
  697: AC_MSG_RESULT($PER_THREAD)
  698: 
  699: #try if m4 understands -s
  700: AC_MSG_CHECKING([how to invoke m4])
  701: if m4 -s /dev/null >/dev/null 2>&1; then
  702:  M4="m4 -s"
  703: else
  704:  M4=m4
  705: fi
  706: AC_SUBST(M4)
  707: AC_MSG_RESULT($M4)
  708: 
  709: #echo "machine='$machine'"
  710: 
  711: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  712: if test x$EC_MODE = xfalse
  713: then
  714:   AS_IF([test -f $srcdir/arch/$machine/asm.fs],
  715:         [asm_fs=arch/$machine/asm.fs])
  716: fi
  717: AC_SUBST(asm_fs)
  718: 
  719: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  720: if test x$EC_MODE = xfalse
  721: then
  722:   AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
  723:    	[disasm_fs=arch/$machine/disasm.fs])
  724: fi
  725: AC_SUBST(disasm_fs)
  726: 
  727: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  728: 
  729: case "$host_os" in
  730: 	*win32*)
  731: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  732: 		DIRSEP="\\\\"
  733: 		PATHSEP=";"
  734: 		#we want the builtins of command.com/cmd.exe and its
  735: 		# handling of .com files.
  736: 		#$COMSPEC contains the name of the Windows shell;
  737: 		# the ./ is there, because the bash does not recognize
  738: 		# absolute DOS filenames
  739: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  740: 		;;
  741: 	*darwin*)
  742: 		#Darwin uses some funny preprocessor by default; eliminate it:
  743: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  744: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  745: 		DIRSEP="/"
  746: 		PATHSEP=":"
  747: 		DEFAULTSYSTEMPREFIX=""
  748:                 #the following magic value was suggested by
  749:                 #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
  750:                 AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
  751: 		;;
  752: 	*linux*)
  753: 		DIRSEP="/"
  754: 		PATHSEP=":"
  755: 		DEFAULTSYSTEMPREFIX=""
  756: 		if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
  757: 		   LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
  758: 		fi
  759: 		;;
  760: 	*)
  761: 		DIRSEP="/"
  762: 		PATHSEP=":"
  763: 		DEFAULTSYSTEMPREFIX=""
  764: 		;;
  765: esac
  766: AC_SUBST(DIRSEP)
  767: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  768: AC_SUBST(PATHSEP)
  769: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  770: AC_SUBST(DEFAULTSYSTEMPREFIX)
  771: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  772: if test -n "$LTDL_LIBRARY_PATH"; then
  773:    AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
  774: fi                                                                
  775: 
  776: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  777: #This magic incantation  seems to be completely undocumented.
  778: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  779: 
  780: dnl Now a little support for DOS/DJGCC
  781: GFORTHFAST_EXE="$GFORTH_EXE"
  782: GFORTHITC_EXE="$GFORTH_EXE"
  783: GFORTHDITC_EXE="$GFORTH_EXE"
  784: AC_SUBST(GFORTH_EXE)
  785: AC_SUBST(GFORTHFAST_EXE)
  786: AC_SUBST(GFORTHITC_EXE)
  787: AC_SUBST(GFORTHDITC_EXE)
  788: 
  789: AC_SUBST(FORTHSIZES)
  790: 
  791: dnl if test "$PEEPHOLE" = "yes"
  792: dnl then
  793: dnl    PEEPHOLEFLAG="true"
  794: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  795: dnl else
  796: dnl    PEEPHOLEFLAG="false"
  797: dnl fi
  798: PEEPHOLEFLAG="true"
  799: AC_SUBST(PEEPHOLEFLAG)
  800: 
  801: dnl copy commands for systems that don't have links
  802: AC_SUBST(LINK_KERNL)
  803: LINK_KERNL=""
  804: 
  805: #if test $host_os=dos
  806: #then
  807: #  echo Configuring for DOS!!!
  808: #  MAKE_EXE="coff2exe gforth"
  809: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  810: #fi
  811: 
  812: dnl the following macro produces a warning with autoconf-2.1
  813: AC_C_BIGENDIAN
  814: AC_SUBST(KERNEL)
  815: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  816: if test $ac_cv_c_bigendian != no; then
  817:   bytesex=b
  818:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  819: else
  820:   bytesex=l
  821:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  822: fi
  823: 
  824: #check how to do asm(".skip 16")
  825: #echo "CFLAGS=$CFLAGS"
  826: #echo "ac_link=$ac_link"
  827: AC_MSG_CHECKING([if and how we can waste code space])
  828: if test -z "$skipcode" && test x$cross_compiling = xyes; then
  829:    # we cannot perform the AC_TRY_RUN check when cross-compiling.  
  830:    skipcode=no
  831:    AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
  832: elif test -z "$skipcode"; then
  833:     skipcode=no
  834:     CFLAGS_1="$CFLAGS"
  835:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  836:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  837:     do
  838: 	AC_TRY_RUN(
  839: [int foo(int,int,int);
  840: main()
  841: {
  842:   exit(foo(0,0,0)!=16);
  843: }
  844: int foo(int x, int y, int z)
  845: {
  846:   static void *labels[]={&&label1, &&label2};
  847:   if (x) {
  848:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  849:   label1:
  850:     asm("$i"); /* or ".space 16" or somesuch */
  851:   label2: ;
  852:   }
  853:   {
  854:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  855:   return labels[1]-labels[0];
  856:   }
  857: }]
  858: 	,skipcode=$i; break
  859: 	,,)
  860:     done
  861:     CFLAGS=$CFLAGS_1
  862: fi
  863: AC_MSG_RESULT($skipcode)
  864: if test "$skipcode" = no
  865: then 
  866:     if test -z $no_dynamic_default; then
  867: 	no_dynamic_default=1
  868: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  869:     fi
  870:     AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
  871: else
  872:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  873: fi
  874: 
  875: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  876: #the point here is to get asm statements that look different to
  877: #gcc's "optimizer"
  878: if test -z "$asmcomment"; then
  879:     asmcomment=no
  880:     CFLAGS_1="$CFLAGS"
  881:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  882:     for i in '"# "' '"! "' '"; "'; do
  883: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  884:     done
  885:     CFLAGS=$CFLAGS_1
  886: fi
  887: AC_MSG_RESULT($asmcomment)
  888: if test "$asmcomment" != no
  889: then 
  890:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  891: fi
  892: 
  893: test "$no_dynamic_default" || no_dynamic_default=0
  894: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  895: 
  896: dnl Checks for programs.
  897: AC_PROG_LN_S
  898: AC_PROG_INSTALL
  899: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  900: 
  901: dnl check for the presence of Emacs
  902: AC_CHECK_PROGS(EMACS,emacs xemacs)
  903: test -n "$EMACS" && gforth_elc=gforth.elc
  904: AC_SUBST(gforth_elc)
  905: 
  906: dnl MacOS X has a libtool that does something else
  907: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
  908: 
  909: dnl Checks for library functions
  910: dnl This check is just for making later checks link with libm.
  911: dnl using sin here is no good idea since it is built-into gcc and typechecked
  912: AC_CHECK_LIB(m,asin)
  913: AC_CHECK_LIB(ltdl,lt_dlinit)
  914: AC_CHECK_LIB(rt,clock_gettime)
  915: 
  916: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
  917:   build_libcc_named=build-libcc-named
  918: else
  919:   build_libcc_named=""
  920:   AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
  921: fi
  922: AC_SUBST(build_libcc_named)
  923: 
  924: 
  925: if test -z "$GNU_LIBTOOL"; then
  926:   AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
  927:   AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
  928:   GNU_LIBTOOL=libtool
  929: fi
  930: 
  931: #check for libffi 2.x
  932: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
  933: if test -z "$FFI_H_NAME"; then
  934:   AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
  935: fi
  936: AC_SUBST(FFI_H_NAME)
  937: AC_CHECK_LIB(ffi,ffi_call,LIBS="$LIBS")
  938: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
  939: then
  940:   LIBFFIFLAG="true"
  941:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
  942: else
  943:   LIBFFIFLAG="false"
  944: fi
  945: #check for ffcall libraries
  946: #unfortunately, these four calls are separated out into a library each.
  947: AC_CHECK_LIB(avcall,__builtin_avcall,LIBS="$LIBS")
  948: dnl AC_CHECK_LIB(callback,__vacall_r)
  949: dnl AC_CHECK_LIB(vacall,vacall)
  950: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
  951: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
  952:   FFCALLFLAG="true"
  953:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
  954: else
  955:   FFCALLFLAG="false"
  956: fi
  957: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
  958:   AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
  959: fi
  960: AC_SUBST(LIBFFIFLAG)
  961: AC_SUBST(FFCALLFLAG)
  962: AC_SUBST(LIBCC_BUILD_SRC)
  963: if test "$host_os" != "nextstep3"
  964: then
  965: 	AC_FUNC_MEMCMP
  966: fi
  967: AC_REPLACE_FUNCS(memmove strtoul pow10 sincos strerror strsignal atanh)
  968: AC_FUNC_FSEEKO
  969: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep clock_gettime)
  970: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  971: AC_DECL_SYS_SIGLIST
  972: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  973: AC_CHECK_FUNCS(expm1 log1p)
  974: AC_REPLACE_FUNCS(rint ecvt)
  975: dnl No check for select, because our replacement is no good under
  976: dnl anything but DOS
  977: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
  978: AC_FUNC_FNMATCH
  979: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  980: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
  981: AM_PATH_LISPDIR
  982: 
  983: kernel_fi=kernl${vwordsize}${bytesex}.fi
  984: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  985: AC_SUBST(kernel_fi)
  986: AC_SUBST(include_fi)
  987: 
  988: # Find installed Gforth
  989: AC_MSG_CHECKING([for gforth])
  990: GFORTH="`cd / && which gforth 2>/dev/null`"
  991: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
  992: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null  && test "$srcdir" = ".") || GFORTH=""
  993: if test -z "$GFORTH"; then
  994:   PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
  995:   GFORTHKER='echo "You need to configure with a gforth in \$PATH to build this part" && false'
  996:   kernel_anti_dependence=''
  997: else
  998:   GFORTH_FI=`cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`
  999:   PREFORTH="$GFORTH -i $GFORTH_FI" ;
 1000:   KERNLX_FI1=`echo $GFORTH_FI | sed -e s/lib/share/g -e s/gforth.fi/kernl*.fi/g`
 1001:   KERNLX_FI2=`echo $GFORTH_FI | sed -e s/gforth.fi/kernl*.fi/g`
 1002:   test -f $KERNLX_FI1 && KERNLX_FI=$KERNLX_FI1
 1003:   test -f $KERNLX_FI2 && KERNLX_FI=$KERNLX_FI2
 1004:   GFORTHKER="$GFORTH -i `echo $KERNLX_FI`" ;
 1005:   kernel_anti_dependence='$(kernel_fi)'
 1006: fi
 1007: AC_SUBST(PREFORTH)
 1008: AC_SUBST(GFORTHKER)
 1009: AC_SUBST(kernel_anti_dependence)
 1010: AC_MSG_RESULT($PREFORTH)
 1011: 
 1012: #this breaks bindists
 1013: #dnl replace srource directory by absolute value
 1014: #if test $srcdir = "."; then srcdir=`pwd` 
 1015: #fi
 1016: 
 1017: AC_SUBST(machine)
 1018: AC_CONFIG_FILES([
 1019: Makefile
 1020: Makedist
 1021: gforthmi
 1022: vmgen
 1023: machpc.fs
 1024: envos.fs
 1025: preforth
 1026: gforthker
 1027: engine/Makefile
 1028: engine/libcc.h
 1029: doc/version.texi
 1030: build-ec ])
 1031: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
 1032: chmod +x gforthmi
 1033: chmod +x vmgen
 1034: chmod +x build-ec
 1035: chmod +x preforth
 1036: chmod +x gforthker
 1037: test -d kernel||mkdir kernel
 1038: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
 1039: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
 1040: $srcdir/mkinstalldirs arch/$machine
 1041: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],
 1042: [PACKAGE_VERSION=$PACKAGE_VERSION
 1043:  machine=$machine])
 1044: AC_OUTPUT

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>