1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.6.9-20080430],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="February 23, 2008"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #remnants from having ltdl as convenience library
33: LTDLDEPS=""
34: LTDLINCL=""
35: LIBLTDL=""
36: LTDL_LDLIBS=""
37: AC_SUBST(LTDLDEPS)
38: AC_SUBST(LTDLINCL)
39: AC_SUBST(LIBLTDL)
40: AC_SUBST(LTDL_LDLIBS)
41:
42: #suppress the "-g -O2" default
43: test "$CFLAGS" || CFLAGS=-O2
44:
45: AC_ARG_ENABLE(force-cdiv,
46: AC_HELP_STRING([--enable-force-cdiv],
47: [ Use the native C division - symmetric - instead of
48: floored division (default disabled).]),
49: ,enable_force_cdiv=no)
50: test "$enable_force_cdiv" = "no"||
51: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
52:
53: AC_SUBST(PROFEXES)
54: AC_SUBST(PROFOBJS)
55: AC_ARG_ENABLE(prof,
56: AC_HELP_STRING([--enable-prof],
57: [ Build gforth-prof, which outputs frequently occuring
58: sequences of primitives.]),
59: ,enable_prof=no)
60: if test "$enable_prof" != "no"; then
61: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
62: fi
63:
64: AC_ARG_WITH(debug,
65: [ --with-debug specifies option -g to compile with debug info
66: --without-debug omits the -g switch and creates smaller images on
67: machines where "strip" has problems with gcc style
68: debugging informations.],
69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
70:
71: GCC_LD="\$(GCC)"
72: EC_MODE="false"
73: EC=""
74: engine2='engine2$(OPT).o'
75: engine_fast2='engine-fast2$(OPT).o'
76: no_dynamic=""
77: image_i=""
78: signals_o="io.o signals.o"
79:
80: AC_ARG_WITH(ec,
81: AC_HELP_STRING([--with-ec=<arch>],
82: [ Build gforth for systems without OS.]),
83: [if test "$withval" = "no"; then
84: echo "defining hosted system"
85: else
86: echo "defining standalone system (${withval})"
87: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
88: EC_MODE="true"
89: EC="-ec"
90: engine2=""
91: engine_fast2=""
92: no_dynamic="-DNO_DYNAMIC"
93: image_i="image.i"
94: if test "$withval" != "yes"; then
95: signals_o="io-${withval}.o"
96: else
97: signals_o="io.o"
98: fi
99: GCC_PATH=$(which $CC)
100: LIB_PATH=${GCC_PATH%/*/*}
101: GCC_LD="\$(LD)"
102: platform=${withval}
103: fi])
104:
105: #variables mentioned in INSTALL
106: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
107: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
108: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
109: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
110: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
111:
112: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
113: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
114: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
115: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
116: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
117: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
118: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
119: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
120: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
121: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
122: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
123: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
124: AC_ARG_VAR(asmcomment, [assembler comment start string])
125: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
126:
127: #set up feature test macros, so the tests get them right:
128: # turn on all POSIX, SUSv3, and GNU features if available
129: AC_GNU_SOURCE
130: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
131:
132: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
133: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
134: dnl but not for _XOPEN_SOURCE)
135: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
136: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
137: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
138: # turn on large file support with 64-bit off_t where available
139: AC_SYS_LARGEFILE
140: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
141: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
142:
143: #currently we force direct threading this way. Eventually we should
144: #setup in the arch and engine files right
145:
146: AC_PROG_CC
147:
148: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
149:
150: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
151: test x$condbranch_opt = x &&
152: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
153: condbranch_opt=0
154: else
155: condbranch_opt=1
156: fi
157: AC_MSG_RESULT($condbranch_opt)
158: AC_SUBST(condbranch_opt)
159:
160: AC_SUBST(CC)
161: AC_SUBST(GCC_LD)
162: AC_SUBST(DEBUGFLAG)
163: AC_SUBST(EC)
164: AC_SUBST(EC_MODE)
165: AC_SUBST(engine2)
166: AC_SUBST(engine_fast2)
167: AC_SUBST(no_dynamic)
168: AC_SUBST(image_i)
169: AC_SUBST(signals_o)
170:
171: #this is used to disable some (not generally essential) part of the
172: #Makefile that some makes don't grok. It would be better to test for
173: #this specific Makefile feature than the make version.
174: AC_MSG_CHECKING(make type)
175: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
176: GNUMAKE='#'
177: test "$make_type" = "GNU Make" && GNUMAKE=''
178: AC_MSG_RESULT($make_type)
179: AC_SUBST(GNUMAKE)
180:
181: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
182: OLDLDFLAGS=$LDFLAGS
183: LDFLAGS="$LDFLAGS -export-dynamic"
184: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
185: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
186: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
187: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
188: AC_MSG_RESULT($ac_export_dynamic)
189:
190: #terminology is a bit unusual here: The host is the system on which
191: #gforth will run; the system on which configure will run is the `build'
192: AC_CANONICAL_HOST
193: case "$host_cpu" in
194: arm*)
195: machine=arm
196: CFLAGS="$CFLAGS -fomit-frame-pointer"
197: if test x$platform = xnxt; then
198: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
199: fi
200: if test -z $arm_cacheflush; then
201: case "$host_os" in
202: *linux*)
203: arm_cacheflush=arch/arm/cacheflush-linux
204: ;;
205: *)
206: no_dynamic_default=1
207: arm_cacheflush=arch/arm/cacheflush0
208: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
209: ;;
210: esac
211: fi
212: AC_LIBSOURCES([../arch/arm/cacheflush0, dnl
213: ../arch/arm/cacheflush-linux])
214: AC_LIBOBJ(../$arm_cacheflush)
215: #longer skipcodes lead to problems on ARM, and it uses
216: #only 4-byte alignment anyway
217: test "$skipcode" || skipcode="nop"
218: ;;
219: hppa*)
220: machine=hppa
221: $srcdir/mkinstalldirs arch/hppa
222: AC_LIBOBJ(../arch/hppa/cache)
223: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
224: LDFLAGS="$LDFLAGS -Xlinker -N"
225: LIBS="$LIBS -L/lib/pa1.1/"
226: ;;
227: sparc*)
228: machine=sparc
229: ;;
230: i386)
231: machine=386
232: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
233: ;;
234: i486)
235: machine=386
236: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
237: ;;
238: i*86)
239: machine=386
240: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
241: CFLAGS_1="$CFLAGS"
242: CFLAGS="$CFLAGS -march=pentium"
243: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
244: ;;
245: x86_64)
246: case $CC
247: in
248: *-m32*)
249: machine=386
250: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
251: CFLAGS_1="$CFLAGS"
252: CFLAGS="$CFLAGS -march=athlon64"
253: ;;
254: *)
255: machine=amd64
256: ;;
257: esac
258: ;;
259: ia64*)
260: machine=ia64
261: AC_LIBOBJ(../arch/ia64/flush_icache_block)
262: test "$skipcode" || skipcode="nop.i 0"
263: #".skip 16" passes the test below,
264: # but gives an assembler error in engine
265: ;;
266: m68k)
267: machine=m68k
268: CFLAGS="$CFLAGS -fomit-frame-pointer"
269: if test "$host_os" = "nextstep3"
270: then
271: AC_LIBOBJ(termios)
272: fi
273: ;;
274: mips*)
275: machine=mips
276: #dynamic native code has the following problems on MIPS:
277: #
278: #1) J/JAL seems relocatable, but is are only
279: #relocatable within a 256MB-segment. While we try to
280: #get the linker to arrange this, there is no guarantee
281: #that this will succeed (and if the user uses a lot of
282: #memory, it is likely to fail).
283: #
284: #2) The way we generate dynamic native code may
285: #violate MIPS architectural restrictions (in
286: #particular, the delay slots of LW, MFLO, etc.)
287: #
288: #Therefore we disable dynamic native code by default:
289: if test -z $no_dynamic_default; then
290: no_dynamic_default=1
291: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
292: fi
293: ;;
294: alpha*)
295: machine=alpha
296: #full IEEE FP support for more uniformity across platforms:
297: CFLAGS="$CFLAGS -mieee"
298: ;;
299: power*|rs6000)
300: machine=power
301: $srcdir/mkinstalldirs arch/power
302: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
303: #long long is broken on (at least) gcc-2.95.* for PPC
304: test x$ac_cv_sizeof_long_long = x &&
305: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
306: ac_cv_sizeof_long_long=0
307: #The only architecture with enough callee-saved registers
308: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
309: #or use 2, hardly slower at run-time and starts up faster
310: ;;
311: *)
312: AC_MSG_WARN([Using a generic machine description])
313: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
314: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
315: machine=generic
316: #I-cache flushing would be needed for dynamic code generation
317: if test -z $no_dynamic_default; then
318: no_dynamic_default=1
319: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
320: fi
321: esac
322: AC_SUBST(host)
323:
324: MAKEINC=""
325:
326: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
327: if test x$EC_MODE = xtrue
328: then
329: echo "Check for arch/$machine/$platform/gforth.ld"
330: if test -f arch/$machine/$platform/gforth.ld
331: then
332: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
333: if test x$platform = xnxt; then
334: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
335: fi
336: fi
337: if test -f arch/$machine/$platform/make.inc
338: then
339: MAKEINC="include ../arch/$machine/$platform/make.inc"
340: fi
341: fi
342: AC_SUBST(MAKEINC)
343:
344: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
345:
346: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
347: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
348: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
349: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
350: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
351: [number of registers in the default stack cache state for gforth-fast and gforth-native])
352:
353: test x$GCC_PR15242_WORKAROUND = x ||
354: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
355: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
356:
357: dnl the following macro produces a warning with autoconf-2.1
358: AC_CHECK_SIZEOF(char *)
359: case "$ac_cv_sizeof_char_p" in
360: 2)
361: wordsize=16
362: ;;
363: 4)
364: wordsize=32
365: ;;
366: 8)
367: wordsize=64
368: ;;
369: esac
370:
371: AC_CHECK_SIZEOF(void *)
372: case "$ac_cv_sizeof_void_p" in
373: 2)
374: vwordsize=16
375: ;;
376: 4)
377: vwordsize=32
378: ;;
379: 8)
380: vwordsize=64
381: ;;
382: esac
383:
384: AC_CHECK_SIZEOF(char)
385: AC_CHECK_SIZEOF(short)
386: AC_CHECK_SIZEOF(int)
387: AC_CHECK_SIZEOF(long)
388: AC_CHECK_SIZEOF(long long)
389: AC_CHECK_SIZEOF(intptr_t)
390: AC_CHECK_SIZEOF(int128_t)
391: AC_CHECK_SIZEOF(uint128_t)
392:
393: AC_MSG_CHECKING([for a C type for cells])
394: ac_cv_int_type_cell=none
395: case "$ac_cv_sizeof_char_p" in
396: $ac_cv_sizeof_int)
397: ac_cv_int_type_cell=int
398: ;;
399: $ac_cv_sizeof_short)
400: ac_cv_int_type_cell=short
401: ;;
402: $ac_cv_sizeof_char)
403: ac_cv_int_type_cell=char
404: ;;
405: $ac_cv_sizeof_long)
406: ac_cv_int_type_cell=long
407: ;;
408: $ac_cv_sizeof_long_long)
409: ac_cv_int_type_cell="long long"
410: ;;
411: $ac_cv_sizeof_intptr_t)
412: ac_cv_int_type_cell="intptr_t"
413: ;;
414: esac
415: AC_MSG_RESULT($ac_cv_int_type_cell)
416: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
417:
418: AC_MSG_CHECKING([for a C type for wydes])
419: ac_cv_wyde_type_cell=none
420: case 2 in
421: $ac_cv_sizeof_int)
422: ac_cv_wyde_type_cell=int
423: ;;
424: $ac_cv_sizeof_short)
425: ac_cv_wyde_type_cell=short
426: ;;
427: $ac_cv_sizeof_char)
428: ac_cv_wyde_type_cell=char
429: ;;
430: $ac_cv_sizeof_long)
431: ac_cv_wyde_type_cell=long
432: ;;
433: $ac_cv_sizeof_long_long)
434: ac_cv_wyde_type_cell="long long"
435: ;;
436: $ac_cv_sizeof_intptr_t)
437: ac_cv_wyde_type_cell="intptr_t"
438: ;;
439: esac
440: AC_MSG_RESULT($ac_cv_wyde_type_cell)
441: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
442:
443: AC_MSG_CHECKING([for a C type for tetrabytes])
444: ac_cv_tetrabyte_type_cell=none
445: case 4 in
446: $ac_cv_sizeof_int)
447: ac_cv_tetrabyte_type_cell=int
448: ;;
449: $ac_cv_sizeof_short)
450: ac_cv_tetrabyte_type_cell=short
451: ;;
452: $ac_cv_sizeof_char)
453: ac_cv_tetrabyte_type_cell=char
454: ;;
455: $ac_cv_sizeof_long)
456: ac_cv_tetrabyte_type_cell=long
457: ;;
458: $ac_cv_sizeof_long_long)
459: ac_cv_tetrabyte_type_cell="long long"
460: ;;
461: $ac_cv_sizeof_intptr_t)
462: ac_cv_tetrabyte_type_cell="intptr_t"
463: ;;
464: esac
465: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
466: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
467:
468: AC_MSG_CHECKING([for a C type for double-cells])
469: ac_cv_int_type_double_cell=none
470: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
471: $ac_cv_sizeof_short)
472: ac_cv_int_type_double_cell=short
473: ;;
474: $ac_cv_sizeof_int)
475: ac_cv_int_type_double_cell=int
476: ;;
477: $ac_cv_sizeof_long)
478: ac_cv_int_type_double_cell=long
479: ;;
480: $ac_cv_sizeof_long_long)
481: ac_cv_int_type_double_cell="long long"
482: ;;
483: $ac_cv_sizeof_intptr_t)
484: ac_cv_int_type_double_cell="intptr_t"
485: ;;
486: $ac_cv_sizeof_int128_t)
487: ac_cv_int_type_double_cell="int128_t"
488: ;;
489: esac
490: AC_MSG_RESULT($ac_cv_int_type_double_cell)
491:
492: AC_MSG_CHECKING([for a C type for unsigned double-cells])
493: ac_cv_int_type_double_ucell=none
494: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
495: $ac_cv_sizeof_short)
496: ac_cv_int_type_double_ucell="unsigned short"
497: ;;
498: $ac_cv_sizeof_int)
499: ac_cv_int_type_double_ucell="unsigned int"
500: ;;
501: $ac_cv_sizeof_long)
502: ac_cv_int_type_double_ucell="unsigned long"
503: ;;
504: $ac_cv_sizeof_long_long)
505: ac_cv_int_type_double_ucell="unsigned long long"
506: ;;
507: $ac_cv_sizeof_intptr_t)
508: ac_cv_int_type_double_ucell="unsigned intptr_t"
509: ;;
510: $ac_cv_sizeof_uint128_t)
511: ac_cv_int_type_double_ucell="uint128_t"
512: ;;
513: esac
514: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
515:
516: if test "$ac_cv_int_type_double_cell" != none && \
517: test "$ac_cv_int_type_double_ucell" != none
518: then
519: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
520: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
521: OPTS=-ll
522: else
523: if test "$ac_cv_sizeof_char_p" = 8; then
524: OPTS="-ll -noll"
525: else
526: OPTS=-noll
527: fi
528: fi
529:
530: if grep -q FORCE_REG arch/$machine/machine.h; then
531: OPTS=`for i in $OPTS; do echo -n "$i-reg "; done`$OPTS
532: else
533: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
534: fi
535: AC_SUBST(OPTS)
536:
537: AC_TYPE_OFF_T
538: AC_CHECK_SIZEOF(off_t)
539: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
540: ac_small_off_t=$?
541: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
542:
543: ENGINE_FLAGS=
544: AC_SUBST(ENGINE_FLAGS)
545:
546: # Try if GCC understands -fno-gcse
547:
548: AC_MSG_CHECKING([if $CC understands -fno-gcse])
549: CFLAGS_1="$CFLAGS"
550: CFLAGS="$CFLAGS -fno-gcse"
551: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
552: CFLAGS="$CFLAGS_1"
553: AC_MSG_RESULT($ac_nogcse)
554:
555: # Try if GCC understands -fno-strict-aliasing
556: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
557: CFLAGS_1="$CFLAGS"
558: CFLAGS="$CFLAGS -fno-strict-aliasing"
559: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
560: CFLAGS="$CFLAGS_1"
561: AC_MSG_RESULT($ac_nostrictaliasing)
562:
563: # Try if GCC understands -fno-crossjumping
564: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
565: CFLAGS_1="$CFLAGS"
566: CFLAGS="$CFLAGS -fno-crossjumping"
567: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
568: CFLAGS="$CFLAGS_1"
569: AC_MSG_RESULT($ac_nocrossjumping)
570:
571: # Try if GCC understands -fno-reorder-blocks
572: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
573: CFLAGS_1="$CFLAGS"
574: CFLAGS="$CFLAGS -fno-reorder-blocks"
575: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
576: CFLAGS="$CFLAGS_1"
577: AC_MSG_RESULT($ac_noreorder_blocks)
578:
579: # Try if GCC understands -falign-labels=1
580: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
581: CFLAGS_1="$CFLAGS"
582: CFLAGS="$CFLAGS -falign-labels=1"
583: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
584: CFLAGS="$CFLAGS_1"
585: AC_MSG_RESULT($ac_align_labels)
586:
587: # Try if GCC understands -falign-loops=1
588: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
589: CFLAGS_1="$CFLAGS"
590: CFLAGS="$CFLAGS -falign-loops=1"
591: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
592: CFLAGS="$CFLAGS_1"
593: AC_MSG_RESULT($ac_align_loops)
594:
595: # Try if GCC understands -falign-jumps=1
596: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
597: CFLAGS_1="$CFLAGS"
598: CFLAGS="$CFLAGS -falign-jumps=1"
599: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
600: CFLAGS="$CFLAGS_1"
601: AC_MSG_RESULT($ac_align_jumps)
602:
603: # Try if GCC understands __attribute__((unused))
604: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
605: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
606: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
607: AC_MSG_RESULT($MAYBE_UNUSED)
608:
609: #try if m4 understands -s
610: AC_MSG_CHECKING([how to invoke m4])
611: if m4 -s /dev/null >/dev/null 2>&1; then
612: M4="m4 -s"
613: else
614: M4=m4
615: fi
616: AC_SUBST(M4)
617: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
618: AC_MSG_RESULT($M4)
619:
620: # Find installed Gforth
621: AC_MSG_CHECKING([for gforth])
622: GFORTH="`cd / && which gforth 2>/dev/null`"
623: if test -z "$GFORTH"; then
624: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
625: else
626: PREFORTH="$GFORTH -i `cd / && gforth --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
627: fi
628: AC_SUBST(PREFORTH)
629: AC_DEFINE_UNQUOTED(PREFORTH,"$PREFORTH",[How to invoke the pre-installed gforth])
630: AC_MSG_RESULT($PREFORTH)
631:
632: #echo "machine='$machine'"
633:
634: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
635: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
636: AC_SUBST(asm_fs)
637:
638: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
639: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
640: AC_SUBST(disasm_fs)
641:
642: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
643:
644: case "$host_os" in
645: *win32*)
646: # !!!FIXME!!! problems with cygwin and ';' as path separator
647: DIRSEP="\\\\"
648: PATHSEP=";"
649: #we want the builtins of command.com/cmd.exe and its
650: # handling of .com files.
651: #$COMSPEC contains the name of the Windows shell;
652: # the ./ is there, because the bash does not recognize
653: # absolute DOS filenames
654: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
655: ;;
656: *darwin*)
657: #Darwin uses some funny preprocessor by default; eliminate it:
658: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
659: CFLAGS="$CFLAGS -no-cpp-precomp"
660: DIRSEP="/"
661: PATHSEP=":"
662: DEFAULTSYSTEMPREFIX=""
663: ;;
664: *)
665: DIRSEP="/"
666: PATHSEP=":"
667: DEFAULTSYSTEMPREFIX=""
668: ;;
669: esac
670: AC_SUBST(DIRSEP)
671: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
672: AC_SUBST(PATHSEP)
673: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
674: AC_SUBST(DEFAULTSYSTEMPREFIX)
675: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
676:
677: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
678: #This magic incantation seems to be completely undocumented.
679: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
680:
681: dnl Now a little support for DOS/DJGCC
682: AC_SUBST(GFORTH_EXE)
683: GFORTH_EXE="true"
684: AC_SUBST(GFORTHFAST_EXE)
685: GFORTHFAST_EXE="true"
686: AC_SUBST(GFORTHITC_EXE)
687: GFORTHITC_EXE="true"
688: AC_SUBST(GFORTHDITC_EXE)
689: GFORTHDITC_EXE="true"
690:
691: AC_SUBST(FORTHSIZES)
692:
693: dnl if test "$PEEPHOLE" = "yes"
694: dnl then
695: dnl PEEPHOLEFLAG="true"
696: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
697: dnl else
698: dnl PEEPHOLEFLAG="false"
699: dnl fi
700: PEEPHOLEFLAG="true"
701: AC_SUBST(PEEPHOLEFLAG)
702:
703: dnl copy commands for systems that don't have links
704: AC_SUBST(LINK_KERNL)
705: LINK_KERNL=""
706:
707: #if test $host_os=dos
708: #then
709: # echo Configuring for DOS!!!
710: # MAKE_EXE="coff2exe gforth"
711: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
712: #fi
713:
714: dnl the following macro produces a warning with autoconf-2.1
715: AC_C_BIGENDIAN
716: AC_SUBST(KERNEL)
717: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
718: if test $ac_cv_c_bigendian = yes; then
719: bytesex=b
720: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
721: else
722: bytesex=l
723: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
724: fi
725:
726: #check how to do asm(".skip 16")
727: #echo "CFLAGS=$CFLAGS"
728: #echo "ac_link=$ac_link"
729: AC_MSG_CHECKING([if and how we can waste code space])
730: if test -z "$skipcode"; then
731: skipcode=no
732: CFLAGS_1="$CFLAGS"
733: CFLAGS="$CFLAGS $ENGINE_FLAGS"
734: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
735: do
736: AC_TRY_RUN(
737: [int foo(int,int,int);
738: main()
739: {
740: exit(foo(0,0,0)!=16);
741: }
742: int foo(int x, int y, int z)
743: {
744: static void *labels[]={&&label1, &&label2};
745: if (x) {
746: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
747: label1:
748: asm("$i"); /* or ".space 16" or somesuch */
749: label2: ;
750: }
751: {
752: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
753: return labels[1]-labels[0];
754: }
755: }]
756: ,skipcode=$i; break
757: ,,)
758: done
759: CFLAGS=$CFLAGS_1
760: fi
761: AC_MSG_RESULT($skipcode)
762: if test "$skipcode" = no
763: then
764: if test -z $no_dynamic_default; then
765: no_dynamic_default=1
766: AC_MSG_WARN(Disabling default dynamic native code generation)
767: fi
768: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
769: else
770: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
771: fi
772:
773: AC_MSG_CHECKING([if and how we can do comments in asm statements])
774: #the point here is to get asm statements that look different to
775: #gcc's "optimizer"
776: if test -z "$asmcomment"; then
777: asmcomment=no
778: CFLAGS_1="$CFLAGS"
779: CFLAGS="$CFLAGS $ENGINE_FLAGS"
780: for i in '"# "' '"! "' '"; "'; do
781: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
782: done
783: CFLAGS=$CFLAGS_1
784: fi
785: AC_MSG_RESULT($asmcomment)
786: if test "$asmcomment" != no
787: then
788: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
789: fi
790:
791: test "$no_dynamic_default" || no_dynamic_default=0
792: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
793:
794: dnl Checks for programs.
795: AC_PROG_LN_S
796: AC_PROG_INSTALL
797: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
798:
799: dnl MacOS X has a libtool that does something else
800: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
801:
802: dnl Checks for library functions
803: dnl This check is just for making later checks link with libm.
804: dnl using sin here is no good idea since it is built-into gcc and typechecked
805: AC_CHECK_LIB(m,asin)
806: AC_CHECK_LIB(ltdl,lt_dlinit)
807: AC_CHECK_LIB(dl,dlopen)
808: dnl check for libffi 2.x
809: AC_CHECK_LIB(ffi,ffi_call)
810: if test $ac_cv_lib_ffi_ffi_call = yes
811: then
812: LIBFFIFLAG="true"
813: FFCALLFLAG="false"
814: OLDCALLFLAG="false"
815: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
816: else
817: dnl check for ffcall libraries
818: dnl unfortunately, these four calls are separated out into a library each.
819: AC_CHECK_LIB(avcall,__builtin_avcall)
820: AC_CHECK_LIB(callback,__vacall_r)
821: AC_CHECK_LIB(vacall,vacall)
822: AC_CHECK_LIB(trampoline,alloc_trampoline)
823: LIBFFIFLAG="false"
824: FFCALLFLAG="false"
825: OLDCALLFLAG="true"
826: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
827: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
828: fi
829: AC_SUBST(LIBFFIFLAG)
830: AC_SUBST(FFCALLFLAG)
831: AC_SUBST(OLDCALLFLAG)
832: if test "$host_os" != "nextstep3"
833: then
834: AC_FUNC_MEMCMP
835: fi
836: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
837: AC_FUNC_FSEEKO
838: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
839: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
840: AC_DECL_SYS_SIGLIST
841: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
842: AC_CHECK_FUNCS(expm1 log1p)
843: AC_REPLACE_FUNCS(rint ecvt)
844: dnl No check for select, because our replacement is no good under
845: dnl anything but DOS
846: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
847: AC_FUNC_FNMATCH
848: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
849: AC_CHECK_FUNCS(mmap sysconf getpagesize)
850: AM_PATH_LISPDIR
851:
852: kernel_fi=kernl${vwordsize}${bytesex}.fi
853: include_fi=kernl${wordsize}${bytesex}${EC}.fi
854: AC_SUBST(kernel_fi)
855: AC_SUBST(include_fi)
856:
857: #this breaks bindists
858: #dnl replace srource directory by absolute value
859: #if test $srcdir = "."; then srcdir=`pwd`
860: #fi
861:
862: AC_SUBST(machine)
863: AC_CONFIG_FILES([
864: Makefile
865: Makedist
866: gforthmi
867: vmgen
868: machpc.fs
869: envos.fs
870: preforth
871: engine/Makefile
872: engine/libcc.h
873: doc/version.texi
874: build-ec ])
875: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
876: chmod +x gforthmi
877: chmod +x vmgen
878: chmod +x build-ec
879: chmod +x preforth
880: test -d kernel||mkdir kernel
881: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
882: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
883: AC_OUTPUT
884:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>