File:  [gforth] / gforth / configure.in
Revision 1.290: download - view: text, annotated - select for diffs
Mon Nov 14 22:33:22 2011 UTC (12 years, 4 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Typos from Josh, new option for easier cross-compilation

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation, either version 3
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.7.9-20101227],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: AC_PREREQ(2.54)
   25: #snapshots have numbers major.minor.release-YYYYMMDD
   26: #note that lexicographic ordering must be heeded.
   27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   28: UPDATED="December 27, 2010"
   29: AC_SUBST(UPDATED)
   30: AC_CONFIG_HEADERS(engine/config.h)
   31: 
   32: #remnants from having ltdl as convenience library
   33: LTDLDEPS=""
   34: LTDLINCL=""
   35: LIBLTDL=""
   36: LTDL_LDLIBS=""
   37: AC_SUBST(LTDLDEPS)
   38: AC_SUBST(LTDLINCL)
   39: AC_SUBST(LIBLTDL)
   40: AC_SUBST(LTDL_LDLIBS)
   41: 
   42: #suppress the "-g -O2" default
   43: test "$CFLAGS" || CFLAGS=-O2
   44: 
   45: AC_ARG_ENABLE(force-cdiv,
   46: 	AC_HELP_STRING([--enable-force-cdiv],
   47: 		       [  Use the native C division - symmetric - instead of
   48: 		          floored division (default disabled).]),
   49: 	,enable_force_cdiv=no)
   50: test "$enable_force_cdiv" = "no"||
   51:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   52: 
   53: AC_SUBST(PROFEXES)
   54: AC_SUBST(PROFOBJS)
   55: AC_ARG_ENABLE(prof,
   56: 	AC_HELP_STRING([--enable-prof],
   57: 			[ Build gforth-prof, which outputs frequently occuring
   58:                           sequences of primitives.]),
   59: 	,enable_prof=no)
   60: if test "$enable_prof" != "no"; then
   61:   PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
   62: fi
   63: 
   64: AC_ARG_WITH(debug,
   65: [  --with-debug		  specifies option -g to compile with debug info
   66:   --without-debug	  omits the -g switch and creates smaller images on
   67: 			  machines where "strip" has problems with gcc style
   68: 			  debugging informations.],
   69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   70: 
   71: GCC_LD="\$(GCC)"
   72: EC_MODE="false"
   73: NO_EC=""
   74: EC=""
   75: engine2='engine2$(OPT).o'
   76: engine_fast2='engine-fast2$(OPT).o'
   77: no_dynamic=""
   78: image_i=""
   79: signals_o="io.o signals.o"
   80: 
   81: AC_CANONICAL_HOST
   82: AC_ARG_WITH(ec,
   83: 	AC_HELP_STRING([--with-ec=<arch>],
   84: 			[  Build gforth for systems without OS.]),
   85: [if test "$withval" = "no"; then
   86:   echo "defining hosted system"
   87: else
   88:   echo "defining standalone system (${withval})"
   89:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
   90:   EC_MODE="true"
   91:   EC="-ec"
   92:   NO_EC="#"
   93:   engine2=""
   94:   engine_fast2=""
   95:   no_dynamic="-DNO_DYNAMIC"
   96:   image_i="image.i"
   97:   if test "$withval" != "yes"; then
   98:     signals_o="io-${withval}.o"
   99:   else
  100:     signals_o="io.o"
  101:   fi
  102:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  103:     source "arch/$host_cpu/${withval}/config.sh"
  104:   fi
  105:   GCC_PATH=$(which $CC)
  106:   LIB_PATH=${GCC_PATH%/*/*}
  107:   GCC_LD="\$(LD)"
  108:   platform=${withval}
  109: fi])
  110: 
  111: AC_ARG_WITH(cross,
  112: 	AC_HELP_STRING([--with-cross=<arch>],
  113: 			[  Build gforth using a cross compiler.]),
  114: [if test "$withval" = "no"; then
  115:   echo "defining hosted system"
  116: else
  117:   echo "defining cross compiled system (${withval})"
  118:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  119:     source "arch/$host_cpu/${withval}/config.sh"
  120:   fi
  121:   GCC_PATH=$(which $CC)
  122:   LIB_PATH=${GCC_PATH%/*/*}
  123:   GCC_LD="\$(LD)"
  124:   platform=${withval}
  125: fi])
  126: 
  127: #variables mentioned in INSTALL
  128: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
  129: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  130: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  131: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  132: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  133: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
  134: 
  135: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  136: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  137: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  138: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  139: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  140: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  141: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  142: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  143: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  144: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  145: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  146: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  147: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  148: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  149: AC_ARG_VAR(asmcomment, [assembler comment start string])
  150: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  151: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
  152: 
  153: #set up feature test macros, so the tests get them right:
  154: # turn on all POSIX, SUSv3, and GNU features if available
  155: AC_GNU_SOURCE
  156: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  157: 
  158: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  159: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  160: dnl but not for _XOPEN_SOURCE)
  161: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  162: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  163: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  164: # turn on large file support with 64-bit off_t where available
  165: AC_SYS_LARGEFILE
  166: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  167: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  168: 
  169: #currently we force direct threading this way.  Eventually we should
  170: #setup in the arch and engine files right
  171: 
  172: AC_PROG_CC
  173: 
  174: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  175: 
  176: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  177: test x$condbranch_opt = x && 
  178: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
  179:    condbranch_opt=0
  180: else
  181:    condbranch_opt=1
  182: fi
  183: AC_MSG_RESULT($condbranch_opt)
  184: AC_SUBST(condbranch_opt)
  185: 
  186: AC_SUBST(CC)
  187: AC_SUBST(GCC_LD)
  188: AC_SUBST(DEBUGFLAG)
  189: AC_SUBST(EC)
  190: AC_SUBST(NO_EC)
  191: AC_SUBST(EC_MODE)
  192: AC_SUBST(engine2)
  193: AC_SUBST(engine_fast2)
  194: AC_SUBST(no_dynamic)
  195: AC_SUBST(image_i)
  196: AC_SUBST(signals_o)
  197: 
  198: #this is used to disable some (not generally essential) part of the
  199: #Makefile that some makes don't grok.  It would be better to test for
  200: #this specific Makefile feature than the make version.
  201: AC_MSG_CHECKING(make type)
  202: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  203: GNUMAKE='#'
  204: test "$make_type" = "GNU Make" && GNUMAKE=''
  205: AC_MSG_RESULT($make_type)
  206: AC_SUBST(GNUMAKE)
  207: 
  208: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  209: OLDLDFLAGS=$LDFLAGS
  210: LDFLAGS="$LDFLAGS -export-dynamic"
  211: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  212: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  213: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  214: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  215: AC_MSG_RESULT($ac_export_dynamic)
  216: 
  217: #terminology is a bit unusual here: The host is the system on which
  218: #gforth will run; the system on which configure will run is the `build'
  219: case "$host_cpu" in
  220: 	arm*)
  221: 		machine=arm
  222: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  223: 		if test x$platform = xnxt; then
  224: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  225: 		fi
  226: 		if test -z $arm_cacheflush; then
  227: 		   case "$host_os" in
  228: 		     *linux*)
  229: 			AC_LIBOBJ(../arch/arm/cacheflush-linux) 
  230: 			;;
  231: 		     *)   
  232: 			no_dynamic_default=1
  233: 			AC_LIBOBJ(../arch/arm/cacheflush0)
  234: 			AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  235: 			;;
  236:                    esac
  237:                 else
  238:                    AC_LIBOBJ(../$arm_cacheflush)
  239:                    test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
  240: 		fi
  241:                 #longer skipcodes lead to problems on ARM, and it uses
  242:                 #only 4-byte alignment anyway
  243: 		test "$skipcode" || skipcode="nop"
  244: 		;;
  245: 	hppa*)
  246: 		machine=hppa
  247: 		AC_LIBOBJ(../arch/hppa/cache)
  248: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  249: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  250: 		LIBS="$LIBS -L/lib/pa1.1/"
  251: 		;;
  252: 	sparc*)
  253: 		machine=sparc
  254: 		;;
  255: 	i386)
  256: 		machine=386
  257: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  258: 		;;
  259: 	i486)
  260: 		machine=386
  261: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  262: 		CFLAGS_1="$CFLAGS"
  263: 		CFLAGS="$CFLAGS -march=i486"
  264: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  265: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  266: 		;;
  267: 	i*86)
  268: 		machine=386
  269: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  270: 		CFLAGS_1="$CFLAGS"
  271: 		CFLAGS="$CFLAGS -march=pentium -mtune=generic"
  272: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
  273: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  274: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  275: 		;;
  276: 	x86_64)
  277: 		case $CC
  278: 		in
  279: 		    *-m32*)
  280: 		    	machine=386
  281: 			CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  282: 			CFLAGS_1="$CFLAGS"
  283: 			CFLAGS="$CFLAGS -march=athlon64"
  284: 			;;
  285: 		    *)
  286: 		    	machine=amd64
  287: 			;;
  288: 		esac
  289: 		;;
  290: 	ia64*)
  291: 		machine=ia64
  292: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  293: 		test "$skipcode" || skipcode="nop.i 0"
  294: 		#".skip 16" passes the test below,
  295: 		# but gives an assembler error in engine
  296: 		;;
  297:         m68k)
  298: 		machine=m68k
  299: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  300: 		if test "$host_os" = "nextstep3"
  301: 		then
  302: 			AC_LIBOBJ(termios)
  303: 		fi
  304: 		;;
  305: 	mips*)
  306: 		machine=mips
  307: 		AC_LIBOBJ(../arch/mips/check_prim) 
  308: 		#dynamic native code has the following problems on MIPS:
  309: 		#
  310: 		#1) J/JAL seems relocatable, but is are only
  311: 		#relocatable within a 256MB-segment.  While we try to
  312: 		#get the linker to arrange this, there is no guarantee
  313: 		#that this will succeed (and if the user uses a lot of
  314: 		#memory, it is likely to fail).
  315: 		#
  316: 		#2) The way we generate dynamic native code may
  317: 		#violate MIPS architectural restrictions (in
  318: 		#particular, the delay slots of LW, MFLO, etc.)
  319: 		#
  320: 		#Therefore we disable dynamic native code by default:
  321: 		if test -z "$no_dynamic_default"; then
  322: 		    no_dynamic_default=1
  323: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  324: 		fi
  325: 		;;
  326: 	alpha*)
  327: 		machine=alpha
  328: 		#full IEEE FP support for more uniformity across platforms:
  329: 		CFLAGS="$CFLAGS -mieee"
  330: 		;;
  331: 	power*|rs6000)
  332: 		machine=power
  333: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  334: 		#long long is broken on (at least) gcc-2.95.* for PPC
  335: 		test x$ac_cv_sizeof_long_long = x && 
  336: 		($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
  337:                      ac_cv_sizeof_long_long=0
  338:                 #The only architecture with enough callee-saved registers
  339:                 test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
  340:                 #or use 2, hardly slower at run-time and starts up faster
  341: 
  342:                 #the skipcode that is normally selected below does not
  343:                 #work with gcc-3.[34]
  344: 		test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
  345: 		;;
  346: 	*)
  347: 		AC_MSG_WARN([Using a generic machine description])
  348: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  349: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  350: 		machine=generic
  351: 		#I-cache flushing would be needed for dynamic code generation
  352: 		if test -z $no_dynamic_default; then
  353: 		    no_dynamic_default=1
  354: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  355: 		fi
  356: esac
  357: AC_SUBST(host)
  358: 
  359: MAKEINC=""
  360: GFORTH_EXE="true"
  361: 
  362: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  363: if test x$EC_MODE = xtrue
  364: then
  365: 	echo "Check for arch/$machine/$platform/gforth.ld"
  366: 	if test -f arch/$machine/$platform/gforth.ld
  367: 	then
  368: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  369: 		if test x$platform = xnxt; then
  370: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  371: 		fi
  372: 	fi
  373: 	if test -f arch/$machine/$platform/make.inc
  374: 	then
  375: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  376: 		GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
  377: 	fi
  378: fi
  379: AC_SUBST(MAKEINC)
  380: 
  381: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  382: 
  383: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
  384: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
  385: 		   [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
  386: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  387: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  388: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  389: 
  390: test x$GCC_PR15242_WORKAROUND = x ||
  391: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  392:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  393: 
  394: dnl the following macro produces a warning with autoconf-2.1
  395: AC_CHECK_SIZEOF(char *)
  396: case "$ac_cv_sizeof_char_p" in
  397:   2)
  398:     wordsize=16
  399:     ;;
  400:   4)
  401:     wordsize=32
  402:     ;;
  403:   8)
  404:     wordsize=64
  405:     ;;
  406: esac
  407: 
  408: AC_CHECK_SIZEOF(void *)
  409: case "$ac_cv_sizeof_void_p" in
  410:   2)
  411:     vwordsize=16
  412:     ;;
  413:   4)
  414:     vwordsize=32
  415:     ;;
  416:   8)
  417:     vwordsize=64
  418:     ;;
  419: esac
  420: 
  421: AC_CHECK_SIZEOF(char)
  422: AC_CHECK_SIZEOF(short)
  423: AC_CHECK_SIZEOF(int)
  424: AC_CHECK_SIZEOF(long)
  425: AC_CHECK_SIZEOF(long long)
  426: AC_CHECK_SIZEOF(intptr_t)
  427: AC_CHECK_SIZEOF(int128_t)
  428: AC_CHECK_SIZEOF(uint128_t)
  429: 
  430: AC_MSG_CHECKING([for a C type for cells])
  431: ac_cv_int_type_cell=none
  432: case "$ac_cv_sizeof_char_p" in
  433:   $ac_cv_sizeof_int)
  434:     ac_cv_int_type_cell=int
  435:     ;;
  436:   $ac_cv_sizeof_short)
  437:     ac_cv_int_type_cell=short
  438:     ;;
  439:   $ac_cv_sizeof_char)
  440:     ac_cv_int_type_cell=char
  441:     ;;
  442:   $ac_cv_sizeof_long)
  443:     ac_cv_int_type_cell=long
  444:     ;;
  445:   $ac_cv_sizeof_long_long)
  446:     ac_cv_int_type_cell="long long"
  447:     ;;
  448:   $ac_cv_sizeof_intptr_t)
  449:     ac_cv_int_type_cell="intptr_t"
  450:     ;;
  451: esac
  452: AC_MSG_RESULT($ac_cv_int_type_cell)
  453: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  454: 
  455: AC_MSG_CHECKING([for a C type for wydes])
  456: ac_cv_wyde_type_cell=none
  457: case 2 in
  458:   $ac_cv_sizeof_int)
  459:     ac_cv_wyde_type_cell=int
  460:     ;;
  461:   $ac_cv_sizeof_short)
  462:     ac_cv_wyde_type_cell=short
  463:     ;;
  464:   $ac_cv_sizeof_char)
  465:     ac_cv_wyde_type_cell=char
  466:     ;;
  467:   $ac_cv_sizeof_long)
  468:     ac_cv_wyde_type_cell=long
  469:     ;;
  470:   $ac_cv_sizeof_long_long)
  471:     ac_cv_wyde_type_cell="long long"
  472:     ;;
  473:   $ac_cv_sizeof_intptr_t)
  474:     ac_cv_wyde_type_cell="intptr_t"
  475:     ;;
  476: esac
  477: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  478: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  479: 
  480: AC_MSG_CHECKING([for a C type for tetrabytes])
  481: ac_cv_tetrabyte_type_cell=none
  482: case 4 in
  483:   $ac_cv_sizeof_int)
  484:     ac_cv_tetrabyte_type_cell=int
  485:     ;;
  486:   $ac_cv_sizeof_short)
  487:     ac_cv_tetrabyte_type_cell=short
  488:     ;;
  489:   $ac_cv_sizeof_char)
  490:     ac_cv_tetrabyte_type_cell=char
  491:     ;;
  492:   $ac_cv_sizeof_long)
  493:     ac_cv_tetrabyte_type_cell=long
  494:     ;;
  495:   $ac_cv_sizeof_long_long)
  496:     ac_cv_tetrabyte_type_cell="long long"
  497:     ;;
  498:   $ac_cv_sizeof_intptr_t)
  499:     ac_cv_tetrabyte_type_cell="intptr_t"
  500:     ;;
  501: esac
  502: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  503: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  504: 
  505: AC_MSG_CHECKING([for a C type for octabytes])
  506: ac_cv_octabyte_type_cell=none
  507: case 8 in
  508:   $ac_cv_sizeof_int)
  509:     ac_cv_octabyte_type_cell=int
  510:     ;;
  511:   $ac_cv_sizeof_short)
  512:     ac_cv_octabyte_type_cell=short
  513:     ;;
  514:   $ac_cv_sizeof_char)
  515:     ac_cv_octabyte_type_cell=char
  516:     ;;
  517:   $ac_cv_sizeof_long)
  518:     ac_cv_octabyte_type_cell=long
  519:     ;;
  520:   $ac_cv_sizeof_long_long)
  521:     ac_cv_octabyte_type_cell="long long"
  522:     ;;
  523:   $ac_cv_sizeof_intptr_t)
  524:     ac_cv_octabyte_type_cell="intptr_t"
  525:     ;;
  526: esac
  527: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
  528: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
  529: 
  530: AC_MSG_CHECKING([for a C type for double-cells])
  531: ac_cv_int_type_double_cell=none
  532: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  533:   $ac_cv_sizeof_short)
  534:     ac_cv_int_type_double_cell=short
  535:     ;;
  536:   $ac_cv_sizeof_int)
  537:     ac_cv_int_type_double_cell=int
  538:     ;;
  539:   $ac_cv_sizeof_long)
  540:     ac_cv_int_type_double_cell=long
  541:     ;;
  542:   $ac_cv_sizeof_long_long)
  543:     ac_cv_int_type_double_cell="long long"
  544:     ;;
  545:   $ac_cv_sizeof_intptr_t)
  546:     ac_cv_int_type_double_cell="intptr_t"
  547:     ;;
  548:   $ac_cv_sizeof_int128_t)
  549:     ac_cv_int_type_double_cell="int128_t"
  550:     ;;
  551: esac
  552: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  553: 
  554: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  555: ac_cv_int_type_double_ucell=none
  556: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  557:   $ac_cv_sizeof_short)
  558:     ac_cv_int_type_double_ucell="unsigned short"
  559:     ;;
  560:   $ac_cv_sizeof_int)
  561:     ac_cv_int_type_double_ucell="unsigned int"
  562:     ;;
  563:   $ac_cv_sizeof_long)
  564:     ac_cv_int_type_double_ucell="unsigned long"
  565:     ;;
  566:   $ac_cv_sizeof_long_long)
  567:     ac_cv_int_type_double_ucell="unsigned long long"
  568:     ;;
  569:   $ac_cv_sizeof_intptr_t)
  570:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  571:     ;;
  572:   $ac_cv_sizeof_uint128_t)
  573:     ac_cv_int_type_double_ucell="uint128_t"
  574:     ;;
  575: esac
  576: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  577: 
  578: if test "$ac_cv_int_type_double_cell" != none && \
  579:    test "$ac_cv_int_type_double_ucell" != none
  580: then
  581: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  582: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  583:         OPTS=-ll
  584: else
  585:         if test "$ac_cv_sizeof_char_p" = 8; then
  586:            OPTS="-ll -noll"
  587:         else
  588:            OPTS=-noll
  589:         fi
  590: fi
  591: 
  592: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
  593:    OPTS2=''
  594:    for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
  595:    OPTS="$OPTS2 $OPTS"
  596: else
  597:   AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
  598: fi
  599: AC_SUBST(OPTS)
  600: 
  601: AC_TYPE_OFF_T
  602: AC_CHECK_SIZEOF(off_t)
  603: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  604: ac_small_off_t=$?
  605: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  606: 
  607: ENGINE_FLAGS=
  608: AC_SUBST(ENGINE_FLAGS)
  609: 
  610: # Try if GCC understands -fno-gcse
  611: 
  612: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  613: CFLAGS_1="$CFLAGS"
  614: CFLAGS="$CFLAGS -fno-gcse"
  615: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  616: CFLAGS="$CFLAGS_1"
  617: AC_MSG_RESULT($ac_nogcse)
  618: 
  619: # Try if GCC understands -fno-strict-aliasing
  620: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  621: CFLAGS_1="$CFLAGS"
  622: CFLAGS="$CFLAGS -fno-strict-aliasing"
  623: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  624: CFLAGS="$CFLAGS_1"
  625: AC_MSG_RESULT($ac_nostrictaliasing)
  626: 
  627: # Try if GCC understands -fno-crossjumping
  628: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  629: CFLAGS_1="$CFLAGS"
  630: CFLAGS="$CFLAGS -fno-crossjumping"
  631: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  632: CFLAGS="$CFLAGS_1"
  633: AC_MSG_RESULT($ac_nocrossjumping)
  634: 
  635: # Try if GCC understands -fno-reorder-blocks
  636: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  637: CFLAGS_1="$CFLAGS"
  638: CFLAGS="$CFLAGS -fno-reorder-blocks"
  639: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  640: CFLAGS="$CFLAGS_1"
  641: AC_MSG_RESULT($ac_noreorder_blocks)
  642: 
  643: # Try if GCC understands -falign-labels=1
  644: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  645: CFLAGS_1="$CFLAGS"
  646: CFLAGS="$CFLAGS -falign-labels=1"
  647: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  648: CFLAGS="$CFLAGS_1"
  649: AC_MSG_RESULT($ac_align_labels)
  650: 
  651: # Try if GCC understands -falign-loops=1
  652: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
  653: CFLAGS_1="$CFLAGS"
  654: CFLAGS="$CFLAGS -falign-loops=1"
  655: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
  656: CFLAGS="$CFLAGS_1"
  657: AC_MSG_RESULT($ac_align_loops)
  658: 
  659: # Try if GCC understands -falign-jumps=1
  660: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
  661: CFLAGS_1="$CFLAGS"
  662: CFLAGS="$CFLAGS -falign-jumps=1"
  663: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
  664: CFLAGS="$CFLAGS_1"
  665: AC_MSG_RESULT($ac_align_jumps)
  666: 
  667: if test -z "$LIBTOOL_CC"
  668: then
  669:   LIBTOOL_CC="$CC"
  670:   # Try if GCC understands -Wimplicit-function-declaration
  671:   AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
  672:   CFLAGS_1="$CFLAGS"
  673:   CFLAGS="$CFLAGS -Wimplicit-function-declaration"
  674:   AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
  675:   CFLAGS="$CFLAGS_1"
  676:   AC_MSG_RESULT($ac_align_jumps)
  677: fi
  678: AC_SUBST(LIBTOOL_CC)
  679: 
  680: 
  681: 
  682: # Try if GCC understands __attribute__((unused))
  683: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  684: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  685: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  686: AC_MSG_RESULT($MAYBE_UNUSED)
  687: 
  688: # Try if GCC understands __thread
  689: AC_MSG_CHECKING([whether gcc understands '__thread'])
  690: AC_TRY_COMPILE(,[extern __thread int foo;],PER_THREAD='__thread',)
  691: AC_DEFINE_UNQUOTED(PER_THREAD,$PER_THREAD,[storage class for thread-local variables])
  692: AC_MSG_RESULT($PER_THREAD)
  693: 
  694: #try if m4 understands -s
  695: AC_MSG_CHECKING([how to invoke m4])
  696: if m4 -s /dev/null >/dev/null 2>&1; then
  697:  M4="m4 -s"
  698: else
  699:  M4=m4
  700: fi
  701: AC_SUBST(M4)
  702: AC_MSG_RESULT($M4)
  703: 
  704: # Find installed Gforth
  705: AC_MSG_CHECKING([for gforth])
  706: GFORTH="`cd / && which gforth 2>/dev/null`"
  707: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
  708: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null  && test "$srcdir" = ".") || GFORTH=""
  709: if test -z "$GFORTH"; then
  710:   PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
  711:   kernel_anti_dependence=''
  712: else
  713:   PREFORTH="$GFORTH -i `cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
  714:   kernel_anti_dependence='$(kernel_fi)'
  715: fi
  716: AC_SUBST(PREFORTH)
  717: AC_SUBST(kernel_anti_dependence)
  718: AC_MSG_RESULT($PREFORTH)
  719: 
  720: #echo "machine='$machine'"
  721: 
  722: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  723: if test x$EC_MODE = xfalse
  724: then
  725:   AS_IF([test -f $srcdir/arch/$machine/asm.fs],
  726:         [asm_fs=arch/$machine/asm.fs])
  727: fi
  728: AC_SUBST(asm_fs)
  729: 
  730: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  731: if test x$EC_MODE = xfalse
  732: then
  733:   AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
  734:    	[disasm_fs=arch/$machine/disasm.fs])
  735: fi
  736: AC_SUBST(disasm_fs)
  737: 
  738: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  739: 
  740: case "$host_os" in
  741: 	*win32*)
  742: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  743: 		DIRSEP="\\\\"
  744: 		PATHSEP=";"
  745: 		#we want the builtins of command.com/cmd.exe and its
  746: 		# handling of .com files.
  747: 		#$COMSPEC contains the name of the Windows shell;
  748: 		# the ./ is there, because the bash does not recognize
  749: 		# absolute DOS filenames
  750: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  751: 		;;
  752: 	*darwin*)
  753: 		#Darwin uses some funny preprocessor by default; eliminate it:
  754: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  755: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  756: 		DIRSEP="/"
  757: 		PATHSEP=":"
  758: 		DEFAULTSYSTEMPREFIX=""
  759:                 #the following magic value was suggested by
  760:                 #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
  761:                 AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
  762: 		;;
  763: 	*linux*)
  764: 		DIRSEP="/"
  765: 		PATHSEP=":"
  766: 		DEFAULTSYSTEMPREFIX=""
  767: 		if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
  768: 		   LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
  769: 		fi
  770: 		;;
  771: 	*)
  772: 		DIRSEP="/"
  773: 		PATHSEP=":"
  774: 		DEFAULTSYSTEMPREFIX=""
  775: 		;;
  776: esac
  777: AC_SUBST(DIRSEP)
  778: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  779: AC_SUBST(PATHSEP)
  780: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  781: AC_SUBST(DEFAULTSYSTEMPREFIX)
  782: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  783: if test -n "$LTDL_LIBRARY_PATH"; then
  784:    AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
  785: fi                                                                
  786: 
  787: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  788: #This magic incantation  seems to be completely undocumented.
  789: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  790: 
  791: dnl Now a little support for DOS/DJGCC
  792: GFORTHFAST_EXE="$GFORTH_EXE"
  793: GFORTHITC_EXE="$GFORTH_EXE"
  794: GFORTHDITC_EXE="$GFORTH_EXE"
  795: AC_SUBST(GFORTH_EXE)
  796: AC_SUBST(GFORTHFAST_EXE)
  797: AC_SUBST(GFORTHITC_EXE)
  798: AC_SUBST(GFORTHDITC_EXE)
  799: 
  800: AC_SUBST(FORTHSIZES)
  801: 
  802: dnl if test "$PEEPHOLE" = "yes"
  803: dnl then
  804: dnl    PEEPHOLEFLAG="true"
  805: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  806: dnl else
  807: dnl    PEEPHOLEFLAG="false"
  808: dnl fi
  809: PEEPHOLEFLAG="true"
  810: AC_SUBST(PEEPHOLEFLAG)
  811: 
  812: dnl copy commands for systems that don't have links
  813: AC_SUBST(LINK_KERNL)
  814: LINK_KERNL=""
  815: 
  816: #if test $host_os=dos
  817: #then
  818: #  echo Configuring for DOS!!!
  819: #  MAKE_EXE="coff2exe gforth"
  820: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  821: #fi
  822: 
  823: dnl the following macro produces a warning with autoconf-2.1
  824: AC_C_BIGENDIAN
  825: AC_SUBST(KERNEL)
  826: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  827: if test $ac_cv_c_bigendian != no; then
  828:   bytesex=b
  829:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  830: else
  831:   bytesex=l
  832:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  833: fi
  834: 
  835: #check how to do asm(".skip 16")
  836: #echo "CFLAGS=$CFLAGS"
  837: #echo "ac_link=$ac_link"
  838: AC_MSG_CHECKING([if and how we can waste code space])
  839: if test -z "$skipcode" && test x$cross_compiling = xyes; then
  840:    # we cannot perform the AC_TRY_RUN check when cross-compiling.  
  841:    skipcode=no
  842:    AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
  843: elif test -z "$skipcode"; then
  844:     skipcode=no
  845:     CFLAGS_1="$CFLAGS"
  846:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  847:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  848:     do
  849: 	AC_TRY_RUN(
  850: [int foo(int,int,int);
  851: main()
  852: {
  853:   exit(foo(0,0,0)!=16);
  854: }
  855: int foo(int x, int y, int z)
  856: {
  857:   static void *labels[]={&&label1, &&label2};
  858:   if (x) {
  859:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  860:   label1:
  861:     asm("$i"); /* or ".space 16" or somesuch */
  862:   label2: ;
  863:   }
  864:   {
  865:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  866:   return labels[1]-labels[0];
  867:   }
  868: }]
  869: 	,skipcode=$i; break
  870: 	,,)
  871:     done
  872:     CFLAGS=$CFLAGS_1
  873: fi
  874: AC_MSG_RESULT($skipcode)
  875: if test "$skipcode" = no
  876: then 
  877:     if test -z $no_dynamic_default; then
  878: 	no_dynamic_default=1
  879: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  880:     fi
  881:     AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
  882: else
  883:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  884: fi
  885: 
  886: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  887: #the point here is to get asm statements that look different to
  888: #gcc's "optimizer"
  889: if test -z "$asmcomment"; then
  890:     asmcomment=no
  891:     CFLAGS_1="$CFLAGS"
  892:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  893:     for i in '"# "' '"! "' '"; "'; do
  894: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  895:     done
  896:     CFLAGS=$CFLAGS_1
  897: fi
  898: AC_MSG_RESULT($asmcomment)
  899: if test "$asmcomment" != no
  900: then 
  901:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  902: fi
  903: 
  904: test "$no_dynamic_default" || no_dynamic_default=0
  905: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  906: 
  907: dnl Checks for programs.
  908: AC_PROG_LN_S
  909: AC_PROG_INSTALL
  910: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  911: 
  912: dnl check for the presence of Emacs
  913: AC_CHECK_PROGS(EMACS,emacs xemacs)
  914: test -n "$EMACS" && gforth_elc=gforth.elc
  915: AC_SUBST(gforth_elc)
  916: 
  917: dnl MacOS X has a libtool that does something else
  918: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
  919: 
  920: dnl Checks for library functions
  921: dnl This check is just for making later checks link with libm.
  922: dnl using sin here is no good idea since it is built-into gcc and typechecked
  923: AC_CHECK_LIB(m,asin)
  924: AC_CHECK_LIB(ltdl,lt_dlinit)
  925: 
  926: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
  927:   build_libcc_named=build-libcc-named
  928: else
  929:   build_libcc_named=""
  930:   AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
  931: fi
  932: AC_SUBST(build_libcc_named)
  933: 
  934: 
  935: if test -z "$GNU_LIBTOOL"; then
  936:   AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
  937:   AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
  938:   GNU_LIBTOOL=libtool
  939: fi
  940: 
  941: #check for libffi 2.x
  942: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
  943: if test -z "$FFI_H_NAME"; then
  944:   AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
  945: fi
  946: AC_SUBST(FFI_H_NAME)
  947: AC_CHECK_LIB(ffi,ffi_call,LIBS="$LIBS")
  948: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
  949: then
  950:   LIBFFIFLAG="true"
  951:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
  952: else
  953:   LIBFFIFLAG="false"
  954: fi
  955: #check for ffcall libraries
  956: #unfortunately, these four calls are separated out into a library each.
  957: AC_CHECK_LIB(avcall,__builtin_avcall,LIBS="$LIBS")
  958: dnl AC_CHECK_LIB(callback,__vacall_r)
  959: dnl AC_CHECK_LIB(vacall,vacall)
  960: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
  961: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
  962:   FFCALLFLAG="true"
  963:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
  964: else
  965:   FFCALLFLAG="false"
  966: fi
  967: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
  968:   AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
  969: fi
  970: AC_SUBST(LIBFFIFLAG)
  971: AC_SUBST(FFCALLFLAG)
  972: AC_SUBST(LIBCC_BUILD_SRC)
  973: if test "$host_os" != "nextstep3"
  974: then
  975: 	AC_FUNC_MEMCMP
  976: fi
  977: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  978: AC_FUNC_FSEEKO
  979: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
  980: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  981: AC_DECL_SYS_SIGLIST
  982: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  983: AC_CHECK_FUNCS(expm1 log1p)
  984: AC_REPLACE_FUNCS(rint ecvt)
  985: dnl No check for select, because our replacement is no good under
  986: dnl anything but DOS
  987: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
  988: AC_FUNC_FNMATCH
  989: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  990: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
  991: AM_PATH_LISPDIR
  992: 
  993: kernel_fi=kernl${vwordsize}${bytesex}.fi
  994: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  995: AC_SUBST(kernel_fi)
  996: AC_SUBST(include_fi)
  997: 
  998: #this breaks bindists
  999: #dnl replace srource directory by absolute value
 1000: #if test $srcdir = "."; then srcdir=`pwd` 
 1001: #fi
 1002: 
 1003: AC_SUBST(machine)
 1004: AC_CONFIG_FILES([
 1005: Makefile
 1006: Makedist
 1007: gforthmi
 1008: vmgen
 1009: machpc.fs
 1010: envos.fs
 1011: preforth
 1012: engine/Makefile
 1013: engine/libcc.h
 1014: doc/version.texi
 1015: build-ec ])
 1016: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
 1017: chmod +x gforthmi
 1018: chmod +x vmgen
 1019: chmod +x build-ec
 1020: chmod +x preforth
 1021: test -d kernel||mkdir kernel
 1022: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
 1023: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
 1024: $srcdir/mkinstalldirs arch/$machine
 1025: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],
 1026: [PACKAGE_VERSION=$PACKAGE_VERSION
 1027:  machine=$machine])
 1028: AC_OUTPUT

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>