File:  [gforth] / gforth / configure.in
Revision 1.150: download - view: text, annotated - select for diffs
Sat Jan 29 16:55:30 2005 UTC (19 years, 1 month ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Added --enable-force-cdiv

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.2-20030910],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="September 10, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: 	AC_HELP_STRING([--enable-force-reg],
   38: 		        [ Use explicit register declarations if they appear in
   39: 			  the machine.h file. This can cause a good speedup,
   40: 			  but also incorrect code with some gcc versions on
   41: 			  some processors (default disabled).]),
   42: 	,enable_force_reg=no)
   43: test "$enable_force_reg" = "no"||
   44:   AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
   45: 
   46: AC_ARG_ENABLE(force-ll,
   47: 	AC_HELP_STRING([--enable-force-ll],
   48: 		       [  Use explicit long long declarations if they appear in
   49: 			  the machine.h file. This can cause a good speedup,
   50: 			  but also incorrect code with some gcc versions on
   51: 			  some processors (default disabled).]),
   52: 	,enable_force_ll=no)
   53: test "$enable_force_ll" = "no"||
   54:   AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
   55: 
   56: AC_ARG_ENABLE(gcc-pr15242-workaround,
   57:               AC_HELP_STRING([--disable-gcc-pr15242-workaround],[Disables
   58:                              dynamic code generation on some versions of gcc
   59:                              (slowdown~2 on Athlon) and causes slower building
   60:                              of gforth (but gforth speedups) on others.
   61:                              (default enabled)]),
   62: 		,enable_gcc_pr15242_workaround=yes)
   63: test "$enable_gcc_pr15242_workaround" = "no"||
   64: AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
   65: generation on gccs affected by PR15242])
   66: 
   67: AC_ARG_ENABLE(force-cdiv,
   68: 	AC_HELP_STRING([--enable-force-cdiv],
   69: 		       [  Use the native C division - symmetric - instead of
   70: 		          floored division (default disabled).]),
   71: 	,enable_force_cdiv=no)
   72: test "$enable_force_cdiv" = "no"||
   73:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   74: 
   75: AC_SUBST(PROFEXES)
   76: AC_SUBST(PROFOBJS)
   77: AC_ARG_ENABLE(prof,
   78: 	AC_HELP_STRING([--enable-prof],
   79: 			[ Build gforth-prof, which outputs frequently occuring
   80:                           sequences of primitives.]),
   81: 	,enable_prof=no)
   82: if test "$enable_prof" = "no"; then
   83:   PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
   84: fi
   85: 
   86: AC_ARG_WITH(debug,
   87: [  --with-debug		  specifies option -g to compile with debug info
   88:   --without-debug	  omits the -g switch and creates smaller images on
   89: 			  machines where "strip" has problems with gcc style
   90: 			  debugging informations.],
   91: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   92: 
   93: dnl PEEPHOLE="yes"
   94: dnl AC_ARG_WITH(peephole,
   95: dnl [  --with-peephole	Enable peephole optimization (default)
   96: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   97: dnl 			but slower images.],
   98: dnl PEEPHOLE="$withval")
   99: 
  100: #variables mentioned in INSTALL
  101: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
  102: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  103: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  104: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  105: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  106: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  107: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  108: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  109: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  110: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  111: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  112: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  113: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  114: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
  115: 
  116: #set up feature test macros, so the tests get them right:
  117: # turn on all POSIX, SUSv3, and GNU features if available
  118: AC_GNU_SOURCE
  119: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  120: 
  121: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  122: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  123: dnl but not for _XOPEN_SOURCE)
  124: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  125: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  126: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  127: # turn on large file support with 64-bit off_t where available
  128: AC_SYS_LARGEFILE
  129: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  130: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  131: 
  132: #currently we force direct threading this way.  Eventually we should
  133: #setup in the arch and engine files right
  134: 
  135: AC_PROG_CC
  136: 
  137: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  138: 
  139: AC_SUBST(CC)
  140: AC_SUBST(DEBUGFLAG)
  141: 
  142: AC_MSG_CHECKING(make type)
  143: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
  144: 
  145: GNUMAKE='#'
  146: test "$make_type" = "GNU Make" && GNUMAKE=''
  147: 
  148: AC_MSG_RESULT($make_type)
  149: 
  150: AC_SUBST(GNUMAKE)
  151: 
  152: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  153: OLDLDFLAGS=$LDFLAGS
  154: LDFLAGS="$LDFLAGS -export-dynamic"
  155: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  156: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  157: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  158: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  159: AC_MSG_RESULT($ac_export_dynamic)
  160: 
  161: #terminology is a bit unusual here: The host is the system on which
  162: #gforth will run; the system on which configure will run is the `build'
  163: AC_CANONICAL_HOST
  164: case "$host_cpu" in
  165: 	arm*)
  166: 		machine=arm
  167: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  168: 		if test -z $no_dynamic_default; then
  169: 		    no_dynamic_default=1
  170: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  171: 		fi
  172: 		;;
  173: 	hppa*)
  174: 		machine=hppa
  175: 		$srcdir/mkinstalldirs arch/hppa
  176: 		AC_LIBOBJ(../arch/hppa/cache)
  177: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  178: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  179: 		LIBS="$LIBS -L/lib/pa1.1/"
  180: 		;;
  181: 	sparc*)
  182: 		machine=sparc
  183: 		;;
  184: 	i386)
  185: 		machine=386
  186: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  187: 		;;
  188: 	i486)
  189: 		machine=386
  190: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  191: 		;;
  192: 	i*86)
  193: 		machine=386
  194: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  195: 		CFLAGS_1="$CFLAGS"
  196: 		CFLAGS="$CFLAGS -march=pentium"
  197: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  198: 		;;
  199: 	x86_64)
  200: 		machine=amd64
  201: 		;;
  202: 	ia64*)
  203: 		machine=ia64
  204: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  205: 		test "$skipcode" || skipcode="nop.i 0"
  206: 		#".skip 16" passes the test below,
  207: 		# but gives an assembler error in engine
  208: 		;;
  209:         m68k)
  210: 		machine=m68k
  211: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  212: 		if test "$host_os" = "nextstep3"
  213: 		then
  214: 			AC_LIBOBJ(termios)
  215: 		fi
  216: 		;;
  217: 	mips*)
  218: 		machine=mips
  219: 		#dynamic native code has the following problems on MIPS:
  220: 		#
  221: 		#1) J/JAL seems relocatable, but is are only
  222: 		#relocatable within a 256MB-segment.  While we try to
  223: 		#get the linker to arrange this, there is no guarantee
  224: 		#that this will succeed (and if the user uses a lot of
  225: 		#memory, it is likely to fail).
  226: 		#
  227: 		#2) The way we generate dynamic native code may
  228: 		#violate MIPS architectural restrictions (in
  229: 		#particular, the delay slots of LW, MFLO, etc.)
  230: 		#
  231: 		#Therefore we disable dynamic native code by default:
  232: 		if test -z $no_dynamic_default; then
  233: 		    no_dynamic_default=1
  234: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  235: 		fi
  236: 		;;
  237: 	alpha*)
  238: 		machine=alpha
  239: 		#full IEEE FP support for more uniformity across platforms:
  240: 		CFLAGS="$CFLAGS -mieee"
  241: 		;;
  242: 	power*|rs6000)
  243: 		machine=power
  244: 		$srcdir/mkinstalldirs arch/power
  245: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  246: 		#long long is broken on (at least) gcc-2.95.* for PPC
  247: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  248: 		;;
  249: 	*)
  250: 		AC_MSG_WARN([Using a generic machine description])
  251: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  252: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  253: 		machine=generic
  254: 		#I-cache flushing would be needed for dynamic code generation
  255: 		if test -z $no_dynamic_default; then
  256: 		    no_dynamic_default=1
  257: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  258: 		fi
  259: esac
  260: AC_SUBST(host)
  261: 
  262: if test "${enable_force_ll+set}" = set; then
  263:    ac_includes_default="$ac_includes_default
  264: #include \"arch/generic/128bit.h\""
  265: fi
  266: 
  267: dnl the following macro produces a warning with autoconf-2.1
  268: AC_CHECK_SIZEOF(char *)
  269: case "$ac_cv_sizeof_char_p" in
  270:   2)
  271:     wordsize=16
  272:     ;;
  273:   4)
  274:     wordsize=32
  275:     ;;
  276:   8)
  277:     wordsize=64
  278:     ;;
  279: esac
  280: 
  281: AC_CHECK_SIZEOF(char)
  282: AC_CHECK_SIZEOF(short)
  283: AC_CHECK_SIZEOF(int)
  284: AC_CHECK_SIZEOF(long)
  285: AC_CHECK_SIZEOF(long long)
  286: AC_CHECK_SIZEOF(intptr_t)
  287: AC_CHECK_SIZEOF(int128_t)
  288: AC_CHECK_SIZEOF(uint128_t)
  289: 
  290: AC_MSG_CHECKING([for a C type for cells])
  291: ac_cv_int_type_cell=none
  292: case "$ac_cv_sizeof_char_p" in
  293:   $ac_cv_sizeof_int)
  294:     ac_cv_int_type_cell=int
  295:     ;;
  296:   $ac_cv_sizeof_short)
  297:     ac_cv_int_type_cell=short
  298:     ;;
  299:   $ac_cv_sizeof_char)
  300:     ac_cv_int_type_cell=char
  301:     ;;
  302:   $ac_cv_sizeof_long)
  303:     ac_cv_int_type_cell=long
  304:     ;;
  305:   $ac_cv_sizeof_long_long)
  306:     ac_cv_int_type_cell="long long"
  307:     ;;
  308:   $ac_cv_sizeof_intptr_t)
  309:     ac_cv_int_type_cell="intptr_t"
  310:     ;;
  311:   $ac_cv_sizeof_int128_t)
  312:     ac_cv_int_type_cell="int128_t"
  313:     ;;
  314: esac
  315: AC_MSG_RESULT($ac_cv_int_type_cell)
  316: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  317: 
  318: AC_MSG_CHECKING([for a C type for double-cells])
  319: ac_cv_int_type_double_cell=none
  320: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  321:   $ac_cv_sizeof_short)
  322:     ac_cv_int_type_double_cell=short
  323:     ;;
  324:   $ac_cv_sizeof_int)
  325:     ac_cv_int_type_double_cell=int
  326:     ;;
  327:   $ac_cv_sizeof_long)
  328:     ac_cv_int_type_double_cell=long
  329:     ;;
  330:   $ac_cv_sizeof_long_long)
  331:     ac_cv_int_type_double_cell="long long"
  332:     ;;
  333:   $ac_cv_sizeof_intptr_t)
  334:     ac_cv_int_type_double_cell="intptr_t"
  335:     ;;
  336:   $ac_cv_sizeof_int128_t)
  337:     ac_cv_int_type_double_cell="int128_t"
  338:     ;;
  339: esac
  340: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  341: 
  342: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  343: ac_cv_int_type_double_ucell=none
  344: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  345:   $ac_cv_sizeof_short)
  346:     ac_cv_int_type_double_ucell="unsigned short"
  347:     ;;
  348:   $ac_cv_sizeof_int)
  349:     ac_cv_int_type_double_ucell="unsigned int"
  350:     ;;
  351:   $ac_cv_sizeof_long)
  352:     ac_cv_int_type_double_ucell="unsigned long"
  353:     ;;
  354:   $ac_cv_sizeof_long_long)
  355:     ac_cv_int_type_double_ucell="unsigned long long"
  356:     ;;
  357:   $ac_cv_sizeof_intptr_t)
  358:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  359:     ;;
  360:   $ac_cv_sizeof_uint128_t)
  361:     ac_cv_int_type_double_ucell="uint128_t"
  362:     ;;
  363: esac
  364: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  365: 
  366: if test "$ac_cv_int_type_double_cell" = none || \
  367:    test "$ac_cv_int_type_double_ucell" = none
  368: then
  369: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  370: 	AC_LIBOBJ(dblsub)
  371: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  372: else
  373: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  374: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  375: fi
  376: 
  377: AC_TYPE_OFF_T
  378: AC_CHECK_SIZEOF(off_t)
  379: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  380: ac_small_off_t=$?
  381: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  382: 
  383: ENGINE_FLAGS=
  384: AC_SUBST(ENGINE_FLAGS)
  385: 
  386: # Try if GCC understands -fno-gcse
  387: 
  388: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  389: CFLAGS_1="$CFLAGS"
  390: CFLAGS="$CFLAGS -fno-gcse"
  391: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  392: CFLAGS="$CFLAGS_1"
  393: AC_MSG_RESULT($ac_nogcse)
  394: 
  395: # Try if GCC understands -fno-strict-aliasing
  396: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  397: CFLAGS_1="$CFLAGS"
  398: CFLAGS="$CFLAGS -fno-strict-aliasing"
  399: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  400: CFLAGS="$CFLAGS_1"
  401: AC_MSG_RESULT($ac_nostrictaliasing)
  402: 
  403: # Try if GCC understands -fno-crossjumping
  404: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  405: CFLAGS_1="$CFLAGS"
  406: CFLAGS="$CFLAGS -fno-crossjumping"
  407: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  408: CFLAGS="$CFLAGS_1"
  409: AC_MSG_RESULT($ac_nocrossjumping)
  410: 
  411: # Try if GCC understands -fno-reorder-blocks
  412: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  413: CFLAGS_1="$CFLAGS"
  414: CFLAGS="$CFLAGS -fno-reorder-blocks"
  415: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  416: CFLAGS="$CFLAGS_1"
  417: AC_MSG_RESULT($ac_noreorder_blocks)
  418: 
  419: # Try if GCC understands __attribute__((unused))
  420: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  421: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  422: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  423: AC_MSG_RESULT($MAYBE_UNUSED)
  424: 
  425: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  426: AC_SUBST(asm_fs)
  427: 
  428: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  429: AC_SUBST(disasm_fs)
  430: 
  431: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  432: 
  433: case "$host_os" in
  434: 	*win32|cygwin)
  435: 		DIRSEP="\\\\"
  436: 		PATHSEP=";"
  437: 		#we want the builtins of command.com/cmd.exe and its
  438: 		# handling of .com files.
  439: 		#$COMSPEC contains the name of the Windows shell;
  440: 		# the ./ is there, because the bash does not recognize
  441: 		# absolute DOS filenames
  442: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  443: 		;;
  444: 	*darwin*)
  445: 		#Darwin uses some funny preprocessor by default; eliminate it:
  446: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  447: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  448: 		DIRSEP="/"
  449: 		PATHSEP=":"
  450: 		DEFAULTSYSTEMPREFIX=""
  451: 		;;
  452: 	*)
  453: 		DIRSEP="/"
  454: 		PATHSEP=":"
  455: 		DEFAULTSYSTEMPREFIX=""
  456: 		;;
  457: esac
  458: AC_SUBST(DIRSEP)
  459: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  460: AC_SUBST(PATHSEP)
  461: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  462: AC_SUBST(DEFAULTSYSTEMPREFIX)
  463: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  464: 
  465: dnl Now a little support for DOS/DJGCC
  466: AC_SUBST(GFORTH_EXE)
  467: GFORTH_EXE=""
  468: AC_SUBST(GFORTHFAST_EXE)
  469: GFORTHFAST_EXE=""
  470: AC_SUBST(GFORTHITC_EXE)
  471: GFORTHITC_EXE=""
  472: AC_SUBST(GFORTHDITC_EXE)
  473: GFORTHDITC_EXE=""
  474: 
  475: AC_SUBST(FORTHSIZES)
  476: 
  477: dnl if test "$PEEPHOLE" = "yes"
  478: dnl then
  479: dnl    PEEPHOLEFLAG="true"
  480: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  481: dnl else
  482: dnl    PEEPHOLEFLAG="false"
  483: dnl fi
  484: PEEPHOLEFLAG="true"
  485: AC_SUBST(PEEPHOLEFLAG)
  486: 
  487: dnl copy commands for systems that don't have links
  488: AC_SUBST(LINK_KERNL)
  489: LINK_KERNL=""
  490: 
  491: #if test $host_os=dos
  492: #then
  493: #  echo Configuring for DOS!!!
  494: #  MAKE_EXE="coff2exe gforth"
  495: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  496: #fi
  497: 
  498: dnl the following macro produces a warning with autoconf-2.1
  499: AC_C_BIGENDIAN
  500: AC_SUBST(KERNEL)
  501: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  502: if test $ac_cv_c_bigendian = yes; then
  503:   bytesex=b
  504:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  505: else
  506:   bytesex=l
  507:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  508: fi
  509: 
  510: #check how to do asm(".skip 16")
  511: echo "CFLAGS=$CFLAGS"
  512: echo "ac_link=$ac_link"
  513: AC_MSG_CHECKING([if and how we can waste code space])
  514: if test -z "$skipcode"; then
  515:     skipcode=no
  516:     CFLAGS_1="$CFLAGS"
  517:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  518:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  519:     do
  520: 	AC_TRY_RUN(
  521: [int foo(int,int,int);
  522: main()
  523: {
  524:   exit(foo(0,0,0)!=16);
  525: }
  526: int foo(int x, int y, int z)
  527: {
  528:   static void *labels[]={&&label1, &&label2};
  529:   if (x) {
  530:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  531:   label1:
  532:     asm("$i"); /* or ".space 16" or somesuch */
  533:   label2: ;
  534:   }
  535:   {
  536:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  537:   return labels[1]-labels[0];
  538:   }
  539: }]
  540: 	,skipcode=$i; break
  541: 	,,)
  542:     done
  543:     CFLAGS=$CFLAGS_1
  544: fi
  545: AC_MSG_RESULT($skipcode)
  546: if test "$skipcode" = no
  547: then 
  548:     if test -z $no_dynamic_default; then
  549: 	no_dynamic_default=1
  550: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  551:     fi
  552:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  553: else
  554:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  555: fi
  556: 
  557: test "$no_dynamic_default" || no_dynamic_default=0
  558: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  559: 
  560: dnl Checks for programs.
  561: AC_PROG_LN_S
  562: AC_PROG_INSTALL
  563: 
  564: dnl Checks for library functions
  565: dnl This check is just for making later checks link with libm.
  566: dnl using sin here is no good idea since it is built-into gcc and typechecked
  567: AC_CHECK_LIB(m,asin)
  568: AC_CHECK_LIB(dl,dlopen)
  569: dnl check for ffcall libraries
  570: dnl unfortunately, these four calls are separated out into a library each.
  571: AC_CHECK_LIB(avcall,__builtin_avcall)
  572: AC_CHECK_LIB(callback,__vacall_r)
  573: AC_CHECK_LIB(vacall,vacall)
  574: AC_CHECK_LIB(trampoline,alloc_trampoline)
  575: FFCALLFLAG="false"
  576: OLDCALLFLAG="true"
  577: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  578: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  579: AC_SUBST(FFCALLFLAG)
  580: AC_SUBST(OLDCALLFLAG)
  581: if test "$host_os" != "nextstep3"
  582: then
  583: 	AC_FUNC_MEMCMP
  584: fi
  585: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  586: AC_FUNC_FSEEKO
  587: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  588: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  589: AC_DECL_SYS_SIGLIST
  590: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  591: AC_CHECK_FUNCS(expm1 log1p)
  592: AC_REPLACE_FUNCS(rint ecvt)
  593: dnl No check for select, because our replacement is no good under
  594: dnl anything but DOS
  595: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  596: AC_FUNC_FNMATCH
  597: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  598: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  599: AM_PATH_LISPDIR
  600: 
  601: kernel_fi=kernl${wordsize}${bytesex}.fi
  602: AC_SUBST(kernel_fi)
  603: 
  604: #this breaks bindists
  605: #dnl replace srource directory by absolute value
  606: #if test $srcdir = "."; then srcdir=`pwd` 
  607: #fi
  608: 
  609: AC_SUBST(machine)
  610: AC_CONFIG_FILES([
  611: Makefile
  612: Makedist
  613: gforthmi
  614: vmgen
  615: machpc.fs
  616: engine/Makefile
  617: doc/version.texi ])
  618: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  619: chmod +x gforthmi
  620: chmod +x vmgen
  621: test -d kernel||mkdir kernel]],[[]])
  622: AC_OUTPUT
  623: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>