File:  [gforth] / gforth / configure.in
Revision 1.209: download - view: text, annotated - select for diffs
Wed Jan 16 21:50:55 2008 UTC (16 years, 2 months ago) by anton
Branches: MAIN
CVS tags: HEAD
BUILD-FROM-SCRATCH: prevent gforth hangs

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation, either version 3
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.6.9-20070604],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: AC_PREREQ(2.54)
   25: #snapshots have numbers major.minor.release-YYYYMMDD
   26: #note that lexicographic ordering must be heeded.
   27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   28: UPDATED="June 02, 2007"
   29: AC_SUBST(UPDATED)
   30: AC_CONFIG_HEADERS(engine/config.h)
   31: 
   32: #suppress the "-g -O2" default
   33: test "$CFLAGS" || CFLAGS=-O2
   34: 
   35: AC_ARG_ENABLE(force-cdiv,
   36: 	AC_HELP_STRING([--enable-force-cdiv],
   37: 		       [  Use the native C division - symmetric - instead of
   38: 		          floored division (default disabled).]),
   39: 	,enable_force_cdiv=no)
   40: test "$enable_force_cdiv" = "no"||
   41:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   42: 
   43: AC_SUBST(PROFEXES)
   44: AC_SUBST(PROFOBJS)
   45: AC_ARG_ENABLE(prof,
   46: 	AC_HELP_STRING([--enable-prof],
   47: 			[ Build gforth-prof, which outputs frequently occuring
   48:                           sequences of primitives.]),
   49: 	,enable_prof=no)
   50: if test "$enable_prof" != "no"; then
   51:   PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
   52: fi
   53: 
   54: AC_ARG_WITH(debug,
   55: [  --with-debug		  specifies option -g to compile with debug info
   56:   --without-debug	  omits the -g switch and creates smaller images on
   57: 			  machines where "strip" has problems with gcc style
   58: 			  debugging informations.],
   59: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   60: 
   61: GCC_LD="\$(GCC)"
   62: EC_MODE="false"
   63: EC=""
   64: engine2='engine2$(OPT).o'
   65: engine_fast2='engine-fast2$(OPT).o'
   66: no_dynamic=""
   67: image_i=""
   68: signals_o="io.o signals.o"
   69: 
   70: AC_ARG_WITH(ec,
   71: 	AC_HELP_STRING([--with-ec=<arch>],
   72: 			[  Build gforth for systems without OS.]),
   73: [if test "$withval" = "no"; then
   74:   echo "defining hosted system"
   75: else
   76:   echo "defining standalone system (${withval})"
   77:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
   78:   EC_MODE="true"
   79:   EC="-ec"
   80:   engine2=""
   81:   engine_fast2=""
   82:   no_dynamic="-DNO_DYNAMIC"
   83:   image_i="image.i"
   84:   if test "$withval" != "yes"; then
   85:     signals_o="io-${withval}.o"
   86:   else
   87:     signals_o="io.o"
   88:   fi
   89:   GCC_PATH=$(which $CC)
   90:   LIB_PATH=${GCC_PATH%/*/*}
   91:   GCC_LD="\$(LD)"
   92:   platform=${withval}
   93: fi])
   94: 
   95: #variables mentioned in INSTALL
   96: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
   97: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   98: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
   99: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  100: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  101: 
  102: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  103: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  104: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  105: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  106: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  107: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  108: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  109: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  110: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  111: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  112: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  113: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  114: AC_ARG_VAR(asmcomment, [assembler comment start string])
  115: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  116: 
  117: #set up feature test macros, so the tests get them right:
  118: # turn on all POSIX, SUSv3, and GNU features if available
  119: AC_GNU_SOURCE
  120: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  121: 
  122: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  123: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  124: dnl but not for _XOPEN_SOURCE)
  125: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  126: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  127: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  128: # turn on large file support with 64-bit off_t where available
  129: AC_SYS_LARGEFILE
  130: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  131: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  132: 
  133: #currently we force direct threading this way.  Eventually we should
  134: #setup in the arch and engine files right
  135: 
  136: AC_PROG_CC
  137: 
  138: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  139: 
  140: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  141: test x$condbranch_opt = x && 
  142: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
  143:    condbranch_opt=0
  144: else
  145:    condbranch_opt=1
  146: fi
  147: AC_MSG_RESULT($condbranch_opt)
  148: AC_SUBST(condbranch_opt)
  149: 
  150: AC_SUBST(CC)
  151: AC_SUBST(GCC_LD)
  152: AC_SUBST(DEBUGFLAG)
  153: AC_SUBST(EC)
  154: AC_SUBST(EC_MODE)
  155: AC_SUBST(engine2)
  156: AC_SUBST(engine_fast2)
  157: AC_SUBST(no_dynamic)
  158: AC_SUBST(image_i)
  159: AC_SUBST(signals_o)
  160: 
  161: #this is used to disable some (not generally essential) part of the
  162: #Makefile that some makes don't grok.  It would be better to test for
  163: #this specific Makefile feature than the make version.
  164: AC_MSG_CHECKING(make type)
  165: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  166: GNUMAKE='#'
  167: test "$make_type" = "GNU Make" && GNUMAKE=''
  168: AC_MSG_RESULT($make_type)
  169: AC_SUBST(GNUMAKE)
  170: 
  171: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  172: OLDLDFLAGS=$LDFLAGS
  173: LDFLAGS="$LDFLAGS -export-dynamic"
  174: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  175: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  176: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  177: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  178: AC_MSG_RESULT($ac_export_dynamic)
  179: 
  180: #terminology is a bit unusual here: The host is the system on which
  181: #gforth will run; the system on which configure will run is the `build'
  182: AC_CANONICAL_HOST
  183: case "$host_cpu" in
  184: 	arm*)
  185: 		machine=arm
  186: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  187: 		if test x$platform = xnxt; then
  188: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  189: 		fi
  190: 		if test -z $arm_cacheflush; then
  191: 		    no_dynamic_default=1
  192:                     arm_cacheflush=arch/arm/cacheflush0
  193: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  194: 		fi
  195:                 AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
  196:                 AC_LIBOBJ(../$arm_cacheflush)
  197:                 #longer skipcodes lead to problems on ARM, and it uses
  198:                 #only 4-byte alignment anyway
  199: 		test "$skipcode" || skipcode="nop"
  200: 		;;
  201: 	hppa*)
  202: 		machine=hppa
  203: 		$srcdir/mkinstalldirs arch/hppa
  204: 		AC_LIBOBJ(../arch/hppa/cache)
  205: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  206: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  207: 		LIBS="$LIBS -L/lib/pa1.1/"
  208: 		;;
  209: 	sparc*)
  210: 		machine=sparc
  211: 		;;
  212: 	i386)
  213: 		machine=386
  214: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  215: 		;;
  216: 	i486)
  217: 		machine=386
  218: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
  219: 		;;
  220: 	i*86)
  221: 		machine=386
  222: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  223: 		CFLAGS_1="$CFLAGS"
  224: 		CFLAGS="$CFLAGS -march=pentium"
  225: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  226: 		;;
  227: 	x86_64)
  228: 		case $CC
  229: 		in
  230: 		    *-m32*)
  231: 		    	machine=386
  232: 			CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  233: 			CFLAGS_1="$CFLAGS"
  234: 			CFLAGS="$CFLAGS -march=athlon64"
  235: 			;;
  236: 		    *)
  237: 		    	machine=amd64
  238: 			;;
  239: 		esac
  240: 		;;
  241: 	ia64*)
  242: 		machine=ia64
  243: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  244: 		test "$skipcode" || skipcode="nop.i 0"
  245: 		#".skip 16" passes the test below,
  246: 		# but gives an assembler error in engine
  247: 		;;
  248:         m68k)
  249: 		machine=m68k
  250: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  251: 		if test "$host_os" = "nextstep3"
  252: 		then
  253: 			AC_LIBOBJ(termios)
  254: 		fi
  255: 		;;
  256: 	mips*)
  257: 		machine=mips
  258: 		#dynamic native code has the following problems on MIPS:
  259: 		#
  260: 		#1) J/JAL seems relocatable, but is are only
  261: 		#relocatable within a 256MB-segment.  While we try to
  262: 		#get the linker to arrange this, there is no guarantee
  263: 		#that this will succeed (and if the user uses a lot of
  264: 		#memory, it is likely to fail).
  265: 		#
  266: 		#2) The way we generate dynamic native code may
  267: 		#violate MIPS architectural restrictions (in
  268: 		#particular, the delay slots of LW, MFLO, etc.)
  269: 		#
  270: 		#Therefore we disable dynamic native code by default:
  271: 		if test -z $no_dynamic_default; then
  272: 		    no_dynamic_default=1
  273: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  274: 		fi
  275: 		;;
  276: 	alpha*)
  277: 		machine=alpha
  278: 		#full IEEE FP support for more uniformity across platforms:
  279: 		CFLAGS="$CFLAGS -mieee"
  280: 		;;
  281: 	power*|rs6000)
  282: 		machine=power
  283: 		$srcdir/mkinstalldirs arch/power
  284: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  285: 		#long long is broken on (at least) gcc-2.95.* for PPC
  286: 		test x$ac_cv_sizeof_long_long = x && 
  287: 		($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
  288: 		ac_cv_sizeof_long_long=0
  289:                 #The only architecture with enough callee-saved registers
  290:                 test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
  291:                 #or use 2, hardly slower at run-time and starts up faster
  292: 		;;
  293: 	*)
  294: 		AC_MSG_WARN([Using a generic machine description])
  295: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  296: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  297: 		machine=generic
  298: 		#I-cache flushing would be needed for dynamic code generation
  299: 		if test -z $no_dynamic_default; then
  300: 		    no_dynamic_default=1
  301: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  302: 		fi
  303: esac
  304: AC_SUBST(host)
  305: 
  306: MAKEINC=""
  307: 
  308: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  309: if test x$EC_MODE = xtrue
  310: then
  311: 	echo "Check for arch/$machine/$platform/gforth.ld"
  312: 	if test -f arch/$machine/$platform/gforth.ld
  313: 	then
  314: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  315: 		if test x$platform = xnxt; then
  316: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  317: 		fi
  318: 	fi
  319: 	if test -f arch/$machine/$platform/make.inc
  320: 	then
  321: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  322: 	fi
  323: fi
  324: AC_SUBST(MAKEINC)
  325: 
  326: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
  327: 
  328: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
  329: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
  330: 		   [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
  331: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  332: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  333: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  334: 
  335: test x$GCC_PR15242_WORKAROUND = x ||
  336: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  337:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  338: 
  339: dnl the following macro produces a warning with autoconf-2.1
  340: AC_CHECK_SIZEOF(char *)
  341: case "$ac_cv_sizeof_char_p" in
  342:   2)
  343:     wordsize=16
  344:     ;;
  345:   4)
  346:     wordsize=32
  347:     ;;
  348:   8)
  349:     wordsize=64
  350:     ;;
  351: esac
  352: 
  353: AC_CHECK_SIZEOF(void *)
  354: case "$ac_cv_sizeof_void_p" in
  355:   2)
  356:     vwordsize=16
  357:     ;;
  358:   4)
  359:     vwordsize=32
  360:     ;;
  361:   8)
  362:     vwordsize=64
  363:     ;;
  364: esac
  365: 
  366: AC_CHECK_SIZEOF(char)
  367: AC_CHECK_SIZEOF(short)
  368: AC_CHECK_SIZEOF(int)
  369: AC_CHECK_SIZEOF(long)
  370: AC_CHECK_SIZEOF(long long)
  371: AC_CHECK_SIZEOF(intptr_t)
  372: AC_CHECK_SIZEOF(int128_t)
  373: AC_CHECK_SIZEOF(uint128_t)
  374: 
  375: AC_MSG_CHECKING([for a C type for cells])
  376: ac_cv_int_type_cell=none
  377: case "$ac_cv_sizeof_char_p" in
  378:   $ac_cv_sizeof_int)
  379:     ac_cv_int_type_cell=int
  380:     ;;
  381:   $ac_cv_sizeof_short)
  382:     ac_cv_int_type_cell=short
  383:     ;;
  384:   $ac_cv_sizeof_char)
  385:     ac_cv_int_type_cell=char
  386:     ;;
  387:   $ac_cv_sizeof_long)
  388:     ac_cv_int_type_cell=long
  389:     ;;
  390:   $ac_cv_sizeof_long_long)
  391:     ac_cv_int_type_cell="long long"
  392:     ;;
  393:   $ac_cv_sizeof_intptr_t)
  394:     ac_cv_int_type_cell="intptr_t"
  395:     ;;
  396: esac
  397: AC_MSG_RESULT($ac_cv_int_type_cell)
  398: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  399: 
  400: AC_MSG_CHECKING([for a C type for wydes])
  401: ac_cv_wyde_type_cell=none
  402: case 2 in
  403:   $ac_cv_sizeof_int)
  404:     ac_cv_wyde_type_cell=int
  405:     ;;
  406:   $ac_cv_sizeof_short)
  407:     ac_cv_wyde_type_cell=short
  408:     ;;
  409:   $ac_cv_sizeof_char)
  410:     ac_cv_wyde_type_cell=char
  411:     ;;
  412:   $ac_cv_sizeof_long)
  413:     ac_cv_wyde_type_cell=long
  414:     ;;
  415:   $ac_cv_sizeof_long_long)
  416:     ac_cv_wyde_type_cell="long long"
  417:     ;;
  418:   $ac_cv_sizeof_intptr_t)
  419:     ac_cv_wyde_type_cell="intptr_t"
  420:     ;;
  421: esac
  422: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  423: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  424: 
  425: AC_MSG_CHECKING([for a C type for tetrabytes])
  426: ac_cv_tetrabyte_type_cell=none
  427: case 4 in
  428:   $ac_cv_sizeof_int)
  429:     ac_cv_tetrabyte_type_cell=int
  430:     ;;
  431:   $ac_cv_sizeof_short)
  432:     ac_cv_tetrabyte_type_cell=short
  433:     ;;
  434:   $ac_cv_sizeof_char)
  435:     ac_cv_tetrabyte_type_cell=char
  436:     ;;
  437:   $ac_cv_sizeof_long)
  438:     ac_cv_tetrabyte_type_cell=long
  439:     ;;
  440:   $ac_cv_sizeof_long_long)
  441:     ac_cv_tetrabyte_type_cell="long long"
  442:     ;;
  443:   $ac_cv_sizeof_intptr_t)
  444:     ac_cv_tetrabyte_type_cell="intptr_t"
  445:     ;;
  446: esac
  447: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  448: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  449: 
  450: AC_MSG_CHECKING([for a C type for double-cells])
  451: ac_cv_int_type_double_cell=none
  452: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  453:   $ac_cv_sizeof_short)
  454:     ac_cv_int_type_double_cell=short
  455:     ;;
  456:   $ac_cv_sizeof_int)
  457:     ac_cv_int_type_double_cell=int
  458:     ;;
  459:   $ac_cv_sizeof_long)
  460:     ac_cv_int_type_double_cell=long
  461:     ;;
  462:   $ac_cv_sizeof_long_long)
  463:     ac_cv_int_type_double_cell="long long"
  464:     ;;
  465:   $ac_cv_sizeof_intptr_t)
  466:     ac_cv_int_type_double_cell="intptr_t"
  467:     ;;
  468:   $ac_cv_sizeof_int128_t)
  469:     ac_cv_int_type_double_cell="int128_t"
  470:     ;;
  471: esac
  472: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  473: 
  474: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  475: ac_cv_int_type_double_ucell=none
  476: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  477:   $ac_cv_sizeof_short)
  478:     ac_cv_int_type_double_ucell="unsigned short"
  479:     ;;
  480:   $ac_cv_sizeof_int)
  481:     ac_cv_int_type_double_ucell="unsigned int"
  482:     ;;
  483:   $ac_cv_sizeof_long)
  484:     ac_cv_int_type_double_ucell="unsigned long"
  485:     ;;
  486:   $ac_cv_sizeof_long_long)
  487:     ac_cv_int_type_double_ucell="unsigned long long"
  488:     ;;
  489:   $ac_cv_sizeof_intptr_t)
  490:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  491:     ;;
  492:   $ac_cv_sizeof_uint128_t)
  493:     ac_cv_int_type_double_ucell="uint128_t"
  494:     ;;
  495: esac
  496: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  497: 
  498: if test "$ac_cv_int_type_double_cell" != none && \
  499:    test "$ac_cv_int_type_double_ucell" != none
  500: then
  501: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  502: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  503:         OPTS=-ll
  504: else
  505:         if test "$ac_cv_sizeof_char_p" == 8; then
  506:            OPTS="-ll -no-ll"
  507:         else
  508:            OPTS=-noll
  509:         fi
  510: fi
  511: 
  512: if grep -q FORCE_REG arch/$machine/machine.h; then
  513:    OPTS=`for i in $OPTS; do echo -n "$i-reg "; done`$OPTS
  514: fi
  515: AC_SUBST(OPTS)
  516: 
  517: AC_TYPE_OFF_T
  518: AC_CHECK_SIZEOF(off_t)
  519: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  520: ac_small_off_t=$?
  521: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  522: 
  523: ENGINE_FLAGS=
  524: AC_SUBST(ENGINE_FLAGS)
  525: 
  526: # Try if GCC understands -fno-gcse
  527: 
  528: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  529: CFLAGS_1="$CFLAGS"
  530: CFLAGS="$CFLAGS -fno-gcse"
  531: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  532: CFLAGS="$CFLAGS_1"
  533: AC_MSG_RESULT($ac_nogcse)
  534: 
  535: # Try if GCC understands -fno-strict-aliasing
  536: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  537: CFLAGS_1="$CFLAGS"
  538: CFLAGS="$CFLAGS -fno-strict-aliasing"
  539: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  540: CFLAGS="$CFLAGS_1"
  541: AC_MSG_RESULT($ac_nostrictaliasing)
  542: 
  543: # Try if GCC understands -fno-crossjumping
  544: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  545: CFLAGS_1="$CFLAGS"
  546: CFLAGS="$CFLAGS -fno-crossjumping"
  547: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  548: CFLAGS="$CFLAGS_1"
  549: AC_MSG_RESULT($ac_nocrossjumping)
  550: 
  551: # Try if GCC understands -fno-reorder-blocks
  552: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  553: CFLAGS_1="$CFLAGS"
  554: CFLAGS="$CFLAGS -fno-reorder-blocks"
  555: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  556: CFLAGS="$CFLAGS_1"
  557: AC_MSG_RESULT($ac_noreorder_blocks)
  558: 
  559: # Try if GCC understands -falign-labels=1
  560: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  561: CFLAGS_1="$CFLAGS"
  562: CFLAGS="$CFLAGS -falign-labels=1"
  563: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  564: CFLAGS="$CFLAGS_1"
  565: AC_MSG_RESULT($ac_align_labels)
  566: 
  567: # Try if GCC understands -falign-loops=1
  568: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
  569: CFLAGS_1="$CFLAGS"
  570: CFLAGS="$CFLAGS -falign-loops=1"
  571: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
  572: CFLAGS="$CFLAGS_1"
  573: AC_MSG_RESULT($ac_align_loops)
  574: 
  575: # Try if GCC understands -falign-jumps=1
  576: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
  577: CFLAGS_1="$CFLAGS"
  578: CFLAGS="$CFLAGS -falign-jumps=1"
  579: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
  580: CFLAGS="$CFLAGS_1"
  581: AC_MSG_RESULT($ac_align_jumps)
  582: 
  583: # Try if GCC understands __attribute__((unused))
  584: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  585: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  586: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  587: AC_MSG_RESULT($MAYBE_UNUSED)
  588: 
  589: #try if m4 understands -s
  590: AC_MSG_CHECKING([how to invoke m4])
  591: if m4 -s /dev/null >/dev/null 2>&1; then
  592:  M4="m4 -s"
  593: else
  594:  M4=m4
  595: fi
  596: AC_SUBST(M4)
  597: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
  598: AC_MSG_RESULT($M4)
  599: 
  600: # Find installed Gforth
  601: AC_MSG_CHECKING([for gforth])
  602: GFORTH="`which gforth 2>/dev/null`"
  603: if test ! -z "$GFORTH"; then  GFORTH="$GFORTH -m4M --die-on-signal" ; fi
  604: AC_SUBST(GFORTH)
  605: AC_DEFINE_UNQUOTED(GFORTH,"$GFORTH",[How to invoke gforth])
  606: AC_MSG_RESULT($GFORTH)
  607: 
  608: echo "machine='$machine'"
  609: 
  610: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  611: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
  612: AC_SUBST(asm_fs)
  613: 
  614: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  615: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
  616: AC_SUBST(disasm_fs)
  617: 
  618: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  619: 
  620: case "$host_os" in
  621: 	*win32*)
  622: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  623: 		DIRSEP="\\\\"
  624: 		PATHSEP=";"
  625: 		#we want the builtins of command.com/cmd.exe and its
  626: 		# handling of .com files.
  627: 		#$COMSPEC contains the name of the Windows shell;
  628: 		# the ./ is there, because the bash does not recognize
  629: 		# absolute DOS filenames
  630: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  631: 		;;
  632: 	*darwin*)
  633: 		#Darwin uses some funny preprocessor by default; eliminate it:
  634: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  635: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  636: 		DIRSEP="/"
  637: 		PATHSEP=":"
  638: 		DEFAULTSYSTEMPREFIX=""
  639: 		;;
  640: 	*)
  641: 		DIRSEP="/"
  642: 		PATHSEP=":"
  643: 		DEFAULTSYSTEMPREFIX=""
  644: 		;;
  645: esac
  646: AC_SUBST(DIRSEP)
  647: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  648: AC_SUBST(PATHSEP)
  649: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  650: AC_SUBST(DEFAULTSYSTEMPREFIX)
  651: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  652: 
  653: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  654: #This magic incantation  seems to be completely undocumented.
  655: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  656: 
  657: dnl Now a little support for DOS/DJGCC
  658: AC_SUBST(GFORTH_EXE)
  659: GFORTH_EXE="true"
  660: AC_SUBST(GFORTHFAST_EXE)
  661: GFORTHFAST_EXE="true"
  662: AC_SUBST(GFORTHITC_EXE)
  663: GFORTHITC_EXE="true"
  664: AC_SUBST(GFORTHDITC_EXE)
  665: GFORTHDITC_EXE="true"
  666: 
  667: AC_SUBST(FORTHSIZES)
  668: 
  669: dnl if test "$PEEPHOLE" = "yes"
  670: dnl then
  671: dnl    PEEPHOLEFLAG="true"
  672: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  673: dnl else
  674: dnl    PEEPHOLEFLAG="false"
  675: dnl fi
  676: PEEPHOLEFLAG="true"
  677: AC_SUBST(PEEPHOLEFLAG)
  678: 
  679: dnl copy commands for systems that don't have links
  680: AC_SUBST(LINK_KERNL)
  681: LINK_KERNL=""
  682: 
  683: #if test $host_os=dos
  684: #then
  685: #  echo Configuring for DOS!!!
  686: #  MAKE_EXE="coff2exe gforth"
  687: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  688: #fi
  689: 
  690: dnl the following macro produces a warning with autoconf-2.1
  691: AC_C_BIGENDIAN
  692: AC_SUBST(KERNEL)
  693: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  694: if test $ac_cv_c_bigendian = yes; then
  695:   bytesex=b
  696:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  697: else
  698:   bytesex=l
  699:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  700: fi
  701: 
  702: #check how to do asm(".skip 16")
  703: #echo "CFLAGS=$CFLAGS"
  704: #echo "ac_link=$ac_link"
  705: AC_MSG_CHECKING([if and how we can waste code space])
  706: if test -z "$skipcode"; then
  707:     skipcode=no
  708:     CFLAGS_1="$CFLAGS"
  709:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  710:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  711:     do
  712: 	AC_TRY_RUN(
  713: [int foo(int,int,int);
  714: main()
  715: {
  716:   exit(foo(0,0,0)!=16);
  717: }
  718: int foo(int x, int y, int z)
  719: {
  720:   static void *labels[]={&&label1, &&label2};
  721:   if (x) {
  722:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  723:   label1:
  724:     asm("$i"); /* or ".space 16" or somesuch */
  725:   label2: ;
  726:   }
  727:   {
  728:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  729:   return labels[1]-labels[0];
  730:   }
  731: }]
  732: 	,skipcode=$i; break
  733: 	,,)
  734:     done
  735:     CFLAGS=$CFLAGS_1
  736: fi
  737: AC_MSG_RESULT($skipcode)
  738: if test "$skipcode" = no
  739: then 
  740:     if test -z $no_dynamic_default; then
  741: 	no_dynamic_default=1
  742: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  743:     fi
  744:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  745: else
  746:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  747: fi
  748: 
  749: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  750: #the point here is to get asm statements that look different to
  751: #gcc's "optimizer"
  752: if test -z "$asmcomment"; then
  753:     asmcomment=no
  754:     CFLAGS_1="$CFLAGS"
  755:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  756:     for i in '"# "' '"! "' '"; "'; do
  757: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  758:     done
  759:     CFLAGS=$CFLAGS_1
  760: fi
  761: AC_MSG_RESULT($asmcomment)
  762: if test "$asmcomment" != no
  763: then 
  764:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  765: fi
  766: 
  767: test "$no_dynamic_default" || no_dynamic_default=0
  768: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  769: 
  770: dnl Checks for programs.
  771: AC_PROG_LN_S
  772: AC_PROG_INSTALL
  773: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  774: 
  775: dnl MacOS X has a libtool that does something else
  776: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
  777: 
  778: dnl Checks for library functions
  779: dnl This check is just for making later checks link with libm.
  780: dnl using sin here is no good idea since it is built-into gcc and typechecked
  781: AC_CHECK_LIB(m,asin)
  782: AC_CHECK_LIB(ltdl,lt_dlinit)
  783: AC_CHECK_LIB(dl,dlopen)
  784: dnl check for libffi 2.x
  785: AC_CHECK_LIB(ffi,ffi_call)
  786: if test $ac_cv_lib_ffi_ffi_call = yes
  787: then
  788: LIBFFIFLAG="true"
  789: FFCALLFLAG="false"
  790: OLDCALLFLAG="false"
  791: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
  792: else
  793: dnl check for ffcall libraries
  794: dnl unfortunately, these four calls are separated out into a library each.
  795: AC_CHECK_LIB(avcall,__builtin_avcall)
  796: AC_CHECK_LIB(callback,__vacall_r)
  797: AC_CHECK_LIB(vacall,vacall)
  798: AC_CHECK_LIB(trampoline,alloc_trampoline)
  799: LIBFFIFLAG="false"
  800: FFCALLFLAG="false"
  801: OLDCALLFLAG="true"
  802: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  803: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  804: fi
  805: AC_SUBST(LIBFFIFLAG)
  806: AC_SUBST(FFCALLFLAG)
  807: AC_SUBST(OLDCALLFLAG)
  808: if test "$host_os" != "nextstep3"
  809: then
  810: 	AC_FUNC_MEMCMP
  811: fi
  812: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  813: AC_FUNC_FSEEKO
  814: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
  815: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  816: AC_DECL_SYS_SIGLIST
  817: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  818: AC_CHECK_FUNCS(expm1 log1p)
  819: AC_REPLACE_FUNCS(rint ecvt)
  820: dnl No check for select, because our replacement is no good under
  821: dnl anything but DOS
  822: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  823: AC_FUNC_FNMATCH
  824: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  825: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  826: AM_PATH_LISPDIR
  827: 
  828: kernel_fi=kernl${vwordsize}${bytesex}.fi
  829: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  830: AC_SUBST(kernel_fi)
  831: AC_SUBST(include_fi)
  832: 
  833: #this breaks bindists
  834: #dnl replace srource directory by absolute value
  835: #if test $srcdir = "."; then srcdir=`pwd` 
  836: #fi
  837: 
  838: AC_SUBST(machine)
  839: AC_CONFIG_FILES([
  840: Makefile
  841: Makedist
  842: gforthmi
  843: vmgen
  844: machpc.fs
  845: envos.fs
  846: engine/Makefile
  847: engine/libcc.h
  848: doc/version.texi
  849: build-ec ])
  850: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  851: chmod +x gforthmi
  852: chmod +x vmgen
  853: chmod +x build-ec
  854: test -d kernel||mkdir kernel
  855: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
  856: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
  857: AC_OUTPUT
  858: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>