File:  [gforth] / gforth / configure.in
Revision 1.216: download - view: text, annotated - select for diffs
Sat Feb 23 13:03:55 2008 UTC (16 years ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Fixed build problem
Some changes for NXT

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation, either version 3
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.6.9-20080223],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: AC_PREREQ(2.54)
   25: #snapshots have numbers major.minor.release-YYYYMMDD
   26: #note that lexicographic ordering must be heeded.
   27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   28: UPDATED="February 23, 2008"
   29: AC_SUBST(UPDATED)
   30: AC_CONFIG_HEADERS(engine/config.h)
   31: 
   32: #suppress the "-g -O2" default
   33: test "$CFLAGS" || CFLAGS=-O2
   34: 
   35: AC_ARG_ENABLE(force-cdiv,
   36: 	AC_HELP_STRING([--enable-force-cdiv],
   37: 		       [  Use the native C division - symmetric - instead of
   38: 		          floored division (default disabled).]),
   39: 	,enable_force_cdiv=no)
   40: test "$enable_force_cdiv" = "no"||
   41:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   42: 
   43: AC_SUBST(PROFEXES)
   44: AC_SUBST(PROFOBJS)
   45: AC_ARG_ENABLE(prof,
   46: 	AC_HELP_STRING([--enable-prof],
   47: 			[ Build gforth-prof, which outputs frequently occuring
   48:                           sequences of primitives.]),
   49: 	,enable_prof=no)
   50: if test "$enable_prof" != "no"; then
   51:   PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
   52: fi
   53: 
   54: AC_ARG_WITH(debug,
   55: [  --with-debug		  specifies option -g to compile with debug info
   56:   --without-debug	  omits the -g switch and creates smaller images on
   57: 			  machines where "strip" has problems with gcc style
   58: 			  debugging informations.],
   59: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   60: 
   61: GCC_LD="\$(GCC)"
   62: EC_MODE="false"
   63: EC=""
   64: engine2='engine2$(OPT).o'
   65: engine_fast2='engine-fast2$(OPT).o'
   66: no_dynamic=""
   67: image_i=""
   68: signals_o="io.o signals.o"
   69: 
   70: AC_ARG_WITH(ec,
   71: 	AC_HELP_STRING([--with-ec=<arch>],
   72: 			[  Build gforth for systems without OS.]),
   73: [if test "$withval" = "no"; then
   74:   echo "defining hosted system"
   75: else
   76:   echo "defining standalone system (${withval})"
   77:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
   78:   EC_MODE="true"
   79:   EC="-ec"
   80:   engine2=""
   81:   engine_fast2=""
   82:   no_dynamic="-DNO_DYNAMIC"
   83:   image_i="image.i"
   84:   if test "$withval" != "yes"; then
   85:     signals_o="io-${withval}.o"
   86:   else
   87:     signals_o="io.o"
   88:   fi
   89:   GCC_PATH=$(which $CC)
   90:   LIB_PATH=${GCC_PATH%/*/*}
   91:   GCC_LD="\$(LD)"
   92:   platform=${withval}
   93: fi])
   94: 
   95: #variables mentioned in INSTALL
   96: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
   97: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   98: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
   99: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  100: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  101: 
  102: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  103: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  104: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  105: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  106: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  107: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  108: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  109: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  110: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  111: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  112: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  113: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  114: AC_ARG_VAR(asmcomment, [assembler comment start string])
  115: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  116: 
  117: #set up feature test macros, so the tests get them right:
  118: # turn on all POSIX, SUSv3, and GNU features if available
  119: AC_GNU_SOURCE
  120: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  121: 
  122: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  123: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  124: dnl but not for _XOPEN_SOURCE)
  125: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  126: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  127: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  128: # turn on large file support with 64-bit off_t where available
  129: AC_SYS_LARGEFILE
  130: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  131: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  132: 
  133: #currently we force direct threading this way.  Eventually we should
  134: #setup in the arch and engine files right
  135: 
  136: AC_PROG_CC
  137: 
  138: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  139: 
  140: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  141: test x$condbranch_opt = x && 
  142: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
  143:    condbranch_opt=0
  144: else
  145:    condbranch_opt=1
  146: fi
  147: AC_MSG_RESULT($condbranch_opt)
  148: AC_SUBST(condbranch_opt)
  149: 
  150: AC_SUBST(CC)
  151: AC_SUBST(GCC_LD)
  152: AC_SUBST(DEBUGFLAG)
  153: AC_SUBST(EC)
  154: AC_SUBST(EC_MODE)
  155: AC_SUBST(engine2)
  156: AC_SUBST(engine_fast2)
  157: AC_SUBST(no_dynamic)
  158: AC_SUBST(image_i)
  159: AC_SUBST(signals_o)
  160: 
  161: #this is used to disable some (not generally essential) part of the
  162: #Makefile that some makes don't grok.  It would be better to test for
  163: #this specific Makefile feature than the make version.
  164: AC_MSG_CHECKING(make type)
  165: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  166: GNUMAKE='#'
  167: test "$make_type" = "GNU Make" && GNUMAKE=''
  168: AC_MSG_RESULT($make_type)
  169: AC_SUBST(GNUMAKE)
  170: 
  171: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  172: OLDLDFLAGS=$LDFLAGS
  173: LDFLAGS="$LDFLAGS -export-dynamic"
  174: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  175: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  176: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  177: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  178: AC_MSG_RESULT($ac_export_dynamic)
  179: 
  180: #terminology is a bit unusual here: The host is the system on which
  181: #gforth will run; the system on which configure will run is the `build'
  182: AC_CANONICAL_HOST
  183: case "$host_cpu" in
  184: 	arm*)
  185: 		machine=arm
  186: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  187: 		if test x$platform = xnxt; then
  188: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  189: 		fi
  190: 		if test -z $arm_cacheflush; then
  191: 		   case "$host_os" in
  192: 		     *linux*)
  193: 			arm_cacheflush=arch/arm/cacheflush-linux 
  194: 			;;
  195: 		     *)   
  196: 			no_dynamic_default=1
  197: 			arm_cacheflush=arch/arm/cacheflush0
  198: 			AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  199: 			;;
  200:                    esac
  201: 		fi
  202:                 AC_LIBSOURCES([../arch/arm/cacheflush0, dnl
  203: 			       ../arch/arm/cacheflush-linux])
  204:                 AC_LIBOBJ(../$arm_cacheflush)
  205:                 #longer skipcodes lead to problems on ARM, and it uses
  206:                 #only 4-byte alignment anyway
  207: 		test "$skipcode" || skipcode="nop"
  208: 		;;
  209: 	hppa*)
  210: 		machine=hppa
  211: 		$srcdir/mkinstalldirs arch/hppa
  212: 		AC_LIBOBJ(../arch/hppa/cache)
  213: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  214: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  215: 		LIBS="$LIBS -L/lib/pa1.1/"
  216: 		;;
  217: 	sparc*)
  218: 		machine=sparc
  219: 		;;
  220: 	i386)
  221: 		machine=386
  222: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  223: 		;;
  224: 	i486)
  225: 		machine=386
  226: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
  227: 		;;
  228: 	i*86)
  229: 		machine=386
  230: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  231: 		CFLAGS_1="$CFLAGS"
  232: 		CFLAGS="$CFLAGS -march=pentium"
  233: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  234: 		;;
  235: 	x86_64)
  236: 		case $CC
  237: 		in
  238: 		    *-m32*)
  239: 		    	machine=386
  240: 			CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  241: 			CFLAGS_1="$CFLAGS"
  242: 			CFLAGS="$CFLAGS -march=athlon64"
  243: 			;;
  244: 		    *)
  245: 		    	machine=amd64
  246: 			;;
  247: 		esac
  248: 		;;
  249: 	ia64*)
  250: 		machine=ia64
  251: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  252: 		test "$skipcode" || skipcode="nop.i 0"
  253: 		#".skip 16" passes the test below,
  254: 		# but gives an assembler error in engine
  255: 		;;
  256:         m68k)
  257: 		machine=m68k
  258: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  259: 		if test "$host_os" = "nextstep3"
  260: 		then
  261: 			AC_LIBOBJ(termios)
  262: 		fi
  263: 		;;
  264: 	mips*)
  265: 		machine=mips
  266: 		#dynamic native code has the following problems on MIPS:
  267: 		#
  268: 		#1) J/JAL seems relocatable, but is are only
  269: 		#relocatable within a 256MB-segment.  While we try to
  270: 		#get the linker to arrange this, there is no guarantee
  271: 		#that this will succeed (and if the user uses a lot of
  272: 		#memory, it is likely to fail).
  273: 		#
  274: 		#2) The way we generate dynamic native code may
  275: 		#violate MIPS architectural restrictions (in
  276: 		#particular, the delay slots of LW, MFLO, etc.)
  277: 		#
  278: 		#Therefore we disable dynamic native code by default:
  279: 		if test -z $no_dynamic_default; then
  280: 		    no_dynamic_default=1
  281: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  282: 		fi
  283: 		;;
  284: 	alpha*)
  285: 		machine=alpha
  286: 		#full IEEE FP support for more uniformity across platforms:
  287: 		CFLAGS="$CFLAGS -mieee"
  288: 		;;
  289: 	power*|rs6000)
  290: 		machine=power
  291: 		$srcdir/mkinstalldirs arch/power
  292: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  293: 		#long long is broken on (at least) gcc-2.95.* for PPC
  294: 		test x$ac_cv_sizeof_long_long = x && 
  295: 		($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
  296: 		ac_cv_sizeof_long_long=0
  297:                 #The only architecture with enough callee-saved registers
  298:                 test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
  299:                 #or use 2, hardly slower at run-time and starts up faster
  300: 		;;
  301: 	*)
  302: 		AC_MSG_WARN([Using a generic machine description])
  303: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  304: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  305: 		machine=generic
  306: 		#I-cache flushing would be needed for dynamic code generation
  307: 		if test -z $no_dynamic_default; then
  308: 		    no_dynamic_default=1
  309: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  310: 		fi
  311: esac
  312: AC_SUBST(host)
  313: 
  314: MAKEINC=""
  315: 
  316: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  317: if test x$EC_MODE = xtrue
  318: then
  319: 	echo "Check for arch/$machine/$platform/gforth.ld"
  320: 	if test -f arch/$machine/$platform/gforth.ld
  321: 	then
  322: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  323: 		if test x$platform = xnxt; then
  324: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  325: 		fi
  326: 	fi
  327: 	if test -f arch/$machine/$platform/make.inc
  328: 	then
  329: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  330: 	fi
  331: fi
  332: AC_SUBST(MAKEINC)
  333: 
  334: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  335: 
  336: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
  337: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
  338: 		   [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
  339: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  340: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  341: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  342: 
  343: test x$GCC_PR15242_WORKAROUND = x ||
  344: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  345:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  346: 
  347: dnl the following macro produces a warning with autoconf-2.1
  348: AC_CHECK_SIZEOF(char *)
  349: case "$ac_cv_sizeof_char_p" in
  350:   2)
  351:     wordsize=16
  352:     ;;
  353:   4)
  354:     wordsize=32
  355:     ;;
  356:   8)
  357:     wordsize=64
  358:     ;;
  359: esac
  360: 
  361: AC_CHECK_SIZEOF(void *)
  362: case "$ac_cv_sizeof_void_p" in
  363:   2)
  364:     vwordsize=16
  365:     ;;
  366:   4)
  367:     vwordsize=32
  368:     ;;
  369:   8)
  370:     vwordsize=64
  371:     ;;
  372: esac
  373: 
  374: AC_CHECK_SIZEOF(char)
  375: AC_CHECK_SIZEOF(short)
  376: AC_CHECK_SIZEOF(int)
  377: AC_CHECK_SIZEOF(long)
  378: AC_CHECK_SIZEOF(long long)
  379: AC_CHECK_SIZEOF(intptr_t)
  380: AC_CHECK_SIZEOF(int128_t)
  381: AC_CHECK_SIZEOF(uint128_t)
  382: 
  383: AC_MSG_CHECKING([for a C type for cells])
  384: ac_cv_int_type_cell=none
  385: case "$ac_cv_sizeof_char_p" in
  386:   $ac_cv_sizeof_int)
  387:     ac_cv_int_type_cell=int
  388:     ;;
  389:   $ac_cv_sizeof_short)
  390:     ac_cv_int_type_cell=short
  391:     ;;
  392:   $ac_cv_sizeof_char)
  393:     ac_cv_int_type_cell=char
  394:     ;;
  395:   $ac_cv_sizeof_long)
  396:     ac_cv_int_type_cell=long
  397:     ;;
  398:   $ac_cv_sizeof_long_long)
  399:     ac_cv_int_type_cell="long long"
  400:     ;;
  401:   $ac_cv_sizeof_intptr_t)
  402:     ac_cv_int_type_cell="intptr_t"
  403:     ;;
  404: esac
  405: AC_MSG_RESULT($ac_cv_int_type_cell)
  406: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  407: 
  408: AC_MSG_CHECKING([for a C type for wydes])
  409: ac_cv_wyde_type_cell=none
  410: case 2 in
  411:   $ac_cv_sizeof_int)
  412:     ac_cv_wyde_type_cell=int
  413:     ;;
  414:   $ac_cv_sizeof_short)
  415:     ac_cv_wyde_type_cell=short
  416:     ;;
  417:   $ac_cv_sizeof_char)
  418:     ac_cv_wyde_type_cell=char
  419:     ;;
  420:   $ac_cv_sizeof_long)
  421:     ac_cv_wyde_type_cell=long
  422:     ;;
  423:   $ac_cv_sizeof_long_long)
  424:     ac_cv_wyde_type_cell="long long"
  425:     ;;
  426:   $ac_cv_sizeof_intptr_t)
  427:     ac_cv_wyde_type_cell="intptr_t"
  428:     ;;
  429: esac
  430: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  431: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  432: 
  433: AC_MSG_CHECKING([for a C type for tetrabytes])
  434: ac_cv_tetrabyte_type_cell=none
  435: case 4 in
  436:   $ac_cv_sizeof_int)
  437:     ac_cv_tetrabyte_type_cell=int
  438:     ;;
  439:   $ac_cv_sizeof_short)
  440:     ac_cv_tetrabyte_type_cell=short
  441:     ;;
  442:   $ac_cv_sizeof_char)
  443:     ac_cv_tetrabyte_type_cell=char
  444:     ;;
  445:   $ac_cv_sizeof_long)
  446:     ac_cv_tetrabyte_type_cell=long
  447:     ;;
  448:   $ac_cv_sizeof_long_long)
  449:     ac_cv_tetrabyte_type_cell="long long"
  450:     ;;
  451:   $ac_cv_sizeof_intptr_t)
  452:     ac_cv_tetrabyte_type_cell="intptr_t"
  453:     ;;
  454: esac
  455: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  456: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  457: 
  458: AC_MSG_CHECKING([for a C type for double-cells])
  459: ac_cv_int_type_double_cell=none
  460: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  461:   $ac_cv_sizeof_short)
  462:     ac_cv_int_type_double_cell=short
  463:     ;;
  464:   $ac_cv_sizeof_int)
  465:     ac_cv_int_type_double_cell=int
  466:     ;;
  467:   $ac_cv_sizeof_long)
  468:     ac_cv_int_type_double_cell=long
  469:     ;;
  470:   $ac_cv_sizeof_long_long)
  471:     ac_cv_int_type_double_cell="long long"
  472:     ;;
  473:   $ac_cv_sizeof_intptr_t)
  474:     ac_cv_int_type_double_cell="intptr_t"
  475:     ;;
  476:   $ac_cv_sizeof_int128_t)
  477:     ac_cv_int_type_double_cell="int128_t"
  478:     ;;
  479: esac
  480: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  481: 
  482: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  483: ac_cv_int_type_double_ucell=none
  484: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  485:   $ac_cv_sizeof_short)
  486:     ac_cv_int_type_double_ucell="unsigned short"
  487:     ;;
  488:   $ac_cv_sizeof_int)
  489:     ac_cv_int_type_double_ucell="unsigned int"
  490:     ;;
  491:   $ac_cv_sizeof_long)
  492:     ac_cv_int_type_double_ucell="unsigned long"
  493:     ;;
  494:   $ac_cv_sizeof_long_long)
  495:     ac_cv_int_type_double_ucell="unsigned long long"
  496:     ;;
  497:   $ac_cv_sizeof_intptr_t)
  498:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  499:     ;;
  500:   $ac_cv_sizeof_uint128_t)
  501:     ac_cv_int_type_double_ucell="uint128_t"
  502:     ;;
  503: esac
  504: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  505: 
  506: if test "$ac_cv_int_type_double_cell" != none && \
  507:    test "$ac_cv_int_type_double_ucell" != none
  508: then
  509: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  510: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  511:         OPTS=-ll
  512: else
  513:         if test "$ac_cv_sizeof_char_p" == 8; then
  514:            OPTS="-ll -noll"
  515:         else
  516:            OPTS=-noll
  517:         fi
  518: fi
  519: 
  520: if grep -q FORCE_REG arch/$machine/machine.h; then
  521:    OPTS=`for i in $OPTS; do echo -n "$i-reg "; done`$OPTS
  522: fi
  523: AC_SUBST(OPTS)
  524: 
  525: AC_TYPE_OFF_T
  526: AC_CHECK_SIZEOF(off_t)
  527: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  528: ac_small_off_t=$?
  529: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  530: 
  531: ENGINE_FLAGS=
  532: AC_SUBST(ENGINE_FLAGS)
  533: 
  534: # Try if GCC understands -fno-gcse
  535: 
  536: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  537: CFLAGS_1="$CFLAGS"
  538: CFLAGS="$CFLAGS -fno-gcse"
  539: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  540: CFLAGS="$CFLAGS_1"
  541: AC_MSG_RESULT($ac_nogcse)
  542: 
  543: # Try if GCC understands -fno-strict-aliasing
  544: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  545: CFLAGS_1="$CFLAGS"
  546: CFLAGS="$CFLAGS -fno-strict-aliasing"
  547: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  548: CFLAGS="$CFLAGS_1"
  549: AC_MSG_RESULT($ac_nostrictaliasing)
  550: 
  551: # Try if GCC understands -fno-crossjumping
  552: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  553: CFLAGS_1="$CFLAGS"
  554: CFLAGS="$CFLAGS -fno-crossjumping"
  555: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  556: CFLAGS="$CFLAGS_1"
  557: AC_MSG_RESULT($ac_nocrossjumping)
  558: 
  559: # Try if GCC understands -fno-reorder-blocks
  560: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  561: CFLAGS_1="$CFLAGS"
  562: CFLAGS="$CFLAGS -fno-reorder-blocks"
  563: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  564: CFLAGS="$CFLAGS_1"
  565: AC_MSG_RESULT($ac_noreorder_blocks)
  566: 
  567: # Try if GCC understands -falign-labels=1
  568: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  569: CFLAGS_1="$CFLAGS"
  570: CFLAGS="$CFLAGS -falign-labels=1"
  571: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  572: CFLAGS="$CFLAGS_1"
  573: AC_MSG_RESULT($ac_align_labels)
  574: 
  575: # Try if GCC understands -falign-loops=1
  576: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
  577: CFLAGS_1="$CFLAGS"
  578: CFLAGS="$CFLAGS -falign-loops=1"
  579: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
  580: CFLAGS="$CFLAGS_1"
  581: AC_MSG_RESULT($ac_align_loops)
  582: 
  583: # Try if GCC understands -falign-jumps=1
  584: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
  585: CFLAGS_1="$CFLAGS"
  586: CFLAGS="$CFLAGS -falign-jumps=1"
  587: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
  588: CFLAGS="$CFLAGS_1"
  589: AC_MSG_RESULT($ac_align_jumps)
  590: 
  591: # Try if GCC understands __attribute__((unused))
  592: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  593: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  594: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  595: AC_MSG_RESULT($MAYBE_UNUSED)
  596: 
  597: #try if m4 understands -s
  598: AC_MSG_CHECKING([how to invoke m4])
  599: if m4 -s /dev/null >/dev/null 2>&1; then
  600:  M4="m4 -s"
  601: else
  602:  M4=m4
  603: fi
  604: AC_SUBST(M4)
  605: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
  606: AC_MSG_RESULT($M4)
  607: 
  608: # Find installed Gforth
  609: AC_MSG_CHECKING([for gforth])
  610: GFORTH="`cd / && which gforth 2>/dev/null`"
  611: if test -z "$GFORTH"; then
  612:   PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
  613: else
  614:   PREFORTH="$GFORTH -i `cd / && gforth --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
  615: fi
  616: AC_SUBST(PREFORTH)
  617: AC_DEFINE_UNQUOTED(PREFORTH,"$PREFORTH",[How to invoke the pre-installed gforth])
  618: AC_MSG_RESULT($PREFORTH)
  619: 
  620: #echo "machine='$machine'"
  621: 
  622: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  623: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
  624: AC_SUBST(asm_fs)
  625: 
  626: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  627: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
  628: AC_SUBST(disasm_fs)
  629: 
  630: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  631: 
  632: case "$host_os" in
  633: 	*win32*)
  634: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  635: 		DIRSEP="\\\\"
  636: 		PATHSEP=";"
  637: 		#we want the builtins of command.com/cmd.exe and its
  638: 		# handling of .com files.
  639: 		#$COMSPEC contains the name of the Windows shell;
  640: 		# the ./ is there, because the bash does not recognize
  641: 		# absolute DOS filenames
  642: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  643: 		;;
  644: 	*darwin*)
  645: 		#Darwin uses some funny preprocessor by default; eliminate it:
  646: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  647: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  648: 		DIRSEP="/"
  649: 		PATHSEP=":"
  650: 		DEFAULTSYSTEMPREFIX=""
  651: 		;;
  652: 	*)
  653: 		DIRSEP="/"
  654: 		PATHSEP=":"
  655: 		DEFAULTSYSTEMPREFIX=""
  656: 		;;
  657: esac
  658: AC_SUBST(DIRSEP)
  659: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  660: AC_SUBST(PATHSEP)
  661: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  662: AC_SUBST(DEFAULTSYSTEMPREFIX)
  663: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  664: 
  665: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  666: #This magic incantation  seems to be completely undocumented.
  667: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  668: 
  669: dnl Now a little support for DOS/DJGCC
  670: AC_SUBST(GFORTH_EXE)
  671: GFORTH_EXE="true"
  672: AC_SUBST(GFORTHFAST_EXE)
  673: GFORTHFAST_EXE="true"
  674: AC_SUBST(GFORTHITC_EXE)
  675: GFORTHITC_EXE="true"
  676: AC_SUBST(GFORTHDITC_EXE)
  677: GFORTHDITC_EXE="true"
  678: 
  679: AC_SUBST(FORTHSIZES)
  680: 
  681: dnl if test "$PEEPHOLE" = "yes"
  682: dnl then
  683: dnl    PEEPHOLEFLAG="true"
  684: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  685: dnl else
  686: dnl    PEEPHOLEFLAG="false"
  687: dnl fi
  688: PEEPHOLEFLAG="true"
  689: AC_SUBST(PEEPHOLEFLAG)
  690: 
  691: dnl copy commands for systems that don't have links
  692: AC_SUBST(LINK_KERNL)
  693: LINK_KERNL=""
  694: 
  695: #if test $host_os=dos
  696: #then
  697: #  echo Configuring for DOS!!!
  698: #  MAKE_EXE="coff2exe gforth"
  699: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  700: #fi
  701: 
  702: dnl the following macro produces a warning with autoconf-2.1
  703: AC_C_BIGENDIAN
  704: AC_SUBST(KERNEL)
  705: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  706: if test $ac_cv_c_bigendian = yes; then
  707:   bytesex=b
  708:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  709: else
  710:   bytesex=l
  711:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  712: fi
  713: 
  714: #check how to do asm(".skip 16")
  715: #echo "CFLAGS=$CFLAGS"
  716: #echo "ac_link=$ac_link"
  717: AC_MSG_CHECKING([if and how we can waste code space])
  718: if test -z "$skipcode"; then
  719:     skipcode=no
  720:     CFLAGS_1="$CFLAGS"
  721:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  722:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  723:     do
  724: 	AC_TRY_RUN(
  725: [int foo(int,int,int);
  726: main()
  727: {
  728:   exit(foo(0,0,0)!=16);
  729: }
  730: int foo(int x, int y, int z)
  731: {
  732:   static void *labels[]={&&label1, &&label2};
  733:   if (x) {
  734:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  735:   label1:
  736:     asm("$i"); /* or ".space 16" or somesuch */
  737:   label2: ;
  738:   }
  739:   {
  740:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  741:   return labels[1]-labels[0];
  742:   }
  743: }]
  744: 	,skipcode=$i; break
  745: 	,,)
  746:     done
  747:     CFLAGS=$CFLAGS_1
  748: fi
  749: AC_MSG_RESULT($skipcode)
  750: if test "$skipcode" = no
  751: then 
  752:     if test -z $no_dynamic_default; then
  753: 	no_dynamic_default=1
  754: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  755:     fi
  756:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  757: else
  758:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  759: fi
  760: 
  761: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  762: #the point here is to get asm statements that look different to
  763: #gcc's "optimizer"
  764: if test -z "$asmcomment"; then
  765:     asmcomment=no
  766:     CFLAGS_1="$CFLAGS"
  767:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  768:     for i in '"# "' '"! "' '"; "'; do
  769: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  770:     done
  771:     CFLAGS=$CFLAGS_1
  772: fi
  773: AC_MSG_RESULT($asmcomment)
  774: if test "$asmcomment" != no
  775: then 
  776:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  777: fi
  778: 
  779: test "$no_dynamic_default" || no_dynamic_default=0
  780: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  781: 
  782: dnl Checks for programs.
  783: AC_PROG_LN_S
  784: AC_PROG_INSTALL
  785: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  786: 
  787: dnl MacOS X has a libtool that does something else
  788: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
  789: 
  790: dnl Checks for library functions
  791: dnl This check is just for making later checks link with libm.
  792: dnl using sin here is no good idea since it is built-into gcc and typechecked
  793: AC_CHECK_LIB(m,asin)
  794: AC_CHECK_LIB(ltdl,lt_dlinit)
  795: AC_CHECK_LIB(dl,dlopen)
  796: dnl check for libffi 2.x
  797: AC_CHECK_LIB(ffi,ffi_call)
  798: if test $ac_cv_lib_ffi_ffi_call = yes
  799: then
  800: LIBFFIFLAG="true"
  801: FFCALLFLAG="false"
  802: OLDCALLFLAG="false"
  803: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
  804: else
  805: dnl check for ffcall libraries
  806: dnl unfortunately, these four calls are separated out into a library each.
  807: AC_CHECK_LIB(avcall,__builtin_avcall)
  808: AC_CHECK_LIB(callback,__vacall_r)
  809: AC_CHECK_LIB(vacall,vacall)
  810: AC_CHECK_LIB(trampoline,alloc_trampoline)
  811: LIBFFIFLAG="false"
  812: FFCALLFLAG="false"
  813: OLDCALLFLAG="true"
  814: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  815: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  816: fi
  817: AC_SUBST(LIBFFIFLAG)
  818: AC_SUBST(FFCALLFLAG)
  819: AC_SUBST(OLDCALLFLAG)
  820: if test "$host_os" != "nextstep3"
  821: then
  822: 	AC_FUNC_MEMCMP
  823: fi
  824: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  825: AC_FUNC_FSEEKO
  826: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
  827: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  828: AC_DECL_SYS_SIGLIST
  829: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  830: AC_CHECK_FUNCS(expm1 log1p)
  831: AC_REPLACE_FUNCS(rint ecvt)
  832: dnl No check for select, because our replacement is no good under
  833: dnl anything but DOS
  834: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  835: AC_FUNC_FNMATCH
  836: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  837: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  838: AM_PATH_LISPDIR
  839: 
  840: kernel_fi=kernl${vwordsize}${bytesex}.fi
  841: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  842: AC_SUBST(kernel_fi)
  843: AC_SUBST(include_fi)
  844: 
  845: #this breaks bindists
  846: #dnl replace srource directory by absolute value
  847: #if test $srcdir = "."; then srcdir=`pwd` 
  848: #fi
  849: 
  850: AC_SUBST(machine)
  851: AC_CONFIG_FILES([
  852: Makefile
  853: Makedist
  854: gforthmi
  855: vmgen
  856: machpc.fs
  857: envos.fs
  858: engine/Makefile
  859: engine/libcc.h
  860: doc/version.texi
  861: build-ec ])
  862: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  863: chmod +x gforthmi
  864: chmod +x vmgen
  865: chmod +x build-ec
  866: test -d kernel||mkdir kernel
  867: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
  868: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
  869: AC_OUTPUT
  870: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>