1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.6.9-20070604],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="June 02, 2007"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #suppress the "-g -O2" default
33: test "$CFLAGS" || CFLAGS=-O2
34:
35: AC_ARG_ENABLE(force-reg,
36: AC_HELP_STRING([--enable-force-reg],
37: [ Use explicit register declarations if they appear in
38: the machine.h file. This can cause a good speedup,
39: but also incorrect code with some gcc versions on
40: some processors (default disabled).]),
41: ,enable_force_reg=no)
42: test "$enable_force_reg" = "no"||
43: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
44:
45: AC_ARG_ENABLE(force-ll,
46: AC_HELP_STRING([--enable-force-ll],
47: [ Use explicit long long declarations if they appear in
48: the machine.h file. This can cause a good speedup,
49: but also incorrect code with some gcc versions on
50: some processors (default disabled).]),
51: ,enable_force_ll=no)
52: test "$enable_force_ll" = "no"||
53: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
54:
55: AC_ARG_ENABLE(force-cdiv,
56: AC_HELP_STRING([--enable-force-cdiv],
57: [ Use the native C division - symmetric - instead of
58: floored division (default disabled).]),
59: ,enable_force_cdiv=no)
60: test "$enable_force_cdiv" = "no"||
61: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
62:
63: AC_SUBST(PROFEXES)
64: AC_SUBST(PROFOBJS)
65: AC_ARG_ENABLE(prof,
66: AC_HELP_STRING([--enable-prof],
67: [ Build gforth-prof, which outputs frequently occuring
68: sequences of primitives.]),
69: ,enable_prof=no)
70: if test "$enable_prof" = "no"; then
71: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
72: fi
73:
74: AC_ARG_WITH(debug,
75: [ --with-debug specifies option -g to compile with debug info
76: --without-debug omits the -g switch and creates smaller images on
77: machines where "strip" has problems with gcc style
78: debugging informations.],
79: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
80:
81: dnl PEEPHOLE="yes"
82: dnl AC_ARG_WITH(peephole,
83: dnl [ --with-peephole Enable peephole optimization (default)
84: dnl --without-peephole disables peephole optimization. Creates smaller,
85: dnl but slower images.],
86: dnl PEEPHOLE="$withval")
87:
88: GCC_LD="\$(GCC)"
89: EC_MODE="false"
90: EC=""
91: engine2="engine2.o"
92: engine_fast2="engine-fast2.o"
93: no_dynamic=""
94: image_i=""
95: signals_o="io.o signals.o"
96:
97: AC_ARG_WITH(ec,
98: AC_HELP_STRING([--with-ec=<arch>],
99: [ Build gforth for systems without OS.]),
100: [if test "$withval" = "no"; then
101: echo "defining hosted system"
102: else
103: echo "defining standalone system (${withval})"
104: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
105: EC_MODE="true"
106: EC="-ec"
107: engine2=""
108: engine_fast2=""
109: no_dynamic="-DNO_DYNAMIC"
110: image_i="image.i"
111: if test "$withval" != "yes"; then
112: signals_o="io-${withval}.o"
113: else
114: signals_o="io.o"
115: fi
116: GCC_PATH=$(which $CC)
117: LIB_PATH=${GCC_PATH%/*/*}
118: GCC_LD="\$(LD)"
119: platform=${withval}
120: fi])
121:
122: #variables mentioned in INSTALL
123: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
124: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
125: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
126: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
127:
128: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
129: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
130: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
131: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
132: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
133: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
134: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
135: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
136: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
137: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
138: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
139: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
140: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
141: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
142: AC_ARG_VAR(asmcomment, [assembler comment start string])
143: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
144:
145: #set up feature test macros, so the tests get them right:
146: # turn on all POSIX, SUSv3, and GNU features if available
147: AC_GNU_SOURCE
148: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
149:
150: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
151: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
152: dnl but not for _XOPEN_SOURCE)
153: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
154: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
155: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
156: # turn on large file support with 64-bit off_t where available
157: AC_SYS_LARGEFILE
158: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
159: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
160:
161: #currently we force direct threading this way. Eventually we should
162: #setup in the arch and engine files right
163:
164: AC_PROG_CC
165:
166: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
167:
168: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
169: test x$condbranch_opt = x &&
170: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
171: condbranch_opt=0
172: else
173: condbranch_opt=1
174: fi
175: AC_MSG_RESULT($condbranch_opt)
176: AC_SUBST(condbranch_opt)
177:
178: AC_SUBST(CC)
179: AC_SUBST(GCC_LD)
180: AC_SUBST(DEBUGFLAG)
181: AC_SUBST(EC)
182: AC_SUBST(EC_MODE)
183: AC_SUBST(engine2)
184: AC_SUBST(engine_fast2)
185: AC_SUBST(no_dynamic)
186: AC_SUBST(image_i)
187: AC_SUBST(signals_o)
188:
189: #this is used to disable some (not generally essential) part of the
190: #Makefile that some makes don't grok. It would be better to test for
191: #this specific Makefile feature than the make version.
192: AC_MSG_CHECKING(make type)
193: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
194: GNUMAKE='#'
195: test "$make_type" = "GNU Make" && GNUMAKE=''
196: AC_MSG_RESULT($make_type)
197: AC_SUBST(GNUMAKE)
198:
199: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
200: OLDLDFLAGS=$LDFLAGS
201: LDFLAGS="$LDFLAGS -export-dynamic"
202: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
203: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
204: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
205: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
206: AC_MSG_RESULT($ac_export_dynamic)
207:
208: #terminology is a bit unusual here: The host is the system on which
209: #gforth will run; the system on which configure will run is the `build'
210: AC_CANONICAL_HOST
211: case "$host_cpu" in
212: arm*)
213: machine=arm
214: CFLAGS="$CFLAGS -fomit-frame-pointer"
215: if test x$platform = xnxt; then
216: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
217: fi
218: if test -z $arm_cacheflush; then
219: no_dynamic_default=1
220: arm_cacheflush=arch/arm/cacheflush0
221: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
222: fi
223: AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
224: AC_LIBOBJ(../$arm_cacheflush)
225: #longer skipcodes lead to problems on ARM, and it uses
226: #only 4-byte alignment anyway
227: test "$skipcode" || skipcode="nop"
228: ;;
229: hppa*)
230: machine=hppa
231: $srcdir/mkinstalldirs arch/hppa
232: AC_LIBOBJ(../arch/hppa/cache)
233: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
234: LDFLAGS="$LDFLAGS -Xlinker -N"
235: LIBS="$LIBS -L/lib/pa1.1/"
236: ;;
237: sparc*)
238: machine=sparc
239: ;;
240: i386)
241: machine=386
242: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
243: ;;
244: i486)
245: machine=386
246: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
247: ;;
248: i*86)
249: machine=386
250: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
251: CFLAGS_1="$CFLAGS"
252: CFLAGS="$CFLAGS -march=pentium"
253: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
254: ;;
255: x86_64)
256: case $CC
257: in
258: *-m32*)
259: machine=386
260: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
261: CFLAGS_1="$CFLAGS"
262: CFLAGS="$CFLAGS -march=athlon64"
263: ;;
264: *)
265: machine=amd64
266: ;;
267: esac
268: ;;
269: ia64*)
270: machine=ia64
271: AC_LIBOBJ(../arch/ia64/flush_icache_block)
272: test "$skipcode" || skipcode="nop.i 0"
273: #".skip 16" passes the test below,
274: # but gives an assembler error in engine
275: ;;
276: m68k)
277: machine=m68k
278: CFLAGS="$CFLAGS -fomit-frame-pointer"
279: if test "$host_os" = "nextstep3"
280: then
281: AC_LIBOBJ(termios)
282: fi
283: ;;
284: mips*)
285: machine=mips
286: #dynamic native code has the following problems on MIPS:
287: #
288: #1) J/JAL seems relocatable, but is are only
289: #relocatable within a 256MB-segment. While we try to
290: #get the linker to arrange this, there is no guarantee
291: #that this will succeed (and if the user uses a lot of
292: #memory, it is likely to fail).
293: #
294: #2) The way we generate dynamic native code may
295: #violate MIPS architectural restrictions (in
296: #particular, the delay slots of LW, MFLO, etc.)
297: #
298: #Therefore we disable dynamic native code by default:
299: if test -z $no_dynamic_default; then
300: no_dynamic_default=1
301: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
302: fi
303: ;;
304: alpha*)
305: machine=alpha
306: #full IEEE FP support for more uniformity across platforms:
307: CFLAGS="$CFLAGS -mieee"
308: ;;
309: power*|rs6000)
310: machine=power
311: $srcdir/mkinstalldirs arch/power
312: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
313: #long long is broken on (at least) gcc-2.95.* for PPC
314: test x$ac_cv_sizeof_long_long = x &&
315: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
316: ac_cv_sizeof_long_long=0
317: ;;
318: *)
319: AC_MSG_WARN([Using a generic machine description])
320: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
321: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
322: machine=generic
323: #I-cache flushing would be needed for dynamic code generation
324: if test -z $no_dynamic_default; then
325: no_dynamic_default=1
326: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
327: fi
328: esac
329: AC_SUBST(host)
330:
331: MAKEINC=""
332:
333: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
334: if test x$EC_MODE = xtrue
335: then
336: echo "Check for arch/$machine/$platform/gforth.ld"
337: if test -f arch/$machine/$platform/gforth.ld
338: then
339: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
340: if test x$platform = xnxt; then
341: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
342: fi
343: fi
344: if test -f arch/$machine/$platform/make.inc
345: then
346: MAKEINC="include ../arch/$machine/$platform/make.inc"
347: fi
348: fi
349: AC_SUBST(MAKEINC)
350:
351: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
352: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
353: [number of registers in the default stack cache state for gforth-fast and gforth-native])
354:
355: test x$GCC_PR15242_WORKAROUND = x ||
356: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
357: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
358:
359: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
360: dnl generation on gccs affected by PR15242])
361:
362:
363: if test "${enable_force_ll+set}" = set; then
364: ac_includes_default="$ac_includes_default
365: #include \"arch/generic/128bit.h\""
366: fi
367:
368: dnl the following macro produces a warning with autoconf-2.1
369: AC_CHECK_SIZEOF(char *)
370: case "$ac_cv_sizeof_char_p" in
371: 2)
372: wordsize=16
373: ;;
374: 4)
375: wordsize=32
376: ;;
377: 8)
378: wordsize=64
379: ;;
380: esac
381:
382: AC_CHECK_SIZEOF(void *)
383: case "$ac_cv_sizeof_void_p" in
384: 2)
385: vwordsize=16
386: ;;
387: 4)
388: vwordsize=32
389: ;;
390: 8)
391: vwordsize=64
392: ;;
393: esac
394:
395: AC_CHECK_SIZEOF(char)
396: AC_CHECK_SIZEOF(short)
397: AC_CHECK_SIZEOF(int)
398: AC_CHECK_SIZEOF(long)
399: AC_CHECK_SIZEOF(long long)
400: AC_CHECK_SIZEOF(intptr_t)
401: AC_CHECK_SIZEOF(int128_t)
402: AC_CHECK_SIZEOF(uint128_t)
403:
404: AC_MSG_CHECKING([for a C type for cells])
405: ac_cv_int_type_cell=none
406: case "$ac_cv_sizeof_char_p" in
407: $ac_cv_sizeof_int)
408: ac_cv_int_type_cell=int
409: ;;
410: $ac_cv_sizeof_short)
411: ac_cv_int_type_cell=short
412: ;;
413: $ac_cv_sizeof_char)
414: ac_cv_int_type_cell=char
415: ;;
416: $ac_cv_sizeof_long)
417: ac_cv_int_type_cell=long
418: ;;
419: $ac_cv_sizeof_long_long)
420: ac_cv_int_type_cell="long long"
421: ;;
422: $ac_cv_sizeof_intptr_t)
423: ac_cv_int_type_cell="intptr_t"
424: ;;
425: $ac_cv_sizeof_int128_t)
426: ac_cv_int_type_cell="int128_t"
427: ;;
428: esac
429: AC_MSG_RESULT($ac_cv_int_type_cell)
430: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
431:
432: AC_MSG_CHECKING([for a C type for wydes])
433: ac_cv_wyde_type_cell=none
434: case 2 in
435: $ac_cv_sizeof_int)
436: ac_cv_wyde_type_cell=int
437: ;;
438: $ac_cv_sizeof_short)
439: ac_cv_wyde_type_cell=short
440: ;;
441: $ac_cv_sizeof_char)
442: ac_cv_wyde_type_cell=char
443: ;;
444: $ac_cv_sizeof_long)
445: ac_cv_wyde_type_cell=long
446: ;;
447: $ac_cv_sizeof_long_long)
448: ac_cv_wyde_type_cell="long long"
449: ;;
450: $ac_cv_sizeof_intptr_t)
451: ac_cv_wyde_type_cell="intptr_t"
452: ;;
453: $ac_cv_sizeof_int128_t)
454: ac_cv_wyde_type_cell="int128_t"
455: ;;
456: esac
457: AC_MSG_RESULT($ac_cv_wyde_type_cell)
458: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
459:
460: AC_MSG_CHECKING([for a C type for tetrabytes])
461: ac_cv_tetrabyte_type_cell=none
462: case 4 in
463: $ac_cv_sizeof_int)
464: ac_cv_tetrabyte_type_cell=int
465: ;;
466: $ac_cv_sizeof_short)
467: ac_cv_tetrabyte_type_cell=short
468: ;;
469: $ac_cv_sizeof_char)
470: ac_cv_tetrabyte_type_cell=char
471: ;;
472: $ac_cv_sizeof_long)
473: ac_cv_tetrabyte_type_cell=long
474: ;;
475: $ac_cv_sizeof_long_long)
476: ac_cv_tetrabyte_type_cell="long long"
477: ;;
478: $ac_cv_sizeof_intptr_t)
479: ac_cv_tetrabyte_type_cell="intptr_t"
480: ;;
481: $ac_cv_sizeof_int128_t)
482: ac_cv_tetrabyte_type_cell="int128_t"
483: ;;
484: esac
485: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
486: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
487:
488: AC_MSG_CHECKING([for a C type for double-cells])
489: ac_cv_int_type_double_cell=none
490: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
491: $ac_cv_sizeof_short)
492: ac_cv_int_type_double_cell=short
493: ;;
494: $ac_cv_sizeof_int)
495: ac_cv_int_type_double_cell=int
496: ;;
497: $ac_cv_sizeof_long)
498: ac_cv_int_type_double_cell=long
499: ;;
500: $ac_cv_sizeof_long_long)
501: ac_cv_int_type_double_cell="long long"
502: ;;
503: $ac_cv_sizeof_intptr_t)
504: ac_cv_int_type_double_cell="intptr_t"
505: ;;
506: $ac_cv_sizeof_int128_t)
507: ac_cv_int_type_double_cell="int128_t"
508: ;;
509: esac
510: AC_MSG_RESULT($ac_cv_int_type_double_cell)
511:
512: AC_MSG_CHECKING([for a C type for unsigned double-cells])
513: ac_cv_int_type_double_ucell=none
514: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
515: $ac_cv_sizeof_short)
516: ac_cv_int_type_double_ucell="unsigned short"
517: ;;
518: $ac_cv_sizeof_int)
519: ac_cv_int_type_double_ucell="unsigned int"
520: ;;
521: $ac_cv_sizeof_long)
522: ac_cv_int_type_double_ucell="unsigned long"
523: ;;
524: $ac_cv_sizeof_long_long)
525: ac_cv_int_type_double_ucell="unsigned long long"
526: ;;
527: $ac_cv_sizeof_intptr_t)
528: ac_cv_int_type_double_ucell="unsigned intptr_t"
529: ;;
530: $ac_cv_sizeof_uint128_t)
531: ac_cv_int_type_double_ucell="uint128_t"
532: ;;
533: esac
534: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
535:
536: if test "$ac_cv_int_type_double_cell" = none || \
537: test "$ac_cv_int_type_double_ucell" = none
538: then
539: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
540: AC_LIBOBJ(dblsub)
541: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
542: else
543: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
544: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
545: fi
546:
547: AC_TYPE_OFF_T
548: AC_CHECK_SIZEOF(off_t)
549: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
550: ac_small_off_t=$?
551: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
552:
553: ENGINE_FLAGS=
554: AC_SUBST(ENGINE_FLAGS)
555:
556: # Try if GCC understands -fno-gcse
557:
558: AC_MSG_CHECKING([if $CC understands -fno-gcse])
559: CFLAGS_1="$CFLAGS"
560: CFLAGS="$CFLAGS -fno-gcse"
561: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
562: CFLAGS="$CFLAGS_1"
563: AC_MSG_RESULT($ac_nogcse)
564:
565: # Try if GCC understands -fno-strict-aliasing
566: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
567: CFLAGS_1="$CFLAGS"
568: CFLAGS="$CFLAGS -fno-strict-aliasing"
569: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
570: CFLAGS="$CFLAGS_1"
571: AC_MSG_RESULT($ac_nostrictaliasing)
572:
573: # Try if GCC understands -fno-crossjumping
574: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
575: CFLAGS_1="$CFLAGS"
576: CFLAGS="$CFLAGS -fno-crossjumping"
577: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
578: CFLAGS="$CFLAGS_1"
579: AC_MSG_RESULT($ac_nocrossjumping)
580:
581: # Try if GCC understands -fno-reorder-blocks
582: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
583: CFLAGS_1="$CFLAGS"
584: CFLAGS="$CFLAGS -fno-reorder-blocks"
585: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
586: CFLAGS="$CFLAGS_1"
587: AC_MSG_RESULT($ac_noreorder_blocks)
588:
589: # Try if GCC understands -falign-labels=1
590: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
591: CFLAGS_1="$CFLAGS"
592: CFLAGS="$CFLAGS -falign-labels=1"
593: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
594: CFLAGS="$CFLAGS_1"
595: AC_MSG_RESULT($ac_align_labels)
596:
597: # Try if GCC understands -falign-loops=1
598: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
599: CFLAGS_1="$CFLAGS"
600: CFLAGS="$CFLAGS -falign-loops=1"
601: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
602: CFLAGS="$CFLAGS_1"
603: AC_MSG_RESULT($ac_align_loops)
604:
605: # Try if GCC understands -falign-jumps=1
606: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
607: CFLAGS_1="$CFLAGS"
608: CFLAGS="$CFLAGS -falign-jumps=1"
609: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
610: CFLAGS="$CFLAGS_1"
611: AC_MSG_RESULT($ac_align_jumps)
612:
613: # Try if GCC understands __attribute__((unused))
614: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
615: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
616: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
617: AC_MSG_RESULT($MAYBE_UNUSED)
618:
619: #try if m4 understands -s
620: AC_MSG_CHECKING([how to invoke m4])
621: if m4 -s /dev/null >/dev/null 2>&1; then
622: M4="m4 -s"
623: else
624: M4=m4
625: fi
626: AC_SUBST(M4)
627: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
628: AC_MSG_RESULT($M4)
629:
630: # Find installed Gforth
631: AC_MSG_CHECKING([for gforth])
632: GFORTH="`which gforth 2>/dev/null`"
633: if test ! -z "$GFORTH"; then GFORTH="$GFORTH -m4M" ; fi
634: AC_SUBST(GFORTH)
635: AC_DEFINE_UNQUOTED(GFORTH,"$GFORTH",[How to invoke gforth])
636: AC_MSG_RESULT($GFORTH)
637:
638: echo "machine='$machine'"
639:
640: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
641: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
642: AC_SUBST(asm_fs)
643:
644: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
645: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
646: AC_SUBST(disasm_fs)
647:
648: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
649:
650: case "$host_os" in
651: *win32*)
652: # !!!FIXME!!! problems with cygwin and ';' as path separator
653: DIRSEP="\\\\"
654: PATHSEP=";"
655: #we want the builtins of command.com/cmd.exe and its
656: # handling of .com files.
657: #$COMSPEC contains the name of the Windows shell;
658: # the ./ is there, because the bash does not recognize
659: # absolute DOS filenames
660: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
661: ;;
662: *darwin*)
663: #Darwin uses some funny preprocessor by default; eliminate it:
664: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
665: CFLAGS="$CFLAGS -no-cpp-precomp"
666: DIRSEP="/"
667: PATHSEP=":"
668: DEFAULTSYSTEMPREFIX=""
669: ;;
670: *)
671: DIRSEP="/"
672: PATHSEP=":"
673: DEFAULTSYSTEMPREFIX=""
674: ;;
675: esac
676: AC_SUBST(DIRSEP)
677: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
678: AC_SUBST(PATHSEP)
679: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
680: AC_SUBST(DEFAULTSYSTEMPREFIX)
681: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
682:
683: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
684: #This magic incantation seems to be completely undocumented.
685: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
686:
687: dnl Now a little support for DOS/DJGCC
688: AC_SUBST(GFORTH_EXE)
689: GFORTH_EXE=""
690: AC_SUBST(GFORTHFAST_EXE)
691: GFORTHFAST_EXE=""
692: AC_SUBST(GFORTHITC_EXE)
693: GFORTHITC_EXE=""
694: AC_SUBST(GFORTHDITC_EXE)
695: GFORTHDITC_EXE=""
696:
697: AC_SUBST(FORTHSIZES)
698:
699: dnl if test "$PEEPHOLE" = "yes"
700: dnl then
701: dnl PEEPHOLEFLAG="true"
702: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
703: dnl else
704: dnl PEEPHOLEFLAG="false"
705: dnl fi
706: PEEPHOLEFLAG="true"
707: AC_SUBST(PEEPHOLEFLAG)
708:
709: dnl copy commands for systems that don't have links
710: AC_SUBST(LINK_KERNL)
711: LINK_KERNL=""
712:
713: #if test $host_os=dos
714: #then
715: # echo Configuring for DOS!!!
716: # MAKE_EXE="coff2exe gforth"
717: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
718: #fi
719:
720: dnl the following macro produces a warning with autoconf-2.1
721: AC_C_BIGENDIAN
722: AC_SUBST(KERNEL)
723: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
724: if test $ac_cv_c_bigendian = yes; then
725: bytesex=b
726: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
727: else
728: bytesex=l
729: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
730: fi
731:
732: #check how to do asm(".skip 16")
733: #echo "CFLAGS=$CFLAGS"
734: #echo "ac_link=$ac_link"
735: AC_MSG_CHECKING([if and how we can waste code space])
736: if test -z "$skipcode"; then
737: skipcode=no
738: CFLAGS_1="$CFLAGS"
739: CFLAGS="$CFLAGS $ENGINE_FLAGS"
740: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
741: do
742: AC_TRY_RUN(
743: [int foo(int,int,int);
744: main()
745: {
746: exit(foo(0,0,0)!=16);
747: }
748: int foo(int x, int y, int z)
749: {
750: static void *labels[]={&&label1, &&label2};
751: if (x) {
752: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
753: label1:
754: asm("$i"); /* or ".space 16" or somesuch */
755: label2: ;
756: }
757: {
758: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
759: return labels[1]-labels[0];
760: }
761: }]
762: ,skipcode=$i; break
763: ,,)
764: done
765: CFLAGS=$CFLAGS_1
766: fi
767: AC_MSG_RESULT($skipcode)
768: if test "$skipcode" = no
769: then
770: if test -z $no_dynamic_default; then
771: no_dynamic_default=1
772: AC_MSG_WARN(Disabling default dynamic native code generation)
773: fi
774: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
775: else
776: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
777: fi
778:
779: AC_MSG_CHECKING([if and how we can do comments in asm statements])
780: #the point here is to get asm statements that look different to
781: #gcc's "optimizer"
782: if test -z "$asmcomment"; then
783: asmcomment=no
784: CFLAGS_1="$CFLAGS"
785: CFLAGS="$CFLAGS $ENGINE_FLAGS"
786: for i in '"# "' '"! "' '"; "'; do
787: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
788: done
789: CFLAGS=$CFLAGS_1
790: fi
791: AC_MSG_RESULT($asmcomment)
792: if test "$asmcomment" != no
793: then
794: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
795: fi
796:
797: test "$no_dynamic_default" || no_dynamic_default=0
798: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
799:
800: dnl Checks for programs.
801: AC_PROG_LN_S
802: AC_PROG_INSTALL
803: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
804:
805: dnl MacOS X has a libtool that does something else
806: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
807:
808: dnl Checks for library functions
809: dnl This check is just for making later checks link with libm.
810: dnl using sin here is no good idea since it is built-into gcc and typechecked
811: AC_CHECK_LIB(m,asin)
812: AC_CHECK_LIB(ltdl,lt_dlinit)
813: AC_CHECK_LIB(dl,dlopen)
814: dnl check for libffi 2.x
815: AC_CHECK_LIB(ffi,ffi_call)
816: if test $ac_cv_lib_ffi_ffi_call = yes
817: then
818: LIBFFIFLAG="true"
819: FFCALLFLAG="false"
820: OLDCALLFLAG="false"
821: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
822: else
823: dnl check for ffcall libraries
824: dnl unfortunately, these four calls are separated out into a library each.
825: AC_CHECK_LIB(avcall,__builtin_avcall)
826: AC_CHECK_LIB(callback,__vacall_r)
827: AC_CHECK_LIB(vacall,vacall)
828: AC_CHECK_LIB(trampoline,alloc_trampoline)
829: LIBFFIFLAG="false"
830: FFCALLFLAG="false"
831: OLDCALLFLAG="true"
832: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
833: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
834: fi
835: AC_SUBST(LIBFFIFLAG)
836: AC_SUBST(FFCALLFLAG)
837: AC_SUBST(OLDCALLFLAG)
838: if test "$host_os" != "nextstep3"
839: then
840: AC_FUNC_MEMCMP
841: fi
842: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
843: AC_FUNC_FSEEKO
844: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
845: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
846: AC_DECL_SYS_SIGLIST
847: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
848: AC_CHECK_FUNCS(expm1 log1p)
849: AC_REPLACE_FUNCS(rint ecvt)
850: dnl No check for select, because our replacement is no good under
851: dnl anything but DOS
852: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
853: AC_FUNC_FNMATCH
854: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
855: AC_CHECK_FUNCS(mmap sysconf getpagesize)
856: AM_PATH_LISPDIR
857:
858: kernel_fi=kernl${vwordsize}${bytesex}.fi
859: include_fi=kernl${wordsize}${bytesex}${EC}.fi
860: AC_SUBST(kernel_fi)
861: AC_SUBST(include_fi)
862:
863: #this breaks bindists
864: #dnl replace srource directory by absolute value
865: #if test $srcdir = "."; then srcdir=`pwd`
866: #fi
867:
868: AC_SUBST(machine)
869: AC_CONFIG_FILES([
870: Makefile
871: Makedist
872: gforthmi
873: vmgen
874: machpc.fs
875: envos.fs
876: engine/Makefile
877: engine/libcc.h
878: doc/version.texi
879: build-ec ])
880: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
881: chmod +x gforthmi
882: chmod +x vmgen
883: chmod +x build-ec
884: test -d kernel||mkdir kernel
885: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
886: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
887: AC_OUTPUT
888:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>