1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20060527],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="April 09, 2006"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(force-cdiv,
57: AC_HELP_STRING([--enable-force-cdiv],
58: [ Use the native C division - symmetric - instead of
59: floored division (default disabled).]),
60: ,enable_force_cdiv=no)
61: test "$enable_force_cdiv" = "no"||
62: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
63:
64: AC_SUBST(PROFEXES)
65: AC_SUBST(PROFOBJS)
66: AC_ARG_ENABLE(prof,
67: AC_HELP_STRING([--enable-prof],
68: [ Build gforth-prof, which outputs frequently occuring
69: sequences of primitives.]),
70: ,enable_prof=no)
71: if test "$enable_prof" = "no"; then
72: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
73: fi
74:
75: AC_ARG_WITH(debug,
76: [ --with-debug specifies option -g to compile with debug info
77: --without-debug omits the -g switch and creates smaller images on
78: machines where "strip" has problems with gcc style
79: debugging informations.],
80: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
81:
82: dnl PEEPHOLE="yes"
83: dnl AC_ARG_WITH(peephole,
84: dnl [ --with-peephole Enable peephole optimization (default)
85: dnl --without-peephole disables peephole optimization. Creates smaller,
86: dnl but slower images.],
87: dnl PEEPHOLE="$withval")
88:
89: AC_ARG_ENABLE(ec,
90: AC_HELP_STRING([--enable-ec],
91: [ Build gforth for systems without OS.]),
92: ,enable_ec=no)
93: if test "$enable_ec" = "yes"; then
94: echo "defining standalone system"
95: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
96: EC_MODE="true"
97: else
98: echo "defining hosted system"
99: EC_MODE="false"
100: fi
101:
102: #variables mentioned in INSTALL
103: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
104: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
105: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
106: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
107:
108: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
109: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
110: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
111: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
112: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
113: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
114: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
115: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
116: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
117: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
118: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
119: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
120: AC_ARG_VAR(asmcomment, [assembler comment start string])
121: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
122:
123: #set up feature test macros, so the tests get them right:
124: # turn on all POSIX, SUSv3, and GNU features if available
125: AC_GNU_SOURCE
126: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
127:
128: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
129: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
130: dnl but not for _XOPEN_SOURCE)
131: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
132: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
133: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
134: # turn on large file support with 64-bit off_t where available
135: AC_SYS_LARGEFILE
136: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
137: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
138:
139: #currently we force direct threading this way. Eventually we should
140: #setup in the arch and engine files right
141:
142: AC_PROG_CC
143:
144: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
145:
146: AC_SUBST(CC)
147: AC_SUBST(DEBUGFLAG)
148: AC_SUBST(EC_MODE)
149:
150: #this is used to disable some (not generally essential) part of the
151: #Makefile that some makes don't grok. It would be better to test for
152: #this specific Makefile feature than the make version.
153: AC_MSG_CHECKING(make type)
154: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
155: GNUMAKE='#'
156: test "$make_type" = "GNU Make" && GNUMAKE=''
157: AC_MSG_RESULT($make_type)
158: AC_SUBST(GNUMAKE)
159:
160: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
161: OLDLDFLAGS=$LDFLAGS
162: LDFLAGS="$LDFLAGS -export-dynamic"
163: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
164: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
165: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
166: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
167: AC_MSG_RESULT($ac_export_dynamic)
168:
169: #terminology is a bit unusual here: The host is the system on which
170: #gforth will run; the system on which configure will run is the `build'
171: AC_CANONICAL_HOST
172: case "$host_cpu" in
173: arm*)
174: machine=arm
175: CFLAGS="$CFLAGS -fomit-frame-pointer"
176: if test -z $arm_cacheflush; then
177: no_dynamic_default=1
178: arm_cacheflush=arch/arm/cacheflush0
179: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
180: fi
181: AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
182: AC_LIBOBJ(../$arm_cacheflush)
183: ;;
184: hppa*)
185: machine=hppa
186: $srcdir/mkinstalldirs arch/hppa
187: AC_LIBOBJ(../arch/hppa/cache)
188: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
189: LDFLAGS="$LDFLAGS -Xlinker -N"
190: LIBS="$LIBS -L/lib/pa1.1/"
191: ;;
192: sparc*)
193: machine=sparc
194: ;;
195: i386)
196: machine=386
197: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
198: ;;
199: i486)
200: machine=386
201: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
202: ;;
203: i*86)
204: machine=386
205: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
206: CFLAGS_1="$CFLAGS"
207: CFLAGS="$CFLAGS -march=pentium"
208: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
209: ;;
210: x86_64)
211: machine=amd64
212: ;;
213: ia64*)
214: machine=ia64
215: AC_LIBOBJ(../arch/ia64/flush_icache_block)
216: test "$skipcode" || skipcode="nop.i 0"
217: #".skip 16" passes the test below,
218: # but gives an assembler error in engine
219: ;;
220: m68k)
221: machine=m68k
222: CFLAGS="$CFLAGS -fomit-frame-pointer"
223: if test "$host_os" = "nextstep3"
224: then
225: AC_LIBOBJ(termios)
226: fi
227: ;;
228: mips*)
229: machine=mips
230: #dynamic native code has the following problems on MIPS:
231: #
232: #1) J/JAL seems relocatable, but is are only
233: #relocatable within a 256MB-segment. While we try to
234: #get the linker to arrange this, there is no guarantee
235: #that this will succeed (and if the user uses a lot of
236: #memory, it is likely to fail).
237: #
238: #2) The way we generate dynamic native code may
239: #violate MIPS architectural restrictions (in
240: #particular, the delay slots of LW, MFLO, etc.)
241: #
242: #Therefore we disable dynamic native code by default:
243: if test -z $no_dynamic_default; then
244: no_dynamic_default=1
245: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
246: fi
247: ;;
248: alpha*)
249: machine=alpha
250: #full IEEE FP support for more uniformity across platforms:
251: CFLAGS="$CFLAGS -mieee"
252: ;;
253: power*|rs6000)
254: machine=power
255: $srcdir/mkinstalldirs arch/power
256: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
257: #long long is broken on (at least) gcc-2.95.* for PPC
258: test x$ac_cv_sizeof_long_long = x &&
259: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
260: ac_cv_sizeof_long_long=0
261: ;;
262: *)
263: AC_MSG_WARN([Using a generic machine description])
264: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
265: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
266: machine=generic
267: #I-cache flushing would be needed for dynamic code generation
268: if test -z $no_dynamic_default; then
269: no_dynamic_default=1
270: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
271: fi
272: esac
273: AC_SUBST(host)
274:
275: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
276: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
277: [number of registers in the default stack cache state for gforth-fast and gforth-native])
278:
279: test x$GCC_PR15242_WORKAROUND = x ||
280: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
281: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
282:
283: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
284: dnl generation on gccs affected by PR15242])
285:
286:
287: if test "${enable_force_ll+set}" = set; then
288: ac_includes_default="$ac_includes_default
289: #include \"arch/generic/128bit.h\""
290: fi
291:
292: dnl the following macro produces a warning with autoconf-2.1
293: AC_CHECK_SIZEOF(char *)
294: case "$ac_cv_sizeof_char_p" in
295: 2)
296: wordsize=16
297: ;;
298: 4)
299: wordsize=32
300: ;;
301: 8)
302: wordsize=64
303: ;;
304: esac
305:
306: AC_CHECK_SIZEOF(char)
307: AC_CHECK_SIZEOF(short)
308: AC_CHECK_SIZEOF(int)
309: AC_CHECK_SIZEOF(long)
310: AC_CHECK_SIZEOF(long long)
311: AC_CHECK_SIZEOF(intptr_t)
312: AC_CHECK_SIZEOF(int128_t)
313: AC_CHECK_SIZEOF(uint128_t)
314:
315: AC_MSG_CHECKING([for a C type for cells])
316: ac_cv_int_type_cell=none
317: case "$ac_cv_sizeof_char_p" in
318: $ac_cv_sizeof_int)
319: ac_cv_int_type_cell=int
320: ;;
321: $ac_cv_sizeof_short)
322: ac_cv_int_type_cell=short
323: ;;
324: $ac_cv_sizeof_char)
325: ac_cv_int_type_cell=char
326: ;;
327: $ac_cv_sizeof_long)
328: ac_cv_int_type_cell=long
329: ;;
330: $ac_cv_sizeof_long_long)
331: ac_cv_int_type_cell="long long"
332: ;;
333: $ac_cv_sizeof_intptr_t)
334: ac_cv_int_type_cell="intptr_t"
335: ;;
336: $ac_cv_sizeof_int128_t)
337: ac_cv_int_type_cell="int128_t"
338: ;;
339: esac
340: AC_MSG_RESULT($ac_cv_int_type_cell)
341: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
342:
343: AC_MSG_CHECKING([for a C type for wydes])
344: ac_cv_wyde_type_cell=none
345: case 2 in
346: $ac_cv_sizeof_int)
347: ac_cv_wyde_type_cell=int
348: ;;
349: $ac_cv_sizeof_short)
350: ac_cv_wyde_type_cell=short
351: ;;
352: $ac_cv_sizeof_char)
353: ac_cv_wyde_type_cell=char
354: ;;
355: $ac_cv_sizeof_long)
356: ac_cv_wyde_type_cell=long
357: ;;
358: $ac_cv_sizeof_long_long)
359: ac_cv_wyde_type_cell="long long"
360: ;;
361: $ac_cv_sizeof_intptr_t)
362: ac_cv_wyde_type_cell="intptr_t"
363: ;;
364: $ac_cv_sizeof_int128_t)
365: ac_cv_wyde_type_cell="int128_t"
366: ;;
367: esac
368: AC_MSG_RESULT($ac_cv_wyde_type_cell)
369: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
370:
371: AC_MSG_CHECKING([for a C type for tetrabytes])
372: ac_cv_tetrabyte_type_cell=none
373: case 4 in
374: $ac_cv_sizeof_int)
375: ac_cv_tetrabyte_type_cell=int
376: ;;
377: $ac_cv_sizeof_short)
378: ac_cv_tetrabyte_type_cell=short
379: ;;
380: $ac_cv_sizeof_char)
381: ac_cv_tetrabyte_type_cell=char
382: ;;
383: $ac_cv_sizeof_long)
384: ac_cv_tetrabyte_type_cell=long
385: ;;
386: $ac_cv_sizeof_long_long)
387: ac_cv_tetrabyte_type_cell="long long"
388: ;;
389: $ac_cv_sizeof_intptr_t)
390: ac_cv_tetrabyte_type_cell="intptr_t"
391: ;;
392: $ac_cv_sizeof_int128_t)
393: ac_cv_tetrabyte_type_cell="int128_t"
394: ;;
395: esac
396: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
397: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
398:
399: AC_MSG_CHECKING([for a C type for double-cells])
400: ac_cv_int_type_double_cell=none
401: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
402: $ac_cv_sizeof_short)
403: ac_cv_int_type_double_cell=short
404: ;;
405: $ac_cv_sizeof_int)
406: ac_cv_int_type_double_cell=int
407: ;;
408: $ac_cv_sizeof_long)
409: ac_cv_int_type_double_cell=long
410: ;;
411: $ac_cv_sizeof_long_long)
412: ac_cv_int_type_double_cell="long long"
413: ;;
414: $ac_cv_sizeof_intptr_t)
415: ac_cv_int_type_double_cell="intptr_t"
416: ;;
417: $ac_cv_sizeof_int128_t)
418: ac_cv_int_type_double_cell="int128_t"
419: ;;
420: esac
421: AC_MSG_RESULT($ac_cv_int_type_double_cell)
422:
423: AC_MSG_CHECKING([for a C type for unsigned double-cells])
424: ac_cv_int_type_double_ucell=none
425: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
426: $ac_cv_sizeof_short)
427: ac_cv_int_type_double_ucell="unsigned short"
428: ;;
429: $ac_cv_sizeof_int)
430: ac_cv_int_type_double_ucell="unsigned int"
431: ;;
432: $ac_cv_sizeof_long)
433: ac_cv_int_type_double_ucell="unsigned long"
434: ;;
435: $ac_cv_sizeof_long_long)
436: ac_cv_int_type_double_ucell="unsigned long long"
437: ;;
438: $ac_cv_sizeof_intptr_t)
439: ac_cv_int_type_double_ucell="unsigned intptr_t"
440: ;;
441: $ac_cv_sizeof_uint128_t)
442: ac_cv_int_type_double_ucell="uint128_t"
443: ;;
444: esac
445: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
446:
447: if test "$ac_cv_int_type_double_cell" = none || \
448: test "$ac_cv_int_type_double_ucell" = none
449: then
450: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
451: AC_LIBOBJ(dblsub)
452: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
453: else
454: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
455: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
456: fi
457:
458: AC_TYPE_OFF_T
459: AC_CHECK_SIZEOF(off_t)
460: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
461: ac_small_off_t=$?
462: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
463:
464: ENGINE_FLAGS=
465: AC_SUBST(ENGINE_FLAGS)
466:
467: # Try if GCC understands -fno-gcse
468:
469: AC_MSG_CHECKING([if $CC understands -fno-gcse])
470: CFLAGS_1="$CFLAGS"
471: CFLAGS="$CFLAGS -fno-gcse"
472: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
473: CFLAGS="$CFLAGS_1"
474: AC_MSG_RESULT($ac_nogcse)
475:
476: # Try if GCC understands -fno-strict-aliasing
477: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
478: CFLAGS_1="$CFLAGS"
479: CFLAGS="$CFLAGS -fno-strict-aliasing"
480: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
481: CFLAGS="$CFLAGS_1"
482: AC_MSG_RESULT($ac_nostrictaliasing)
483:
484: # Try if GCC understands -fno-crossjumping
485: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
486: CFLAGS_1="$CFLAGS"
487: CFLAGS="$CFLAGS -fno-crossjumping"
488: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
489: CFLAGS="$CFLAGS_1"
490: AC_MSG_RESULT($ac_nocrossjumping)
491:
492: # Try if GCC understands -fno-reorder-blocks
493: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
494: CFLAGS_1="$CFLAGS"
495: CFLAGS="$CFLAGS -fno-reorder-blocks"
496: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
497: CFLAGS="$CFLAGS_1"
498: AC_MSG_RESULT($ac_noreorder_blocks)
499:
500: # Try if GCC understands __attribute__((unused))
501: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
502: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
503: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
504: AC_MSG_RESULT($MAYBE_UNUSED)
505:
506: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
507: AC_SUBST(asm_fs)
508:
509: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
510: AC_SUBST(disasm_fs)
511:
512: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
513:
514: case "$host_os" in
515: *win32*)
516: # !!!FIXME!!! problems with cygwin and ';' as path separator
517: DIRSEP="\\\\"
518: PATHSEP=";"
519: #we want the builtins of command.com/cmd.exe and its
520: # handling of .com files.
521: #$COMSPEC contains the name of the Windows shell;
522: # the ./ is there, because the bash does not recognize
523: # absolute DOS filenames
524: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
525: ;;
526: *darwin*)
527: #Darwin uses some funny preprocessor by default; eliminate it:
528: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
529: CFLAGS="$CFLAGS -no-cpp-precomp"
530: DIRSEP="/"
531: PATHSEP=":"
532: DEFAULTSYSTEMPREFIX=""
533: ;;
534: *)
535: DIRSEP="/"
536: PATHSEP=":"
537: DEFAULTSYSTEMPREFIX=""
538: ;;
539: esac
540: AC_SUBST(DIRSEP)
541: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
542: AC_SUBST(PATHSEP)
543: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
544: AC_SUBST(DEFAULTSYSTEMPREFIX)
545: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
546:
547: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
548: #This magic incantation seems to be completely undocumented.
549: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
550:
551: dnl Now a little support for DOS/DJGCC
552: AC_SUBST(GFORTH_EXE)
553: GFORTH_EXE=""
554: AC_SUBST(GFORTHFAST_EXE)
555: GFORTHFAST_EXE=""
556: AC_SUBST(GFORTHITC_EXE)
557: GFORTHITC_EXE=""
558: AC_SUBST(GFORTHDITC_EXE)
559: GFORTHDITC_EXE=""
560:
561: AC_SUBST(FORTHSIZES)
562:
563: dnl if test "$PEEPHOLE" = "yes"
564: dnl then
565: dnl PEEPHOLEFLAG="true"
566: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
567: dnl else
568: dnl PEEPHOLEFLAG="false"
569: dnl fi
570: PEEPHOLEFLAG="true"
571: AC_SUBST(PEEPHOLEFLAG)
572:
573: dnl copy commands for systems that don't have links
574: AC_SUBST(LINK_KERNL)
575: LINK_KERNL=""
576:
577: #if test $host_os=dos
578: #then
579: # echo Configuring for DOS!!!
580: # MAKE_EXE="coff2exe gforth"
581: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
582: #fi
583:
584: dnl the following macro produces a warning with autoconf-2.1
585: AC_C_BIGENDIAN
586: AC_SUBST(KERNEL)
587: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
588: if test $ac_cv_c_bigendian = yes; then
589: bytesex=b
590: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
591: else
592: bytesex=l
593: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
594: fi
595:
596: #check how to do asm(".skip 16")
597: #echo "CFLAGS=$CFLAGS"
598: #echo "ac_link=$ac_link"
599: AC_MSG_CHECKING([if and how we can waste code space])
600: if test -z "$skipcode"; then
601: skipcode=no
602: CFLAGS_1="$CFLAGS"
603: CFLAGS="$CFLAGS $ENGINE_FLAGS"
604: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
605: do
606: AC_TRY_RUN(
607: [int foo(int,int,int);
608: main()
609: {
610: exit(foo(0,0,0)!=16);
611: }
612: int foo(int x, int y, int z)
613: {
614: static void *labels[]={&&label1, &&label2};
615: if (x) {
616: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
617: label1:
618: asm("$i"); /* or ".space 16" or somesuch */
619: label2: ;
620: }
621: {
622: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
623: return labels[1]-labels[0];
624: }
625: }]
626: ,skipcode=$i; break
627: ,,)
628: done
629: CFLAGS=$CFLAGS_1
630: fi
631: AC_MSG_RESULT($skipcode)
632: if test "$skipcode" = no
633: then
634: if test -z $no_dynamic_default; then
635: no_dynamic_default=1
636: AC_MSG_WARN(Disabling default dynamic native code generation)
637: fi
638: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
639: else
640: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
641: fi
642:
643: AC_MSG_CHECKING([if and how we can do comments in asm statements])
644: #the point here is to get asm statements that look different to
645: #gcc's "optimizer"
646: if test -z "$asmcomment"; then
647: asmcomment=no
648: CFLAGS_1="$CFLAGS"
649: CFLAGS="$CFLAGS $ENGINE_FLAGS"
650: for i in '"# "' '"! "' '"; "'; do
651: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
652: done
653: CFLAGS=$CFLAGS_1
654: fi
655: AC_MSG_RESULT($asmcomment)
656: if test "$asmcomment" != no
657: then
658: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
659: fi
660:
661: test "$no_dynamic_default" || no_dynamic_default=0
662: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
663:
664: dnl Checks for programs.
665: AC_PROG_LN_S
666: AC_PROG_INSTALL
667: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
668:
669: dnl Checks for library functions
670: dnl This check is just for making later checks link with libm.
671: dnl using sin here is no good idea since it is built-into gcc and typechecked
672: AC_CHECK_LIB(m,asin)
673: AC_CHECK_LIB(dl,dlopen)
674: dnl check for libffi 2.x
675: AC_CHECK_LIB(ffi,ffi_call)
676: if test $ac_cv_lib_ffi_ffi_call = yes
677: then
678: LIBFFIFLAG="true"
679: FFCALLFLAG="false"
680: OLDCALLFLAG="false"
681: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
682: else
683: dnl check for ffcall libraries
684: dnl unfortunately, these four calls are separated out into a library each.
685: AC_CHECK_LIB(avcall,__builtin_avcall)
686: AC_CHECK_LIB(callback,__vacall_r)
687: AC_CHECK_LIB(vacall,vacall)
688: AC_CHECK_LIB(trampoline,alloc_trampoline)
689: LIBFFIFLAG="false"
690: FFCALLFLAG="false"
691: OLDCALLFLAG="true"
692: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
693: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
694: fi
695: AC_SUBST(LIBFFIFLAG)
696: AC_SUBST(FFCALLFLAG)
697: AC_SUBST(OLDCALLFLAG)
698: if test "$host_os" != "nextstep3"
699: then
700: AC_FUNC_MEMCMP
701: fi
702: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
703: AC_FUNC_FSEEKO
704: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
705: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
706: AC_DECL_SYS_SIGLIST
707: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
708: AC_CHECK_FUNCS(expm1 log1p)
709: AC_REPLACE_FUNCS(rint ecvt)
710: dnl No check for select, because our replacement is no good under
711: dnl anything but DOS
712: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
713: AC_FUNC_FNMATCH
714: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
715: AC_CHECK_FUNCS(mmap sysconf getpagesize)
716: AM_PATH_LISPDIR
717:
718: kernel_fi=kernl${wordsize}${bytesex}.fi
719: AC_SUBST(kernel_fi)
720:
721: #this breaks bindists
722: #dnl replace srource directory by absolute value
723: #if test $srcdir = "."; then srcdir=`pwd`
724: #fi
725:
726: AC_SUBST(machine)
727: AC_CONFIG_FILES([
728: Makefile
729: Makedist
730: gforthmi
731: vmgen
732: machpc.fs
733: envos.fs
734: engine/Makefile
735: doc/version.texi
736: build-ec ])
737: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
738: chmod +x gforthmi
739: chmod +x vmgen
740: chmod +x build-ec
741: test -d kernel||mkdir kernel]],[[]])
742: AC_OUTPUT
743:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>