1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.6.9-20080716],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="July 16, 2008"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #remnants from having ltdl as convenience library
33: LTDLDEPS=""
34: LTDLINCL=""
35: LIBLTDL=""
36: LTDL_LDLIBS=""
37: AC_SUBST(LTDLDEPS)
38: AC_SUBST(LTDLINCL)
39: AC_SUBST(LIBLTDL)
40: AC_SUBST(LTDL_LDLIBS)
41:
42: #suppress the "-g -O2" default
43: test "$CFLAGS" || CFLAGS=-O2
44:
45: AC_ARG_ENABLE(force-cdiv,
46: AC_HELP_STRING([--enable-force-cdiv],
47: [ Use the native C division - symmetric - instead of
48: floored division (default disabled).]),
49: ,enable_force_cdiv=no)
50: test "$enable_force_cdiv" = "no"||
51: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
52:
53: AC_SUBST(PROFEXES)
54: AC_SUBST(PROFOBJS)
55: AC_ARG_ENABLE(prof,
56: AC_HELP_STRING([--enable-prof],
57: [ Build gforth-prof, which outputs frequently occuring
58: sequences of primitives.]),
59: ,enable_prof=no)
60: if test "$enable_prof" != "no"; then
61: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
62: fi
63:
64: AC_ARG_WITH(debug,
65: [ --with-debug specifies option -g to compile with debug info
66: --without-debug omits the -g switch and creates smaller images on
67: machines where "strip" has problems with gcc style
68: debugging informations.],
69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
70:
71: GCC_LD="\$(GCC)"
72: EC_MODE="false"
73: EC=""
74: engine2='engine2$(OPT).o'
75: engine_fast2='engine-fast2$(OPT).o'
76: no_dynamic=""
77: image_i=""
78: signals_o="io.o signals.o"
79:
80: AC_ARG_WITH(ec,
81: AC_HELP_STRING([--with-ec=<arch>],
82: [ Build gforth for systems without OS.]),
83: [if test "$withval" = "no"; then
84: echo "defining hosted system"
85: else
86: echo "defining standalone system (${withval})"
87: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
88: EC_MODE="true"
89: EC="-ec"
90: engine2=""
91: engine_fast2=""
92: no_dynamic="-DNO_DYNAMIC"
93: image_i="image.i"
94: if test "$withval" != "yes"; then
95: signals_o="io-${withval}.o"
96: else
97: signals_o="io.o"
98: fi
99: GCC_PATH=$(which $CC)
100: LIB_PATH=${GCC_PATH%/*/*}
101: GCC_LD="\$(LD)"
102: platform=${withval}
103: fi])
104:
105: #variables mentioned in INSTALL
106: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
107: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
108: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
109: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
110: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
111: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
112:
113: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
114: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
115: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
116: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
117: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
118: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
119: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
120: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
121: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
122: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
123: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
124: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
125: AC_ARG_VAR(asmcomment, [assembler comment start string])
126: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
127:
128: #set up feature test macros, so the tests get them right:
129: # turn on all POSIX, SUSv3, and GNU features if available
130: AC_GNU_SOURCE
131: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
132:
133: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
134: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
135: dnl but not for _XOPEN_SOURCE)
136: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
137: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
138: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
139: # turn on large file support with 64-bit off_t where available
140: AC_SYS_LARGEFILE
141: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
142: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
143:
144: #currently we force direct threading this way. Eventually we should
145: #setup in the arch and engine files right
146:
147: AC_PROG_CC
148:
149: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
150:
151: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
152: test x$condbranch_opt = x &&
153: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
154: condbranch_opt=0
155: else
156: condbranch_opt=1
157: fi
158: AC_MSG_RESULT($condbranch_opt)
159: AC_SUBST(condbranch_opt)
160:
161: AC_SUBST(CC)
162: AC_SUBST(GCC_LD)
163: AC_SUBST(DEBUGFLAG)
164: AC_SUBST(EC)
165: AC_SUBST(EC_MODE)
166: AC_SUBST(engine2)
167: AC_SUBST(engine_fast2)
168: AC_SUBST(no_dynamic)
169: AC_SUBST(image_i)
170: AC_SUBST(signals_o)
171:
172: #this is used to disable some (not generally essential) part of the
173: #Makefile that some makes don't grok. It would be better to test for
174: #this specific Makefile feature than the make version.
175: AC_MSG_CHECKING(make type)
176: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
177: GNUMAKE='#'
178: test "$make_type" = "GNU Make" && GNUMAKE=''
179: AC_MSG_RESULT($make_type)
180: AC_SUBST(GNUMAKE)
181:
182: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
183: OLDLDFLAGS=$LDFLAGS
184: LDFLAGS="$LDFLAGS -export-dynamic"
185: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
186: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
187: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
188: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
189: AC_MSG_RESULT($ac_export_dynamic)
190:
191: #terminology is a bit unusual here: The host is the system on which
192: #gforth will run; the system on which configure will run is the `build'
193: AC_CANONICAL_HOST
194: case "$host_cpu" in
195: arm*)
196: machine=arm
197: CFLAGS="$CFLAGS -fomit-frame-pointer"
198: if test x$platform = xnxt; then
199: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
200: fi
201: if test -z $arm_cacheflush; then
202: case "$host_os" in
203: *linux*)
204: arm_cacheflush=arch/arm/cacheflush-linux
205: ;;
206: *)
207: no_dynamic_default=1
208: arm_cacheflush=arch/arm/cacheflush0
209: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
210: ;;
211: esac
212: fi
213: AC_LIBSOURCES([../arch/arm/cacheflush0, dnl
214: ../arch/arm/cacheflush-linux])
215: AC_LIBOBJ(../$arm_cacheflush)
216: #longer skipcodes lead to problems on ARM, and it uses
217: #only 4-byte alignment anyway
218: test "$skipcode" || skipcode="nop"
219: ;;
220: hppa*)
221: machine=hppa
222: $srcdir/mkinstalldirs arch/hppa
223: AC_LIBOBJ(../arch/hppa/cache)
224: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
225: LDFLAGS="$LDFLAGS -Xlinker -N"
226: LIBS="$LIBS -L/lib/pa1.1/"
227: ;;
228: sparc*)
229: machine=sparc
230: ;;
231: i386)
232: machine=386
233: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
234: ;;
235: i486)
236: machine=386
237: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
238: ;;
239: i*86)
240: machine=386
241: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
242: CFLAGS_1="$CFLAGS"
243: CFLAGS="$CFLAGS -march=pentium"
244: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
245: ;;
246: x86_64)
247: case $CC
248: in
249: *-m32*)
250: machine=386
251: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
252: CFLAGS_1="$CFLAGS"
253: CFLAGS="$CFLAGS -march=athlon64"
254: ;;
255: *)
256: machine=amd64
257: ;;
258: esac
259: ;;
260: ia64*)
261: machine=ia64
262: AC_LIBOBJ(../arch/ia64/flush_icache_block)
263: test "$skipcode" || skipcode="nop.i 0"
264: #".skip 16" passes the test below,
265: # but gives an assembler error in engine
266: ;;
267: m68k)
268: machine=m68k
269: CFLAGS="$CFLAGS -fomit-frame-pointer"
270: if test "$host_os" = "nextstep3"
271: then
272: AC_LIBOBJ(termios)
273: fi
274: ;;
275: mips*)
276: machine=mips
277: #dynamic native code has the following problems on MIPS:
278: #
279: #1) J/JAL seems relocatable, but is are only
280: #relocatable within a 256MB-segment. While we try to
281: #get the linker to arrange this, there is no guarantee
282: #that this will succeed (and if the user uses a lot of
283: #memory, it is likely to fail).
284: #
285: #2) The way we generate dynamic native code may
286: #violate MIPS architectural restrictions (in
287: #particular, the delay slots of LW, MFLO, etc.)
288: #
289: #Therefore we disable dynamic native code by default:
290: if test -z $no_dynamic_default; then
291: no_dynamic_default=1
292: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
293: fi
294: ;;
295: alpha*)
296: machine=alpha
297: #full IEEE FP support for more uniformity across platforms:
298: CFLAGS="$CFLAGS -mieee"
299: ;;
300: power*|rs6000)
301: machine=power
302: $srcdir/mkinstalldirs arch/power
303: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
304: #long long is broken on (at least) gcc-2.95.* for PPC
305: test x$ac_cv_sizeof_long_long = x &&
306: ($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
307: ac_cv_sizeof_long_long=0
308: #The only architecture with enough callee-saved registers
309: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
310: #or use 2, hardly slower at run-time and starts up faster
311: ;;
312: *)
313: AC_MSG_WARN([Using a generic machine description])
314: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
315: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
316: machine=generic
317: #I-cache flushing would be needed for dynamic code generation
318: if test -z $no_dynamic_default; then
319: no_dynamic_default=1
320: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
321: fi
322: esac
323: AC_SUBST(host)
324:
325: MAKEINC=""
326:
327: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
328: if test x$EC_MODE = xtrue
329: then
330: echo "Check for arch/$machine/$platform/gforth.ld"
331: if test -f arch/$machine/$platform/gforth.ld
332: then
333: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
334: if test x$platform = xnxt; then
335: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
336: fi
337: fi
338: if test -f arch/$machine/$platform/make.inc
339: then
340: MAKEINC="include ../arch/$machine/$platform/make.inc"
341: fi
342: fi
343: AC_SUBST(MAKEINC)
344:
345: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
346:
347: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
348: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
349: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
350: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
351: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
352: [number of registers in the default stack cache state for gforth-fast and gforth-native])
353:
354: test x$GCC_PR15242_WORKAROUND = x ||
355: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
356: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
357:
358: dnl the following macro produces a warning with autoconf-2.1
359: AC_CHECK_SIZEOF(char *)
360: case "$ac_cv_sizeof_char_p" in
361: 2)
362: wordsize=16
363: ;;
364: 4)
365: wordsize=32
366: ;;
367: 8)
368: wordsize=64
369: ;;
370: esac
371:
372: AC_CHECK_SIZEOF(void *)
373: case "$ac_cv_sizeof_void_p" in
374: 2)
375: vwordsize=16
376: ;;
377: 4)
378: vwordsize=32
379: ;;
380: 8)
381: vwordsize=64
382: ;;
383: esac
384:
385: AC_CHECK_SIZEOF(char)
386: AC_CHECK_SIZEOF(short)
387: AC_CHECK_SIZEOF(int)
388: AC_CHECK_SIZEOF(long)
389: AC_CHECK_SIZEOF(long long)
390: AC_CHECK_SIZEOF(intptr_t)
391: AC_CHECK_SIZEOF(int128_t)
392: AC_CHECK_SIZEOF(uint128_t)
393:
394: AC_MSG_CHECKING([for a C type for cells])
395: ac_cv_int_type_cell=none
396: case "$ac_cv_sizeof_char_p" in
397: $ac_cv_sizeof_int)
398: ac_cv_int_type_cell=int
399: ;;
400: $ac_cv_sizeof_short)
401: ac_cv_int_type_cell=short
402: ;;
403: $ac_cv_sizeof_char)
404: ac_cv_int_type_cell=char
405: ;;
406: $ac_cv_sizeof_long)
407: ac_cv_int_type_cell=long
408: ;;
409: $ac_cv_sizeof_long_long)
410: ac_cv_int_type_cell="long long"
411: ;;
412: $ac_cv_sizeof_intptr_t)
413: ac_cv_int_type_cell="intptr_t"
414: ;;
415: esac
416: AC_MSG_RESULT($ac_cv_int_type_cell)
417: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
418:
419: AC_MSG_CHECKING([for a C type for wydes])
420: ac_cv_wyde_type_cell=none
421: case 2 in
422: $ac_cv_sizeof_int)
423: ac_cv_wyde_type_cell=int
424: ;;
425: $ac_cv_sizeof_short)
426: ac_cv_wyde_type_cell=short
427: ;;
428: $ac_cv_sizeof_char)
429: ac_cv_wyde_type_cell=char
430: ;;
431: $ac_cv_sizeof_long)
432: ac_cv_wyde_type_cell=long
433: ;;
434: $ac_cv_sizeof_long_long)
435: ac_cv_wyde_type_cell="long long"
436: ;;
437: $ac_cv_sizeof_intptr_t)
438: ac_cv_wyde_type_cell="intptr_t"
439: ;;
440: esac
441: AC_MSG_RESULT($ac_cv_wyde_type_cell)
442: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
443:
444: AC_MSG_CHECKING([for a C type for tetrabytes])
445: ac_cv_tetrabyte_type_cell=none
446: case 4 in
447: $ac_cv_sizeof_int)
448: ac_cv_tetrabyte_type_cell=int
449: ;;
450: $ac_cv_sizeof_short)
451: ac_cv_tetrabyte_type_cell=short
452: ;;
453: $ac_cv_sizeof_char)
454: ac_cv_tetrabyte_type_cell=char
455: ;;
456: $ac_cv_sizeof_long)
457: ac_cv_tetrabyte_type_cell=long
458: ;;
459: $ac_cv_sizeof_long_long)
460: ac_cv_tetrabyte_type_cell="long long"
461: ;;
462: $ac_cv_sizeof_intptr_t)
463: ac_cv_tetrabyte_type_cell="intptr_t"
464: ;;
465: esac
466: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
467: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
468:
469: AC_MSG_CHECKING([for a C type for double-cells])
470: ac_cv_int_type_double_cell=none
471: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
472: $ac_cv_sizeof_short)
473: ac_cv_int_type_double_cell=short
474: ;;
475: $ac_cv_sizeof_int)
476: ac_cv_int_type_double_cell=int
477: ;;
478: $ac_cv_sizeof_long)
479: ac_cv_int_type_double_cell=long
480: ;;
481: $ac_cv_sizeof_long_long)
482: ac_cv_int_type_double_cell="long long"
483: ;;
484: $ac_cv_sizeof_intptr_t)
485: ac_cv_int_type_double_cell="intptr_t"
486: ;;
487: $ac_cv_sizeof_int128_t)
488: ac_cv_int_type_double_cell="int128_t"
489: ;;
490: esac
491: AC_MSG_RESULT($ac_cv_int_type_double_cell)
492:
493: AC_MSG_CHECKING([for a C type for unsigned double-cells])
494: ac_cv_int_type_double_ucell=none
495: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
496: $ac_cv_sizeof_short)
497: ac_cv_int_type_double_ucell="unsigned short"
498: ;;
499: $ac_cv_sizeof_int)
500: ac_cv_int_type_double_ucell="unsigned int"
501: ;;
502: $ac_cv_sizeof_long)
503: ac_cv_int_type_double_ucell="unsigned long"
504: ;;
505: $ac_cv_sizeof_long_long)
506: ac_cv_int_type_double_ucell="unsigned long long"
507: ;;
508: $ac_cv_sizeof_intptr_t)
509: ac_cv_int_type_double_ucell="unsigned intptr_t"
510: ;;
511: $ac_cv_sizeof_uint128_t)
512: ac_cv_int_type_double_ucell="uint128_t"
513: ;;
514: esac
515: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
516:
517: if test "$ac_cv_int_type_double_cell" != none && \
518: test "$ac_cv_int_type_double_ucell" != none
519: then
520: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
521: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
522: OPTS=-ll
523: else
524: if test "$ac_cv_sizeof_char_p" = 8; then
525: OPTS="-ll -noll"
526: else
527: OPTS=-noll
528: fi
529: fi
530:
531: if grep FORCE_REG arch/$machine/machine.h >/dev/null; then
532: OPTS2=''
533: for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
534: OPTS="$OPTS2 $OPTS"
535: else
536: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
537: fi
538: AC_SUBST(OPTS)
539:
540: AC_TYPE_OFF_T
541: AC_CHECK_SIZEOF(off_t)
542: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
543: ac_small_off_t=$?
544: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
545:
546: ENGINE_FLAGS=
547: AC_SUBST(ENGINE_FLAGS)
548:
549: # Try if GCC understands -fno-gcse
550:
551: AC_MSG_CHECKING([if $CC understands -fno-gcse])
552: CFLAGS_1="$CFLAGS"
553: CFLAGS="$CFLAGS -fno-gcse"
554: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
555: CFLAGS="$CFLAGS_1"
556: AC_MSG_RESULT($ac_nogcse)
557:
558: # Try if GCC understands -fno-strict-aliasing
559: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
560: CFLAGS_1="$CFLAGS"
561: CFLAGS="$CFLAGS -fno-strict-aliasing"
562: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
563: CFLAGS="$CFLAGS_1"
564: AC_MSG_RESULT($ac_nostrictaliasing)
565:
566: # Try if GCC understands -fno-crossjumping
567: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
568: CFLAGS_1="$CFLAGS"
569: CFLAGS="$CFLAGS -fno-crossjumping"
570: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
571: CFLAGS="$CFLAGS_1"
572: AC_MSG_RESULT($ac_nocrossjumping)
573:
574: # Try if GCC understands -fno-reorder-blocks
575: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
576: CFLAGS_1="$CFLAGS"
577: CFLAGS="$CFLAGS -fno-reorder-blocks"
578: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
579: CFLAGS="$CFLAGS_1"
580: AC_MSG_RESULT($ac_noreorder_blocks)
581:
582: # Try if GCC understands -falign-labels=1
583: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
584: CFLAGS_1="$CFLAGS"
585: CFLAGS="$CFLAGS -falign-labels=1"
586: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
587: CFLAGS="$CFLAGS_1"
588: AC_MSG_RESULT($ac_align_labels)
589:
590: # Try if GCC understands -falign-loops=1
591: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
592: CFLAGS_1="$CFLAGS"
593: CFLAGS="$CFLAGS -falign-loops=1"
594: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
595: CFLAGS="$CFLAGS_1"
596: AC_MSG_RESULT($ac_align_loops)
597:
598: # Try if GCC understands -falign-jumps=1
599: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
600: CFLAGS_1="$CFLAGS"
601: CFLAGS="$CFLAGS -falign-jumps=1"
602: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
603: CFLAGS="$CFLAGS_1"
604: AC_MSG_RESULT($ac_align_jumps)
605:
606: # Try if GCC understands __attribute__((unused))
607: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
608: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
609: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
610: AC_MSG_RESULT($MAYBE_UNUSED)
611:
612: #try if m4 understands -s
613: AC_MSG_CHECKING([how to invoke m4])
614: if m4 -s /dev/null >/dev/null 2>&1; then
615: M4="m4 -s"
616: else
617: M4=m4
618: fi
619: AC_SUBST(M4)
620: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
621: AC_MSG_RESULT($M4)
622:
623: # Find installed Gforth
624: AC_MSG_CHECKING([for gforth])
625: GFORTH="`cd / && which gforth 2>/dev/null`"
626: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null) || GFORTH=""
627: if test -z "$GFORTH"; then
628: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
629: kernel_anti_dependence=''
630: else
631: PREFORTH="$GFORTH -i `cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
632: kernel_anti_dependence='$(kernel_fi)'
633: fi
634: AC_SUBST(PREFORTH)
635: AC_SUBST(kernel_anti_dependence)
636: AC_MSG_RESULT($PREFORTH)
637:
638: #echo "machine='$machine'"
639:
640: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
641: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
642: AC_SUBST(asm_fs)
643:
644: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
645: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
646: AC_SUBST(disasm_fs)
647:
648: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
649:
650: case "$host_os" in
651: *win32*)
652: # !!!FIXME!!! problems with cygwin and ';' as path separator
653: DIRSEP="\\\\"
654: PATHSEP=";"
655: #we want the builtins of command.com/cmd.exe and its
656: # handling of .com files.
657: #$COMSPEC contains the name of the Windows shell;
658: # the ./ is there, because the bash does not recognize
659: # absolute DOS filenames
660: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
661: ;;
662: *darwin*)
663: #Darwin uses some funny preprocessor by default; eliminate it:
664: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
665: CFLAGS="$CFLAGS -no-cpp-precomp"
666: DIRSEP="/"
667: PATHSEP=":"
668: DEFAULTSYSTEMPREFIX=""
669: ;;
670: *)
671: DIRSEP="/"
672: PATHSEP=":"
673: DEFAULTSYSTEMPREFIX=""
674: ;;
675: esac
676: AC_SUBST(DIRSEP)
677: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
678: AC_SUBST(PATHSEP)
679: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
680: AC_SUBST(DEFAULTSYSTEMPREFIX)
681: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
682:
683: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
684: #This magic incantation seems to be completely undocumented.
685: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
686:
687: dnl Now a little support for DOS/DJGCC
688: AC_SUBST(GFORTH_EXE)
689: GFORTH_EXE="true"
690: AC_SUBST(GFORTHFAST_EXE)
691: GFORTHFAST_EXE="true"
692: AC_SUBST(GFORTHITC_EXE)
693: GFORTHITC_EXE="true"
694: AC_SUBST(GFORTHDITC_EXE)
695: GFORTHDITC_EXE="true"
696:
697: AC_SUBST(FORTHSIZES)
698:
699: dnl if test "$PEEPHOLE" = "yes"
700: dnl then
701: dnl PEEPHOLEFLAG="true"
702: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
703: dnl else
704: dnl PEEPHOLEFLAG="false"
705: dnl fi
706: PEEPHOLEFLAG="true"
707: AC_SUBST(PEEPHOLEFLAG)
708:
709: dnl copy commands for systems that don't have links
710: AC_SUBST(LINK_KERNL)
711: LINK_KERNL=""
712:
713: #if test $host_os=dos
714: #then
715: # echo Configuring for DOS!!!
716: # MAKE_EXE="coff2exe gforth"
717: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
718: #fi
719:
720: dnl the following macro produces a warning with autoconf-2.1
721: AC_C_BIGENDIAN
722: AC_SUBST(KERNEL)
723: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
724: if test $ac_cv_c_bigendian = yes; then
725: bytesex=b
726: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
727: else
728: bytesex=l
729: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
730: fi
731:
732: #check how to do asm(".skip 16")
733: #echo "CFLAGS=$CFLAGS"
734: #echo "ac_link=$ac_link"
735: AC_MSG_CHECKING([if and how we can waste code space])
736: if test -z "$skipcode"; then
737: skipcode=no
738: CFLAGS_1="$CFLAGS"
739: CFLAGS="$CFLAGS $ENGINE_FLAGS"
740: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
741: do
742: AC_TRY_RUN(
743: [int foo(int,int,int);
744: main()
745: {
746: exit(foo(0,0,0)!=16);
747: }
748: int foo(int x, int y, int z)
749: {
750: static void *labels[]={&&label1, &&label2};
751: if (x) {
752: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
753: label1:
754: asm("$i"); /* or ".space 16" or somesuch */
755: label2: ;
756: }
757: {
758: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
759: return labels[1]-labels[0];
760: }
761: }]
762: ,skipcode=$i; break
763: ,,)
764: done
765: CFLAGS=$CFLAGS_1
766: fi
767: AC_MSG_RESULT($skipcode)
768: if test "$skipcode" = no
769: then
770: if test -z $no_dynamic_default; then
771: no_dynamic_default=1
772: AC_MSG_WARN(Disabling default dynamic native code generation)
773: fi
774: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
775: else
776: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
777: fi
778:
779: AC_MSG_CHECKING([if and how we can do comments in asm statements])
780: #the point here is to get asm statements that look different to
781: #gcc's "optimizer"
782: if test -z "$asmcomment"; then
783: asmcomment=no
784: CFLAGS_1="$CFLAGS"
785: CFLAGS="$CFLAGS $ENGINE_FLAGS"
786: for i in '"# "' '"! "' '"; "'; do
787: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
788: done
789: CFLAGS=$CFLAGS_1
790: fi
791: AC_MSG_RESULT($asmcomment)
792: if test "$asmcomment" != no
793: then
794: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
795: fi
796:
797: test "$no_dynamic_default" || no_dynamic_default=0
798: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
799:
800: dnl Checks for programs.
801: AC_PROG_LN_S
802: AC_PROG_INSTALL
803: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
804:
805: dnl MacOS X has a libtool that does something else
806: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
807:
808: dnl Checks for library functions
809: dnl This check is just for making later checks link with libm.
810: dnl using sin here is no good idea since it is built-into gcc and typechecked
811: AC_CHECK_LIB(m,asin)
812: AC_CHECK_LIB(ltdl,lt_dlinit)
813: #check for libffi 2.x
814: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
815: if test -z "$FFI_H_NAME"; then
816: AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
817: fi
818: AC_SUBST(FFI_H_NAME)
819: AC_CHECK_LIB(ffi,ffi_call)
820: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
821: then
822: LIBFFIFLAG="true"
823: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
824: else
825: LIBFFIFLAG="false"
826: fi
827: #check for ffcall libraries
828: #unfortunately, these four calls are separated out into a library each.
829: AC_CHECK_LIB(avcall,__builtin_avcall)
830: dnl AC_CHECK_LIB(callback,__vacall_r)
831: dnl AC_CHECK_LIB(vacall,vacall)
832: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
833: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
834: FFCALLFLAG="true"
835: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
836: else
837: FFCALLFLAG="false"
838: fi
839: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
840: AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
841: fi
842: AC_SUBST(LIBFFIFLAG)
843: AC_SUBST(FFCALLFLAG)
844: AC_SUBST(LIBCC_BUILD_SRC)
845: if test "$host_os" != "nextstep3"
846: then
847: AC_FUNC_MEMCMP
848: fi
849: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
850: AC_FUNC_FSEEKO
851: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
852: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
853: AC_DECL_SYS_SIGLIST
854: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
855: AC_CHECK_FUNCS(expm1 log1p)
856: AC_REPLACE_FUNCS(rint ecvt)
857: dnl No check for select, because our replacement is no good under
858: dnl anything but DOS
859: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
860: AC_FUNC_FNMATCH
861: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
862: AC_CHECK_FUNCS(mmap sysconf getpagesize)
863: AM_PATH_LISPDIR
864:
865: kernel_fi=kernl${vwordsize}${bytesex}.fi
866: include_fi=kernl${wordsize}${bytesex}${EC}.fi
867: AC_SUBST(kernel_fi)
868: AC_SUBST(include_fi)
869:
870: #this breaks bindists
871: #dnl replace srource directory by absolute value
872: #if test $srcdir = "."; then srcdir=`pwd`
873: #fi
874:
875: AC_SUBST(machine)
876: AC_CONFIG_FILES([
877: Makefile
878: Makedist
879: gforthmi
880: vmgen
881: machpc.fs
882: envos.fs
883: preforth
884: engine/Makefile
885: engine/libcc.h
886: doc/version.texi
887: build-ec ])
888: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
889: chmod +x gforthmi
890: chmod +x vmgen
891: chmod +x build-ec
892: chmod +x preforth
893: test -d kernel||mkdir kernel
894: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
895: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
896: AC_OUTPUT
897:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>