File:  [gforth] / gforth / configure.in
Revision 1.182: download - view: text, annotated - select for diffs
Mon Apr 9 22:36:01 2007 UTC (16 years, 11 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Some stuff to get closer to run Gforth on NXT

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.9-20070401],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="April 09, 2006"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: 	AC_HELP_STRING([--enable-force-reg],
   38: 		        [ Use explicit register declarations if they appear in
   39: 			  the machine.h file. This can cause a good speedup,
   40: 			  but also incorrect code with some gcc versions on
   41: 			  some processors (default disabled).]),
   42: 	,enable_force_reg=no)
   43: test "$enable_force_reg" = "no"||
   44:   AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
   45: 
   46: AC_ARG_ENABLE(force-ll,
   47: 	AC_HELP_STRING([--enable-force-ll],
   48: 		       [  Use explicit long long declarations if they appear in
   49: 			  the machine.h file. This can cause a good speedup,
   50: 			  but also incorrect code with some gcc versions on
   51: 			  some processors (default disabled).]),
   52: 	,enable_force_ll=no)
   53: test "$enable_force_ll" = "no"||
   54:   AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
   55: 
   56: AC_ARG_ENABLE(force-cdiv,
   57: 	AC_HELP_STRING([--enable-force-cdiv],
   58: 		       [  Use the native C division - symmetric - instead of
   59: 		          floored division (default disabled).]),
   60: 	,enable_force_cdiv=no)
   61: test "$enable_force_cdiv" = "no"||
   62:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   63: 
   64: AC_SUBST(PROFEXES)
   65: AC_SUBST(PROFOBJS)
   66: AC_ARG_ENABLE(prof,
   67: 	AC_HELP_STRING([--enable-prof],
   68: 			[ Build gforth-prof, which outputs frequently occuring
   69:                           sequences of primitives.]),
   70: 	,enable_prof=no)
   71: if test "$enable_prof" = "no"; then
   72:   PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
   73: fi
   74: 
   75: AC_ARG_WITH(debug,
   76: [  --with-debug		  specifies option -g to compile with debug info
   77:   --without-debug	  omits the -g switch and creates smaller images on
   78: 			  machines where "strip" has problems with gcc style
   79: 			  debugging informations.],
   80: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   81: 
   82: dnl PEEPHOLE="yes"
   83: dnl AC_ARG_WITH(peephole,
   84: dnl [  --with-peephole	Enable peephole optimization (default)
   85: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   86: dnl 			but slower images.],
   87: dnl PEEPHOLE="$withval")
   88: 
   89: AC_ARG_WITH(ec,
   90: 	AC_HELP_STRING([--with-ec=<arch>],
   91: 			[  Build gforth for systems without OS.]),
   92: [if test "$withval" = "no"; then
   93:   echo "defining hosted system"
   94:   EC_MODE="false"
   95:   EC=""
   96:   engine2="engine2.o"
   97:   engine_fast2="engine-fast2.o"
   98:   no_dynamic=""
   99:   image_i=""
  100:   signals_o="io.o signals.o"
  101: else
  102:   echo "defining standalone system (${withval})"
  103:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
  104:   EC_MODE="true"
  105:   EC="-ec"
  106:   engine2=""
  107:   engine_fast2=""
  108:   no_dynamic="-DNO_DYNAMIC"
  109:   image_i="image.i"
  110:   if test "$withval" != "yes"; then
  111:     signals_o="io-${withval}.o"
  112:   else
  113:     signals_o="io.o"
  114:   fi
  115: fi])
  116: 
  117: #variables mentioned in INSTALL
  118: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
  119: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  120: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  121: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  122: 
  123: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  124: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  125: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  126: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  127: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  128: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  129: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  130: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  131: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  132: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  133: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  134: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  135: AC_ARG_VAR(asmcomment, [assembler comment start string])
  136: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  137: 
  138: #set up feature test macros, so the tests get them right:
  139: # turn on all POSIX, SUSv3, and GNU features if available
  140: AC_GNU_SOURCE
  141: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  142: 
  143: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  144: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  145: dnl but not for _XOPEN_SOURCE)
  146: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  147: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  148: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  149: # turn on large file support with 64-bit off_t where available
  150: AC_SYS_LARGEFILE
  151: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  152: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  153: 
  154: #currently we force direct threading this way.  Eventually we should
  155: #setup in the arch and engine files right
  156: 
  157: AC_PROG_CC
  158: 
  159: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  160: 
  161: AC_SUBST(CC)
  162: AC_SUBST(DEBUGFLAG)
  163: AC_SUBST(EC)
  164: AC_SUBST(EC_MODE)
  165: AC_SUBST(engine2)
  166: AC_SUBST(engine_fast2)
  167: AC_SUBST(no_dynamic)
  168: AC_SUBST(image_i)
  169: AC_SUBST(signals_o)
  170: 
  171: #this is used to disable some (not generally essential) part of the
  172: #Makefile that some makes don't grok.  It would be better to test for
  173: #this specific Makefile feature than the make version.
  174: AC_MSG_CHECKING(make type)
  175: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  176: GNUMAKE='#'
  177: test "$make_type" = "GNU Make" && GNUMAKE=''
  178: AC_MSG_RESULT($make_type)
  179: AC_SUBST(GNUMAKE)
  180: 
  181: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  182: OLDLDFLAGS=$LDFLAGS
  183: LDFLAGS="$LDFLAGS -export-dynamic"
  184: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  185: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  186: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  187: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  188: AC_MSG_RESULT($ac_export_dynamic)
  189: 
  190: #terminology is a bit unusual here: The host is the system on which
  191: #gforth will run; the system on which configure will run is the `build'
  192: AC_CANONICAL_HOST
  193: case "$host_cpu" in
  194: 	arm*)
  195: 		machine=arm
  196: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  197: 		if test -z $arm_cacheflush; then
  198: 		    no_dynamic_default=1
  199:                     arm_cacheflush=arch/arm/cacheflush0
  200: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  201: 		fi
  202:                 AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
  203:                 AC_LIBOBJ(../$arm_cacheflush)
  204:                 #longer skipcodes lead to problems on ARM, and it uses
  205:                 #only 4-byte alignment anyway
  206: 		test "$skipcode" || skipcode="nop"
  207: 		;;
  208: 	hppa*)
  209: 		machine=hppa
  210: 		$srcdir/mkinstalldirs arch/hppa
  211: 		AC_LIBOBJ(../arch/hppa/cache)
  212: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  213: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  214: 		LIBS="$LIBS -L/lib/pa1.1/"
  215: 		;;
  216: 	sparc*)
  217: 		machine=sparc
  218: 		;;
  219: 	i386)
  220: 		machine=386
  221: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  222: 		;;
  223: 	i486)
  224: 		machine=386
  225: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  226: 		;;
  227: 	i*86)
  228: 		machine=386
  229: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  230: 		CFLAGS_1="$CFLAGS"
  231: 		CFLAGS="$CFLAGS -march=pentium"
  232: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  233: 		;;
  234: 	x86_64)
  235: 		machine=amd64
  236: 		;;
  237: 	ia64*)
  238: 		machine=ia64
  239: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  240: 		test "$skipcode" || skipcode="nop.i 0"
  241: 		#".skip 16" passes the test below,
  242: 		# but gives an assembler error in engine
  243: 		;;
  244:         m68k)
  245: 		machine=m68k
  246: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  247: 		if test "$host_os" = "nextstep3"
  248: 		then
  249: 			AC_LIBOBJ(termios)
  250: 		fi
  251: 		;;
  252: 	mips*)
  253: 		machine=mips
  254: 		#dynamic native code has the following problems on MIPS:
  255: 		#
  256: 		#1) J/JAL seems relocatable, but is are only
  257: 		#relocatable within a 256MB-segment.  While we try to
  258: 		#get the linker to arrange this, there is no guarantee
  259: 		#that this will succeed (and if the user uses a lot of
  260: 		#memory, it is likely to fail).
  261: 		#
  262: 		#2) The way we generate dynamic native code may
  263: 		#violate MIPS architectural restrictions (in
  264: 		#particular, the delay slots of LW, MFLO, etc.)
  265: 		#
  266: 		#Therefore we disable dynamic native code by default:
  267: 		if test -z $no_dynamic_default; then
  268: 		    no_dynamic_default=1
  269: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  270: 		fi
  271: 		;;
  272: 	alpha*)
  273: 		machine=alpha
  274: 		#full IEEE FP support for more uniformity across platforms:
  275: 		CFLAGS="$CFLAGS -mieee"
  276: 		;;
  277: 	power*|rs6000)
  278: 		machine=power
  279: 		$srcdir/mkinstalldirs arch/power
  280: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  281: 		#long long is broken on (at least) gcc-2.95.* for PPC
  282: 		test x$ac_cv_sizeof_long_long = x && 
  283: 		($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
  284: 		ac_cv_sizeof_long_long=0
  285: 		;;
  286: 	*)
  287: 		AC_MSG_WARN([Using a generic machine description])
  288: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  289: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  290: 		machine=generic
  291: 		#I-cache flushing would be needed for dynamic code generation
  292: 		if test -z $no_dynamic_default; then
  293: 		    no_dynamic_default=1
  294: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  295: 		fi
  296: esac
  297: AC_SUBST(host)
  298: 
  299: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  300: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  301: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  302: 
  303: test x$GCC_PR15242_WORKAROUND = x ||
  304: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  305:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  306: 
  307: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
  308: dnl generation on gccs affected by PR15242])
  309: 
  310: 
  311: if test "${enable_force_ll+set}" = set; then
  312:    ac_includes_default="$ac_includes_default
  313: #include \"arch/generic/128bit.h\""
  314: fi
  315: 
  316: dnl the following macro produces a warning with autoconf-2.1
  317: AC_CHECK_SIZEOF(char *)
  318: case "$ac_cv_sizeof_char_p" in
  319:   2)
  320:     wordsize=16
  321:     ;;
  322:   4)
  323:     wordsize=32
  324:     ;;
  325:   8)
  326:     wordsize=64
  327:     ;;
  328: esac
  329: 
  330: AC_CHECK_SIZEOF(char)
  331: AC_CHECK_SIZEOF(short)
  332: AC_CHECK_SIZEOF(int)
  333: AC_CHECK_SIZEOF(long)
  334: AC_CHECK_SIZEOF(long long)
  335: AC_CHECK_SIZEOF(intptr_t)
  336: AC_CHECK_SIZEOF(int128_t)
  337: AC_CHECK_SIZEOF(uint128_t)
  338: 
  339: AC_MSG_CHECKING([for a C type for cells])
  340: ac_cv_int_type_cell=none
  341: case "$ac_cv_sizeof_char_p" in
  342:   $ac_cv_sizeof_int)
  343:     ac_cv_int_type_cell=int
  344:     ;;
  345:   $ac_cv_sizeof_short)
  346:     ac_cv_int_type_cell=short
  347:     ;;
  348:   $ac_cv_sizeof_char)
  349:     ac_cv_int_type_cell=char
  350:     ;;
  351:   $ac_cv_sizeof_long)
  352:     ac_cv_int_type_cell=long
  353:     ;;
  354:   $ac_cv_sizeof_long_long)
  355:     ac_cv_int_type_cell="long long"
  356:     ;;
  357:   $ac_cv_sizeof_intptr_t)
  358:     ac_cv_int_type_cell="intptr_t"
  359:     ;;
  360:   $ac_cv_sizeof_int128_t)
  361:     ac_cv_int_type_cell="int128_t"
  362:     ;;
  363: esac
  364: AC_MSG_RESULT($ac_cv_int_type_cell)
  365: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  366: 
  367: AC_MSG_CHECKING([for a C type for wydes])
  368: ac_cv_wyde_type_cell=none
  369: case 2 in
  370:   $ac_cv_sizeof_int)
  371:     ac_cv_wyde_type_cell=int
  372:     ;;
  373:   $ac_cv_sizeof_short)
  374:     ac_cv_wyde_type_cell=short
  375:     ;;
  376:   $ac_cv_sizeof_char)
  377:     ac_cv_wyde_type_cell=char
  378:     ;;
  379:   $ac_cv_sizeof_long)
  380:     ac_cv_wyde_type_cell=long
  381:     ;;
  382:   $ac_cv_sizeof_long_long)
  383:     ac_cv_wyde_type_cell="long long"
  384:     ;;
  385:   $ac_cv_sizeof_intptr_t)
  386:     ac_cv_wyde_type_cell="intptr_t"
  387:     ;;
  388:   $ac_cv_sizeof_int128_t)
  389:     ac_cv_wyde_type_cell="int128_t"
  390:     ;;
  391: esac
  392: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  393: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  394: 
  395: AC_MSG_CHECKING([for a C type for tetrabytes])
  396: ac_cv_tetrabyte_type_cell=none
  397: case 4 in
  398:   $ac_cv_sizeof_int)
  399:     ac_cv_tetrabyte_type_cell=int
  400:     ;;
  401:   $ac_cv_sizeof_short)
  402:     ac_cv_tetrabyte_type_cell=short
  403:     ;;
  404:   $ac_cv_sizeof_char)
  405:     ac_cv_tetrabyte_type_cell=char
  406:     ;;
  407:   $ac_cv_sizeof_long)
  408:     ac_cv_tetrabyte_type_cell=long
  409:     ;;
  410:   $ac_cv_sizeof_long_long)
  411:     ac_cv_tetrabyte_type_cell="long long"
  412:     ;;
  413:   $ac_cv_sizeof_intptr_t)
  414:     ac_cv_tetrabyte_type_cell="intptr_t"
  415:     ;;
  416:   $ac_cv_sizeof_int128_t)
  417:     ac_cv_tetrabyte_type_cell="int128_t"
  418:     ;;
  419: esac
  420: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  421: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  422: 
  423: AC_MSG_CHECKING([for a C type for double-cells])
  424: ac_cv_int_type_double_cell=none
  425: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  426:   $ac_cv_sizeof_short)
  427:     ac_cv_int_type_double_cell=short
  428:     ;;
  429:   $ac_cv_sizeof_int)
  430:     ac_cv_int_type_double_cell=int
  431:     ;;
  432:   $ac_cv_sizeof_long)
  433:     ac_cv_int_type_double_cell=long
  434:     ;;
  435:   $ac_cv_sizeof_long_long)
  436:     ac_cv_int_type_double_cell="long long"
  437:     ;;
  438:   $ac_cv_sizeof_intptr_t)
  439:     ac_cv_int_type_double_cell="intptr_t"
  440:     ;;
  441:   $ac_cv_sizeof_int128_t)
  442:     ac_cv_int_type_double_cell="int128_t"
  443:     ;;
  444: esac
  445: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  446: 
  447: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  448: ac_cv_int_type_double_ucell=none
  449: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  450:   $ac_cv_sizeof_short)
  451:     ac_cv_int_type_double_ucell="unsigned short"
  452:     ;;
  453:   $ac_cv_sizeof_int)
  454:     ac_cv_int_type_double_ucell="unsigned int"
  455:     ;;
  456:   $ac_cv_sizeof_long)
  457:     ac_cv_int_type_double_ucell="unsigned long"
  458:     ;;
  459:   $ac_cv_sizeof_long_long)
  460:     ac_cv_int_type_double_ucell="unsigned long long"
  461:     ;;
  462:   $ac_cv_sizeof_intptr_t)
  463:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  464:     ;;
  465:   $ac_cv_sizeof_uint128_t)
  466:     ac_cv_int_type_double_ucell="uint128_t"
  467:     ;;
  468: esac
  469: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  470: 
  471: if test "$ac_cv_int_type_double_cell" = none || \
  472:    test "$ac_cv_int_type_double_ucell" = none
  473: then
  474: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  475: 	AC_LIBOBJ(dblsub)
  476: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  477: else
  478: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  479: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  480: fi
  481: 
  482: AC_TYPE_OFF_T
  483: AC_CHECK_SIZEOF(off_t)
  484: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  485: ac_small_off_t=$?
  486: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  487: 
  488: ENGINE_FLAGS=
  489: AC_SUBST(ENGINE_FLAGS)
  490: 
  491: # Try if GCC understands -fno-gcse
  492: 
  493: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  494: CFLAGS_1="$CFLAGS"
  495: CFLAGS="$CFLAGS -fno-gcse"
  496: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  497: CFLAGS="$CFLAGS_1"
  498: AC_MSG_RESULT($ac_nogcse)
  499: 
  500: # Try if GCC understands -fno-strict-aliasing
  501: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  502: CFLAGS_1="$CFLAGS"
  503: CFLAGS="$CFLAGS -fno-strict-aliasing"
  504: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  505: CFLAGS="$CFLAGS_1"
  506: AC_MSG_RESULT($ac_nostrictaliasing)
  507: 
  508: # Try if GCC understands -fno-crossjumping
  509: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  510: CFLAGS_1="$CFLAGS"
  511: CFLAGS="$CFLAGS -fno-crossjumping"
  512: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  513: CFLAGS="$CFLAGS_1"
  514: AC_MSG_RESULT($ac_nocrossjumping)
  515: 
  516: # Try if GCC understands -fno-reorder-blocks
  517: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  518: CFLAGS_1="$CFLAGS"
  519: CFLAGS="$CFLAGS -fno-reorder-blocks"
  520: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  521: CFLAGS="$CFLAGS_1"
  522: AC_MSG_RESULT($ac_noreorder_blocks)
  523: 
  524: # Try if GCC understands __attribute__((unused))
  525: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  526: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  527: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  528: AC_MSG_RESULT($MAYBE_UNUSED)
  529: 
  530: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  531: AC_SUBST(asm_fs)
  532: 
  533: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  534: AC_SUBST(disasm_fs)
  535: 
  536: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  537: 
  538: case "$host_os" in
  539: 	*win32*)
  540: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  541: 		DIRSEP="\\\\"
  542: 		PATHSEP=";"
  543: 		#we want the builtins of command.com/cmd.exe and its
  544: 		# handling of .com files.
  545: 		#$COMSPEC contains the name of the Windows shell;
  546: 		# the ./ is there, because the bash does not recognize
  547: 		# absolute DOS filenames
  548: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  549: 		;;
  550: 	*darwin*)
  551: 		#Darwin uses some funny preprocessor by default; eliminate it:
  552: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  553: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  554: 		DIRSEP="/"
  555: 		PATHSEP=":"
  556: 		DEFAULTSYSTEMPREFIX=""
  557: 		;;
  558: 	*)
  559: 		DIRSEP="/"
  560: 		PATHSEP=":"
  561: 		DEFAULTSYSTEMPREFIX=""
  562: 		;;
  563: esac
  564: AC_SUBST(DIRSEP)
  565: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  566: AC_SUBST(PATHSEP)
  567: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  568: AC_SUBST(DEFAULTSYSTEMPREFIX)
  569: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  570: 
  571: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  572: #This magic incantation  seems to be completely undocumented.
  573: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  574: 
  575: dnl Now a little support for DOS/DJGCC
  576: AC_SUBST(GFORTH_EXE)
  577: GFORTH_EXE=""
  578: AC_SUBST(GFORTHFAST_EXE)
  579: GFORTHFAST_EXE=""
  580: AC_SUBST(GFORTHITC_EXE)
  581: GFORTHITC_EXE=""
  582: AC_SUBST(GFORTHDITC_EXE)
  583: GFORTHDITC_EXE=""
  584: 
  585: AC_SUBST(FORTHSIZES)
  586: 
  587: dnl if test "$PEEPHOLE" = "yes"
  588: dnl then
  589: dnl    PEEPHOLEFLAG="true"
  590: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  591: dnl else
  592: dnl    PEEPHOLEFLAG="false"
  593: dnl fi
  594: PEEPHOLEFLAG="true"
  595: AC_SUBST(PEEPHOLEFLAG)
  596: 
  597: dnl copy commands for systems that don't have links
  598: AC_SUBST(LINK_KERNL)
  599: LINK_KERNL=""
  600: 
  601: #if test $host_os=dos
  602: #then
  603: #  echo Configuring for DOS!!!
  604: #  MAKE_EXE="coff2exe gforth"
  605: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  606: #fi
  607: 
  608: dnl the following macro produces a warning with autoconf-2.1
  609: AC_C_BIGENDIAN
  610: AC_SUBST(KERNEL)
  611: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  612: if test $ac_cv_c_bigendian = yes; then
  613:   bytesex=b
  614:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  615: else
  616:   bytesex=l
  617:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  618: fi
  619: 
  620: #check how to do asm(".skip 16")
  621: #echo "CFLAGS=$CFLAGS"
  622: #echo "ac_link=$ac_link"
  623: AC_MSG_CHECKING([if and how we can waste code space])
  624: if test -z "$skipcode"; then
  625:     skipcode=no
  626:     CFLAGS_1="$CFLAGS"
  627:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  628:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  629:     do
  630: 	AC_TRY_RUN(
  631: [int foo(int,int,int);
  632: main()
  633: {
  634:   exit(foo(0,0,0)!=16);
  635: }
  636: int foo(int x, int y, int z)
  637: {
  638:   static void *labels[]={&&label1, &&label2};
  639:   if (x) {
  640:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  641:   label1:
  642:     asm("$i"); /* or ".space 16" or somesuch */
  643:   label2: ;
  644:   }
  645:   {
  646:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  647:   return labels[1]-labels[0];
  648:   }
  649: }]
  650: 	,skipcode=$i; break
  651: 	,,)
  652:     done
  653:     CFLAGS=$CFLAGS_1
  654: fi
  655: AC_MSG_RESULT($skipcode)
  656: if test "$skipcode" = no
  657: then 
  658:     if test -z $no_dynamic_default; then
  659: 	no_dynamic_default=1
  660: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  661:     fi
  662:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  663: else
  664:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  665: fi
  666: 
  667: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  668: #the point here is to get asm statements that look different to
  669: #gcc's "optimizer"
  670: if test -z "$asmcomment"; then
  671:     asmcomment=no
  672:     CFLAGS_1="$CFLAGS"
  673:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  674:     for i in '"# "' '"! "' '"; "'; do
  675: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  676:     done
  677:     CFLAGS=$CFLAGS_1
  678: fi
  679: AC_MSG_RESULT($asmcomment)
  680: if test "$asmcomment" != no
  681: then 
  682:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  683: fi
  684: 
  685: test "$no_dynamic_default" || no_dynamic_default=0
  686: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  687: 
  688: dnl Checks for programs.
  689: AC_PROG_LN_S
  690: AC_PROG_INSTALL
  691: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  692: 
  693: dnl Checks for library functions
  694: dnl This check is just for making later checks link with libm.
  695: dnl using sin here is no good idea since it is built-into gcc and typechecked
  696: AC_CHECK_LIB(m,asin)
  697: AC_CHECK_LIB(dl,dlopen)
  698: dnl check for libffi 2.x
  699: AC_CHECK_LIB(ffi,ffi_call)
  700: if test $ac_cv_lib_ffi_ffi_call = yes
  701: then
  702: LIBFFIFLAG="true"
  703: FFCALLFLAG="false"
  704: OLDCALLFLAG="false"
  705: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
  706: else
  707: dnl check for ffcall libraries
  708: dnl unfortunately, these four calls are separated out into a library each.
  709: AC_CHECK_LIB(avcall,__builtin_avcall)
  710: AC_CHECK_LIB(callback,__vacall_r)
  711: AC_CHECK_LIB(vacall,vacall)
  712: AC_CHECK_LIB(trampoline,alloc_trampoline)
  713: LIBFFIFLAG="false"
  714: FFCALLFLAG="false"
  715: OLDCALLFLAG="true"
  716: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  717: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  718: fi
  719: AC_SUBST(LIBFFIFLAG)
  720: AC_SUBST(FFCALLFLAG)
  721: AC_SUBST(OLDCALLFLAG)
  722: if test "$host_os" != "nextstep3"
  723: then
  724: 	AC_FUNC_MEMCMP
  725: fi
  726: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  727: AC_FUNC_FSEEKO
  728: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  729: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  730: AC_DECL_SYS_SIGLIST
  731: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  732: AC_CHECK_FUNCS(expm1 log1p)
  733: AC_REPLACE_FUNCS(rint ecvt)
  734: dnl No check for select, because our replacement is no good under
  735: dnl anything but DOS
  736: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  737: AC_FUNC_FNMATCH
  738: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  739: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  740: AM_PATH_LISPDIR
  741: 
  742: kernel_fi=kernl${wordsize}${bytesex}.fi
  743: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  744: AC_SUBST(kernel_fi)
  745: AC_SUBST(include_fi)
  746: 
  747: #this breaks bindists
  748: #dnl replace srource directory by absolute value
  749: #if test $srcdir = "."; then srcdir=`pwd` 
  750: #fi
  751: 
  752: AC_SUBST(machine)
  753: AC_CONFIG_FILES([
  754: Makefile
  755: Makedist
  756: gforthmi
  757: vmgen
  758: machpc.fs
  759: envos.fs
  760: engine/Makefile
  761: doc/version.texi
  762: build-ec ])
  763: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  764: chmod +x gforthmi
  765: chmod +x vmgen
  766: chmod +x build-ec
  767: test -d kernel||mkdir kernel]],[[]])
  768: AC_OUTPUT
  769: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>