File:  [gforth] / gforth / configure.in
Revision 1.191: download - view: text, annotated - select for diffs
Sun Jun 24 16:02:23 2007 UTC (16 years, 8 months ago) by anton
Branches: MAIN
CVS tags: HEAD
updated asm_fs and disasm_fs detection for new autoconf

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.9-20070604],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="June 02, 2007"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: 	AC_HELP_STRING([--enable-force-reg],
   38: 		        [ Use explicit register declarations if they appear in
   39: 			  the machine.h file. This can cause a good speedup,
   40: 			  but also incorrect code with some gcc versions on
   41: 			  some processors (default disabled).]),
   42: 	,enable_force_reg=no)
   43: test "$enable_force_reg" = "no"||
   44:   AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
   45: 
   46: AC_ARG_ENABLE(force-ll,
   47: 	AC_HELP_STRING([--enable-force-ll],
   48: 		       [  Use explicit long long declarations if they appear in
   49: 			  the machine.h file. This can cause a good speedup,
   50: 			  but also incorrect code with some gcc versions on
   51: 			  some processors (default disabled).]),
   52: 	,enable_force_ll=no)
   53: test "$enable_force_ll" = "no"||
   54:   AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
   55: 
   56: AC_ARG_ENABLE(force-cdiv,
   57: 	AC_HELP_STRING([--enable-force-cdiv],
   58: 		       [  Use the native C division - symmetric - instead of
   59: 		          floored division (default disabled).]),
   60: 	,enable_force_cdiv=no)
   61: test "$enable_force_cdiv" = "no"||
   62:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   63: 
   64: AC_SUBST(PROFEXES)
   65: AC_SUBST(PROFOBJS)
   66: AC_ARG_ENABLE(prof,
   67: 	AC_HELP_STRING([--enable-prof],
   68: 			[ Build gforth-prof, which outputs frequently occuring
   69:                           sequences of primitives.]),
   70: 	,enable_prof=no)
   71: if test "$enable_prof" = "no"; then
   72:   PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
   73: fi
   74: 
   75: AC_ARG_WITH(debug,
   76: [  --with-debug		  specifies option -g to compile with debug info
   77:   --without-debug	  omits the -g switch and creates smaller images on
   78: 			  machines where "strip" has problems with gcc style
   79: 			  debugging informations.],
   80: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   81: 
   82: dnl PEEPHOLE="yes"
   83: dnl AC_ARG_WITH(peephole,
   84: dnl [  --with-peephole	Enable peephole optimization (default)
   85: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   86: dnl 			but slower images.],
   87: dnl PEEPHOLE="$withval")
   88: 
   89: GCC_LD="\$(GCC)"
   90: EC_MODE="false"
   91: EC=""
   92: engine2="engine2.o"
   93: engine_fast2="engine-fast2.o"
   94: no_dynamic=""
   95: image_i=""
   96: signals_o="io.o signals.o"
   97: 
   98: AC_ARG_WITH(ec,
   99: 	AC_HELP_STRING([--with-ec=<arch>],
  100: 			[  Build gforth for systems without OS.]),
  101: [if test "$withval" = "no"; then
  102:   echo "defining hosted system"
  103: else
  104:   echo "defining standalone system (${withval})"
  105:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
  106:   EC_MODE="true"
  107:   EC="-ec"
  108:   engine2=""
  109:   engine_fast2=""
  110:   no_dynamic="-DNO_DYNAMIC"
  111:   image_i="image.i"
  112:   if test "$withval" != "yes"; then
  113:     signals_o="io-${withval}.o"
  114:   else
  115:     signals_o="io.o"
  116:   fi
  117:   GCC_PATH=$(which $CC)
  118:   LIB_PATH=${GCC_PATH%/*/*}
  119:   GCC_LD="\$(LD)"
  120:   platform=${withval}
  121: fi])
  122: 
  123: #variables mentioned in INSTALL
  124: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
  125: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  126: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  127: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  128: 
  129: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  130: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  131: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  132: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  133: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  134: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  135: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  136: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  137: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  138: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  139: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  140: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  141: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
  142: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  143: AC_ARG_VAR(asmcomment, [assembler comment start string])
  144: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  145: 
  146: #set up feature test macros, so the tests get them right:
  147: # turn on all POSIX, SUSv3, and GNU features if available
  148: AC_GNU_SOURCE
  149: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  150: 
  151: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  152: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  153: dnl but not for _XOPEN_SOURCE)
  154: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  155: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  156: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  157: # turn on large file support with 64-bit off_t where available
  158: AC_SYS_LARGEFILE
  159: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  160: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  161: 
  162: #currently we force direct threading this way.  Eventually we should
  163: #setup in the arch and engine files right
  164: 
  165: AC_PROG_CC
  166: 
  167: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  168: 
  169: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
  170: test x$condbranch_opt = x && 
  171: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
  172:    condbranch_opt=0
  173: else
  174:    condbranch_opt=1
  175: fi
  176: AC_MSG_RESULT($condbranch_opt)
  177: AC_SUBST(condbranch_opt)
  178: 
  179: AC_SUBST(CC)
  180: AC_SUBST(GCC_LD)
  181: AC_SUBST(DEBUGFLAG)
  182: AC_SUBST(EC)
  183: AC_SUBST(EC_MODE)
  184: AC_SUBST(engine2)
  185: AC_SUBST(engine_fast2)
  186: AC_SUBST(no_dynamic)
  187: AC_SUBST(image_i)
  188: AC_SUBST(signals_o)
  189: 
  190: #this is used to disable some (not generally essential) part of the
  191: #Makefile that some makes don't grok.  It would be better to test for
  192: #this specific Makefile feature than the make version.
  193: AC_MSG_CHECKING(make type)
  194: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  195: GNUMAKE='#'
  196: test "$make_type" = "GNU Make" && GNUMAKE=''
  197: AC_MSG_RESULT($make_type)
  198: AC_SUBST(GNUMAKE)
  199: 
  200: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  201: OLDLDFLAGS=$LDFLAGS
  202: LDFLAGS="$LDFLAGS -export-dynamic"
  203: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  204: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  205: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  206: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  207: AC_MSG_RESULT($ac_export_dynamic)
  208: 
  209: #terminology is a bit unusual here: The host is the system on which
  210: #gforth will run; the system on which configure will run is the `build'
  211: AC_CANONICAL_HOST
  212: case "$host_cpu" in
  213: 	arm*)
  214: 		machine=arm
  215: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  216: 		if test x$platform = xnxt; then
  217: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  218: 		fi
  219: 		if test -z $arm_cacheflush; then
  220: 		    no_dynamic_default=1
  221:                     arm_cacheflush=arch/arm/cacheflush0
  222: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  223: 		fi
  224:                 AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
  225:                 AC_LIBOBJ(../$arm_cacheflush)
  226:                 #longer skipcodes lead to problems on ARM, and it uses
  227:                 #only 4-byte alignment anyway
  228: 		test "$skipcode" || skipcode="nop"
  229: 		;;
  230: 	hppa*)
  231: 		machine=hppa
  232: 		$srcdir/mkinstalldirs arch/hppa
  233: 		AC_LIBOBJ(../arch/hppa/cache)
  234: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  235: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  236: 		LIBS="$LIBS -L/lib/pa1.1/"
  237: 		;;
  238: 	sparc*)
  239: 		machine=sparc
  240: 		;;
  241: 	i386)
  242: 		machine=386
  243: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  244: 		;;
  245: 	i486)
  246: 		machine=386
  247: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
  248: 		;;
  249: 	i*86)
  250: 		machine=386
  251: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
  252: 		CFLAGS_1="$CFLAGS"
  253: 		CFLAGS="$CFLAGS -march=pentium"
  254: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  255: 		;;
  256: 	x86_64)
  257: 		machine=amd64
  258: 		;;
  259: 	ia64*)
  260: 		machine=ia64
  261: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  262: 		test "$skipcode" || skipcode="nop.i 0"
  263: 		#".skip 16" passes the test below,
  264: 		# but gives an assembler error in engine
  265: 		;;
  266:         m68k)
  267: 		machine=m68k
  268: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  269: 		if test "$host_os" = "nextstep3"
  270: 		then
  271: 			AC_LIBOBJ(termios)
  272: 		fi
  273: 		;;
  274: 	mips*)
  275: 		machine=mips
  276: 		#dynamic native code has the following problems on MIPS:
  277: 		#
  278: 		#1) J/JAL seems relocatable, but is are only
  279: 		#relocatable within a 256MB-segment.  While we try to
  280: 		#get the linker to arrange this, there is no guarantee
  281: 		#that this will succeed (and if the user uses a lot of
  282: 		#memory, it is likely to fail).
  283: 		#
  284: 		#2) The way we generate dynamic native code may
  285: 		#violate MIPS architectural restrictions (in
  286: 		#particular, the delay slots of LW, MFLO, etc.)
  287: 		#
  288: 		#Therefore we disable dynamic native code by default:
  289: 		if test -z $no_dynamic_default; then
  290: 		    no_dynamic_default=1
  291: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  292: 		fi
  293: 		;;
  294: 	alpha*)
  295: 		machine=alpha
  296: 		#full IEEE FP support for more uniformity across platforms:
  297: 		CFLAGS="$CFLAGS -mieee"
  298: 		;;
  299: 	power*|rs6000)
  300: 		machine=power
  301: 		$srcdir/mkinstalldirs arch/power
  302: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  303: 		#long long is broken on (at least) gcc-2.95.* for PPC
  304: 		test x$ac_cv_sizeof_long_long = x && 
  305: 		($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
  306: 		ac_cv_sizeof_long_long=0
  307: 		;;
  308: 	*)
  309: 		AC_MSG_WARN([Using a generic machine description])
  310: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  311: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  312: 		machine=generic
  313: 		#I-cache flushing would be needed for dynamic code generation
  314: 		if test -z $no_dynamic_default; then
  315: 		    no_dynamic_default=1
  316: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  317: 		fi
  318: esac
  319: AC_SUBST(host)
  320: 
  321: MAKEINC=""
  322: 
  323: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  324: if test x$EC_MODE = xtrue
  325: then
  326: 	echo "Check for arch/$machine/$platform/gforth.ld"
  327: 	if test -f arch/$machine/$platform/gforth.ld
  328: 	then
  329: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  330: 		if test x$platform = xnxt; then
  331: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  332: 		fi
  333: 	fi
  334: 	if test -f arch/$machine/$platform/make.inc
  335: 	then
  336: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  337: 	fi
  338: fi
  339: AC_SUBST(MAKEINC)
  340: 
  341: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  342: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  343: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  344: 
  345: test x$GCC_PR15242_WORKAROUND = x ||
  346: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  347:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  348: 
  349: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
  350: dnl generation on gccs affected by PR15242])
  351: 
  352: 
  353: if test "${enable_force_ll+set}" = set; then
  354:    ac_includes_default="$ac_includes_default
  355: #include \"arch/generic/128bit.h\""
  356: fi
  357: 
  358: dnl the following macro produces a warning with autoconf-2.1
  359: AC_CHECK_SIZEOF(char *)
  360: case "$ac_cv_sizeof_char_p" in
  361:   2)
  362:     wordsize=16
  363:     ;;
  364:   4)
  365:     wordsize=32
  366:     ;;
  367:   8)
  368:     wordsize=64
  369:     ;;
  370: esac
  371: 
  372: AC_CHECK_SIZEOF(void *)
  373: case "$ac_cv_sizeof_void_p" in
  374:   2)
  375:     vwordsize=16
  376:     ;;
  377:   4)
  378:     vwordsize=32
  379:     ;;
  380:   8)
  381:     vwordsize=64
  382:     ;;
  383: esac
  384: 
  385: AC_CHECK_SIZEOF(char)
  386: AC_CHECK_SIZEOF(short)
  387: AC_CHECK_SIZEOF(int)
  388: AC_CHECK_SIZEOF(long)
  389: AC_CHECK_SIZEOF(long long)
  390: AC_CHECK_SIZEOF(intptr_t)
  391: AC_CHECK_SIZEOF(int128_t)
  392: AC_CHECK_SIZEOF(uint128_t)
  393: 
  394: AC_MSG_CHECKING([for a C type for cells])
  395: ac_cv_int_type_cell=none
  396: case "$ac_cv_sizeof_char_p" in
  397:   $ac_cv_sizeof_int)
  398:     ac_cv_int_type_cell=int
  399:     ;;
  400:   $ac_cv_sizeof_short)
  401:     ac_cv_int_type_cell=short
  402:     ;;
  403:   $ac_cv_sizeof_char)
  404:     ac_cv_int_type_cell=char
  405:     ;;
  406:   $ac_cv_sizeof_long)
  407:     ac_cv_int_type_cell=long
  408:     ;;
  409:   $ac_cv_sizeof_long_long)
  410:     ac_cv_int_type_cell="long long"
  411:     ;;
  412:   $ac_cv_sizeof_intptr_t)
  413:     ac_cv_int_type_cell="intptr_t"
  414:     ;;
  415:   $ac_cv_sizeof_int128_t)
  416:     ac_cv_int_type_cell="int128_t"
  417:     ;;
  418: esac
  419: AC_MSG_RESULT($ac_cv_int_type_cell)
  420: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  421: 
  422: AC_MSG_CHECKING([for a C type for wydes])
  423: ac_cv_wyde_type_cell=none
  424: case 2 in
  425:   $ac_cv_sizeof_int)
  426:     ac_cv_wyde_type_cell=int
  427:     ;;
  428:   $ac_cv_sizeof_short)
  429:     ac_cv_wyde_type_cell=short
  430:     ;;
  431:   $ac_cv_sizeof_char)
  432:     ac_cv_wyde_type_cell=char
  433:     ;;
  434:   $ac_cv_sizeof_long)
  435:     ac_cv_wyde_type_cell=long
  436:     ;;
  437:   $ac_cv_sizeof_long_long)
  438:     ac_cv_wyde_type_cell="long long"
  439:     ;;
  440:   $ac_cv_sizeof_intptr_t)
  441:     ac_cv_wyde_type_cell="intptr_t"
  442:     ;;
  443:   $ac_cv_sizeof_int128_t)
  444:     ac_cv_wyde_type_cell="int128_t"
  445:     ;;
  446: esac
  447: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  448: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  449: 
  450: AC_MSG_CHECKING([for a C type for tetrabytes])
  451: ac_cv_tetrabyte_type_cell=none
  452: case 4 in
  453:   $ac_cv_sizeof_int)
  454:     ac_cv_tetrabyte_type_cell=int
  455:     ;;
  456:   $ac_cv_sizeof_short)
  457:     ac_cv_tetrabyte_type_cell=short
  458:     ;;
  459:   $ac_cv_sizeof_char)
  460:     ac_cv_tetrabyte_type_cell=char
  461:     ;;
  462:   $ac_cv_sizeof_long)
  463:     ac_cv_tetrabyte_type_cell=long
  464:     ;;
  465:   $ac_cv_sizeof_long_long)
  466:     ac_cv_tetrabyte_type_cell="long long"
  467:     ;;
  468:   $ac_cv_sizeof_intptr_t)
  469:     ac_cv_tetrabyte_type_cell="intptr_t"
  470:     ;;
  471:   $ac_cv_sizeof_int128_t)
  472:     ac_cv_tetrabyte_type_cell="int128_t"
  473:     ;;
  474: esac
  475: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  476: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  477: 
  478: AC_MSG_CHECKING([for a C type for double-cells])
  479: ac_cv_int_type_double_cell=none
  480: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  481:   $ac_cv_sizeof_short)
  482:     ac_cv_int_type_double_cell=short
  483:     ;;
  484:   $ac_cv_sizeof_int)
  485:     ac_cv_int_type_double_cell=int
  486:     ;;
  487:   $ac_cv_sizeof_long)
  488:     ac_cv_int_type_double_cell=long
  489:     ;;
  490:   $ac_cv_sizeof_long_long)
  491:     ac_cv_int_type_double_cell="long long"
  492:     ;;
  493:   $ac_cv_sizeof_intptr_t)
  494:     ac_cv_int_type_double_cell="intptr_t"
  495:     ;;
  496:   $ac_cv_sizeof_int128_t)
  497:     ac_cv_int_type_double_cell="int128_t"
  498:     ;;
  499: esac
  500: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  501: 
  502: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  503: ac_cv_int_type_double_ucell=none
  504: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  505:   $ac_cv_sizeof_short)
  506:     ac_cv_int_type_double_ucell="unsigned short"
  507:     ;;
  508:   $ac_cv_sizeof_int)
  509:     ac_cv_int_type_double_ucell="unsigned int"
  510:     ;;
  511:   $ac_cv_sizeof_long)
  512:     ac_cv_int_type_double_ucell="unsigned long"
  513:     ;;
  514:   $ac_cv_sizeof_long_long)
  515:     ac_cv_int_type_double_ucell="unsigned long long"
  516:     ;;
  517:   $ac_cv_sizeof_intptr_t)
  518:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  519:     ;;
  520:   $ac_cv_sizeof_uint128_t)
  521:     ac_cv_int_type_double_ucell="uint128_t"
  522:     ;;
  523: esac
  524: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  525: 
  526: if test "$ac_cv_int_type_double_cell" = none || \
  527:    test "$ac_cv_int_type_double_ucell" = none
  528: then
  529: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  530: 	AC_LIBOBJ(dblsub)
  531: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  532: else
  533: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  534: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  535: fi
  536: 
  537: AC_TYPE_OFF_T
  538: AC_CHECK_SIZEOF(off_t)
  539: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  540: ac_small_off_t=$?
  541: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  542: 
  543: ENGINE_FLAGS=
  544: AC_SUBST(ENGINE_FLAGS)
  545: 
  546: # Try if GCC understands -fno-gcse
  547: 
  548: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  549: CFLAGS_1="$CFLAGS"
  550: CFLAGS="$CFLAGS -fno-gcse"
  551: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  552: CFLAGS="$CFLAGS_1"
  553: AC_MSG_RESULT($ac_nogcse)
  554: 
  555: # Try if GCC understands -fno-strict-aliasing
  556: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  557: CFLAGS_1="$CFLAGS"
  558: CFLAGS="$CFLAGS -fno-strict-aliasing"
  559: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  560: CFLAGS="$CFLAGS_1"
  561: AC_MSG_RESULT($ac_nostrictaliasing)
  562: 
  563: # Try if GCC understands -fno-crossjumping
  564: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  565: CFLAGS_1="$CFLAGS"
  566: CFLAGS="$CFLAGS -fno-crossjumping"
  567: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  568: CFLAGS="$CFLAGS_1"
  569: AC_MSG_RESULT($ac_nocrossjumping)
  570: 
  571: # Try if GCC understands -fno-reorder-blocks
  572: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  573: CFLAGS_1="$CFLAGS"
  574: CFLAGS="$CFLAGS -fno-reorder-blocks"
  575: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  576: CFLAGS="$CFLAGS_1"
  577: AC_MSG_RESULT($ac_noreorder_blocks)
  578: 
  579: # Try if GCC understands -falign-labels=1
  580: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
  581: CFLAGS_1="$CFLAGS"
  582: CFLAGS="$CFLAGS -falign-labels=1"
  583: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
  584: CFLAGS="$CFLAGS_1"
  585: AC_MSG_RESULT($ac_align_labels)
  586: 
  587: # Try if GCC understands __attribute__((unused))
  588: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  589: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  590: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  591: AC_MSG_RESULT($MAYBE_UNUSED)
  592: 
  593: echo "machine='$machine'"
  594: 
  595: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  596: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
  597: AC_SUBST(asm_fs)
  598: 
  599: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  600: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
  601: AC_SUBST(disasm_fs)
  602: 
  603: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  604: 
  605: case "$host_os" in
  606: 	*win32*)
  607: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  608: 		DIRSEP="\\\\"
  609: 		PATHSEP=";"
  610: 		#we want the builtins of command.com/cmd.exe and its
  611: 		# handling of .com files.
  612: 		#$COMSPEC contains the name of the Windows shell;
  613: 		# the ./ is there, because the bash does not recognize
  614: 		# absolute DOS filenames
  615: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  616: 		;;
  617: 	*darwin*)
  618: 		#Darwin uses some funny preprocessor by default; eliminate it:
  619: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  620: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  621: 		DIRSEP="/"
  622: 		PATHSEP=":"
  623: 		DEFAULTSYSTEMPREFIX=""
  624: 		;;
  625: 	*)
  626: 		DIRSEP="/"
  627: 		PATHSEP=":"
  628: 		DEFAULTSYSTEMPREFIX=""
  629: 		;;
  630: esac
  631: AC_SUBST(DIRSEP)
  632: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  633: AC_SUBST(PATHSEP)
  634: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  635: AC_SUBST(DEFAULTSYSTEMPREFIX)
  636: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  637: 
  638: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  639: #This magic incantation  seems to be completely undocumented.
  640: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  641: 
  642: dnl Now a little support for DOS/DJGCC
  643: AC_SUBST(GFORTH_EXE)
  644: GFORTH_EXE=""
  645: AC_SUBST(GFORTHFAST_EXE)
  646: GFORTHFAST_EXE=""
  647: AC_SUBST(GFORTHITC_EXE)
  648: GFORTHITC_EXE=""
  649: AC_SUBST(GFORTHDITC_EXE)
  650: GFORTHDITC_EXE=""
  651: 
  652: AC_SUBST(FORTHSIZES)
  653: 
  654: dnl if test "$PEEPHOLE" = "yes"
  655: dnl then
  656: dnl    PEEPHOLEFLAG="true"
  657: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  658: dnl else
  659: dnl    PEEPHOLEFLAG="false"
  660: dnl fi
  661: PEEPHOLEFLAG="true"
  662: AC_SUBST(PEEPHOLEFLAG)
  663: 
  664: dnl copy commands for systems that don't have links
  665: AC_SUBST(LINK_KERNL)
  666: LINK_KERNL=""
  667: 
  668: #if test $host_os=dos
  669: #then
  670: #  echo Configuring for DOS!!!
  671: #  MAKE_EXE="coff2exe gforth"
  672: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  673: #fi
  674: 
  675: dnl the following macro produces a warning with autoconf-2.1
  676: AC_C_BIGENDIAN
  677: AC_SUBST(KERNEL)
  678: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  679: if test $ac_cv_c_bigendian = yes; then
  680:   bytesex=b
  681:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  682: else
  683:   bytesex=l
  684:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  685: fi
  686: 
  687: #check how to do asm(".skip 16")
  688: #echo "CFLAGS=$CFLAGS"
  689: #echo "ac_link=$ac_link"
  690: AC_MSG_CHECKING([if and how we can waste code space])
  691: if test -z "$skipcode"; then
  692:     skipcode=no
  693:     CFLAGS_1="$CFLAGS"
  694:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  695:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  696:     do
  697: 	AC_TRY_RUN(
  698: [int foo(int,int,int);
  699: main()
  700: {
  701:   exit(foo(0,0,0)!=16);
  702: }
  703: int foo(int x, int y, int z)
  704: {
  705:   static void *labels[]={&&label1, &&label2};
  706:   if (x) {
  707:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  708:   label1:
  709:     asm("$i"); /* or ".space 16" or somesuch */
  710:   label2: ;
  711:   }
  712:   {
  713:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  714:   return labels[1]-labels[0];
  715:   }
  716: }]
  717: 	,skipcode=$i; break
  718: 	,,)
  719:     done
  720:     CFLAGS=$CFLAGS_1
  721: fi
  722: AC_MSG_RESULT($skipcode)
  723: if test "$skipcode" = no
  724: then 
  725:     if test -z $no_dynamic_default; then
  726: 	no_dynamic_default=1
  727: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  728:     fi
  729:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  730: else
  731:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  732: fi
  733: 
  734: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  735: #the point here is to get asm statements that look different to
  736: #gcc's "optimizer"
  737: if test -z "$asmcomment"; then
  738:     asmcomment=no
  739:     CFLAGS_1="$CFLAGS"
  740:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  741:     for i in '"# "' '"! "' '"; "'; do
  742: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  743:     done
  744:     CFLAGS=$CFLAGS_1
  745: fi
  746: AC_MSG_RESULT($asmcomment)
  747: if test "$asmcomment" != no
  748: then 
  749:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  750: fi
  751: 
  752: test "$no_dynamic_default" || no_dynamic_default=0
  753: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  754: 
  755: dnl Checks for programs.
  756: AC_PROG_LN_S
  757: AC_PROG_INSTALL
  758: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  759: 
  760: dnl Checks for library functions
  761: dnl This check is just for making later checks link with libm.
  762: dnl using sin here is no good idea since it is built-into gcc and typechecked
  763: AC_CHECK_LIB(m,asin)
  764: AC_CHECK_LIB(dl,dlopen)
  765: dnl check for libffi 2.x
  766: AC_CHECK_LIB(ffi,ffi_call)
  767: if test $ac_cv_lib_ffi_ffi_call = yes
  768: then
  769: LIBFFIFLAG="true"
  770: FFCALLFLAG="false"
  771: OLDCALLFLAG="false"
  772: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
  773: else
  774: dnl check for ffcall libraries
  775: dnl unfortunately, these four calls are separated out into a library each.
  776: AC_CHECK_LIB(avcall,__builtin_avcall)
  777: AC_CHECK_LIB(callback,__vacall_r)
  778: AC_CHECK_LIB(vacall,vacall)
  779: AC_CHECK_LIB(trampoline,alloc_trampoline)
  780: LIBFFIFLAG="false"
  781: FFCALLFLAG="false"
  782: OLDCALLFLAG="true"
  783: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  784: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  785: fi
  786: AC_SUBST(LIBFFIFLAG)
  787: AC_SUBST(FFCALLFLAG)
  788: AC_SUBST(OLDCALLFLAG)
  789: if test "$host_os" != "nextstep3"
  790: then
  791: 	AC_FUNC_MEMCMP
  792: fi
  793: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  794: AC_FUNC_FSEEKO
  795: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
  796: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  797: AC_DECL_SYS_SIGLIST
  798: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  799: AC_CHECK_FUNCS(expm1 log1p)
  800: AC_REPLACE_FUNCS(rint ecvt)
  801: dnl No check for select, because our replacement is no good under
  802: dnl anything but DOS
  803: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  804: AC_FUNC_FNMATCH
  805: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  806: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  807: AM_PATH_LISPDIR
  808: 
  809: kernel_fi=kernl${vwordsize}${bytesex}.fi
  810: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  811: AC_SUBST(kernel_fi)
  812: AC_SUBST(include_fi)
  813: 
  814: #this breaks bindists
  815: #dnl replace srource directory by absolute value
  816: #if test $srcdir = "."; then srcdir=`pwd` 
  817: #fi
  818: 
  819: AC_SUBST(machine)
  820: AC_CONFIG_FILES([
  821: Makefile
  822: Makedist
  823: gforthmi
  824: vmgen
  825: machpc.fs
  826: envos.fs
  827: engine/Makefile
  828: engine/libcc.h
  829: doc/version.texi
  830: build-ec ])
  831: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  832: chmod +x gforthmi
  833: chmod +x vmgen
  834: chmod +x build-ec
  835: test -d kernel||mkdir kernel
  836: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
  837: ln -s ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
  838: AC_OUTPUT
  839: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>