1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.9-20070401],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="April 09, 2006"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(force-cdiv,
57: AC_HELP_STRING([--enable-force-cdiv],
58: [ Use the native C division - symmetric - instead of
59: floored division (default disabled).]),
60: ,enable_force_cdiv=no)
61: test "$enable_force_cdiv" = "no"||
62: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
63:
64: AC_SUBST(PROFEXES)
65: AC_SUBST(PROFOBJS)
66: AC_ARG_ENABLE(prof,
67: AC_HELP_STRING([--enable-prof],
68: [ Build gforth-prof, which outputs frequently occuring
69: sequences of primitives.]),
70: ,enable_prof=no)
71: if test "$enable_prof" = "no"; then
72: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
73: fi
74:
75: AC_ARG_WITH(debug,
76: [ --with-debug specifies option -g to compile with debug info
77: --without-debug omits the -g switch and creates smaller images on
78: machines where "strip" has problems with gcc style
79: debugging informations.],
80: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
81:
82: dnl PEEPHOLE="yes"
83: dnl AC_ARG_WITH(peephole,
84: dnl [ --with-peephole Enable peephole optimization (default)
85: dnl --without-peephole disables peephole optimization. Creates smaller,
86: dnl but slower images.],
87: dnl PEEPHOLE="$withval")
88:
89: AC_ARG_WITH(ec,
90: AC_HELP_STRING([--with-ec=<arch>],
91: [ Build gforth for systems without OS.]),
92: [if test "$withval" = "no"; then
93: echo "defining hosted system"
94: EC_MODE="false"
95: EC=""
96: engine2="engine2.o"
97: engine_fast2="engine-fast2.o"
98: no_dynamic=""
99: image_i=""
100: signals_o="io.o signals.o"
101: GCC_LD="\$(GCC)"
102: else
103: echo "defining standalone system (${withval})"
104: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
105: EC_MODE="true"
106: EC="-ec"
107: engine2=""
108: engine_fast2=""
109: no_dynamic="-DNO_DYNAMIC"
110: image_i="image.i"
111: if test "$withval" != "yes"; then
112: signals_o="io-${withval}.o"
113: else
114: signals_o="io.o"
115: fi
116: GCC_PATH=$(which $CC)
117: LIB_PATH=${GCC_PATH%/*/*}
118: GCC_LD="\$(LD)"
119: platform=${withval}
120: fi])
121:
122: #variables mentioned in INSTALL
123: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
124: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
125: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
126: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
127:
128: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
129: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
130: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
131: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
132: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
133: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
134: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
135: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
136: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
137: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
138: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
139: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
140: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
141: AC_ARG_VAR(asmcomment, [assembler comment start string])
142: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
143:
144: #set up feature test macros, so the tests get them right:
145: # turn on all POSIX, SUSv3, and GNU features if available
146: AC_GNU_SOURCE
147: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
148:
149: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
150: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
151: dnl but not for _XOPEN_SOURCE)
152: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
153: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
154: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
155: # turn on large file support with 64-bit off_t where available
156: AC_SYS_LARGEFILE
157: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
158: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
159:
160: #currently we force direct threading this way. Eventually we should
161: #setup in the arch and engine files right
162:
163: AC_PROG_CC
164:
165: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
166:
167: AC_SUBST(CC)
168: AC_SUBST(GCC_LD)
169: AC_SUBST(DEBUGFLAG)
170: AC_SUBST(EC)
171: AC_SUBST(EC_MODE)
172: AC_SUBST(engine2)
173: AC_SUBST(engine_fast2)
174: AC_SUBST(no_dynamic)
175: AC_SUBST(image_i)
176: AC_SUBST(signals_o)
177:
178: #this is used to disable some (not generally essential) part of the
179: #Makefile that some makes don't grok. It would be better to test for
180: #this specific Makefile feature than the make version.
181: AC_MSG_CHECKING(make type)
182: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
183: GNUMAKE='#'
184: test "$make_type" = "GNU Make" && GNUMAKE=''
185: AC_MSG_RESULT($make_type)
186: AC_SUBST(GNUMAKE)
187:
188: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
189: OLDLDFLAGS=$LDFLAGS
190: LDFLAGS="$LDFLAGS -export-dynamic"
191: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
192: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
193: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
194: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
195: AC_MSG_RESULT($ac_export_dynamic)
196:
197: #terminology is a bit unusual here: The host is the system on which
198: #gforth will run; the system on which configure will run is the `build'
199: AC_CANONICAL_HOST
200: case "$host_cpu" in
201: arm*)
202: machine=arm
203: CFLAGS="$CFLAGS -fomit-frame-pointer"
204: if test x$platform = xnxt; then
205: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
206: fi
207: if test -z $arm_cacheflush; then
208: no_dynamic_default=1
209: arm_cacheflush=arch/arm/cacheflush0
210: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
211: fi
212: AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
213: AC_LIBOBJ(../$arm_cacheflush)
214: #longer skipcodes lead to problems on ARM, and it uses
215: #only 4-byte alignment anyway
216: test "$skipcode" || skipcode="nop"
217: ;;
218: hppa*)
219: machine=hppa
220: $srcdir/mkinstalldirs arch/hppa
221: AC_LIBOBJ(../arch/hppa/cache)
222: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
223: LDFLAGS="$LDFLAGS -Xlinker -N"
224: LIBS="$LIBS -L/lib/pa1.1/"
225: ;;
226: sparc*)
227: machine=sparc
228: ;;
229: i386)
230: machine=386
231: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
232: ;;
233: i486)
234: machine=386
235: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
236: ;;
237: i*86)
238: machine=386
239: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
240: CFLAGS_1="$CFLAGS"
241: CFLAGS="$CFLAGS -march=pentium"
242: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
243: ;;
244: x86_64)
245: machine=amd64
246: ;;
247: ia64*)
248: machine=ia64
249: AC_LIBOBJ(../arch/ia64/flush_icache_block)
250: test "$skipcode" || skipcode="nop.i 0"
251: #".skip 16" passes the test below,
252: # but gives an assembler error in engine
253: ;;
254: m68k)
255: machine=m68k
256: CFLAGS="$CFLAGS -fomit-frame-pointer"
257: if test "$host_os" = "nextstep3"
258: then
259: AC_LIBOBJ(termios)
260: fi
261: ;;
262: mips*)
263: machine=mips
264: #dynamic native code has the following problems on MIPS:
265: #
266: #1) J/JAL seems relocatable, but is are only
267: #relocatable within a 256MB-segment. While we try to
268: #get the linker to arrange this, there is no guarantee
269: #that this will succeed (and if the user uses a lot of
270: #memory, it is likely to fail).
271: #
272: #2) The way we generate dynamic native code may
273: #violate MIPS architectural restrictions (in
274: #particular, the delay slots of LW, MFLO, etc.)
275: #
276: #Therefore we disable dynamic native code by default:
277: if test -z $no_dynamic_default; then
278: no_dynamic_default=1
279: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
280: fi
281: ;;
282: alpha*)
283: machine=alpha
284: #full IEEE FP support for more uniformity across platforms:
285: CFLAGS="$CFLAGS -mieee"
286: ;;
287: power*|rs6000)
288: machine=power
289: $srcdir/mkinstalldirs arch/power
290: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
291: #long long is broken on (at least) gcc-2.95.* for PPC
292: test x$ac_cv_sizeof_long_long = x &&
293: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
294: ac_cv_sizeof_long_long=0
295: ;;
296: *)
297: AC_MSG_WARN([Using a generic machine description])
298: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
299: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
300: machine=generic
301: #I-cache flushing would be needed for dynamic code generation
302: if test -z $no_dynamic_default; then
303: no_dynamic_default=1
304: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
305: fi
306: esac
307: AC_SUBST(host)
308:
309: MAKEINC=""
310:
311: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
312: if test x$EC_MODE = xtrue
313: then
314: echo "Check for arch/$machine/$platform/gforth.ld"
315: if test -f arch/$machine/$platform/gforth.ld
316: then
317: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
318: if test x$platform = xnxt; then
319: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
320: fi
321: fi
322: if test -f arch/$machine/$platform/make.inc
323: then
324: MAKEINC="include ../arch/$machine/$platform/make.inc"
325: fi
326: fi
327: AC_SUBST(MAKEINC)
328:
329: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
330: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
331: [number of registers in the default stack cache state for gforth-fast and gforth-native])
332:
333: test x$GCC_PR15242_WORKAROUND = x ||
334: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
335: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
336:
337: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
338: dnl generation on gccs affected by PR15242])
339:
340:
341: if test "${enable_force_ll+set}" = set; then
342: ac_includes_default="$ac_includes_default
343: #include \"arch/generic/128bit.h\""
344: fi
345:
346: dnl the following macro produces a warning with autoconf-2.1
347: AC_CHECK_SIZEOF(char *)
348: case "$ac_cv_sizeof_char_p" in
349: 2)
350: wordsize=16
351: ;;
352: 4)
353: wordsize=32
354: ;;
355: 8)
356: wordsize=64
357: ;;
358: esac
359:
360: AC_CHECK_SIZEOF(void *)
361: case "$ac_cv_sizeof_void_p" in
362: 2)
363: vwordsize=16
364: ;;
365: 4)
366: vwordsize=32
367: ;;
368: 8)
369: vwordsize=64
370: ;;
371: esac
372:
373: AC_CHECK_SIZEOF(char)
374: AC_CHECK_SIZEOF(short)
375: AC_CHECK_SIZEOF(int)
376: AC_CHECK_SIZEOF(long)
377: AC_CHECK_SIZEOF(long long)
378: AC_CHECK_SIZEOF(intptr_t)
379: AC_CHECK_SIZEOF(int128_t)
380: AC_CHECK_SIZEOF(uint128_t)
381:
382: AC_MSG_CHECKING([for a C type for cells])
383: ac_cv_int_type_cell=none
384: case "$ac_cv_sizeof_char_p" in
385: $ac_cv_sizeof_int)
386: ac_cv_int_type_cell=int
387: ;;
388: $ac_cv_sizeof_short)
389: ac_cv_int_type_cell=short
390: ;;
391: $ac_cv_sizeof_char)
392: ac_cv_int_type_cell=char
393: ;;
394: $ac_cv_sizeof_long)
395: ac_cv_int_type_cell=long
396: ;;
397: $ac_cv_sizeof_long_long)
398: ac_cv_int_type_cell="long long"
399: ;;
400: $ac_cv_sizeof_intptr_t)
401: ac_cv_int_type_cell="intptr_t"
402: ;;
403: $ac_cv_sizeof_int128_t)
404: ac_cv_int_type_cell="int128_t"
405: ;;
406: esac
407: AC_MSG_RESULT($ac_cv_int_type_cell)
408: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
409:
410: AC_MSG_CHECKING([for a C type for wydes])
411: ac_cv_wyde_type_cell=none
412: case 2 in
413: $ac_cv_sizeof_int)
414: ac_cv_wyde_type_cell=int
415: ;;
416: $ac_cv_sizeof_short)
417: ac_cv_wyde_type_cell=short
418: ;;
419: $ac_cv_sizeof_char)
420: ac_cv_wyde_type_cell=char
421: ;;
422: $ac_cv_sizeof_long)
423: ac_cv_wyde_type_cell=long
424: ;;
425: $ac_cv_sizeof_long_long)
426: ac_cv_wyde_type_cell="long long"
427: ;;
428: $ac_cv_sizeof_intptr_t)
429: ac_cv_wyde_type_cell="intptr_t"
430: ;;
431: $ac_cv_sizeof_int128_t)
432: ac_cv_wyde_type_cell="int128_t"
433: ;;
434: esac
435: AC_MSG_RESULT($ac_cv_wyde_type_cell)
436: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
437:
438: AC_MSG_CHECKING([for a C type for tetrabytes])
439: ac_cv_tetrabyte_type_cell=none
440: case 4 in
441: $ac_cv_sizeof_int)
442: ac_cv_tetrabyte_type_cell=int
443: ;;
444: $ac_cv_sizeof_short)
445: ac_cv_tetrabyte_type_cell=short
446: ;;
447: $ac_cv_sizeof_char)
448: ac_cv_tetrabyte_type_cell=char
449: ;;
450: $ac_cv_sizeof_long)
451: ac_cv_tetrabyte_type_cell=long
452: ;;
453: $ac_cv_sizeof_long_long)
454: ac_cv_tetrabyte_type_cell="long long"
455: ;;
456: $ac_cv_sizeof_intptr_t)
457: ac_cv_tetrabyte_type_cell="intptr_t"
458: ;;
459: $ac_cv_sizeof_int128_t)
460: ac_cv_tetrabyte_type_cell="int128_t"
461: ;;
462: esac
463: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
464: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
465:
466: AC_MSG_CHECKING([for a C type for double-cells])
467: ac_cv_int_type_double_cell=none
468: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
469: $ac_cv_sizeof_short)
470: ac_cv_int_type_double_cell=short
471: ;;
472: $ac_cv_sizeof_int)
473: ac_cv_int_type_double_cell=int
474: ;;
475: $ac_cv_sizeof_long)
476: ac_cv_int_type_double_cell=long
477: ;;
478: $ac_cv_sizeof_long_long)
479: ac_cv_int_type_double_cell="long long"
480: ;;
481: $ac_cv_sizeof_intptr_t)
482: ac_cv_int_type_double_cell="intptr_t"
483: ;;
484: $ac_cv_sizeof_int128_t)
485: ac_cv_int_type_double_cell="int128_t"
486: ;;
487: esac
488: AC_MSG_RESULT($ac_cv_int_type_double_cell)
489:
490: AC_MSG_CHECKING([for a C type for unsigned double-cells])
491: ac_cv_int_type_double_ucell=none
492: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
493: $ac_cv_sizeof_short)
494: ac_cv_int_type_double_ucell="unsigned short"
495: ;;
496: $ac_cv_sizeof_int)
497: ac_cv_int_type_double_ucell="unsigned int"
498: ;;
499: $ac_cv_sizeof_long)
500: ac_cv_int_type_double_ucell="unsigned long"
501: ;;
502: $ac_cv_sizeof_long_long)
503: ac_cv_int_type_double_ucell="unsigned long long"
504: ;;
505: $ac_cv_sizeof_intptr_t)
506: ac_cv_int_type_double_ucell="unsigned intptr_t"
507: ;;
508: $ac_cv_sizeof_uint128_t)
509: ac_cv_int_type_double_ucell="uint128_t"
510: ;;
511: esac
512: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
513:
514: if test "$ac_cv_int_type_double_cell" = none || \
515: test "$ac_cv_int_type_double_ucell" = none
516: then
517: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
518: AC_LIBOBJ(dblsub)
519: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
520: else
521: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
522: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
523: fi
524:
525: AC_TYPE_OFF_T
526: AC_CHECK_SIZEOF(off_t)
527: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
528: ac_small_off_t=$?
529: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
530:
531: ENGINE_FLAGS=
532: AC_SUBST(ENGINE_FLAGS)
533:
534: # Try if GCC understands -fno-gcse
535:
536: AC_MSG_CHECKING([if $CC understands -fno-gcse])
537: CFLAGS_1="$CFLAGS"
538: CFLAGS="$CFLAGS -fno-gcse"
539: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
540: CFLAGS="$CFLAGS_1"
541: AC_MSG_RESULT($ac_nogcse)
542:
543: # Try if GCC understands -fno-strict-aliasing
544: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
545: CFLAGS_1="$CFLAGS"
546: CFLAGS="$CFLAGS -fno-strict-aliasing"
547: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
548: CFLAGS="$CFLAGS_1"
549: AC_MSG_RESULT($ac_nostrictaliasing)
550:
551: # Try if GCC understands -fno-crossjumping
552: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
553: CFLAGS_1="$CFLAGS"
554: CFLAGS="$CFLAGS -fno-crossjumping"
555: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
556: CFLAGS="$CFLAGS_1"
557: AC_MSG_RESULT($ac_nocrossjumping)
558:
559: # Try if GCC understands -fno-reorder-blocks
560: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
561: CFLAGS_1="$CFLAGS"
562: CFLAGS="$CFLAGS -fno-reorder-blocks"
563: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
564: CFLAGS="$CFLAGS_1"
565: AC_MSG_RESULT($ac_noreorder_blocks)
566:
567: # Try if GCC understands __attribute__((unused))
568: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
569: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
570: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
571: AC_MSG_RESULT($MAYBE_UNUSED)
572:
573: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
574: AC_SUBST(asm_fs)
575:
576: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
577: AC_SUBST(disasm_fs)
578:
579: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
580:
581: case "$host_os" in
582: *win32*)
583: # !!!FIXME!!! problems with cygwin and ';' as path separator
584: DIRSEP="\\\\"
585: PATHSEP=";"
586: #we want the builtins of command.com/cmd.exe and its
587: # handling of .com files.
588: #$COMSPEC contains the name of the Windows shell;
589: # the ./ is there, because the bash does not recognize
590: # absolute DOS filenames
591: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
592: ;;
593: *darwin*)
594: #Darwin uses some funny preprocessor by default; eliminate it:
595: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
596: CFLAGS="$CFLAGS -no-cpp-precomp"
597: DIRSEP="/"
598: PATHSEP=":"
599: DEFAULTSYSTEMPREFIX=""
600: ;;
601: *)
602: DIRSEP="/"
603: PATHSEP=":"
604: DEFAULTSYSTEMPREFIX=""
605: ;;
606: esac
607: AC_SUBST(DIRSEP)
608: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
609: AC_SUBST(PATHSEP)
610: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
611: AC_SUBST(DEFAULTSYSTEMPREFIX)
612: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
613:
614: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
615: #This magic incantation seems to be completely undocumented.
616: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
617:
618: dnl Now a little support for DOS/DJGCC
619: AC_SUBST(GFORTH_EXE)
620: GFORTH_EXE=""
621: AC_SUBST(GFORTHFAST_EXE)
622: GFORTHFAST_EXE=""
623: AC_SUBST(GFORTHITC_EXE)
624: GFORTHITC_EXE=""
625: AC_SUBST(GFORTHDITC_EXE)
626: GFORTHDITC_EXE=""
627:
628: AC_SUBST(FORTHSIZES)
629:
630: dnl if test "$PEEPHOLE" = "yes"
631: dnl then
632: dnl PEEPHOLEFLAG="true"
633: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
634: dnl else
635: dnl PEEPHOLEFLAG="false"
636: dnl fi
637: PEEPHOLEFLAG="true"
638: AC_SUBST(PEEPHOLEFLAG)
639:
640: dnl copy commands for systems that don't have links
641: AC_SUBST(LINK_KERNL)
642: LINK_KERNL=""
643:
644: #if test $host_os=dos
645: #then
646: # echo Configuring for DOS!!!
647: # MAKE_EXE="coff2exe gforth"
648: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
649: #fi
650:
651: dnl the following macro produces a warning with autoconf-2.1
652: AC_C_BIGENDIAN
653: AC_SUBST(KERNEL)
654: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
655: if test $ac_cv_c_bigendian = yes; then
656: bytesex=b
657: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
658: else
659: bytesex=l
660: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
661: fi
662:
663: #check how to do asm(".skip 16")
664: #echo "CFLAGS=$CFLAGS"
665: #echo "ac_link=$ac_link"
666: AC_MSG_CHECKING([if and how we can waste code space])
667: if test -z "$skipcode"; then
668: skipcode=no
669: CFLAGS_1="$CFLAGS"
670: CFLAGS="$CFLAGS $ENGINE_FLAGS"
671: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
672: do
673: AC_TRY_RUN(
674: [int foo(int,int,int);
675: main()
676: {
677: exit(foo(0,0,0)!=16);
678: }
679: int foo(int x, int y, int z)
680: {
681: static void *labels[]={&&label1, &&label2};
682: if (x) {
683: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
684: label1:
685: asm("$i"); /* or ".space 16" or somesuch */
686: label2: ;
687: }
688: {
689: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
690: return labels[1]-labels[0];
691: }
692: }]
693: ,skipcode=$i; break
694: ,,)
695: done
696: CFLAGS=$CFLAGS_1
697: fi
698: AC_MSG_RESULT($skipcode)
699: if test "$skipcode" = no
700: then
701: if test -z $no_dynamic_default; then
702: no_dynamic_default=1
703: AC_MSG_WARN(Disabling default dynamic native code generation)
704: fi
705: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
706: else
707: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
708: fi
709:
710: AC_MSG_CHECKING([if and how we can do comments in asm statements])
711: #the point here is to get asm statements that look different to
712: #gcc's "optimizer"
713: if test -z "$asmcomment"; then
714: asmcomment=no
715: CFLAGS_1="$CFLAGS"
716: CFLAGS="$CFLAGS $ENGINE_FLAGS"
717: for i in '"# "' '"! "' '"; "'; do
718: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
719: done
720: CFLAGS=$CFLAGS_1
721: fi
722: AC_MSG_RESULT($asmcomment)
723: if test "$asmcomment" != no
724: then
725: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
726: fi
727:
728: test "$no_dynamic_default" || no_dynamic_default=0
729: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
730:
731: dnl Checks for programs.
732: AC_PROG_LN_S
733: AC_PROG_INSTALL
734: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
735:
736: dnl Checks for library functions
737: dnl This check is just for making later checks link with libm.
738: dnl using sin here is no good idea since it is built-into gcc and typechecked
739: AC_CHECK_LIB(m,asin)
740: AC_CHECK_LIB(dl,dlopen)
741: dnl check for libffi 2.x
742: AC_CHECK_LIB(ffi,ffi_call)
743: if test $ac_cv_lib_ffi_ffi_call = yes
744: then
745: LIBFFIFLAG="true"
746: FFCALLFLAG="false"
747: OLDCALLFLAG="false"
748: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
749: else
750: dnl check for ffcall libraries
751: dnl unfortunately, these four calls are separated out into a library each.
752: AC_CHECK_LIB(avcall,__builtin_avcall)
753: AC_CHECK_LIB(callback,__vacall_r)
754: AC_CHECK_LIB(vacall,vacall)
755: AC_CHECK_LIB(trampoline,alloc_trampoline)
756: LIBFFIFLAG="false"
757: FFCALLFLAG="false"
758: OLDCALLFLAG="true"
759: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
760: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
761: fi
762: AC_SUBST(LIBFFIFLAG)
763: AC_SUBST(FFCALLFLAG)
764: AC_SUBST(OLDCALLFLAG)
765: if test "$host_os" != "nextstep3"
766: then
767: AC_FUNC_MEMCMP
768: fi
769: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
770: AC_FUNC_FSEEKO
771: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
772: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
773: AC_DECL_SYS_SIGLIST
774: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
775: AC_CHECK_FUNCS(expm1 log1p)
776: AC_REPLACE_FUNCS(rint ecvt)
777: dnl No check for select, because our replacement is no good under
778: dnl anything but DOS
779: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
780: AC_FUNC_FNMATCH
781: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
782: AC_CHECK_FUNCS(mmap sysconf getpagesize)
783: AM_PATH_LISPDIR
784:
785: kernel_fi=kernl${vwordsize}${bytesex}.fi
786: include_fi=kernl${wordsize}${bytesex}${EC}.fi
787: AC_SUBST(kernel_fi)
788: AC_SUBST(include_fi)
789:
790: #this breaks bindists
791: #dnl replace srource directory by absolute value
792: #if test $srcdir = "."; then srcdir=`pwd`
793: #fi
794:
795: AC_SUBST(machine)
796: AC_CONFIG_FILES([
797: Makefile
798: Makedist
799: gforthmi
800: vmgen
801: machpc.fs
802: envos.fs
803: engine/Makefile
804: doc/version.texi
805: build-ec ])
806: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
807: chmod +x gforthmi
808: chmod +x vmgen
809: chmod +x build-ec
810: test -d kernel||mkdir kernel]],[[]])
811: AC_OUTPUT
812:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>