1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.7.0-20090215],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="November 8, 2008"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #remnants from having ltdl as convenience library
33: LTDLDEPS=""
34: LTDLINCL=""
35: LIBLTDL=""
36: LTDL_LDLIBS=""
37: AC_SUBST(LTDLDEPS)
38: AC_SUBST(LTDLINCL)
39: AC_SUBST(LIBLTDL)
40: AC_SUBST(LTDL_LDLIBS)
41:
42: #suppress the "-g -O2" default
43: test "$CFLAGS" || CFLAGS=-O2
44:
45: AC_ARG_ENABLE(force-cdiv,
46: AC_HELP_STRING([--enable-force-cdiv],
47: [ Use the native C division - symmetric - instead of
48: floored division (default disabled).]),
49: ,enable_force_cdiv=no)
50: test "$enable_force_cdiv" = "no"||
51: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
52:
53: AC_SUBST(PROFEXES)
54: AC_SUBST(PROFOBJS)
55: AC_ARG_ENABLE(prof,
56: AC_HELP_STRING([--enable-prof],
57: [ Build gforth-prof, which outputs frequently occuring
58: sequences of primitives.]),
59: ,enable_prof=no)
60: if test "$enable_prof" != "no"; then
61: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
62: fi
63:
64: AC_ARG_WITH(debug,
65: [ --with-debug specifies option -g to compile with debug info
66: --without-debug omits the -g switch and creates smaller images on
67: machines where "strip" has problems with gcc style
68: debugging informations.],
69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
70:
71: GCC_LD="\$(GCC)"
72: EC_MODE="false"
73: NO_EC=""
74: EC=""
75: engine2='engine2$(OPT).o'
76: engine_fast2='engine-fast2$(OPT).o'
77: no_dynamic=""
78: image_i=""
79: signals_o="io.o signals.o"
80:
81: AC_CANONICAL_HOST
82: AC_ARG_WITH(ec,
83: AC_HELP_STRING([--with-ec=<arch>],
84: [ Build gforth for systems without OS.]),
85: [if test "$withval" = "no"; then
86: echo "defining hosted system"
87: else
88: echo "defining standalone system (${withval})"
89: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
90: EC_MODE="true"
91: EC="-ec"
92: NO_EC="#"
93: engine2=""
94: engine_fast2=""
95: no_dynamic="-DNO_DYNAMIC"
96: image_i="image.i"
97: if test "$withval" != "yes"; then
98: signals_o="io-${withval}.o"
99: else
100: signals_o="io.o"
101: fi
102: if test -f "arch/$host_cpu/${withval}/config.sh"; then
103: source "arch/$host_cpu/${withval}/config.sh"
104: fi
105: GCC_PATH=$(which $CC)
106: LIB_PATH=${GCC_PATH%/*/*}
107: GCC_LD="\$(LD)"
108: platform=${withval}
109: fi])
110:
111: #variables mentioned in INSTALL
112: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
113: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
114: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
115: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
116: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
117: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
118:
119: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
120: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
121: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
122: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
123: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
124: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
125: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
126: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
127: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
128: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
129: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
130: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
131: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
132: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
133: AC_ARG_VAR(asmcomment, [assembler comment start string])
134: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
135: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
136:
137: #set up feature test macros, so the tests get them right:
138: # turn on all POSIX, SUSv3, and GNU features if available
139: AC_GNU_SOURCE
140: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
141:
142: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
143: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
144: dnl but not for _XOPEN_SOURCE)
145: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
146: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
147: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
148: # turn on large file support with 64-bit off_t where available
149: AC_SYS_LARGEFILE
150: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
151: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
152:
153: #currently we force direct threading this way. Eventually we should
154: #setup in the arch and engine files right
155:
156: AC_PROG_CC
157:
158: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
159:
160: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
161: test x$condbranch_opt = x &&
162: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
163: condbranch_opt=0
164: else
165: condbranch_opt=1
166: fi
167: AC_MSG_RESULT($condbranch_opt)
168: AC_SUBST(condbranch_opt)
169:
170: AC_SUBST(CC)
171: AC_SUBST(GCC_LD)
172: AC_SUBST(DEBUGFLAG)
173: AC_SUBST(EC)
174: AC_SUBST(NO_EC)
175: AC_SUBST(EC_MODE)
176: AC_SUBST(engine2)
177: AC_SUBST(engine_fast2)
178: AC_SUBST(no_dynamic)
179: AC_SUBST(image_i)
180: AC_SUBST(signals_o)
181:
182: #this is used to disable some (not generally essential) part of the
183: #Makefile that some makes don't grok. It would be better to test for
184: #this specific Makefile feature than the make version.
185: AC_MSG_CHECKING(make type)
186: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
187: GNUMAKE='#'
188: test "$make_type" = "GNU Make" && GNUMAKE=''
189: AC_MSG_RESULT($make_type)
190: AC_SUBST(GNUMAKE)
191:
192: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
193: OLDLDFLAGS=$LDFLAGS
194: LDFLAGS="$LDFLAGS -export-dynamic"
195: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
196: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
197: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
198: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
199: AC_MSG_RESULT($ac_export_dynamic)
200:
201: #terminology is a bit unusual here: The host is the system on which
202: #gforth will run; the system on which configure will run is the `build'
203: case "$host_cpu" in
204: arm*)
205: machine=arm
206: CFLAGS="$CFLAGS -fomit-frame-pointer"
207: if test x$platform = xnxt; then
208: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
209: fi
210: if test -z $arm_cacheflush; then
211: case "$host_os" in
212: *linux*)
213: AC_LIBOBJ(../arch/arm/cacheflush-linux)
214: ;;
215: *)
216: no_dynamic_default=1
217: AC_LIBOBJ(../arch/arm/cacheflush0)
218: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
219: ;;
220: esac
221: else
222: AC_LIBOBJ(../$arm_cacheflush)
223: test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
224: fi
225: #longer skipcodes lead to problems on ARM, and it uses
226: #only 4-byte alignment anyway
227: test "$skipcode" || skipcode="nop"
228: ;;
229: hppa*)
230: machine=hppa
231: AC_LIBOBJ(../arch/hppa/cache)
232: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
233: LDFLAGS="$LDFLAGS -Xlinker -N"
234: LIBS="$LIBS -L/lib/pa1.1/"
235: ;;
236: sparc*)
237: machine=sparc
238: ;;
239: i386)
240: machine=386
241: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
242: ;;
243: i486)
244: machine=386
245: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
246: ;;
247: i*86)
248: machine=386
249: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
250: CFLAGS_1="$CFLAGS"
251: CFLAGS="$CFLAGS -march=pentium"
252: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
253: ;;
254: x86_64)
255: case $CC
256: in
257: *-m32*)
258: machine=386
259: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
260: CFLAGS_1="$CFLAGS"
261: CFLAGS="$CFLAGS -march=athlon64"
262: ;;
263: *)
264: machine=amd64
265: ;;
266: esac
267: ;;
268: ia64*)
269: machine=ia64
270: AC_LIBOBJ(../arch/ia64/flush_icache_block)
271: test "$skipcode" || skipcode="nop.i 0"
272: #".skip 16" passes the test below,
273: # but gives an assembler error in engine
274: ;;
275: m68k)
276: machine=m68k
277: CFLAGS="$CFLAGS -fomit-frame-pointer"
278: if test "$host_os" = "nextstep3"
279: then
280: AC_LIBOBJ(termios)
281: fi
282: ;;
283: mips*)
284: machine=mips
285: #dynamic native code has the following problems on MIPS:
286: #
287: #1) J/JAL seems relocatable, but is are only
288: #relocatable within a 256MB-segment. While we try to
289: #get the linker to arrange this, there is no guarantee
290: #that this will succeed (and if the user uses a lot of
291: #memory, it is likely to fail).
292: #
293: #2) The way we generate dynamic native code may
294: #violate MIPS architectural restrictions (in
295: #particular, the delay slots of LW, MFLO, etc.)
296: #
297: #Therefore we disable dynamic native code by default:
298: if test -z "$no_dynamic_default"; then
299: no_dynamic_default=1
300: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
301: fi
302: ;;
303: alpha*)
304: machine=alpha
305: #full IEEE FP support for more uniformity across platforms:
306: CFLAGS="$CFLAGS -mieee"
307: ;;
308: power*|rs6000)
309: machine=power
310: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
311: #long long is broken on (at least) gcc-2.95.* for PPC
312: test x$ac_cv_sizeof_long_long = x &&
313: ($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
314: ac_cv_sizeof_long_long=0
315: #The only architecture with enough callee-saved registers
316: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
317: #or use 2, hardly slower at run-time and starts up faster
318:
319: #the skipcode that is normally selected below does not
320: #work with gcc-3.[34]
321: test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
322: ;;
323: *)
324: AC_MSG_WARN([Using a generic machine description])
325: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
326: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
327: machine=generic
328: #I-cache flushing would be needed for dynamic code generation
329: if test -z $no_dynamic_default; then
330: no_dynamic_default=1
331: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
332: fi
333: esac
334: AC_SUBST(host)
335:
336: MAKEINC=""
337: GFORTH_EXE="true"
338:
339: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
340: if test x$EC_MODE = xtrue
341: then
342: echo "Check for arch/$machine/$platform/gforth.ld"
343: if test -f arch/$machine/$platform/gforth.ld
344: then
345: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
346: if test x$platform = xnxt; then
347: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
348: fi
349: fi
350: if test -f arch/$machine/$platform/make.inc
351: then
352: MAKEINC="include ../arch/$machine/$platform/make.inc"
353: GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
354: fi
355: fi
356: AC_SUBST(MAKEINC)
357:
358: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
359:
360: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
361: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
362: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
363: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
364: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
365: [number of registers in the default stack cache state for gforth-fast and gforth-native])
366:
367: test x$GCC_PR15242_WORKAROUND = x ||
368: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
369: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
370:
371: dnl the following macro produces a warning with autoconf-2.1
372: AC_CHECK_SIZEOF(char *)
373: case "$ac_cv_sizeof_char_p" in
374: 2)
375: wordsize=16
376: ;;
377: 4)
378: wordsize=32
379: ;;
380: 8)
381: wordsize=64
382: ;;
383: esac
384:
385: AC_CHECK_SIZEOF(void *)
386: case "$ac_cv_sizeof_void_p" in
387: 2)
388: vwordsize=16
389: ;;
390: 4)
391: vwordsize=32
392: ;;
393: 8)
394: vwordsize=64
395: ;;
396: esac
397:
398: AC_CHECK_SIZEOF(char)
399: AC_CHECK_SIZEOF(short)
400: AC_CHECK_SIZEOF(int)
401: AC_CHECK_SIZEOF(long)
402: AC_CHECK_SIZEOF(long long)
403: AC_CHECK_SIZEOF(intptr_t)
404: AC_CHECK_SIZEOF(int128_t)
405: AC_CHECK_SIZEOF(uint128_t)
406:
407: AC_MSG_CHECKING([for a C type for cells])
408: ac_cv_int_type_cell=none
409: case "$ac_cv_sizeof_char_p" in
410: $ac_cv_sizeof_int)
411: ac_cv_int_type_cell=int
412: ;;
413: $ac_cv_sizeof_short)
414: ac_cv_int_type_cell=short
415: ;;
416: $ac_cv_sizeof_char)
417: ac_cv_int_type_cell=char
418: ;;
419: $ac_cv_sizeof_long)
420: ac_cv_int_type_cell=long
421: ;;
422: $ac_cv_sizeof_long_long)
423: ac_cv_int_type_cell="long long"
424: ;;
425: $ac_cv_sizeof_intptr_t)
426: ac_cv_int_type_cell="intptr_t"
427: ;;
428: esac
429: AC_MSG_RESULT($ac_cv_int_type_cell)
430: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
431:
432: AC_MSG_CHECKING([for a C type for wydes])
433: ac_cv_wyde_type_cell=none
434: case 2 in
435: $ac_cv_sizeof_int)
436: ac_cv_wyde_type_cell=int
437: ;;
438: $ac_cv_sizeof_short)
439: ac_cv_wyde_type_cell=short
440: ;;
441: $ac_cv_sizeof_char)
442: ac_cv_wyde_type_cell=char
443: ;;
444: $ac_cv_sizeof_long)
445: ac_cv_wyde_type_cell=long
446: ;;
447: $ac_cv_sizeof_long_long)
448: ac_cv_wyde_type_cell="long long"
449: ;;
450: $ac_cv_sizeof_intptr_t)
451: ac_cv_wyde_type_cell="intptr_t"
452: ;;
453: esac
454: AC_MSG_RESULT($ac_cv_wyde_type_cell)
455: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
456:
457: AC_MSG_CHECKING([for a C type for tetrabytes])
458: ac_cv_tetrabyte_type_cell=none
459: case 4 in
460: $ac_cv_sizeof_int)
461: ac_cv_tetrabyte_type_cell=int
462: ;;
463: $ac_cv_sizeof_short)
464: ac_cv_tetrabyte_type_cell=short
465: ;;
466: $ac_cv_sizeof_char)
467: ac_cv_tetrabyte_type_cell=char
468: ;;
469: $ac_cv_sizeof_long)
470: ac_cv_tetrabyte_type_cell=long
471: ;;
472: $ac_cv_sizeof_long_long)
473: ac_cv_tetrabyte_type_cell="long long"
474: ;;
475: $ac_cv_sizeof_intptr_t)
476: ac_cv_tetrabyte_type_cell="intptr_t"
477: ;;
478: esac
479: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
480: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
481:
482: AC_MSG_CHECKING([for a C type for double-cells])
483: ac_cv_int_type_double_cell=none
484: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
485: $ac_cv_sizeof_short)
486: ac_cv_int_type_double_cell=short
487: ;;
488: $ac_cv_sizeof_int)
489: ac_cv_int_type_double_cell=int
490: ;;
491: $ac_cv_sizeof_long)
492: ac_cv_int_type_double_cell=long
493: ;;
494: $ac_cv_sizeof_long_long)
495: ac_cv_int_type_double_cell="long long"
496: ;;
497: $ac_cv_sizeof_intptr_t)
498: ac_cv_int_type_double_cell="intptr_t"
499: ;;
500: $ac_cv_sizeof_int128_t)
501: ac_cv_int_type_double_cell="int128_t"
502: ;;
503: esac
504: AC_MSG_RESULT($ac_cv_int_type_double_cell)
505:
506: AC_MSG_CHECKING([for a C type for unsigned double-cells])
507: ac_cv_int_type_double_ucell=none
508: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
509: $ac_cv_sizeof_short)
510: ac_cv_int_type_double_ucell="unsigned short"
511: ;;
512: $ac_cv_sizeof_int)
513: ac_cv_int_type_double_ucell="unsigned int"
514: ;;
515: $ac_cv_sizeof_long)
516: ac_cv_int_type_double_ucell="unsigned long"
517: ;;
518: $ac_cv_sizeof_long_long)
519: ac_cv_int_type_double_ucell="unsigned long long"
520: ;;
521: $ac_cv_sizeof_intptr_t)
522: ac_cv_int_type_double_ucell="unsigned intptr_t"
523: ;;
524: $ac_cv_sizeof_uint128_t)
525: ac_cv_int_type_double_ucell="uint128_t"
526: ;;
527: esac
528: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
529:
530: if test "$ac_cv_int_type_double_cell" != none && \
531: test "$ac_cv_int_type_double_ucell" != none
532: then
533: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
534: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
535: OPTS=-ll
536: else
537: if test "$ac_cv_sizeof_char_p" = 8; then
538: OPTS="-ll -noll"
539: else
540: OPTS=-noll
541: fi
542: fi
543:
544: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
545: OPTS2=''
546: for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
547: OPTS="$OPTS2 $OPTS"
548: else
549: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
550: fi
551: AC_SUBST(OPTS)
552:
553: AC_TYPE_OFF_T
554: AC_CHECK_SIZEOF(off_t)
555: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
556: ac_small_off_t=$?
557: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
558:
559: ENGINE_FLAGS=
560: AC_SUBST(ENGINE_FLAGS)
561:
562: # Try if GCC understands -fno-gcse
563:
564: AC_MSG_CHECKING([if $CC understands -fno-gcse])
565: CFLAGS_1="$CFLAGS"
566: CFLAGS="$CFLAGS -fno-gcse"
567: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
568: CFLAGS="$CFLAGS_1"
569: AC_MSG_RESULT($ac_nogcse)
570:
571: # Try if GCC understands -fno-strict-aliasing
572: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
573: CFLAGS_1="$CFLAGS"
574: CFLAGS="$CFLAGS -fno-strict-aliasing"
575: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
576: CFLAGS="$CFLAGS_1"
577: AC_MSG_RESULT($ac_nostrictaliasing)
578:
579: # Try if GCC understands -fno-crossjumping
580: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
581: CFLAGS_1="$CFLAGS"
582: CFLAGS="$CFLAGS -fno-crossjumping"
583: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
584: CFLAGS="$CFLAGS_1"
585: AC_MSG_RESULT($ac_nocrossjumping)
586:
587: # Try if GCC understands -fno-reorder-blocks
588: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
589: CFLAGS_1="$CFLAGS"
590: CFLAGS="$CFLAGS -fno-reorder-blocks"
591: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
592: CFLAGS="$CFLAGS_1"
593: AC_MSG_RESULT($ac_noreorder_blocks)
594:
595: # Try if GCC understands -falign-labels=1
596: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
597: CFLAGS_1="$CFLAGS"
598: CFLAGS="$CFLAGS -falign-labels=1"
599: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
600: CFLAGS="$CFLAGS_1"
601: AC_MSG_RESULT($ac_align_labels)
602:
603: # Try if GCC understands -falign-loops=1
604: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
605: CFLAGS_1="$CFLAGS"
606: CFLAGS="$CFLAGS -falign-loops=1"
607: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
608: CFLAGS="$CFLAGS_1"
609: AC_MSG_RESULT($ac_align_loops)
610:
611: # Try if GCC understands -falign-jumps=1
612: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
613: CFLAGS_1="$CFLAGS"
614: CFLAGS="$CFLAGS -falign-jumps=1"
615: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
616: CFLAGS="$CFLAGS_1"
617: AC_MSG_RESULT($ac_align_jumps)
618:
619: if test -z "$LIBTOOL_CC"
620: then
621: LIBTOOL_CC="$CC"
622: # Try if GCC understands -Wimplicit-function-declaration
623: AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
624: CFLAGS_1="$CFLAGS"
625: CFLAGS="$CFLAGS -Wimplicit-function-declaration"
626: AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
627: CFLAGS="$CFLAGS_1"
628: AC_MSG_RESULT($ac_align_jumps)
629: fi
630: AC_SUBST(LIBTOOL_CC)
631:
632:
633:
634: # Try if GCC understands __attribute__((unused))
635: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
636: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
637: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
638: AC_MSG_RESULT($MAYBE_UNUSED)
639:
640: #try if m4 understands -s
641: AC_MSG_CHECKING([how to invoke m4])
642: if m4 -s /dev/null >/dev/null 2>&1; then
643: M4="m4 -s"
644: else
645: M4=m4
646: fi
647: AC_SUBST(M4)
648: AC_MSG_RESULT($M4)
649:
650: # Find installed Gforth
651: AC_MSG_CHECKING([for gforth])
652: GFORTH="`cd / && which gforth 2>/dev/null`"
653: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
654: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null && test "$srcdir" = ".") || GFORTH=""
655: if test -z "$GFORTH"; then
656: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
657: kernel_anti_dependence=''
658: else
659: PREFORTH="$GFORTH -i `cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
660: kernel_anti_dependence='$(kernel_fi)'
661: fi
662: AC_SUBST(PREFORTH)
663: AC_SUBST(kernel_anti_dependence)
664: AC_MSG_RESULT($PREFORTH)
665:
666: #echo "machine='$machine'"
667:
668: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
669: if test x$EC_MODE = xfalse
670: then
671: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
672: fi
673: AC_SUBST(asm_fs)
674:
675: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
676: if test x$EC_MODE = xfalse
677: then
678: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
679: fi
680: AC_SUBST(disasm_fs)
681:
682: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
683:
684: case "$host_os" in
685: *win32*)
686: # !!!FIXME!!! problems with cygwin and ';' as path separator
687: DIRSEP="\\\\"
688: PATHSEP=";"
689: #we want the builtins of command.com/cmd.exe and its
690: # handling of .com files.
691: #$COMSPEC contains the name of the Windows shell;
692: # the ./ is there, because the bash does not recognize
693: # absolute DOS filenames
694: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
695: ;;
696: *darwin*)
697: #Darwin uses some funny preprocessor by default; eliminate it:
698: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
699: CFLAGS="$CFLAGS -no-cpp-precomp"
700: DIRSEP="/"
701: PATHSEP=":"
702: DEFAULTSYSTEMPREFIX=""
703: #the following magic value was suggested by
704: #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
705: AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
706: ;;
707: *linux*)
708: DIRSEP="/"
709: PATHSEP=":"
710: DEFAULTSYSTEMPREFIX=""
711: if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
712: LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
713: fi
714: ;;
715: *)
716: DIRSEP="/"
717: PATHSEP=":"
718: DEFAULTSYSTEMPREFIX=""
719: ;;
720: esac
721: AC_SUBST(DIRSEP)
722: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
723: AC_SUBST(PATHSEP)
724: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
725: AC_SUBST(DEFAULTSYSTEMPREFIX)
726: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
727: if test -n "$LTDL_LIBRARY_PATH"; then
728: AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
729: fi
730:
731: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
732: #This magic incantation seems to be completely undocumented.
733: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
734:
735: dnl Now a little support for DOS/DJGCC
736: GFORTHFAST_EXE="$GFORTH_EXE"
737: GFORTHITC_EXE="$GFORTH_EXE"
738: GFORTHDITC_EXE="$GFORTH_EXE"
739: AC_SUBST(GFORTH_EXE)
740: AC_SUBST(GFORTHFAST_EXE)
741: AC_SUBST(GFORTHITC_EXE)
742: AC_SUBST(GFORTHDITC_EXE)
743:
744: AC_SUBST(FORTHSIZES)
745:
746: dnl if test "$PEEPHOLE" = "yes"
747: dnl then
748: dnl PEEPHOLEFLAG="true"
749: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
750: dnl else
751: dnl PEEPHOLEFLAG="false"
752: dnl fi
753: PEEPHOLEFLAG="true"
754: AC_SUBST(PEEPHOLEFLAG)
755:
756: dnl copy commands for systems that don't have links
757: AC_SUBST(LINK_KERNL)
758: LINK_KERNL=""
759:
760: #if test $host_os=dos
761: #then
762: # echo Configuring for DOS!!!
763: # MAKE_EXE="coff2exe gforth"
764: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
765: #fi
766:
767: dnl the following macro produces a warning with autoconf-2.1
768: AC_C_BIGENDIAN
769: AC_SUBST(KERNEL)
770: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
771: if test $ac_cv_c_bigendian != no; then
772: bytesex=b
773: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
774: else
775: bytesex=l
776: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
777: fi
778:
779: #check how to do asm(".skip 16")
780: #echo "CFLAGS=$CFLAGS"
781: #echo "ac_link=$ac_link"
782: AC_MSG_CHECKING([if and how we can waste code space])
783: if test -z "$skipcode"; then
784: skipcode=no
785: CFLAGS_1="$CFLAGS"
786: CFLAGS="$CFLAGS $ENGINE_FLAGS"
787: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
788: do
789: AC_TRY_RUN(
790: [int foo(int,int,int);
791: main()
792: {
793: exit(foo(0,0,0)!=16);
794: }
795: int foo(int x, int y, int z)
796: {
797: static void *labels[]={&&label1, &&label2};
798: if (x) {
799: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
800: label1:
801: asm("$i"); /* or ".space 16" or somesuch */
802: label2: ;
803: }
804: {
805: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
806: return labels[1]-labels[0];
807: }
808: }]
809: ,skipcode=$i; break
810: ,,)
811: done
812: CFLAGS=$CFLAGS_1
813: fi
814: AC_MSG_RESULT($skipcode)
815: if test "$skipcode" = no
816: then
817: if test -z $no_dynamic_default; then
818: no_dynamic_default=1
819: AC_MSG_WARN(Disabling default dynamic native code generation)
820: fi
821: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
822: else
823: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
824: fi
825:
826: AC_MSG_CHECKING([if and how we can do comments in asm statements])
827: #the point here is to get asm statements that look different to
828: #gcc's "optimizer"
829: if test -z "$asmcomment"; then
830: asmcomment=no
831: CFLAGS_1="$CFLAGS"
832: CFLAGS="$CFLAGS $ENGINE_FLAGS"
833: for i in '"# "' '"! "' '"; "'; do
834: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
835: done
836: CFLAGS=$CFLAGS_1
837: fi
838: AC_MSG_RESULT($asmcomment)
839: if test "$asmcomment" != no
840: then
841: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
842: fi
843:
844: test "$no_dynamic_default" || no_dynamic_default=0
845: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
846:
847: dnl Checks for programs.
848: AC_PROG_LN_S
849: AC_PROG_INSTALL
850: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
851:
852: dnl MacOS X has a libtool that does something else
853: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
854:
855: dnl Checks for library functions
856: dnl This check is just for making later checks link with libm.
857: dnl using sin here is no good idea since it is built-into gcc and typechecked
858: AC_CHECK_LIB(m,asin)
859: AC_CHECK_LIB(ltdl,lt_dlinit)
860:
861: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
862: build_libcc_named=build-libcc-named
863: else
864: build_libcc_named=""
865: AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
866: fi
867: AC_SUBST(build_libcc_named)
868:
869:
870: if test -z "$GNU_LIBTOOL"; then
871: AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
872: AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
873: GNU_LIBTOOL=libtool
874: fi
875:
876: #check for libffi 2.x
877: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
878: if test -z "$FFI_H_NAME"; then
879: AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
880: fi
881: AC_SUBST(FFI_H_NAME)
882: AC_CHECK_LIB(ffi,ffi_call)
883: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
884: then
885: LIBFFIFLAG="true"
886: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
887: else
888: LIBFFIFLAG="false"
889: fi
890: #check for ffcall libraries
891: #unfortunately, these four calls are separated out into a library each.
892: AC_CHECK_LIB(avcall,__builtin_avcall)
893: dnl AC_CHECK_LIB(callback,__vacall_r)
894: dnl AC_CHECK_LIB(vacall,vacall)
895: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
896: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
897: FFCALLFLAG="true"
898: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
899: else
900: FFCALLFLAG="false"
901: fi
902: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
903: AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
904: fi
905: AC_SUBST(LIBFFIFLAG)
906: AC_SUBST(FFCALLFLAG)
907: AC_SUBST(LIBCC_BUILD_SRC)
908: if test "$host_os" != "nextstep3"
909: then
910: AC_FUNC_MEMCMP
911: fi
912: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
913: AC_FUNC_FSEEKO
914: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
915: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
916: AC_DECL_SYS_SIGLIST
917: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
918: AC_CHECK_FUNCS(expm1 log1p)
919: AC_REPLACE_FUNCS(rint ecvt)
920: dnl No check for select, because our replacement is no good under
921: dnl anything but DOS
922: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h)
923: AC_FUNC_FNMATCH
924: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
925: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
926: AM_PATH_LISPDIR
927:
928: kernel_fi=kernl${vwordsize}${bytesex}.fi
929: include_fi=kernl${wordsize}${bytesex}${EC}.fi
930: AC_SUBST(kernel_fi)
931: AC_SUBST(include_fi)
932:
933: #this breaks bindists
934: #dnl replace srource directory by absolute value
935: #if test $srcdir = "."; then srcdir=`pwd`
936: #fi
937:
938: AC_SUBST(machine)
939: AC_CONFIG_FILES([
940: Makefile
941: Makedist
942: gforthmi
943: vmgen
944: machpc.fs
945: envos.fs
946: preforth
947: engine/Makefile
948: engine/libcc.h
949: doc/version.texi
950: build-ec ])
951: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
952: chmod +x gforthmi
953: chmod +x vmgen
954: chmod +x build-ec
955: chmod +x preforth
956: test -d kernel||mkdir kernel
957: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
958: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
959: $srcdir/mkinstalldirs arch/$machine
960: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],
961: [PACKAGE_VERSION=$PACKAGE_VERSION
962: machine=$machine])
963: AC_OUTPUT
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>