1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20060527],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="April 09, 2006"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(gcc-pr15242-workaround,
57: AC_HELP_STRING([--disable-gcc-pr15242-workaround],[Disables
58: dynamic code generation on some versions of gcc
59: (slowdown~2 on Athlon) and causes slower building
60: of gforth (but gforth speedups) on others.
61: (default enabled)]),
62: ,enable_gcc_pr15242_workaround=yes)
63: test "$enable_gcc_pr15242_workaround" = "no"||
64: AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
65: generation on gccs affected by PR15242])
66:
67: AC_ARG_ENABLE(force-cdiv,
68: AC_HELP_STRING([--enable-force-cdiv],
69: [ Use the native C division - symmetric - instead of
70: floored division (default disabled).]),
71: ,enable_force_cdiv=no)
72: test "$enable_force_cdiv" = "no"||
73: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
74:
75: AC_SUBST(PROFEXES)
76: AC_SUBST(PROFOBJS)
77: AC_ARG_ENABLE(prof,
78: AC_HELP_STRING([--enable-prof],
79: [ Build gforth-prof, which outputs frequently occuring
80: sequences of primitives.]),
81: ,enable_prof=no)
82: if test "$enable_prof" = "no"; then
83: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
84: fi
85:
86: AC_ARG_WITH(debug,
87: [ --with-debug specifies option -g to compile with debug info
88: --without-debug omits the -g switch and creates smaller images on
89: machines where "strip" has problems with gcc style
90: debugging informations.],
91: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
92:
93: dnl PEEPHOLE="yes"
94: dnl AC_ARG_WITH(peephole,
95: dnl [ --with-peephole Enable peephole optimization (default)
96: dnl --without-peephole disables peephole optimization. Creates smaller,
97: dnl but slower images.],
98: dnl PEEPHOLE="$withval")
99:
100: AC_ARG_ENABLE(ec,
101: AC_HELP_STRING([--enable-ec],
102: [ Build gforth for systems without OS.]),
103: ,enable_ec=no)
104: if test "$enable_ec" = "yes"; then
105: AC_DEFINE(HAVE_EC,,[Define if you want a Gforth without OS])
106: EC_MODE="true"
107: else
108: EC_MODE="false"
109: fi
110:
111: #variables mentioned in INSTALL
112: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
113: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
114: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
115: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
116: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
117: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
118: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
119: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
120: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
121: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
122: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
123: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
124: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
125: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
126: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
127:
128: #set up feature test macros, so the tests get them right:
129: # turn on all POSIX, SUSv3, and GNU features if available
130: AC_GNU_SOURCE
131: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
132:
133: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
134: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
135: dnl but not for _XOPEN_SOURCE)
136: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
137: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
138: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
139: # turn on large file support with 64-bit off_t where available
140: AC_SYS_LARGEFILE
141: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
142: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
143:
144: #currently we force direct threading this way. Eventually we should
145: #setup in the arch and engine files right
146:
147: AC_PROG_CC
148:
149: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
150:
151: AC_SUBST(CC)
152: AC_SUBST(DEBUGFLAG)
153: AC_SUBST(HAVE_EC)
154: AC_SUBST(EC_MODE)
155:
156: AC_MSG_CHECKING(make type)
157: make_type=`make -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
158:
159: GNUMAKE='#'
160: test "$make_type" = "GNU Make" && GNUMAKE=''
161:
162: AC_MSG_RESULT($make_type)
163:
164: AC_SUBST(GNUMAKE)
165:
166: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
167: OLDLDFLAGS=$LDFLAGS
168: LDFLAGS="$LDFLAGS -export-dynamic"
169: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
170: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
171: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
172: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
173: AC_MSG_RESULT($ac_export_dynamic)
174:
175: #terminology is a bit unusual here: The host is the system on which
176: #gforth will run; the system on which configure will run is the `build'
177: AC_CANONICAL_HOST
178: case "$host_cpu" in
179: arm*)
180: machine=arm
181: CFLAGS="$CFLAGS -fomit-frame-pointer"
182: if test -z $no_dynamic_default; then
183: no_dynamic_default=1
184: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
185: fi
186: ;;
187: hppa*)
188: machine=hppa
189: $srcdir/mkinstalldirs arch/hppa
190: AC_LIBOBJ(../arch/hppa/cache)
191: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
192: LDFLAGS="$LDFLAGS -Xlinker -N"
193: LIBS="$LIBS -L/lib/pa1.1/"
194: ;;
195: sparc*)
196: machine=sparc
197: ;;
198: i386)
199: machine=386
200: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
201: ;;
202: i486)
203: machine=386
204: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
205: ;;
206: i*86)
207: machine=386
208: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
209: CFLAGS_1="$CFLAGS"
210: CFLAGS="$CFLAGS -march=pentium"
211: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
212: ;;
213: x86_64)
214: machine=amd64
215: ;;
216: ia64*)
217: machine=ia64
218: AC_LIBOBJ(../arch/ia64/flush_icache_block)
219: test "$skipcode" || skipcode="nop.i 0"
220: #".skip 16" passes the test below,
221: # but gives an assembler error in engine
222: ;;
223: m68k)
224: machine=m68k
225: CFLAGS="$CFLAGS -fomit-frame-pointer"
226: if test "$host_os" = "nextstep3"
227: then
228: AC_LIBOBJ(termios)
229: fi
230: ;;
231: mips*)
232: machine=mips
233: #dynamic native code has the following problems on MIPS:
234: #
235: #1) J/JAL seems relocatable, but is are only
236: #relocatable within a 256MB-segment. While we try to
237: #get the linker to arrange this, there is no guarantee
238: #that this will succeed (and if the user uses a lot of
239: #memory, it is likely to fail).
240: #
241: #2) The way we generate dynamic native code may
242: #violate MIPS architectural restrictions (in
243: #particular, the delay slots of LW, MFLO, etc.)
244: #
245: #Therefore we disable dynamic native code by default:
246: if test -z $no_dynamic_default; then
247: no_dynamic_default=1
248: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
249: fi
250: ;;
251: alpha*)
252: machine=alpha
253: #full IEEE FP support for more uniformity across platforms:
254: CFLAGS="$CFLAGS -mieee"
255: ;;
256: power*|rs6000)
257: machine=power
258: $srcdir/mkinstalldirs arch/power
259: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
260: #long long is broken on (at least) gcc-2.95.* for PPC
261: test x$ac_cv_sizeof_long_long = x &&
262: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
263: ac_cv_sizeof_long_long=0
264: ;;
265: *)
266: AC_MSG_WARN([Using a generic machine description])
267: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
268: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
269: machine=generic
270: #I-cache flushing would be needed for dynamic code generation
271: if test -z $no_dynamic_default; then
272: no_dynamic_default=1
273: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
274: fi
275: esac
276: AC_SUBST(host)
277:
278: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
279: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
280: [number of registers in the default stack cache state for gforth-fast and gforth-native])
281:
282: if test "${enable_force_ll+set}" = set; then
283: ac_includes_default="$ac_includes_default
284: #include \"arch/generic/128bit.h\""
285: fi
286:
287: dnl the following macro produces a warning with autoconf-2.1
288: AC_CHECK_SIZEOF(char *)
289: case "$ac_cv_sizeof_char_p" in
290: 2)
291: wordsize=16
292: ;;
293: 4)
294: wordsize=32
295: ;;
296: 8)
297: wordsize=64
298: ;;
299: esac
300:
301: AC_CHECK_SIZEOF(char)
302: AC_CHECK_SIZEOF(short)
303: AC_CHECK_SIZEOF(int)
304: AC_CHECK_SIZEOF(long)
305: AC_CHECK_SIZEOF(long long)
306: AC_CHECK_SIZEOF(intptr_t)
307: AC_CHECK_SIZEOF(int128_t)
308: AC_CHECK_SIZEOF(uint128_t)
309:
310: AC_MSG_CHECKING([for a C type for cells])
311: ac_cv_int_type_cell=none
312: case "$ac_cv_sizeof_char_p" in
313: $ac_cv_sizeof_int)
314: ac_cv_int_type_cell=int
315: ;;
316: $ac_cv_sizeof_short)
317: ac_cv_int_type_cell=short
318: ;;
319: $ac_cv_sizeof_char)
320: ac_cv_int_type_cell=char
321: ;;
322: $ac_cv_sizeof_long)
323: ac_cv_int_type_cell=long
324: ;;
325: $ac_cv_sizeof_long_long)
326: ac_cv_int_type_cell="long long"
327: ;;
328: $ac_cv_sizeof_intptr_t)
329: ac_cv_int_type_cell="intptr_t"
330: ;;
331: $ac_cv_sizeof_int128_t)
332: ac_cv_int_type_cell="int128_t"
333: ;;
334: esac
335: AC_MSG_RESULT($ac_cv_int_type_cell)
336: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
337:
338: AC_MSG_CHECKING([for a C type for wydes])
339: ac_cv_wyde_type_cell=none
340: case 2 in
341: $ac_cv_sizeof_int)
342: ac_cv_wyde_type_cell=int
343: ;;
344: $ac_cv_sizeof_short)
345: ac_cv_wyde_type_cell=short
346: ;;
347: $ac_cv_sizeof_char)
348: ac_cv_wyde_type_cell=char
349: ;;
350: $ac_cv_sizeof_long)
351: ac_cv_wyde_type_cell=long
352: ;;
353: $ac_cv_sizeof_long_long)
354: ac_cv_wyde_type_cell="long long"
355: ;;
356: $ac_cv_sizeof_intptr_t)
357: ac_cv_wyde_type_cell="intptr_t"
358: ;;
359: $ac_cv_sizeof_int128_t)
360: ac_cv_wyde_type_cell="int128_t"
361: ;;
362: esac
363: AC_MSG_RESULT($ac_cv_wyde_type_cell)
364: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
365:
366: AC_MSG_CHECKING([for a C type for tetrabytes])
367: ac_cv_tetrabyte_type_cell=none
368: case 4 in
369: $ac_cv_sizeof_int)
370: ac_cv_tetrabyte_type_cell=int
371: ;;
372: $ac_cv_sizeof_short)
373: ac_cv_tetrabyte_type_cell=short
374: ;;
375: $ac_cv_sizeof_char)
376: ac_cv_tetrabyte_type_cell=char
377: ;;
378: $ac_cv_sizeof_long)
379: ac_cv_tetrabyte_type_cell=long
380: ;;
381: $ac_cv_sizeof_long_long)
382: ac_cv_tetrabyte_type_cell="long long"
383: ;;
384: $ac_cv_sizeof_intptr_t)
385: ac_cv_tetrabyte_type_cell="intptr_t"
386: ;;
387: $ac_cv_sizeof_int128_t)
388: ac_cv_tetrabyte_type_cell="int128_t"
389: ;;
390: esac
391: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
392: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
393:
394: AC_MSG_CHECKING([for a C type for double-cells])
395: ac_cv_int_type_double_cell=none
396: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
397: $ac_cv_sizeof_short)
398: ac_cv_int_type_double_cell=short
399: ;;
400: $ac_cv_sizeof_int)
401: ac_cv_int_type_double_cell=int
402: ;;
403: $ac_cv_sizeof_long)
404: ac_cv_int_type_double_cell=long
405: ;;
406: $ac_cv_sizeof_long_long)
407: ac_cv_int_type_double_cell="long long"
408: ;;
409: $ac_cv_sizeof_intptr_t)
410: ac_cv_int_type_double_cell="intptr_t"
411: ;;
412: $ac_cv_sizeof_int128_t)
413: ac_cv_int_type_double_cell="int128_t"
414: ;;
415: esac
416: AC_MSG_RESULT($ac_cv_int_type_double_cell)
417:
418: AC_MSG_CHECKING([for a C type for unsigned double-cells])
419: ac_cv_int_type_double_ucell=none
420: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
421: $ac_cv_sizeof_short)
422: ac_cv_int_type_double_ucell="unsigned short"
423: ;;
424: $ac_cv_sizeof_int)
425: ac_cv_int_type_double_ucell="unsigned int"
426: ;;
427: $ac_cv_sizeof_long)
428: ac_cv_int_type_double_ucell="unsigned long"
429: ;;
430: $ac_cv_sizeof_long_long)
431: ac_cv_int_type_double_ucell="unsigned long long"
432: ;;
433: $ac_cv_sizeof_intptr_t)
434: ac_cv_int_type_double_ucell="unsigned intptr_t"
435: ;;
436: $ac_cv_sizeof_uint128_t)
437: ac_cv_int_type_double_ucell="uint128_t"
438: ;;
439: esac
440: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
441:
442: if test "$ac_cv_int_type_double_cell" = none || \
443: test "$ac_cv_int_type_double_ucell" = none
444: then
445: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
446: AC_LIBOBJ(dblsub)
447: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
448: else
449: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
450: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
451: fi
452:
453: AC_TYPE_OFF_T
454: AC_CHECK_SIZEOF(off_t)
455: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
456: ac_small_off_t=$?
457: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
458:
459: ENGINE_FLAGS=
460: AC_SUBST(ENGINE_FLAGS)
461:
462: # Try if GCC understands -fno-gcse
463:
464: AC_MSG_CHECKING([if $CC understands -fno-gcse])
465: CFLAGS_1="$CFLAGS"
466: CFLAGS="$CFLAGS -fno-gcse"
467: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
468: CFLAGS="$CFLAGS_1"
469: AC_MSG_RESULT($ac_nogcse)
470:
471: # Try if GCC understands -fno-strict-aliasing
472: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
473: CFLAGS_1="$CFLAGS"
474: CFLAGS="$CFLAGS -fno-strict-aliasing"
475: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
476: CFLAGS="$CFLAGS_1"
477: AC_MSG_RESULT($ac_nostrictaliasing)
478:
479: # Try if GCC understands -fno-crossjumping
480: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
481: CFLAGS_1="$CFLAGS"
482: CFLAGS="$CFLAGS -fno-crossjumping"
483: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
484: CFLAGS="$CFLAGS_1"
485: AC_MSG_RESULT($ac_nocrossjumping)
486:
487: # Try if GCC understands -fno-reorder-blocks
488: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
489: CFLAGS_1="$CFLAGS"
490: CFLAGS="$CFLAGS -fno-reorder-blocks"
491: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
492: CFLAGS="$CFLAGS_1"
493: AC_MSG_RESULT($ac_noreorder_blocks)
494:
495: # Try if GCC understands __attribute__((unused))
496: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
497: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
498: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
499: AC_MSG_RESULT($MAYBE_UNUSED)
500:
501: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
502: AC_SUBST(asm_fs)
503:
504: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
505: AC_SUBST(disasm_fs)
506:
507: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
508:
509: case "$host_os" in
510: *win32*)
511: # !!!FIXME!!! problems with cygwin and ';' as path separator
512: DIRSEP="\\\\"
513: PATHSEP=";"
514: #we want the builtins of command.com/cmd.exe and its
515: # handling of .com files.
516: #$COMSPEC contains the name of the Windows shell;
517: # the ./ is there, because the bash does not recognize
518: # absolute DOS filenames
519: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
520: ;;
521: *darwin*)
522: #Darwin uses some funny preprocessor by default; eliminate it:
523: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
524: CFLAGS="$CFLAGS -no-cpp-precomp"
525: DIRSEP="/"
526: PATHSEP=":"
527: DEFAULTSYSTEMPREFIX=""
528: ;;
529: *)
530: DIRSEP="/"
531: PATHSEP=":"
532: DEFAULTSYSTEMPREFIX=""
533: ;;
534: esac
535: AC_SUBST(DIRSEP)
536: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
537: AC_SUBST(PATHSEP)
538: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
539: AC_SUBST(DEFAULTSYSTEMPREFIX)
540: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
541:
542: dnl Now a little support for DOS/DJGCC
543: AC_SUBST(GFORTH_EXE)
544: GFORTH_EXE=""
545: AC_SUBST(GFORTHFAST_EXE)
546: GFORTHFAST_EXE=""
547: AC_SUBST(GFORTHITC_EXE)
548: GFORTHITC_EXE=""
549: AC_SUBST(GFORTHDITC_EXE)
550: GFORTHDITC_EXE=""
551:
552: AC_SUBST(FORTHSIZES)
553:
554: dnl if test "$PEEPHOLE" = "yes"
555: dnl then
556: dnl PEEPHOLEFLAG="true"
557: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
558: dnl else
559: dnl PEEPHOLEFLAG="false"
560: dnl fi
561: PEEPHOLEFLAG="true"
562: AC_SUBST(PEEPHOLEFLAG)
563:
564: dnl copy commands for systems that don't have links
565: AC_SUBST(LINK_KERNL)
566: LINK_KERNL=""
567:
568: #if test $host_os=dos
569: #then
570: # echo Configuring for DOS!!!
571: # MAKE_EXE="coff2exe gforth"
572: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
573: #fi
574:
575: dnl the following macro produces a warning with autoconf-2.1
576: AC_C_BIGENDIAN
577: AC_SUBST(KERNEL)
578: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
579: if test $ac_cv_c_bigendian = yes; then
580: bytesex=b
581: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
582: else
583: bytesex=l
584: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
585: fi
586:
587: #check how to do asm(".skip 16")
588: echo "CFLAGS=$CFLAGS"
589: echo "ac_link=$ac_link"
590: AC_MSG_CHECKING([if and how we can waste code space])
591: if test -z "$skipcode"; then
592: skipcode=no
593: CFLAGS_1="$CFLAGS"
594: CFLAGS="$CFLAGS $ENGINE_FLAGS"
595: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
596: do
597: AC_TRY_RUN(
598: [int foo(int,int,int);
599: main()
600: {
601: exit(foo(0,0,0)!=16);
602: }
603: int foo(int x, int y, int z)
604: {
605: static void *labels[]={&&label1, &&label2};
606: if (x) {
607: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
608: label1:
609: asm("$i"); /* or ".space 16" or somesuch */
610: label2: ;
611: }
612: {
613: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
614: return labels[1]-labels[0];
615: }
616: }]
617: ,skipcode=$i; break
618: ,,)
619: done
620: CFLAGS=$CFLAGS_1
621: fi
622: AC_MSG_RESULT($skipcode)
623: if test "$skipcode" = no
624: then
625: if test -z $no_dynamic_default; then
626: no_dynamic_default=1
627: AC_MSG_WARN(Disabling default dynamic native code generation)
628: fi
629: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
630: else
631: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
632: fi
633:
634: test "$no_dynamic_default" || no_dynamic_default=0
635: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
636:
637: dnl Checks for programs.
638: AC_PROG_LN_S
639: AC_PROG_INSTALL
640: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
641:
642: dnl Checks for library functions
643: dnl This check is just for making later checks link with libm.
644: dnl using sin here is no good idea since it is built-into gcc and typechecked
645: AC_CHECK_LIB(m,asin)
646: AC_CHECK_LIB(dl,dlopen)
647: dnl check for libffi 2.x
648: AC_CHECK_LIB(ffi,ffi_call)
649: if test $ac_cv_lib_ffi_ffi_call = yes
650: then
651: LIBFFIFLAG="true"
652: FFCALLFLAG="false"
653: OLDCALLFLAG="false"
654: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
655: else
656: dnl check for ffcall libraries
657: dnl unfortunately, these four calls are separated out into a library each.
658: AC_CHECK_LIB(avcall,__builtin_avcall)
659: AC_CHECK_LIB(callback,__vacall_r)
660: AC_CHECK_LIB(vacall,vacall)
661: AC_CHECK_LIB(trampoline,alloc_trampoline)
662: LIBFFIFLAG="false"
663: FFCALLFLAG="false"
664: OLDCALLFLAG="true"
665: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
666: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
667: fi
668: AC_SUBST(LIBFFIFLAG)
669: AC_SUBST(FFCALLFLAG)
670: AC_SUBST(OLDCALLFLAG)
671: if test "$host_os" != "nextstep3"
672: then
673: AC_FUNC_MEMCMP
674: fi
675: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
676: AC_FUNC_FSEEKO
677: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
678: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
679: AC_DECL_SYS_SIGLIST
680: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
681: AC_CHECK_FUNCS(expm1 log1p)
682: AC_REPLACE_FUNCS(rint ecvt)
683: dnl No check for select, because our replacement is no good under
684: dnl anything but DOS
685: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
686: AC_FUNC_FNMATCH
687: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
688: AC_CHECK_FUNCS(mmap sysconf getpagesize)
689: AM_PATH_LISPDIR
690:
691: kernel_fi=kernl${wordsize}${bytesex}.fi
692: AC_SUBST(kernel_fi)
693:
694: #this breaks bindists
695: #dnl replace srource directory by absolute value
696: #if test $srcdir = "."; then srcdir=`pwd`
697: #fi
698:
699: AC_SUBST(machine)
700: AC_CONFIG_FILES([
701: Makefile
702: Makedist
703: gforthmi
704: vmgen
705: machpc.fs
706: envos.fs
707: engine/Makefile
708: doc/version.texi
709: build-ec ])
710: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
711: chmod +x gforthmi
712: chmod +x vmgen
713: chmod +x build-ec
714: test -d kernel||mkdir kernel]],[[]])
715: AC_OUTPUT
716:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>