File:  [gforth] / gforth / configure.in
Revision 1.282: download - view: text, annotated - select for diffs
Mon Sep 13 18:18:11 2010 UTC (9 years, 1 month ago) by dvdkhlng
Branches: MAIN
CVS tags: HEAD
bugfix: when host=i486-linux-gnu, configure added option -m486 to the GCC
command line.  That option is long deprecated and does not work with newer GCC
version (not with 4.3.3).
Now try march=-i486, -m486, (none) in that order, for which one works.
Also changed GCC options for 586 and later:
- Also try to add -mtune=generic
- when falling back to -m486, try if that works, and else fall back to (none)

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation, either version 3
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.7.0-20100807],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: AC_PREREQ(2.54)
   25: #snapshots have numbers major.minor.release-YYYYMMDD
   26: #note that lexicographic ordering must be heeded.
   27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   28: UPDATED="November 8, 2008"
   29: AC_SUBST(UPDATED)
   30: AC_CONFIG_HEADERS(engine/config.h)
   31: 
   32: #remnants from having ltdl as convenience library
   33: LTDLDEPS=""
   34: LTDLINCL=""
   35: LIBLTDL=""
   36: LTDL_LDLIBS=""
   37: AC_SUBST(LTDLDEPS)
   38: AC_SUBST(LTDLINCL)
   39: AC_SUBST(LIBLTDL)
   40: AC_SUBST(LTDL_LDLIBS)
   41: 
   42: #suppress the "-g -O2" default
   43: test "$CFLAGS" || CFLAGS=-O2
   44: 
   45: AC_ARG_ENABLE(force-cdiv,
   46: 	AC_HELP_STRING([--enable-force-cdiv],
   47: 		       [  Use the native C division - symmetric - instead of
   48: 		          floored division (default disabled).]),
   49: 	,enable_force_cdiv=no)
   50: test "$enable_force_cdiv" = "no"||
   51:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   52: 
   53: AC_SUBST(PROFEXES)
   54: AC_SUBST(PROFOBJS)
   55: AC_ARG_ENABLE(prof,
   56: 	AC_HELP_STRING([--enable-prof],
   57: 			[ Build gforth-prof, which outputs frequently occuring
   58:                           sequences of primitives.]),
   59: 	,enable_prof=no)
   60: if test "$enable_prof" != "no"; then
   61:   PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
   62: fi
   63: 
   64: AC_ARG_WITH(debug,
   65: [  --with-debug		  specifies option -g to compile with debug info
   66:   --without-debug	  omits the -g switch and creates smaller images on
   67: 			  machines where "strip" has problems with gcc style
   68: 			  debugging informations.],
   69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   70: 
   71: GCC_LD="\$(GCC)"
   72: EC_MODE="false"
   73: NO_EC=""
   74: EC=""
   75: engine2='engine2$(OPT).o'
   76: engine_fast2='engine-fast2$(OPT).o'
   77: no_dynamic=""
   78: image_i=""
   79: signals_o="io.o signals.o"
   80: 
   81: AC_CANONICAL_HOST
   82: AC_ARG_WITH(ec,
   83: 	AC_HELP_STRING([--with-ec=<arch>],
   84: 			[  Build gforth for systems without OS.]),
   85: [if test "$withval" = "no"; then
   86:   echo "defining hosted system"
   87: else
   88:   echo "defining standalone system (${withval})"
   89:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
   90:   EC_MODE="true"
   91:   EC="-ec"
   92:   NO_EC="#"
   93:   engine2=""
   94:   engine_fast2=""
   95:   no_dynamic="-DNO_DYNAMIC"
   96:   image_i="image.i"
   97:   if test "$withval" != "yes"; then
   98:     signals_o="io-${withval}.o"
   99:   else
  100:     signals_o="io.o"
  101:   fi
  102:   if test -f "arch/$host_cpu/${withval}/config.sh"; then
  103:     source "arch/$host_cpu/${withval}/config.sh"
  104:   fi
  105:   GCC_PATH=$(which $CC)
  106:   LIB_PATH=${GCC_PATH%/*/*}
  107:   GCC_LD="\$(LD)"
  108:   platform=${withval}
  109: fi])
  110: 
  111: #variables mentioned in INSTALL
  112: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
  113: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  114: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  115: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  116: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  117: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
  118: 
  119: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  120: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  121: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  122: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  123: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  124: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  125: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  126: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  127: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  128: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  129: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  130: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  131: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  132: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  133: AC_ARG_VAR(asmcomment, [assembler comment start string])
  134: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  135: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
  136: 
  137: #set up feature test macros, so the tests get them right:
  138: # turn on all POSIX, SUSv3, and GNU features if available
  139: AC_GNU_SOURCE
  140: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  141: 
  142: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  143: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  144: dnl but not for _XOPEN_SOURCE)
  145: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  146: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  147: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  148: # turn on large file support with 64-bit off_t where available
  149: AC_SYS_LARGEFILE
  150: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  151: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  152: 
  153: #currently we force direct threading this way.  Eventually we should
  154: #setup in the arch and engine files right
  155: 
  156: AC_PROG_CC
  157: 
  158: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  159: 
  160: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  161: test x$condbranch_opt = x && 
  162: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
  163:    condbranch_opt=0
  164: else
  165:    condbranch_opt=1
  166: fi
  167: AC_MSG_RESULT($condbranch_opt)
  168: AC_SUBST(condbranch_opt)
  169: 
  170: AC_SUBST(CC)
  171: AC_SUBST(GCC_LD)
  172: AC_SUBST(DEBUGFLAG)
  173: AC_SUBST(EC)
  174: AC_SUBST(NO_EC)
  175: AC_SUBST(EC_MODE)
  176: AC_SUBST(engine2)
  177: AC_SUBST(engine_fast2)
  178: AC_SUBST(no_dynamic)
  179: AC_SUBST(image_i)
  180: AC_SUBST(signals_o)
  181: 
  182: #this is used to disable some (not generally essential) part of the
  183: #Makefile that some makes don't grok.  It would be better to test for
  184: #this specific Makefile feature than the make version.
  185: AC_MSG_CHECKING(make type)
  186: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  187: GNUMAKE='#'
  188: test "$make_type" = "GNU Make" && GNUMAKE=''
  189: AC_MSG_RESULT($make_type)
  190: AC_SUBST(GNUMAKE)
  191: 
  192: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  193: OLDLDFLAGS=$LDFLAGS
  194: LDFLAGS="$LDFLAGS -export-dynamic"
  195: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  196: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  197: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  198: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  199: AC_MSG_RESULT($ac_export_dynamic)
  200: 
  201: #terminology is a bit unusual here: The host is the system on which
  202: #gforth will run; the system on which configure will run is the `build'
  203: case "$host_cpu" in
  204: 	arm*)
  205: 		machine=arm
  206: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  207: 		if test x$platform = xnxt; then
  208: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  209: 		fi
  210: 		if test -z $arm_cacheflush; then
  211: 		   case "$host_os" in
  212: 		     *linux*)
  213: 			AC_LIBOBJ(../arch/arm/cacheflush-linux) 
  214: 			;;
  215: 		     *)   
  216: 			no_dynamic_default=1
  217: 			AC_LIBOBJ(../arch/arm/cacheflush0)
  218: 			AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  219: 			;;
  220:                    esac
  221:                 else
  222:                    AC_LIBOBJ(../$arm_cacheflush)
  223:                    test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
  224: 		fi
  225:                 #longer skipcodes lead to problems on ARM, and it uses
  226:                 #only 4-byte alignment anyway
  227: 		test "$skipcode" || skipcode="nop"
  228: 		;;
  229: 	hppa*)
  230: 		machine=hppa
  231: 		AC_LIBOBJ(../arch/hppa/cache)
  232: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  233: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  234: 		LIBS="$LIBS -L/lib/pa1.1/"
  235: 		;;
  236: 	sparc*)
  237: 		machine=sparc
  238: 		;;
  239: 	i386)
  240: 		machine=386
  241: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  242: 		;;
  243: 	i486)
  244: 		machine=386
  245: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  246: 		CFLAGS_1="$CFLAGS"
  247: 		CFLAGS="$CFLAGS -march=i486"
  248: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  249: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  250: 		;;
  251: 	i*86)
  252: 		machine=386
  253: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  254: 		CFLAGS_1="$CFLAGS"
  255: 		CFLAGS="$CFLAGS -march=pentium -mtune=generic"
  256: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
  257: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  258: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  259: 		;;
  260: 	x86_64)
  261: 		case $CC
  262: 		in
  263: 		    *-m32*)
  264: 		    	machine=386
  265: 			CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  266: 			CFLAGS_1="$CFLAGS"
  267: 			CFLAGS="$CFLAGS -march=athlon64"
  268: 			;;
  269: 		    *)
  270: 		    	machine=amd64
  271: 			;;
  272: 		esac
  273: 		;;
  274: 	ia64*)
  275: 		machine=ia64
  276: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  277: 		test "$skipcode" || skipcode="nop.i 0"
  278: 		#".skip 16" passes the test below,
  279: 		# but gives an assembler error in engine
  280: 		;;
  281:         m68k)
  282: 		machine=m68k
  283: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  284: 		if test "$host_os" = "nextstep3"
  285: 		then
  286: 			AC_LIBOBJ(termios)
  287: 		fi
  288: 		;;
  289: 	mips*)
  290: 		machine=mips
  291: 		AC_LIBOBJ(../arch/mips/check_prim) 
  292: 		#dynamic native code has the following problems on MIPS:
  293: 		#
  294: 		#1) J/JAL seems relocatable, but is are only
  295: 		#relocatable within a 256MB-segment.  While we try to
  296: 		#get the linker to arrange this, there is no guarantee
  297: 		#that this will succeed (and if the user uses a lot of
  298: 		#memory, it is likely to fail).
  299: 		#
  300: 		#2) The way we generate dynamic native code may
  301: 		#violate MIPS architectural restrictions (in
  302: 		#particular, the delay slots of LW, MFLO, etc.)
  303: 		#
  304: 		#Therefore we disable dynamic native code by default:
  305: 		if test -z "$no_dynamic_default"; then
  306: 		    no_dynamic_default=1
  307: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  308: 		fi
  309: 		;;
  310: 	alpha*)
  311: 		machine=alpha
  312: 		#full IEEE FP support for more uniformity across platforms:
  313: 		CFLAGS="$CFLAGS -mieee"
  314: 		;;
  315: 	power*|rs6000)
  316: 		machine=power
  317: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  318: 		#long long is broken on (at least) gcc-2.95.* for PPC
  319: 		test x$ac_cv_sizeof_long_long = x && 
  320: 		($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
  321:                      ac_cv_sizeof_long_long=0
  322:                 #The only architecture with enough callee-saved registers
  323:                 test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
  324:                 #or use 2, hardly slower at run-time and starts up faster
  325: 
  326:                 #the skipcode that is normally selected below does not
  327:                 #work with gcc-3.[34]
  328: 		test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
  329: 		;;
  330: 	*)
  331: 		AC_MSG_WARN([Using a generic machine description])
  332: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  333: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  334: 		machine=generic
  335: 		#I-cache flushing would be needed for dynamic code generation
  336: 		if test -z $no_dynamic_default; then
  337: 		    no_dynamic_default=1
  338: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  339: 		fi
  340: esac
  341: AC_SUBST(host)
  342: 
  343: MAKEINC=""
  344: GFORTH_EXE="true"
  345: 
  346: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  347: if test x$EC_MODE = xtrue
  348: then
  349: 	echo "Check for arch/$machine/$platform/gforth.ld"
  350: 	if test -f arch/$machine/$platform/gforth.ld
  351: 	then
  352: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  353: 		if test x$platform = xnxt; then
  354: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  355: 		fi
  356: 	fi
  357: 	if test -f arch/$machine/$platform/make.inc
  358: 	then
  359: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  360: 		GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
  361: 	fi
  362: fi
  363: AC_SUBST(MAKEINC)
  364: 
  365: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  366: 
  367: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
  368: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
  369: 		   [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
  370: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  371: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  372: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  373: 
  374: test x$GCC_PR15242_WORKAROUND = x ||
  375: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  376:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  377: 
  378: dnl the following macro produces a warning with autoconf-2.1
  379: AC_CHECK_SIZEOF(char *)
  380: case "$ac_cv_sizeof_char_p" in
  381:   2)
  382:     wordsize=16
  383:     ;;
  384:   4)
  385:     wordsize=32
  386:     ;;
  387:   8)
  388:     wordsize=64
  389:     ;;
  390: esac
  391: 
  392: AC_CHECK_SIZEOF(void *)
  393: case "$ac_cv_sizeof_void_p" in
  394:   2)
  395:     vwordsize=16
  396:     ;;
  397:   4)
  398:     vwordsize=32
  399:     ;;
  400:   8)
  401:     vwordsize=64
  402:     ;;
  403: esac
  404: 
  405: AC_CHECK_SIZEOF(char)
  406: AC_CHECK_SIZEOF(short)
  407: AC_CHECK_SIZEOF(int)
  408: AC_CHECK_SIZEOF(long)
  409: AC_CHECK_SIZEOF(long long)
  410: AC_CHECK_SIZEOF(intptr_t)
  411: AC_CHECK_SIZEOF(int128_t)
  412: AC_CHECK_SIZEOF(uint128_t)
  413: 
  414: AC_MSG_CHECKING([for a C type for cells])
  415: ac_cv_int_type_cell=none
  416: case "$ac_cv_sizeof_char_p" in
  417:   $ac_cv_sizeof_int)
  418:     ac_cv_int_type_cell=int
  419:     ;;
  420:   $ac_cv_sizeof_short)
  421:     ac_cv_int_type_cell=short
  422:     ;;
  423:   $ac_cv_sizeof_char)
  424:     ac_cv_int_type_cell=char
  425:     ;;
  426:   $ac_cv_sizeof_long)
  427:     ac_cv_int_type_cell=long
  428:     ;;
  429:   $ac_cv_sizeof_long_long)
  430:     ac_cv_int_type_cell="long long"
  431:     ;;
  432:   $ac_cv_sizeof_intptr_t)
  433:     ac_cv_int_type_cell="intptr_t"
  434:     ;;
  435: esac
  436: AC_MSG_RESULT($ac_cv_int_type_cell)
  437: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  438: 
  439: AC_MSG_CHECKING([for a C type for wydes])
  440: ac_cv_wyde_type_cell=none
  441: case 2 in
  442:   $ac_cv_sizeof_int)
  443:     ac_cv_wyde_type_cell=int
  444:     ;;
  445:   $ac_cv_sizeof_short)
  446:     ac_cv_wyde_type_cell=short
  447:     ;;
  448:   $ac_cv_sizeof_char)
  449:     ac_cv_wyde_type_cell=char
  450:     ;;
  451:   $ac_cv_sizeof_long)
  452:     ac_cv_wyde_type_cell=long
  453:     ;;
  454:   $ac_cv_sizeof_long_long)
  455:     ac_cv_wyde_type_cell="long long"
  456:     ;;
  457:   $ac_cv_sizeof_intptr_t)
  458:     ac_cv_wyde_type_cell="intptr_t"
  459:     ;;
  460: esac
  461: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  462: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  463: 
  464: AC_MSG_CHECKING([for a C type for tetrabytes])
  465: ac_cv_tetrabyte_type_cell=none
  466: case 4 in
  467:   $ac_cv_sizeof_int)
  468:     ac_cv_tetrabyte_type_cell=int
  469:     ;;
  470:   $ac_cv_sizeof_short)
  471:     ac_cv_tetrabyte_type_cell=short
  472:     ;;
  473:   $ac_cv_sizeof_char)
  474:     ac_cv_tetrabyte_type_cell=char
  475:     ;;
  476:   $ac_cv_sizeof_long)
  477:     ac_cv_tetrabyte_type_cell=long
  478:     ;;
  479:   $ac_cv_sizeof_long_long)
  480:     ac_cv_tetrabyte_type_cell="long long"
  481:     ;;
  482:   $ac_cv_sizeof_intptr_t)
  483:     ac_cv_tetrabyte_type_cell="intptr_t"
  484:     ;;
  485: esac
  486: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  487: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  488: 
  489: AC_MSG_CHECKING([for a C type for octabytes])
  490: ac_cv_octabyte_type_cell=none
  491: case 8 in
  492:   $ac_cv_sizeof_int)
  493:     ac_cv_octabyte_type_cell=int
  494:     ;;
  495:   $ac_cv_sizeof_short)
  496:     ac_cv_octabyte_type_cell=short
  497:     ;;
  498:   $ac_cv_sizeof_char)
  499:     ac_cv_octabyte_type_cell=char
  500:     ;;
  501:   $ac_cv_sizeof_long)
  502:     ac_cv_octabyte_type_cell=long
  503:     ;;
  504:   $ac_cv_sizeof_long_long)
  505:     ac_cv_octabyte_type_cell="long long"
  506:     ;;
  507:   $ac_cv_sizeof_intptr_t)
  508:     ac_cv_octabyte_type_cell="intptr_t"
  509:     ;;
  510: esac
  511: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
  512: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
  513: 
  514: AC_MSG_CHECKING([for a C type for double-cells])
  515: ac_cv_int_type_double_cell=none
  516: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  517:   $ac_cv_sizeof_short)
  518:     ac_cv_int_type_double_cell=short
  519:     ;;
  520:   $ac_cv_sizeof_int)
  521:     ac_cv_int_type_double_cell=int
  522:     ;;
  523:   $ac_cv_sizeof_long)
  524:     ac_cv_int_type_double_cell=long
  525:     ;;
  526:   $ac_cv_sizeof_long_long)
  527:     ac_cv_int_type_double_cell="long long"
  528:     ;;
  529:   $ac_cv_sizeof_intptr_t)
  530:     ac_cv_int_type_double_cell="intptr_t"
  531:     ;;
  532:   $ac_cv_sizeof_int128_t)
  533:     ac_cv_int_type_double_cell="int128_t"
  534:     ;;
  535: esac
  536: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  537: 
  538: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  539: ac_cv_int_type_double_ucell=none
  540: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  541:   $ac_cv_sizeof_short)
  542:     ac_cv_int_type_double_ucell="unsigned short"
  543:     ;;
  544:   $ac_cv_sizeof_int)
  545:     ac_cv_int_type_double_ucell="unsigned int"
  546:     ;;
  547:   $ac_cv_sizeof_long)
  548:     ac_cv_int_type_double_ucell="unsigned long"
  549:     ;;
  550:   $ac_cv_sizeof_long_long)
  551:     ac_cv_int_type_double_ucell="unsigned long long"
  552:     ;;
  553:   $ac_cv_sizeof_intptr_t)
  554:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  555:     ;;
  556:   $ac_cv_sizeof_uint128_t)
  557:     ac_cv_int_type_double_ucell="uint128_t"
  558:     ;;
  559: esac
  560: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  561: 
  562: if test "$ac_cv_int_type_double_cell" != none && \
  563:    test "$ac_cv_int_type_double_ucell" != none
  564: then
  565: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  566: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  567:         OPTS=-ll
  568: else
  569:         if test "$ac_cv_sizeof_char_p" = 8; then
  570:            OPTS="-ll -noll"
  571:         else
  572:            OPTS=-noll
  573:         fi
  574: fi
  575: 
  576: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
  577:    OPTS2=''
  578:    for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
  579:    OPTS="$OPTS2 $OPTS"
  580: else
  581:   AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
  582: fi
  583: AC_SUBST(OPTS)
  584: 
  585: AC_TYPE_OFF_T
  586: AC_CHECK_SIZEOF(off_t)
  587: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  588: ac_small_off_t=$?
  589: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  590: 
  591: ENGINE_FLAGS=
  592: AC_SUBST(ENGINE_FLAGS)
  593: 
  594: # Try if GCC understands -fno-gcse
  595: 
  596: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  597: CFLAGS_1="$CFLAGS"
  598: CFLAGS="$CFLAGS -fno-gcse"
  599: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  600: CFLAGS="$CFLAGS_1"
  601: AC_MSG_RESULT($ac_nogcse)
  602: 
  603: # Try if GCC understands -fno-strict-aliasing
  604: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  605: CFLAGS_1="$CFLAGS"
  606: CFLAGS="$CFLAGS -fno-strict-aliasing"
  607: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  608: CFLAGS="$CFLAGS_1"
  609: AC_MSG_RESULT($ac_nostrictaliasing)
  610: 
  611: # Try if GCC understands -fno-crossjumping
  612: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  613: CFLAGS_1="$CFLAGS"
  614: CFLAGS="$CFLAGS -fno-crossjumping"
  615: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  616: CFLAGS="$CFLAGS_1"
  617: AC_MSG_RESULT($ac_nocrossjumping)
  618: 
  619: # Try if GCC understands -fno-reorder-blocks
  620: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  621: CFLAGS_1="$CFLAGS"
  622: CFLAGS="$CFLAGS -fno-reorder-blocks"
  623: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  624: CFLAGS="$CFLAGS_1"
  625: AC_MSG_RESULT($ac_noreorder_blocks)
  626: 
  627: # Try if GCC understands -falign-labels=1
  628: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  629: CFLAGS_1="$CFLAGS"
  630: CFLAGS="$CFLAGS -falign-labels=1"
  631: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  632: CFLAGS="$CFLAGS_1"
  633: AC_MSG_RESULT($ac_align_labels)
  634: 
  635: # Try if GCC understands -falign-loops=1
  636: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
  637: CFLAGS_1="$CFLAGS"
  638: CFLAGS="$CFLAGS -falign-loops=1"
  639: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
  640: CFLAGS="$CFLAGS_1"
  641: AC_MSG_RESULT($ac_align_loops)
  642: 
  643: # Try if GCC understands -falign-jumps=1
  644: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
  645: CFLAGS_1="$CFLAGS"
  646: CFLAGS="$CFLAGS -falign-jumps=1"
  647: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
  648: CFLAGS="$CFLAGS_1"
  649: AC_MSG_RESULT($ac_align_jumps)
  650: 
  651: if test -z "$LIBTOOL_CC"
  652: then
  653:   LIBTOOL_CC="$CC"
  654:   # Try if GCC understands -Wimplicit-function-declaration
  655:   AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
  656:   CFLAGS_1="$CFLAGS"
  657:   CFLAGS="$CFLAGS -Wimplicit-function-declaration"
  658:   AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
  659:   CFLAGS="$CFLAGS_1"
  660:   AC_MSG_RESULT($ac_align_jumps)
  661: fi
  662: AC_SUBST(LIBTOOL_CC)
  663: 
  664: 
  665: 
  666: # Try if GCC understands __attribute__((unused))
  667: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  668: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  669: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  670: AC_MSG_RESULT($MAYBE_UNUSED)
  671: 
  672: #try if m4 understands -s
  673: AC_MSG_CHECKING([how to invoke m4])
  674: if m4 -s /dev/null >/dev/null 2>&1; then
  675:  M4="m4 -s"
  676: else
  677:  M4=m4
  678: fi
  679: AC_SUBST(M4)
  680: AC_MSG_RESULT($M4)
  681: 
  682: # Find installed Gforth
  683: AC_MSG_CHECKING([for gforth])
  684: GFORTH="`cd / && which gforth 2>/dev/null`"
  685: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
  686: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null  && test "$srcdir" = ".") || GFORTH=""
  687: if test -z "$GFORTH"; then
  688:   PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
  689:   kernel_anti_dependence=''
  690: else
  691:   PREFORTH="$GFORTH -i `cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
  692:   kernel_anti_dependence='$(kernel_fi)'
  693: fi
  694: AC_SUBST(PREFORTH)
  695: AC_SUBST(kernel_anti_dependence)
  696: AC_MSG_RESULT($PREFORTH)
  697: 
  698: #echo "machine='$machine'"
  699: 
  700: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  701: if test x$EC_MODE = xfalse
  702: then
  703:   AS_IF([test -f $srcdir/arch/$machine/asm.fs],
  704:         [asm_fs=arch/$machine/asm.fs])
  705: fi
  706: AC_SUBST(asm_fs)
  707: 
  708: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  709: if test x$EC_MODE = xfalse
  710: then
  711:   AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
  712:    	[disasm_fs=arch/$machine/disasm.fs])
  713: fi
  714: AC_SUBST(disasm_fs)
  715: 
  716: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  717: 
  718: case "$host_os" in
  719: 	*win32*)
  720: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  721: 		DIRSEP="\\\\"
  722: 		PATHSEP=";"
  723: 		#we want the builtins of command.com/cmd.exe and its
  724: 		# handling of .com files.
  725: 		#$COMSPEC contains the name of the Windows shell;
  726: 		# the ./ is there, because the bash does not recognize
  727: 		# absolute DOS filenames
  728: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  729: 		;;
  730: 	*darwin*)
  731: 		#Darwin uses some funny preprocessor by default; eliminate it:
  732: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  733: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  734: 		DIRSEP="/"
  735: 		PATHSEP=":"
  736: 		DEFAULTSYSTEMPREFIX=""
  737:                 #the following magic value was suggested by
  738:                 #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
  739:                 AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
  740: 		;;
  741: 	*linux*)
  742: 		DIRSEP="/"
  743: 		PATHSEP=":"
  744: 		DEFAULTSYSTEMPREFIX=""
  745: 		if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
  746: 		   LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
  747: 		fi
  748: 		;;
  749: 	*)
  750: 		DIRSEP="/"
  751: 		PATHSEP=":"
  752: 		DEFAULTSYSTEMPREFIX=""
  753: 		;;
  754: esac
  755: AC_SUBST(DIRSEP)
  756: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  757: AC_SUBST(PATHSEP)
  758: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  759: AC_SUBST(DEFAULTSYSTEMPREFIX)
  760: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  761: if test -n "$LTDL_LIBRARY_PATH"; then
  762:    AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
  763: fi                                                                
  764: 
  765: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  766: #This magic incantation  seems to be completely undocumented.
  767: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  768: 
  769: dnl Now a little support for DOS/DJGCC
  770: GFORTHFAST_EXE="$GFORTH_EXE"
  771: GFORTHITC_EXE="$GFORTH_EXE"
  772: GFORTHDITC_EXE="$GFORTH_EXE"
  773: AC_SUBST(GFORTH_EXE)
  774: AC_SUBST(GFORTHFAST_EXE)
  775: AC_SUBST(GFORTHITC_EXE)
  776: AC_SUBST(GFORTHDITC_EXE)
  777: 
  778: AC_SUBST(FORTHSIZES)
  779: 
  780: dnl if test "$PEEPHOLE" = "yes"
  781: dnl then
  782: dnl    PEEPHOLEFLAG="true"
  783: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  784: dnl else
  785: dnl    PEEPHOLEFLAG="false"
  786: dnl fi
  787: PEEPHOLEFLAG="true"
  788: AC_SUBST(PEEPHOLEFLAG)
  789: 
  790: dnl copy commands for systems that don't have links
  791: AC_SUBST(LINK_KERNL)
  792: LINK_KERNL=""
  793: 
  794: #if test $host_os=dos
  795: #then
  796: #  echo Configuring for DOS!!!
  797: #  MAKE_EXE="coff2exe gforth"
  798: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  799: #fi
  800: 
  801: dnl the following macro produces a warning with autoconf-2.1
  802: AC_C_BIGENDIAN
  803: AC_SUBST(KERNEL)
  804: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  805: if test $ac_cv_c_bigendian != no; then
  806:   bytesex=b
  807:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  808: else
  809:   bytesex=l
  810:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  811: fi
  812: 
  813: #check how to do asm(".skip 16")
  814: #echo "CFLAGS=$CFLAGS"
  815: #echo "ac_link=$ac_link"
  816: AC_MSG_CHECKING([if and how we can waste code space])
  817: if test -z "$skipcode" && test x$cross_compiling = xyes; then
  818:    # we cannot perform the AC_TRY_RUN check when cross-compiling.  
  819:    skipcode=no
  820:    AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
  821: elif test -z "$skipcode"; then
  822:     skipcode=no
  823:     CFLAGS_1="$CFLAGS"
  824:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  825:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  826:     do
  827: 	AC_TRY_RUN(
  828: [int foo(int,int,int);
  829: main()
  830: {
  831:   exit(foo(0,0,0)!=16);
  832: }
  833: int foo(int x, int y, int z)
  834: {
  835:   static void *labels[]={&&label1, &&label2};
  836:   if (x) {
  837:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  838:   label1:
  839:     asm("$i"); /* or ".space 16" or somesuch */
  840:   label2: ;
  841:   }
  842:   {
  843:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  844:   return labels[1]-labels[0];
  845:   }
  846: }]
  847: 	,skipcode=$i; break
  848: 	,,)
  849:     done
  850:     CFLAGS=$CFLAGS_1
  851: fi
  852: AC_MSG_RESULT($skipcode)
  853: if test "$skipcode" = no
  854: then 
  855:     if test -z $no_dynamic_default; then
  856: 	no_dynamic_default=1
  857: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  858:     fi
  859:     AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
  860: else
  861:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  862: fi
  863: 
  864: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  865: #the point here is to get asm statements that look different to
  866: #gcc's "optimizer"
  867: if test -z "$asmcomment"; then
  868:     asmcomment=no
  869:     CFLAGS_1="$CFLAGS"
  870:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  871:     for i in '"# "' '"! "' '"; "'; do
  872: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  873:     done
  874:     CFLAGS=$CFLAGS_1
  875: fi
  876: AC_MSG_RESULT($asmcomment)
  877: if test "$asmcomment" != no
  878: then 
  879:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  880: fi
  881: 
  882: test "$no_dynamic_default" || no_dynamic_default=0
  883: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  884: 
  885: dnl Checks for programs.
  886: AC_PROG_LN_S
  887: AC_PROG_INSTALL
  888: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  889: 
  890: dnl MacOS X has a libtool that does something else
  891: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
  892: 
  893: dnl Checks for library functions
  894: dnl This check is just for making later checks link with libm.
  895: dnl using sin here is no good idea since it is built-into gcc and typechecked
  896: AC_CHECK_LIB(m,asin)
  897: AC_CHECK_LIB(ltdl,lt_dlinit)
  898: 
  899: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
  900:   build_libcc_named=build-libcc-named
  901: else
  902:   build_libcc_named=""
  903:   AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
  904: fi
  905: AC_SUBST(build_libcc_named)
  906: 
  907: 
  908: if test -z "$GNU_LIBTOOL"; then
  909:   AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
  910:   AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
  911:   GNU_LIBTOOL=libtool
  912: fi
  913: 
  914: #check for libffi 2.x
  915: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
  916: if test -z "$FFI_H_NAME"; then
  917:   AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
  918: fi
  919: AC_SUBST(FFI_H_NAME)
  920: AC_CHECK_LIB(ffi,ffi_call)
  921: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
  922: then
  923:   LIBFFIFLAG="true"
  924:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
  925: else
  926:   LIBFFIFLAG="false"
  927: fi
  928: #check for ffcall libraries
  929: #unfortunately, these four calls are separated out into a library each.
  930: AC_CHECK_LIB(avcall,__builtin_avcall)
  931: dnl AC_CHECK_LIB(callback,__vacall_r)
  932: dnl AC_CHECK_LIB(vacall,vacall)
  933: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
  934: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
  935:   FFCALLFLAG="true"
  936:   LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
  937: else
  938:   FFCALLFLAG="false"
  939: fi
  940: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
  941:   AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
  942: fi
  943: AC_SUBST(LIBFFIFLAG)
  944: AC_SUBST(FFCALLFLAG)
  945: AC_SUBST(LIBCC_BUILD_SRC)
  946: if test "$host_os" != "nextstep3"
  947: then
  948: 	AC_FUNC_MEMCMP
  949: fi
  950: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  951: AC_FUNC_FSEEKO
  952: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
  953: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  954: AC_DECL_SYS_SIGLIST
  955: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  956: AC_CHECK_FUNCS(expm1 log1p)
  957: AC_REPLACE_FUNCS(rint ecvt)
  958: dnl No check for select, because our replacement is no good under
  959: dnl anything but DOS
  960: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
  961: AC_FUNC_FNMATCH
  962: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  963: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
  964: AM_PATH_LISPDIR
  965: 
  966: kernel_fi=kernl${vwordsize}${bytesex}.fi
  967: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  968: AC_SUBST(kernel_fi)
  969: AC_SUBST(include_fi)
  970: 
  971: #this breaks bindists
  972: #dnl replace srource directory by absolute value
  973: #if test $srcdir = "."; then srcdir=`pwd` 
  974: #fi
  975: 
  976: AC_SUBST(machine)
  977: AC_CONFIG_FILES([
  978: Makefile
  979: Makedist
  980: gforthmi
  981: vmgen
  982: machpc.fs
  983: envos.fs
  984: preforth
  985: engine/Makefile
  986: engine/libcc.h
  987: doc/version.texi
  988: build-ec ])
  989: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  990: chmod +x gforthmi
  991: chmod +x vmgen
  992: chmod +x build-ec
  993: chmod +x preforth
  994: test -d kernel||mkdir kernel
  995: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
  996: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
  997: $srcdir/mkinstalldirs arch/$machine
  998: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],
  999: [PACKAGE_VERSION=$PACKAGE_VERSION
 1000:  machine=$machine])
 1001: AC_OUTPUT

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>